qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 494         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 495         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 507         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 508         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 509         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 511         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 513         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 514
 515         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 516         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 517
 518         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 520         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 521         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 522         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 523
 524         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 525         if (f > 0)
 526         {
 527                 if (s == "cl_weaponpriority")
 528                         self.switchweapon = w_getbestweapon(self);
 529                 if (s == "cl_allow_uidtracking")
 530                         PlayerStats_AddPlayer(self);
 531         }
 532 }
 533
 534 // decolorizes and team colors the player name when needed
 535 string playername(entity p)
 536 {
 537     string t;
 538     if (teamplay && !intermission_running && IS_PLAYER(p))
 539     {
 540         t = Team_ColorCode(p.team);
 541         return strcat(t, strdecolorize(p.netname));
 542     }
 543     else
 544         return p.netname;
 545 }
 546
 547 vector randompos(vector m1, vector m2)
 548 {
 549     vector v;
 550     m2 = m2 - m1;
 551     v_x = m2_x * random() + m1_x;
 552     v_y = m2_y * random() + m1_y;
 553     v_z = m2_z * random() + m1_z;
 554     return  v;
 555 }
 556
 557 //#NO AUTOCVARS START
 558
 559 float g_pickup_shells;
 560 float g_pickup_shells_max;
 561 float g_pickup_nails;
 562 float g_pickup_nails_max;
 563 float g_pickup_rockets;
 564 float g_pickup_rockets_max;
 565 float g_pickup_cells;
 566 float g_pickup_cells_max;
 567 float g_pickup_fuel;
 568 float g_pickup_fuel_jetpack;
 569 float g_pickup_fuel_max;
 570 float g_pickup_armorsmall;
 571 float g_pickup_armorsmall_max;
 572 float g_pickup_armorsmall_anyway;
 573 float g_pickup_armormedium;
 574 float g_pickup_armormedium_max;
 575 float g_pickup_armormedium_anyway;
 576 float g_pickup_armorbig;
 577 float g_pickup_armorbig_max;
 578 float g_pickup_armorbig_anyway;
 579 float g_pickup_armorlarge;
 580 float g_pickup_armorlarge_max;
 581 float g_pickup_armorlarge_anyway;
 582 float g_pickup_healthsmall;
 583 float g_pickup_healthsmall_max;
 584 float g_pickup_healthsmall_anyway;
 585 float g_pickup_healthmedium;
 586 float g_pickup_healthmedium_max;
 587 float g_pickup_healthmedium_anyway;
 588 float g_pickup_healthlarge;
 589 float g_pickup_healthlarge_max;
 590 float g_pickup_healthlarge_anyway;
 591 float g_pickup_healthmega;
 592 float g_pickup_healthmega_max;
 593 float g_pickup_healthmega_anyway;
 594 float g_pickup_ammo_anyway;
 595 float g_pickup_weapons_anyway;
 596 float g_weaponarena;
 597 WepSet g_weaponarena_weapons;
 598 float g_weaponarena_random;
 599 float g_weaponarena_random_with_laser;
 600 string g_weaponarena_list;
 601 float g_weaponspeedfactor;
 602 float g_weaponratefactor;
 603 float g_weapondamagefactor;
 604 float g_weaponforcefactor;
 605 float g_weaponspreadfactor;
 606
 607 WepSet start_weapons;
 608 WepSet start_weapons_default;
 609 WepSet start_weapons_defaultmask;
 610 float start_items;
 611 float start_ammo_shells;
 612 float start_ammo_nails;
 613 float start_ammo_rockets;
 614 float start_ammo_cells;
 615 float start_ammo_fuel;
 616 float start_health;
 617 float start_armorvalue;
 618 WepSet warmup_start_weapons;
 619 WepSet warmup_start_weapons_default;
 620 WepSet warmup_start_weapons_defaultmask;
 621 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 622 float warmup_start_ammo_shells;
 623 float warmup_start_ammo_nails;
 624 float warmup_start_ammo_rockets;
 625 float warmup_start_ammo_cells;
 626 float warmup_start_ammo_fuel;
 627 float warmup_start_health;
 628 float warmup_start_armorvalue;
 629 float g_weapon_stay;
 630
 631 entity get_weaponinfo(float w);
 632
 633 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 634 {
 635         var float i = weaponinfo.weapon;
 636         var float d = 0;
 637
 638         if (!i)
 639                 return 0;
 640
 641         if (g_lms || g_ca || allguns)
 642         {
 643                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 644                         d = TRUE;
 645                 else
 646                         d = FALSE;
 647         }
 648         else if (g_cts)
 649                 d = (i == WEP_SHOTGUN);
 650         else if (g_nexball)
 651                 d = 0; // weapon is set a few lines later
 652         else
 653                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 654
 655         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 656                 d |= (i == WEP_HOOK);
 657         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 658                 d = 0;
 659
 660         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 661
 662         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 663
 664         // bit order in t:
 665         // 1: want or not
 666         // 2: is default?
 667         // 4: is set by default?
 668         if(t < 0)
 669                 t = 4 | (3 * d);
 670         else
 671                 t |= (2 * d);
 672
 673         return t;
 674 }
 675
 676 void readplayerstartcvars()
 677 {
 678         entity e;
 679         float i, j, t;
 680         string s;
 681
 682         // initialize starting values for players
 683         start_weapons = '0 0 0';
 684         start_weapons_default = '0 0 0';
 685         start_weapons_defaultmask = '0 0 0';
 686         start_items = 0;
 687         start_ammo_shells = 0;
 688         start_ammo_nails = 0;
 689         start_ammo_rockets = 0;
 690         start_ammo_cells = 0;
 691         start_health = cvar("g_balance_health_start");
 692         start_armorvalue = cvar("g_balance_armor_start");
 693
 694         g_weaponarena = 0;
 695         g_weaponarena_weapons = '0 0 0';
 696
 697         s = cvar_string("g_weaponarena");
 698         if (s == "0" || s == "")
 699         {
 700                 if(g_ca)
 701                         s = "most";
 702         }
 703
 704         if (s == "0" || s == "")
 705         {
 706                 // no arena
 707         }
 708         else if (s == "off")
 709         {
 710                 // forcibly turn off weaponarena
 711         }
 712         else if (s == "all")
 713         {
 714                 g_weaponarena = 1;
 715                 g_weaponarena_list = "All Weapons";
 716                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 717                 {
 718                         e = get_weaponinfo(j);
 719                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 720                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 721                 }
 722         }
 723         else if (s == "most")
 724         {
 725                 g_weaponarena = 1;
 726                 g_weaponarena_list = "Most Weapons";
 727                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 728                 {
 729                         e = get_weaponinfo(j);
 730                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 731                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 732                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 733                 }
 734         }
 735         else if (s == "none")
 736         {
 737                 g_weaponarena = 1;
 738                 g_weaponarena_list = "No Weapons";
 739         }
 740         else
 741         {
 742                 g_weaponarena = 1;
 743                 t = tokenize_console(s);
 744                 g_weaponarena_list = "";
 745                 for (i = 0; i < t; ++i)
 746                 {
 747                         s = argv(i);
 748                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 749                         {
 750                                 e = get_weaponinfo(j);
 751                                 if (e.netname == s)
 752                                 {
 753                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 754                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 755                                         break;
 756                                 }
 757                         }
 758                         if (j > WEP_LAST)
 759                         {
 760                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 761                         }
 762                 }
 763                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 764         }
 765
 766         if(g_weaponarena)
 767                 g_weaponarena_random = cvar("g_weaponarena_random");
 768         else
 769                 g_weaponarena_random = 0;
 770         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 771
 772         if (g_weaponarena)
 773         {
 774                 g_weapon_stay = 0; // incompatible
 775                 start_weapons = g_weaponarena_weapons;
 776                 start_items |= IT_UNLIMITED_AMMO;
 777         }
 778         else
 779         {
 780                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 781                 {
 782                         e = get_weaponinfo(i);
 783                         float w = want_weapon("g_start_weapon_", e, FALSE);
 784                         if(w & 1)
 785                                 start_weapons |= WepSet_FromWeapon(i);
 786                         if(w & 2)
 787                                 start_weapons_default |= WepSet_FromWeapon(i);
 788                         if(w & 4)
 789                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 790                 }
 791         }
 792
 793         if(!cvar("g_use_ammunition"))
 794                 start_items |= IT_UNLIMITED_AMMO;
 795
 796         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 797         {
 798                 start_ammo_rockets = 999;
 799                 start_ammo_shells = 999;
 800                 start_ammo_cells = 999;
 801                 start_ammo_nails = 999;
 802                 start_ammo_fuel = 999;
 803         }
 804         else
 805         {
 806                 start_ammo_shells = cvar("g_start_ammo_shells");
 807                 start_ammo_nails = cvar("g_start_ammo_nails");
 808                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 809                 start_ammo_cells = cvar("g_start_ammo_cells");
 810                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 811         }
 812
 813         if (warmup_stage)
 814         {
 815                 warmup_start_ammo_shells = start_ammo_shells;
 816                 warmup_start_ammo_nails = start_ammo_nails;
 817                 warmup_start_ammo_rockets = start_ammo_rockets;
 818                 warmup_start_ammo_cells = start_ammo_cells;
 819                 warmup_start_ammo_fuel = start_ammo_fuel;
 820                 warmup_start_health = start_health;
 821                 warmup_start_armorvalue = start_armorvalue;
 822                 warmup_start_weapons = start_weapons;
 823                 warmup_start_weapons_default = start_weapons_default;
 824                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 825
 826                 if (!g_weaponarena && !g_ca)
 827                 {
 828                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 829                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 830                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 831                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 832                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 833                         warmup_start_health = cvar("g_warmup_start_health");
 834                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 835                         warmup_start_weapons = '0 0 0';
 836                         warmup_start_weapons_default = '0 0 0';
 837                         warmup_start_weapons_defaultmask = '0 0 0';
 838                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 839                         {
 840                                 e = get_weaponinfo(i);
 841                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 842                                 if(w & 1)
 843                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 844                                 if(w & 2)
 845                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 846                                 if(w & 4)
 847                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 848                         }
 849                 }
 850         }
 851
 852         if (g_jetpack)
 853                 start_items |= IT_JETPACK;
 854
 855         MUTATOR_CALLHOOK(SetStartItems);
 856
 857         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 858         {
 859                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 860                 start_items |= IT_FUEL_REGEN;
 861                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 863         }
 864
 865         WepSet precache_weapons = start_weapons;
 866         if (g_warmup_allguns != 1)
 867                 precache_weapons |= warmup_start_weapons;
 868         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 869         {
 870                 e = get_weaponinfo(i);
 871                 if(precache_weapons & WepSet_FromWeapon(i))
 872                         weapon_action(i, WR_PRECACHE);
 873         }
 874
 875         start_ammo_shells = max(0, start_ammo_shells);
 876         start_ammo_nails = max(0, start_ammo_nails);
 877         start_ammo_cells = max(0, start_ammo_cells);
 878         start_ammo_rockets = max(0, start_ammo_rockets);
 879         start_ammo_fuel = max(0, start_ammo_fuel);
 880
 881         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 882         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 883         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 884         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 885         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 886 }
 887
 888 float g_bugrigs;
 889 float g_bugrigs_planar_movement;
 890 float g_bugrigs_planar_movement_car_jumping;
 891 float g_bugrigs_reverse_spinning;
 892 float g_bugrigs_reverse_speeding;
 893 float g_bugrigs_reverse_stopping;
 894 float g_bugrigs_air_steering;
 895 float g_bugrigs_angle_smoothing;
 896 float g_bugrigs_friction_floor;
 897 float g_bugrigs_friction_brake;
 898 float g_bugrigs_friction_air;
 899 float g_bugrigs_accel;
 900 float g_bugrigs_speed_ref;
 901 float g_bugrigs_speed_pow;
 902 float g_bugrigs_steer;
 903
 904 float sv_autotaunt;
 905 float sv_taunt;
 906
 907 string GetGametype(); // g_world.qc
 908 void readlevelcvars(void)
 909 {
 910         // load mutators
 911         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 912                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 913
 914         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 915         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, teamplay);
 916         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 917         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 918         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 919         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 921         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 923         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 924         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 925         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 926         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 927         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 928         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 929         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 930         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 931         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 932         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 933         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 934
 935         #undef CHECK_MUTATOR_ADD
 936
 937         if(cvar("sv_allow_fullbright"))
 938                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 939
 940     g_bugrigs = cvar("g_bugrigs");
 941     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 942     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 943     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 944     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 945     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 946     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 947     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 948     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 949     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 950     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 951     g_bugrigs_accel = cvar("g_bugrigs_accel");
 952     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 953     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 954     g_bugrigs_steer = cvar("g_bugrigs_steer");
 955
 956         g_minstagib = cvar("g_minstagib");
 957
 958         sv_clones = cvar("sv_clones");
 959         sv_foginterval = cvar("sv_foginterval");
 960         g_cloaked = cvar("g_cloaked");
 961     if(g_cts)
 962         g_cloaked = 1; // always enable cloak in CTS
 963         g_footsteps = cvar("g_footsteps");
 964         g_grappling_hook = cvar("g_grappling_hook");
 965         g_jetpack = cvar("g_jetpack");
 966         sv_maxidle = cvar("sv_maxidle");
 967         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 968         sv_autotaunt = cvar("sv_autotaunt");
 969         sv_taunt = cvar("sv_taunt");
 970
 971         warmup_stage = cvar("g_warmup");
 972         g_warmup_limit = cvar("g_warmup_limit");
 973         g_warmup_allguns = cvar("g_warmup_allguns");
 974         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 975
 976         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 977                 warmup_stage = 0; // these modes cannot work together, sorry
 978
 979         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 980         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 981         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 982         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 983         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 984         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 985         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 986         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 987         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 988         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 989         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 990         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 991         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 992         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 993
 994         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 995         g_weaponratefactor = cvar("g_weaponratefactor");
 996         g_weapondamagefactor = cvar("g_weapondamagefactor");
 997         g_weaponforcefactor = cvar("g_weaponforcefactor");
 998         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 999
1000         g_pickup_shells = cvar("g_pickup_shells");
1001         g_pickup_shells_max = cvar("g_pickup_shells_max");
1002         g_pickup_nails = cvar("g_pickup_nails");
1003         g_pickup_nails_max = cvar("g_pickup_nails_max");
1004         g_pickup_rockets = cvar("g_pickup_rockets");
1005         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1006         g_pickup_cells = cvar("g_pickup_cells");
1007         g_pickup_cells_max = cvar("g_pickup_cells_max");
1008         g_pickup_fuel = cvar("g_pickup_fuel");
1009         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1010         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1011         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1012         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1013         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1014         g_pickup_armormedium = cvar("g_pickup_armormedium");
1015         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1016         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1017         g_pickup_armorbig = cvar("g_pickup_armorbig");
1018         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1019         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1020         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1021         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1022         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1023         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1024         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1025         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1026         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1027         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1028         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1029         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1030         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1031         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1032         g_pickup_healthmega = cvar("g_pickup_healthmega");
1033         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1034         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1035
1036         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1037         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1038
1039     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1040     if(!g_weapon_stay)
1041         g_weapon_stay = cvar("g_weapon_stay");
1042
1043         if (!warmup_stage)
1044                 game_starttime = time + cvar("g_start_delay");
1045
1046         readplayerstartcvars();
1047 }
1048
1049 //#NO AUTOCVARS END
1050
1051 // Sound functions
1052 string precache_sound (string s) = #19;
1053 float precache_sound_index (string s) = #19;
1054
1055 #define SND_VOLUME      1
1056 #define SND_ATTENUATION 2
1057 #define SND_LARGEENTITY 8
1058 #define SND_LARGESOUND  16
1059
1060 float sound_allowed(float dest, entity e)
1061 {
1062     // sounds from world may always pass
1063     for (;;)
1064     {
1065         if (e.classname == "body")
1066             e = e.enemy;
1067         else if (e.realowner && e.realowner != e)
1068             e = e.realowner;
1069         else if (e.owner && e.owner != e)
1070             e = e.owner;
1071         else
1072             break;
1073     }
1074     // sounds to self may always pass
1075     if (dest == MSG_ONE)
1076         if (e == msg_entity)
1077             return TRUE;
1078     // sounds by players can be removed
1079     if (autocvar_bot_sound_monopoly)
1080         if (IS_REAL_CLIENT(e))
1081             return FALSE;
1082     // anything else may pass
1083     return TRUE;
1084 }
1085
1086 #ifdef COMPAT_XON010_CHANNELS
1087 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1088 void sound(entity e, float chan, string samp, float vol, float atten)
1089 {
1090     if (!sound_allowed(MSG_BROADCAST, e))
1091         return;
1092     builtin_sound(e, chan, samp, vol, atten);
1093 }
1094 #else
1095 #undef sound
1096 void sound(entity e, float chan, string samp, float vol, float atten)
1097 {
1098     if (!sound_allowed(MSG_BROADCAST, e))
1099         return;
1100     sound7(e, chan, samp, vol, atten, 0, 0);
1101 }
1102 #endif
1103
1104 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1105 {
1106     float entno, idx;
1107
1108     if (!sound_allowed(dest, e))
1109         return;
1110
1111     entno = num_for_edict(e);
1112     idx = precache_sound_index(samp);
1113
1114     float sflags;
1115     sflags = 0;
1116
1117     atten = floor(atten * 64);
1118     vol = floor(vol * 255);
1119
1120     if (vol != 255)
1121         sflags |= SND_VOLUME;
1122     if (atten != 64)
1123         sflags |= SND_ATTENUATION;
1124     if (entno >= 8192 || chan < 0 || chan > 7)
1125         sflags |= SND_LARGEENTITY;
1126     if (idx >= 256)
1127         sflags |= SND_LARGESOUND;
1128
1129     WriteByte(dest, SVC_SOUND);
1130     WriteByte(dest, sflags);
1131     if (sflags & SND_VOLUME)
1132         WriteByte(dest, vol);
1133     if (sflags & SND_ATTENUATION)
1134         WriteByte(dest, atten);
1135     if (sflags & SND_LARGEENTITY)
1136     {
1137         WriteShort(dest, entno);
1138         WriteByte(dest, chan);
1139     }
1140     else
1141     {
1142         WriteShort(dest, entno * 8 + chan);
1143     }
1144     if (sflags & SND_LARGESOUND)
1145         WriteShort(dest, idx);
1146     else
1147         WriteByte(dest, idx);
1148
1149     WriteCoord(dest, o_x);
1150     WriteCoord(dest, o_y);
1151     WriteCoord(dest, o_z);
1152 }
1153 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1154 {
1155     vector o;
1156
1157     if (!sound_allowed(dest, e))
1158         return;
1159
1160     o = e.origin + 0.5 * (e.mins + e.maxs);
1161     soundtoat(dest, e, o, chan, samp, vol, atten);
1162 }
1163 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1164 {
1165     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1166 }
1167 void stopsoundto(float dest, entity e, float chan)
1168 {
1169     float entno;
1170
1171     if (!sound_allowed(dest, e))
1172         return;
1173
1174     entno = num_for_edict(e);
1175
1176     if (entno >= 8192 || chan < 0 || chan > 7)
1177     {
1178         float idx, sflags;
1179         idx = precache_sound_index("misc/null.wav");
1180         sflags = SND_LARGEENTITY;
1181         if (idx >= 256)
1182             sflags |= SND_LARGESOUND;
1183         WriteByte(dest, SVC_SOUND);
1184         WriteByte(dest, sflags);
1185         WriteShort(dest, entno);
1186         WriteByte(dest, chan);
1187         if (sflags & SND_LARGESOUND)
1188             WriteShort(dest, idx);
1189         else
1190             WriteByte(dest, idx);
1191         WriteCoord(dest, e.origin_x);
1192         WriteCoord(dest, e.origin_y);
1193         WriteCoord(dest, e.origin_z);
1194     }
1195     else
1196     {
1197         WriteByte(dest, SVC_STOPSOUND);
1198         WriteShort(dest, entno * 8 + chan);
1199     }
1200 }
1201 void stopsound(entity e, float chan)
1202 {
1203     if (!sound_allowed(MSG_BROADCAST, e))
1204         return;
1205
1206     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1207     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1208 }
1209
1210 void play2(entity e, string filename)
1211 {
1212     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1213     msg_entity = e;
1214     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1215 }
1216
1217 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1218 .float spamtime;
1219 float spamsound(entity e, float chan, string samp, float vol, float atten)
1220 {
1221     if (!sound_allowed(MSG_BROADCAST, e))
1222         return FALSE;
1223
1224     if (time > e.spamtime)
1225     {
1226         e.spamtime = time;
1227         sound(e, chan, samp, vol, atten);
1228         return TRUE;
1229     }
1230     return FALSE;
1231 }
1232
1233 void play2team(float t, string filename)
1234 {
1235     entity head;
1236
1237     if (autocvar_bot_sound_monopoly)
1238         return;
1239
1240     FOR_EACH_REALPLAYER(head)
1241     {
1242         if (head.team == t)
1243             play2(head, filename);
1244     }
1245 }
1246
1247 void play2all(string samp)
1248 {
1249     if (autocvar_bot_sound_monopoly)
1250         return;
1251
1252     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1253 }
1254
1255 void PrecachePlayerSounds(string f);
1256 void precache_playermodel(string m)
1257 {
1258         float globhandle, i, n;
1259         string f;
1260
1261         if(substring(m, -9,5) == "_lod1")
1262                 return;
1263         if(substring(m, -9,5) == "_lod2")
1264                 return;
1265         precache_model(m);
1266         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1267         if(fexists(f))
1268                 precache_model(f);
1269         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1270         if(fexists(f))
1271                 precache_model(f);
1272
1273         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1274         if (globhandle < 0)
1275                 return;
1276         n = search_getsize(globhandle);
1277         for (i = 0; i < n; ++i)
1278         {
1279                 //print(search_getfilename(globhandle, i), "\n");
1280                 f = search_getfilename(globhandle, i);
1281                 PrecachePlayerSounds(f);
1282         }
1283         search_end(globhandle);
1284 }
1285 void precache_all_playermodels(string pattern)
1286 {
1287         float globhandle, i, n;
1288         string f;
1289
1290         globhandle = search_begin(pattern, TRUE, FALSE);
1291         if (globhandle < 0)
1292                 return;
1293         n = search_getsize(globhandle);
1294         for (i = 0; i < n; ++i)
1295         {
1296                 //print(search_getfilename(globhandle, i), "\n");
1297                 f = search_getfilename(globhandle, i);
1298                 precache_playermodel(f);
1299         }
1300         search_end(globhandle);
1301 }
1302
1303 void precache()
1304 {
1305     // gamemode related things
1306     precache_model ("models/misc/chatbubble.spr");
1307
1308 #ifdef TTURRETS_ENABLED
1309     if (autocvar_g_turrets)
1310         turrets_precash();
1311 #endif
1312
1313     // Precache all player models if desired
1314     if (autocvar_sv_precacheplayermodels)
1315     {
1316         PrecachePlayerSounds("sound/player/default.sounds");
1317         precache_all_playermodels("models/player/*.zym");
1318         precache_all_playermodels("models/player/*.dpm");
1319         precache_all_playermodels("models/player/*.md3");
1320         precache_all_playermodels("models/player/*.psk");
1321         precache_all_playermodels("models/player/*.iqm");
1322     }
1323
1324     if (autocvar_sv_defaultcharacter)
1325     {
1326         string s;
1327         s = autocvar_sv_defaultplayermodel_red;
1328         if (s != "")
1329             precache_playermodel(s);
1330         s = autocvar_sv_defaultplayermodel_blue;
1331         if (s != "")
1332             precache_playermodel(s);
1333         s = autocvar_sv_defaultplayermodel_yellow;
1334         if (s != "")
1335             precache_playermodel(s);
1336         s = autocvar_sv_defaultplayermodel_pink;
1337         if (s != "")
1338             precache_playermodel(s);
1339         s = autocvar_sv_defaultplayermodel;
1340         if (s != "")
1341             precache_playermodel(s);
1342     }
1343
1344     if (g_footsteps)
1345     {
1346         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1347         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1348     }
1349
1350     // gore and miscellaneous sounds
1351     //precache_sound ("misc/h2ohit.wav");
1352     precache_model ("models/hook.md3");
1353     precache_sound ("misc/armorimpact.wav");
1354     precache_sound ("misc/bodyimpact1.wav");
1355     precache_sound ("misc/bodyimpact2.wav");
1356     precache_sound ("misc/gib.wav");
1357     precache_sound ("misc/gib_splat01.wav");
1358     precache_sound ("misc/gib_splat02.wav");
1359     precache_sound ("misc/gib_splat03.wav");
1360     precache_sound ("misc/gib_splat04.wav");
1361     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1362     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1363     precache_sound ("misc/null.wav");
1364     precache_sound ("misc/spawn.wav");
1365     precache_sound ("misc/talk.wav");
1366     precache_sound ("misc/teleport.wav");
1367     precache_sound ("misc/poweroff.wav");
1368     precache_sound ("player/lava.wav");
1369     precache_sound ("player/slime.wav");
1370
1371     precache_model ("models/sprites/0.spr32");
1372     precache_model ("models/sprites/1.spr32");
1373     precache_model ("models/sprites/2.spr32");
1374     precache_model ("models/sprites/3.spr32");
1375     precache_model ("models/sprites/4.spr32");
1376     precache_model ("models/sprites/5.spr32");
1377     precache_model ("models/sprites/6.spr32");
1378     precache_model ("models/sprites/7.spr32");
1379     precache_model ("models/sprites/8.spr32");
1380     precache_model ("models/sprites/9.spr32");
1381     precache_model ("models/sprites/10.spr32");
1382
1383     // common weapon precaches
1384         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1385     precache_sound ("weapons/weapon_switch.wav");
1386     precache_sound ("weapons/weaponpickup.wav");
1387     precache_sound ("weapons/unavailable.wav");
1388     precache_sound ("weapons/dryfire.wav");
1389     if (g_grappling_hook)
1390     {
1391         precache_sound ("weapons/hook_fire.wav"); // hook
1392         precache_sound ("weapons/hook_impact.wav"); // hook
1393     }
1394
1395     if(autocvar_sv_precacheweapons)
1396     {
1397         //precache weapon models/sounds
1398         float wep;
1399         wep = WEP_FIRST;
1400         while (wep <= WEP_LAST)
1401         {
1402             weapon_action(wep, WR_PRECACHE);
1403             wep = wep + 1;
1404         }
1405     }
1406
1407     precache_model("models/elaser.mdl");
1408     precache_model("models/laser.mdl");
1409     precache_model("models/ebomb.mdl");
1410
1411 #if 0
1412     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1413
1414     if (!self.noise && self.music) // quake 3 uses the music field
1415         self.noise = self.music;
1416
1417     // plays music for the level if there is any
1418     if (self.noise)
1419     {
1420         precache_sound (self.noise);
1421         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1422     }
1423 #endif
1424
1425 #include "precache-for-csqc.inc"
1426 }
1427
1428 // WARNING: this kills the trace globals
1429 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1430 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1431
1432 #define INITPRIO_FIRST              0
1433 #define INITPRIO_GAMETYPE           0
1434 #define INITPRIO_GAMETYPE_FALLBACK  1
1435 #define INITPRIO_FINDTARGET        10
1436 #define INITPRIO_DROPTOFLOOR       20
1437 #define INITPRIO_SETLOCATION       90
1438 #define INITPRIO_LINKDOORS         91
1439 #define INITPRIO_LAST              99
1440
1441 .void(void) initialize_entity;
1442 .float initialize_entity_order;
1443 .entity initialize_entity_next;
1444 entity initialize_entity_first;
1445
1446 void make_safe_for_remove(entity e)
1447 {
1448     if (e.initialize_entity)
1449     {
1450         entity ent, prev = world;
1451         for (ent = initialize_entity_first; ent; )
1452         {
1453             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1454             {
1455                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1456                 // skip it in linked list
1457                 if (prev)
1458                 {
1459                     prev.initialize_entity_next = ent.initialize_entity_next;
1460                     ent = prev.initialize_entity_next;
1461                 }
1462                 else
1463                 {
1464                     initialize_entity_first = ent.initialize_entity_next;
1465                     ent = initialize_entity_first;
1466                 }
1467             }
1468             else
1469             {
1470                 prev = ent;
1471                 ent = ent.initialize_entity_next;
1472             }
1473         }
1474     }
1475 }
1476
1477 void objerror(string s)
1478 {
1479     make_safe_for_remove(self);
1480     builtin_objerror(s);
1481 }
1482
1483 .float remove_except_protected_forbidden;
1484 void remove_except_protected(entity e)
1485 {
1486         if(e.remove_except_protected_forbidden)
1487                 error("not allowed to remove this at this point");
1488         builtin_remove(e);
1489 }
1490
1491 void remove_unsafely(entity e)
1492 {
1493     if(e.classname == "spike")
1494         error("Removing spikes is forbidden (crylink bug), please report");
1495     builtin_remove(e);
1496 }
1497
1498 void remove_safely(entity e)
1499 {
1500     make_safe_for_remove(e);
1501     builtin_remove(e);
1502 }
1503
1504 void InitializeEntity(entity e, void(void) func, float order)
1505 {
1506     entity prev, cur;
1507
1508     if (!e || e.initialize_entity)
1509     {
1510         // make a proxy initializer entity
1511         entity e_old;
1512         e_old = e;
1513         e = spawn();
1514         e.classname = "initialize_entity";
1515         e.enemy = e_old;
1516     }
1517
1518     e.initialize_entity = func;
1519     e.initialize_entity_order = order;
1520
1521     cur = initialize_entity_first;
1522     prev = world;
1523     for (;;)
1524     {
1525         if (!cur || cur.initialize_entity_order > order)
1526         {
1527             // insert between prev and cur
1528             if (prev)
1529                 prev.initialize_entity_next = e;
1530             else
1531                 initialize_entity_first = e;
1532             e.initialize_entity_next = cur;
1533             return;
1534         }
1535         prev = cur;
1536         cur = cur.initialize_entity_next;
1537     }
1538 }
1539 void InitializeEntitiesRun()
1540 {
1541     entity startoflist;
1542     startoflist = initialize_entity_first;
1543     initialize_entity_first = world;
1544     remove = remove_except_protected;
1545     for (self = startoflist; self; self = self.initialize_entity_next)
1546     {
1547         self.remove_except_protected_forbidden = 1;
1548     }
1549     for (self = startoflist; self; )
1550     {
1551         entity e;
1552         var void(void) func;
1553         e = self.initialize_entity_next;
1554         func = self.initialize_entity;
1555         self.initialize_entity_order = 0;
1556         self.initialize_entity = func_null;
1557         self.initialize_entity_next = world;
1558         self.remove_except_protected_forbidden = 0;
1559         if (self.classname == "initialize_entity")
1560         {
1561             entity e_old;
1562             e_old = self.enemy;
1563             builtin_remove(self);
1564             self = e_old;
1565         }
1566         //dprint("Delayed initialization: ", self.classname, "\n");
1567         if(func)
1568             func();
1569         else
1570         {
1571             eprint(self);
1572             backtrace(strcat("Null function in: ", self.classname, "\n"));
1573         }
1574         self = e;
1575     }
1576     remove = remove_unsafely;
1577 }
1578
1579 .float uncustomizeentityforclient_set;
1580 .void(void) uncustomizeentityforclient;
1581 void UncustomizeEntitiesRun()
1582 {
1583     entity oldself;
1584     oldself = self;
1585     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1586         self.uncustomizeentityforclient();
1587     self = oldself;
1588 }
1589 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1590 {
1591     e.customizeentityforclient = customizer;
1592     e.uncustomizeentityforclient = uncustomizer;
1593     e.uncustomizeentityforclient_set = !!uncustomizer;
1594 }
1595
1596 .float nottargeted;
1597 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1598
1599 void() SUB_Remove;
1600 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1601 {
1602     vector mi, ma;
1603
1604     if (e.classname == "")
1605         e.classname = "net_linked";
1606
1607     if (e.model == "" || self.modelindex == 0)
1608     {
1609         mi = e.mins;
1610         ma = e.maxs;
1611         setmodel(e, "null");
1612         setsize(e, mi, ma);
1613     }
1614
1615     e.SendEntity = sendfunc;
1616     e.SendFlags = 0xFFFFFF;
1617
1618     if (!docull)
1619         e.effects |= EF_NODEPTHTEST;
1620
1621     if (dt)
1622     {
1623         e.nextthink = time + dt;
1624         e.think = SUB_Remove;
1625     }
1626 }
1627
1628 void adaptor_think2touch()
1629 {
1630     entity o;
1631     o = other;
1632     other = world;
1633     self.touch();
1634     other = o;
1635 }
1636
1637 void adaptor_think2use()
1638 {
1639     entity o, a;
1640     o = other;
1641     a = activator;
1642     activator = world;
1643     other = world;
1644     self.use();
1645     other = o;
1646     activator = a;
1647 }
1648
1649 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1650 {
1651         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1652                 self.projectiledeathtype |= HITTYPE_SPLASH;
1653         adaptor_think2use();
1654 }
1655
1656 // deferred dropping
1657 void DropToFloor_Handler()
1658 {
1659     builtin_droptofloor();
1660     self.dropped_origin = self.origin;
1661 }
1662
1663 void droptofloor()
1664 {
1665     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1666 }
1667
1668
1669
1670 float trace_hits_box_a0, trace_hits_box_a1;
1671
1672 float trace_hits_box_1d(float end, float thmi, float thma)
1673 {
1674     if (end == 0)
1675     {
1676         // just check if x is in range
1677         if (0 < thmi)
1678             return FALSE;
1679         if (0 > thma)
1680             return FALSE;
1681     }
1682     else
1683     {
1684         // do the trace with respect to x
1685         // 0 -> end has to stay in thmi -> thma
1686         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1687         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1688         if (trace_hits_box_a0 > trace_hits_box_a1)
1689             return FALSE;
1690     }
1691     return TRUE;
1692 }
1693
1694 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1695 {
1696     end -= start;
1697     thmi -= start;
1698     thma -= start;
1699     // now it is a trace from 0 to end
1700
1701     trace_hits_box_a0 = 0;
1702     trace_hits_box_a1 = 1;
1703
1704     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1705         return FALSE;
1706     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1707         return FALSE;
1708     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1709         return FALSE;
1710
1711     return TRUE;
1712 }
1713
1714 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1715 {
1716     return trace_hits_box(start, end, thmi - ma, thma - mi);
1717 }
1718
1719 float SUB_NoImpactCheck()
1720 {
1721         // zero hitcontents = this is not the real impact, but either the
1722         // mirror-impact of something hitting the projectile instead of the
1723         // projectile hitting the something, or a touchareagrid one. Neither of
1724         // these stop the projectile from moving, so...
1725         if(trace_dphitcontents == 0)
1726         {
1727                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1728                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1729                 checkclient();
1730         }
1731     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1732         return 1;
1733     if (other == world && self.size != '0 0 0')
1734     {
1735         vector tic;
1736         tic = self.velocity * sys_frametime;
1737         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1738         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1739         if (trace_fraction >= 1)
1740         {
1741             dprint("Odd... did not hit...?\n");
1742         }
1743         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1744         {
1745             dprint("Detected and prevented the sky-grapple bug.\n");
1746             return 1;
1747         }
1748     }
1749
1750     return 0;
1751 }
1752
1753 #define SUB_OwnerCheck() (other && (other == self.owner))
1754
1755 void RemoveGrapplingHook(entity pl);
1756 void W_Crylink_Dequeue(entity e);
1757 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1758 {
1759         if(SUB_OwnerCheck())
1760                 return TRUE;
1761         if(SUB_NoImpactCheck())
1762         {
1763                 if(self.classname == "grapplinghook")
1764                         RemoveGrapplingHook(self.realowner);
1765                 else if(self.classname == "spike")
1766                 {
1767                         W_Crylink_Dequeue(self);
1768                         remove(self);
1769                 }
1770                 else
1771                         remove(self);
1772                 return TRUE;
1773         }
1774         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1775                 UpdateCSQCProjectile(self);
1776         return FALSE;
1777 }
1778 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1779
1780 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1781 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1782
1783 void URI_Get_Callback(float id, float status, string data)
1784 {
1785         if(url_URI_Get_Callback(id, status, data))
1786         {
1787                 // handled
1788         }
1789         else if (id == URI_GET_DISCARD)
1790         {
1791                 // discard
1792         }
1793         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1794         {
1795                 // sv_cmd curl
1796                 Curl_URI_Get_Callback(id, status, data);
1797         }
1798         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1799         {
1800                 // online ban list
1801                 OnlineBanList_URI_Get_Callback(id, status, data);
1802         }
1803         else
1804         {
1805                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1806         }
1807 }
1808
1809 string uid2name(string myuid) {
1810         string s;
1811         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1812
1813         // FIXME remove this later after 0.6 release
1814         // convert old style broken records to correct style
1815         if(s == "")
1816         {
1817                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1818                 if(s != "")
1819                 {
1820                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1821                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1822                 }
1823         }
1824
1825         if(s == "")
1826                 s = "^1Unregistered Player";
1827         return s;
1828 }
1829
1830 float race_readTime(string map, float pos)
1831 {
1832         string rr;
1833         if(g_cts)
1834                 rr = CTS_RECORD;
1835         else
1836                 rr = RACE_RECORD;
1837
1838         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1839 }
1840
1841 string race_readUID(string map, float pos)
1842 {
1843         string rr;
1844         if(g_cts)
1845                 rr = CTS_RECORD;
1846         else
1847                 rr = RACE_RECORD;
1848
1849         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1850 }
1851
1852 float race_readPos(string map, float t) {
1853         float i;
1854         for (i = 1; i <= RANKINGS_CNT; ++i)
1855                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1856                         return i;
1857
1858         return 0; // pos is zero if unranked
1859 }
1860
1861 void race_writeTime(string map, float t, string myuid)
1862 {
1863         string rr;
1864         if(g_cts)
1865                 rr = CTS_RECORD;
1866         else
1867                 rr = RACE_RECORD;
1868
1869         float newpos;
1870         newpos = race_readPos(map, t);
1871
1872         float i, prevpos = 0;
1873         for(i = 1; i <= RANKINGS_CNT; ++i)
1874         {
1875                 if(race_readUID(map, i) == myuid)
1876                         prevpos = i;
1877         }
1878         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1879                 for (i = prevpos; i > newpos; --i) {
1880                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1881                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1882                 }
1883         } else { // player has no ranked record yet
1884                 for (i = RANKINGS_CNT; i > newpos; --i) {
1885                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1886                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1887                 }
1888         }
1889
1890         // store new time itself
1891         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1892         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1893 }
1894
1895 string race_readName(string map, float pos)
1896 {
1897         string rr;
1898         if(g_cts)
1899                 rr = CTS_RECORD;
1900         else
1901                 rr = RACE_RECORD;
1902
1903         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1904 }
1905
1906 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1907 {
1908     float m, i;
1909     vector start, org, delta, end, enddown, mstart;
1910     entity sp;
1911
1912     m = e.dphitcontentsmask;
1913     e.dphitcontentsmask = goodcontents | badcontents;
1914
1915     org = world.mins;
1916     delta = world.maxs - world.mins;
1917
1918     start = end = org;
1919
1920     for (i = 0; i < attempts; ++i)
1921     {
1922         start_x = org_x + random() * delta_x;
1923         start_y = org_y + random() * delta_y;
1924         start_z = org_z + random() * delta_z;
1925
1926         // rule 1: start inside world bounds, and outside
1927         // solid, and don't start from somewhere where you can
1928         // fall down to evil
1929         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1930         if (trace_fraction >= 1)
1931             continue;
1932         if (trace_startsolid)
1933             continue;
1934         if (trace_dphitcontents & badcontents)
1935             continue;
1936         if (trace_dphitq3surfaceflags & badsurfaceflags)
1937             continue;
1938
1939         // rule 2: if we are too high, lower the point
1940         if (trace_fraction * delta_z > maxaboveground)
1941             start = trace_endpos + '0 0 1' * maxaboveground;
1942         enddown = trace_endpos;
1943
1944         // rule 3: make sure we aren't outside the map. This only works
1945         // for somewhat well formed maps. A good rule of thumb is that
1946         // the map should have a convex outside hull.
1947         // these can be traceLINES as we already verified the starting box
1948         mstart = start + 0.5 * (e.mins + e.maxs);
1949         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1950         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1951             continue;
1952         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1953         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1954             continue;
1955         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1956         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1957             continue;
1958         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1959         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1960             continue;
1961         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1962         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1963             continue;
1964
1965         // rule 4: we must "see" some spawnpoint or item
1966         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1967                 if(checkpvs(mstart, sp))
1968                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1969                                 break;
1970         if(!sp)
1971         {
1972                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1973                         if(checkpvs(mstart, sp))
1974                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1975                                         break;
1976                 if(!sp)
1977                         continue;
1978         }
1979
1980         // find a random vector to "look at"
1981         end_x = org_x + random() * delta_x;
1982         end_y = org_y + random() * delta_y;
1983         end_z = org_z + random() * delta_z;
1984         end = start + normalize(end - start) * vlen(delta);
1985
1986         // rule 4: start TO end must not be too short
1987         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1988         if (trace_startsolid)
1989             continue;
1990         if (trace_fraction < minviewdistance / vlen(delta))
1991             continue;
1992
1993         // rule 5: don't want to look at sky
1994         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1995             continue;
1996
1997         // rule 6: we must not end up in trigger_hurt
1998         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1999             continue;
2000
2001         break;
2002     }
2003
2004     e.dphitcontentsmask = m;
2005
2006     if (i < attempts)
2007     {
2008         setorigin(e, start);
2009         e.angles = vectoangles(end - start);
2010         dprint("Needed ", ftos(i + 1), " attempts\n");
2011         return TRUE;
2012     }
2013     else
2014         return FALSE;
2015 }
2016
2017 void write_recordmarker(entity pl, float tstart, float dt)
2018 {
2019     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2020
2021     // also write a marker into demo files for demotc-race-record-extractor to find
2022     stuffcmd(pl,
2023              strcat(
2024                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2025                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2026 }
2027
2028 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2029 {
2030         switch(algn)
2031         {
2032                 default:
2033                 case 3: // right
2034                         break;
2035
2036                 case 4: // left
2037                         vecs_y = -vecs_y;
2038                         break;
2039
2040                 case 1:
2041                         if(allowcenter) // 2: allow center handedness
2042                         {
2043                                 // center
2044                                 vecs_y = 0;
2045                                 vecs_z -= 2;
2046                         }
2047                         else
2048                         {
2049                                 // right
2050                         }
2051                         break;
2052
2053                 case 2:
2054                         if(allowcenter) // 2: allow center handedness
2055                         {
2056                                 // center
2057                                 vecs_y = 0;
2058                                 vecs_z -= 2;
2059                         }
2060                         else
2061                         {
2062                                 // left
2063                                 vecs_y = -vecs_y;
2064                         }
2065                         break;
2066         }
2067         return vecs;
2068 }
2069
2070 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2071 {
2072         string s;
2073         vector v;
2074
2075         if (autocvar_g_shootfromeye)
2076         {
2077                 if (visual)
2078                 {
2079                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2080                         else { vecs_y = 0; vecs_z -= 2; }
2081                 }
2082                 else
2083                 {
2084                         vecs_y = 0;
2085                         vecs_z = 0;
2086                 }
2087         }
2088         else if (autocvar_g_shootfromcenter)
2089         {
2090                 vecs_y = 0;
2091                 vecs_z -= 2;
2092         }
2093         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2094         {
2095                 v = stov(s);
2096                 if (y_is_right)
2097                         v_y = -v_y;
2098                 if (v_x != 0)
2099                         vecs_x = v_x;
2100                 vecs_y = v_y;
2101                 vecs_z = v_z;
2102         }
2103         else if (autocvar_g_shootfromclient)
2104         {
2105                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2106         }
2107         return vecs;
2108 }
2109
2110 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2111 {
2112         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2113 }
2114
2115
2116 void attach_sameorigin(entity e, entity to, string tag)
2117 {
2118     vector org, t_forward, t_left, t_up, e_forward, e_up;
2119     float tagscale;
2120
2121     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2122     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2123     t_forward = v_forward * tagscale;
2124     t_left = v_right * -tagscale;
2125     t_up = v_up * tagscale;
2126
2127     e.origin_x = org * t_forward;
2128     e.origin_y = org * t_left;
2129     e.origin_z = org * t_up;
2130
2131     // current forward and up directions
2132     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2133                 e.angles = AnglesTransform_FromVAngles(e.angles);
2134         else
2135                 e.angles = AnglesTransform_FromAngles(e.angles);
2136     fixedmakevectors(e.angles);
2137
2138     // untransform forward, up!
2139     e_forward_x = v_forward * t_forward;
2140     e_forward_y = v_forward * t_left;
2141     e_forward_z = v_forward * t_up;
2142     e_up_x = v_up * t_forward;
2143     e_up_y = v_up * t_left;
2144     e_up_z = v_up * t_up;
2145
2146     e.angles = fixedvectoangles2(e_forward, e_up);
2147     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2148                 e.angles = AnglesTransform_ToVAngles(e.angles);
2149         else
2150                 e.angles = AnglesTransform_ToAngles(e.angles);
2151
2152     setattachment(e, to, tag);
2153     setorigin(e, e.origin);
2154 }
2155
2156 void detach_sameorigin(entity e)
2157 {
2158     vector org;
2159     org = gettaginfo(e, 0);
2160     e.angles = fixedvectoangles2(v_forward, v_up);
2161     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2162                 e.angles = AnglesTransform_ToVAngles(e.angles);
2163         else
2164                 e.angles = AnglesTransform_ToAngles(e.angles);
2165     setorigin(e, org);
2166     setattachment(e, world, "");
2167     setorigin(e, e.origin);
2168 }
2169
2170 void follow_sameorigin(entity e, entity to)
2171 {
2172     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2173     e.aiment = to; // make the hole follow bmodel
2174     e.punchangle = to.angles; // the original angles of bmodel
2175     e.view_ofs = e.origin - to.origin; // relative origin
2176     e.v_angle = e.angles - to.angles; // relative angles
2177 }
2178
2179 void unfollow_sameorigin(entity e)
2180 {
2181     e.movetype = MOVETYPE_NONE;
2182 }
2183
2184 entity gettaginfo_relative_ent;
2185 vector gettaginfo_relative(entity e, float tag)
2186 {
2187     if (!gettaginfo_relative_ent)
2188     {
2189         gettaginfo_relative_ent = spawn();
2190         gettaginfo_relative_ent.effects = EF_NODRAW;
2191     }
2192     gettaginfo_relative_ent.model = e.model;
2193     gettaginfo_relative_ent.modelindex = e.modelindex;
2194     gettaginfo_relative_ent.frame = e.frame;
2195     return gettaginfo(gettaginfo_relative_ent, tag);
2196 }
2197
2198 .float scale2;
2199
2200 float modeleffect_SendEntity(entity to, float sf)
2201 {
2202         float f;
2203         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2204
2205         f = 0;
2206         if(self.velocity != '0 0 0')
2207                 f |= 1;
2208         if(self.angles != '0 0 0')
2209                 f |= 2;
2210         if(self.avelocity != '0 0 0')
2211                 f |= 4;
2212
2213         WriteByte(MSG_ENTITY, f);
2214         WriteShort(MSG_ENTITY, self.modelindex);
2215         WriteByte(MSG_ENTITY, self.skin);
2216         WriteByte(MSG_ENTITY, self.frame);
2217         WriteCoord(MSG_ENTITY, self.origin_x);
2218         WriteCoord(MSG_ENTITY, self.origin_y);
2219         WriteCoord(MSG_ENTITY, self.origin_z);
2220         if(f & 1)
2221         {
2222                 WriteCoord(MSG_ENTITY, self.velocity_x);
2223                 WriteCoord(MSG_ENTITY, self.velocity_y);
2224                 WriteCoord(MSG_ENTITY, self.velocity_z);
2225         }
2226         if(f & 2)
2227         {
2228                 WriteCoord(MSG_ENTITY, self.angles_x);
2229                 WriteCoord(MSG_ENTITY, self.angles_y);
2230                 WriteCoord(MSG_ENTITY, self.angles_z);
2231         }
2232         if(f & 4)
2233         {
2234                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2235                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2236                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2237         }
2238         WriteShort(MSG_ENTITY, self.scale * 256.0);
2239         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2240         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2241         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2242         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2243
2244         return TRUE;
2245 }
2246
2247 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2248 {
2249         entity e;
2250         float sz;
2251         e = spawn();
2252         e.classname = "modeleffect";
2253         setmodel(e, m);
2254         e.frame = f;
2255         setorigin(e, o);
2256         e.velocity = v;
2257         e.angles = ang;
2258         e.avelocity = angv;
2259         e.alpha = a;
2260         e.teleport_time = t1;
2261         e.fade_time = t2;
2262         e.skin = s;
2263         if(s0 >= 0)
2264                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2265         else
2266                 e.scale = -s0;
2267         if(s2 >= 0)
2268                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2269         else
2270                 e.scale2 = -s2;
2271         sz = max(e.scale, e.scale2);
2272         setsize(e, e.mins * sz, e.maxs * sz);
2273         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2274 }
2275
2276 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2277 {
2278         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2279 }
2280
2281 float randombit(float bits)
2282 {
2283         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2284                 return bits;
2285
2286         float n, f, b, r;
2287
2288         r = random();
2289         b = 0;
2290         n = 0;
2291
2292         for(f = 1; f <= bits; f *= 2)
2293         {
2294                 if(bits & f)
2295                 {
2296                         ++n;
2297                         r *= n;
2298                         if(r <= 1)
2299                                 b = f;
2300                         else
2301                                 r = (r - 1) / (n - 1);
2302                 }
2303         }
2304
2305         return b;
2306 }
2307
2308 float randombits(float bits, float k, float error_return)
2309 {
2310         float r;
2311         r = 0;
2312         while(k > 0 && bits != r)
2313         {
2314                 r += randombit(bits - r);
2315                 --k;
2316         }
2317         if(error_return)
2318                 if(k > 0)
2319                         return -1; // all
2320         return r;
2321 }
2322
2323 void randombit_test(float bits, float iter)
2324 {
2325         while(iter > 0)
2326         {
2327                 print(ftos(randombit(bits)), "\n");
2328                 --iter;
2329         }
2330 }
2331
2332 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2333 {
2334         if(halflifedist > 0)
2335                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2336         else if(halflifedist < 0)
2337                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2338         else
2339                 return 1;
2340 }
2341
2342
2343
2344
2345 #ifdef RELEASE
2346 #define cvar_string_normal builtin_cvar_string
2347 #define cvar_normal builtin_cvar
2348 #else
2349 string cvar_string_normal(string n)
2350 {
2351         if (!(cvar_type(n) & 1))
2352                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2353         return builtin_cvar_string(n);
2354 }
2355
2356 float cvar_normal(string n)
2357 {
2358         return stof(cvar_string_normal(n));
2359 }
2360 #endif
2361 #define cvar_set_normal builtin_cvar_set
2362
2363 void defer_think()
2364 {
2365     entity oself;
2366
2367     oself           = self;
2368     self            = self.owner;
2369     oself.think     = SUB_Remove;
2370     oself.nextthink = time;
2371
2372     oself.use();
2373 }
2374
2375 /*
2376     Execute func() after time + fdelay.
2377     self when func is executed = self when defer is called
2378 */
2379 void defer(float fdelay, void() func)
2380 {
2381     entity e;
2382
2383     e           = spawn();
2384     e.owner     = self;
2385     e.use       = func;
2386     e.think     = defer_think;
2387     e.nextthink = time + fdelay;
2388 }
2389
2390 .string aiment_classname;
2391 .float aiment_deadflag;
2392 void SetMovetypeFollow(entity ent, entity e)
2393 {
2394         // FIXME this may not be warpzone aware
2395         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2396         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2397         ent.aiment = e; // make the hole follow bmodel
2398         ent.punchangle = e.angles; // the original angles of bmodel
2399         ent.view_ofs = ent.origin - e.origin; // relative origin
2400         ent.v_angle = ent.angles - e.angles; // relative angles
2401         ent.aiment_classname = strzone(e.classname);
2402         ent.aiment_deadflag = e.deadflag;
2403 }
2404 void UnsetMovetypeFollow(entity ent)
2405 {
2406         ent.movetype = MOVETYPE_FLY;
2407         PROJECTILE_MAKETRIGGER(ent);
2408         ent.aiment = world;
2409 }
2410 float LostMovetypeFollow(entity ent)
2411 {
2412 /*
2413         if(ent.movetype != MOVETYPE_FOLLOW)
2414                 if(ent.aiment)
2415                         error("???");
2416 */
2417         if(ent.aiment)
2418         {
2419                 if(ent.aiment.classname != ent.aiment_classname)
2420                         return 1;
2421                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2422                         return 1;
2423         }
2424         return 0;
2425 }
2426
2427 float isPushable(entity e)
2428 {
2429         if(e.iscreature)
2430                 return TRUE;
2431         if(e.pushable)
2432                 return TRUE;
2433         switch(e.classname)
2434         {
2435                 case "body":
2436                 case "droppedweapon":
2437                 case "keepawayball":
2438                 case "nexball_basketball":
2439                 case "nexball_football":
2440                         return TRUE;
2441                 case "bullet": // antilagged bullets can't hit this either
2442                         return FALSE;
2443         }
2444         if (e.projectiledeathtype)
2445                 return TRUE;
2446         return FALSE;
2447 }