qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  10                 return;
  11
  12         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  13                 return; // already waiting for next round to start
  14
  15         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  16                 || (redalive >= 1 && yellowalive >= 1)
  17                 || (redalive >= 1 && pinkalive >= 1)
  18                 || (bluealive >= 1 && yellowalive >= 1)
  19                 || (bluealive >= 1 && pinkalive >= 1)
  20                 || (yellowalive >= 1 && pinkalive >= 1))
  21                 return; // we still have active players on two or more teams, nobody won yet
  22
  23         entity e, winner;
  24         string teamname;
  25
  26         FOR_EACH_PLAYER(e)
  27         {
  28                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  29                 {
  30                         winner = e;
  31                         break; // break, we found the winner
  32                 }
  33         }
  34
  35         if(winner != world) // just in case a winner wasn't found
  36         {
  37                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  38                 if(winner.team == COLOR_TEAM1)
  39                         teamname = "^1Red Team";
  40                 else if(winner.team == COLOR_TEAM2)
  41                         teamname = "^4Blue Team";
  42                 else if(winner.team == COLOR_TEAM3)
  43                         teamname = "^3Yellow Team";
  44                 else
  45                         teamname = "^6Pink Team";
  46                 FOR_EACH_PLAYER(e) {
  47                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  48                 }
  49                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  50         }
  51
  52         next_round = time + 5;
  53 }
  54
  55 void freezetag_Ice_Think()
  56 {
  57         setorigin(self, self.owner.origin - '0 0 16');
  58         self.nextthink = time;
  59 }
  60
  61 void freezetag_Freeze()
  62 {
  63         self.freezetag_frozen = 1;
  64
  65         entity ice;
  66         ice = spawn();
  67         ice.owner = self;
  68         ice.classname = "freezetag_ice";
  69         ice.think = freezetag_Ice_Think;
  70         ice.nextthink = time;
  71         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  72         setmodel(ice, "models/ice/ice.md3");
  73
  74         entity oldself;
  75         olfself = self;
  76         self = ice;
  77         freezetag_Ice_Think();
  78         self = oldself;
  79
  80         // add waypoint
  81         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  82         if(self.waypointsprite_attached)
  83         {
  84                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  85         }
  86 }
  87
  88 void freezetag_Unfreeze()
  89 {
  90         self.freezetag_frozen = 0;
  91
  92         // remove the ice block
  93         entity ice;
  94         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  95         {
  96                 remove(ice);
  97                 break;
  98         }
  99
 100         // remove waypoint
 101         if(self.waypointsprite_attached)
 102                 WaypointSprite_Kill(self.waypointsprite_attached);
 103 }
 104
 105 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 106 {
 107         if(self.freezetag_frozen == 0)
 108         {
 109                 if(self.team == COLOR_TEAM1)
 110                         --redalive;
 111                 else if(self.team == COLOR_TEAM2)
 112                         --bluealive;
 113                 else if(self.team == COLOR_TEAM3)
 114                         --yellowalive;
 115                 else if(self.team == COLOR_TEAM4)
 116                         --pinkalive;
 117                 --totalalive;
 118         }
 119
 120         if(totalspawned > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 121                 freezetag_CheckWinner();
 122
 123         freezetag_Unfreeze();
 124
 125         return 1;
 126 }
 127
 128 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 129 {
 130         if(self.freezetag_frozen == 0)
 131         {
 132                 if(self.team == COLOR_TEAM1)
 133                         --redalive;
 134                 else if(self.team == COLOR_TEAM2)
 135                         --bluealive;
 136                 else if(self.team == COLOR_TEAM3)
 137                         --yellowalive;
 138                 else if(self.team == COLOR_TEAM4)
 139                         --pinkalive;
 140                 --totalalive;
 141
 142         freezetag_Freeze();
 143         }
 144
 145     if(frag_attacker.classname == STR_PLAYER)
 146         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 147
 148         if(frag_attacker == frag_target || frag_attacker == world)
 149         {
 150         if(frag_target.classname == STR_PLAYER)
 151             centerprint(frag_target, "^1You froze yourself.\n");
 152                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 153         }
 154         else
 155         {
 156         if(frag_target.classname == STR_PLAYER)
 157             centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 158                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 159         }
 160
 161         frag_target.health = autocvar_g_balance_health_start; // "respawn" the player :P
 162
 163         freezetag_CheckWinner();
 164
 165         return 1;
 166 }
 167
 168 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 169 {
 170     freezetag_Unfreeze(); // start by making sure that all ice blocks are removed
 171
 172         if(totalspawned == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 173         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 174         {
 175                 next_round = time;
 176                 return 1;
 177         }
 178         if(warmup && time > warmup) // spawn too late, freeze player
 179         {
 180                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 181                 freezetag_Freeze();
 182         }
 183
 184         return 1;
 185 }
 186
 187 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 188 {
 189         frag_score = 0; // no frags counted in Freeze Tag
 190         return 1;
 191 }
 192
 193 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 194 {
 195     vector revive_extra_size;
 196     revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 197
 198     float teammate_nearby;
 199     FOR_EACH_PLAYER(other) if(self != other)
 200     {
 201         if(other.freezetag_frozen == 0)
 202         {
 203             if(other.team == self.team)
 204             {
 205                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 206                 if(teammate_nearby)
 207                     break;
 208             }
 209         }
 210     }
 211
 212     if(teammate_nearby && self.freezetag_frozen == 1) // OK, there is at least one teammate reviving us
 213     {
 214         if(self.freezetag_beginrevive_time == -9999) // initialize values if this is the first frame of revival
 215         {
 216             self.freezetag_beginrevive_time = time;
 217             self.freezetag_revive_progress = 0;
 218         }
 219         else
 220         {
 221             self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / autocvar_g_freezetag_revive_time;
 222             if(time - self.freezetag_beginrevive_time >= autocvar_g_freezetag_revive_time)
 223             {
 224                 freezetag_Unfreeze();
 225
 226                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 227                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 228                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 229
 230                 self.freezetag_beginrevive_time = -9999;
 231                 self.freezetag_revive_progress = 0;
 232             }
 233         }
 234         // now find EVERY teammate within reviving radius, set their revive_progress values correct
 235         FOR_EACH_PLAYER(other) if(self != other)
 236         {
 237             if(other.freezetag_frozen == 0)
 238             {
 239                 if(other.team == self.team)
 240                 {
 241                     teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 242                     if(teammate_nearby)
 243                         other.freezetag_revive_progress = self.freezetag_revive_progress;
 244                 }
 245             }
 246         }
 247     }
 248     else if(!teammate_nearby) // only if no teammate is nearby will we reset
 249     {
 250         self.freezetag_beginrevive_time = -9999;
 251         self.freezetag_revive_progress = 0;
 252     }
 253
 254         return 1;
 255 }
 256
 257 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 258 {
 259         if(self.freezetag_frozen)
 260         {
 261                 self.movement = '0 0 0';
 262                 self.disableclientprediction = 1;
 263         }
 264         return 1;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 268 {
 269     if(g_freezetag)
 270     {
 271         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 272         {
 273             frag_damage = 0;
 274             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 275         }
 276     }
 277     return 1;
 278 }
 279
 280 MUTATOR_DEFINITION(gamemode_freezetag)
 281 {
 282         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 283         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 284         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 285         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 286         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 287         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 288         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 289         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 290
 291         MUTATOR_ONADD
 292         {
 293                 if(time > 1) // game loads at time 1
 294                         error("This is a game type and it cannot be added at runtime.");
 295                 g_freezetag = 1;
 296                 freezetag_Initialize();
 297         }
 298
 299         MUTATOR_ONREMOVE
 300         {
 301                 g_freezetag = 0;
 302                 error("This is a game type and it cannot be removed at runtime.");
 303         }
 304
 305         return 0;
 306 }