qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280                 if(g_ca)
 281                         return FALSE;
 282                 if(g_arena)
 283                         return FALSE;
 284         }
 285         else
 286         {
 287                 if(autocvar_g_pickup_items > 0)
 288                         return TRUE;
 289                 if(autocvar_g_pickup_items == 0)
 290                         return FALSE;
 291                 if(g_ca)
 292                         return FALSE;
 293                 if(g_weaponarena)
 294                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 295                                 return FALSE;
 296         }
 297         return TRUE;
 298 }
 299
 300 #define ITEM_RESPAWN_TICKS 10
 301
 302 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 303         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 304 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 305         // range: 10 .. respawntime + respawntimejitter
 306
 307 floatfield Item_CounterField(float it)
 308 {
 309         switch(it)
 310         {
 311                 case IT_SHELLS:      return ammo_shells;
 312                 case IT_NAILS:       return ammo_nails;
 313                 case IT_ROCKETS:     return ammo_rockets;
 314                 case IT_CELLS:       return ammo_cells;
 315                 case IT_FUEL:        return ammo_fuel;
 316                 case IT_5HP:         return health;
 317                 case IT_25HP:        return health;
 318                 case IT_HEALTH:      return health;
 319                 case IT_ARMOR_SHARD: return armorvalue;
 320                 case IT_ARMOR:       return armorvalue;
 321                 // add more things here (health, armor)
 322                 default:             error("requested item has no counter field");
 323         }
 324 #ifdef GMQCC
 325         // should never happen
 326         return health;
 327 #endif
 328 }
 329
 330 string Item_CounterFieldName(float it)
 331 {
 332         switch(it)
 333         {
 334                 case IT_SHELLS:      return "shells";
 335                 case IT_NAILS:       return "nails";
 336                 case IT_ROCKETS:     return "rockets";
 337                 case IT_CELLS:       return "cells";
 338                 case IT_FUEL:        return "fuel";
 339
 340                 // add more things here (health, armor)
 341                 default:             error("requested item has no counter field name");
 342         }
 343 #ifdef GMQCC
 344         // should never happen
 345         return string_null;
 346 #endif
 347 }
 348
 349 .float max_armorvalue;
 350 .float pickup_anyway;
 351 /*
 352 float Item_Customize()
 353 {
 354         if(self.spawnshieldtime)
 355                 return TRUE;
 356         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 357         {
 358                 self.colormod = '0 0 0';
 359                 self.glowmod = self.colormod;
 360                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 361                 return TRUE;
 362         }
 363         else
 364         {
 365                 if(g_ghost_items)
 366                 {
 367                         self.colormod = stov(autocvar_g_ghost_items_color);
 368                         self.glowmod = self.colormod;
 369                         self.alpha = g_ghost_items;
 370                         return TRUE;
 371                 }
 372                 else
 373                         return FALSE;
 374         }
 375 }
 376 */
 377
 378 void Item_Show (entity e, float mode)
 379 {
 380         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 381         e.ItemStatus &~= ITS_STAYWEP;
 382         if (mode > 0)
 383         {
 384                 // make the item look normal, and be touchable
 385                 e.model = e.mdl;
 386                 e.solid = SOLID_TRIGGER;
 387                 e.spawnshieldtime = 1;
 388                 e.ItemStatus |= ITS_AVAILABLE;
 389         }
 390         else if (mode < 0)
 391         {
 392                 // hide the item completely
 393                 e.model = string_null;
 394                 e.solid = SOLID_NOT;
 395                 e.spawnshieldtime = 1;
 396                 e.ItemStatus &~= ITS_AVAILABLE;
 397         }
 398         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 399         {
 400                 // make the item translucent and not touchable
 401                 e.model = e.mdl;
 402                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 403                 e.effects |= EF_STARDUST;
 404                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 405                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 406         }
 407         else
 408         {
 409                 //setmodel(e, "null");
 410                 e.solid = SOLID_NOT;
 411                 e.colormod = '0 0 0';
 412                 e.glowmod = e.colormod;
 413                 e.spawnshieldtime = 1;
 414                 e.ItemStatus &~= ITS_AVAILABLE;
 415         }
 416
 417         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 418             e.ItemStatus |= ITS_POWERUP;
 419
 420         if (autocvar_g_nodepthtestitems)
 421                 e.effects |= EF_NODEPTHTEST;
 422
 423
 424     if (autocvar_g_fullbrightitems)
 425                 e.ItemStatus |= ITS_ALLOWFB;
 426
 427         if (autocvar_sv_simple_items)
 428         e.ItemStatus |= ITS_ALLOWSI;
 429
 430         // relink entity (because solid may have changed)
 431         setorigin(e, e.origin);
 432     e.SendFlags |= ISF_STATUS;
 433 }
 434
 435 void Item_Respawn (void)
 436 {
 437         Item_Show(self, 1);
 438         // this is ugly...
 439         if(self.items == IT_STRENGTH)
 440                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 441         else if(self.items == IT_INVINCIBLE)
 442                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 443         else
 444                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 445         setorigin (self, self.origin);
 446
 447         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 448         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 449 }
 450
 451 void Item_RespawnCountdown (void)
 452 {
 453         if(self.count >= ITEM_RESPAWN_TICKS)
 454         {
 455                 if(self.waypointsprite_attached)
 456                         WaypointSprite_Kill(self.waypointsprite_attached);
 457                 Item_Respawn();
 458         }
 459         else
 460         {
 461                 self.nextthink = time + 1;
 462                 self.count += 1;
 463                 if(self.count == 1)
 464                 {
 465                         string name;
 466                         vector rgb = '1 0 1';
 467                         name = string_null;
 468                         switch(self.items)
 469                         {
 470                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 471                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 472                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 473                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 474                         }
 475                         item_name = name;
 476                         item_color = rgb;
 477                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 478                         name = item_name;
 479                         rgb = item_color;
 480                         if(self.flags & FL_WEAPON)
 481                         {
 482                                 entity wi = get_weaponinfo(self.weapon);
 483                                 if(wi)
 484                                 {
 485                                         name = wi.model2;
 486                                         rgb = '1 0 0';
 487                                 }
 488                         }
 489                         if(name)
 490                         {
 491                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 492                                 if(self.waypointsprite_attached)
 493                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 494                         }
 495                         else
 496                         {
 497                                 print("Unknown powerup-marked item is wanting to respawn\n");
 498                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 499                         }
 500                 }
 501                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 502                 if(self.waypointsprite_attached)
 503                 {
 504                         WaypointSprite_Ping(self.waypointsprite_attached);
 505                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 506                 }
 507         }
 508 }
 509
 510 void Item_ScheduleRespawnIn(entity e, float t)
 511 {
 512         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 513         {
 514                 e.think = Item_RespawnCountdown;
 515                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 516                 e.count = 0;
 517         }
 518         else
 519         {
 520                 e.think = Item_Respawn;
 521                 e.nextthink = time + t;
 522         }
 523 }
 524
 525 void Item_ScheduleRespawn(entity e)
 526 {
 527         if(e.respawntime > 0)
 528         {
 529                 Item_Show(e, 0);
 530                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 531         }
 532         else // if respawntime is -1, this item does not respawn
 533                 Item_Show(e, -1);
 534 }
 535
 536 void Item_ScheduleInitialRespawn(entity e)
 537 {
 538         Item_Show(e, 0);
 539         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 540 }
 541
 542 float ITEM_MODE_NONE = 0;
 543 float ITEM_MODE_HEALTH = 1;
 544 float ITEM_MODE_ARMOR = 2;
 545 float ITEM_MODE_FUEL = 3;
 546 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 547 {
 548         if (!item.ammofield)
 549                 return FALSE;
 550
 551         if (item.spawnshieldtime)
 552         {
 553                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 554                 {
 555                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 556                         goto YEAH;
 557                 }
 558         }
 559         else if(g_weapon_stay == 2)
 560         {
 561                 float mi = min(item.ammofield, ammomax);
 562                 if (player.ammofield < mi)
 563                 {
 564                         player.ammofield = mi;
 565                         goto YEAH;
 566                 }
 567         }
 568
 569         return FALSE;
 570
 571 :YEAH
 572         switch(mode)
 573         {
 574                 case ITEM_MODE_FUEL:
 575                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 576                         break;
 577                 case ITEM_MODE_HEALTH:
 578                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 579                         break;
 580                 case ITEM_MODE_ARMOR:
 581                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 582                         break;
 583                 default:
 584                         break;
 585         }
 586         return TRUE;
 587 }
 588
 589 float Item_GiveTo(entity item, entity player)
 590 {
 591         float _switchweapon;
 592         float pickedup;
 593         float it;
 594         float i;
 595
 596         // if nothing happens to player, just return without taking the item
 597         pickedup = FALSE;
 598         _switchweapon = FALSE;
 599         // in case the player has autoswitch enabled do the following:
 600         // if the player is using their best weapon before items are given, they
 601         // probably want to switch to an even better weapon after items are given
 602         if (player.autoswitch)
 603         if (player.switchweapon == w_getbestweapon(player))
 604                 _switchweapon = TRUE;
 605
 606         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 607                 _switchweapon = TRUE;
 608
 609         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 610         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 611         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 612         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 613         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 614         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 615         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 616
 617         if (item.flags & FL_WEAPON)
 618         {
 619                 WEPSET_DECLARE_A(it);
 620                 WEPSET_COPY_AE(it, item);
 621                 WEPSET_ANDNOT_AE(it, player);
 622
 623                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && item.pickup_anyway))
 624                 {
 625                         pickedup = TRUE;
 626                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 627                         if(WEPSET_CONTAINS_AW(it, i))
 628                                 W_GiveWeapon(player, i);
 629                 }
 630         }
 631
 632         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 633         {
 634                 pickedup = TRUE;
 635                 player.items |= it;
 636                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 637         }
 638
 639         if (item.strength_finished)
 640         {
 641                 pickedup = TRUE;
 642                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 643         }
 644         if (item.invincible_finished)
 645         {
 646                 pickedup = TRUE;
 647                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 648         }
 649         if (item.superweapons_finished)
 650         {
 651                 pickedup = TRUE;
 652                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 653         }
 654
 655 :skip
 656
 657         // always eat teamed entities
 658         if(item.team)
 659                 pickedup = TRUE;
 660
 661         if (!pickedup)
 662                 return 0;
 663
 664         if (_switchweapon)
 665                 if (player.switchweapon != w_getbestweapon(player))
 666                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 667
 668         return 1;
 669 }
 670
 671 void Item_Touch (void)
 672 {
 673         entity e, head;
 674
 675         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 676         if(self.classname == "droppedweapon")
 677         {
 678                 if (ITEM_TOUCH_NEEDKILL())
 679                 {
 680                         remove(self);
 681                         return;
 682                 }
 683         }
 684
 685         if not(IS_PLAYER(other))
 686                 return;
 687         if (other.frozen)
 688                 return;
 689         if (other.deadflag)
 690                 return;
 691         if (self.solid != SOLID_TRIGGER)
 692                 return;
 693         if (self.owner == other)
 694                 return;
 695         if(MUTATOR_CALLHOOK(ItemTouch))
 696                 return;
 697
 698         if (self.classname == "droppedweapon")
 699         {
 700                 self.strength_finished = max(0, self.strength_finished - time);
 701                 self.invincible_finished = max(0, self.invincible_finished - time);
 702                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 703         }
 704
 705         if(!Item_GiveTo(self, other))
 706         {
 707                 if (self.classname == "droppedweapon")
 708                 {
 709                         // undo what we did above
 710                         self.strength_finished += time;
 711                         self.invincible_finished += time;
 712                         self.superweapons_finished += time;
 713                 }
 714                 return;
 715         }
 716
 717         other.last_pickup = time;
 718
 719         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 720         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 721
 722         if (self.classname == "droppedweapon")
 723                 remove (self);
 724         else if not(self.spawnshieldtime)
 725                 return;
 726         else
 727         {
 728                 if(self.team)
 729                 {
 730                         RandomSelection_Init();
 731                         for(head = world; (head = findfloat(head, team, self.team)); )
 732                         {
 733                                 if(head.flags & FL_ITEM)
 734                                 {
 735                                         Item_Show(head, -1);
 736                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 737                                 }
 738                         }
 739                         e = RandomSelection_chosen_ent;
 740
 741                 }
 742                 else
 743                         e = self;
 744                 Item_ScheduleRespawn(e);
 745         }
 746 }
 747
 748 void Item_Reset()
 749 {
 750         Item_Show(self, !self.state);
 751         setorigin (self, self.origin);
 752
 753         if(self.classname != "droppedweapon")
 754         {
 755                 self.think = func_null;
 756                 self.nextthink = 0;
 757
 758                 if(self.waypointsprite_attached)
 759                         WaypointSprite_Kill(self.waypointsprite_attached);
 760
 761                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 762                         Item_ScheduleInitialRespawn(self);
 763         }
 764 }
 765
 766 void Item_FindTeam()
 767 {
 768         entity head, e;
 769
 770         if(self.effects & EF_NODRAW)
 771         {
 772                 // marker for item team search
 773                 dprint("Initializing item team ", ftos(self.team), "\n");
 774                 RandomSelection_Init();
 775                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 776                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 777                 e = RandomSelection_chosen_ent;
 778                 e.state = 0;
 779                 Item_Show(e, 1);
 780
 781                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 782                 {
 783                         if(head != e)
 784                         {
 785                                 // make it a non-spawned item
 786                                 Item_Show(head, -1);
 787                                 head.state = 1; // state 1 = initially hidden item
 788                         }
 789                         head.effects &~= EF_NODRAW;
 790                 }
 791
 792                 Item_Reset();
 793         }
 794 }
 795
 796 // Savage: used for item garbage-collection
 797 // TODO: perhaps nice special effect?
 798 void RemoveItem(void)
 799 {
 800         remove(self);
 801 }
 802
 803 // pickup evaluation functions
 804 // these functions decide how desirable an item is to the bots
 805
 806 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 807
 808 float weapon_pickupevalfunc(entity player, entity item)
 809 {
 810         float c, j, position;
 811
 812         // See if I have it already
 813         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 814         {
 815                 // If I can pick it up
 816                 if(!item.spawnshieldtime)
 817                         c = 0;
 818                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 819                 {
 820                         // Skilled bots will grab more
 821                         c = bound(0, skill / 10, 1) * 0.5;
 822                 }
 823                 else
 824                         c = 0;
 825         }
 826         else
 827                 c = 1;
 828
 829         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 830         if( bot_custom_weapon && c )
 831         {
 832                 // Find the highest position on any range
 833                 position = -1;
 834                 for(j = 0; j < WEP_LAST ; ++j){
 835                         if(
 836                                         bot_weapons_far[j] == item.weapon ||
 837                                         bot_weapons_mid[j] == item.weapon ||
 838                                         bot_weapons_close[j] == item.weapon
 839                           )
 840                         {
 841                                 position = j;
 842                                 break;
 843                         }
 844                 }
 845
 846                 // Rate it
 847                 if (position >= 0 )
 848                 {
 849                         position = WEP_LAST - position;
 850                         // item.bot_pickupbasevalue is overwritten here
 851                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 852                 }
 853         }
 854
 855         return item.bot_pickupbasevalue * c;
 856 }
 857
 858 float commodity_pickupevalfunc(entity player, entity item)
 859 {
 860         float c, i;
 861         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 862         entity wi;
 863         c = 0;
 864
 865         // Detect needed ammo
 866         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 867         {
 868                 wi = get_weaponinfo(i);
 869
 870                 if not(WEPSET_CONTAINS_EW(player, i))
 871                         continue;
 872
 873                 if(wi.items & IT_SHELLS)
 874                         need_shells = TRUE;
 875                 else if(wi.items & IT_NAILS)
 876                         need_nails = TRUE;
 877                 else if(wi.items & IT_ROCKETS)
 878                         need_rockets = TRUE;
 879                 else if(wi.items & IT_CELLS)
 880                         need_cells = TRUE;
 881                 else if(wi.items & IT_FUEL)
 882                         need_cells = TRUE;
 883         }
 884
 885         // TODO: figure out if the player even has the weapon this ammo is for?
 886         // may not affect strategy much though...
 887         // find out how much more ammo/armor/health the player can hold
 888         if (need_shells)
 889         if (item.ammo_shells)
 890         if (player.ammo_shells < g_pickup_shells_max)
 891                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 892         if (need_nails)
 893         if (item.ammo_nails)
 894         if (player.ammo_nails < g_pickup_nails_max)
 895                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 896         if (need_rockets)
 897         if (item.ammo_rockets)
 898         if (player.ammo_rockets < g_pickup_rockets_max)
 899                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 900         if (need_cells)
 901         if (item.ammo_cells)
 902         if (player.ammo_cells < g_pickup_cells_max)
 903                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 904         if (need_fuel)
 905         if (item.ammo_fuel)
 906         if (player.ammo_fuel < g_pickup_fuel_max)
 907                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 908         if (item.armorvalue)
 909         if (player.armorvalue < item.max_armorvalue)
 910                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 911         if (item.health)
 912         if (player.health < item.max_health)
 913                 c = c + max(0, 1 - player.health / item.max_health);
 914
 915         return item.bot_pickupbasevalue * c;
 916 }
 917
 918 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 919 {
 920         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 921                 RemoveItem();
 922 }
 923
 924 .float is_item;
 925 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 926 {
 927         startitem_failed = FALSE;
 928
 929         if(self.model == "")
 930                 self.model = itemmodel;
 931
 932         if(self.model == "")
 933     {
 934         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 935         return;
 936     }
 937
 938         if(self.item_pickupsound == "")
 939                 self.item_pickupsound = pickupsound;
 940
 941         if(!self.respawntime) // both need to be set
 942         {
 943                 self.respawntime = defaultrespawntime;
 944                 self.respawntimejitter = defaultrespawntimejitter;
 945         }
 946
 947         self.items = itemid;
 948         self.weapon = weaponid;
 949
 950         if(weaponid)
 951                 WEPSET_COPY_EW(self, weaponid);
 952
 953         self.flags = FL_ITEM | itemflags;
 954
 955         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 956         {
 957                 startitem_failed = TRUE;
 958                 remove(self);
 959                 return;
 960         }
 961
 962         // is it a dropped weapon?
 963         if (self.classname == "droppedweapon")
 964         {
 965                 self.reset = SUB_Remove;
 966                 // it's a dropped weapon
 967                 self.movetype = MOVETYPE_TOSS;
 968
 969                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 970                 self.think = RemoveItem;
 971                 self.nextthink = time + 20;
 972
 973                 self.takedamage = DAMAGE_YES;
 974                 self.event_damage = Item_Damage;
 975
 976                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 977                 /*
 978                 if(self.items == 0)
 979                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 980                 if(self.ammo_nails == 0)
 981                 if(self.ammo_cells == 0)
 982                 if(self.ammo_rockets == 0)
 983                 if(self.ammo_shells == 0)
 984                 if(self.ammo_fuel == 0)
 985                 if(self.health == 0)
 986                 if(self.armorvalue == 0)
 987                 */
 988                 {
 989                         // if item is worthless after a timer, have it expire then
 990                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 991                 }
 992
 993                 // don't drop if in a NODROP zone (such as lava)
 994                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 995                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 996                 {
 997                         startitem_failed = TRUE;
 998                         remove(self);
 999                         return;
1000                 }
1001         }
1002         else
1003         {
1004                 if(!have_pickup_item())
1005                 {
1006                         startitem_failed = TRUE;
1007                         remove (self);
1008                         return;
1009                 }
1010
1011                 if(self.angles != '0 0 0')
1012             self.SendFlags |= ISF_ANGLES;
1013
1014                 self.reset = Item_Reset;
1015                 // it's a level item
1016                 if(self.spawnflags & 1)
1017                         self.noalign = 1;
1018                 if (self.noalign)
1019                         self.movetype = MOVETYPE_NONE;
1020                 else
1021                         self.movetype = MOVETYPE_TOSS;
1022                 // do item filtering according to game mode and other things
1023                 if (!self.noalign)
1024                 {
1025                         // first nudge it off the floor a little bit to avoid math errors
1026                         setorigin(self, self.origin + '0 0 1');
1027                         // set item size before we spawn a spawnfunc_waypoint
1028                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1029                                 setsize (self, '-16 -16 0', '16 16 48');
1030                         else
1031                                 setsize (self, '-16 -16 0', '16 16 32');
1032                         // note droptofloor returns FALSE if stuck/or would fall too far
1033                         droptofloor();
1034                         waypoint_spawnforitem(self);
1035                 }
1036
1037                 /*
1038                  * can't do it that way, as it would break maps
1039                  * TODO make a target_give like entity another way, that perhaps has
1040                  * the weapon name in a key
1041                 if(self.targetname)
1042                 {
1043                         // target_give not yet supported; maybe later
1044                         print("removed targeted ", self.classname, "\n");
1045                         startitem_failed = TRUE;
1046                         remove (self);
1047                         return;
1048                 }
1049                 */
1050
1051                 if(autocvar_spawn_debug >= 2)
1052                 {
1053                         entity otheritem;
1054                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1055                         {
1056                             // why not flags & fl_item?
1057                                 if(otheritem.is_item)
1058                                 {
1059                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1060                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1061                                         error("Mapper sucks.");
1062                                 }
1063                         }
1064                         self.is_item = TRUE;
1065                 }
1066
1067                 WEPSET_OR_AW(weaponsInMap, weaponid);
1068
1069                 precache_model (self.model);
1070                 precache_sound (self.item_pickupsound);
1071
1072                 precache_sound ("misc/itemrespawncountdown.wav");
1073                 if(itemid == IT_STRENGTH)
1074                         precache_sound ("misc/strength_respawn.wav");
1075                 else if(itemid == IT_INVINCIBLE)
1076                         precache_sound ("misc/shield_respawn.wav");
1077                 else
1078                         precache_sound ("misc/itemrespawn.wav");
1079
1080                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1081                         self.target = "###item###"; // for finding the nearest item using find()
1082         }
1083
1084         self.bot_pickup = TRUE;
1085         self.bot_pickupevalfunc = pickupevalfunc;
1086         self.bot_pickupbasevalue = pickupbasevalue;
1087         self.mdl = self.model;
1088         self.netname = itemname;
1089         self.touch = Item_Touch;
1090         setmodel(self, "null"); // precision set below
1091         //self.effects |= EF_LOWPRECISION;
1092
1093         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1094     {
1095         self.pos1 = '-16 -16 0';
1096         self.pos2 = '16 16 48';
1097     }
1098         else
1099     {
1100         self.pos1 = '-16 -16 0';
1101         self.pos2 = '16 16 32';
1102     }
1103     setsize (self, self.pos1, self.pos2);
1104
1105     if(itemflags & FL_POWERUP)
1106         self.ItemStatus |= ITS_ANIMATE1;
1107
1108         if(self.armorvalue || self.health)
1109         self.ItemStatus |= ITS_ANIMATE2;
1110
1111         if(itemflags & FL_WEAPON)
1112         {
1113                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1114             self.colormap = 1024; // color shirt=0 pants=0 grey
1115         else
1116             self.gravity = 1;
1117
1118                 self.ItemStatus |= ITS_ANIMATE1;
1119                 self.ItemStatus |= ISF_COLORMAP;
1120         }
1121
1122         self.state = 0;
1123         if(self.team) // broken, no idea why.
1124         {
1125                 if(!self.cnt)
1126                         self.cnt = 1; // item probability weight
1127
1128                 self.effects |= EF_NODRAW; // marker for item team search
1129                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1130         }
1131         else
1132                 Item_Reset();
1133
1134     Net_LinkEntity(self, FALSE, 0, ItemSend);
1135
1136         // call this hook after everything else has been done
1137         if(MUTATOR_CALLHOOK(Item_Spawn))
1138         {
1139                 startitem_failed = TRUE;
1140                 remove(self);
1141                 return;
1142         }
1143 }
1144
1145 float weaponswapping;
1146 float internalteam;
1147
1148 void weapon_defaultspawnfunc(float wpn)
1149 {
1150         entity e;
1151         float t;
1152         var .float ammofield;
1153         string s;
1154         entity oldself;
1155         float i, j;
1156         float f;
1157
1158         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1159         {
1160                 e = get_weaponinfo(wpn);
1161
1162                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1163                 {
1164                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1165                         /*
1166                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1167                         startitem_failed = TRUE;
1168                         return;
1169                         */
1170                 }
1171
1172                 s = W_Apply_Weaponreplace(e.netname);
1173                 ret_string = s;
1174                 other = e;
1175                 MUTATOR_CALLHOOK(SetWeaponreplace);
1176                 s = ret_string;
1177                 if(s == "")
1178                 {
1179                         remove(self);
1180                         startitem_failed = TRUE;
1181                         return;
1182                 }
1183                 t = tokenize_console(s);
1184                 if(t >= 2)
1185                 {
1186                         self.team = --internalteam;
1187                         oldself = self;
1188                         for(i = 1; i < t; ++i)
1189                         {
1190                                 s = argv(i);
1191                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1192                                 {
1193                                         e = get_weaponinfo(j);
1194                                         if(e.netname == s)
1195                                         {
1196                                                 self = spawn();
1197                                                 copyentity(oldself, self);
1198                                                 self.classname = "replacedweapon";
1199                                                 weapon_defaultspawnfunc(j);
1200                                                 break;
1201                                         }
1202                                 }
1203                                 if(j > WEP_LAST)
1204                                 {
1205                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1206                                 }
1207                         }
1208                         self = oldself;
1209                 }
1210                 if(t >= 1) // always the case!
1211                 {
1212                         s = argv(0);
1213                         wpn = 0;
1214                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1215                         {
1216                                 e = get_weaponinfo(j);
1217                                 if(e.netname == s)
1218                                 {
1219                                         wpn = j;
1220                                         break;
1221                                 }
1222                         }
1223                         if(j > WEP_LAST)
1224                         {
1225                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1226                         }
1227                 }
1228                 if(wpn == 0)
1229                 {
1230                         remove(self);
1231                         startitem_failed = TRUE;
1232                         return;
1233                 }
1234         }
1235
1236         e = get_weaponinfo(wpn);
1237
1238         if(!self.respawntime)
1239         {
1240                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1241                 {
1242                         self.respawntime = g_pickup_respawntime_superweapon;
1243                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1244                 }
1245                 else
1246                 {
1247                         self.respawntime = g_pickup_respawntime_weapon;
1248                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1249                 }
1250         }
1251
1252         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1253                 if(!self.superweapons_finished)
1254                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1255
1256         if(e.items)
1257         {
1258                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1259                 {
1260                         if(e.items & j)
1261                         {
1262                                 ammofield = Item_CounterField(j);
1263                                 if(!self.ammofield)
1264                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1265                         }
1266                 }
1267         }
1268
1269         // pickup anyway
1270         if(g_pickup_weapons_anyway)
1271                 self.pickup_anyway = TRUE;
1272
1273         f = FL_WEAPON;
1274
1275         // no weapon-stay on superweapons
1276         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1277                 f |= FL_NO_WEAPON_STAY;
1278
1279         // weapon stay isn't supported for teamed weapons
1280         if(self.team)
1281                 f |= FL_NO_WEAPON_STAY;
1282
1283         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1284         if (self.modelindex) // don't precache if self was removed
1285                 weapon_action(e.weapon, WR_PRECACHE);
1286 }
1287
1288 void spawnfunc_weapon_shotgun (void);
1289 void spawnfunc_weapon_uzi (void) {
1290         if(autocvar_sv_q3acompat_machineshotgunswap)
1291         if(self.classname != "droppedweapon")
1292         {
1293                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1294                 return;
1295         }
1296         weapon_defaultspawnfunc(WEP_UZI);
1297 }
1298
1299 void spawnfunc_weapon_shotgun (void) {
1300         if(autocvar_sv_q3acompat_machineshotgunswap)
1301         if(self.classname != "droppedweapon")
1302         {
1303                 weapon_defaultspawnfunc(WEP_UZI);
1304                 return;
1305         }
1306         weapon_defaultspawnfunc(WEP_SHOTGUN);
1307 }
1308
1309 void spawnfunc_weapon_nex (void)
1310 {
1311         weapon_defaultspawnfunc(WEP_NEX);
1312 }
1313
1314 void spawnfunc_weapon_minstanex (void)
1315 {
1316         weapon_defaultspawnfunc(WEP_MINSTANEX);
1317 }
1318
1319 void spawnfunc_weapon_rocketlauncher (void)
1320 {
1321         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1322 }
1323
1324 void spawnfunc_item_rockets (void) {
1325         if(!self.ammo_rockets)
1326                 self.ammo_rockets = g_pickup_rockets;
1327         if(!self.pickup_anyway)
1328                 self.pickup_anyway = g_pickup_ammo_anyway;
1329         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1330 }
1331
1332 void spawnfunc_item_shells (void);
1333 void spawnfunc_item_bullets (void) {
1334         if(!weaponswapping)
1335         if(autocvar_sv_q3acompat_machineshotgunswap)
1336         if(self.classname != "droppedweapon")
1337         {
1338                 weaponswapping = TRUE;
1339                 spawnfunc_item_shells();
1340                 weaponswapping = FALSE;
1341                 return;
1342         }
1343
1344         if(!self.ammo_nails)
1345                 self.ammo_nails = g_pickup_nails;
1346         if(!self.pickup_anyway)
1347                 self.pickup_anyway = g_pickup_ammo_anyway;
1348         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1349 }
1350
1351 void spawnfunc_item_cells (void) {
1352         if(!self.ammo_cells)
1353                 self.ammo_cells = g_pickup_cells;
1354         if(!self.pickup_anyway)
1355                 self.pickup_anyway = g_pickup_ammo_anyway;
1356         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1357 }
1358
1359 void spawnfunc_item_shells (void) {
1360         if(!weaponswapping)
1361         if(autocvar_sv_q3acompat_machineshotgunswap)
1362         if(self.classname != "droppedweapon")
1363         {
1364                 weaponswapping = TRUE;
1365                 spawnfunc_item_bullets();
1366                 weaponswapping = FALSE;
1367                 return;
1368         }
1369
1370         if(!self.ammo_shells)
1371                 self.ammo_shells = g_pickup_shells;
1372         if(!self.pickup_anyway)
1373                 self.pickup_anyway = g_pickup_ammo_anyway;
1374         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1375 }
1376
1377 void spawnfunc_item_armor_small (void) {
1378         if(!self.armorvalue)
1379                 self.armorvalue = g_pickup_armorsmall;
1380         if(!self.max_armorvalue)
1381                 self.max_armorvalue = g_pickup_armorsmall_max;
1382         if(!self.pickup_anyway)
1383                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1384         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1385 }
1386
1387 void spawnfunc_item_armor_medium (void) {
1388         if(!self.armorvalue)
1389                 self.armorvalue = g_pickup_armormedium;
1390         if(!self.max_armorvalue)
1391                 self.max_armorvalue = g_pickup_armormedium_max;
1392         if(!self.pickup_anyway)
1393                 self.pickup_anyway = g_pickup_armormedium_anyway;
1394         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1395 }
1396
1397 void spawnfunc_item_armor_big (void) {
1398         if(!self.armorvalue)
1399                 self.armorvalue = g_pickup_armorbig;
1400         if(!self.max_armorvalue)
1401                 self.max_armorvalue = g_pickup_armorbig_max;
1402         if(!self.pickup_anyway)
1403                 self.pickup_anyway = g_pickup_armorbig_anyway;
1404         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1405 }
1406
1407 void spawnfunc_item_armor_large (void) {
1408         if(!self.armorvalue)
1409                 self.armorvalue = g_pickup_armorlarge;
1410         if(!self.max_armorvalue)
1411                 self.max_armorvalue = g_pickup_armorlarge_max;
1412         if(!self.pickup_anyway)
1413                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1414         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1415 }
1416
1417 void spawnfunc_item_health_small (void) {
1418         if(!self.max_health)
1419                 self.max_health = g_pickup_healthsmall_max;
1420         if(!self.health)
1421                 self.health = g_pickup_healthsmall;
1422         if(!self.pickup_anyway)
1423                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1424         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1425 }
1426
1427 void spawnfunc_item_health_medium (void) {
1428         if(!self.max_health)
1429                 self.max_health = g_pickup_healthmedium_max;
1430         if(!self.health)
1431                 self.health = g_pickup_healthmedium;
1432         if(!self.pickup_anyway)
1433                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1434         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1435 }
1436
1437 void spawnfunc_item_health_large (void) {
1438         if(!self.max_health)
1439                 self.max_health = g_pickup_healthlarge_max;
1440         if(!self.health)
1441                 self.health = g_pickup_healthlarge;
1442         if(!self.pickup_anyway)
1443                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1444         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1445 }
1446
1447 void spawnfunc_item_health_mega (void) {
1448                 if(!self.max_health)
1449                         self.max_health = g_pickup_healthmega_max;
1450                 if(!self.health)
1451                         self.health = g_pickup_healthmega;
1452                 if(!self.pickup_anyway)
1453                         self.pickup_anyway = g_pickup_healthmega_anyway;
1454                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1455 }
1456
1457 // support old misnamed entities
1458 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1459 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1460 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1461 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1462 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1463
1464 void spawnfunc_item_strength (void) {
1465                 precache_sound("weapons/strength_fire.wav");
1466                 if(!self.strength_finished)
1467                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1468                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1469 }
1470
1471 void spawnfunc_item_invincible (void) {
1472                 if(!self.invincible_finished)
1473                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1474                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1475 }
1476
1477 // compatibility:
1478 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1479
1480 float GiveItems(entity e, float beginarg, float endarg);
1481 void target_items_use (void)
1482 {
1483         if(activator.classname == "droppedweapon")
1484         {
1485                 EXACTTRIGGER_TOUCH;
1486                 remove(activator);
1487                 return;
1488         }
1489
1490         if not(IS_PLAYER(activator))
1491                 return;
1492         if(activator.deadflag != DEAD_NO)
1493                 return;
1494         EXACTTRIGGER_TOUCH;
1495
1496         entity e;
1497         for(e = world; (e = find(e, classname, "droppedweapon")); )
1498                 if(e.enemy == activator)
1499                         remove(e);
1500
1501         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1502                 centerprint(activator, self.message);
1503 }
1504
1505 void spawnfunc_target_items (void)
1506 {
1507         float n, i, j;
1508         entity e;
1509
1510         self.use = target_items_use;
1511         if(!self.strength_finished)
1512                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1513         if(!self.invincible_finished)
1514                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1515         if(!self.superweapons_finished)
1516                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1517
1518         precache_sound("misc/itempickup.wav");
1519         precache_sound("misc/megahealth.wav");
1520         precache_sound("misc/armor25.wav");
1521         precache_sound("misc/powerup.wav");
1522         precache_sound("misc/poweroff.wav");
1523         precache_sound("weapons/weaponpickup.wav");
1524
1525         n = tokenize_console(self.netname);
1526         if(argv(0) == "give")
1527         {
1528                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1529         }
1530         else
1531         {
1532                 for(i = 0; i < n; ++i)
1533                 {
1534                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1535                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1536                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1537                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1538                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1539                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1540                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1541                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1542                         else
1543                         {
1544                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1545                                 {
1546                                         e = get_weaponinfo(j);
1547                                         if(argv(i) == e.netname)
1548                                         {
1549                                                 WEPSET_OR_EW(self, j);
1550                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1551                                                         weapon_action(e.weapon, WR_PRECACHE);
1552                                                 break;
1553                                         }
1554                                 }
1555                                 if(j > WEP_LAST)
1556                                         print("target_items: invalid item ", argv(i), "\n");
1557                         }
1558                 }
1559
1560                 string itemprefix, valueprefix;
1561                 if(self.spawnflags == 0)
1562                 {
1563                         itemprefix = "";
1564                         valueprefix = "";
1565                 }
1566                 else if(self.spawnflags == 1)
1567                 {
1568                         itemprefix = "max ";
1569                         valueprefix = "max ";
1570                 }
1571                 else if(self.spawnflags == 2)
1572                 {
1573                         itemprefix = "min ";
1574                         valueprefix = "min ";
1575                 }
1576                 else if(self.spawnflags == 4)
1577                 {
1578                         itemprefix = "minus ";
1579                         valueprefix = "max ";
1580                 }
1581                 else
1582                 {
1583                         error("invalid spawnflags");
1584 #ifdef GMQCC
1585                         itemprefix = string_null;
1586                         valueprefix = string_null;
1587 #endif
1588                 }
1589
1590                 self.netname = "";
1591                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1592                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1593                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1594                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1595                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1596                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1597                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1598                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1599                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1600                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1601                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1602                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1603                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1604                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1605                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1606                 {
1607                         e = get_weaponinfo(j);
1608                         if(e.weapon)
1609                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1610                 }
1611         }
1612         self.netname = strzone(self.netname);
1613         //print(self.netname, "\n");
1614
1615         n = tokenize_console(self.netname);
1616         for(i = 0; i < n; ++i)
1617         {
1618                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1619                 {
1620                         e = get_weaponinfo(j);
1621                         if(argv(i) == e.netname)
1622                         {
1623                                 weapon_action(e.weapon, WR_PRECACHE);
1624                                 break;
1625                         }
1626                 }
1627         }
1628 }
1629
1630 void spawnfunc_item_fuel(void)
1631 {
1632         if(!self.ammo_fuel)
1633                 self.ammo_fuel = g_pickup_fuel;
1634         if(!self.pickup_anyway)
1635                 self.pickup_anyway = g_pickup_ammo_anyway;
1636         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1637 }
1638
1639 void spawnfunc_item_fuel_regen(void)
1640 {
1641         if(start_items & IT_FUEL_REGEN)
1642         {
1643                 spawnfunc_item_fuel();
1644                 return;
1645         }
1646         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1647 }
1648
1649 void spawnfunc_item_jetpack(void)
1650 {
1651         if(g_grappling_hook)
1652                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1653         if(!self.ammo_fuel)
1654                 self.ammo_fuel = g_pickup_fuel_jetpack;
1655         if(start_items & IT_JETPACK)
1656         {
1657                 spawnfunc_item_fuel();
1658                 return;
1659         }
1660         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1661 }
1662
1663
1664 #define OP_SET 0
1665 #define OP_MIN 1
1666 #define OP_MAX 2
1667 #define OP_PLUS 3
1668 #define OP_MINUS 4
1669
1670 float GiveWeapon(entity e, float wpn, float op, float val)
1671 {
1672         float v0, v1;
1673         v0 = WEPSET_CONTAINS_EW(e, wpn);
1674         switch(op)
1675         {
1676                 case OP_SET:
1677                         if(val > 0)
1678                                 WEPSET_OR_EW(e, wpn);
1679                         else
1680                                 WEPSET_ANDNOT_EW(e, wpn);
1681                         break;
1682                 case OP_MIN:
1683                 case OP_PLUS:
1684                         if(val > 0)
1685                                 WEPSET_OR_EW(e, wpn);
1686                         break;
1687                 case OP_MAX:
1688                         if(val <= 0)
1689                                 WEPSET_ANDNOT_EW(e, wpn);
1690                         break;
1691                 case OP_MINUS:
1692                         if(val > 0)
1693                                 WEPSET_ANDNOT_EW(e, wpn);
1694                         break;
1695         }
1696         v1 = WEPSET_CONTAINS_EW(e, wpn);
1697         return (v0 != v1);
1698 }
1699
1700 float GiveBit(entity e, .float fld, float bit, float op, float val)
1701 {
1702         float v0, v1;
1703         v0 = (e.fld & bit);
1704         switch(op)
1705         {
1706                 case OP_SET:
1707                         if(val > 0)
1708                                 e.fld |= bit;
1709                         else
1710                                 e.fld &~= bit;
1711                         break;
1712                 case OP_MIN:
1713                 case OP_PLUS:
1714                         if(val > 0)
1715                                 e.fld |= bit;
1716                         break;
1717                 case OP_MAX:
1718                         if(val <= 0)
1719                                 e.fld &~= bit;
1720                         break;
1721                 case OP_MINUS:
1722                         if(val > 0)
1723                                 e.fld &~= bit;
1724                         break;
1725         }
1726         v1 = (e.fld & bit);
1727         return (v0 != v1);
1728 }
1729
1730 float GiveValue(entity e, .float fld, float op, float val)
1731 {
1732         float v0, v1;
1733         v0 = e.fld;
1734         switch(op)
1735         {
1736                 case OP_SET:
1737                         e.fld = val;
1738                         break;
1739                 case OP_MIN:
1740                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1741                         break;
1742                 case OP_MAX:
1743                         e.fld = min(e.fld, val);
1744                         break;
1745                 case OP_PLUS:
1746                         e.fld += val;
1747                         break;
1748                 case OP_MINUS:
1749                         e.fld -= val;
1750                         break;
1751         }
1752         v1 = e.fld;
1753         return (v0 != v1);
1754 }
1755
1756 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1757 {
1758         if(v1 == v0)
1759                 return;
1760         if(v1 <= v0 - t)
1761         {
1762                 if(snd_decr != "")
1763                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1764         }
1765         else if(v0 >= v0 + t)
1766         {
1767                 if(snd_incr != "")
1768                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1769         }
1770 }
1771
1772 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1773 {
1774         if(v0 < v1)
1775                 e.rotfield = max(e.rotfield, time + rottime);
1776         else if(v0 > v1)
1777                 e.regenfield = max(e.regenfield, time + regentime);
1778 }
1779
1780 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1781 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1782 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1783 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1784 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1785 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1786
1787 float GiveItems(entity e, float beginarg, float endarg)
1788 {
1789         float got, i, j, val, op;
1790         float _switchweapon;
1791         entity wi;
1792         string cmd;
1793
1794         val = 999;
1795         op = OP_SET;
1796
1797         got = 0;
1798
1799         _switchweapon = FALSE;
1800         if (e.autoswitch)
1801                 if (e.switchweapon == w_getbestweapon(e))
1802                         _switchweapon = TRUE;
1803
1804         e.strength_finished = max(0, e.strength_finished - time);
1805         e.invincible_finished = max(0, e.invincible_finished - time);
1806         e.superweapons_finished = max(0, e.superweapons_finished - time);
1807
1808         PREGIVE(e, items);
1809         PREGIVE_WEAPONS(e);
1810         PREGIVE(e, strength_finished);
1811         PREGIVE(e, invincible_finished);
1812         PREGIVE(e, superweapons_finished);
1813         PREGIVE(e, ammo_nails);
1814         PREGIVE(e, ammo_cells);
1815         PREGIVE(e, ammo_shells);
1816         PREGIVE(e, ammo_rockets);
1817         PREGIVE(e, ammo_fuel);
1818         PREGIVE(e, armorvalue);
1819         PREGIVE(e, health);
1820
1821         for(i = beginarg; i < endarg; ++i)
1822         {
1823                 cmd = argv(i);
1824
1825                 if(cmd == "0" || stof(cmd))
1826                 {
1827                         val = stof(cmd);
1828                         continue;
1829                 }
1830                 switch(cmd)
1831                 {
1832                         case "no":
1833                                 op = OP_MAX;
1834                                 val = 0;
1835                                 continue;
1836                         case "max":
1837                                 op = OP_MAX;
1838                                 continue;
1839                         case "min":
1840                                 op = OP_MIN;
1841                                 continue;
1842                         case "plus":
1843                                 op = OP_PLUS;
1844                                 continue;
1845                         case "minus":
1846                                 op = OP_MINUS;
1847                                 continue;
1848                         case "ALL":
1849                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1850                                 got += GiveValue(e, strength_finished, op, val);
1851                                 got += GiveValue(e, invincible_finished, op, val);
1852                                 got += GiveValue(e, superweapons_finished, op, val);
1853                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1854                         case "all":
1855                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1856                                 got += GiveValue(e, health, op, val);
1857                                 got += GiveValue(e, armorvalue, op, val);
1858                         case "allweapons":
1859                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1860                                 {
1861                                         wi = get_weaponinfo(j);
1862                                         if(wi.weapon)
1863                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1864                                                         got += GiveWeapon(e, j, op, val);
1865                                 }
1866                         case "allammo":
1867                                 got += GiveValue(e, ammo_cells, op, val);
1868                                 got += GiveValue(e, ammo_shells, op, val);
1869                                 got += GiveValue(e, ammo_nails, op, val);
1870                                 got += GiveValue(e, ammo_rockets, op, val);
1871                                 got += GiveValue(e, ammo_fuel, op, val);
1872                                 break;
1873                         case "unlimited_ammo":
1874                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1875                                 break;
1876                         case "unlimited_weapon_ammo":
1877                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1878                                 break;
1879                         case "unlimited_superweapons":
1880                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1881                                 break;
1882                         case "jetpack":
1883                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1884                                 break;
1885                         case "fuel_regen":
1886                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1887                                 break;
1888                         case "strength":
1889                                 got += GiveValue(e, strength_finished, op, val);
1890                                 break;
1891                         case "invincible":
1892                                 got += GiveValue(e, invincible_finished, op, val);
1893                                 break;
1894                         case "superweapons":
1895                                 got += GiveValue(e, superweapons_finished, op, val);
1896                                 break;
1897                         case "cells":
1898                                 got += GiveValue(e, ammo_cells, op, val);
1899                                 break;
1900                         case "shells":
1901                                 got += GiveValue(e, ammo_shells, op, val);
1902                                 break;
1903                         case "nails":
1904                         case "bullets":
1905                                 got += GiveValue(e, ammo_nails, op, val);
1906                                 break;
1907                         case "rockets":
1908                                 got += GiveValue(e, ammo_rockets, op, val);
1909                                 break;
1910                         case "health":
1911                                 got += GiveValue(e, health, op, val);
1912                                 break;
1913                         case "armor":
1914                                 got += GiveValue(e, armorvalue, op, val);
1915                                 break;
1916                         case "fuel":
1917                                 got += GiveValue(e, ammo_fuel, op, val);
1918                                 break;
1919                         default:
1920                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1921                                 {
1922                                         wi = get_weaponinfo(j);
1923                                         if(cmd == wi.netname)
1924                                         {
1925                                                 got += GiveWeapon(e, j, op, val);
1926                                                 break;
1927                                         }
1928                                 }
1929                                 if(j > WEP_LAST)
1930                                         print("give: invalid item ", cmd, "\n");
1931                                 break;
1932                 }
1933                 val = 999;
1934                 op = OP_SET;
1935         }
1936
1937         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1938         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1939         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1940         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1941         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1942         {
1943                 wi = get_weaponinfo(j);
1944                 if(wi.weapon)
1945                 {
1946                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1947                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1948                                 if(WEPSET_CONTAINS_EW(e, j))
1949                                         weapon_action(wi.weapon, WR_PRECACHE);
1950                 }
1951         }
1952         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1953         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1954         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1955         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1956         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1957         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1958         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1959         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1960         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1961
1962         if(e.superweapons_finished <= 0)
1963                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1964                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1965
1966         if(e.strength_finished <= 0)
1967                 e.strength_finished = 0;
1968         else
1969                 e.strength_finished += time;
1970         if(e.invincible_finished <= 0)
1971                 e.invincible_finished = 0;
1972         else
1973                 e.invincible_finished += time;
1974         if(e.superweapons_finished <= 0)
1975                 e.superweapons_finished = 0;
1976         else
1977                 e.superweapons_finished += time;
1978
1979         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1980                 _switchweapon = TRUE;
1981         if(_switchweapon)
1982                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1983
1984         return got;
1985 }
1986 #endif