qcsrc/server/mutators/gamemode_freezetag.qc

   1 .float freezetag_frozen_time;
   2 .float freezetag_frozen_timeout;
   3 .float freezetag_revive_progress;
   4 .entity freezetag_ice;
   5 #define ICE_MAX_ALPHA 1
   6 #define ICE_MIN_ALPHA 0.1
   7 float freezetag_teams;
   8
   9 void freezetag_count_alive_players()
  10 {
  11         entity e;
  12         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  13         FOR_EACH_PLAYER(e) {
  14                 if(e.team == NUM_TEAM_1 && e.health >= 1)
  15                 {
  16                         ++total_players;
  17                         if (!e.freezetag_frozen) ++redalive;
  18                 }
  19                 else if(e.team == NUM_TEAM_2 && e.health >= 1)
  20                 {
  21                         ++total_players;
  22                         if (!e.freezetag_frozen) ++bluealive;
  23                 }
  24                 else if(e.team == NUM_TEAM_3 && e.health >= 1)
  25                 {
  26                         ++total_players;
  27                         if (!e.freezetag_frozen) ++yellowalive;
  28                 }
  29                 else if(e.team == NUM_TEAM_4 && e.health >= 1)
  30                 {
  31                         ++total_players;
  32                         if (!e.freezetag_frozen) ++pinkalive;
  33                 }
  34         }
  35         FOR_EACH_REALCLIENT(e) {
  36                 e.redalive_stat = redalive;
  37                 e.bluealive_stat = bluealive;
  38                 e.yellowalive_stat = yellowalive;
  39                 e.pinkalive_stat = pinkalive;
  40         }
  41 }
  42 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  43 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  44
  45 float prev_missing_teams_mask;
  46 float freezetag_CheckTeams()
  47 {
  48         if(FREEZETAG_ALIVE_TEAMS_OK())
  49         {
  50                 if(prev_missing_teams_mask > 0)
  51                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
  52                 prev_missing_teams_mask = -1;
  53                 return 1;
  54         }
  55         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
  56         if(freezetag_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
  57         if(freezetag_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
  58         if(prev_missing_teams_mask != missing_teams_mask)
  59         {
  60                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  61                 prev_missing_teams_mask = missing_teams_mask;
  62         }
  63         return 0;
  64 }
  65
  66 float freezetag_getWinnerTeam()
  67 {
  68         float winner_team = 0;
  69         if(redalive >= 1)
  70                 winner_team = NUM_TEAM_1;
  71         if(bluealive >= 1)
  72         {
  73                 if(winner_team) return 0;
  74                 winner_team = NUM_TEAM_2;
  75         }
  76         if(yellowalive >= 1)
  77         {
  78                 if(winner_team) return 0;
  79                 winner_team = NUM_TEAM_3;
  80         }
  81         if(pinkalive >= 1)
  82         {
  83                 if(winner_team) return 0;
  84                 winner_team = NUM_TEAM_4;
  85         }
  86         if(winner_team)
  87                 return winner_team;
  88         return -1; // no player left
  89 }
  90
  91 float freezetag_CheckWinner()
  92 {
  93         entity e;
  94         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  95         {
  96                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  97                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  98                 FOR_EACH_PLAYER(e)
  99                 {
 100                         e.freezetag_frozen_timeout = 0;
 101                         e.freezetag_revive_progress = 0;
 102                 }
 103                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 104                 return 1;
 105         }
 106
 107         if(FREEZETAG_ALIVE_TEAMS() > 1)
 108                 return 0;
 109
 110         float winner_team;
 111         winner_team = freezetag_getWinnerTeam();
 112         if(winner_team > 0)
 113         {
 114                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
 115                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
 116                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 117         }
 118         else if(winner_team == -1)
 119         {
 120                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 121                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 122         }
 123
 124         FOR_EACH_PLAYER(e)
 125         {
 126                 e.freezetag_frozen_timeout = 0;
 127                 e.freezetag_revive_progress = 0;
 128         }
 129         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 130         return 1;
 131 }
 132
 133 // this is needed to allow the player to turn his view around (fixangle can't
 134 // be used to freeze his view, as that also changes the angles), while not
 135 // turning that ice object with the player
 136 void freezetag_Ice_Think()
 137 {
 138         setorigin(self, self.owner.origin - '0 0 16');
 139         self.nextthink = time;
 140 }
 141
 142 void freezetag_Add_Score(entity attacker)
 143 {
 144         if(attacker == self)
 145         {
 146                 // you froze your own dumb self
 147                 // counted as "suicide" already
 148                 PlayerScore_Add(self, SP_SCORE, -1);
 149         }
 150         else if(IS_PLAYER(attacker))
 151         {
 152                 // got frozen by an enemy
 153                 // counted as "kill" and "death" already
 154                 PlayerScore_Add(self, SP_SCORE, -1);
 155                 PlayerScore_Add(attacker, SP_SCORE, +1);
 156         }
 157         // else nothing - got frozen by the game type rules themselves
 158 }
 159
 160 void freezetag_Freeze(entity attacker)
 161 {
 162         if(self.freezetag_frozen)
 163                 return;
 164         self.freezetag_frozen = 1;
 165         self.freezetag_frozen_time = time;
 166         self.freezetag_revive_progress = 0;
 167         self.health = 1;
 168         if(autocvar_g_freezetag_frozen_maxtime > 0)
 169                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 170
 171         freezetag_count_alive_players();
 172
 173         entity ice;
 174         ice = spawn();
 175         ice.owner = self;
 176         ice.classname = "freezetag_ice";
 177         ice.think = freezetag_Ice_Think;
 178         ice.nextthink = time;
 179         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 180         ice.alpha = ICE_MAX_ALPHA;
 181         ice.colormod = Team_ColorRGB(self.team);
 182         ice.glowmod = ice.colormod;
 183         setmodel(ice, "models/ice/ice.md3");
 184
 185         self.freezetag_ice = ice;
 186
 187         RemoveGrapplingHook(self);
 188
 189         // add waypoint
 190         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 191
 192         freezetag_Add_Score(attacker);
 193 }
 194
 195 void freezetag_Unfreeze(entity attacker)
 196 {
 197         self.freezetag_frozen = 0;
 198         self.freezetag_frozen_time = 0;
 199         self.freezetag_frozen_timeout = 0;
 200         self.freezetag_revive_progress = 0;
 201
 202         remove(self.freezetag_ice);
 203         self.freezetag_ice = world;
 204
 205         if(self.waypointsprite_attached)
 206                 WaypointSprite_Kill(self.waypointsprite_attached);
 207 }
 208
 209
 210 // ================
 211 // Bot player logic
 212 // ================
 213
 214 void() havocbot_role_ft_freeing;
 215 void() havocbot_role_ft_offense;
 216
 217 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 218 {
 219         entity head;
 220         float distance;
 221
 222         FOR_EACH_PLAYER(head)
 223         {
 224                 if ((head != self) && (head.team == self.team))
 225                 {
 226                         if (head.freezetag_frozen)
 227                         {
 228                                 distance = vlen(head.origin - org);
 229                                 if (distance > sradius)
 230                                         continue;
 231                                 navigation_routerating(head, ratingscale, 2000);
 232                         }
 233                         else
 234                         {
 235                                 // If teamate is not frozen still seek them out as fight better
 236                                 // in a group.
 237                                 navigation_routerating(head, ratingscale/3, 2000);
 238                         }
 239                 }
 240         }
 241 }
 242
 243 void havocbot_role_ft_offense()
 244 {
 245         entity head;
 246         float unfrozen;
 247
 248         if(self.deadflag != DEAD_NO)
 249                 return;
 250
 251         if (!self.havocbot_role_timeout)
 252                 self.havocbot_role_timeout = time + random() * 10 + 20;
 253
 254         // Count how many players on team are unfrozen.
 255         unfrozen = 0;
 256         FOR_EACH_PLAYER(head)
 257         {
 258                 if ((head.team == self.team) && (!head.freezetag_frozen))
 259                         unfrozen++;
 260         }
 261
 262         // If only one left on team or if role has timed out then start trying to free players.
 263         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 264         {
 265                 dprint("changing role to freeing\n");
 266                 self.havocbot_role = havocbot_role_ft_freeing;
 267                 self.havocbot_role_timeout = 0;
 268                 return;
 269         }
 270
 271         if (time > self.bot_strategytime)
 272         {
 273                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 274
 275                 navigation_goalrating_start();
 276                 havocbot_goalrating_items(10000, self.origin, 10000);
 277                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 278                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 279                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 280                 navigation_goalrating_end();
 281         }
 282 }
 283
 284 void havocbot_role_ft_freeing()
 285 {
 286         if(self.deadflag != DEAD_NO)
 287                 return;
 288
 289         if (!self.havocbot_role_timeout)
 290                 self.havocbot_role_timeout = time + random() * 10 + 20;
 291
 292         if (time > self.havocbot_role_timeout)
 293         {
 294                 dprint("changing role to offense\n");
 295                 self.havocbot_role = havocbot_role_ft_offense;
 296                 self.havocbot_role_timeout = 0;
 297                 return;
 298         }
 299
 300         if (time > self.bot_strategytime)
 301         {
 302                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 303
 304                 navigation_goalrating_start();
 305                 havocbot_goalrating_items(8000, self.origin, 10000);
 306                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 307                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 308                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 309                 navigation_goalrating_end();
 310         }
 311 }
 312
 313
 314 // ==============
 315 // Hook Functions
 316 // ==============
 317
 318 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 319 {
 320         self.health = 0; // neccessary to update correctly alive stats
 321         freezetag_Unfreeze(world);
 322         freezetag_count_alive_players();
 323         return 1;
 324 }
 325
 326 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 327 {
 328         if(round_handler_IsActive())
 329         if(round_handler_CountdownRunning())
 330         {
 331                 if(self.freezetag_frozen)
 332                         freezetag_Unfreeze(world);
 333                 freezetag_count_alive_players();
 334                 return 1; // let the player die so that he can respawn whenever he wants
 335         }
 336
 337         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 338         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 339         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 340                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 341         {
 342                 // let the player die, he will be automatically frozen when he respawns
 343                 if(!self.freezetag_frozen)
 344                 {
 345                         freezetag_Add_Score(frag_attacker);
 346                         freezetag_count_alive_players();
 347                 }
 348                 else
 349                         freezetag_Unfreeze(world); // remove ice
 350                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 351                 return 1;
 352         }
 353
 354         if(self.freezetag_frozen)
 355                 return 1;
 356
 357         freezetag_Freeze(frag_attacker);
 358
 359         if(frag_attacker == frag_target || frag_attacker == world)
 360         {
 361                 if(IS_PLAYER(frag_target))
 362                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 363                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 364         }
 365         else
 366         {
 367                 if(IS_PLAYER(frag_target))
 368                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_FROZEN, frag_attacker.netname);
 369                 if(IS_PLAYER(frag_attacker))
 370                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_FREEZETAG_FREEZE, frag_target.netname);
 371                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 372         }
 373
 374         frag_target.health = 1; // "respawn" the player :P
 375
 376         return 1;
 377 }
 378
 379 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 380 {
 381         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 382                 return 1; // do nothing, round is starting right now
 383
 384         if(self.freezetag_frozen_timeout == -2) // player was dead
 385         {
 386                 freezetag_Freeze(world);
 387                 return 1;
 388         }
 389
 390         freezetag_count_alive_players();
 391
 392         if(round_handler_IsActive())
 393         if(round_handler_IsRoundStarted())
 394         {
 395                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 396                 freezetag_Freeze(world);
 397         }
 398
 399         return 1;
 400 }
 401
 402 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 403 {
 404         FOR_EACH_PLAYER(self)
 405         {
 406                 self.killcount = 0;
 407                 if (self.freezetag_frozen)
 408                         freezetag_Unfreeze(world);
 409                 self.freezetag_frozen_timeout = -1;
 410                 PutClientInServer();
 411                 self.freezetag_frozen_timeout = 0;
 412         }
 413         freezetag_count_alive_players();
 414         return 1;
 415 }
 416
 417 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 418 {
 419         frag_score = 0; // no frags counted in Freeze Tag
 420         return 1;
 421 }
 422
 423 .float reviving; // temp var
 424 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 425 {
 426         float n;
 427
 428         if(gameover)
 429                 return 1;
 430
 431         if(self.freezetag_frozen)
 432         {
 433                 // keep health = 1
 434                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 435         }
 436
 437         if(round_handler_IsActive())
 438         if(!round_handler_IsRoundStarted())
 439                 return 1;
 440
 441         entity o;
 442         o = world;
 443         if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 444                 self.freezetag_ice.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 445
 446         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 447                 n = -1;
 448         else
 449         {
 450                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 451                 n = 0;
 452                 FOR_EACH_PLAYER(other) if(self != other)
 453                 {
 454                         if(other.freezetag_frozen == 0)
 455                         {
 456                                 if(other.team == self.team)
 457                                 {
 458                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 459                                         {
 460                                                 if(!o)
 461                                                         o = other;
 462                                                 if(self.freezetag_frozen)
 463                                                         other.reviving = TRUE;
 464                                                 ++n;
 465                                         }
 466                                 }
 467                         }
 468                 }
 469         }
 470
 471         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 472         {
 473                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
 474                 if(warmup_stage)
 475                         self.health = max(1, self.freezetag_revive_progress * warmup_start_health);
 476                 else
 477                         self.health = max(1, self.freezetag_revive_progress * start_health);
 478
 479                 if(self.freezetag_revive_progress >= 1)
 480                 {
 481                         freezetag_Unfreeze(self);
 482                         freezetag_count_alive_players();
 483
 484                         if(n == -1)
 485                         {
 486                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, autocvar_g_freezetag_frozen_maxtime);
 487                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, self.netname, autocvar_g_freezetag_frozen_maxtime);
 488                                 return 1;
 489                         }
 490
 491                         // EVERY team mate nearby gets a point (even if multiple!)
 492                         FOR_EACH_PLAYER(other)
 493                         {
 494                                 if(other.reviving)
 495                                 {
 496                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 497                                         PlayerScore_Add(other, SP_SCORE, +1);
 498                                 }
 499                         }
 500
 501                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
 502                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
 503                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED, self.netname, o.netname);
 504                 }
 505
 506                 FOR_EACH_PLAYER(other)
 507                 {
 508                         if(other.reviving)
 509                         {
 510                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 511                                 other.reviving = FALSE;
 512                         }
 513                 }
 514         }
 515         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 516         {
 517                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 518                 if(warmup_stage)
 519                         self.health = max(1, self.freezetag_revive_progress * warmup_start_health);
 520                 else
 521                         self.health = max(1, self.freezetag_revive_progress * start_health);
 522         }
 523         else if(!n)
 524         {
 525                 self.freezetag_revive_progress = 0; // thawing nobody
 526         }
 527
 528         return 1;
 529 }
 530
 531 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 532 {
 533         if(self.freezetag_frozen)
 534         {
 535                 if(autocvar_sv_dodging_frozen && IS_REAL_CLIENT(self))
 536                 {
 537                         self.movement_x = bound(-5, self.movement_x, 5);
 538                         self.movement_y = bound(-5, self.movement_y, 5);
 539                         self.movement_z = bound(-5, self.movement_z, 5);
 540                 }
 541                 else
 542                         self.movement = '0 0 0';
 543
 544                 self.disableclientprediction = 1;
 545         }
 546         return 1;
 547 }
 548
 549 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 550 {
 551         if(frag_target.freezetag_frozen && frag_deathtype != DEATH_HURTTRIGGER)
 552         {
 553                 if(autocvar_g_freezetag_revive_falldamage > 0)
 554                 if(frag_deathtype == DEATH_FALL)
 555                 if(frag_damage >= autocvar_g_freezetag_revive_falldamage)
 556                 {
 557                         freezetag_Unfreeze(frag_target);
 558                         frag_target.health = autocvar_g_freezetag_revive_falldamage_health;
 559                         pointparticles(particleeffectnum("iceorglass"), frag_target.origin, '0 0 0', 3);
 560                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_FALL, frag_target.netname);
 561                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_FALL);
 562                 }
 563
 564                 frag_damage = 0;
 565                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 566         }
 567         return 1;
 568 }
 569
 570 MUTATOR_HOOKFUNCTION(freezetag_PlayerJump)
 571 {
 572         if(self.freezetag_frozen)
 573                 return TRUE; // no jumping in freezetag when frozen
 574
 575         return FALSE;
 576 }
 577
 578 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 579 {
 580         if (self.freezetag_frozen)
 581                 return 1;
 582         return 0;
 583 }
 584
 585 MUTATOR_HOOKFUNCTION(freezetag_ItemTouch)
 586 {
 587         if (other.freezetag_frozen)
 588                 return MUT_ITEMTOUCH_RETURN;
 589         return MUT_ITEMTOUCH_CONTINUE;
 590 }
 591
 592 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 593 {
 594         if (!self.deadflag)
 595         {
 596                 if (random() < 0.5)
 597                         self.havocbot_role = havocbot_role_ft_freeing;
 598                 else
 599                         self.havocbot_role = havocbot_role_ft_offense;
 600         }
 601
 602         return TRUE;
 603 }
 604
 605 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 606 {
 607         self.freezetag_frozen = other.freezetag_frozen;
 608         self.freezetag_revive_progress = other.freezetag_revive_progress;
 609         return 0;
 610 }
 611
 612 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 613 {
 614         ret_float = freezetag_teams;
 615         return 0;
 616 }
 617
 618 MUTATOR_HOOKFUNCTION(freezetag_VehicleTouch)
 619 {
 620         if(other.freezetag_frozen)
 621                 return TRUE;
 622
 623         return FALSE;
 624 }
 625
 626 void freezetag_Initialize()
 627 {
 628         precache_model("models/ice/ice.md3");
 629
 630         freezetag_teams = autocvar_g_freezetag_teams_override;
 631         if(freezetag_teams < 2)
 632                 freezetag_teams = autocvar_g_freezetag_teams;
 633         freezetag_teams = bound(2, freezetag_teams, 4);
 634         ScoreRules_freezetag(freezetag_teams);
 635
 636         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 637         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 638
 639         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 640         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 641         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 642         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 643
 644         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 645         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 646 }
 647
 648 MUTATOR_DEFINITION(gamemode_freezetag)
 649 {
 650         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 651         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 652         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 653         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 654         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 655         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 656         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 657         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 658         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 659         MUTATOR_HOOK(PlayerJump, freezetag_PlayerJump, CBC_ORDER_ANY);
 660         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 661         MUTATOR_HOOK(ItemTouch, freezetag_ItemTouch, CBC_ORDER_ANY);
 662         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 663         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 664         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 665         MUTATOR_HOOK(VehicleTouch, freezetag_VehicleTouch, CBC_ORDER_ANY);
 666
 667         MUTATOR_ONADD
 668         {
 669                 if(time > 1) // game loads at time 1
 670                         error("This is a game type and it cannot be added at runtime.");
 671                 freezetag_Initialize();
 672         }
 673
 674         MUTATOR_ONROLLBACK_OR_REMOVE
 675         {
 676                 // we actually cannot roll back freezetag_Initialize here
 677                 // BUT: we don't need to! If this gets called, adding always
 678                 // succeeds.
 679         }
 680
 681         MUTATOR_ONREMOVE
 682         {
 683                 print("This is a game type and it cannot be removed at runtime.");
 684                 return -1;
 685         }
 686
 687         return 0;
 688 }