qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "bot/bot.qh"
   9     #include "bot/waypoints.qh"
  10
  11     #include "mutators/mutators_include.qh"
  12
  13     #include "weapons/common.qh"
  14     #include "weapons/selection.qh"
  15     #include "weapons/weaponsystem.qh"
  16
  17     #include "../common/constants.qh"
  18     #include "../common/deathtypes.qh"
  19     #include "../common/notifications.qh"
  20         #include "../common/triggers/subs.qh"
  21     #include "../common/util.qh"
  22
  23     #include "../common/monsters/all.qh"
  24
  25     #include "../common/weapons/all.qh"
  26
  27     #include "../warpzonelib/util_server.qh"
  28 #endif
  29
  30 #ifdef CSQC
  31 void ItemDraw()
  32 {
  33     if(self.gravity)
  34     {
  35         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  36         if(self.move_flags & FL_ONGROUND)
  37         { // For some reason move_avelocity gets set to '0 0 0' here ...
  38             self.oldorigin = self.origin;
  39             self.gravity = 0;
  40
  41             if(autocvar_cl_animate_items)
  42             { // ... so reset it if animations are requested.
  43                 if(self.ItemStatus & ITS_ANIMATE1)
  44                     self.move_avelocity = '0 180 0';
  45
  46                 if(self.ItemStatus & ITS_ANIMATE2)
  47                     self.move_avelocity = '0 -90 0';
  48             }
  49         }
  50     }
  51     else if (autocvar_cl_animate_items)
  52     {
  53         if(self.ItemStatus & ITS_ANIMATE1)
  54         {
  55             self.angles += self.move_avelocity * frametime;
  56             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  57         }
  58
  59         if(self.ItemStatus & ITS_ANIMATE2)
  60         {
  61             self.angles += self.move_avelocity * frametime;
  62             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  63         }
  64     }
  65 }
  66
  67 void ItemDrawSimple()
  68 {
  69     if(self.gravity)
  70     {
  71         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  72
  73         if(self.move_flags & FL_ONGROUND)
  74             self.gravity = 0;
  75     }
  76 }
  77
  78 void ItemRead(float _IsNew)
  79 {
  80     int sf = ReadByte();
  81
  82     if(sf & ISF_LOCATION)
  83     {
  84         self.origin_x = ReadCoord();
  85         self.origin_y = ReadCoord();
  86         self.origin_z = ReadCoord();
  87         setorigin(self, self.origin);
  88         self.oldorigin = self.origin;
  89     }
  90
  91     if(sf & ISF_ANGLES)
  92     {
  93         self.angles_x = ReadCoord();
  94         self.angles_y = ReadCoord();
  95         self.angles_z = ReadCoord();
  96         self.move_angles = self.angles;
  97     }
  98
  99     if(sf & ISF_SIZE)
 100     {
 101         self.mins_x = ReadCoord();
 102         self.mins_y = ReadCoord();
 103         self.mins_z = ReadCoord();
 104         self.maxs_x = ReadCoord();
 105         self.maxs_y = ReadCoord();
 106         self.maxs_z = ReadCoord();
 107         setsize(self, self.mins, self.maxs);
 108     }
 109
 110     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 111     {
 112         self.ItemStatus = ReadByte();
 113
 114         if(self.ItemStatus & ITS_AVAILABLE)
 115         {
 116             self.alpha = 1;
 117             self.colormod = self.glowmod = '1 1 1';
 118         }
 119         else
 120         {
 121             if (autocvar_cl_ghost_items_color)
 122             {
 123                 self.alpha = autocvar_cl_ghost_items;
 124                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 125             }
 126             else
 127                 self.alpha = -1;
 128         }
 129
 130         if(autocvar_cl_fullbright_items)
 131             if(self.ItemStatus & ITS_ALLOWFB)
 132                 self.effects |= EF_FULLBRIGHT;
 133
 134         if(self.ItemStatus & ITS_STAYWEP)
 135         {
 136             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 137             self.alpha = autocvar_cl_weapon_stay_alpha;
 138
 139         }
 140
 141         if(self.ItemStatus & ITS_POWERUP)
 142         {
 143             if(self.ItemStatus & ITS_AVAILABLE)
 144                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 145             else
 146                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 147         }
 148     }
 149
 150     if(sf & ISF_MODEL)
 151     {
 152         self.drawmask  = MASK_NORMAL;
 153         self.movetype  = MOVETYPE_TOSS;
 154         self.draw       = ItemDraw;
 155
 156         if(self.mdl)
 157             strunzone(self.mdl);
 158
 159         self.mdl = "";
 160         string _fn = ReadString();
 161
 162         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 163         {
 164             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 165             self.draw = ItemDrawSimple;
 166
 167
 168
 169             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 170                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 171             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 177             else
 178             {
 179                 self.draw = ItemDraw;
 180                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 181             }
 182         }
 183
 184         if(self.draw != ItemDrawSimple)
 185             self.mdl = strzone(_fn);
 186
 187
 188         if(self.mdl == "")
 189             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 190
 191         precache_model(self.mdl);
 192         setmodel(self, self.mdl);
 193     }
 194
 195     if(sf & ISF_COLORMAP)
 196         self.colormap = ReadShort();
 197
 198     if(sf & ISF_DROP)
 199     {
 200         self.gravity = 1;
 201         //self.move_angles = '0 0 0';
 202         self.move_movetype = MOVETYPE_TOSS;
 203         self.move_velocity_x = ReadCoord();
 204         self.move_velocity_y = ReadCoord();
 205         self.move_velocity_z = ReadCoord();
 206         self.velocity = self.move_velocity;
 207         self.move_origin = self.oldorigin;
 208
 209         if(!self.move_time)
 210         {
 211             self.move_time = time;
 212             self.spawntime = time;
 213         }
 214         else
 215             self.move_time = max(self.move_time, time);
 216     }
 217
 218     if(autocvar_cl_animate_items)
 219     {
 220         if(self.ItemStatus & ITS_ANIMATE1)
 221             self.move_avelocity = '0 180 0';
 222
 223         if(self.ItemStatus & ITS_ANIMATE2)
 224             self.move_avelocity = '0 -90 0';
 225     }
 226 }
 227
 228 #endif
 229
 230 #ifdef SVQC
 231 bool ItemSend(entity to, int sf)
 232 {
 233     if(self.gravity)
 234         sf |= ISF_DROP;
 235     else
 236         sf &= ~ISF_DROP;
 237
 238         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 239         WriteByte(MSG_ENTITY, sf);
 240
 241         //WriteByte(MSG_ENTITY, self.cnt);
 242     if(sf & ISF_LOCATION)
 243     {
 244         WriteCoord(MSG_ENTITY, self.origin.x);
 245         WriteCoord(MSG_ENTITY, self.origin.y);
 246         WriteCoord(MSG_ENTITY, self.origin.z);
 247     }
 248
 249     if(sf & ISF_ANGLES)
 250     {
 251         WriteCoord(MSG_ENTITY, self.angles.x);
 252         WriteCoord(MSG_ENTITY, self.angles.y);
 253         WriteCoord(MSG_ENTITY, self.angles.z);
 254     }
 255
 256     if(sf & ISF_SIZE)
 257     {
 258         WriteCoord(MSG_ENTITY, self.mins.x);
 259         WriteCoord(MSG_ENTITY, self.mins.y);
 260         WriteCoord(MSG_ENTITY, self.mins.z);
 261         WriteCoord(MSG_ENTITY, self.maxs.x);
 262         WriteCoord(MSG_ENTITY, self.maxs.y);
 263         WriteCoord(MSG_ENTITY, self.maxs.z);
 264     }
 265
 266     if(sf & ISF_STATUS)
 267         WriteByte(MSG_ENTITY, self.ItemStatus);
 268
 269     if(sf & ISF_MODEL)
 270     {
 271
 272         if(self.mdl == "")
 273             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 274
 275         WriteString(MSG_ENTITY, self.mdl);
 276     }
 277
 278
 279     if(sf & ISF_COLORMAP)
 280         WriteShort(MSG_ENTITY, self.colormap);
 281
 282     if(sf & ISF_DROP)
 283     {
 284         WriteCoord(MSG_ENTITY, self.velocity.x);
 285         WriteCoord(MSG_ENTITY, self.velocity.y);
 286         WriteCoord(MSG_ENTITY, self.velocity.z);
 287     }
 288
 289     return true;
 290 }
 291
 292 void ItemUpdate(entity item)
 293 {
 294         item.SendFlags |= ISF_LOCATION;
 295 }
 296
 297 float have_pickup_item(void)
 298 {
 299         if(self.flags & FL_POWERUP)
 300         {
 301                 if(autocvar_g_powerups > 0)
 302                         return true;
 303                 if(autocvar_g_powerups == 0)
 304                         return false;
 305         }
 306         else
 307         {
 308                 if(autocvar_g_pickup_items > 0)
 309                         return true;
 310                 if(autocvar_g_pickup_items == 0)
 311                         return false;
 312                 if(g_weaponarena)
 313                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 314                                 return false;
 315         }
 316         return true;
 317 }
 318
 319 /*
 320 float Item_Customize()
 321 {
 322         if(self.spawnshieldtime)
 323                 return true;
 324         if(self.weapons & ~other.weapons)
 325         {
 326                 self.colormod = '0 0 0';
 327                 self.glowmod = self.colormod;
 328                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 329                 return true;
 330         }
 331         else
 332         {
 333                 if(g_ghost_items)
 334                 {
 335                         self.colormod = stov(autocvar_g_ghost_items_color);
 336                         self.glowmod = self.colormod;
 337                         self.alpha = g_ghost_items;
 338                         return true;
 339                 }
 340                 else
 341                         return false;
 342         }
 343 }
 344 */
 345
 346 void Item_Show (entity e, float mode)
 347 {
 348         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 349         e.ItemStatus &= ~ITS_STAYWEP;
 350         if (mode > 0)
 351         {
 352                 // make the item look normal, and be touchable
 353                 e.model = e.mdl;
 354                 e.solid = SOLID_TRIGGER;
 355                 e.spawnshieldtime = 1;
 356                 e.ItemStatus |= ITS_AVAILABLE;
 357         }
 358         else if (mode < 0)
 359         {
 360                 // hide the item completely
 361                 e.model = string_null;
 362                 e.solid = SOLID_NOT;
 363                 e.spawnshieldtime = 1;
 364                 e.ItemStatus &= ~ITS_AVAILABLE;
 365         }
 366         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 367         {
 368                 // make the item translucent and not touchable
 369                 e.model = e.mdl;
 370                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 371                 e.effects |= EF_STARDUST;
 372                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 373                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 374         }
 375         else
 376         {
 377                 //setmodel(e, "null");
 378                 e.solid = SOLID_NOT;
 379                 e.colormod = '0 0 0';
 380                 e.glowmod = e.colormod;
 381                 e.spawnshieldtime = 1;
 382                 e.ItemStatus &= ~ITS_AVAILABLE;
 383         }
 384
 385         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 386             e.ItemStatus |= ITS_POWERUP;
 387
 388         if (autocvar_g_nodepthtestitems)
 389                 e.effects |= EF_NODEPTHTEST;
 390
 391
 392     if (autocvar_g_fullbrightitems)
 393                 e.ItemStatus |= ITS_ALLOWFB;
 394
 395         if (autocvar_sv_simple_items)
 396         e.ItemStatus |= ITS_ALLOWSI;
 397
 398         // relink entity (because solid may have changed)
 399         setorigin(e, e.origin);
 400     e.SendFlags |= ISF_STATUS;
 401 }
 402
 403 void Item_Think()
 404 {
 405         self.nextthink = time;
 406         if(self.origin != self.oldorigin)
 407         {
 408                 self.oldorigin = self.origin;
 409                 ItemUpdate(self);
 410         }
 411 }
 412
 413 bool Item_ItemsTime_Allow(entity e);
 414 float Item_ItemsTime_UpdateTime(entity e, float t);
 415 void Item_ItemsTime_SetTime(entity e, float t);
 416 void Item_ItemsTime_SetTimesForAllPlayers();
 417
 418 void Item_Respawn (void)
 419 {
 420         Item_Show(self, 1);
 421         // this is ugly...
 422         if(self.items == ITEM_Strength.m_itemid)
 423                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 424         else if(self.items == ITEM_Shield.m_itemid)
 425                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 426         else
 427                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 428         setorigin (self, self.origin);
 429
 430     if (Item_ItemsTime_Allow(self))
 431         {
 432                 float t = Item_ItemsTime_UpdateTime(self, 0);
 433                 Item_ItemsTime_SetTime(self, t);
 434                 Item_ItemsTime_SetTimesForAllPlayers();
 435         }
 436
 437         self.think = Item_Think;
 438         self.nextthink = time;
 439
 440         //Send_Effect("item_respawn", self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 441         Send_Effect("item_respawn", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 442 }
 443
 444 void Item_RespawnCountdown (void)
 445 {
 446         if(self.count >= ITEM_RESPAWN_TICKS)
 447         {
 448                 if(self.waypointsprite_attached)
 449                         WaypointSprite_Kill(self.waypointsprite_attached);
 450                 Item_Respawn();
 451         }
 452         else
 453         {
 454                 self.nextthink = time + 1;
 455                 self.count += 1;
 456                 if(self.count == 1)
 457                 {
 458                         string name = string_null;
 459                         vector rgb = '1 0 1';
 460             entity e = self.itemdef;
 461             if (e) {
 462                 name = e.m_waypoint;
 463                 rgb = e.m_color;
 464             }
 465                         MUTATOR_CALLHOOK(Item_RespawnCountdown, name, rgb);
 466                         name = item_name;
 467                         rgb = item_color;
 468                         if(self.flags & FL_WEAPON)
 469                         {
 470                                 entity wi = get_weaponinfo(self.weapon);
 471                                 if(wi)
 472                                 {
 473                                         name = wi.wpmodel;
 474                                         rgb = '1 0 0';
 475                                 }
 476                         }
 477                         if(name)
 478                         {
 479                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 480                                 if(self.waypointsprite_attached)
 481                                 {
 482                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 483                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 484                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 485                                 }
 486                         }
 487                         else
 488                         {
 489                                 print("Unknown powerup-marked item is wanting to respawn\n");
 490                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 491                         }
 492                 }
 493
 494                 if(self.waypointsprite_attached)
 495                 {
 496                         entity e;
 497                         entity it = self;
 498                         self = self.waypointsprite_attached;
 499                         FOR_EACH_REALCLIENT(e)
 500                                 if(self.waypointsprite_visible_for_player(e))
 501                                 {
 502                                         msg_entity = e;
 503                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 504                                 }
 505                         self = it;
 506
 507                         WaypointSprite_Ping(self.waypointsprite_attached);
 508                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 509                 }
 510                 else
 511                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 512         }
 513 }
 514
 515 void Item_RespawnThink()
 516 {
 517         self.nextthink = time;
 518         if(self.origin != self.oldorigin)
 519         {
 520                 self.oldorigin = self.origin;
 521                 ItemUpdate(self);
 522         }
 523
 524         if(time >= self.wait)
 525                 Item_Respawn();
 526 }
 527
 528 void Item_ScheduleRespawnIn(entity e, float t)
 529 {
 530         if (Item_ItemsTime_Allow(e))
 531         {
 532                 e.think = Item_RespawnCountdown;
 533                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 534                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 535                 e.count = 0;
 536                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 537                 Item_ItemsTime_SetTime(e, t);
 538                 Item_ItemsTime_SetTimesForAllPlayers();
 539         }
 540         else
 541         {
 542                 e.think = Item_RespawnThink;
 543                 e.nextthink = time;
 544                 e.scheduledrespawntime = time + t;
 545                 e.wait = time + t;
 546         }
 547 }
 548
 549 void Item_ScheduleRespawn(entity e)
 550 {
 551         if(e.respawntime > 0)
 552         {
 553                 Item_Show(e, 0);
 554                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 555         }
 556         else // if respawntime is -1, this item does not respawn
 557                 Item_Show(e, -1);
 558 }
 559
 560 void Item_ScheduleInitialRespawn(entity e)
 561 {
 562         Item_Show(e, 0);
 563         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 564 }
 565
 566 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 567 {
 568         if (!item.(ammotype))
 569                 return false;
 570
 571         if (item.spawnshieldtime)
 572         {
 573                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 574                 {
 575                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 576                         goto YEAH;
 577                 }
 578         }
 579         else if(g_weapon_stay == 2)
 580         {
 581                 float mi = min(item.(ammotype), ammomax);
 582                 if (player.(ammotype) < mi)
 583                 {
 584                         player.(ammotype) = mi;
 585                         goto YEAH;
 586                 }
 587         }
 588
 589         return false;
 590
 591 :YEAH
 592         switch(mode)
 593         {
 594                 case ITEM_MODE_FUEL:
 595                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 596                         break;
 597                 case ITEM_MODE_HEALTH:
 598                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 599                         break;
 600                 case ITEM_MODE_ARMOR:
 601                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 602                         break;
 603                 default:
 604                         break;
 605         }
 606         return true;
 607 }
 608
 609 float Item_GiveTo(entity item, entity player)
 610 {
 611         float _switchweapon;
 612         float pickedup;
 613         float it;
 614         float i;
 615
 616         // if nothing happens to player, just return without taking the item
 617         pickedup = false;
 618         _switchweapon = false;
 619         // in case the player has autoswitch enabled do the following:
 620         // if the player is using their best weapon before items are given, they
 621         // probably want to switch to an even better weapon after items are given
 622         if (player.autoswitch)
 623         if (player.switchweapon == w_getbestweapon(player))
 624                 _switchweapon = true;
 625
 626         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 627                 _switchweapon = true;
 628
 629         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 630         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 631         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 632         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 633         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 634         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 635         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 636         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 637
 638         if (item.flags & FL_WEAPON)
 639         {
 640                 WepSet it;
 641                 it = item.weapons;
 642                 it &= ~player.weapons;
 643
 644                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 645                 {
 646                         pickedup = true;
 647                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 648                         if(it & WepSet_FromWeapon(i))
 649                         {
 650                                 W_DropEvent(WR_PICKUP, player, i, item);
 651                                 W_GiveWeapon(player, i);
 652                         }
 653                 }
 654         }
 655
 656         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 657         {
 658                 pickedup = true;
 659                 player.items |= it;
 660                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 661         }
 662
 663         if (item.strength_finished)
 664         {
 665                 pickedup = true;
 666                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 667         }
 668         if (item.invincible_finished)
 669         {
 670                 pickedup = true;
 671                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 672         }
 673         if (item.superweapons_finished)
 674         {
 675                 pickedup = true;
 676                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 677         }
 678
 679 :skip
 680
 681         // always eat teamed entities
 682         if(item.team)
 683                 pickedup = true;
 684
 685         if (!pickedup)
 686                 return 0;
 687
 688         if (_switchweapon)
 689                 if (player.switchweapon != w_getbestweapon(player))
 690                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 691
 692         return 1;
 693 }
 694
 695 void Item_Touch (void)
 696 {
 697         entity e, head;
 698
 699         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 700         if(self.classname == "droppedweapon")
 701         {
 702                 if (ITEM_TOUCH_NEEDKILL())
 703                 {
 704                         remove(self);
 705                         return;
 706                 }
 707         }
 708
 709         if (!IS_PLAYER(other))
 710                 return;
 711         if (other.frozen)
 712                 return;
 713         if (other.deadflag)
 714                 return;
 715         if (self.solid != SOLID_TRIGGER)
 716                 return;
 717         if (self.owner == other)
 718                 return;
 719         if (time < self.item_spawnshieldtime)
 720                 return;
 721
 722         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 723         {
 724                 case MUT_ITEMTOUCH_RETURN: { return; }
 725                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 726         }
 727
 728         if (self.classname == "droppedweapon")
 729         {
 730                 self.strength_finished = max(0, self.strength_finished - time);
 731                 self.invincible_finished = max(0, self.invincible_finished - time);
 732                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 733         }
 734         entity it = self.itemdef;
 735         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 736         if (!gave)
 737         {
 738                 if (self.classname == "droppedweapon")
 739                 {
 740                         // undo what we did above
 741                         self.strength_finished += time;
 742                         self.invincible_finished += time;
 743                         self.superweapons_finished += time;
 744                 }
 745                 return;
 746         }
 747
 748         :pickup
 749
 750         other.last_pickup = time;
 751
 752         Send_Effect("item_pickup", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 753         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 754
 755         if (self.classname == "droppedweapon")
 756                 remove (self);
 757         else if (self.spawnshieldtime)
 758         {
 759                 if(self.team)
 760                 {
 761                         RandomSelection_Init();
 762                         for(head = world; (head = findfloat(head, team, self.team)); )
 763                         {
 764                                 if(head.flags & FL_ITEM)
 765                                 {
 766                                         Item_Show(head, -1);
 767                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 768                                 }
 769                         }
 770                         e = RandomSelection_chosen_ent;
 771
 772                 }
 773                 else
 774                         e = self;
 775                 Item_ScheduleRespawn(e);
 776         }
 777 }
 778
 779 void Item_Reset()
 780 {
 781         Item_Show(self, !self.state);
 782         setorigin (self, self.origin);
 783
 784         if(self.classname != "droppedweapon")
 785         {
 786                 self.think = Item_Think;
 787                 self.nextthink = time;
 788
 789                 if(self.waypointsprite_attached)
 790                         WaypointSprite_Kill(self.waypointsprite_attached);
 791
 792                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 793                         Item_ScheduleInitialRespawn(self);
 794         }
 795 }
 796
 797 void Item_FindTeam()
 798 {
 799         entity head, e;
 800
 801         if(self.effects & EF_NODRAW)
 802         {
 803                 // marker for item team search
 804                 dprint("Initializing item team ", ftos(self.team), "\n");
 805                 RandomSelection_Init();
 806                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 807                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 808                 e = RandomSelection_chosen_ent;
 809                 e.state = 0;
 810                 Item_Show(e, 1);
 811
 812                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 813                 {
 814                         if(head != e)
 815                         {
 816                                 // make it a non-spawned item
 817                                 Item_Show(head, -1);
 818                                 head.state = 1; // state 1 = initially hidden item
 819                         }
 820                         head.effects &= ~EF_NODRAW;
 821                 }
 822
 823                 Item_Reset();
 824         }
 825 }
 826
 827 // Savage: used for item garbage-collection
 828 // TODO: perhaps nice special effect?
 829 void RemoveItem(void)
 830 {
 831         Send_Effect("item_pickup", CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 832         remove(self);
 833 }
 834
 835 // pickup evaluation functions
 836 // these functions decide how desirable an item is to the bots
 837
 838 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 839
 840 float weapon_pickupevalfunc(entity player, entity item)
 841 {
 842         float c;
 843
 844         // See if I have it already
 845         if(item.weapons & ~player.weapons)
 846         {
 847                 // If I can pick it up
 848                 if(!item.spawnshieldtime)
 849                         c = 0;
 850                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 851                 {
 852                         // Skilled bots will grab more
 853                         c = bound(0, skill / 10, 1) * 0.5;
 854                 }
 855                 else
 856                         c = 0;
 857         }
 858         else
 859                 c = 1;
 860
 861         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 862         if( bot_custom_weapon && c )
 863         {
 864                 // Find the highest position on any range
 865                 int position = -1;
 866                 for (int j = 0; j < WEP_LAST ; ++j){
 867                         if(
 868                                         bot_weapons_far[j] == item.weapon ||
 869                                         bot_weapons_mid[j] == item.weapon ||
 870                                         bot_weapons_close[j] == item.weapon
 871                           )
 872                         {
 873                                 position = j;
 874                                 break;
 875                         }
 876                 }
 877
 878                 // Rate it
 879                 if (position >= 0 )
 880                 {
 881                         position = WEP_LAST - position;
 882                         // item.bot_pickupbasevalue is overwritten here
 883                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 884                 }
 885         }
 886
 887         return item.bot_pickupbasevalue * c;
 888 }
 889
 890 float commodity_pickupevalfunc(entity player, entity item)
 891 {
 892         float c, i;
 893         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 894         entity wi;
 895         c = 0;
 896
 897         // Detect needed ammo
 898         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 899         {
 900                 wi = get_weaponinfo(i);
 901
 902                 if (!(player.weapons & WepSet_FromWeapon(i)))
 903                         continue;
 904
 905                 if(wi.items & ITEM_Shells.m_itemid)
 906                         need_shells = true;
 907                 else if(wi.items & ITEM_Bullets.m_itemid)
 908                         need_nails = true;
 909                 else if(wi.items & ITEM_Rockets.m_itemid)
 910                         need_rockets = true;
 911                 else if(wi.items & ITEM_Cells.m_itemid)
 912                         need_cells = true;
 913                 else if(wi.items & ITEM_Plasma.m_itemid)
 914                         need_plasma = true;
 915                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 916                         need_fuel = true;
 917         }
 918
 919         // TODO: figure out if the player even has the weapon this ammo is for?
 920         // may not affect strategy much though...
 921         // find out how much more ammo/armor/health the player can hold
 922         if (need_shells)
 923         if (item.ammo_shells)
 924         if (player.ammo_shells < g_pickup_shells_max)
 925                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 926         if (need_nails)
 927         if (item.ammo_nails)
 928         if (player.ammo_nails < g_pickup_nails_max)
 929                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 930         if (need_rockets)
 931         if (item.ammo_rockets)
 932         if (player.ammo_rockets < g_pickup_rockets_max)
 933                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 934         if (need_cells)
 935         if (item.ammo_cells)
 936         if (player.ammo_cells < g_pickup_cells_max)
 937                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 938         if (need_plasma)
 939         if (item.ammo_plasma)
 940         if (player.ammo_plasma < g_pickup_plasma_max)
 941                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 942         if (need_fuel)
 943         if (item.ammo_fuel)
 944         if (player.ammo_fuel < g_pickup_fuel_max)
 945                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 946         if (item.armorvalue)
 947         if (player.armorvalue < item.max_armorvalue)
 948                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 949         if (item.health)
 950         if (player.health < item.max_health)
 951                 c = c + max(0, 1 - player.health / item.max_health);
 952
 953         return item.bot_pickupbasevalue * c;
 954 }
 955
 956 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 957 {
 958         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 959                 RemoveItem();
 960 }
 961
 962 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 963 {
 964         startitem_failed = false;
 965
 966         if(self.model == "")
 967                 self.model = itemmodel;
 968
 969         if(self.model == "")
 970     {
 971         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 972         return;
 973     }
 974
 975         if(self.item_pickupsound == "")
 976                 self.item_pickupsound = pickupsound;
 977
 978         if(!self.respawntime) // both need to be set
 979         {
 980                 self.respawntime = defaultrespawntime;
 981                 self.respawntimejitter = defaultrespawntimejitter;
 982         }
 983
 984         self.items = itemid;
 985         self.weapon = weaponid;
 986
 987         if(weaponid)
 988                 self.weapons = WepSet_FromWeapon(weaponid);
 989
 990         self.flags = FL_ITEM | itemflags;
 991
 992         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 993         {
 994                 startitem_failed = true;
 995                 remove(self);
 996                 return;
 997         }
 998
 999         // is it a dropped weapon?
1000         if (self.classname == "droppedweapon")
1001         {
1002                 self.reset = SUB_Remove;
1003                 // it's a dropped weapon
1004                 self.movetype = MOVETYPE_TOSS;
1005
1006                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1007                 self.think = RemoveItem;
1008                 self.nextthink = time + 20;
1009
1010                 self.takedamage = DAMAGE_YES;
1011                 self.event_damage = Item_Damage;
1012
1013                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1014                 /*
1015                 if(self.items == 0)
1016                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1017                 if(self.ammo_nails == 0)
1018                 if(self.ammo_cells == 0)
1019                 if(self.ammo_rockets == 0)
1020                 if(self.ammo_shells == 0)
1021                 if(self.ammo_fuel == 0)
1022                 if(self.health == 0)
1023                 if(self.armorvalue == 0)
1024                 */
1025                 {
1026                         // if item is worthless after a timer, have it expire then
1027                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1028                 }
1029
1030                 // don't drop if in a NODROP zone (such as lava)
1031                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1032                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1033                 {
1034                         startitem_failed = true;
1035                         remove(self);
1036                         return;
1037                 }
1038         }
1039         else
1040         {
1041                 if(!have_pickup_item())
1042                 {
1043                         startitem_failed = true;
1044                         remove (self);
1045                         return;
1046                 }
1047
1048                 self.reset = Item_Reset;
1049                 // it's a level item
1050                 if(self.spawnflags & 1)
1051                         self.noalign = 1;
1052                 if (self.noalign)
1053                         self.movetype = MOVETYPE_NONE;
1054                 else
1055                         self.movetype = MOVETYPE_TOSS;
1056                 // do item filtering according to game mode and other things
1057                 if (!self.noalign)
1058                 {
1059                         // first nudge it off the floor a little bit to avoid math errors
1060                         setorigin(self, self.origin + '0 0 1');
1061                         // set item size before we spawn a spawnfunc_waypoint
1062                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1063                                 setsize (self, '-16 -16 0', '16 16 48');
1064                         else
1065                                 setsize (self, '-16 -16 0', '16 16 32');
1066
1067                         // note droptofloor returns false if stuck/or would fall too far
1068                         droptofloor();
1069                         waypoint_spawnforitem(self);
1070                 }
1071
1072                 /*
1073                  * can't do it that way, as it would break maps
1074                  * TODO make a target_give like entity another way, that perhaps has
1075                  * the weapon name in a key
1076                 if(self.targetname)
1077                 {
1078                         // target_give not yet supported; maybe later
1079                         print("removed targeted ", self.classname, "\n");
1080                         startitem_failed = true;
1081                         remove (self);
1082                         return;
1083                 }
1084                 */
1085
1086                 if(autocvar_spawn_debug >= 2)
1087                 {
1088                         entity otheritem;
1089                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1090                         {
1091                             // why not flags & fl_item?
1092                                 if(otheritem.is_item)
1093                                 {
1094                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1095                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1096                                         error("Mapper sucks.");
1097                                 }
1098                         }
1099                         self.is_item = true;
1100                 }
1101
1102                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1103
1104                 precache_model (self.model);
1105                 precache_sound (self.item_pickupsound);
1106
1107                 precache_sound ("misc/itemrespawncountdown.wav");
1108                 if(itemid == ITEM_Strength.m_itemid)
1109                         precache_sound ("misc/strength_respawn.wav");
1110                 else if(itemid == ITEM_Shield.m_itemid)
1111                         precache_sound ("misc/shield_respawn.wav");
1112                 else
1113                         precache_sound ("misc/itemrespawn.wav");
1114
1115                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1116                         self.target = "###item###"; // for finding the nearest item using find()
1117
1118                 Item_ItemsTime_SetTime(self, 0);
1119         }
1120
1121         self.bot_pickup = true;
1122         self.bot_pickupevalfunc = pickupevalfunc;
1123         self.bot_pickupbasevalue = pickupbasevalue;
1124         self.mdl = self.model;
1125         self.netname = itemname;
1126         self.touch = Item_Touch;
1127         setmodel(self, "null"); // precision set below
1128         //self.effects |= EF_LOWPRECISION;
1129
1130         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1131     {
1132         self.pos1 = '-16 -16 0';
1133         self.pos2 = '16 16 48';
1134     }
1135         else
1136     {
1137         self.pos1 = '-16 -16 0';
1138         self.pos2 = '16 16 32';
1139     }
1140     setsize (self, self.pos1, self.pos2);
1141
1142     if(itemflags & FL_POWERUP)
1143         self.ItemStatus |= ITS_ANIMATE1;
1144
1145         if(self.armorvalue || self.health)
1146         self.ItemStatus |= ITS_ANIMATE2;
1147
1148         if(itemflags & FL_WEAPON)
1149         {
1150                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1151             self.colormap = 1024; // color shirt=0 pants=0 grey
1152         else
1153             self.gravity = 1;
1154
1155                 self.ItemStatus |= ITS_ANIMATE1;
1156                 self.ItemStatus |= ISF_COLORMAP;
1157         }
1158
1159         self.state = 0;
1160         if(self.team) // broken, no idea why.
1161         {
1162                 if(!self.cnt)
1163                         self.cnt = 1; // item probability weight
1164
1165                 self.effects |= EF_NODRAW; // marker for item team search
1166                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1167         }
1168         else
1169                 Item_Reset();
1170
1171     Net_LinkEntity(self, false, 0, ItemSend);
1172
1173         self.SendFlags |= ISF_SIZE;
1174         if(self.angles)
1175                 self.SendFlags |= ISF_ANGLES;
1176
1177         // call this hook after everything else has been done
1178         if(MUTATOR_CALLHOOK(Item_Spawn, self))
1179         {
1180                 startitem_failed = true;
1181                 remove(self);
1182                 return;
1183         }
1184 }
1185
1186 void StartItemA (entity a)
1187 {
1188     self.itemdef = a;
1189     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1190 }
1191
1192 void spawnfunc_item_rockets (void) {
1193         if(!self.ammo_rockets)
1194                 self.ammo_rockets = g_pickup_rockets;
1195         if(!self.pickup_anyway)
1196                 self.pickup_anyway = g_pickup_ammo_anyway;
1197     StartItemA (ITEM_Rockets);
1198 }
1199
1200 void spawnfunc_item_bullets (void) {
1201         if(!weaponswapping)
1202         if(autocvar_sv_q3acompat_machineshotgunswap)
1203         if(self.classname != "droppedweapon")
1204         {
1205                 weaponswapping = true;
1206                 spawnfunc_item_shells();
1207                 weaponswapping = false;
1208                 return;
1209         }
1210
1211         if(!self.ammo_nails)
1212                 self.ammo_nails = g_pickup_nails;
1213         if(!self.pickup_anyway)
1214                 self.pickup_anyway = g_pickup_ammo_anyway;
1215     StartItemA (ITEM_Bullets);
1216 }
1217
1218 void spawnfunc_item_cells (void) {
1219         if(!self.ammo_cells)
1220                 self.ammo_cells = g_pickup_cells;
1221         if(!self.pickup_anyway)
1222                 self.pickup_anyway = g_pickup_ammo_anyway;
1223         StartItemA (ITEM_Cells);
1224 }
1225
1226 void spawnfunc_item_plasma()
1227 {
1228         if(!self.ammo_plasma)
1229                 self.ammo_plasma = g_pickup_plasma;
1230         if(!self.pickup_anyway)
1231                 self.pickup_anyway = g_pickup_ammo_anyway;
1232         StartItemA (ITEM_Plasma);
1233 }
1234
1235 void spawnfunc_item_shells (void) {
1236         if(!weaponswapping)
1237         if(autocvar_sv_q3acompat_machineshotgunswap)
1238         if(self.classname != "droppedweapon")
1239         {
1240                 weaponswapping = true;
1241                 spawnfunc_item_bullets();
1242                 weaponswapping = false;
1243                 return;
1244         }
1245
1246         if(!self.ammo_shells)
1247                 self.ammo_shells = g_pickup_shells;
1248         if(!self.pickup_anyway)
1249                 self.pickup_anyway = g_pickup_ammo_anyway;
1250         StartItemA (ITEM_Shells);
1251 }
1252
1253 void spawnfunc_item_armor_small (void) {
1254         if(!self.armorvalue)
1255                 self.armorvalue = g_pickup_armorsmall;
1256         if(!self.max_armorvalue)
1257                 self.max_armorvalue = g_pickup_armorsmall_max;
1258         if(!self.pickup_anyway)
1259                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1260         StartItemA (ITEM_ArmorSmall);
1261 }
1262
1263 void spawnfunc_item_armor_medium (void) {
1264         if(!self.armorvalue)
1265                 self.armorvalue = g_pickup_armormedium;
1266         if(!self.max_armorvalue)
1267                 self.max_armorvalue = g_pickup_armormedium_max;
1268         if(!self.pickup_anyway)
1269                 self.pickup_anyway = g_pickup_armormedium_anyway;
1270         StartItemA (ITEM_ArmorMedium);
1271 }
1272
1273 void spawnfunc_item_armor_big (void) {
1274         if(!self.armorvalue)
1275                 self.armorvalue = g_pickup_armorbig;
1276         if(!self.max_armorvalue)
1277                 self.max_armorvalue = g_pickup_armorbig_max;
1278         if(!self.pickup_anyway)
1279                 self.pickup_anyway = g_pickup_armorbig_anyway;
1280         StartItemA (ITEM_ArmorLarge);
1281 }
1282
1283 void spawnfunc_item_armor_large (void) {
1284         if(!self.armorvalue)
1285                 self.armorvalue = g_pickup_armorlarge;
1286         if(!self.max_armorvalue)
1287                 self.max_armorvalue = g_pickup_armorlarge_max;
1288         if(!self.pickup_anyway)
1289                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1290         StartItemA (ITEM_ArmorMega);
1291 }
1292
1293 void spawnfunc_item_health_small (void) {
1294         if(!self.max_health)
1295                 self.max_health = g_pickup_healthsmall_max;
1296         if(!self.health)
1297                 self.health = g_pickup_healthsmall;
1298         if(!self.pickup_anyway)
1299                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1300         StartItemA (ITEM_HealthSmall);
1301 }
1302
1303 void spawnfunc_item_health_medium (void) {
1304         if(!self.max_health)
1305                 self.max_health = g_pickup_healthmedium_max;
1306         if(!self.health)
1307                 self.health = g_pickup_healthmedium;
1308         if(!self.pickup_anyway)
1309                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1310     StartItemA (ITEM_HealthMedium);
1311 }
1312
1313 void spawnfunc_item_health_large (void) {
1314         if(!self.max_health)
1315                 self.max_health = g_pickup_healthlarge_max;
1316         if(!self.health)
1317                 self.health = g_pickup_healthlarge;
1318         if(!self.pickup_anyway)
1319                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1320         StartItemA (ITEM_HealthLarge);
1321 }
1322
1323 void spawnfunc_item_health_mega (void) {
1324     if(!self.max_health)
1325         self.max_health = g_pickup_healthmega_max;
1326     if(!self.health)
1327         self.health = g_pickup_healthmega;
1328     if(!self.pickup_anyway)
1329         self.pickup_anyway = g_pickup_healthmega_anyway;
1330     StartItemA (ITEM_HealthMega);
1331 }
1332
1333 // support old misnamed entities
1334 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1335 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1336 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1337 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1338 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1339
1340 void spawnfunc_item_strength (void) {
1341                 precache_sound("weapons/strength_fire.wav");
1342                 if(!self.strength_finished)
1343                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1344                 StartItemA (ITEM_Strength);
1345 }
1346
1347 void spawnfunc_item_invincible (void) {
1348                 if(!self.invincible_finished)
1349                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1350                 StartItemA (ITEM_Shield);
1351 }
1352
1353 // compatibility:
1354 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1355
1356 void target_items_use (void)
1357 {
1358         if(activator.classname == "droppedweapon")
1359         {
1360                 EXACTTRIGGER_TOUCH;
1361                 remove(activator);
1362                 return;
1363         }
1364
1365         if (!IS_PLAYER(activator))
1366                 return;
1367         if(activator.deadflag != DEAD_NO)
1368                 return;
1369         EXACTTRIGGER_TOUCH;
1370
1371         entity e;
1372         for(e = world; (e = find(e, classname, "droppedweapon")); )
1373                 if(e.enemy == activator)
1374                         remove(e);
1375
1376         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1377                 centerprint(activator, self.message);
1378 }
1379
1380 void spawnfunc_target_items (void)
1381 {
1382         float n, i, j;
1383         entity e;
1384         string s;
1385
1386         self.use = target_items_use;
1387         if(!self.strength_finished)
1388                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1389         if(!self.invincible_finished)
1390                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1391         if(!self.superweapons_finished)
1392                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1393
1394         precache_sound("misc/itempickup.wav");
1395         precache_sound("misc/megahealth.wav");
1396         precache_sound("misc/armor25.wav");
1397         precache_sound("misc/powerup.wav");
1398         precache_sound("misc/poweroff.wav");
1399         precache_sound("weapons/weaponpickup.wav");
1400
1401         n = tokenize_console(self.netname);
1402         if(argv(0) == "give")
1403         {
1404                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1405         }
1406         else
1407         {
1408                 for(i = 0; i < n; ++i)
1409                 {
1410                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1411                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1412                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1413                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1414                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1415                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1416                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1417                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1418                         else
1419                         {
1420                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1421                                 {
1422                                         e = get_weaponinfo(j);
1423                                         s = W_UndeprecateName(argv(i));
1424                                         if(s == e.netname)
1425                                         {
1426                                                 self.weapons |= WepSet_FromWeapon(j);
1427                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1428                                                         WEP_ACTION(e.weapon, WR_INIT);
1429                                                 break;
1430                                         }
1431                                 }
1432                                 if(j > WEP_LAST)
1433                                         print("target_items: invalid item ", argv(i), "\n");
1434                         }
1435                 }
1436
1437                 string itemprefix, valueprefix;
1438                 if(self.spawnflags == 0)
1439                 {
1440                         itemprefix = "";
1441                         valueprefix = "";
1442                 }
1443                 else if(self.spawnflags == 1)
1444                 {
1445                         itemprefix = "max ";
1446                         valueprefix = "max ";
1447                 }
1448                 else if(self.spawnflags == 2)
1449                 {
1450                         itemprefix = "min ";
1451                         valueprefix = "min ";
1452                 }
1453                 else if(self.spawnflags == 4)
1454                 {
1455                         itemprefix = "minus ";
1456                         valueprefix = "max ";
1457                 }
1458                 else
1459                 {
1460                         error("invalid spawnflags");
1461                         itemprefix = valueprefix = string_null;
1462                 }
1463
1464                 self.netname = "";
1465                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1466                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1467                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1468                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1469                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1470                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1471                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1472                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1473                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1474                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1475                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1476                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1477                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1478                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1479                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1480                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1481                 {
1482                         e = get_weaponinfo(j);
1483                         if(e.weapon)
1484                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1485                 }
1486         }
1487         self.netname = strzone(self.netname);
1488         //print(self.netname, "\n");
1489
1490         n = tokenize_console(self.netname);
1491         for(i = 0; i < n; ++i)
1492         {
1493                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1494                 {
1495                         e = get_weaponinfo(j);
1496                         if(argv(i) == e.netname)
1497                         {
1498                                 WEP_ACTION(e.weapon, WR_INIT);
1499                                 break;
1500                         }
1501                 }
1502         }
1503 }
1504
1505 void spawnfunc_item_fuel(void)
1506 {
1507         if(!self.ammo_fuel)
1508                 self.ammo_fuel = g_pickup_fuel;
1509         if(!self.pickup_anyway)
1510                 self.pickup_anyway = g_pickup_ammo_anyway;
1511         StartItemA (ITEM_JetpackFuel);
1512 }
1513
1514 void spawnfunc_item_fuel_regen(void)
1515 {
1516         if(start_items & ITEM_JetpackRegen.m_itemid)
1517         {
1518                 spawnfunc_item_fuel();
1519                 return;
1520         }
1521         StartItemA (ITEM_JetpackRegen);
1522 }
1523
1524 void spawnfunc_item_jetpack(void)
1525 {
1526         if(!self.ammo_fuel)
1527                 self.ammo_fuel = g_pickup_fuel_jetpack;
1528         if(start_items & ITEM_Jetpack.m_itemid)
1529         {
1530                 spawnfunc_item_fuel();
1531                 return;
1532         }
1533         StartItemA (ITEM_Jetpack);
1534 }
1535
1536 float GiveWeapon(entity e, float wpn, float op, float val)
1537 {
1538         WepSet v0, v1;
1539         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1540         switch(op)
1541         {
1542                 case OP_SET:
1543                         if(val > 0)
1544                                 e.weapons |= WepSet_FromWeapon(wpn);
1545                         else
1546                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1547                         break;
1548                 case OP_MIN:
1549                 case OP_PLUS:
1550                         if(val > 0)
1551                                 e.weapons |= WepSet_FromWeapon(wpn);
1552                         break;
1553                 case OP_MAX:
1554                         if(val <= 0)
1555                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1556                         break;
1557                 case OP_MINUS:
1558                         if(val > 0)
1559                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1560                         break;
1561         }
1562         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1563         return (v0 != v1);
1564 }
1565
1566 float GiveBit(entity e, .float fld, float bit, float op, float val)
1567 {
1568         float v0, v1;
1569         v0 = (e.(fld) & bit);
1570         switch(op)
1571         {
1572                 case OP_SET:
1573                         if(val > 0)
1574                                 e.(fld) |= bit;
1575                         else
1576                                 e.(fld) &= ~bit;
1577                         break;
1578                 case OP_MIN:
1579                 case OP_PLUS:
1580                         if(val > 0)
1581                                 e.(fld) |= bit;
1582                         break;
1583                 case OP_MAX:
1584                         if(val <= 0)
1585                                 e.(fld) &= ~bit;
1586                         break;
1587                 case OP_MINUS:
1588                         if(val > 0)
1589                                 e.(fld) &= ~bit;
1590                         break;
1591         }
1592         v1 = (e.(fld) & bit);
1593         return (v0 != v1);
1594 }
1595
1596 float GiveValue(entity e, .float fld, float op, float val)
1597 {
1598         float v0, v1;
1599         v0 = e.(fld);
1600         switch(op)
1601         {
1602                 case OP_SET:
1603                         e.(fld) = val;
1604                         break;
1605                 case OP_MIN:
1606                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1607                         break;
1608                 case OP_MAX:
1609                         e.(fld) = min(e.(fld), val);
1610                         break;
1611                 case OP_PLUS:
1612                         e.(fld) += val;
1613                         break;
1614                 case OP_MINUS:
1615                         e.(fld) -= val;
1616                         break;
1617         }
1618         v1 = e.(fld);
1619         return (v0 != v1);
1620 }
1621
1622 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1623 {
1624         if(v1 == v0)
1625                 return;
1626         if(v1 <= v0 - t)
1627         {
1628                 if(snd_decr != "")
1629                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1630         }
1631         else if(v0 >= v0 + t)
1632         {
1633                 if(snd_incr != "")
1634                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1635         }
1636 }
1637
1638 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1639 {
1640         if(v0 < v1)
1641                 e.(rotfield) = max(e.(rotfield), time + rottime);
1642         else if(v0 > v1)
1643                 e.(regenfield) = max(e.(regenfield), time + regentime);
1644 }
1645 float GiveItems(entity e, float beginarg, float endarg)
1646 {
1647         float got, i, j, val, op;
1648         float _switchweapon;
1649         entity wi;
1650         string cmd;
1651
1652         val = 999;
1653         op = OP_SET;
1654
1655         got = 0;
1656
1657         _switchweapon = false;
1658         if (e.autoswitch)
1659                 if (e.switchweapon == w_getbestweapon(e))
1660                         _switchweapon = true;
1661
1662         e.strength_finished = max(0, e.strength_finished - time);
1663         e.invincible_finished = max(0, e.invincible_finished - time);
1664         e.superweapons_finished = max(0, e.superweapons_finished - time);
1665
1666         PREGIVE(e, items);
1667         PREGIVE_WEAPONS(e);
1668         PREGIVE(e, strength_finished);
1669         PREGIVE(e, invincible_finished);
1670         PREGIVE(e, superweapons_finished);
1671         PREGIVE(e, ammo_nails);
1672         PREGIVE(e, ammo_cells);
1673         PREGIVE(e, ammo_plasma);
1674         PREGIVE(e, ammo_shells);
1675         PREGIVE(e, ammo_rockets);
1676         PREGIVE(e, ammo_fuel);
1677         PREGIVE(e, armorvalue);
1678         PREGIVE(e, health);
1679
1680         for(i = beginarg; i < endarg; ++i)
1681         {
1682                 cmd = argv(i);
1683
1684                 if(cmd == "0" || stof(cmd))
1685                 {
1686                         val = stof(cmd);
1687                         continue;
1688                 }
1689                 switch(cmd)
1690                 {
1691                         case "no":
1692                                 op = OP_MAX;
1693                                 val = 0;
1694                                 continue;
1695                         case "max":
1696                                 op = OP_MAX;
1697                                 continue;
1698                         case "min":
1699                                 op = OP_MIN;
1700                                 continue;
1701                         case "plus":
1702                                 op = OP_PLUS;
1703                                 continue;
1704                         case "minus":
1705                                 op = OP_MINUS;
1706                                 continue;
1707                         case "ALL":
1708                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1709                                 got += GiveValue(e, strength_finished, op, val);
1710                                 got += GiveValue(e, invincible_finished, op, val);
1711                                 got += GiveValue(e, superweapons_finished, op, val);
1712                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1713                         case "all":
1714                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1715                                 got += GiveValue(e, health, op, val);
1716                                 got += GiveValue(e, armorvalue, op, val);
1717                         case "allweapons":
1718                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1719                                 {
1720                                         wi = get_weaponinfo(j);
1721                                         if(wi.weapon)
1722                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1723                                                         got += GiveWeapon(e, j, op, val);
1724                                 }
1725                         case "allammo":
1726                                 got += GiveValue(e, ammo_cells, op, val);
1727                                 got += GiveValue(e, ammo_plasma, op, val);
1728                                 got += GiveValue(e, ammo_shells, op, val);
1729                                 got += GiveValue(e, ammo_nails, op, val);
1730                                 got += GiveValue(e, ammo_rockets, op, val);
1731                                 got += GiveValue(e, ammo_fuel, op, val);
1732                                 break;
1733                         case "unlimited_ammo":
1734                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1735                                 break;
1736                         case "unlimited_weapon_ammo":
1737                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1738                                 break;
1739                         case "unlimited_superweapons":
1740                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1741                                 break;
1742                         case "jetpack":
1743                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1744                                 break;
1745                         case "fuel_regen":
1746                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1747                                 break;
1748                         case "strength":
1749                                 got += GiveValue(e, strength_finished, op, val);
1750                                 break;
1751                         case "invincible":
1752                                 got += GiveValue(e, invincible_finished, op, val);
1753                                 break;
1754                         case "superweapons":
1755                                 got += GiveValue(e, superweapons_finished, op, val);
1756                                 break;
1757                         case "cells":
1758                                 got += GiveValue(e, ammo_cells, op, val);
1759                                 break;
1760                         case "plasma":
1761                                 got += GiveValue(e, ammo_plasma, op, val);
1762                                 break;
1763                         case "shells":
1764                                 got += GiveValue(e, ammo_shells, op, val);
1765                                 break;
1766                         case "nails":
1767                         case "bullets":
1768                                 got += GiveValue(e, ammo_nails, op, val);
1769                                 break;
1770                         case "rockets":
1771                                 got += GiveValue(e, ammo_rockets, op, val);
1772                                 break;
1773                         case "health":
1774                                 got += GiveValue(e, health, op, val);
1775                                 break;
1776                         case "armor":
1777                                 got += GiveValue(e, armorvalue, op, val);
1778                                 break;
1779                         case "fuel":
1780                                 got += GiveValue(e, ammo_fuel, op, val);
1781                                 break;
1782                         default:
1783                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1784                                 {
1785                                         wi = get_weaponinfo(j);
1786                                         if(cmd == wi.netname)
1787                                         {
1788                                                 got += GiveWeapon(e, j, op, val);
1789                                                 break;
1790                                         }
1791                                 }
1792                                 if(j > WEP_LAST)
1793                                         print("give: invalid item ", cmd, "\n");
1794                                 break;
1795                 }
1796                 val = 999;
1797                 op = OP_SET;
1798         }
1799
1800         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, "misc/itempickup.wav", string_null);
1801         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1802         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1803         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, "misc/itempickup.wav", string_null);
1804         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1805         {
1806                 wi = get_weaponinfo(j);
1807                 if(wi.weapon)
1808                 {
1809                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1810                         if (!(save_weapons & WepSet_FromWeapon(j)))
1811                                 if(e.weapons & WepSet_FromWeapon(j))
1812                                         WEP_ACTION(wi.weapon, WR_INIT);
1813                 }
1814         }
1815         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1816         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1817         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1818         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1819         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1820         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1821         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1822         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1823         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1824         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1825
1826         if(e.superweapons_finished <= 0)
1827                 if(self.weapons & WEPSET_SUPERWEAPONS)
1828                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1829
1830         if(e.strength_finished <= 0)
1831                 e.strength_finished = 0;
1832         else
1833                 e.strength_finished += time;
1834         if(e.invincible_finished <= 0)
1835                 e.invincible_finished = 0;
1836         else
1837                 e.invincible_finished += time;
1838         if(e.superweapons_finished <= 0)
1839                 e.superweapons_finished = 0;
1840         else
1841                 e.superweapons_finished += time;
1842
1843         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1844                 _switchweapon = true;
1845         if(_switchweapon)
1846                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1847
1848         return got;
1849 }
1850 #endif