qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 //#NO AUTOCVARS START
 547
 548 float g_pickup_shells;
 549 float g_pickup_shells_max;
 550 float g_pickup_nails;
 551 float g_pickup_nails_max;
 552 float g_pickup_rockets;
 553 float g_pickup_rockets_max;
 554 float g_pickup_cells;
 555 float g_pickup_cells_max;
 556 float g_pickup_fuel;
 557 float g_pickup_fuel_jetpack;
 558 float g_pickup_fuel_max;
 559 float g_pickup_armorsmall;
 560 float g_pickup_armorsmall_max;
 561 float g_pickup_armorsmall_anyway;
 562 float g_pickup_armormedium;
 563 float g_pickup_armormedium_max;
 564 float g_pickup_armormedium_anyway;
 565 float g_pickup_armorbig;
 566 float g_pickup_armorbig_max;
 567 float g_pickup_armorbig_anyway;
 568 float g_pickup_armorlarge;
 569 float g_pickup_armorlarge_max;
 570 float g_pickup_armorlarge_anyway;
 571 float g_pickup_healthsmall;
 572 float g_pickup_healthsmall_max;
 573 float g_pickup_healthsmall_anyway;
 574 float g_pickup_healthmedium;
 575 float g_pickup_healthmedium_max;
 576 float g_pickup_healthmedium_anyway;
 577 float g_pickup_healthlarge;
 578 float g_pickup_healthlarge_max;
 579 float g_pickup_healthlarge_anyway;
 580 float g_pickup_healthmega;
 581 float g_pickup_healthmega_max;
 582 float g_pickup_healthmega_anyway;
 583 float g_pickup_ammo_anyway;
 584 float g_pickup_weapons_anyway;
 585 float g_weaponarena;
 586 WepSet g_weaponarena_weapons;
 587 float g_weaponarena_random;
 588 float g_weaponarena_random_with_laser;
 589 string g_weaponarena_list;
 590 float g_weaponspeedfactor;
 591 float g_weaponratefactor;
 592 float g_weapondamagefactor;
 593 float g_weaponforcefactor;
 594 float g_weaponspreadfactor;
 595
 596 WepSet start_weapons;
 597 WepSet start_weapons_default;
 598 WepSet start_weapons_defaultmask;
 599 float start_items;
 600 float start_ammo_shells;
 601 float start_ammo_nails;
 602 float start_ammo_rockets;
 603 float start_ammo_cells;
 604 float start_ammo_fuel;
 605 float start_health;
 606 float start_armorvalue;
 607 WepSet warmup_start_weapons;
 608 WepSet warmup_start_weapons_default;
 609 WepSet warmup_start_weapons_defaultmask;
 610 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 611 float warmup_start_ammo_shells;
 612 float warmup_start_ammo_nails;
 613 float warmup_start_ammo_rockets;
 614 float warmup_start_ammo_cells;
 615 float warmup_start_ammo_fuel;
 616 float warmup_start_health;
 617 float warmup_start_armorvalue;
 618 float g_weapon_stay;
 619
 620 entity get_weaponinfo(float w);
 621
 622 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 623 {
 624         var float i = weaponinfo.weapon;
 625         var float d = 0;
 626
 627         if (!i)
 628                 return 0;
 629
 630         if (g_lms || g_ca || allguns)
 631         {
 632                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 633                         d = TRUE;
 634                 else
 635                         d = FALSE;
 636         }
 637         else if (g_cts)
 638                 d = (i == WEP_SHOTGUN);
 639         else if (g_nexball)
 640                 d = 0; // weapon is set a few lines later
 641         else
 642                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 643
 644         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 645                 d |= (i == WEP_HOOK);
 646         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 647                 d = 0;
 648
 649         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 650
 651         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 652
 653         // bit order in t:
 654         // 1: want or not
 655         // 2: is default?
 656         // 4: is set by default?
 657         if(t < 0)
 658                 t = 4 | (3 * d);
 659         else
 660                 t |= (2 * d);
 661
 662         return t;
 663 }
 664
 665 void readplayerstartcvars()
 666 {
 667         entity e;
 668         float i, j, t;
 669         string s;
 670
 671         // initialize starting values for players
 672         start_weapons = '0 0 0';
 673         start_weapons_default = '0 0 0';
 674         start_weapons_defaultmask = '0 0 0';
 675         start_items = 0;
 676         start_ammo_shells = 0;
 677         start_ammo_nails = 0;
 678         start_ammo_rockets = 0;
 679         start_ammo_cells = 0;
 680         start_health = cvar("g_balance_health_start");
 681         start_armorvalue = cvar("g_balance_armor_start");
 682
 683         g_weaponarena = 0;
 684         g_weaponarena_weapons = '0 0 0';
 685
 686         s = cvar_string("g_weaponarena");
 687         if (s == "0" || s == "")
 688         {
 689                 if(g_ca)
 690                         s = "most";
 691         }
 692
 693         if (s == "0" || s == "")
 694         {
 695                 // no arena
 696         }
 697         else if (s == "off")
 698         {
 699                 // forcibly turn off weaponarena
 700         }
 701         else if (s == "all")
 702         {
 703                 g_weaponarena = 1;
 704                 g_weaponarena_list = "All Weapons";
 705                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 706                 {
 707                         e = get_weaponinfo(j);
 708                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 709                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 710                 }
 711         }
 712         else if (s == "most")
 713         {
 714                 g_weaponarena = 1;
 715                 g_weaponarena_list = "Most Weapons";
 716                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 717                 {
 718                         e = get_weaponinfo(j);
 719                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 720                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 721                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 722                 }
 723         }
 724         else if (s == "none")
 725         {
 726                 g_weaponarena = 1;
 727                 g_weaponarena_list = "No Weapons";
 728         }
 729         else
 730         {
 731                 g_weaponarena = 1;
 732                 t = tokenize_console(s);
 733                 g_weaponarena_list = "";
 734                 for (i = 0; i < t; ++i)
 735                 {
 736                         s = argv(i);
 737                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 738                         {
 739                                 e = get_weaponinfo(j);
 740                                 if (e.netname == s)
 741                                 {
 742                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 743                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 744                                         break;
 745                                 }
 746                         }
 747                         if (j > WEP_LAST)
 748                         {
 749                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 750                         }
 751                 }
 752                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 753         }
 754
 755         if(g_weaponarena)
 756                 g_weaponarena_random = cvar("g_weaponarena_random");
 757         else
 758                 g_weaponarena_random = 0;
 759         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 760
 761         if (g_weaponarena)
 762         {
 763                 g_weapon_stay = 0; // incompatible
 764                 start_weapons = g_weaponarena_weapons;
 765                 start_items |= IT_UNLIMITED_AMMO;
 766         }
 767         else
 768         {
 769                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 770                 {
 771                         e = get_weaponinfo(i);
 772                         float w = want_weapon("g_start_weapon_", e, FALSE);
 773                         if(w & 1)
 774                                 start_weapons |= WepSet_FromWeapon(i);
 775                         if(w & 2)
 776                                 start_weapons_default |= WepSet_FromWeapon(i);
 777                         if(w & 4)
 778                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 779                 }
 780         }
 781
 782         if(!cvar("g_use_ammunition"))
 783                 start_items |= IT_UNLIMITED_AMMO;
 784
 785         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 786         {
 787                 start_ammo_rockets = 999;
 788                 start_ammo_shells = 999;
 789                 start_ammo_cells = 999;
 790                 start_ammo_nails = 999;
 791                 start_ammo_fuel = 999;
 792         }
 793         else
 794         {
 795                 start_ammo_shells = cvar("g_start_ammo_shells");
 796                 start_ammo_nails = cvar("g_start_ammo_nails");
 797                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 798                 start_ammo_cells = cvar("g_start_ammo_cells");
 799                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 800         }
 801
 802         if (warmup_stage)
 803         {
 804                 warmup_start_ammo_shells = start_ammo_shells;
 805                 warmup_start_ammo_nails = start_ammo_nails;
 806                 warmup_start_ammo_rockets = start_ammo_rockets;
 807                 warmup_start_ammo_cells = start_ammo_cells;
 808                 warmup_start_ammo_fuel = start_ammo_fuel;
 809                 warmup_start_health = start_health;
 810                 warmup_start_armorvalue = start_armorvalue;
 811                 warmup_start_weapons = start_weapons;
 812                 warmup_start_weapons_default = start_weapons_default;
 813                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 814
 815                 if (!g_weaponarena && !g_ca)
 816                 {
 817                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 818                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 819                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 820                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 821                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 822                         warmup_start_health = cvar("g_warmup_start_health");
 823                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 824                         warmup_start_weapons = '0 0 0';
 825                         warmup_start_weapons_default = '0 0 0';
 826                         warmup_start_weapons_defaultmask = '0 0 0';
 827                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 828                         {
 829                                 e = get_weaponinfo(i);
 830                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 831                                 if(w & 1)
 832                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 833                                 if(w & 2)
 834                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 835                                 if(w & 4)
 836                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 837                         }
 838                 }
 839         }
 840
 841         if (g_jetpack)
 842                 start_items |= IT_JETPACK;
 843
 844         MUTATOR_CALLHOOK(SetStartItems);
 845
 846         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 847         {
 848                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 849                 start_items |= IT_FUEL_REGEN;
 850                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 851                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 852         }
 853
 854         WepSet precache_weapons = start_weapons;
 855         if (g_warmup_allguns != 1)
 856                 precache_weapons |= warmup_start_weapons;
 857         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 858         {
 859                 e = get_weaponinfo(i);
 860                 if(precache_weapons & WepSet_FromWeapon(i))
 861                         weapon_action(i, WR_PRECACHE);
 862         }
 863
 864         start_ammo_shells = max(0, start_ammo_shells);
 865         start_ammo_nails = max(0, start_ammo_nails);
 866         start_ammo_cells = max(0, start_ammo_cells);
 867         start_ammo_rockets = max(0, start_ammo_rockets);
 868         start_ammo_fuel = max(0, start_ammo_fuel);
 869
 870         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 871         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 872         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 873         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 874         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 875 }
 876
 877 float g_bugrigs;
 878 float g_bugrigs_planar_movement;
 879 float g_bugrigs_planar_movement_car_jumping;
 880 float g_bugrigs_reverse_spinning;
 881 float g_bugrigs_reverse_speeding;
 882 float g_bugrigs_reverse_stopping;
 883 float g_bugrigs_air_steering;
 884 float g_bugrigs_angle_smoothing;
 885 float g_bugrigs_friction_floor;
 886 float g_bugrigs_friction_brake;
 887 float g_bugrigs_friction_air;
 888 float g_bugrigs_accel;
 889 float g_bugrigs_speed_ref;
 890 float g_bugrigs_speed_pow;
 891 float g_bugrigs_steer;
 892
 893 float sv_autotaunt;
 894 float sv_taunt;
 895
 896 string GetGametype(); // g_world.qc
 897 void readlevelcvars(void)
 898 {
 899         // load mutators
 900         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 901                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 902
 903         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 904         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, teamplay);
 905         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 906         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 907         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 908         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 909         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 910         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 911         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 912         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 913         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 914         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 915         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 916         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 918         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 919         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 921         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 922         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 923
 924         #undef CHECK_MUTATOR_ADD
 925
 926         if(cvar("sv_allow_fullbright"))
 927                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 928
 929     g_bugrigs = cvar("g_bugrigs");
 930     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 931     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 932     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 933     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 934     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 935     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 936     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 937     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 938     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 939     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 940     g_bugrigs_accel = cvar("g_bugrigs_accel");
 941     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 942     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 943     g_bugrigs_steer = cvar("g_bugrigs_steer");
 944
 945         g_minstagib = cvar("g_minstagib");
 946
 947         sv_clones = cvar("sv_clones");
 948         sv_foginterval = cvar("sv_foginterval");
 949         g_cloaked = cvar("g_cloaked");
 950     if(g_cts)
 951         g_cloaked = 1; // always enable cloak in CTS
 952         g_footsteps = cvar("g_footsteps");
 953         g_grappling_hook = cvar("g_grappling_hook");
 954         g_jetpack = cvar("g_jetpack");
 955         sv_maxidle = cvar("sv_maxidle");
 956         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 957         sv_autotaunt = cvar("sv_autotaunt");
 958         sv_taunt = cvar("sv_taunt");
 959
 960         warmup_stage = cvar("g_warmup");
 961         g_warmup_limit = cvar("g_warmup_limit");
 962         g_warmup_allguns = cvar("g_warmup_allguns");
 963         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 964
 965         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 966                 warmup_stage = 0; // these modes cannot work together, sorry
 967
 968         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 969         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 970         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 971         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 972         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 973         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 974         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 975         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 976         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 977         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 978         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 979         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 980         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 981         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 982
 983         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 984         g_weaponratefactor = cvar("g_weaponratefactor");
 985         g_weapondamagefactor = cvar("g_weapondamagefactor");
 986         g_weaponforcefactor = cvar("g_weaponforcefactor");
 987         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 988
 989         g_pickup_shells = cvar("g_pickup_shells");
 990         g_pickup_shells_max = cvar("g_pickup_shells_max");
 991         g_pickup_nails = cvar("g_pickup_nails");
 992         g_pickup_nails_max = cvar("g_pickup_nails_max");
 993         g_pickup_rockets = cvar("g_pickup_rockets");
 994         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 995         g_pickup_cells = cvar("g_pickup_cells");
 996         g_pickup_cells_max = cvar("g_pickup_cells_max");
 997         g_pickup_fuel = cvar("g_pickup_fuel");
 998         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 999         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1000         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1001         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1002         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1003         g_pickup_armormedium = cvar("g_pickup_armormedium");
1004         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1005         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1006         g_pickup_armorbig = cvar("g_pickup_armorbig");
1007         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1008         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1009         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1010         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1011         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1012         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1013         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1014         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1015         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1016         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1017         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1018         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1019         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1020         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1021         g_pickup_healthmega = cvar("g_pickup_healthmega");
1022         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1023         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1024
1025         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1026         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1027
1028     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1029     if(!g_weapon_stay)
1030         g_weapon_stay = cvar("g_weapon_stay");
1031
1032         if (!warmup_stage)
1033                 game_starttime = time + cvar("g_start_delay");
1034
1035         readplayerstartcvars();
1036 }
1037
1038 //#NO AUTOCVARS END
1039
1040 // Sound functions
1041 string precache_sound (string s) = #19;
1042 float precache_sound_index (string s) = #19;
1043
1044 #define SND_VOLUME      1
1045 #define SND_ATTENUATION 2
1046 #define SND_LARGEENTITY 8
1047 #define SND_LARGESOUND  16
1048
1049 float sound_allowed(float dest, entity e)
1050 {
1051     // sounds from world may always pass
1052     for (;;)
1053     {
1054         if (e.classname == "body")
1055             e = e.enemy;
1056         else if (e.realowner && e.realowner != e)
1057             e = e.realowner;
1058         else if (e.owner && e.owner != e)
1059             e = e.owner;
1060         else
1061             break;
1062     }
1063     // sounds to self may always pass
1064     if (dest == MSG_ONE)
1065         if (e == msg_entity)
1066             return TRUE;
1067     // sounds by players can be removed
1068     if (autocvar_bot_sound_monopoly)
1069         if (IS_REAL_CLIENT(e))
1070             return FALSE;
1071     // anything else may pass
1072     return TRUE;
1073 }
1074
1075 #ifdef COMPAT_XON010_CHANNELS
1076 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1077 void sound(entity e, float chan, string samp, float vol, float atten)
1078 {
1079     if (!sound_allowed(MSG_BROADCAST, e))
1080         return;
1081     builtin_sound(e, chan, samp, vol, atten);
1082 }
1083 #else
1084 #undef sound
1085 void sound(entity e, float chan, string samp, float vol, float atten)
1086 {
1087     if (!sound_allowed(MSG_BROADCAST, e))
1088         return;
1089     sound7(e, chan, samp, vol, atten, 0, 0);
1090 }
1091 #endif
1092
1093 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1094 {
1095     float entno, idx;
1096
1097     if (!sound_allowed(dest, e))
1098         return;
1099
1100     entno = num_for_edict(e);
1101     idx = precache_sound_index(samp);
1102
1103     float sflags;
1104     sflags = 0;
1105
1106     atten = floor(atten * 64);
1107     vol = floor(vol * 255);
1108
1109     if (vol != 255)
1110         sflags |= SND_VOLUME;
1111     if (atten != 64)
1112         sflags |= SND_ATTENUATION;
1113     if (entno >= 8192 || chan < 0 || chan > 7)
1114         sflags |= SND_LARGEENTITY;
1115     if (idx >= 256)
1116         sflags |= SND_LARGESOUND;
1117
1118     WriteByte(dest, SVC_SOUND);
1119     WriteByte(dest, sflags);
1120     if (sflags & SND_VOLUME)
1121         WriteByte(dest, vol);
1122     if (sflags & SND_ATTENUATION)
1123         WriteByte(dest, atten);
1124     if (sflags & SND_LARGEENTITY)
1125     {
1126         WriteShort(dest, entno);
1127         WriteByte(dest, chan);
1128     }
1129     else
1130     {
1131         WriteShort(dest, entno * 8 + chan);
1132     }
1133     if (sflags & SND_LARGESOUND)
1134         WriteShort(dest, idx);
1135     else
1136         WriteByte(dest, idx);
1137
1138     WriteCoord(dest, o_x);
1139     WriteCoord(dest, o_y);
1140     WriteCoord(dest, o_z);
1141 }
1142 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1143 {
1144     vector o;
1145
1146     if (!sound_allowed(dest, e))
1147         return;
1148
1149     o = e.origin + 0.5 * (e.mins + e.maxs);
1150     soundtoat(dest, e, o, chan, samp, vol, atten);
1151 }
1152 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1153 {
1154     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1155 }
1156 void stopsoundto(float dest, entity e, float chan)
1157 {
1158     float entno;
1159
1160     if (!sound_allowed(dest, e))
1161         return;
1162
1163     entno = num_for_edict(e);
1164
1165     if (entno >= 8192 || chan < 0 || chan > 7)
1166     {
1167         float idx, sflags;
1168         idx = precache_sound_index("misc/null.wav");
1169         sflags = SND_LARGEENTITY;
1170         if (idx >= 256)
1171             sflags |= SND_LARGESOUND;
1172         WriteByte(dest, SVC_SOUND);
1173         WriteByte(dest, sflags);
1174         WriteShort(dest, entno);
1175         WriteByte(dest, chan);
1176         if (sflags & SND_LARGESOUND)
1177             WriteShort(dest, idx);
1178         else
1179             WriteByte(dest, idx);
1180         WriteCoord(dest, e.origin_x);
1181         WriteCoord(dest, e.origin_y);
1182         WriteCoord(dest, e.origin_z);
1183     }
1184     else
1185     {
1186         WriteByte(dest, SVC_STOPSOUND);
1187         WriteShort(dest, entno * 8 + chan);
1188     }
1189 }
1190 void stopsound(entity e, float chan)
1191 {
1192     if (!sound_allowed(MSG_BROADCAST, e))
1193         return;
1194
1195     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1196     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1197 }
1198
1199 void play2(entity e, string filename)
1200 {
1201     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1202     msg_entity = e;
1203     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1204 }
1205
1206 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1207 .float spamtime;
1208 float spamsound(entity e, float chan, string samp, float vol, float atten)
1209 {
1210     if (!sound_allowed(MSG_BROADCAST, e))
1211         return FALSE;
1212
1213     if (time > e.spamtime)
1214     {
1215         e.spamtime = time;
1216         sound(e, chan, samp, vol, atten);
1217         return TRUE;
1218     }
1219     return FALSE;
1220 }
1221
1222 void play2team(float t, string filename)
1223 {
1224     entity head;
1225
1226     if (autocvar_bot_sound_monopoly)
1227         return;
1228
1229     FOR_EACH_REALPLAYER(head)
1230     {
1231         if (head.team == t)
1232             play2(head, filename);
1233     }
1234 }
1235
1236 void play2all(string samp)
1237 {
1238     if (autocvar_bot_sound_monopoly)
1239         return;
1240
1241     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1242 }
1243
1244 void PrecachePlayerSounds(string f);
1245 void precache_playermodel(string m)
1246 {
1247         float globhandle, i, n;
1248         string f;
1249
1250         if(substring(m, -9,5) == "_lod1")
1251                 return;
1252         if(substring(m, -9,5) == "_lod2")
1253                 return;
1254         precache_model(m);
1255         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1256         if(fexists(f))
1257                 precache_model(f);
1258         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1259         if(fexists(f))
1260                 precache_model(f);
1261
1262         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1263         if (globhandle < 0)
1264                 return;
1265         n = search_getsize(globhandle);
1266         for (i = 0; i < n; ++i)
1267         {
1268                 //print(search_getfilename(globhandle, i), "\n");
1269                 f = search_getfilename(globhandle, i);
1270                 PrecachePlayerSounds(f);
1271         }
1272         search_end(globhandle);
1273 }
1274 void precache_all_playermodels(string pattern)
1275 {
1276         float globhandle, i, n;
1277         string f;
1278
1279         globhandle = search_begin(pattern, TRUE, FALSE);
1280         if (globhandle < 0)
1281                 return;
1282         n = search_getsize(globhandle);
1283         for (i = 0; i < n; ++i)
1284         {
1285                 //print(search_getfilename(globhandle, i), "\n");
1286                 f = search_getfilename(globhandle, i);
1287                 precache_playermodel(f);
1288         }
1289         search_end(globhandle);
1290 }
1291
1292 void precache()
1293 {
1294     // gamemode related things
1295     precache_model ("models/misc/chatbubble.spr");
1296
1297 #ifdef TTURRETS_ENABLED
1298     if (autocvar_g_turrets)
1299         turrets_precash();
1300 #endif
1301
1302     // Precache all player models if desired
1303     if (autocvar_sv_precacheplayermodels)
1304     {
1305         PrecachePlayerSounds("sound/player/default.sounds");
1306         precache_all_playermodels("models/player/*.zym");
1307         precache_all_playermodels("models/player/*.dpm");
1308         precache_all_playermodels("models/player/*.md3");
1309         precache_all_playermodels("models/player/*.psk");
1310         precache_all_playermodels("models/player/*.iqm");
1311     }
1312
1313     if (autocvar_sv_defaultcharacter)
1314     {
1315         string s;
1316         s = autocvar_sv_defaultplayermodel_red;
1317         if (s != "")
1318             precache_playermodel(s);
1319         s = autocvar_sv_defaultplayermodel_blue;
1320         if (s != "")
1321             precache_playermodel(s);
1322         s = autocvar_sv_defaultplayermodel_yellow;
1323         if (s != "")
1324             precache_playermodel(s);
1325         s = autocvar_sv_defaultplayermodel_pink;
1326         if (s != "")
1327             precache_playermodel(s);
1328         s = autocvar_sv_defaultplayermodel;
1329         if (s != "")
1330             precache_playermodel(s);
1331     }
1332
1333     if (g_footsteps)
1334     {
1335         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1336         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1337     }
1338
1339     // gore and miscellaneous sounds
1340     //precache_sound ("misc/h2ohit.wav");
1341     precache_model ("models/hook.md3");
1342     precache_sound ("misc/armorimpact.wav");
1343     precache_sound ("misc/bodyimpact1.wav");
1344     precache_sound ("misc/bodyimpact2.wav");
1345     precache_sound ("misc/gib.wav");
1346     precache_sound ("misc/gib_splat01.wav");
1347     precache_sound ("misc/gib_splat02.wav");
1348     precache_sound ("misc/gib_splat03.wav");
1349     precache_sound ("misc/gib_splat04.wav");
1350     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1351     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1352     precache_sound ("misc/null.wav");
1353     precache_sound ("misc/spawn.wav");
1354     precache_sound ("misc/talk.wav");
1355     precache_sound ("misc/teleport.wav");
1356     precache_sound ("misc/poweroff.wav");
1357     precache_sound ("player/lava.wav");
1358     precache_sound ("player/slime.wav");
1359
1360     precache_model ("models/sprites/0.spr32");
1361     precache_model ("models/sprites/1.spr32");
1362     precache_model ("models/sprites/2.spr32");
1363     precache_model ("models/sprites/3.spr32");
1364     precache_model ("models/sprites/4.spr32");
1365     precache_model ("models/sprites/5.spr32");
1366     precache_model ("models/sprites/6.spr32");
1367     precache_model ("models/sprites/7.spr32");
1368     precache_model ("models/sprites/8.spr32");
1369     precache_model ("models/sprites/9.spr32");
1370     precache_model ("models/sprites/10.spr32");
1371
1372     // common weapon precaches
1373         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1374     precache_sound ("weapons/weapon_switch.wav");
1375     precache_sound ("weapons/weaponpickup.wav");
1376     precache_sound ("weapons/unavailable.wav");
1377     precache_sound ("weapons/dryfire.wav");
1378     if (g_grappling_hook)
1379     {
1380         precache_sound ("weapons/hook_fire.wav"); // hook
1381         precache_sound ("weapons/hook_impact.wav"); // hook
1382     }
1383
1384     if(autocvar_sv_precacheweapons)
1385     {
1386         //precache weapon models/sounds
1387         float wep;
1388         wep = WEP_FIRST;
1389         while (wep <= WEP_LAST)
1390         {
1391             weapon_action(wep, WR_PRECACHE);
1392             wep = wep + 1;
1393         }
1394     }
1395
1396     precache_model("models/elaser.mdl");
1397     precache_model("models/laser.mdl");
1398     precache_model("models/ebomb.mdl");
1399
1400 #if 0
1401     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1402
1403     if (!self.noise && self.music) // quake 3 uses the music field
1404         self.noise = self.music;
1405
1406     // plays music for the level if there is any
1407     if (self.noise)
1408     {
1409         precache_sound (self.noise);
1410         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1411     }
1412 #endif
1413
1414 #include "precache-for-csqc.inc"
1415 }
1416
1417 // WARNING: this kills the trace globals
1418 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1419 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1420
1421 #define INITPRIO_FIRST              0
1422 #define INITPRIO_GAMETYPE           0
1423 #define INITPRIO_GAMETYPE_FALLBACK  1
1424 #define INITPRIO_FINDTARGET        10
1425 #define INITPRIO_DROPTOFLOOR       20
1426 #define INITPRIO_SETLOCATION       90
1427 #define INITPRIO_LINKDOORS         91
1428 #define INITPRIO_LAST              99
1429
1430 .void(void) initialize_entity;
1431 .float initialize_entity_order;
1432 .entity initialize_entity_next;
1433 entity initialize_entity_first;
1434
1435 void make_safe_for_remove(entity e)
1436 {
1437     if (e.initialize_entity)
1438     {
1439         entity ent, prev = world;
1440         for (ent = initialize_entity_first; ent; )
1441         {
1442             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1443             {
1444                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1445                 // skip it in linked list
1446                 if (prev)
1447                 {
1448                     prev.initialize_entity_next = ent.initialize_entity_next;
1449                     ent = prev.initialize_entity_next;
1450                 }
1451                 else
1452                 {
1453                     initialize_entity_first = ent.initialize_entity_next;
1454                     ent = initialize_entity_first;
1455                 }
1456             }
1457             else
1458             {
1459                 prev = ent;
1460                 ent = ent.initialize_entity_next;
1461             }
1462         }
1463     }
1464 }
1465
1466 void objerror(string s)
1467 {
1468     make_safe_for_remove(self);
1469     builtin_objerror(s);
1470 }
1471
1472 .float remove_except_protected_forbidden;
1473 void remove_except_protected(entity e)
1474 {
1475         if(e.remove_except_protected_forbidden)
1476                 error("not allowed to remove this at this point");
1477         builtin_remove(e);
1478 }
1479
1480 void remove_unsafely(entity e)
1481 {
1482     if(e.classname == "spike")
1483         error("Removing spikes is forbidden (crylink bug), please report");
1484     builtin_remove(e);
1485 }
1486
1487 void remove_safely(entity e)
1488 {
1489     make_safe_for_remove(e);
1490     builtin_remove(e);
1491 }
1492
1493 void InitializeEntity(entity e, void(void) func, float order)
1494 {
1495     entity prev, cur;
1496
1497     if (!e || e.initialize_entity)
1498     {
1499         // make a proxy initializer entity
1500         entity e_old;
1501         e_old = e;
1502         e = spawn();
1503         e.classname = "initialize_entity";
1504         e.enemy = e_old;
1505     }
1506
1507     e.initialize_entity = func;
1508     e.initialize_entity_order = order;
1509
1510     cur = initialize_entity_first;
1511     prev = world;
1512     for (;;)
1513     {
1514         if (!cur || cur.initialize_entity_order > order)
1515         {
1516             // insert between prev and cur
1517             if (prev)
1518                 prev.initialize_entity_next = e;
1519             else
1520                 initialize_entity_first = e;
1521             e.initialize_entity_next = cur;
1522             return;
1523         }
1524         prev = cur;
1525         cur = cur.initialize_entity_next;
1526     }
1527 }
1528 void InitializeEntitiesRun()
1529 {
1530     entity startoflist;
1531     startoflist = initialize_entity_first;
1532     initialize_entity_first = world;
1533     remove = remove_except_protected;
1534     for (self = startoflist; self; self = self.initialize_entity_next)
1535     {
1536         self.remove_except_protected_forbidden = 1;
1537     }
1538     for (self = startoflist; self; )
1539     {
1540         entity e;
1541         var void(void) func;
1542         e = self.initialize_entity_next;
1543         func = self.initialize_entity;
1544         self.initialize_entity_order = 0;
1545         self.initialize_entity = func_null;
1546         self.initialize_entity_next = world;
1547         self.remove_except_protected_forbidden = 0;
1548         if (self.classname == "initialize_entity")
1549         {
1550             entity e_old;
1551             e_old = self.enemy;
1552             builtin_remove(self);
1553             self = e_old;
1554         }
1555         //dprint("Delayed initialization: ", self.classname, "\n");
1556         if(func)
1557             func();
1558         else
1559         {
1560             eprint(self);
1561             backtrace(strcat("Null function in: ", self.classname, "\n"));
1562         }
1563         self = e;
1564     }
1565     remove = remove_unsafely;
1566 }
1567
1568 .float uncustomizeentityforclient_set;
1569 .void(void) uncustomizeentityforclient;
1570 void UncustomizeEntitiesRun()
1571 {
1572     entity oldself;
1573     oldself = self;
1574     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1575         self.uncustomizeentityforclient();
1576     self = oldself;
1577 }
1578 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1579 {
1580     e.customizeentityforclient = customizer;
1581     e.uncustomizeentityforclient = uncustomizer;
1582     e.uncustomizeentityforclient_set = !!uncustomizer;
1583 }
1584
1585 .float nottargeted;
1586 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1587
1588 void() SUB_Remove;
1589 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1590 {
1591     vector mi, ma;
1592
1593     if (e.classname == "")
1594         e.classname = "net_linked";
1595
1596     if (e.model == "" || self.modelindex == 0)
1597     {
1598         mi = e.mins;
1599         ma = e.maxs;
1600         setmodel(e, "null");
1601         setsize(e, mi, ma);
1602     }
1603
1604     e.SendEntity = sendfunc;
1605     e.SendFlags = 0xFFFFFF;
1606
1607     if (!docull)
1608         e.effects |= EF_NODEPTHTEST;
1609
1610     if (dt)
1611     {
1612         e.nextthink = time + dt;
1613         e.think = SUB_Remove;
1614     }
1615 }
1616
1617 void adaptor_think2touch()
1618 {
1619     entity o;
1620     o = other;
1621     other = world;
1622     self.touch();
1623     other = o;
1624 }
1625
1626 void adaptor_think2use()
1627 {
1628     entity o, a;
1629     o = other;
1630     a = activator;
1631     activator = world;
1632     other = world;
1633     self.use();
1634     other = o;
1635     activator = a;
1636 }
1637
1638 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1639 {
1640         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1641                 self.projectiledeathtype |= HITTYPE_SPLASH;
1642         adaptor_think2use();
1643 }
1644
1645 // deferred dropping
1646 void DropToFloor_Handler()
1647 {
1648     builtin_droptofloor();
1649     self.dropped_origin = self.origin;
1650 }
1651
1652 void droptofloor()
1653 {
1654     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1655 }
1656
1657
1658
1659 float trace_hits_box_a0, trace_hits_box_a1;
1660
1661 float trace_hits_box_1d(float end, float thmi, float thma)
1662 {
1663     if (end == 0)
1664     {
1665         // just check if x is in range
1666         if (0 < thmi)
1667             return FALSE;
1668         if (0 > thma)
1669             return FALSE;
1670     }
1671     else
1672     {
1673         // do the trace with respect to x
1674         // 0 -> end has to stay in thmi -> thma
1675         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1676         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1677         if (trace_hits_box_a0 > trace_hits_box_a1)
1678             return FALSE;
1679     }
1680     return TRUE;
1681 }
1682
1683 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1684 {
1685     end -= start;
1686     thmi -= start;
1687     thma -= start;
1688     // now it is a trace from 0 to end
1689
1690     trace_hits_box_a0 = 0;
1691     trace_hits_box_a1 = 1;
1692
1693     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1694         return FALSE;
1695     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1696         return FALSE;
1697     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1698         return FALSE;
1699
1700     return TRUE;
1701 }
1702
1703 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1704 {
1705     return trace_hits_box(start, end, thmi - ma, thma - mi);
1706 }
1707
1708 float SUB_NoImpactCheck()
1709 {
1710         // zero hitcontents = this is not the real impact, but either the
1711         // mirror-impact of something hitting the projectile instead of the
1712         // projectile hitting the something, or a touchareagrid one. Neither of
1713         // these stop the projectile from moving, so...
1714         if(trace_dphitcontents == 0)
1715         {
1716                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1717                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1718                 checkclient();
1719         }
1720     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1721         return 1;
1722     if (other == world && self.size != '0 0 0')
1723     {
1724         vector tic;
1725         tic = self.velocity * sys_frametime;
1726         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1727         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1728         if (trace_fraction >= 1)
1729         {
1730             dprint("Odd... did not hit...?\n");
1731         }
1732         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1733         {
1734             dprint("Detected and prevented the sky-grapple bug.\n");
1735             return 1;
1736         }
1737     }
1738
1739     return 0;
1740 }
1741
1742 #define SUB_OwnerCheck() (other && (other == self.owner))
1743
1744 void RemoveGrapplingHook(entity pl);
1745 void W_Crylink_Dequeue(entity e);
1746 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1747 {
1748         if(SUB_OwnerCheck())
1749                 return TRUE;
1750         if(SUB_NoImpactCheck())
1751         {
1752                 if(self.classname == "grapplinghook")
1753                         RemoveGrapplingHook(self.realowner);
1754                 else if(self.classname == "spike")
1755                 {
1756                         W_Crylink_Dequeue(self);
1757                         remove(self);
1758                 }
1759                 else
1760                         remove(self);
1761                 return TRUE;
1762         }
1763         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1764                 UpdateCSQCProjectile(self);
1765         return FALSE;
1766 }
1767 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1768
1769 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1770 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1771
1772 void URI_Get_Callback(float id, float status, string data)
1773 {
1774         if(url_URI_Get_Callback(id, status, data))
1775         {
1776                 // handled
1777         }
1778         else if (id == URI_GET_DISCARD)
1779         {
1780                 // discard
1781         }
1782         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1783         {
1784                 // sv_cmd curl
1785                 Curl_URI_Get_Callback(id, status, data);
1786         }
1787         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1788         {
1789                 // online ban list
1790                 OnlineBanList_URI_Get_Callback(id, status, data);
1791         }
1792         else
1793         {
1794                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1795         }
1796 }
1797
1798 string uid2name(string myuid) {
1799         string s;
1800         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1801
1802         // FIXME remove this later after 0.6 release
1803         // convert old style broken records to correct style
1804         if(s == "")
1805         {
1806                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1807                 if(s != "")
1808                 {
1809                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1810                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1811                 }
1812         }
1813
1814         if(s == "")
1815                 s = "^1Unregistered Player";
1816         return s;
1817 }
1818
1819 float race_readTime(string map, float pos)
1820 {
1821         string rr;
1822         if(g_cts)
1823                 rr = CTS_RECORD;
1824         else
1825                 rr = RACE_RECORD;
1826
1827         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1828 }
1829
1830 string race_readUID(string map, float pos)
1831 {
1832         string rr;
1833         if(g_cts)
1834                 rr = CTS_RECORD;
1835         else
1836                 rr = RACE_RECORD;
1837
1838         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1839 }
1840
1841 float race_readPos(string map, float t) {
1842         float i;
1843         for (i = 1; i <= RANKINGS_CNT; ++i)
1844                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1845                         return i;
1846
1847         return 0; // pos is zero if unranked
1848 }
1849
1850 void race_writeTime(string map, float t, string myuid)
1851 {
1852         string rr;
1853         if(g_cts)
1854                 rr = CTS_RECORD;
1855         else
1856                 rr = RACE_RECORD;
1857
1858         float newpos;
1859         newpos = race_readPos(map, t);
1860
1861         float i, prevpos = 0;
1862         for(i = 1; i <= RANKINGS_CNT; ++i)
1863         {
1864                 if(race_readUID(map, i) == myuid)
1865                         prevpos = i;
1866         }
1867         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1868                 for (i = prevpos; i > newpos; --i) {
1869                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1870                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1871                 }
1872         } else { // player has no ranked record yet
1873                 for (i = RANKINGS_CNT; i > newpos; --i) {
1874                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1875                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1876                 }
1877         }
1878
1879         // store new time itself
1880         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1881         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1882 }
1883
1884 string race_readName(string map, float pos)
1885 {
1886         string rr;
1887         if(g_cts)
1888                 rr = CTS_RECORD;
1889         else
1890                 rr = RACE_RECORD;
1891
1892         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1893 }
1894
1895 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1896 {
1897     float m, i;
1898     vector start, org, delta, end, enddown, mstart;
1899     entity sp;
1900
1901     m = e.dphitcontentsmask;
1902     e.dphitcontentsmask = goodcontents | badcontents;
1903
1904     org = world.mins;
1905     delta = world.maxs - world.mins;
1906
1907     start = end = org;
1908
1909     for (i = 0; i < attempts; ++i)
1910     {
1911         start_x = org_x + random() * delta_x;
1912         start_y = org_y + random() * delta_y;
1913         start_z = org_z + random() * delta_z;
1914
1915         // rule 1: start inside world bounds, and outside
1916         // solid, and don't start from somewhere where you can
1917         // fall down to evil
1918         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1919         if (trace_fraction >= 1)
1920             continue;
1921         if (trace_startsolid)
1922             continue;
1923         if (trace_dphitcontents & badcontents)
1924             continue;
1925         if (trace_dphitq3surfaceflags & badsurfaceflags)
1926             continue;
1927
1928         // rule 2: if we are too high, lower the point
1929         if (trace_fraction * delta_z > maxaboveground)
1930             start = trace_endpos + '0 0 1' * maxaboveground;
1931         enddown = trace_endpos;
1932
1933         // rule 3: make sure we aren't outside the map. This only works
1934         // for somewhat well formed maps. A good rule of thumb is that
1935         // the map should have a convex outside hull.
1936         // these can be traceLINES as we already verified the starting box
1937         mstart = start + 0.5 * (e.mins + e.maxs);
1938         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1939         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1940             continue;
1941         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1942         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1943             continue;
1944         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1945         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1946             continue;
1947         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1948         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1949             continue;
1950         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1951         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1952             continue;
1953
1954         // rule 4: we must "see" some spawnpoint or item
1955         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1956                 if(checkpvs(mstart, sp))
1957                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1958                                 break;
1959         if(!sp)
1960         {
1961                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1962                         if(checkpvs(mstart, sp))
1963                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1964                                         break;
1965                 if(!sp)
1966                         continue;
1967         }
1968
1969         // find a random vector to "look at"
1970         end_x = org_x + random() * delta_x;
1971         end_y = org_y + random() * delta_y;
1972         end_z = org_z + random() * delta_z;
1973         end = start + normalize(end - start) * vlen(delta);
1974
1975         // rule 4: start TO end must not be too short
1976         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1977         if (trace_startsolid)
1978             continue;
1979         if (trace_fraction < minviewdistance / vlen(delta))
1980             continue;
1981
1982         // rule 5: don't want to look at sky
1983         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1984             continue;
1985
1986         // rule 6: we must not end up in trigger_hurt
1987         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1988             continue;
1989
1990         break;
1991     }
1992
1993     e.dphitcontentsmask = m;
1994
1995     if (i < attempts)
1996     {
1997         setorigin(e, start);
1998         e.angles = vectoangles(end - start);
1999         dprint("Needed ", ftos(i + 1), " attempts\n");
2000         return TRUE;
2001     }
2002     else
2003         return FALSE;
2004 }
2005
2006 void write_recordmarker(entity pl, float tstart, float dt)
2007 {
2008     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2009
2010     // also write a marker into demo files for demotc-race-record-extractor to find
2011     stuffcmd(pl,
2012              strcat(
2013                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2014                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2015 }
2016
2017 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2018 {
2019         switch(algn)
2020         {
2021                 default:
2022                 case 3: // right
2023                         break;
2024
2025                 case 4: // left
2026                         vecs_y = -vecs_y;
2027                         break;
2028
2029                 case 1:
2030                         if(allowcenter) // 2: allow center handedness
2031                         {
2032                                 // center
2033                                 vecs_y = 0;
2034                                 vecs_z -= 2;
2035                         }
2036                         else
2037                         {
2038                                 // right
2039                         }
2040                         break;
2041
2042                 case 2:
2043                         if(allowcenter) // 2: allow center handedness
2044                         {
2045                                 // center
2046                                 vecs_y = 0;
2047                                 vecs_z -= 2;
2048                         }
2049                         else
2050                         {
2051                                 // left
2052                                 vecs_y = -vecs_y;
2053                         }
2054                         break;
2055         }
2056         return vecs;
2057 }
2058
2059 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2060 {
2061         string s;
2062         vector v;
2063
2064         if (autocvar_g_shootfromeye)
2065         {
2066                 if (visual)
2067                 {
2068                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2069                         else { vecs_y = 0; vecs_z -= 2; }
2070                 }
2071                 else
2072                 {
2073                         vecs_y = 0;
2074                         vecs_z = 0;
2075                 }
2076         }
2077         else if (autocvar_g_shootfromcenter)
2078         {
2079                 vecs_y = 0;
2080                 vecs_z -= 2;
2081         }
2082         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2083         {
2084                 v = stov(s);
2085                 if (y_is_right)
2086                         v_y = -v_y;
2087                 if (v_x != 0)
2088                         vecs_x = v_x;
2089                 vecs_y = v_y;
2090                 vecs_z = v_z;
2091         }
2092         else if (autocvar_g_shootfromclient)
2093         {
2094                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2095         }
2096         return vecs;
2097 }
2098
2099 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2100 {
2101         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2102 }
2103
2104
2105 void attach_sameorigin(entity e, entity to, string tag)
2106 {
2107     vector org, t_forward, t_left, t_up, e_forward, e_up;
2108     float tagscale;
2109
2110     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2111     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2112     t_forward = v_forward * tagscale;
2113     t_left = v_right * -tagscale;
2114     t_up = v_up * tagscale;
2115
2116     e.origin_x = org * t_forward;
2117     e.origin_y = org * t_left;
2118     e.origin_z = org * t_up;
2119
2120     // current forward and up directions
2121     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2122                 e.angles = AnglesTransform_FromVAngles(e.angles);
2123         else
2124                 e.angles = AnglesTransform_FromAngles(e.angles);
2125     fixedmakevectors(e.angles);
2126
2127     // untransform forward, up!
2128     e_forward_x = v_forward * t_forward;
2129     e_forward_y = v_forward * t_left;
2130     e_forward_z = v_forward * t_up;
2131     e_up_x = v_up * t_forward;
2132     e_up_y = v_up * t_left;
2133     e_up_z = v_up * t_up;
2134
2135     e.angles = fixedvectoangles2(e_forward, e_up);
2136     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2137                 e.angles = AnglesTransform_ToVAngles(e.angles);
2138         else
2139                 e.angles = AnglesTransform_ToAngles(e.angles);
2140
2141     setattachment(e, to, tag);
2142     setorigin(e, e.origin);
2143 }
2144
2145 void detach_sameorigin(entity e)
2146 {
2147     vector org;
2148     org = gettaginfo(e, 0);
2149     e.angles = fixedvectoangles2(v_forward, v_up);
2150     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2151                 e.angles = AnglesTransform_ToVAngles(e.angles);
2152         else
2153                 e.angles = AnglesTransform_ToAngles(e.angles);
2154     setorigin(e, org);
2155     setattachment(e, world, "");
2156     setorigin(e, e.origin);
2157 }
2158
2159 void follow_sameorigin(entity e, entity to)
2160 {
2161     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2162     e.aiment = to; // make the hole follow bmodel
2163     e.punchangle = to.angles; // the original angles of bmodel
2164     e.view_ofs = e.origin - to.origin; // relative origin
2165     e.v_angle = e.angles - to.angles; // relative angles
2166 }
2167
2168 void unfollow_sameorigin(entity e)
2169 {
2170     e.movetype = MOVETYPE_NONE;
2171 }
2172
2173 entity gettaginfo_relative_ent;
2174 vector gettaginfo_relative(entity e, float tag)
2175 {
2176     if (!gettaginfo_relative_ent)
2177     {
2178         gettaginfo_relative_ent = spawn();
2179         gettaginfo_relative_ent.effects = EF_NODRAW;
2180     }
2181     gettaginfo_relative_ent.model = e.model;
2182     gettaginfo_relative_ent.modelindex = e.modelindex;
2183     gettaginfo_relative_ent.frame = e.frame;
2184     return gettaginfo(gettaginfo_relative_ent, tag);
2185 }
2186
2187 .float scale2;
2188
2189 float modeleffect_SendEntity(entity to, float sf)
2190 {
2191         float f;
2192         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2193
2194         f = 0;
2195         if(self.velocity != '0 0 0')
2196                 f |= 1;
2197         if(self.angles != '0 0 0')
2198                 f |= 2;
2199         if(self.avelocity != '0 0 0')
2200                 f |= 4;
2201
2202         WriteByte(MSG_ENTITY, f);
2203         WriteShort(MSG_ENTITY, self.modelindex);
2204         WriteByte(MSG_ENTITY, self.skin);
2205         WriteByte(MSG_ENTITY, self.frame);
2206         WriteCoord(MSG_ENTITY, self.origin_x);
2207         WriteCoord(MSG_ENTITY, self.origin_y);
2208         WriteCoord(MSG_ENTITY, self.origin_z);
2209         if(f & 1)
2210         {
2211                 WriteCoord(MSG_ENTITY, self.velocity_x);
2212                 WriteCoord(MSG_ENTITY, self.velocity_y);
2213                 WriteCoord(MSG_ENTITY, self.velocity_z);
2214         }
2215         if(f & 2)
2216         {
2217                 WriteCoord(MSG_ENTITY, self.angles_x);
2218                 WriteCoord(MSG_ENTITY, self.angles_y);
2219                 WriteCoord(MSG_ENTITY, self.angles_z);
2220         }
2221         if(f & 4)
2222         {
2223                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2224                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2225                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2226         }
2227         WriteShort(MSG_ENTITY, self.scale * 256.0);
2228         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2229         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2230         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2231         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2232
2233         return TRUE;
2234 }
2235
2236 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2237 {
2238         entity e;
2239         float sz;
2240         e = spawn();
2241         e.classname = "modeleffect";
2242         setmodel(e, m);
2243         e.frame = f;
2244         setorigin(e, o);
2245         e.velocity = v;
2246         e.angles = ang;
2247         e.avelocity = angv;
2248         e.alpha = a;
2249         e.teleport_time = t1;
2250         e.fade_time = t2;
2251         e.skin = s;
2252         if(s0 >= 0)
2253                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2254         else
2255                 e.scale = -s0;
2256         if(s2 >= 0)
2257                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2258         else
2259                 e.scale2 = -s2;
2260         sz = max(e.scale, e.scale2);
2261         setsize(e, e.mins * sz, e.maxs * sz);
2262         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2263 }
2264
2265 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2266 {
2267         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2268 }
2269
2270 float randombit(float bits)
2271 {
2272         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2273                 return bits;
2274
2275         float n, f, b, r;
2276
2277         r = random();
2278         b = 0;
2279         n = 0;
2280
2281         for(f = 1; f <= bits; f *= 2)
2282         {
2283                 if(bits & f)
2284                 {
2285                         ++n;
2286                         r *= n;
2287                         if(r <= 1)
2288                                 b = f;
2289                         else
2290                                 r = (r - 1) / (n - 1);
2291                 }
2292         }
2293
2294         return b;
2295 }
2296
2297 float randombits(float bits, float k, float error_return)
2298 {
2299         float r;
2300         r = 0;
2301         while(k > 0 && bits != r)
2302         {
2303                 r += randombit(bits - r);
2304                 --k;
2305         }
2306         if(error_return)
2307                 if(k > 0)
2308                         return -1; // all
2309         return r;
2310 }
2311
2312 void randombit_test(float bits, float iter)
2313 {
2314         while(iter > 0)
2315         {
2316                 print(ftos(randombit(bits)), "\n");
2317                 --iter;
2318         }
2319 }
2320
2321 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2322 {
2323         if(halflifedist > 0)
2324                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2325         else if(halflifedist < 0)
2326                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2327         else
2328                 return 1;
2329 }
2330
2331
2332
2333
2334 #ifdef RELEASE
2335 #define cvar_string_normal builtin_cvar_string
2336 #define cvar_normal builtin_cvar
2337 #else
2338 string cvar_string_normal(string n)
2339 {
2340         if (!(cvar_type(n) & 1))
2341                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2342         return builtin_cvar_string(n);
2343 }
2344
2345 float cvar_normal(string n)
2346 {
2347         return stof(cvar_string_normal(n));
2348 }
2349 #endif
2350 #define cvar_set_normal builtin_cvar_set
2351
2352 void defer_think()
2353 {
2354     entity oself;
2355
2356     oself           = self;
2357     self            = self.owner;
2358     oself.think     = SUB_Remove;
2359     oself.nextthink = time;
2360
2361     oself.use();
2362 }
2363
2364 /*
2365     Execute func() after time + fdelay.
2366     self when func is executed = self when defer is called
2367 */
2368 void defer(float fdelay, void() func)
2369 {
2370     entity e;
2371
2372     e           = spawn();
2373     e.owner     = self;
2374     e.use       = func;
2375     e.think     = defer_think;
2376     e.nextthink = time + fdelay;
2377 }
2378
2379 .string aiment_classname;
2380 .float aiment_deadflag;
2381 void SetMovetypeFollow(entity ent, entity e)
2382 {
2383         // FIXME this may not be warpzone aware
2384         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2385         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2386         ent.aiment = e; // make the hole follow bmodel
2387         ent.punchangle = e.angles; // the original angles of bmodel
2388         ent.view_ofs = ent.origin - e.origin; // relative origin
2389         ent.v_angle = ent.angles - e.angles; // relative angles
2390         ent.aiment_classname = strzone(e.classname);
2391         ent.aiment_deadflag = e.deadflag;
2392 }
2393 void UnsetMovetypeFollow(entity ent)
2394 {
2395         ent.movetype = MOVETYPE_FLY;
2396         PROJECTILE_MAKETRIGGER(ent);
2397         ent.aiment = world;
2398 }
2399 float LostMovetypeFollow(entity ent)
2400 {
2401 /*
2402         if(ent.movetype != MOVETYPE_FOLLOW)
2403                 if(ent.aiment)
2404                         error("???");
2405 */
2406         if(ent.aiment)
2407         {
2408                 if(ent.aiment.classname != ent.aiment_classname)
2409                         return 1;
2410                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2411                         return 1;
2412         }
2413         return 0;
2414 }
2415
2416 float isPushable(entity e)
2417 {
2418         if(e.iscreature)
2419                 return TRUE;
2420         if(e.pushable)
2421                 return TRUE;
2422         switch(e.classname)
2423         {
2424                 case "body":
2425                 case "droppedweapon":
2426                 case "keepawayball":
2427                 case "nexball_basketball":
2428                 case "nexball_football":
2429                         return TRUE;
2430                 case "bullet": // antilagged bullets can't hit this either
2431                         return FALSE;
2432         }
2433         if (e.projectiledeathtype)
2434                 return TRUE;
2435         return FALSE;
2436 }