qcsrc/server/main.qc

   1 #include "main.qh"
   2
   3 #include <common/command/generic.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/debug.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/monsters/sv_monsters.qh>
   9 #include <common/util.qh>
  10 #include <common/vehicles/all.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <lib/csqcmodel/sv_model.qh>
  13 #include <lib/warpzone/common.qh>
  14 #include <lib/warpzone/server.qh>
  15 #include <server/anticheat.qh>
  16 #include <server/bot/api.qh>
  17 #include <server/command/common.qh>
  18 #include <server/compat/quake3.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/hook.qh>
  22 #include <server/ipban.qh>
  23 #include <server/mutators/_mod.qh>
  24 #include <server/spawnpoints.qh>
  25 #include <server/weapons/common.qh>
  26 #include <server/weapons/csqcprojectile.qh>
  27 #include <server/world.qh>
  28
  29 void dropclient_do(entity this)
  30 {
  31         if (this.owner)
  32                 dropclient(this.owner);
  33         delete(this);
  34 }
  35
  36 /**
  37  * Schedules dropclient for a player and returns true;
  38  * if dropclient is already scheduled (for that player) it does nothing and returns false.
  39  *
  40  * NOTE: this function exists only to allow sending a message to the kicked player with
  41  * Send_Notification, which doesn't work if called together with dropclient
  42  */
  43 bool dropclient_schedule(entity this)
  44 {
  45         bool scheduled = false;
  46         FOREACH_ENTITY_CLASS("dropclient_handler", true,
  47         {
  48                 if(it.owner == this)
  49                 {
  50                         scheduled = true;
  51                         break; // can't use return here, compiler shows a warning
  52                 }
  53         });
  54         if (scheduled)
  55                 return false;
  56
  57         entity e = new_pure(dropclient_handler);
  58         setthink(e, dropclient_do);
  59         e.owner = this;
  60         e.nextthink = time + 0.1;
  61         return true;
  62 }
  63
  64 void CreatureFrame_hotliquids(entity this)
  65 {
  66         if (this.contents_damagetime >= time)
  67         {
  68                 return;
  69         }
  70
  71         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  72
  73         if (this.flags & FL_PROJECTILE)
  74         {
  75                 if (this.watertype == CONTENT_LAVA)
  76                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  77                 else if (this.watertype == CONTENT_SLIME)
  78                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  79         }
  80         else
  81         {
  82                 if (STAT(FROZEN, this))
  83                 {
  84                         if (this.watertype == CONTENT_LAVA)
  85                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  86                         else if (this.watertype == CONTENT_SLIME)
  87                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  88                 }
  89                 else if (this.watertype == CONTENT_LAVA)
  90                 {
  91                         if (this.watersound_finished < time)
  92                         {
  93                                 this.watersound_finished = time + 0.5;
  94                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  95                         }
  96                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  97                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  98                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  99                 }
 100                 else if (this.watertype == CONTENT_SLIME)
 101                 {
 102                         if (this.watersound_finished < time)
 103                         {
 104                                 this.watersound_finished = time + 0.5;
 105                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
 106                         }
 107                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
 108                 }
 109         }
 110 }
 111
 112 void CreatureFrame_Liquids(entity this)
 113 {
 114         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
 115         {
 116                 if (!(this.flags & FL_INWATER))
 117                 {
 118                         this.flags |= FL_INWATER;
 119                         this.contents_damagetime = 0;
 120                 }
 121
 122                 CreatureFrame_hotliquids(this);
 123         }
 124         else
 125         {
 126                 if (this.flags & FL_INWATER)
 127                 {
 128                         // play leave water sound
 129                         this.flags &= ~FL_INWATER;
 130                         this.contents_damagetime = 0;
 131                 }
 132         }
 133 }
 134
 135 void CreatureFrame_FallDamage(entity this)
 136 {
 137         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 138                 return; // vehicles and projectiles don't receive fall damage
 139         if(!(this.velocity || this.oldvelocity))
 140                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 141
 142         // check for falling damage
 143         bool have_hook = false;
 144         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 145         {
 146                 .entity weaponentity = weaponentities[slot];
 147                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 148                 {
 149                         have_hook = true;
 150                         break;
 151                 }
 152         }
 153         if(!have_hook)
 154         {
 155                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 156                 if(autocvar_g_balance_falldamage_onlyvertical)
 157                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 158                 else
 159                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 160                 if (IS_DEAD(this))
 161                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 162                 else
 163                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 164                 if (dm > 0)
 165                 {
 166                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 167                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 168                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 169                 }
 170         }
 171
 172         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 173                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 174 }
 175
 176 void CreatureFrame_All()
 177 {
 178         if(game_stopped || time < game_starttime)
 179                 return;
 180
 181         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 182         {
 183                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 184                 CreatureFrame_Liquids(it);
 185                 CreatureFrame_FallDamage(it);
 186                 it.oldvelocity = it.velocity;
 187         });
 188 }
 189
 190 // called shortly after map change in dedicated
 191 void Pause_TryPause_Dedicated(entity this)
 192 {
 193         if (player_count == 0 && !intermission_running && !autocvar__endmatch)
 194                 setpause(1);
 195 }
 196
 197 // called every normal frame in singleplayer/listen
 198 void Pause_TryPause()
 199 {
 200         int n = 0, p = 0;
 201         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 202                 if (PHYS_INPUT_BUTTON_CHAT(it)) ++p;
 203                 ++n;
 204         });
 205         if (!n) return;
 206         if (n == p)
 207                 setpause(1);
 208         else
 209                 setpause(0);
 210 }
 211
 212 // called every paused frame by DP
 213 void SV_PausedTic(float elapsedtime)
 214 {
 215         if (autocvar__endmatch) // `endmatch` while paused
 216                 setpause(0); // proceed to intermission
 217         else if (!server_is_dedicated)
 218         {
 219                 if (autocvar_sv_autopause)
 220                         Pause_TryPause();
 221                 else
 222                         setpause(0);
 223         }
 224 }
 225
 226 void dedicated_print(string input)
 227 {
 228         if (server_is_dedicated) print(input);
 229 }
 230
 231 void make_safe_for_remove(entity e)
 232 {
 233         if (e.initialize_entity)
 234         {
 235                 entity ent, prev = NULL;
 236                 for (ent = initialize_entity_first; ent; )
 237                 {
 238                         if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 239                         {
 240                                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 241                                 // skip it in linked list
 242                                 if (prev)
 243                                 {
 244                                         prev.initialize_entity_next = ent.initialize_entity_next;
 245                                         ent = prev.initialize_entity_next;
 246                                 }
 247                                 else
 248                                 {
 249                                         initialize_entity_first = ent.initialize_entity_next;
 250                                         ent = initialize_entity_first;
 251                                 }
 252                         }
 253                         else
 254                         {
 255                                 prev = ent;
 256                                 ent = ent.initialize_entity_next;
 257                         }
 258                 }
 259         }
 260 }
 261
 262 void remove_except_protected(entity e)
 263 {
 264         if(e.remove_except_protected_forbidden)
 265                 error("not allowed to remove this at this point");
 266         builtin_remove(e);
 267 }
 268
 269 void remove_unsafely(entity e)
 270 {
 271         if(e.classname == "spike")
 272                 error("Removing spikes is forbidden (crylink bug), please report");
 273         builtin_remove(e);
 274 }
 275
 276 void remove_safely(entity e)
 277 {
 278         make_safe_for_remove(e);
 279         builtin_remove(e);
 280 }
 281
 282 /*
 283 =============
 284 StartFrame
 285
 286 Called before each frame by the server
 287 =============
 288 */
 289
 290 bool game_delay_last;
 291
 292 void systems_update();
 293 void sys_phys_update(entity this, float dt);
 294 void StartFrame()
 295 {
 296         // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 297         IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 298         IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 299
 300         execute_next_frame();
 301
 302         delete_fn = remove_unsafely; // not during spawning!
 303         serverprevtime = servertime;
 304         servertime = time;
 305         serverframetime = frametime;
 306
 307 #ifdef PROFILING
 308         if(time > client_cefc_accumulatortime + 1)
 309         {
 310                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 311                 int c_seeing = 0;
 312                 int c_seen = 0;
 313                 FOREACH_CLIENT(true, {
 314                         if(IS_REAL_CLIENT(it))
 315                                 ++c_seeing;
 316                         if(IS_PLAYER(it))
 317                                 ++c_seen;
 318                 });
 319                 LOG_INFO(
 320                         "CEFC time: ", ftos(t * 1000), "ms; ",
 321                         "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 322                         "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 323                 );
 324                 client_cefc_accumulatortime = time;
 325                 client_cefc_accumulator = 0;
 326         }
 327 #endif
 328
 329         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 330
 331         if (RedirectionThink()) return;
 332
 333         UncustomizeEntitiesRun();
 334         InitializeEntitiesRun();
 335
 336         WarpZone_StartFrame();
 337
 338         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 339         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 340
 341         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 342                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 343
 344         // detect when the pre-game countdown (if any) has ended and the game has started
 345         bool game_delay = (time < game_starttime);
 346         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 347                 GameLogEcho(":startdelay_ended");
 348         game_delay_last = game_delay;
 349
 350         CreatureFrame_All();
 351         CheckRules_World();
 352
 353         // after CheckRules_World() as it may set intermission_running, and after RedirectionThink() in case listen server is closing
 354         if (autocvar_sv_autopause && !server_is_dedicated && !intermission_running)
 355                 Pause_TryPause();
 356
 357         if (warmup_stage && !game_stopped && warmup_limit > 0 && time - game_starttime >= warmup_limit) {
 358                 ReadyRestart(true);
 359                 return;
 360         }
 361
 362         bot_serverframe();
 363         anticheat_startframe();
 364         MUTATOR_CALLHOOK(SV_StartFrame);
 365
 366         GlobalStats_updateglobal();
 367         FOREACH_CLIENT(true, GlobalStats_update(it));
 368         IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 369 }
 370
 371 .vector originjitter;
 372 .vector anglesjitter;
 373 .float anglejitter;
 374 .string gametypefilter;
 375 .string cvarfilter;
 376
 377 void SV_OnEntityPreSpawnFunction(entity this)
 378 {
 379         if (this)
 380         if (this.gametypefilter != "")
 381         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 382         {
 383                 delete(this);
 384                 return;
 385         }
 386         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 387                 delete(this);
 388                 return;
 389         }
 390
 391         if (q3compat && DoesQ3ARemoveThisEntity(this)) {
 392                 delete(this);
 393                 return;
 394         }
 395
 396         set_movetype(this, this.movetype);
 397
 398         if (this.monster_attack) {
 399                 IL_PUSH(g_monster_targets, this);
 400         }
 401
 402         // support special -1 and -2 angle from radiant
 403         if (this.angles == '0 -1 0') {
 404                 this.angles = '-90 0 0';
 405         } else if (this.angles == '0 -2 0') {
 406                 this.angles = '+90 0 0';
 407         }
 408
 409         #define X(out, in) MACRO_BEGIN \
 410                 if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 411         MACRO_END
 412         X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 413         X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 414         X(this.angles.y, this.anglejitter);
 415         #undef X
 416
 417         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 418                 delete(this);
 419                 return;
 420         }
 421 }
 422
 423 string GetField_fullspawndata(entity e, string f, ...)
 424 /* Retrieves the value of a map entity field from fullspawndata
 425  * This bypasses field value changes made by the engine,
 426  * eg string-to-float and escape sequence substitution.
 427  *
 428  * Avoids the need to declare fields just to read them once :)
 429  *
 430  * Returns the last instance of the field to match DarkPlaces behaviour.
 431  * Path support: converts \ to / and tests the file if a third (bool, true) arg is passed.
 432  * Returns string_null if the entity does not have the field, or the file is not in the VFS.
 433  *
 434  * FIXME: entities with //comments are not supported.
 435  */
 436 {
 437         string v = string_null;
 438
 439         if (!e.fullspawndata)
 440         {
 441                 //LOG_WARNF("^1EDICT %s (classname %s) has no fullspawndata, engine lacks support?", ftos(num_for_edict(e)), e.classname);
 442                 return v;
 443         }
 444
 445         if (strstrofs(e.fullspawndata, "//", 0) >= 0)
 446         {
 447                 // tokenize and tokenize_console return early if "//" is reached,
 448                 // which can leave an odd number of tokens and break key:value pairing.
 449                 LOG_WARNF("^1EDICT %s fullspawndata contains unsupported //comment^7%s", ftos(num_for_edict(e)), e.fullspawndata);
 450                 return v;
 451         }
 452
 453         //print(sprintf("%s(EDICT %s, FIELD %s)\n", __FUNC__, ftos(num_for_edict(e)), f));
 454         //print(strcat("FULLSPAWNDATA:", e.fullspawndata, "\n"));
 455
 456         // tokenize treats \ as an escape, but tokenize_console returns the required literal
 457         for (int t = tokenize_console(e.fullspawndata) - 3; t > 0; t -= 2)
 458         {
 459                 //print(sprintf("\tTOKEN %s:%s\t%s:%s\n", ftos(t), ftos(t + 1), argv(t), argv(t + 1)));
 460                 if (argv(t) == f)
 461                 {
 462                         v = argv(t + 1);
 463                         break;
 464                 }
 465         }
 466
 467         //print(strcat("RESULT: ", v, "\n\n"));
 468
 469         if (v && ...(0, bool) == true)
 470         {
 471                 v = strreplace("\\", "/", v);
 472                 if (whichpack(v) == "")
 473                         return string_null;
 474         }
 475
 476         return v;
 477 }
 478
 479 void WarpZone_PostInitialize_Callback()
 480 {
 481         // create waypoint links for warpzones
 482         entity tracetest_ent = spawn();
 483         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 484         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 485         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 486         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 487                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 488         delete(tracetest_ent);
 489 }
 490
 491 /** engine callback */
 492 void URI_Get_Callback(float id, float status, string data)
 493 {
 494         if(url_URI_Get_Callback(id, status, data))
 495         {
 496                 // handled
 497         }
 498         else if (id == URI_GET_DISCARD)
 499         {
 500                 // discard
 501         }
 502         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 503         {
 504                 // sv_cmd curl
 505                 Curl_URI_Get_Callback(id, status, data);
 506         }
 507         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
 508         {
 509                 // online ban list
 510                 OnlineBanList_URI_Get_Callback(id, status, data);
 511         }
 512         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
 513         {
 514                 // handled by a mutator
 515         }
 516         else
 517         {
 518                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
 519         }
 520 }
 521
 522 /*
 523 ==================
 524 main
 525
 526 unused but required by the engine
 527 ==================
 528 */
 529 void main ()
 530 {
 531
 532 }