qcsrc/server/mutators/gamemode_freezetag.qc

   1 .float freezetag_frozen_time;
   2 .float freezetag_frozen_timeout;
   3 .float freezetag_revive_progress;
   4 .entity freezetag_ice;
   5 #define ICE_MAX_ALPHA 1
   6 #define ICE_MIN_ALPHA 0.1
   7 float freezetag_teams;
   8
   9 void freezetag_count_alive_players()
  10 {
  11         entity e;
  12         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  13         FOR_EACH_PLAYER(e) {
  14                 if(e.team == NUM_TEAM_1 && e.health >= 1)
  15                 {
  16                         ++total_players;
  17                         if (!e.freezetag_frozen) ++redalive;
  18                 }
  19                 else if(e.team == NUM_TEAM_2 && e.health >= 1)
  20                 {
  21                         ++total_players;
  22                         if (!e.freezetag_frozen) ++bluealive;
  23                 }
  24                 else if(e.team == NUM_TEAM_3 && e.health >= 1)
  25                 {
  26                         ++total_players;
  27                         if (!e.freezetag_frozen) ++yellowalive;
  28                 }
  29                 else if(e.team == NUM_TEAM_4 && e.health >= 1)
  30                 {
  31                         ++total_players;
  32                         if (!e.freezetag_frozen) ++pinkalive;
  33                 }
  34         }
  35         FOR_EACH_REALCLIENT(e) {
  36                 e.redalive_stat = redalive;
  37                 e.bluealive_stat = bluealive;
  38                 e.yellowalive_stat = yellowalive;
  39                 e.pinkalive_stat = pinkalive;
  40         }
  41 }
  42 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  43 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  44
  45 float prev_missing_teams_mask;
  46 float freezetag_CheckTeams()
  47 {
  48         if(FREEZETAG_ALIVE_TEAMS_OK())
  49         {
  50                 if(prev_missing_teams_mask > 0)
  51                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
  52                 prev_missing_teams_mask = -1;
  53                 return 1;
  54         }
  55         if(total_players == 0)
  56         {
  57                 if(prev_missing_teams_mask > 0)
  58                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
  59                 prev_missing_teams_mask = -1;
  60                 return 0;
  61         }
  62         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
  63         if(freezetag_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
  64         if(freezetag_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
  65         if(prev_missing_teams_mask != missing_teams_mask)
  66         {
  67                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  68                 prev_missing_teams_mask = missing_teams_mask;
  69         }
  70         return 0;
  71 }
  72
  73 float freezetag_getWinnerTeam()
  74 {
  75         float winner_team = 0;
  76         if(redalive >= 1)
  77                 winner_team = NUM_TEAM_1;
  78         if(bluealive >= 1)
  79         {
  80                 if(winner_team) return 0;
  81                 winner_team = NUM_TEAM_2;
  82         }
  83         if(yellowalive >= 1)
  84         {
  85                 if(winner_team) return 0;
  86                 winner_team = NUM_TEAM_3;
  87         }
  88         if(pinkalive >= 1)
  89         {
  90                 if(winner_team) return 0;
  91                 winner_team = NUM_TEAM_4;
  92         }
  93         if(winner_team)
  94                 return winner_team;
  95         return -1; // no player left
  96 }
  97
  98 float freezetag_CheckWinner()
  99 {
 100         entity e;
 101         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 102         {
 103                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 104                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 105                 FOR_EACH_PLAYER(e)
 106                 {
 107                         e.freezetag_frozen_timeout = 0;
 108                         e.freezetag_revive_progress = 0;
 109                 }
 110                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 111                 return 1;
 112         }
 113
 114         if(FREEZETAG_ALIVE_TEAMS() > 1)
 115                 return 0;
 116
 117         float winner_team;
 118         winner_team = freezetag_getWinnerTeam();
 119         if(winner_team > 0)
 120         {
 121                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
 122                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
 123                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 124         }
 125         else if(winner_team == -1)
 126         {
 127                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 128                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 129         }
 130
 131         FOR_EACH_PLAYER(e)
 132         {
 133                 e.freezetag_frozen_timeout = 0;
 134                 e.freezetag_revive_progress = 0;
 135         }
 136         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 137         return 1;
 138 }
 139
 140 // this is needed to allow the player to turn his view around (fixangle can't
 141 // be used to freeze his view, as that also changes the angles), while not
 142 // turning that ice object with the player
 143 void freezetag_Ice_Think()
 144 {
 145         setorigin(self, self.owner.origin - '0 0 16');
 146         self.nextthink = time;
 147 }
 148
 149 void freezetag_Add_Score(entity attacker)
 150 {
 151         if(attacker == self)
 152         {
 153                 // you froze your own dumb self
 154                 // counted as "suicide" already
 155                 PlayerScore_Add(self, SP_SCORE, -1);
 156         }
 157         else if(IS_PLAYER(attacker))
 158         {
 159                 // got frozen by an enemy
 160                 // counted as "kill" and "death" already
 161                 PlayerScore_Add(self, SP_SCORE, -1);
 162                 PlayerScore_Add(attacker, SP_SCORE, +1);
 163         }
 164         // else nothing - got frozen by the game type rules themselves
 165 }
 166
 167 void freezetag_Freeze(entity attacker)
 168 {
 169         if(self.freezetag_frozen)
 170                 return;
 171         self.freezetag_frozen = 1;
 172         self.freezetag_frozen_time = time;
 173         self.freezetag_revive_progress = 0;
 174         self.health = 1;
 175         if(autocvar_g_freezetag_frozen_maxtime > 0)
 176                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 177
 178         freezetag_count_alive_players();
 179
 180         entity ice;
 181         ice = spawn();
 182         ice.owner = self;
 183         ice.classname = "freezetag_ice";
 184         ice.think = freezetag_Ice_Think;
 185         ice.nextthink = time;
 186         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 187         ice.alpha = ICE_MAX_ALPHA;
 188         ice.colormod = Team_ColorRGB(self.team);
 189         ice.glowmod = ice.colormod;
 190         setmodel(ice, "models/ice/ice.md3");
 191
 192         self.freezetag_ice = ice;
 193
 194         RemoveGrapplingHook(self);
 195
 196         // add waypoint
 197         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 198
 199         freezetag_Add_Score(attacker);
 200 }
 201
 202 void freezetag_Unfreeze(entity attacker)
 203 {
 204         self.freezetag_frozen = 0;
 205         self.freezetag_frozen_time = 0;
 206         self.freezetag_frozen_timeout = 0;
 207         self.freezetag_revive_progress = 0;
 208
 209         remove(self.freezetag_ice);
 210         self.freezetag_ice = world;
 211
 212         if(self.waypointsprite_attached)
 213                 WaypointSprite_Kill(self.waypointsprite_attached);
 214 }
 215
 216
 217 // ================
 218 // Bot player logic
 219 // ================
 220
 221 void() havocbot_role_ft_freeing;
 222 void() havocbot_role_ft_offense;
 223
 224 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 225 {
 226         entity head;
 227         float distance;
 228
 229         FOR_EACH_PLAYER(head)
 230         {
 231                 if ((head != self) && (head.team == self.team))
 232                 {
 233                         if (head.freezetag_frozen)
 234                         {
 235                                 distance = vlen(head.origin - org);
 236                                 if (distance > sradius)
 237                                         continue;
 238                                 navigation_routerating(head, ratingscale, 2000);
 239                         }
 240                         else
 241                         {
 242                                 // If teamate is not frozen still seek them out as fight better
 243                                 // in a group.
 244                                 navigation_routerating(head, ratingscale/3, 2000);
 245                         }
 246                 }
 247         }
 248 }
 249
 250 void havocbot_role_ft_offense()
 251 {
 252         entity head;
 253         float unfrozen;
 254
 255         if(self.deadflag != DEAD_NO)
 256                 return;
 257
 258         if (!self.havocbot_role_timeout)
 259                 self.havocbot_role_timeout = time + random() * 10 + 20;
 260
 261         // Count how many players on team are unfrozen.
 262         unfrozen = 0;
 263         FOR_EACH_PLAYER(head)
 264         {
 265                 if ((head.team == self.team) && (!head.freezetag_frozen))
 266                         unfrozen++;
 267         }
 268
 269         // If only one left on team or if role has timed out then start trying to free players.
 270         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 271         {
 272                 dprint("changing role to freeing\n");
 273                 self.havocbot_role = havocbot_role_ft_freeing;
 274                 self.havocbot_role_timeout = 0;
 275                 return;
 276         }
 277
 278         if (time > self.bot_strategytime)
 279         {
 280                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 281
 282                 navigation_goalrating_start();
 283                 havocbot_goalrating_items(10000, self.origin, 10000);
 284                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 285                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 286                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 287                 navigation_goalrating_end();
 288         }
 289 }
 290
 291 void havocbot_role_ft_freeing()
 292 {
 293         if(self.deadflag != DEAD_NO)
 294                 return;
 295
 296         if (!self.havocbot_role_timeout)
 297                 self.havocbot_role_timeout = time + random() * 10 + 20;
 298
 299         if (time > self.havocbot_role_timeout)
 300         {
 301                 dprint("changing role to offense\n");
 302                 self.havocbot_role = havocbot_role_ft_offense;
 303                 self.havocbot_role_timeout = 0;
 304                 return;
 305         }
 306
 307         if (time > self.bot_strategytime)
 308         {
 309                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 310
 311                 navigation_goalrating_start();
 312                 havocbot_goalrating_items(8000, self.origin, 10000);
 313                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 314                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 315                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 316                 navigation_goalrating_end();
 317         }
 318 }
 319
 320
 321 // ==============
 322 // Hook Functions
 323 // ==============
 324
 325 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 326 {
 327         self.health = 0; // neccessary to update correctly alive stats
 328         freezetag_Unfreeze(world);
 329         freezetag_count_alive_players();
 330         return 1;
 331 }
 332
 333 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 334 {
 335         if(round_handler_IsActive())
 336         if(round_handler_CountdownRunning())
 337         {
 338                 if(self.freezetag_frozen)
 339                         freezetag_Unfreeze(world);
 340                 freezetag_count_alive_players();
 341                 return 1; // let the player die so that he can respawn whenever he wants
 342         }
 343
 344         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 345         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 346         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 347                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 348         {
 349                 // let the player die, he will be automatically frozen when he respawns
 350                 if(!self.freezetag_frozen)
 351                 {
 352                         freezetag_Add_Score(frag_attacker);
 353                         freezetag_count_alive_players();
 354                 }
 355                 else
 356                         freezetag_Unfreeze(world); // remove ice
 357                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 358                 return 1;
 359         }
 360
 361         if(self.freezetag_frozen)
 362                 return 1;
 363
 364         freezetag_Freeze(frag_attacker);
 365
 366         if(frag_attacker == frag_target || frag_attacker == world)
 367         {
 368                 if(IS_PLAYER(frag_target))
 369                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 370                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 371         }
 372         else
 373         {
 374                 if(IS_PLAYER(frag_target))
 375                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_FROZEN, frag_attacker.netname);
 376                 if(IS_PLAYER(frag_attacker))
 377                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_FREEZETAG_FREEZE, frag_target.netname);
 378                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 379         }
 380
 381         frag_target.health = 1; // "respawn" the player :P
 382
 383         return 1;
 384 }
 385
 386 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 387 {
 388         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 389                 return 1; // do nothing, round is starting right now
 390
 391         if(self.freezetag_frozen_timeout == -2) // player was dead
 392         {
 393                 freezetag_Freeze(world);
 394                 return 1;
 395         }
 396
 397         freezetag_count_alive_players();
 398
 399         if(round_handler_IsActive())
 400         if(round_handler_IsRoundStarted())
 401         {
 402                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 403                 freezetag_Freeze(world);
 404         }
 405
 406         return 1;
 407 }
 408
 409 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 410 {
 411         FOR_EACH_PLAYER(self)
 412         {
 413                 self.killcount = 0;
 414                 if (self.freezetag_frozen)
 415                         freezetag_Unfreeze(world);
 416                 self.freezetag_frozen_timeout = -1;
 417                 PutClientInServer();
 418                 self.freezetag_frozen_timeout = 0;
 419         }
 420         freezetag_count_alive_players();
 421         return 1;
 422 }
 423
 424 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 425 {
 426         frag_score = 0; // no frags counted in Freeze Tag
 427         return 1;
 428 }
 429
 430 .float reviving; // temp var
 431 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 432 {
 433         float n;
 434
 435         if(gameover)
 436                 return 1;
 437
 438         if(self.freezetag_frozen)
 439         {
 440                 // keep health = 1
 441                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 442         }
 443
 444         if(round_handler_IsActive())
 445         if(!round_handler_IsRoundStarted())
 446                 return 1;
 447
 448         entity o;
 449         o = world;
 450         if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 451                 self.freezetag_ice.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 452
 453         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 454                 n = -1;
 455         else
 456         {
 457                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 458                 n = 0;
 459                 FOR_EACH_PLAYER(other) if(self != other)
 460                 {
 461                         if(other.freezetag_frozen == 0)
 462                         {
 463                                 if(other.team == self.team)
 464                                 {
 465                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 466                                         {
 467                                                 if(!o)
 468                                                         o = other;
 469                                                 if(self.freezetag_frozen)
 470                                                         other.reviving = TRUE;
 471                                                 ++n;
 472                                         }
 473                                 }
 474                         }
 475                 }
 476         }
 477
 478         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 479         {
 480                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
 481                 if(warmup_stage)
 482                         self.health = max(1, self.freezetag_revive_progress * warmup_start_health);
 483                 else
 484                         self.health = max(1, self.freezetag_revive_progress * start_health);
 485
 486                 if(self.freezetag_revive_progress >= 1)
 487                 {
 488                         freezetag_Unfreeze(self);
 489                         freezetag_count_alive_players();
 490
 491                         if(n == -1)
 492                         {
 493                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, autocvar_g_freezetag_frozen_maxtime);
 494                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, self.netname, autocvar_g_freezetag_frozen_maxtime);
 495                                 return 1;
 496                         }
 497
 498                         // EVERY team mate nearby gets a point (even if multiple!)
 499                         FOR_EACH_PLAYER(other)
 500                         {
 501                                 if(other.reviving)
 502                                 {
 503                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 504                                         PlayerScore_Add(other, SP_SCORE, +1);
 505                                 }
 506                         }
 507
 508                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
 509                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
 510                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED, self.netname, o.netname);
 511                 }
 512
 513                 FOR_EACH_PLAYER(other)
 514                 {
 515                         if(other.reviving)
 516                         {
 517                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 518                                 other.reviving = FALSE;
 519                         }
 520                 }
 521         }
 522         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 523         {
 524                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 525                 if(warmup_stage)
 526                         self.health = max(1, self.freezetag_revive_progress * warmup_start_health);
 527                 else
 528                         self.health = max(1, self.freezetag_revive_progress * start_health);
 529         }
 530         else if(!n)
 531         {
 532                 self.freezetag_revive_progress = 0; // thawing nobody
 533         }
 534
 535         return 1;
 536 }
 537
 538 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 539 {
 540         if(self.freezetag_frozen)
 541         {
 542                 if(autocvar_sv_dodging_frozen && IS_REAL_CLIENT(self))
 543                 {
 544                         self.movement_x = bound(-5, self.movement_x, 5);
 545                         self.movement_y = bound(-5, self.movement_y, 5);
 546                         self.movement_z = bound(-5, self.movement_z, 5);
 547                 }
 548                 else
 549                         self.movement = '0 0 0';
 550
 551                 self.disableclientprediction = 1;
 552         }
 553         return 1;
 554 }
 555
 556 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 557 {
 558         if(frag_target.freezetag_frozen && frag_deathtype != DEATH_HURTTRIGGER)
 559         {
 560                 if(autocvar_g_freezetag_revive_falldamage > 0)
 561                 if(frag_deathtype == DEATH_FALL)
 562                 if(frag_damage >= autocvar_g_freezetag_revive_falldamage)
 563                 {
 564                         freezetag_Unfreeze(frag_target);
 565                         frag_target.health = autocvar_g_freezetag_revive_falldamage_health;
 566                         pointparticles(particleeffectnum("iceorglass"), frag_target.origin, '0 0 0', 3);
 567                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_FALL, frag_target.netname);
 568                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_FALL);
 569                 }
 570
 571                 frag_damage = 0;
 572                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 573         }
 574         return 1;
 575 }
 576
 577 MUTATOR_HOOKFUNCTION(freezetag_PlayerJump)
 578 {
 579         if(self.freezetag_frozen)
 580                 return TRUE; // no jumping in freezetag when frozen
 581
 582         return FALSE;
 583 }
 584
 585 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 586 {
 587         if (self.freezetag_frozen)
 588                 return 1;
 589         return 0;
 590 }
 591
 592 MUTATOR_HOOKFUNCTION(freezetag_ItemTouch)
 593 {
 594         if (other.freezetag_frozen)
 595                 return MUT_ITEMTOUCH_RETURN;
 596         return MUT_ITEMTOUCH_CONTINUE;
 597 }
 598
 599 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 600 {
 601         if (!self.deadflag)
 602         {
 603                 if (random() < 0.5)
 604                         self.havocbot_role = havocbot_role_ft_freeing;
 605                 else
 606                         self.havocbot_role = havocbot_role_ft_offense;
 607         }
 608
 609         return TRUE;
 610 }
 611
 612 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 613 {
 614         self.freezetag_frozen = other.freezetag_frozen;
 615         self.freezetag_revive_progress = other.freezetag_revive_progress;
 616         return 0;
 617 }
 618
 619 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 620 {
 621         ret_float = freezetag_teams;
 622         return 0;
 623 }
 624
 625 MUTATOR_HOOKFUNCTION(freezetag_VehicleTouch)
 626 {
 627         if(other.freezetag_frozen)
 628                 return TRUE;
 629
 630         return FALSE;
 631 }
 632
 633 void freezetag_Initialize()
 634 {
 635         precache_model("models/ice/ice.md3");
 636
 637         freezetag_teams = autocvar_g_freezetag_teams_override;
 638         if(freezetag_teams < 2)
 639                 freezetag_teams = autocvar_g_freezetag_teams;
 640         freezetag_teams = bound(2, freezetag_teams, 4);
 641         ScoreRules_freezetag(freezetag_teams);
 642
 643         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 644         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 645
 646         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 647         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 648         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 649         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 650
 651         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 652         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 653 }
 654
 655 MUTATOR_DEFINITION(gamemode_freezetag)
 656 {
 657         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 658         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 659         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 660         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 661         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 662         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 663         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 664         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 665         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 666         MUTATOR_HOOK(PlayerJump, freezetag_PlayerJump, CBC_ORDER_ANY);
 667         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 668         MUTATOR_HOOK(ItemTouch, freezetag_ItemTouch, CBC_ORDER_ANY);
 669         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 670         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 671         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 672         MUTATOR_HOOK(VehicleTouch, freezetag_VehicleTouch, CBC_ORDER_ANY);
 673
 674         MUTATOR_ONADD
 675         {
 676                 if(time > 1) // game loads at time 1
 677                         error("This is a game type and it cannot be added at runtime.");
 678                 freezetag_Initialize();
 679         }
 680
 681         MUTATOR_ONROLLBACK_OR_REMOVE
 682         {
 683                 // we actually cannot roll back freezetag_Initialize here
 684                 // BUT: we don't need to! If this gets called, adding always
 685                 // succeeds.
 686         }
 687
 688         MUTATOR_ONREMOVE
 689         {
 690                 print("This is a game type and it cannot be removed at runtime.");
 691                 return -1;
 692         }
 693
 694         return 0;
 695 }