qcsrc/server/mutators/gamemode_ca.qc

   1 float total_players;
   2 float redalive, bluealive, yellowalive, pinkalive;
   3 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
   4 float ca_teams;
   5 float allowed_to_spawn;
   6
   7 void CA_count_alive_players()
   8 {
   9         entity e;
  10         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  11         FOR_EACH_PLAYER(e) {
  12                 if(e.team == NUM_TEAM_1)
  13                 {
  14                         ++total_players;
  15                         if (e.health >= 1) ++redalive;
  16                 }
  17                 else if(e.team == NUM_TEAM_2)
  18                 {
  19                         ++total_players;
  20                         if (e.health >= 1) ++bluealive;
  21                 }
  22                 else if(e.team == NUM_TEAM_3)
  23                 {
  24                         ++total_players;
  25                         if (e.health >= 1) ++yellowalive;
  26                 }
  27                 else if(e.team == NUM_TEAM_4)
  28                 {
  29                         ++total_players;
  30                         if (e.health >= 1) ++pinkalive;
  31                 }
  32         }
  33         FOR_EACH_REALCLIENT(e) {
  34                 e.redalive_stat = redalive;
  35                 e.bluealive_stat = bluealive;
  36                 e.yellowalive_stat = yellowalive;
  37                 e.pinkalive_stat = pinkalive;
  38         }
  39 }
  40
  41 float CA_GetWinnerTeam()
  42 {
  43         float winner_team = 0;
  44         if(redalive >= 1)
  45                 winner_team = NUM_TEAM_1;
  46         if(bluealive >= 1)
  47         {
  48                 if(winner_team) return 0;
  49                 winner_team = NUM_TEAM_2;
  50         }
  51         if(yellowalive >= 1)
  52         {
  53                 if(winner_team) return 0;
  54                 winner_team = NUM_TEAM_3;
  55         }
  56         if(pinkalive >= 1)
  57         {
  58                 if(winner_team) return 0;
  59                 winner_team = NUM_TEAM_4;
  60         }
  61         if(winner_team)
  62                 return winner_team;
  63         return -1; // no player left
  64 }
  65
  66 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  67 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
  68 float CA_CheckWinner()
  69 {
  70         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  71         {
  72                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  73                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  74                 allowed_to_spawn = FALSE;
  75                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  76                 return 1;
  77         }
  78
  79         CA_count_alive_players();
  80         if(CA_ALIVE_TEAMS() > 1)
  81                 return 0;
  82
  83         float winner_team = CA_GetWinnerTeam();
  84         if(winner_team > 0)
  85         {
  86                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
  87                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
  88                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  89         }
  90         else if(winner_team == -1)
  91         {
  92                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
  93                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
  94         }
  95
  96         allowed_to_spawn = FALSE;
  97         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  98         return 1;
  99 }
 100
 101 void CA_RoundStart()
 102 {
 103         if(warmup_stage)
 104                 allowed_to_spawn = TRUE;
 105         else
 106                 allowed_to_spawn = FALSE;
 107 }
 108
 109 float prev_missing_teams_mask;
 110 float CA_CheckTeams()
 111 {
 112         allowed_to_spawn = TRUE;
 113         CA_count_alive_players();
 114         if(CA_ALIVE_TEAMS_OK())
 115         {
 116                 if(prev_missing_teams_mask > 0)
 117                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 118                 prev_missing_teams_mask = -1;
 119                 return 1;
 120         }
 121         if(total_players == 0)
 122         {
 123                 if(prev_missing_teams_mask > 0)
 124                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 125                 prev_missing_teams_mask = -1;
 126                 return 0;
 127         }
 128         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
 129         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 130         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 131         if(prev_missing_teams_mask != missing_teams_mask)
 132         {
 133                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 134                 prev_missing_teams_mask = missing_teams_mask;
 135         }
 136         return 0;
 137 }
 138
 139 MUTATOR_HOOKFUNCTION(ca_PlayerSpawn)
 140 {
 141         self.caplayer = 1;
 142         return 1;
 143 }
 144
 145 MUTATOR_HOOKFUNCTION(ca_PutClientInServer)
 146 {
 147         if(!allowed_to_spawn)
 148         if(IS_PLAYER(self)) // this is true even when player is trying to join
 149         {
 150                 self.classname = "observer";
 151                 if(self.jointime != time) //not when connecting
 152                 if(!self.caplayer)
 153                 {
 154                         self.caplayer = 0.5;
 155                         if(IS_REAL_CLIENT(self))
 156                                 sprint(self, "You will join the game in the next round.\n");
 157                 }
 158         }
 159         return 1;
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(ca_reset_map_players)
 163 {
 164         FOR_EACH_CLIENT(self)
 165         {
 166                 self.killcount = 0;
 167                 if(!self.caplayer && IS_BOT_CLIENT(self))
 168                 {
 169                         self.team = -1;
 170                         self.caplayer = 1;
 171                 }
 172                 if(self.caplayer)
 173                 {
 174                         self.classname = "player";
 175                         self.caplayer = 1;
 176                         PutClientInServer();
 177                 }
 178         }
 179         return 1;
 180 }
 181
 182 MUTATOR_HOOKFUNCTION(ca_ClientConnect)
 183 {
 184         self.classname = "observer";
 185         return 1;
 186 }
 187
 188 MUTATOR_HOOKFUNCTION(ca_reset_map_global)
 189 {
 190         allowed_to_spawn = TRUE;
 191         return 1;
 192 }
 193
 194 MUTATOR_HOOKFUNCTION(ca_GetTeamCount)
 195 {
 196         ret_float = ca_teams;
 197         return 0;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(ca_PlayerDies)
 201 {
 202         if(!allowed_to_spawn)
 203                 self.respawn_flags =  RESPAWN_SILENT;
 204         return 1;
 205 }
 206
 207 MUTATOR_HOOKFUNCTION(ca_ForbidPlayerScore_Clear)
 208 {
 209         return 1;
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(ca_MakePlayerObserver)
 213 {
 214         if(self.killindicator_teamchange == -2)
 215                 self.caplayer = 0;
 216         if(self.caplayer)
 217                 self.frags = FRAGS_LMS_LOSER;
 218         return 1;
 219 }
 220
 221 MUTATOR_HOOKFUNCTION(ca_ForbidThrowCurrentWeapon)
 222 {
 223         return 1;
 224 }
 225
 226 MUTATOR_HOOKFUNCTION(ca_GiveFragsForKill)
 227 {
 228         frag_score = 0; // score will be given to the winner team when the round ends
 229         return 1;
 230 }
 231
 232 MUTATOR_HOOKFUNCTION(ca_SetStartItems)
 233 {
 234         start_items &= ~IT_UNLIMITED_AMMO;
 235         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 236         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 237         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 238         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 239         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 240         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 241         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 242
 243         return 0;
 244 }
 245
 246 MUTATOR_HOOKFUNCTION(ca_PlayerDamage)
 247 {
 248         if(IS_PLAYER(frag_target))
 249         if(frag_target.deadflag == DEAD_NO)
 250         if(frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL)
 251                 frag_damage = 0;
 252
 253         frag_mirrordamage = 0;
 254
 255         return FALSE;
 256 }
 257
 258 MUTATOR_HOOKFUNCTION(ca_FilterItem)
 259 {
 260         if(autocvar_g_powerups <= 0)
 261         if(self.flags & FL_POWERUP)
 262                 return TRUE;
 263
 264         if(autocvar_g_pickup_items <= 0)
 265                 return TRUE;
 266
 267         return FALSE;
 268 }
 269
 270 MUTATOR_HOOKFUNCTION(ca_PlayerDamage_SplitHealthArmor)
 271 {
 272         float excess = max(0, frag_damage - damage_take - damage_save);
 273
 274         if(frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 275                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 276
 277         return FALSE;
 278 }
 279
 280 MUTATOR_HOOKFUNCTION(ca_PlayerRegen)
 281 {
 282         // no regeneration in CA
 283         return TRUE;
 284 }
 285
 286 void ca_Initialize()
 287 {
 288         allowed_to_spawn = TRUE;
 289
 290         ca_teams = autocvar_g_ca_teams_override;
 291         if(ca_teams < 2)
 292                 ca_teams = autocvar_g_ca_teams;
 293         ca_teams = bound(2, ca_teams, 4);
 294         ret_float = ca_teams;
 295         ScoreRules_ca(ca_teams);
 296
 297         round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
 298         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 299
 300         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 301         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 302         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 303         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 304 }
 305
 306 MUTATOR_DEFINITION(gamemode_ca)
 307 {
 308         MUTATOR_HOOK(PlayerSpawn, ca_PlayerSpawn, CBC_ORDER_ANY);
 309         MUTATOR_HOOK(PutClientInServer, ca_PutClientInServer, CBC_ORDER_ANY);
 310         MUTATOR_HOOK(MakePlayerObserver, ca_MakePlayerObserver, CBC_ORDER_ANY);
 311         MUTATOR_HOOK(ClientConnect, ca_ClientConnect, CBC_ORDER_ANY);
 312         MUTATOR_HOOK(reset_map_global, ca_reset_map_global, CBC_ORDER_ANY);
 313         MUTATOR_HOOK(reset_map_players, ca_reset_map_players, CBC_ORDER_ANY);
 314         MUTATOR_HOOK(GetTeamCount, ca_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 315         MUTATOR_HOOK(PlayerDies, ca_PlayerDies, CBC_ORDER_ANY);
 316         MUTATOR_HOOK(ForbidPlayerScore_Clear, ca_ForbidPlayerScore_Clear, CBC_ORDER_ANY);
 317         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ca_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 318         MUTATOR_HOOK(GiveFragsForKill, ca_GiveFragsForKill, CBC_ORDER_FIRST);
 319         MUTATOR_HOOK(SetStartItems, ca_SetStartItems, CBC_ORDER_ANY);
 320         MUTATOR_HOOK(PlayerDamage_Calculate, ca_PlayerDamage, CBC_ORDER_ANY);
 321         MUTATOR_HOOK(FilterItem, ca_FilterItem, CBC_ORDER_ANY);
 322         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ca_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 323         MUTATOR_HOOK(PlayerRegen, ca_PlayerRegen, CBC_ORDER_ANY);
 324
 325         MUTATOR_ONADD
 326         {
 327                 if(time > 1) // game loads at time 1
 328                         error("This is a game type and it cannot be added at runtime.");
 329                 ca_Initialize();
 330         }
 331
 332         MUTATOR_ONREMOVE
 333         {
 334                 print("This is a game type and it cannot be removed at runtime.");
 335                 return -1;
 336         }
 337
 338         return 0;
 339 }