qcsrc/server/portals.qc

   1 #define PORTALS_ARE_NOT_SOLID
   2
   3 #define SAFENUDGE '1 1 1'
   4 #define SAFERNUDGE '8 8 8'
   5
   6 .vector portal_transform;
   7 .vector portal_safe_origin;
   8 .float portal_wants_to_vanish;
   9 .float portal_activatetime;
  10 .float savemodelindex;
  11
  12 float PlayerEdgeDistance(entity p, vector v)
  13 {
  14         vector vbest;
  15
  16         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  17         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  18         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  19
  20         return vbest * v;
  21 }
  22
  23 vector Portal_ApplyTransformToPlayerAngle(vector transform, vector vangle)
  24 {
  25         vector old_forward, old_up;
  26         vector old_yawforward;
  27         vector new_forward, new_up;
  28         vector new_yawforward;
  29
  30         vector ang;
  31         ang = vangle;
  32         /*
  33            ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  34            ang = AnglesTransform_ApplyToVAngles(transform, ang);
  35          */
  36
  37         // PLAYERS use different math
  38 #ifndef POSITIVE_PITCH_IS_DOWN
  39         ang_x = -ang_x;
  40 #endif
  41
  42         //print("reference: ", vtos(AnglesTransform_ApplyToVAngles(transform, ang)), "\n");
  43
  44         fixedmakevectors(ang);
  45         old_forward = v_forward;
  46         old_up = v_up;
  47         fixedmakevectors(ang_y * '0 1 0');
  48         old_yawforward = v_forward;
  49
  50         // their aiming directions are portalled...
  51         new_forward = AnglesTransform_Apply(transform, old_forward);
  52         new_up = AnglesTransform_Apply(transform, old_up);
  53         new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
  54
  55         // but now find a new sense of direction
  56         // this is NOT easy!
  57         // assume new_forward points straight up.
  58         // What is our yaw?
  59         //
  60         // new_up could now point forward OR backward... which direction to choose?
  61
  62         if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
  63         {
  64                 // new_yawforward and new_yawup define the new aiming half-circle
  65                 // we "just" need to find out whether new_up or -new_up is in that half circle
  66                 ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
  67                 if(new_up * new_yawforward < 0)
  68                         new_up = -1 * new_up;
  69                 ang_y = vectoyaw(new_up); // this vector is the yaw we want
  70                 //print("UP/DOWN path: ", vtos(ang), "\n");
  71         }
  72         else
  73         {
  74                 // good angles; here, "forward" suffices
  75                 ang = fixedvectoangles(new_forward);
  76                 //print("GOOD path: ", vtos(ang), "\n");
  77         }
  78
  79 #ifndef POSITIVE_PITCH_IS_DOWN
  80         ang_x = -ang_x;
  81 #endif
  82         ang_z = vangle_z;
  83         return ang;
  84 }
  85
  86 .vector right_vector;
  87 float Portal_TeleportPlayer(entity teleporter, entity player)
  88 {
  89         vector from, to, safe, step, transform, ang, newvel;
  90         float planeshift, s, t;
  91
  92         if (!teleporter.enemy)
  93         {
  94                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
  95                 return 0;
  96         }
  97
  98         from = teleporter.origin;
  99         transform = teleporter.portal_transform;
 100
 101         to = teleporter.enemy.origin;
 102         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
 103         newvel = AnglesTransform_Apply(transform, player.velocity);
 104         // this now is INSIDE the plane... can't use that
 105
 106         // shift it out
 107         fixedmakevectors(teleporter.enemy.mangle);
 108
 109         // first shift it ON the plane if needed
 110         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 111         /*
 112         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 113                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 114                 to += newvel * (planeshift / (newvel * v_forward));
 115         else
 116         */
 117                 to += v_forward * planeshift;
 118
 119         s = (to - teleporter.enemy.origin) * v_right;
 120         t = (to - teleporter.enemy.origin) * v_up;
 121         s = bound(-48, s, 48);
 122         t = bound(-48, t, 48);
 123         to = teleporter.enemy.origin
 124            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 125            +     s                                        * v_right
 126            +     t                                        * v_up;
 127
 128         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 129         step = to + ((safe - to) * v_forward) * v_forward;
 130         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 131         if(trace_startsolid)
 132         {
 133                 print("'safe' teleport location is not safe!\n");
 134                 // FAIL TODO why does this happen?
 135                 return 0;
 136         }
 137         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 138         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 139         if(trace_startsolid)
 140         {
 141                 print("trace_endpos in solid, this can't be!\n");
 142                 // FAIL TODO why does this happen? (reported by MrBougo)
 143                 return 0;
 144         }
 145         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 146         //print(vtos(to), "\n");
 147
 148         // ang_x stuff works around weird quake angles
 149         if(IS_PLAYER(player))
 150                 ang = Portal_ApplyTransformToPlayerAngle(transform, player.v_angle);
 151         else
 152                 ang = AnglesTransform_ApplyToAngles(transform, player.angles);
 153
 154         // factor -1 allows chaining portals, but may be weird
 155         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 156
 157         entity oldself = self;
 158         self = player;
 159         MUTATOR_CALLHOOK(PortalTeleport);
 160         player = self;
 161         self = oldself;
 162
 163         if (!teleporter.enemy)
 164         {
 165                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 166                 return 0;
 167         }
 168
 169         tdeath_hit = 0;
 170         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax, TELEPORT_FLAGS_PORTAL);
 171         if(tdeath_hit)
 172         {
 173                 // telefrag within 1 second of portal creation = amazing
 174                 if(time < teleporter.teleport_time + 1)
 175                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_ACHIEVEMENT_AMAZING);
 176         }
 177
 178         if (!teleporter.enemy)
 179         {
 180                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 181                 return 0;
 182         }
 183
 184         // reset fade counter
 185         teleporter.portal_wants_to_vanish = 0;
 186         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 187         teleporter.health = autocvar_g_balance_portal_health;
 188         teleporter.enemy.health = autocvar_g_balance_portal_health;
 189
 190         return 1;
 191 }
 192
 193 float Portal_FindSafeOrigin(entity portal)
 194 {
 195         vector o;
 196         o = portal.origin;
 197         portal.mins = PL_MIN - SAFERNUDGE;
 198         portal.maxs = PL_MAX + SAFERNUDGE;
 199         fixedmakevectors(portal.mangle);
 200         portal.origin += 16 * v_forward;
 201         if(!move_out_of_solid(portal))
 202         {
 203 #ifdef DEBUG
 204                 print("NO SAFE ORIGIN\n");
 205 #endif
 206                 return 0;
 207         }
 208         portal.portal_safe_origin = portal.origin;
 209         setorigin(portal, o);
 210         return 1;
 211 }
 212
 213 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 214 {
 215         float dist, distpersec, delta;
 216         vector v;
 217
 218         dist = (eorg - porg) * pnorm;
 219         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 220         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 221         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 222         if(dist < -1) // other side?
 223                 return 0;
 224 #ifdef PORTALS_ARE_NOT_SOLID
 225         distpersec = evel * pnorm;
 226         if(distpersec >= 0) // going away from the portal?
 227                 return 0;
 228         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 229         delta = dist / distpersec;
 230         v = eorg - evel * delta - porg;
 231         v = v - pnorm * (pnorm * v);
 232         return vlen(v) < psize;
 233 #else
 234         return 1;
 235 #endif
 236 }
 237
 238 void Portal_Touch()
 239 {
 240         vector g;
 241
 242 #ifdef PORTALS_ARE_NOT_SOLID
 243         // portal is being removed?
 244         if(self.solid != SOLID_TRIGGER)
 245                 return; // possibly engine bug
 246
 247         if(IS_PLAYER(other))
 248                 return; // handled by think
 249 #endif
 250
 251         if(other.classname == "item_flag_team")
 252                 return; // never portal these
 253
 254         if(other.classname == "grapplinghook")
 255                 return; // handled by think
 256
 257         if(!autocvar_g_vehicles_teleportable)
 258         if(other.vehicle_flags & VHF_ISVEHICLE)
 259                 return; // no teleporting vehicles?
 260
 261         if(!self.enemy)
 262                 error("Portal_Touch called for a broken portal\n");
 263
 264 #ifdef PORTALS_ARE_NOT_SOLID
 265         if(trace_fraction < 1)
 266                 return; // only handle TouchAreaGrid ones (only these can teleport)
 267 #else
 268         if(trace_fraction >= 1)
 269                 return; // only handle impacts
 270 #endif
 271
 272         if(other.classname == "porto")
 273         {
 274                 if(other.portal_id == self.portal_id)
 275                         return;
 276         }
 277         if(time < self.portal_activatetime)
 278                 if(other == self.aiment)
 279                 {
 280                         self.portal_activatetime = time + 0.1;
 281                         return;
 282                 }
 283         if(other != self.aiment)
 284                 if(IS_PLAYER(other))
 285                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 286                                 return; // cannot go through someone else's portal
 287         if(other.aiment != self.aiment)
 288                 if(IS_PLAYER(other.aiment))
 289                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 290                                 return; // cannot go through someone else's portal
 291         fixedmakevectors(self.mangle);
 292         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 293         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 294                 return;
 295
 296         /*
 297         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 298         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 299         {
 300                 // can't teleport this
 301                 return;
 302         }
 303         */
 304
 305         if(Portal_TeleportPlayer(self, other))
 306                 if(other.classname == "porto")
 307                         if(other.effects & EF_RED)
 308                                 other.effects += EF_BLUE - EF_RED;
 309 }
 310
 311 void Portal_Think();
 312 void Portal_MakeBrokenPortal(entity portal)
 313 {
 314         portal.skin = 2;
 315         portal.solid = SOLID_NOT;
 316         portal.touch = func_null;
 317         portal.think = func_null;
 318         portal.effects = 0;
 319         portal.nextthink = 0;
 320         portal.takedamage = DAMAGE_NO;
 321 }
 322
 323 void Portal_MakeWaitingPortal(entity portal)
 324 {
 325         portal.skin = 2;
 326         portal.solid = SOLID_NOT;
 327         portal.touch = func_null;
 328         portal.think = func_null;
 329         portal.effects = EF_ADDITIVE;
 330         portal.nextthink = 0;
 331         portal.takedamage = DAMAGE_YES;
 332 }
 333
 334 void Portal_MakeInPortal(entity portal)
 335 {
 336         portal.skin = 0;
 337         portal.solid = SOLID_NOT; // this is done when connecting them!
 338         portal.touch = Portal_Touch;
 339         portal.think = Portal_Think;
 340         portal.effects = EF_RED;
 341         portal.nextthink = time;
 342         portal.takedamage = DAMAGE_NO;
 343 }
 344
 345 void Portal_MakeOutPortal(entity portal)
 346 {
 347         portal.skin = 1;
 348         portal.solid = SOLID_NOT;
 349         portal.touch = func_null;
 350         portal.think = func_null;
 351         portal.effects = EF_STARDUST | EF_BLUE;
 352         portal.nextthink = 0;
 353         portal.takedamage = DAMAGE_YES;
 354 }
 355
 356 void Portal_Disconnect(entity teleporter, entity destination)
 357 {
 358         teleporter.enemy = world;
 359         destination.enemy = world;
 360         Portal_MakeBrokenPortal(teleporter);
 361         Portal_MakeBrokenPortal(destination);
 362 }
 363
 364 void Portal_Connect(entity teleporter, entity destination)
 365 {
 366         teleporter.portal_transform = AnglesTransform_RightDivide(AnglesTransform_TurnDirectionFR(destination.mangle), teleporter.mangle);
 367
 368         teleporter.enemy = destination;
 369         destination.enemy = teleporter;
 370         Portal_MakeInPortal(teleporter);
 371         Portal_MakeOutPortal(destination);
 372         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 373         destination.fade_time = teleporter.fade_time;
 374         teleporter.portal_wants_to_vanish = 0;
 375         destination.portal_wants_to_vanish = 0;
 376         teleporter.teleport_time = time;
 377 #ifdef PORTALS_ARE_NOT_SOLID
 378         teleporter.solid = SOLID_TRIGGER;
 379 #else
 380         teleporter.solid = SOLID_BSP;
 381 #endif
 382 }
 383
 384 void Portal_Remove(entity portal, float killed)
 385 {
 386         entity e;
 387         e = portal.enemy;
 388
 389         if(e)
 390         {
 391                 Portal_Disconnect(portal, e);
 392                 Portal_Remove(e, killed);
 393         }
 394
 395         if(portal == portal.aiment.portal_in)
 396                 portal.aiment.portal_in = world;
 397         if(portal == portal.aiment.portal_out)
 398                 portal.aiment.portal_out = world;
 399         //portal.aiment = world;
 400
 401         // makes the portal vanish
 402         if(killed)
 403         {
 404                 fixedmakevectors(portal.mangle);
 405                 sound(portal, CH_SHOTS, "porto/explode.wav", VOL_BASE, ATTEN_NORM);
 406                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 407                 remove(portal);
 408         }
 409         else
 410         {
 411                 Portal_MakeBrokenPortal(portal);
 412                 sound(portal, CH_SHOTS, "porto/expire.wav", VOL_BASE, ATTEN_NORM);
 413                 SUB_SetFade(portal, time, 0.5);
 414         }
 415 }
 416
 417 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 418 {
 419         if(deathtype == DEATH_TELEFRAG)
 420                 return;
 421         if(attacker != self.aiment)
 422                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 423                         return;
 424         self.health -= damage;
 425         if(self.health < 0)
 426                 Portal_Remove(self, 1);
 427 }
 428
 429 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 430 {
 431         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 432                 return;
 433
 434         // if e would hit the portal in a frame...
 435         // already teleport him
 436         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 437         if(trace_ent == self)
 438                 Portal_TeleportPlayer(self, e);
 439 }
 440
 441 void Portal_Think()
 442 {
 443         entity e, o;
 444         vector g;
 445
 446 #ifdef PORTALS_ARE_NOT_SOLID
 447         // portal is being removed?
 448         if(self.solid != SOLID_TRIGGER)
 449                 return; // possibly engine bug
 450
 451         if(!self.enemy)
 452                 error("Portal_Think called for a broken portal\n");
 453
 454         o = self.aiment;
 455         self.solid = SOLID_BBOX;
 456         self.aiment = world;
 457
 458         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 459
 460         fixedmakevectors(self.mangle);
 461
 462         FOR_EACH_PLAYER(e)
 463         {
 464                 if(e != o)
 465                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 466                                 continue; // cannot go through someone else's portal
 467
 468                 if(e != o || time >= self.portal_activatetime)
 469                         Portal_Think_TryTeleportPlayer(e, g);
 470
 471                 if(e.hook)
 472                         Portal_Think_TryTeleportPlayer(e.hook, g);
 473         }
 474         self.solid = SOLID_TRIGGER;
 475         self.aiment = o;
 476 #endif
 477
 478         self.nextthink = time;
 479
 480         if(time > self.fade_time)
 481                 Portal_Remove(self, 0);
 482 }
 483
 484 float Portal_Customize()
 485 {
 486         if(IS_SPEC(other))
 487                 other = other.enemy;
 488         if(other == self.aiment)
 489         {
 490                 self.modelindex = self.savemodelindex;
 491         }
 492         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 493         {
 494                 self.modelindex = 0;
 495         }
 496         else
 497         {
 498                 self.modelindex = self.savemodelindex;
 499         }
 500         return TRUE;
 501 }
 502
 503 // cleanup:
 504 //   when creating in-portal:
 505 //     disconnect
 506 //     clear existing in-portal
 507 //     set as in-portal
 508 //     connect
 509 //   when creating out-portal:
 510 //     disconnect
 511 //     clear existing out-portal
 512 //     set as out-portal
 513 //   when player dies:
 514 //     disconnect portals
 515 //     clear both portals
 516 //   after timeout of in-portal:
 517 //     disconnect portals
 518 //     clear both portals
 519 //   TODO: ensure only one portal shot at once
 520 float Portal_SetInPortal(entity own, entity portal)
 521 {
 522         if(own.portal_in)
 523         {
 524                 if(own.portal_out)
 525                         Portal_Disconnect(own.portal_in, own.portal_out);
 526                 Portal_Remove(own.portal_in, 0);
 527         }
 528         own.portal_in = portal;
 529         if(own.portal_out)
 530         {
 531                 own.portal_out.portal_id = portal.portal_id;
 532                 Portal_Connect(own.portal_in, own.portal_out);
 533         }
 534         return 2;
 535 }
 536 float Portal_SetOutPortal(entity own, entity portal)
 537 {
 538         if(own.portal_out)
 539         {
 540                 if(own.portal_in)
 541                         Portal_Disconnect(own.portal_in, own.portal_out);
 542                 Portal_Remove(own.portal_out, 0);
 543         }
 544         own.portal_out = portal;
 545         if(own.portal_in)
 546         {
 547                 own.portal_in.portal_id = portal.portal_id;
 548                 Portal_Connect(own.portal_in, own.portal_out);
 549         }
 550         return 1;
 551 }
 552 void Portal_ClearAll_PortalsOnly(entity own)
 553 {
 554         if(own.portal_in)
 555                 Portal_Remove(own.portal_in, 0);
 556         if(own.portal_out)
 557                 Portal_Remove(own.portal_out, 0);
 558 }
 559 void Portal_ClearAll(entity own)
 560 {
 561         Portal_ClearAll_PortalsOnly(own);
 562         W_Porto_Remove(own);
 563 }
 564 void Portal_RemoveLater_Think()
 565 {
 566         Portal_Remove(self, self.cnt);
 567 }
 568 void Portal_RemoveLater(entity portal, float kill)
 569 {
 570         Portal_MakeBrokenPortal(portal);
 571         portal.cnt = kill;
 572         portal.think = Portal_RemoveLater_Think;
 573         portal.nextthink = time;
 574 }
 575 void Portal_ClearAllLater_PortalsOnly(entity own)
 576 {
 577         if(own.portal_in)
 578                 Portal_RemoveLater(own.portal_in, 0);
 579         if(own.portal_out)
 580                 Portal_RemoveLater(own.portal_out, 0);
 581 }
 582 void Portal_ClearAllLater(entity own)
 583 {
 584         Portal_ClearAllLater_PortalsOnly(own);
 585         W_Porto_Remove(own);
 586 }
 587 void Portal_ClearWithID(entity own, float id)
 588 {
 589         if(own.portal_in)
 590                 if(own.portal_in.portal_id == id)
 591                 {
 592                         if(own.portal_out)
 593                                 Portal_Disconnect(own.portal_in, own.portal_out);
 594                         Portal_Remove(own.portal_in, 0);
 595                 }
 596         if(own.portal_out)
 597                 if(own.portal_out.portal_id == id)
 598                 {
 599                         if(own.portal_in)
 600                                 Portal_Disconnect(own.portal_in, own.portal_out);
 601                         Portal_Remove(own.portal_out, 0);
 602                 }
 603 }
 604
 605 entity Portal_Spawn(entity own, vector org, vector ang)
 606 {
 607         entity portal;
 608
 609         fixedmakevectors(ang);
 610         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 611                 return world;
 612
 613         portal = spawn();
 614         portal.classname = "portal";
 615         portal.aiment = own;
 616         setorigin(portal, org);
 617         portal.mangle = ang;
 618         portal.angles = ang;
 619         portal.angles_x = -portal.angles_x; // is a bmodel
 620         portal.think = Portal_Think;
 621         portal.nextthink = 0;
 622         portal.portal_activatetime = time + 0.1;
 623         portal.takedamage = DAMAGE_AIM;
 624         portal.event_damage = Portal_Damage;
 625         portal.fade_time = time + autocvar_g_balance_portal_lifetime;
 626         portal.health = autocvar_g_balance_portal_health;
 627         setmodel(portal, "models/portal.md3");
 628         portal.savemodelindex = portal.modelindex;
 629         portal.customizeentityforclient = Portal_Customize;
 630
 631         if(!Portal_FindSafeOrigin(portal))
 632         {
 633                 remove(portal);
 634                 return world;
 635         }
 636
 637         setsize(portal, '-48 -48 -48', '48 48 48');
 638         Portal_MakeWaitingPortal(portal);
 639
 640         return portal;
 641 }
 642
 643 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 644 {
 645         entity portal;
 646         vector ang;
 647         vector org;
 648
 649         org = trace_endpos;
 650         ang = fixedvectoangles2(trace_plane_normal, dir);
 651         fixedmakevectors(ang);
 652
 653         portal = Portal_Spawn(own, org, ang);
 654         if(!portal)
 655                 return 0;
 656
 657         portal.portal_id = portal_id_val;
 658         Portal_SetInPortal(own, portal);
 659
 660         return 1;
 661 }
 662
 663 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 664 {
 665         entity portal;
 666         vector ang;
 667         vector org;
 668
 669         org = trace_endpos;
 670         ang = fixedvectoangles2(trace_plane_normal, dir);
 671         fixedmakevectors(ang);
 672
 673         portal = Portal_Spawn(own, org, ang);
 674         if(!portal)
 675                 return 0;
 676
 677         portal.portal_id = portal_id_val;
 678         Portal_SetOutPortal(own, portal);
 679
 680         return 1;
 681 }