qcsrc/server/mutators/mutator_minstagib.qc

   1 void spawnfunc_item_minst_cells (void)
   2 {
   3         if not(g_minstagib) { remove(self); return; }
   4         if not(self.ammo_cells)
   5                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
   6
   7         StartItem ("models/items/a_cells.md3",
   8                            "misc/itempickup.wav", 45, 0,
   9                            "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
  10 }
  11
  12 void minstagib_health_mega()
  13 {
  14         self.max_health = 1;
  15         StartItem ("models/items/g_h100.md3",
  16                            "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
  17                            "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
  18 }
  19
  20 .float minstagib_nextthink;
  21 .float minstagib_needammo;
  22 void minstagib_stop_countdown(entity e)
  23 {
  24         if (!e.minstagib_needammo)
  25                 return;
  26         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_MINSTA_FINDAMMO);
  27         e.minstagib_needammo = FALSE;
  28 }
  29 void minstagib_ammocheck(void)
  30 {
  31         if not(IS_PLAYER(self))
  32                 return; // not a player
  33         if (time < self.minstagib_nextthink)
  34                 return;
  35
  36         if (self.deadflag || gameover)
  37                 minstagib_stop_countdown(self);
  38         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO))
  39                 minstagib_stop_countdown(self);
  40         else
  41         {
  42                 self.minstagib_needammo = TRUE;
  43                 if (self.health == 5)
  44                 {
  45                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
  46                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_MINSTAGIB_TERMINATED);
  47                 }
  48                 else if (self.health == 10)
  49                 {
  50                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
  51                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_1);
  52                 }
  53                 else if (self.health == 20)
  54                 {
  55                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  56                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_2);
  57                 }
  58                 else if (self.health == 30)
  59                 {
  60                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  61                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_3);
  62                 }
  63                 else if (self.health == 40)
  64                 {
  65                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  66                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_4);
  67                 }
  68                 else if (self.health == 50)
  69                 {
  70                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  71                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_5);
  72                 }
  73                 else if (self.health == 60)
  74                 {
  75                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  76                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_6);
  77                 }
  78                 else if (self.health == 70)
  79                 {
  80                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  81                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_7);
  82                 }
  83                 else if (self.health == 80)
  84                 {
  85                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  86                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_8);
  87                 }
  88                 else if (self.health == 90)
  89                 {
  90                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MINSTA_FINDAMMO);
  91                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  92                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_9);
  93                 }
  94                 else if (self.health == 100)
  95                 {
  96                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_MULTI, MULTI_MINSTA_FINDAMMO);
  97                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  98                 }
  99         }
 100         self.minstagib_nextthink = time + 1;
 101 }
 102
 103 MUTATOR_HOOKFUNCTION(minstagib_MatchEnd)
 104 {
 105         entity head;
 106         FOR_EACH_PLAYER(head)
 107                 minstagib_stop_countdown(head);
 108
 109         return FALSE;
 110 }
 111
 112 MUTATOR_HOOKFUNCTION(minstagib_MonsterLoot)
 113 {
 114         other.monster_loot = spawnfunc_item_minst_cells;
 115
 116         return FALSE;
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(minstagib_BotShouldAttack)
 120 {
 121         if(checkentity.items & IT_STRENGTH)
 122                 return TRUE;
 123
 124         return FALSE;
 125 }
 126
 127 MUTATOR_HOOKFUNCTION(minstagib_MakePlayerObserver)
 128 {
 129         minstagib_stop_countdown(self);
 130         return FALSE;
 131 }
 132
 133 MUTATOR_HOOKFUNCTION(minstagib_PlayerSpawn)
 134 {
 135         self.effects |= EF_FULLBRIGHT;
 136         return FALSE;
 137 }
 138
 139 MUTATOR_HOOKFUNCTION(minstagib_PlayerPreThink)
 140 {
 141         minstagib_ammocheck();
 142         return FALSE;
 143 }
 144
 145 MUTATOR_HOOKFUNCTION(minstagib_PlayerPowerups)
 146 {
 147         if not(self.effects & EF_FULLBRIGHT)
 148                 self.effects |= EF_FULLBRIGHT;
 149
 150         if (self.items & IT_STRENGTH)
 151         {
 152                 play_countdown(self.strength_finished, "misc/poweroff.wav");
 153                 if (time > self.strength_finished)
 154                 {
 155                         self.alpha = default_player_alpha;
 156                         self.exteriorweaponentity.alpha = default_weapon_alpha;
 157                         self.items &~= IT_STRENGTH;
 158                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
 159                 }
 160         }
 161         else
 162         {
 163                 if (time < self.strength_finished)
 164                 {
 165                         self.alpha = autocvar_g_minstagib_invis_alpha;
 166                         self.exteriorweaponentity.alpha = autocvar_g_minstagib_invis_alpha;
 167                         self.items |= IT_STRENGTH;
 168                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
 169                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
 170                 }
 171         }
 172
 173         if (self.items & IT_INVINCIBLE)
 174         {
 175                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
 176                 if (time > self.invincible_finished)
 177                 {
 178                         self.items &~= IT_INVINCIBLE;
 179                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
 180                 }
 181         }
 182         else
 183         {
 184                 if (time < self.invincible_finished)
 185                 {
 186                         self.items |= IT_INVINCIBLE;
 187                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
 188                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
 189                 }
 190         }
 191         return FALSE;
 192 }
 193
 194 MUTATOR_HOOKFUNCTION(minstagib_PlayerPhysics)
 195 {
 196         if(self.items & IT_INVINCIBLE)
 197                 self.stat_sv_maxspeed = self.stat_sv_maxspeed * autocvar_g_minstagib_speed_highspeed;
 198
 199         return FALSE;
 200 }
 201
 202 MUTATOR_HOOKFUNCTION(minstagib_SplitHealthArmor)
 203 {
 204         damage_save = 0;
 205         //damage_take = frag_damage; // frag_damage isn't even set here?!
 206
 207         return FALSE;
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(minstagib_ForbidThrowing)
 211 {
 212         if (self.health < 1)
 213                 return FALSE;
 214
 215         return TRUE;
 216 }
 217
 218 MUTATOR_HOOKFUNCTION(minstagib_PlayerDamage)
 219 {
 220         if(autocvar_g_friendlyfire == 0 && !IsDifferentTeam(frag_target, frag_attacker) && IS_PLAYER(frag_target))
 221                 frag_damage = 0;
 222
 223         if(IS_PLAYER(frag_target))
 224         {
 225                 if ((frag_deathtype == DEATH_FALL)  ||
 226                         (frag_deathtype == DEATH_DROWN) ||
 227                         (frag_deathtype == DEATH_SLIME) ||
 228                         (frag_deathtype == DEATH_LAVA))
 229                 {
 230                         frag_damage = 0;
 231                 }
 232
 233                 if (frag_target.armorvalue && (frag_deathtype == WEP_MINSTANEX) && frag_damage)
 234                 {
 235                         frag_target.armorvalue -= 1;
 236                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_target.armorvalue);
 237                         frag_damage = 0;
 238                         frag_target.hitsound += 1;
 239                         frag_attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 240                 }
 241                 if (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
 242                 {
 243                         frag_damage = 0;
 244                         frag_mirrordamage = 0;
 245                         if (frag_target != frag_attacker)
 246                         {
 247                                 if ((frag_target.health >= 1) && IS_PLAYER(frag_target))
 248                                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
 249                                 frag_force = '0 0 0';
 250                                 // keep mirrorfrag_force
 251                                 frag_attacker = frag_target;
 252                         }
 253                 }
 254         }
 255
 256         if(frag_mirrordamage > 0)
 257         {
 258                 // just lose extra LIVES, don't kill the player for mirror damage
 259                 if(frag_attacker.armorvalue > 0)
 260                 {
 261                         frag_attacker.armorvalue = frag_attacker.armorvalue - 1;
 262                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_attacker.armorvalue);
 263                         frag_attacker.hitsound += 1;
 264                 }
 265                 frag_mirrordamage = 0;
 266         }
 267
 268         if(frag_target.items & IT_STRENGTH)
 269                 yoda = 1;
 270
 271         return FALSE;
 272 }
 273
 274 MUTATOR_HOOKFUNCTION(minstagib_SetStartItems)
 275 {
 276         start_ammo_cells = cvar("g_minstagib_ammo_start");
 277
 278         start_health = 100;
 279         start_armorvalue = 0;
 280         WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 281         start_items |= IT_UNLIMITED_SUPERWEAPONS;
 282
 283         return FALSE;
 284 }
 285
 286 MUTATOR_HOOKFUNCTION(minstagib_FilterItem)
 287 {
 288         if(self.classname == "item_cells")
 289                 return TRUE; // no normal cells?
 290
 291         if(self.weapon == WEP_MINSTANEX && self.classname == "droppedweapon")
 292         {
 293                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 294                 return FALSE;
 295         }
 296
 297         if(self.weapon == WEP_ROCKET_LAUNCHER || self.weapon == WEP_NEX)
 298         {
 299                 entity e = spawn();
 300                 setorigin(e, self.origin);
 301                 entity oldself;
 302                 oldself = self;
 303                 self = e;
 304                 spawnfunc_item_minst_cells();
 305                 self = oldself;
 306                 return TRUE;
 307         }
 308
 309         if(self.flags & FL_POWERUP)
 310                 return FALSE;
 311
 312         if(self.ammo_cells > autocvar_g_minstagib_ammo_drop && self.classname != "item_minst_cells")
 313                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 314
 315         if(self.ammo_cells && !self.weapon)
 316                 return FALSE;
 317
 318         return TRUE;
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(minstagib_CustomizeWaypoint)
 322 {
 323         entity e = WaypointSprite_getviewentity(other);
 324
 325         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 326         // but only apply this to real players, not to spectators
 327         if((self.owner.flags & FL_CLIENT) && (self.owner.items & IT_STRENGTH) && (e == other))
 328         if(IsDifferentTeam(self.owner, e))
 329                 return TRUE;
 330
 331         return FALSE;
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(minstagib_ItemCountdown)
 335 {
 336         switch(self.items)
 337         {
 338                 case IT_STRENGTH:   item_name = "item-invis"; item_color = '0 0 1'; break;
 339                 case IT_NAILS:      item_name = "item-extralife"; item_color = '1 0 0'; break;
 340                 case IT_INVINCIBLE: item_name = "item-speed"; item_color = '1 0 1'; break;
 341         }
 342         return FALSE;
 343 }
 344
 345 MUTATOR_HOOKFUNCTION(minstagib_ItemTouch)
 346 {
 347         if(self.ammo_cells)
 348         {
 349                 // play some cool sounds ;)
 350                 if (IS_CLIENT(other))
 351                 {
 352                         if(other.health <= 5)
 353                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
 354                         else if(other.health < 50)
 355                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
 356                 }
 357
 358                 if(other.health < 100)
 359                         other.health = 100;
 360
 361                 return MUT_ITEMTOUCH_CONTINUE;
 362         }
 363
 364         if(self.max_health)
 365         {
 366                 other.armorvalue = bound(other.armorvalue, 999, other.armorvalue + autocvar_g_minstagib_extralives);
 367                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 368                 return MUT_ITEMTOUCH_PICKUP;
 369         }
 370
 371         return MUT_ITEMTOUCH_RETURN;
 372 }
 373
 374 MUTATOR_HOOKFUNCTION(minstagib_OnEntityPreSpawn)
 375 {
 376         if not(autocvar_g_powerups) { return FALSE; }
 377         if not(self.classname == "item_strength" || self.classname == "item_invincible" || self.classname == "item_health_mega")
 378                 return FALSE;
 379
 380         entity e = spawn();
 381
 382         if(random() < 0.3)
 383                 e.think = spawnfunc_item_strength;
 384         else if(random() < 0.6)
 385                 e.think = minstagib_health_mega;
 386         else
 387                 e.think = spawnfunc_item_invincible;
 388
 389         e.nextthink = time + 0.1;
 390         e.spawnflags = self.spawnflags;
 391         e.noalign = self.noalign;
 392         setorigin(e, self.origin);
 393
 394         return TRUE;
 395 }
 396
 397 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsString)
 398 {
 399         ret_string = strcat(ret_string, ":MinstaGib");
 400         return FALSE;
 401 }
 402
 403 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsPrettyString)
 404 {
 405         ret_string = strcat(ret_string, ", MinstaGib");
 406         return FALSE;
 407 }
 408
 409 MUTATOR_DEFINITION(mutator_minstagib)
 410 {
 411         MUTATOR_HOOK(MatchEnd, minstagib_MatchEnd, CBC_ORDER_ANY);
 412         MUTATOR_HOOK(MonsterDropItem, minstagib_MonsterLoot, CBC_ORDER_ANY);
 413         MUTATOR_HOOK(BotShouldAttack, minstagib_BotShouldAttack, CBC_ORDER_ANY);
 414         MUTATOR_HOOK(PlayerPhysics, minstagib_PlayerPhysics, CBC_ORDER_ANY);
 415         MUTATOR_HOOK(PlayerSpawn, minstagib_PlayerSpawn, CBC_ORDER_ANY);
 416         MUTATOR_HOOK(PlayerDamage_Calculate, minstagib_PlayerDamage, CBC_ORDER_ANY);
 417         MUTATOR_HOOK(MakePlayerObserver, minstagib_MakePlayerObserver, CBC_ORDER_ANY);
 418         MUTATOR_HOOK(SetStartItems, minstagib_SetStartItems, CBC_ORDER_ANY);
 419         MUTATOR_HOOK(ItemTouch, minstagib_ItemTouch, CBC_ORDER_ANY);
 420         MUTATOR_HOOK(FilterItem, minstagib_FilterItem, CBC_ORDER_ANY);
 421         MUTATOR_HOOK(CustomizeWaypoint, minstagib_CustomizeWaypoint, CBC_ORDER_ANY);
 422         MUTATOR_HOOK(Item_RespawnCountdown, minstagib_ItemCountdown, CBC_ORDER_ANY);
 423         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, minstagib_SplitHealthArmor, CBC_ORDER_ANY);
 424         MUTATOR_HOOK(PlayerPowerups, minstagib_PlayerPowerups, CBC_ORDER_ANY);
 425         MUTATOR_HOOK(ForbidThrowCurrentWeapon, minstagib_ForbidThrowing, CBC_ORDER_ANY);
 426         MUTATOR_HOOK(PlayerPreThink, minstagib_PlayerPreThink, CBC_ORDER_ANY);
 427         MUTATOR_HOOK(OnEntityPreSpawn, minstagib_OnEntityPreSpawn, CBC_ORDER_ANY);
 428         MUTATOR_HOOK(BuildMutatorsString, minstagib_BuildMutatorsString, CBC_ORDER_ANY);
 429         MUTATOR_HOOK(BuildMutatorsPrettyString, minstagib_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 430
 431         return FALSE;
 432 }