qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = WEP_NAME(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else if (self.items & IT_PLASMA) replacement = "plasma";
 365                         else replacement = "batteries"; // ;)
 366                 } else if (escape == "x") {
 367                         replacement = cursor_ent.netname;
 368                         if (replacement == "" || !cursor_ent)
 369                                 replacement = "nothing";
 370                 } else if (escape == "s")
 371                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 372                 else if (escape == "S")
 373                         replacement = ftos(vlen(self.velocity));
 374
 375                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 376                 p = p + strlen(replacement);
 377         }
 378         return msg;
 379 }
 380
 381 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 382         return (value == 0) ? FALSE : TRUE;
 383 }
 384
 385 /*
 386 =============
 387 GetCvars
 388 =============
 389 Called with:
 390   0:  sends the request
 391   >0: receives a cvar from name=argv(f) value=argv(f+1)
 392 */
 393 void GetCvars_handleString(string thisname, float f, .string field, string name)
 394 {
 395         if (f < 0)
 396         {
 397                 if (self.field)
 398                         strunzone(self.field);
 399                 self.field = string_null;
 400         }
 401         else if (f > 0)
 402         {
 403                 if (thisname == name)
 404                 {
 405                         if (self.field)
 406                                 strunzone(self.field);
 407                         self.field = strzone(argv(f + 1));
 408                 }
 409         }
 410         else
 411                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 412 }
 413 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 414 {
 415         GetCvars_handleString(thisname, f, field, name);
 416         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 417                 if (thisname == name)
 418                 {
 419                         string s;
 420                         s = func(strcat1(self.field));
 421                         if (s != self.field)
 422                         {
 423                                 strunzone(self.field);
 424                                 self.field = strzone(s);
 425                         }
 426                 }
 427 }
 428 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 429 {
 430         if (f < 0)
 431         {
 432         }
 433         else if (f > 0)
 434         {
 435                 if (thisname == name)
 436                         self.field = stof(argv(f + 1));
 437         }
 438         else
 439                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 440 }
 441 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 442 {
 443         if (f < 0)
 444         {
 445         }
 446         else if (f > 0)
 447         {
 448                 if (thisname == name)
 449                 {
 450                         if(!self.field)
 451                         {
 452                                 self.field = stof(argv(f + 1));
 453                                 if(!self.field)
 454                                         self.field = -1;
 455                         }
 456                 }
 457         }
 458         else
 459         {
 460                 if(!self.field)
 461                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462         }
 463 }
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_GameReport_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_plasma;
 567 float g_pickup_plasma_max;
 568 float g_pickup_fuel;
 569 float g_pickup_fuel_jetpack;
 570 float g_pickup_fuel_max;
 571 float g_pickup_armorsmall;
 572 float g_pickup_armorsmall_max;
 573 float g_pickup_armorsmall_anyway;
 574 float g_pickup_armormedium;
 575 float g_pickup_armormedium_max;
 576 float g_pickup_armormedium_anyway;
 577 float g_pickup_armorbig;
 578 float g_pickup_armorbig_max;
 579 float g_pickup_armorbig_anyway;
 580 float g_pickup_armorlarge;
 581 float g_pickup_armorlarge_max;
 582 float g_pickup_armorlarge_anyway;
 583 float g_pickup_healthsmall;
 584 float g_pickup_healthsmall_max;
 585 float g_pickup_healthsmall_anyway;
 586 float g_pickup_healthmedium;
 587 float g_pickup_healthmedium_max;
 588 float g_pickup_healthmedium_anyway;
 589 float g_pickup_healthlarge;
 590 float g_pickup_healthlarge_max;
 591 float g_pickup_healthlarge_anyway;
 592 float g_pickup_healthmega;
 593 float g_pickup_healthmega_max;
 594 float g_pickup_healthmega_anyway;
 595 float g_pickup_ammo_anyway;
 596 float g_pickup_weapons_anyway;
 597 float g_weaponarena;
 598 WepSet g_weaponarena_weapons;
 599 float g_weaponarena_random;
 600 float g_weaponarena_random_with_blaster;
 601 string g_weaponarena_list;
 602 float g_weaponspeedfactor;
 603 float g_weaponratefactor;
 604 float g_weapondamagefactor;
 605 float g_weaponforcefactor;
 606 float g_weaponspreadfactor;
 607
 608 WepSet start_weapons;
 609 WepSet start_weapons_default;
 610 WepSet start_weapons_defaultmask;
 611 float start_items;
 612 float start_ammo_shells;
 613 float start_ammo_nails;
 614 float start_ammo_rockets;
 615 float start_ammo_cells;
 616 float start_ammo_plasma;
 617 float start_ammo_fuel;
 618 float start_health;
 619 float start_armorvalue;
 620 WepSet warmup_start_weapons;
 621 WepSet warmup_start_weapons_default;
 622 WepSet warmup_start_weapons_defaultmask;
 623 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 624 float warmup_start_ammo_shells;
 625 float warmup_start_ammo_nails;
 626 float warmup_start_ammo_rockets;
 627 float warmup_start_ammo_cells;
 628 float warmup_start_ammo_plasma;
 629 float warmup_start_ammo_fuel;
 630 float warmup_start_health;
 631 float warmup_start_armorvalue;
 632 float g_weapon_stay;
 633
 634 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 635 {
 636         var float i = weaponinfo.weapon;
 637         var float d = 0;
 638
 639         if (!i)
 640                 return 0;
 641
 642         if (g_lms || g_ca || allguns)
 643         {
 644                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 645                         d = TRUE;
 646                 else
 647                         d = FALSE;
 648         }
 649         else if (g_cts)
 650                 d = (i == WEP_SHOTGUN);
 651         else if (g_nexball)
 652                 d = 0; // weapon is set a few lines later
 653         else
 654                 d = !(!weaponinfo.weaponstart);
 655
 656         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 657                 d |= (i == WEP_HOOK);
 658         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 659                 d = 0;
 660
 661         var float t = weaponinfo.weaponstartoverride;
 662
 663         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 664
 665         // bit order in t:
 666         // 1: want or not
 667         // 2: is default?
 668         // 4: is set by default?
 669         if(t < 0)
 670                 t = 4 | (3 * d);
 671         else
 672                 t |= (2 * d);
 673
 674         return t;
 675 }
 676
 677 void readplayerstartcvars()
 678 {
 679         entity e;
 680         float i, j, t;
 681         string s;
 682
 683         // initialize starting values for players
 684         start_weapons = '0 0 0';
 685         start_weapons_default = '0 0 0';
 686         start_weapons_defaultmask = '0 0 0';
 687         start_items = 0;
 688         start_ammo_shells = 0;
 689         start_ammo_nails = 0;
 690         start_ammo_rockets = 0;
 691         start_ammo_cells = 0;
 692         start_ammo_plasma = 0;
 693         start_health = cvar("g_balance_health_start");
 694         start_armorvalue = cvar("g_balance_armor_start");
 695
 696         g_weaponarena = 0;
 697         g_weaponarena_weapons = '0 0 0';
 698
 699         s = cvar_string("g_weaponarena");
 700         if (s == "0" || s == "")
 701         {
 702                 if(g_ca)
 703                         s = "most";
 704         }
 705
 706         if (s == "0" || s == "")
 707         {
 708                 // no arena
 709         }
 710         else if (s == "off")
 711         {
 712                 // forcibly turn off weaponarena
 713         }
 714         else if (s == "all" || s == "1")
 715         {
 716                 g_weaponarena = 1;
 717                 g_weaponarena_list = "All Weapons";
 718                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 719                 {
 720                         e = get_weaponinfo(j);
 721                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 722                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 723                 }
 724         }
 725         else if (s == "most")
 726         {
 727                 g_weaponarena = 1;
 728                 g_weaponarena_list = "Most Weapons";
 729                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 730                 {
 731                         e = get_weaponinfo(j);
 732                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 733                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 734                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 735                 }
 736         }
 737         else if (s == "none")
 738         {
 739                 g_weaponarena = 1;
 740                 g_weaponarena_list = "No Weapons";
 741         }
 742         else
 743         {
 744                 g_weaponarena = 1;
 745                 t = tokenize_console(s);
 746                 g_weaponarena_list = "";
 747                 for (i = 0; i < t; ++i)
 748                 {
 749                         s = argv(i);
 750                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 751                         {
 752                                 e = get_weaponinfo(j);
 753                                 if (e.netname == s)
 754                                 {
 755                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 756                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 757                                         break;
 758                                 }
 759                         }
 760                         if (j > WEP_LAST)
 761                         {
 762                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 763                         }
 764                 }
 765                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 766         }
 767
 768         if(g_weaponarena)
 769                 g_weaponarena_random = cvar("g_weaponarena_random");
 770         else
 771                 g_weaponarena_random = 0;
 772         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 773
 774         if (g_weaponarena)
 775         {
 776                 g_weapon_stay = 0; // incompatible
 777                 start_weapons = g_weaponarena_weapons;
 778                 start_items |= IT_UNLIMITED_AMMO;
 779         }
 780         else
 781         {
 782                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 783                 {
 784                         e = get_weaponinfo(i);
 785                         float w = want_weapon(e, FALSE);
 786                         if(w & 1)
 787                                 start_weapons |= WepSet_FromWeapon(i);
 788                         if(w & 2)
 789                                 start_weapons_default |= WepSet_FromWeapon(i);
 790                         if(w & 4)
 791                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 792                 }
 793         }
 794
 795         if(!cvar("g_use_ammunition"))
 796                 start_items |= IT_UNLIMITED_AMMO;
 797
 798         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 799         {
 800                 start_ammo_rockets = 999;
 801                 start_ammo_shells = 999;
 802                 start_ammo_cells = 999;
 803                 start_ammo_plasma = 999;
 804                 start_ammo_nails = 999;
 805                 start_ammo_fuel = 999;
 806         }
 807         else
 808         {
 809                 start_ammo_shells = cvar("g_start_ammo_shells");
 810                 start_ammo_nails = cvar("g_start_ammo_nails");
 811                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 812                 start_ammo_cells = cvar("g_start_ammo_cells");
 813                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 814                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 815         }
 816
 817         if (warmup_stage)
 818         {
 819                 warmup_start_ammo_shells = start_ammo_shells;
 820                 warmup_start_ammo_nails = start_ammo_nails;
 821                 warmup_start_ammo_rockets = start_ammo_rockets;
 822                 warmup_start_ammo_cells = start_ammo_cells;
 823                 warmup_start_ammo_fuel = start_ammo_fuel;
 824                 warmup_start_health = start_health;
 825                 warmup_start_armorvalue = start_armorvalue;
 826                 warmup_start_weapons = start_weapons;
 827                 warmup_start_weapons_default = start_weapons_default;
 828                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 829
 830                 if (!g_weaponarena && !g_ca)
 831                 {
 832                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 833                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 834                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 835                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 836                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 837                         warmup_start_health = cvar("g_warmup_start_health");
 838                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 839                         warmup_start_weapons = '0 0 0';
 840                         warmup_start_weapons_default = '0 0 0';
 841                         warmup_start_weapons_defaultmask = '0 0 0';
 842                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 843                         {
 844                                 e = get_weaponinfo(i);
 845                                 float w = want_weapon(e, g_warmup_allguns);
 846                                 if(w & 1)
 847                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 848                                 if(w & 2)
 849                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 850                                 if(w & 4)
 851                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 852                         }
 853                 }
 854         }
 855
 856         if (g_jetpack)
 857                 start_items |= IT_JETPACK;
 858
 859         MUTATOR_CALLHOOK(SetStartItems);
 860
 861         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 862         {
 863                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 864                 start_items |= IT_FUEL_REGEN;
 865                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 866                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 867         }
 868
 869         WepSet precache_weapons = start_weapons;
 870         if (g_warmup_allguns != 1)
 871                 precache_weapons |= warmup_start_weapons;
 872         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 873         {
 874                 e = get_weaponinfo(i);
 875                 if(precache_weapons & WepSet_FromWeapon(i))
 876                         WEP_ACTION(i, WR_INIT);
 877         }
 878
 879         start_ammo_shells = max(0, start_ammo_shells);
 880         start_ammo_nails = max(0, start_ammo_nails);
 881         start_ammo_cells = max(0, start_ammo_cells);
 882         start_ammo_plasma = max(0, start_ammo_plasma);
 883         start_ammo_rockets = max(0, start_ammo_rockets);
 884         start_ammo_fuel = max(0, start_ammo_fuel);
 885
 886         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 887         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 888         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 889         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 890         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 891         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 892 }
 893
 894 float g_bugrigs;
 895 float g_bugrigs_planar_movement;
 896 float g_bugrigs_planar_movement_car_jumping;
 897 float g_bugrigs_reverse_spinning;
 898 float g_bugrigs_reverse_speeding;
 899 float g_bugrigs_reverse_stopping;
 900 float g_bugrigs_air_steering;
 901 float g_bugrigs_angle_smoothing;
 902 float g_bugrigs_friction_floor;
 903 float g_bugrigs_friction_brake;
 904 float g_bugrigs_friction_air;
 905 float g_bugrigs_accel;
 906 float g_bugrigs_speed_ref;
 907 float g_bugrigs_speed_pow;
 908 float g_bugrigs_steer;
 909
 910 float sv_autotaunt;
 911 float sv_taunt;
 912
 913 string GetGametype(); // g_world.qc
 914 void mutators_add(); // mutators.qc
 915 void readlevelcvars(void)
 916 {
 917         // load mutators
 918         mutators_add();
 919
 920         if(cvar("sv_allow_fullbright"))
 921                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 922
 923     g_bugrigs = cvar("g_bugrigs");
 924     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 925     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 926     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 927     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 928     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 929     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 930     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 931     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 932     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 933     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 934     g_bugrigs_accel = cvar("g_bugrigs_accel");
 935     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 936     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 937     g_bugrigs_steer = cvar("g_bugrigs_steer");
 938
 939         g_instagib = cvar("g_instagib");
 940
 941         sv_clones = cvar("sv_clones");
 942         sv_foginterval = cvar("sv_foginterval");
 943         g_cloaked = cvar("g_cloaked");
 944         g_footsteps = cvar("g_footsteps");
 945         g_grappling_hook = cvar("g_grappling_hook");
 946         g_jetpack = cvar("g_jetpack");
 947         sv_maxidle = cvar("sv_maxidle");
 948         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 949         sv_autotaunt = cvar("sv_autotaunt");
 950         sv_taunt = cvar("sv_taunt");
 951
 952         warmup_stage = cvar("g_warmup");
 953         g_warmup_limit = cvar("g_warmup_limit");
 954         g_warmup_allguns = cvar("g_warmup_allguns");
 955         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 956
 957         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 958                 warmup_stage = 0; // these modes cannot work together, sorry
 959
 960         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 961         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 962         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 963         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 964         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 965         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 966         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 967         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 968         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 969         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 970         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 971         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 972         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 973         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 974
 975         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 976         g_weaponratefactor = cvar("g_weaponratefactor");
 977         g_weapondamagefactor = cvar("g_weapondamagefactor");
 978         g_weaponforcefactor = cvar("g_weaponforcefactor");
 979         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 980
 981         g_pickup_shells = cvar("g_pickup_shells");
 982         g_pickup_shells_max = cvar("g_pickup_shells_max");
 983         g_pickup_nails = cvar("g_pickup_nails");
 984         g_pickup_nails_max = cvar("g_pickup_nails_max");
 985         g_pickup_rockets = cvar("g_pickup_rockets");
 986         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 987         g_pickup_cells = cvar("g_pickup_cells");
 988         g_pickup_cells_max = cvar("g_pickup_cells_max");
 989         g_pickup_plasma = cvar("g_pickup_plasma");
 990         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
 991         g_pickup_fuel = cvar("g_pickup_fuel");
 992         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 993         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 994         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 995         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 996         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 997         g_pickup_armormedium = cvar("g_pickup_armormedium");
 998         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
 999         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1000         g_pickup_armorbig = cvar("g_pickup_armorbig");
1001         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1002         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1003         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1004         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1005         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1006         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1007         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1008         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1009         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1010         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1011         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1012         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1013         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1014         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1015         g_pickup_healthmega = cvar("g_pickup_healthmega");
1016         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1017         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1018
1019         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1020         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1021
1022     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1023     if(!g_weapon_stay)
1024         g_weapon_stay = cvar("g_weapon_stay");
1025
1026         if (!warmup_stage)
1027                 game_starttime = time + cvar("g_start_delay");
1028
1029         readplayerstartcvars();
1030 }
1031
1032 //#NO AUTOCVARS END
1033
1034 // Sound functions
1035 string precache_sound (string s) = #19;
1036 float precache_sound_index (string s) = #19;
1037
1038 #define SND_VOLUME      1
1039 #define SND_ATTENUATION 2
1040 #define SND_LARGEENTITY 8
1041 #define SND_LARGESOUND  16
1042
1043 float sound_allowed(float dest, entity e)
1044 {
1045     // sounds from world may always pass
1046     for (;;)
1047     {
1048         if (e.classname == "body")
1049             e = e.enemy;
1050         else if (e.realowner && e.realowner != e)
1051             e = e.realowner;
1052         else if (e.owner && e.owner != e)
1053             e = e.owner;
1054         else
1055             break;
1056     }
1057     // sounds to self may always pass
1058     if (dest == MSG_ONE)
1059         if (e == msg_entity)
1060             return TRUE;
1061     // sounds by players can be removed
1062     if (autocvar_bot_sound_monopoly)
1063         if (IS_REAL_CLIENT(e))
1064             return FALSE;
1065     // anything else may pass
1066     return TRUE;
1067 }
1068
1069 #undef sound
1070 void sound(entity e, float chan, string samp, float vol, float atten)
1071 {
1072     if (!sound_allowed(MSG_BROADCAST, e))
1073         return;
1074     sound7(e, chan, samp, vol, atten, 0, 0);
1075 }
1076
1077 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1078 {
1079     float entno, idx;
1080
1081     if (!sound_allowed(dest, e))
1082         return;
1083
1084     entno = num_for_edict(e);
1085     idx = precache_sound_index(samp);
1086
1087     float sflags;
1088     sflags = 0;
1089
1090     atten = floor(atten * 64);
1091     vol = floor(vol * 255);
1092
1093     if (vol != 255)
1094         sflags |= SND_VOLUME;
1095     if (atten != 64)
1096         sflags |= SND_ATTENUATION;
1097     if (entno >= 8192 || chan < 0 || chan > 7)
1098         sflags |= SND_LARGEENTITY;
1099     if (idx >= 256)
1100         sflags |= SND_LARGESOUND;
1101
1102     WriteByte(dest, SVC_SOUND);
1103     WriteByte(dest, sflags);
1104     if (sflags & SND_VOLUME)
1105         WriteByte(dest, vol);
1106     if (sflags & SND_ATTENUATION)
1107         WriteByte(dest, atten);
1108     if (sflags & SND_LARGEENTITY)
1109     {
1110         WriteShort(dest, entno);
1111         WriteByte(dest, chan);
1112     }
1113     else
1114     {
1115         WriteShort(dest, entno * 8 + chan);
1116     }
1117     if (sflags & SND_LARGESOUND)
1118         WriteShort(dest, idx);
1119     else
1120         WriteByte(dest, idx);
1121
1122     WriteCoord(dest, o_x);
1123     WriteCoord(dest, o_y);
1124     WriteCoord(dest, o_z);
1125 }
1126 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1127 {
1128     vector o;
1129
1130     if (!sound_allowed(dest, e))
1131         return;
1132
1133     o = e.origin + 0.5 * (e.mins + e.maxs);
1134     soundtoat(dest, e, o, chan, samp, vol, atten);
1135 }
1136 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1137 {
1138     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1139 }
1140 void stopsoundto(float dest, entity e, float chan)
1141 {
1142     float entno;
1143
1144     if (!sound_allowed(dest, e))
1145         return;
1146
1147     entno = num_for_edict(e);
1148
1149     if (entno >= 8192 || chan < 0 || chan > 7)
1150     {
1151         float idx, sflags;
1152         idx = precache_sound_index("misc/null.wav");
1153         sflags = SND_LARGEENTITY;
1154         if (idx >= 256)
1155             sflags |= SND_LARGESOUND;
1156         WriteByte(dest, SVC_SOUND);
1157         WriteByte(dest, sflags);
1158         WriteShort(dest, entno);
1159         WriteByte(dest, chan);
1160         if (sflags & SND_LARGESOUND)
1161             WriteShort(dest, idx);
1162         else
1163             WriteByte(dest, idx);
1164         WriteCoord(dest, e.origin_x);
1165         WriteCoord(dest, e.origin_y);
1166         WriteCoord(dest, e.origin_z);
1167     }
1168     else
1169     {
1170         WriteByte(dest, SVC_STOPSOUND);
1171         WriteShort(dest, entno * 8 + chan);
1172     }
1173 }
1174 void stopsound(entity e, float chan)
1175 {
1176     if (!sound_allowed(MSG_BROADCAST, e))
1177         return;
1178
1179     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1180     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1181 }
1182
1183 void play2(entity e, string filename)
1184 {
1185     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1186     msg_entity = e;
1187     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1188 }
1189
1190 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1191 .float spamtime;
1192 float spamsound(entity e, float chan, string samp, float vol, float atten)
1193 {
1194     if (!sound_allowed(MSG_BROADCAST, e))
1195         return FALSE;
1196
1197     if (time > e.spamtime)
1198     {
1199         e.spamtime = time;
1200         sound(e, chan, samp, vol, atten);
1201         return TRUE;
1202     }
1203     return FALSE;
1204 }
1205
1206 void play2team(float t, string filename)
1207 {
1208     entity head;
1209
1210     if (autocvar_bot_sound_monopoly)
1211         return;
1212
1213     FOR_EACH_REALPLAYER(head)
1214     {
1215         if (head.team == t)
1216             play2(head, filename);
1217     }
1218 }
1219
1220 void play2all(string samp)
1221 {
1222     if (autocvar_bot_sound_monopoly)
1223         return;
1224
1225     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1226 }
1227
1228 void PrecachePlayerSounds(string f);
1229 void precache_playermodel(string m)
1230 {
1231         float globhandle, i, n;
1232         string f;
1233
1234         if(substring(m, -9,5) == "_lod1")
1235                 return;
1236         if(substring(m, -9,5) == "_lod2")
1237                 return;
1238         precache_model(m);
1239         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1240         if(fexists(f))
1241                 precache_model(f);
1242         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1243         if(fexists(f))
1244                 precache_model(f);
1245
1246         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1247         if (globhandle < 0)
1248                 return;
1249         n = search_getsize(globhandle);
1250         for (i = 0; i < n; ++i)
1251         {
1252                 //print(search_getfilename(globhandle, i), "\n");
1253                 f = search_getfilename(globhandle, i);
1254                 PrecachePlayerSounds(f);
1255         }
1256         search_end(globhandle);
1257 }
1258 void precache_all_playermodels(string pattern)
1259 {
1260         float globhandle, i, n;
1261         string f;
1262
1263         globhandle = search_begin(pattern, TRUE, FALSE);
1264         if (globhandle < 0)
1265                 return;
1266         n = search_getsize(globhandle);
1267         for (i = 0; i < n; ++i)
1268         {
1269                 //print(search_getfilename(globhandle, i), "\n");
1270                 f = search_getfilename(globhandle, i);
1271                 precache_playermodel(f);
1272         }
1273         search_end(globhandle);
1274 }
1275
1276 void precache()
1277 {
1278     // gamemode related things
1279     precache_model ("models/misc/chatbubble.spr");
1280         precache_model("models/ice/ice.md3");
1281
1282 #ifdef TTURRETS_ENABLED
1283     if (autocvar_g_turrets)
1284         turrets_precash();
1285 #endif
1286
1287     // Precache all player models if desired
1288     if (autocvar_sv_precacheplayermodels)
1289     {
1290         PrecachePlayerSounds("sound/player/default.sounds");
1291         precache_all_playermodels("models/player/*.zym");
1292         precache_all_playermodels("models/player/*.dpm");
1293         precache_all_playermodels("models/player/*.md3");
1294         precache_all_playermodels("models/player/*.psk");
1295         precache_all_playermodels("models/player/*.iqm");
1296     }
1297
1298     if (autocvar_sv_defaultcharacter)
1299     {
1300         string s;
1301         s = autocvar_sv_defaultplayermodel_red;
1302         if (s != "")
1303             precache_playermodel(s);
1304         s = autocvar_sv_defaultplayermodel_blue;
1305         if (s != "")
1306             precache_playermodel(s);
1307         s = autocvar_sv_defaultplayermodel_yellow;
1308         if (s != "")
1309             precache_playermodel(s);
1310         s = autocvar_sv_defaultplayermodel_pink;
1311         if (s != "")
1312             precache_playermodel(s);
1313         s = autocvar_sv_defaultplayermodel;
1314         if (s != "")
1315             precache_playermodel(s);
1316     }
1317
1318     if (g_footsteps)
1319     {
1320         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1321         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1322     }
1323
1324     // gore and miscellaneous sounds
1325     //precache_sound ("misc/h2ohit.wav");
1326     precache_model ("models/hook.md3");
1327     precache_sound ("misc/armorimpact.wav");
1328     precache_sound ("misc/bodyimpact1.wav");
1329     precache_sound ("misc/bodyimpact2.wav");
1330     precache_sound ("misc/gib.wav");
1331     precache_sound ("misc/gib_splat01.wav");
1332     precache_sound ("misc/gib_splat02.wav");
1333     precache_sound ("misc/gib_splat03.wav");
1334     precache_sound ("misc/gib_splat04.wav");
1335     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1336     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1337     precache_sound ("misc/null.wav");
1338     precache_sound ("misc/spawn.wav");
1339     precache_sound ("misc/talk.wav");
1340     precache_sound ("misc/teleport.wav");
1341     precache_sound ("misc/poweroff.wav");
1342     precache_sound ("player/lava.wav");
1343     precache_sound ("player/slime.wav");
1344
1345     precache_model ("models/sprites/0.spr32");
1346     precache_model ("models/sprites/1.spr32");
1347     precache_model ("models/sprites/2.spr32");
1348     precache_model ("models/sprites/3.spr32");
1349     precache_model ("models/sprites/4.spr32");
1350     precache_model ("models/sprites/5.spr32");
1351     precache_model ("models/sprites/6.spr32");
1352     precache_model ("models/sprites/7.spr32");
1353     precache_model ("models/sprites/8.spr32");
1354     precache_model ("models/sprites/9.spr32");
1355     precache_model ("models/sprites/10.spr32");
1356
1357     // common weapon precaches
1358         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1359     precache_sound ("weapons/weapon_switch.wav");
1360     precache_sound ("weapons/weaponpickup.wav");
1361     precache_sound ("weapons/unavailable.wav");
1362     precache_sound ("weapons/dryfire.wav");
1363     if (g_grappling_hook)
1364     {
1365         precache_sound ("weapons/hook_fire.wav"); // hook
1366         precache_sound ("weapons/hook_impact.wav"); // hook
1367     }
1368
1369     precache_model("models/elaser.mdl");
1370     precache_model("models/laser.mdl");
1371     precache_model("models/ebomb.mdl");
1372
1373 #if 0
1374     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1375
1376     if (!self.noise && self.music) // quake 3 uses the music field
1377         self.noise = self.music;
1378
1379     // plays music for the level if there is any
1380     if (self.noise)
1381     {
1382         precache_sound (self.noise);
1383         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1384     }
1385 #endif
1386
1387 #include "precache-for-csqc.inc"
1388 }
1389
1390 // WARNING: this kills the trace globals
1391 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1392 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1393
1394 #define INITPRIO_FIRST              0
1395 #define INITPRIO_GAMETYPE           0
1396 #define INITPRIO_GAMETYPE_FALLBACK  1
1397 #define INITPRIO_FINDTARGET        10
1398 #define INITPRIO_DROPTOFLOOR       20
1399 #define INITPRIO_SETLOCATION       90
1400 #define INITPRIO_LINKDOORS         91
1401 #define INITPRIO_LAST              99
1402
1403 .void(void) initialize_entity;
1404 .float initialize_entity_order;
1405 .entity initialize_entity_next;
1406 entity initialize_entity_first;
1407
1408 void make_safe_for_remove(entity e)
1409 {
1410     if (e.initialize_entity)
1411     {
1412         entity ent, prev = world;
1413         for (ent = initialize_entity_first; ent; )
1414         {
1415             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1416             {
1417                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1418                 // skip it in linked list
1419                 if (prev)
1420                 {
1421                     prev.initialize_entity_next = ent.initialize_entity_next;
1422                     ent = prev.initialize_entity_next;
1423                 }
1424                 else
1425                 {
1426                     initialize_entity_first = ent.initialize_entity_next;
1427                     ent = initialize_entity_first;
1428                 }
1429             }
1430             else
1431             {
1432                 prev = ent;
1433                 ent = ent.initialize_entity_next;
1434             }
1435         }
1436     }
1437 }
1438
1439 void objerror(string s)
1440 {
1441     make_safe_for_remove(self);
1442     builtin_objerror(s);
1443 }
1444
1445 .float remove_except_protected_forbidden;
1446 void remove_except_protected(entity e)
1447 {
1448         if(e.remove_except_protected_forbidden)
1449                 error("not allowed to remove this at this point");
1450         builtin_remove(e);
1451 }
1452
1453 void remove_unsafely(entity e)
1454 {
1455     if(e.classname == "spike")
1456         error("Removing spikes is forbidden (crylink bug), please report");
1457     builtin_remove(e);
1458 }
1459
1460 void remove_safely(entity e)
1461 {
1462     make_safe_for_remove(e);
1463     builtin_remove(e);
1464 }
1465
1466 void InitializeEntity(entity e, void(void) func, float order)
1467 {
1468     entity prev, cur;
1469
1470     if (!e || e.initialize_entity)
1471     {
1472         // make a proxy initializer entity
1473         entity e_old;
1474         e_old = e;
1475         e = spawn();
1476         e.classname = "initialize_entity";
1477         e.enemy = e_old;
1478     }
1479
1480     e.initialize_entity = func;
1481     e.initialize_entity_order = order;
1482
1483     cur = initialize_entity_first;
1484     prev = world;
1485     for (;;)
1486     {
1487         if (!cur || cur.initialize_entity_order > order)
1488         {
1489             // insert between prev and cur
1490             if (prev)
1491                 prev.initialize_entity_next = e;
1492             else
1493                 initialize_entity_first = e;
1494             e.initialize_entity_next = cur;
1495             return;
1496         }
1497         prev = cur;
1498         cur = cur.initialize_entity_next;
1499     }
1500 }
1501 void InitializeEntitiesRun()
1502 {
1503     entity startoflist;
1504     startoflist = initialize_entity_first;
1505     initialize_entity_first = world;
1506     remove = remove_except_protected;
1507     for (self = startoflist; self; self = self.initialize_entity_next)
1508     {
1509         self.remove_except_protected_forbidden = 1;
1510     }
1511     for (self = startoflist; self; )
1512     {
1513         entity e;
1514         var void(void) func;
1515         e = self.initialize_entity_next;
1516         func = self.initialize_entity;
1517         self.initialize_entity_order = 0;
1518         self.initialize_entity = func_null;
1519         self.initialize_entity_next = world;
1520         self.remove_except_protected_forbidden = 0;
1521         if (self.classname == "initialize_entity")
1522         {
1523             entity e_old;
1524             e_old = self.enemy;
1525             builtin_remove(self);
1526             self = e_old;
1527         }
1528         //dprint("Delayed initialization: ", self.classname, "\n");
1529         if(func)
1530             func();
1531         else
1532         {
1533             eprint(self);
1534             backtrace(strcat("Null function in: ", self.classname, "\n"));
1535         }
1536         self = e;
1537     }
1538     remove = remove_unsafely;
1539 }
1540
1541 .float uncustomizeentityforclient_set;
1542 .void(void) uncustomizeentityforclient;
1543 void UncustomizeEntitiesRun()
1544 {
1545     entity oldself;
1546     oldself = self;
1547     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1548         self.uncustomizeentityforclient();
1549     self = oldself;
1550 }
1551 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1552 {
1553     e.customizeentityforclient = customizer;
1554     e.uncustomizeentityforclient = uncustomizer;
1555     e.uncustomizeentityforclient_set = !!uncustomizer;
1556 }
1557
1558 .float nottargeted;
1559 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1560
1561 void() SUB_Remove;
1562 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1563 {
1564     vector mi, ma;
1565
1566     if (e.classname == "")
1567         e.classname = "net_linked";
1568
1569     if (e.model == "" || self.modelindex == 0)
1570     {
1571         mi = e.mins;
1572         ma = e.maxs;
1573         setmodel(e, "null");
1574         setsize(e, mi, ma);
1575     }
1576
1577     e.SendEntity = sendfunc;
1578     e.SendFlags = 0xFFFFFF;
1579
1580     if (!docull)
1581         e.effects |= EF_NODEPTHTEST;
1582
1583     if (dt)
1584     {
1585         e.nextthink = time + dt;
1586         e.think = SUB_Remove;
1587     }
1588 }
1589
1590
1591 entity eliminatedPlayers;
1592 .float(entity) isEliminated;
1593 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1594 {
1595         float i, f, b;
1596         entity e;
1597         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1598         WriteByte(MSG_ENTITY, sendflags);
1599
1600         if(sendflags & 1)
1601         {
1602                 for(i = 1; i <= maxclients; i += 8)
1603                 {
1604                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1605                         {
1606                                 if(eliminatedPlayers.isEliminated(e))
1607                                         f |= b;
1608                         }
1609                         WriteByte(MSG_ENTITY, f);
1610                 }
1611         }
1612
1613         return TRUE;
1614 }
1615
1616 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1617 {
1618         if(eliminatedPlayers)
1619         {
1620                 backtrace("Can't spawn eliminatedPlayers again!");
1621                 return;
1622         }
1623         Net_LinkEntity(eliminatedPlayers = spawn(), FALSE, 0, EliminatedPlayers_SendEntity);
1624         eliminatedPlayers.isEliminated = isEliminated_func;
1625 }
1626
1627
1628 void adaptor_think2touch()
1629 {
1630     entity o;
1631     o = other;
1632     other = world;
1633     self.touch();
1634     other = o;
1635 }
1636
1637 void adaptor_think2use()
1638 {
1639     entity o, a;
1640     o = other;
1641     a = activator;
1642     activator = world;
1643     other = world;
1644     self.use();
1645     other = o;
1646     activator = a;
1647 }
1648
1649 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1650 {
1651         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1652                 self.projectiledeathtype |= HITTYPE_SPLASH;
1653         adaptor_think2use();
1654 }
1655
1656 // deferred dropping
1657 void DropToFloor_Handler()
1658 {
1659     builtin_droptofloor();
1660     self.dropped_origin = self.origin;
1661 }
1662
1663 void droptofloor()
1664 {
1665     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1666 }
1667
1668
1669
1670 float trace_hits_box_a0, trace_hits_box_a1;
1671
1672 float trace_hits_box_1d(float end, float thmi, float thma)
1673 {
1674     if (end == 0)
1675     {
1676         // just check if x is in range
1677         if (0 < thmi)
1678             return FALSE;
1679         if (0 > thma)
1680             return FALSE;
1681     }
1682     else
1683     {
1684         // do the trace with respect to x
1685         // 0 -> end has to stay in thmi -> thma
1686         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1687         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1688         if (trace_hits_box_a0 > trace_hits_box_a1)
1689             return FALSE;
1690     }
1691     return TRUE;
1692 }
1693
1694 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1695 {
1696     end -= start;
1697     thmi -= start;
1698     thma -= start;
1699     // now it is a trace from 0 to end
1700
1701     trace_hits_box_a0 = 0;
1702     trace_hits_box_a1 = 1;
1703
1704     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1705         return FALSE;
1706     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1707         return FALSE;
1708     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1709         return FALSE;
1710
1711     return TRUE;
1712 }
1713
1714 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1715 {
1716     return trace_hits_box(start, end, thmi - ma, thma - mi);
1717 }
1718
1719 float SUB_NoImpactCheck()
1720 {
1721         // zero hitcontents = this is not the real impact, but either the
1722         // mirror-impact of something hitting the projectile instead of the
1723         // projectile hitting the something, or a touchareagrid one. Neither of
1724         // these stop the projectile from moving, so...
1725         if(trace_dphitcontents == 0)
1726         {
1727                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1728                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1729                 checkclient();
1730         }
1731     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1732         return 1;
1733     if (other == world && self.size != '0 0 0')
1734     {
1735         vector tic;
1736         tic = self.velocity * sys_frametime;
1737         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1738         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1739         if (trace_fraction >= 1)
1740         {
1741             dprint("Odd... did not hit...?\n");
1742         }
1743         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1744         {
1745             dprint("Detected and prevented the sky-grapple bug.\n");
1746             return 1;
1747         }
1748     }
1749
1750     return 0;
1751 }
1752
1753 #define SUB_OwnerCheck() (other && (other == self.owner))
1754
1755 void RemoveGrapplingHook(entity pl);
1756 void W_Crylink_Dequeue(entity e);
1757 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1758 {
1759         if(SUB_OwnerCheck())
1760                 return TRUE;
1761         if(SUB_NoImpactCheck())
1762         {
1763                 if(self.classname == "grapplinghook")
1764                         RemoveGrapplingHook(self.realowner);
1765                 else if(self.classname == "spike")
1766                 {
1767                         W_Crylink_Dequeue(self);
1768                         remove(self);
1769                 }
1770                 else
1771                         remove(self);
1772                 return TRUE;
1773         }
1774         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1775                 UpdateCSQCProjectile(self);
1776         return FALSE;
1777 }
1778 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1779
1780 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1781 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1782
1783 void URI_Get_Callback(float id, float status, string data)
1784 {
1785         if(url_URI_Get_Callback(id, status, data))
1786         {
1787                 // handled
1788         }
1789         else if (id == URI_GET_DISCARD)
1790         {
1791                 // discard
1792         }
1793         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1794         {
1795                 // sv_cmd curl
1796                 Curl_URI_Get_Callback(id, status, data);
1797         }
1798         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1799         {
1800                 // online ban list
1801                 OnlineBanList_URI_Get_Callback(id, status, data);
1802         }
1803         else
1804         {
1805                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1806         }
1807 }
1808
1809 string uid2name(string myuid) {
1810         string s;
1811         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1812
1813         // FIXME remove this later after 0.6 release
1814         // convert old style broken records to correct style
1815         if(s == "")
1816         {
1817                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1818                 if(s != "")
1819                 {
1820                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1821                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1822                 }
1823         }
1824
1825         if(s == "")
1826                 s = "^1Unregistered Player";
1827         return s;
1828 }
1829
1830 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1831 {
1832     float m, i;
1833     vector start, org, delta, end, enddown, mstart;
1834     entity sp;
1835
1836     m = e.dphitcontentsmask;
1837     e.dphitcontentsmask = goodcontents | badcontents;
1838
1839     org = world.mins;
1840     delta = world.maxs - world.mins;
1841
1842     start = end = org;
1843
1844     for (i = 0; i < attempts; ++i)
1845     {
1846         start_x = org_x + random() * delta_x;
1847         start_y = org_y + random() * delta_y;
1848         start_z = org_z + random() * delta_z;
1849
1850         // rule 1: start inside world bounds, and outside
1851         // solid, and don't start from somewhere where you can
1852         // fall down to evil
1853         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1854         if (trace_fraction >= 1)
1855             continue;
1856         if (trace_startsolid)
1857             continue;
1858         if (trace_dphitcontents & badcontents)
1859             continue;
1860         if (trace_dphitq3surfaceflags & badsurfaceflags)
1861             continue;
1862
1863         // rule 2: if we are too high, lower the point
1864         if (trace_fraction * delta_z > maxaboveground)
1865             start = trace_endpos + '0 0 1' * maxaboveground;
1866         enddown = trace_endpos;
1867
1868         // rule 3: make sure we aren't outside the map. This only works
1869         // for somewhat well formed maps. A good rule of thumb is that
1870         // the map should have a convex outside hull.
1871         // these can be traceLINES as we already verified the starting box
1872         mstart = start + 0.5 * (e.mins + e.maxs);
1873         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1874         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1875             continue;
1876         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1877         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1878             continue;
1879         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1880         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1881             continue;
1882         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1883         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1884             continue;
1885         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1886         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1887             continue;
1888
1889         // rule 4: we must "see" some spawnpoint or item
1890         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1891                 if(checkpvs(mstart, sp))
1892                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1893                                 break;
1894         if(!sp)
1895         {
1896                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1897                         if(checkpvs(mstart, sp))
1898                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1899                                         break;
1900                 if(!sp)
1901                         continue;
1902         }
1903
1904         // find a random vector to "look at"
1905         end_x = org_x + random() * delta_x;
1906         end_y = org_y + random() * delta_y;
1907         end_z = org_z + random() * delta_z;
1908         end = start + normalize(end - start) * vlen(delta);
1909
1910         // rule 4: start TO end must not be too short
1911         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1912         if (trace_startsolid)
1913             continue;
1914         if (trace_fraction < minviewdistance / vlen(delta))
1915             continue;
1916
1917         // rule 5: don't want to look at sky
1918         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1919             continue;
1920
1921         // rule 6: we must not end up in trigger_hurt
1922         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1923             continue;
1924
1925         break;
1926     }
1927
1928     e.dphitcontentsmask = m;
1929
1930     if (i < attempts)
1931     {
1932         setorigin(e, start);
1933         e.angles = vectoangles(end - start);
1934         dprint("Needed ", ftos(i + 1), " attempts\n");
1935         return TRUE;
1936     }
1937     else
1938         return FALSE;
1939 }
1940
1941 void write_recordmarker(entity pl, float tstart, float dt)
1942 {
1943     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1944
1945     // also write a marker into demo files for demotc-race-record-extractor to find
1946     stuffcmd(pl,
1947              strcat(
1948                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1949                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1950 }
1951
1952 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1953 {
1954         switch(algn)
1955         {
1956                 default:
1957                 case 3: // right
1958                         break;
1959
1960                 case 4: // left
1961                         vecs_y = -vecs_y;
1962                         break;
1963
1964                 case 1:
1965                         if(allowcenter) // 2: allow center handedness
1966                         {
1967                                 // center
1968                                 vecs_y = 0;
1969                                 vecs_z -= 2;
1970                         }
1971                         else
1972                         {
1973                                 // right
1974                         }
1975                         break;
1976
1977                 case 2:
1978                         if(allowcenter) // 2: allow center handedness
1979                         {
1980                                 // center
1981                                 vecs_y = 0;
1982                                 vecs_z -= 2;
1983                         }
1984                         else
1985                         {
1986                                 // left
1987                                 vecs_y = -vecs_y;
1988                         }
1989                         break;
1990         }
1991         return vecs;
1992 }
1993
1994 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1995 {
1996         string s;
1997         vector v;
1998
1999         if (autocvar_g_shootfromeye)
2000         {
2001                 if (visual)
2002                 {
2003                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2004                         else { vecs_y = 0; vecs_z -= 2; }
2005                 }
2006                 else
2007                 {
2008                         vecs_y = 0;
2009                         vecs_z = 0;
2010                 }
2011         }
2012         else if (autocvar_g_shootfromcenter)
2013         {
2014                 vecs_y = 0;
2015                 vecs_z -= 2;
2016         }
2017         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2018         {
2019                 v = stov(s);
2020                 if (y_is_right)
2021                         v_y = -v_y;
2022                 if (v_x != 0)
2023                         vecs_x = v_x;
2024                 vecs_y = v_y;
2025                 vecs_z = v_z;
2026         }
2027         else if (autocvar_g_shootfromclient)
2028         {
2029                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2030         }
2031         return vecs;
2032 }
2033
2034 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2035 {
2036         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2037 }
2038
2039
2040 void attach_sameorigin(entity e, entity to, string tag)
2041 {
2042     vector org, t_forward, t_left, t_up, e_forward, e_up;
2043     float tagscale;
2044
2045     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2046     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2047     t_forward = v_forward * tagscale;
2048     t_left = v_right * -tagscale;
2049     t_up = v_up * tagscale;
2050
2051     e.origin_x = org * t_forward;
2052     e.origin_y = org * t_left;
2053     e.origin_z = org * t_up;
2054
2055     // current forward and up directions
2056     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2057                 e.angles = AnglesTransform_FromVAngles(e.angles);
2058         else
2059                 e.angles = AnglesTransform_FromAngles(e.angles);
2060     fixedmakevectors(e.angles);
2061
2062     // untransform forward, up!
2063     e_forward_x = v_forward * t_forward;
2064     e_forward_y = v_forward * t_left;
2065     e_forward_z = v_forward * t_up;
2066     e_up_x = v_up * t_forward;
2067     e_up_y = v_up * t_left;
2068     e_up_z = v_up * t_up;
2069
2070     e.angles = fixedvectoangles2(e_forward, e_up);
2071     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2072                 e.angles = AnglesTransform_ToVAngles(e.angles);
2073         else
2074                 e.angles = AnglesTransform_ToAngles(e.angles);
2075
2076     setattachment(e, to, tag);
2077     setorigin(e, e.origin);
2078 }
2079
2080 void detach_sameorigin(entity e)
2081 {
2082     vector org;
2083     org = gettaginfo(e, 0);
2084     e.angles = fixedvectoangles2(v_forward, v_up);
2085     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2086                 e.angles = AnglesTransform_ToVAngles(e.angles);
2087         else
2088                 e.angles = AnglesTransform_ToAngles(e.angles);
2089     setorigin(e, org);
2090     setattachment(e, world, "");
2091     setorigin(e, e.origin);
2092 }
2093
2094 void follow_sameorigin(entity e, entity to)
2095 {
2096     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2097     e.aiment = to; // make the hole follow bmodel
2098     e.punchangle = to.angles; // the original angles of bmodel
2099     e.view_ofs = e.origin - to.origin; // relative origin
2100     e.v_angle = e.angles - to.angles; // relative angles
2101 }
2102
2103 void unfollow_sameorigin(entity e)
2104 {
2105     e.movetype = MOVETYPE_NONE;
2106 }
2107
2108 entity gettaginfo_relative_ent;
2109 vector gettaginfo_relative(entity e, float tag)
2110 {
2111     if (!gettaginfo_relative_ent)
2112     {
2113         gettaginfo_relative_ent = spawn();
2114         gettaginfo_relative_ent.effects = EF_NODRAW;
2115     }
2116     gettaginfo_relative_ent.model = e.model;
2117     gettaginfo_relative_ent.modelindex = e.modelindex;
2118     gettaginfo_relative_ent.frame = e.frame;
2119     return gettaginfo(gettaginfo_relative_ent, tag);
2120 }
2121
2122 .float scale2;
2123
2124 float modeleffect_SendEntity(entity to, float sf)
2125 {
2126         float f;
2127         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2128
2129         f = 0;
2130         if(self.velocity != '0 0 0')
2131                 f |= 1;
2132         if(self.angles != '0 0 0')
2133                 f |= 2;
2134         if(self.avelocity != '0 0 0')
2135                 f |= 4;
2136
2137         WriteByte(MSG_ENTITY, f);
2138         WriteShort(MSG_ENTITY, self.modelindex);
2139         WriteByte(MSG_ENTITY, self.skin);
2140         WriteByte(MSG_ENTITY, self.frame);
2141         WriteCoord(MSG_ENTITY, self.origin_x);
2142         WriteCoord(MSG_ENTITY, self.origin_y);
2143         WriteCoord(MSG_ENTITY, self.origin_z);
2144         if(f & 1)
2145         {
2146                 WriteCoord(MSG_ENTITY, self.velocity_x);
2147                 WriteCoord(MSG_ENTITY, self.velocity_y);
2148                 WriteCoord(MSG_ENTITY, self.velocity_z);
2149         }
2150         if(f & 2)
2151         {
2152                 WriteCoord(MSG_ENTITY, self.angles_x);
2153                 WriteCoord(MSG_ENTITY, self.angles_y);
2154                 WriteCoord(MSG_ENTITY, self.angles_z);
2155         }
2156         if(f & 4)
2157         {
2158                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2159                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2160                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2161         }
2162         WriteShort(MSG_ENTITY, self.scale * 256.0);
2163         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2164         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2165         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2166         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2167
2168         return TRUE;
2169 }
2170
2171 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2172 {
2173         entity e;
2174         float sz;
2175         e = spawn();
2176         e.classname = "modeleffect";
2177         setmodel(e, m);
2178         e.frame = f;
2179         setorigin(e, o);
2180         e.velocity = v;
2181         e.angles = ang;
2182         e.avelocity = angv;
2183         e.alpha = a;
2184         e.teleport_time = t1;
2185         e.fade_time = t2;
2186         e.skin = s;
2187         if(s0 >= 0)
2188                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2189         else
2190                 e.scale = -s0;
2191         if(s2 >= 0)
2192                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2193         else
2194                 e.scale2 = -s2;
2195         sz = max(e.scale, e.scale2);
2196         setsize(e, e.mins * sz, e.maxs * sz);
2197         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2198 }
2199
2200 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2201 {
2202         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2203 }
2204
2205 float randombit(float bits)
2206 {
2207         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2208                 return bits;
2209
2210         float n, f, b, r;
2211
2212         r = random();
2213         b = 0;
2214         n = 0;
2215
2216         for(f = 1; f <= bits; f *= 2)
2217         {
2218                 if(bits & f)
2219                 {
2220                         ++n;
2221                         r *= n;
2222                         if(r <= 1)
2223                                 b = f;
2224                         else
2225                                 r = (r - 1) / (n - 1);
2226                 }
2227         }
2228
2229         return b;
2230 }
2231
2232 float randombits(float bits, float k, float error_return)
2233 {
2234         float r;
2235         r = 0;
2236         while(k > 0 && bits != r)
2237         {
2238                 r += randombit(bits - r);
2239                 --k;
2240         }
2241         if(error_return)
2242                 if(k > 0)
2243                         return -1; // all
2244         return r;
2245 }
2246
2247 void randombit_test(float bits, float iter)
2248 {
2249         while(iter > 0)
2250         {
2251                 print(ftos(randombit(bits)), "\n");
2252                 --iter;
2253         }
2254 }
2255
2256 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2257 {
2258         if(halflifedist > 0)
2259                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2260         else if(halflifedist < 0)
2261                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2262         else
2263                 return 1;
2264 }
2265
2266
2267
2268
2269 #ifdef RELEASE
2270 #define cvar_string_normal builtin_cvar_string
2271 #define cvar_normal builtin_cvar
2272 #else
2273 string cvar_string_normal(string n)
2274 {
2275         if (!(cvar_type(n) & 1))
2276                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2277         return builtin_cvar_string(n);
2278 }
2279
2280 float cvar_normal(string n)
2281 {
2282         return stof(cvar_string_normal(n));
2283 }
2284 #endif
2285 #define cvar_set_normal builtin_cvar_set
2286
2287 void defer_think()
2288 {
2289     entity oself;
2290
2291     oself           = self;
2292     self            = self.owner;
2293     oself.think     = SUB_Remove;
2294     oself.nextthink = time;
2295
2296     oself.use();
2297 }
2298
2299 /*
2300     Execute func() after time + fdelay.
2301     self when func is executed = self when defer is called
2302 */
2303 void defer(float fdelay, void() func)
2304 {
2305     entity e;
2306
2307     e           = spawn();
2308     e.owner     = self;
2309     e.use       = func;
2310     e.think     = defer_think;
2311     e.nextthink = time + fdelay;
2312 }
2313
2314 .string aiment_classname;
2315 .float aiment_deadflag;
2316 void SetMovetypeFollow(entity ent, entity e)
2317 {
2318         // FIXME this may not be warpzone aware
2319         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2320         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2321         ent.aiment = e; // make the hole follow bmodel
2322         ent.punchangle = e.angles; // the original angles of bmodel
2323         ent.view_ofs = ent.origin - e.origin; // relative origin
2324         ent.v_angle = ent.angles - e.angles; // relative angles
2325         ent.aiment_classname = strzone(e.classname);
2326         ent.aiment_deadflag = e.deadflag;
2327 }
2328 void UnsetMovetypeFollow(entity ent)
2329 {
2330         ent.movetype = MOVETYPE_FLY;
2331         PROJECTILE_MAKETRIGGER(ent);
2332         ent.aiment = world;
2333 }
2334 float LostMovetypeFollow(entity ent)
2335 {
2336 /*
2337         if(ent.movetype != MOVETYPE_FOLLOW)
2338                 if(ent.aiment)
2339                         error("???");
2340 */
2341         if(ent.aiment)
2342         {
2343                 if(ent.aiment.classname != ent.aiment_classname)
2344                         return 1;
2345                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2346                         return 1;
2347         }
2348         return 0;
2349 }
2350
2351 float isPushable(entity e)
2352 {
2353         if(e.iscreature)
2354                 return TRUE;
2355         if(e.pushable)
2356                 return TRUE;
2357         switch(e.classname)
2358         {
2359                 case "body":
2360                 case "droppedweapon":
2361                 case "keepawayball":
2362                 case "nexball_basketball":
2363                 case "nexball_football":
2364                         return TRUE;
2365                 case "bullet": // antilagged bullets can't hit this either
2366                         return FALSE;
2367         }
2368         if (e.projectiledeathtype)
2369                 return TRUE;
2370         return FALSE;
2371 }