qcsrc/server/main.qc

   1 #include "main.qh"
   2
   3 #include <common/command/generic.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/debug.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/monsters/sv_monsters.qh>
   9 #include <common/util.qh>
  10 #include <common/vehicles/all.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <lib/csqcmodel/sv_model.qh>
  13 #include <lib/warpzone/common.qh>
  14 #include <lib/warpzone/server.qh>
  15 #include <server/anticheat.qh>
  16 #include <server/bot/api.qh>
  17 #include <server/command/common.qh>
  18 #include <server/compat/quake3.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/hook.qh>
  22 #include <server/ipban.qh>
  23 #include <server/mutators/_mod.qh>
  24 #include <server/spawnpoints.qh>
  25 #include <server/weapons/common.qh>
  26 #include <server/weapons/csqcprojectile.qh>
  27 #include <server/world.qh>
  28
  29 void dropclient_do(entity this)
  30 {
  31         if (this.owner)
  32                 dropclient(this.owner);
  33         delete(this);
  34 }
  35
  36 /**
  37  * Schedules dropclient for a player and returns true;
  38  * if dropclient is already scheduled (for that player) it does nothing and returns false.
  39  *
  40  * NOTE: this function exists only to allow sending a message to the kicked player with
  41  * Send_Notification, which doesn't work if called together with dropclient
  42  */
  43 bool dropclient_schedule(entity this)
  44 {
  45         bool scheduled = false;
  46         FOREACH_ENTITY_CLASS("dropclient_handler", true,
  47         {
  48                 if(it.owner == this)
  49                 {
  50                         scheduled = true;
  51                         break; // can't use return here, compiler shows a warning
  52                 }
  53         });
  54         if (scheduled)
  55                 return false;
  56
  57         entity e = new_pure(dropclient_handler);
  58         setthink(e, dropclient_do);
  59         e.owner = this;
  60         e.nextthink = time + 0.1;
  61         return true;
  62 }
  63
  64 void CreatureFrame_hotliquids(entity this)
  65 {
  66         if (this.contents_damagetime >= time)
  67         {
  68                 return;
  69         }
  70
  71         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  72
  73         if (this.flags & FL_PROJECTILE)
  74         {
  75                 if (this.watertype == CONTENT_LAVA)
  76                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  77                 else if (this.watertype == CONTENT_SLIME)
  78                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  79         }
  80         else
  81         {
  82                 if (STAT(FROZEN, this))
  83                 {
  84                         if (this.watertype == CONTENT_LAVA)
  85                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  86                         else if (this.watertype == CONTENT_SLIME)
  87                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  88                 }
  89                 else if (this.watertype == CONTENT_LAVA)
  90                 {
  91                         if (this.watersound_finished < time)
  92                         {
  93                                 this.watersound_finished = time + 0.5;
  94                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  95                         }
  96                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  97                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  98                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  99                 }
 100                 else if (this.watertype == CONTENT_SLIME)
 101                 {
 102                         if (this.watersound_finished < time)
 103                         {
 104                                 this.watersound_finished = time + 0.5;
 105                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
 106                         }
 107                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
 108                 }
 109         }
 110 }
 111
 112 void CreatureFrame_Liquids(entity this)
 113 {
 114         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
 115         {
 116                 if (!(this.flags & FL_INWATER))
 117                 {
 118                         this.flags |= FL_INWATER;
 119                         this.contents_damagetime = 0;
 120                 }
 121
 122                 CreatureFrame_hotliquids(this);
 123         }
 124         else
 125         {
 126                 if (this.flags & FL_INWATER)
 127                 {
 128                         // play leave water sound
 129                         this.flags &= ~FL_INWATER;
 130                         this.contents_damagetime = 0;
 131                 }
 132         }
 133 }
 134
 135 void CreatureFrame_FallDamage(entity this)
 136 {
 137         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 138                 return; // vehicles and projectiles don't receive fall damage
 139         if(!(this.velocity || this.oldvelocity))
 140                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 141
 142         // check for falling damage
 143         bool have_hook = false;
 144         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 145         {
 146                 .entity weaponentity = weaponentities[slot];
 147                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 148                 {
 149                         have_hook = true;
 150                         break;
 151                 }
 152         }
 153         if(!have_hook)
 154         {
 155                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 156                 if(autocvar_g_balance_falldamage_onlyvertical)
 157                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 158                 else
 159                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 160                 if (IS_DEAD(this))
 161                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 162                 else
 163                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 164                 if (dm > 0)
 165                 {
 166                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 167                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 168                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 169                 }
 170         }
 171
 172         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 173                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 174 }
 175
 176 void CreatureFrame_All()
 177 {
 178         if(game_stopped || time < game_starttime)
 179                 return;
 180
 181         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 182         {
 183                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 184                 CreatureFrame_Liquids(it);
 185                 CreatureFrame_FallDamage(it);
 186                 it.oldvelocity = it.velocity;
 187         });
 188 }
 189
 190 void Pause_TryPause_Dedicated(entity this)
 191 {
 192         if (player_count == 0)
 193                 setpause(1);
 194 }
 195
 196 void Pause_TryPause()
 197 {
 198         int n = 0, p = 0;
 199         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 200                 if (PHYS_INPUT_BUTTON_CHAT(it)) ++p;
 201                 ++n;
 202         });
 203         if (!n) return;
 204         if (n == p)
 205                 setpause(1);
 206         else
 207                 setpause(0);
 208 }
 209
 210 void SV_PausedTic(float elapsedtime)
 211 {
 212         if (!server_is_dedicated)
 213         {
 214                 if (autocvar_sv_autopause)
 215                         Pause_TryPause();
 216                 else
 217                         setpause(0);
 218         }
 219 }
 220
 221 void dedicated_print(string input)
 222 {
 223         if (server_is_dedicated) print(input);
 224 }
 225
 226 void make_safe_for_remove(entity e)
 227 {
 228         if (e.initialize_entity)
 229         {
 230                 entity ent, prev = NULL;
 231                 for (ent = initialize_entity_first; ent; )
 232                 {
 233                         if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 234                         {
 235                                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 236                                 // skip it in linked list
 237                                 if (prev)
 238                                 {
 239                                         prev.initialize_entity_next = ent.initialize_entity_next;
 240                                         ent = prev.initialize_entity_next;
 241                                 }
 242                                 else
 243                                 {
 244                                         initialize_entity_first = ent.initialize_entity_next;
 245                                         ent = initialize_entity_first;
 246                                 }
 247                         }
 248                         else
 249                         {
 250                                 prev = ent;
 251                                 ent = ent.initialize_entity_next;
 252                         }
 253                 }
 254         }
 255 }
 256
 257 void remove_except_protected(entity e)
 258 {
 259         if(e.remove_except_protected_forbidden)
 260                 error("not allowed to remove this at this point");
 261         builtin_remove(e);
 262 }
 263
 264 void remove_unsafely(entity e)
 265 {
 266         if(e.classname == "spike")
 267                 error("Removing spikes is forbidden (crylink bug), please report");
 268         builtin_remove(e);
 269 }
 270
 271 void remove_safely(entity e)
 272 {
 273         make_safe_for_remove(e);
 274         builtin_remove(e);
 275 }
 276
 277 /*
 278 =============
 279 StartFrame
 280
 281 Called before each frame by the server
 282 =============
 283 */
 284
 285 bool game_delay_last;
 286
 287 void systems_update();
 288 void sys_phys_update(entity this, float dt);
 289 void StartFrame()
 290 {
 291         // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 292         IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 293         IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 294
 295         execute_next_frame();
 296         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause();
 297
 298         delete_fn = remove_unsafely; // not during spawning!
 299         serverprevtime = servertime;
 300         servertime = time;
 301         serverframetime = frametime;
 302
 303 #ifdef PROFILING
 304         if(time > client_cefc_accumulatortime + 1)
 305         {
 306                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 307                 int c_seeing = 0;
 308                 int c_seen = 0;
 309                 FOREACH_CLIENT(true, {
 310                         if(IS_REAL_CLIENT(it))
 311                                 ++c_seeing;
 312                         if(IS_PLAYER(it))
 313                                 ++c_seen;
 314                 });
 315                 LOG_INFO(
 316                         "CEFC time: ", ftos(t * 1000), "ms; ",
 317                         "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 318                         "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 319                 );
 320                 client_cefc_accumulatortime = time;
 321                 client_cefc_accumulator = 0;
 322         }
 323 #endif
 324
 325         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 326
 327         if (RedirectionThink()) return;
 328
 329         UncustomizeEntitiesRun();
 330         InitializeEntitiesRun();
 331
 332         WarpZone_StartFrame();
 333
 334         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 335         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 336
 337         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 338                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 339
 340         // detect when the pre-game countdown (if any) has ended and the game has started
 341         bool game_delay = (time < game_starttime);
 342         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 343                 GameLogEcho(":startdelay_ended");
 344         game_delay_last = game_delay;
 345
 346         CreatureFrame_All();
 347         CheckRules_World();
 348
 349         if (warmup_stage && !game_stopped && warmup_limit > 0 && time - game_starttime >= warmup_limit) {
 350                 ReadyRestart(true);
 351                 return;
 352         }
 353
 354         bot_serverframe();
 355         anticheat_startframe();
 356         MUTATOR_CALLHOOK(SV_StartFrame);
 357
 358         GlobalStats_updateglobal();
 359         FOREACH_CLIENT(true, GlobalStats_update(it));
 360         IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 361 }
 362
 363 .vector originjitter;
 364 .vector anglesjitter;
 365 .float anglejitter;
 366 .string gametypefilter;
 367 .string cvarfilter;
 368
 369 void SV_OnEntityPreSpawnFunction(entity this)
 370 {
 371         if (this)
 372         if (this.gametypefilter != "")
 373         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 374         {
 375                 delete(this);
 376                 return;
 377         }
 378         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 379                 delete(this);
 380                 return;
 381         }
 382
 383         if (q3compat && DoesQ3ARemoveThisEntity(this)) {
 384                 delete(this);
 385                 return;
 386         }
 387
 388         set_movetype(this, this.movetype);
 389
 390         if (this.monster_attack) {
 391                 IL_PUSH(g_monster_targets, this);
 392         }
 393
 394         // support special -1 and -2 angle from radiant
 395         if (this.angles == '0 -1 0') {
 396                 this.angles = '-90 0 0';
 397         } else if (this.angles == '0 -2 0') {
 398                 this.angles = '+90 0 0';
 399         }
 400
 401         #define X(out, in) MACRO_BEGIN \
 402                 if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 403         MACRO_END
 404         X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 405         X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 406         X(this.angles.y, this.anglejitter);
 407         #undef X
 408
 409         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 410                 delete(this);
 411                 return;
 412         }
 413 }
 414
 415 string GetField_fullspawndata(entity e, string f, ...)
 416 /* Retrieves the value of a map entity field from fullspawndata
 417  * This bypasses field value changes made by the engine,
 418  * eg string-to-float and escape sequence substitution.
 419  *
 420  * Avoids the need to declare fields just to read them once :)
 421  *
 422  * Returns the last instance of the field to match DarkPlaces behaviour.
 423  * Path support: converts \ to / and tests the file if a third (bool, true) arg is passed.
 424  * Returns string_null if the entity does not have the field, or the file is not in the VFS.
 425  *
 426  * FIXME: entities with //comments are not supported.
 427  */
 428 {
 429         string v = string_null;
 430
 431         if (!e.fullspawndata)
 432         {
 433                 //LOG_WARNF("^1EDICT %s (classname %s) has no fullspawndata, engine lacks support?", ftos(num_for_edict(e)), e.classname);
 434                 return v;
 435         }
 436
 437         if (strstrofs(e.fullspawndata, "//", 0) >= 0)
 438         {
 439                 // tokenize and tokenize_console return early if "//" is reached,
 440                 // which can leave an odd number of tokens and break key:value pairing.
 441                 LOG_WARNF("^1EDICT %s fullspawndata contains unsupported //comment^7%s", ftos(num_for_edict(e)), e.fullspawndata);
 442                 return v;
 443         }
 444
 445         //print(sprintf("%s(EDICT %s, FIELD %s)\n", __FUNC__, ftos(num_for_edict(e)), f));
 446         //print(strcat("FULLSPAWNDATA:", e.fullspawndata, "\n"));
 447
 448         // tokenize treats \ as an escape, but tokenize_console returns the required literal
 449         for (int t = tokenize_console(e.fullspawndata) - 3; t > 0; t -= 2)
 450         {
 451                 //print(sprintf("\tTOKEN %s:%s\t%s:%s\n", ftos(t), ftos(t + 1), argv(t), argv(t + 1)));
 452                 if (argv(t) == f)
 453                 {
 454                         v = argv(t + 1);
 455                         break;
 456                 }
 457         }
 458
 459         //print(strcat("RESULT: ", v, "\n\n"));
 460
 461         if (v && ...(0, bool) == true)
 462         {
 463                 v = strreplace("\\", "/", v);
 464                 if (whichpack(v) == "")
 465                         return string_null;
 466         }
 467
 468         return v;
 469 }
 470
 471 void WarpZone_PostInitialize_Callback()
 472 {
 473         // create waypoint links for warpzones
 474         entity tracetest_ent = spawn();
 475         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 476         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 477         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 478         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 479                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 480         delete(tracetest_ent);
 481 }
 482
 483 /** engine callback */
 484 void URI_Get_Callback(float id, float status, string data)
 485 {
 486         if(url_URI_Get_Callback(id, status, data))
 487         {
 488                 // handled
 489         }
 490         else if (id == URI_GET_DISCARD)
 491         {
 492                 // discard
 493         }
 494         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 495         {
 496                 // sv_cmd curl
 497                 Curl_URI_Get_Callback(id, status, data);
 498         }
 499         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
 500         {
 501                 // online ban list
 502                 OnlineBanList_URI_Get_Callback(id, status, data);
 503         }
 504         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
 505         {
 506                 // handled by a mutator
 507         }
 508         else
 509         {
 510                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
 511         }
 512 }
 513
 514 /*
 515 ==================
 516 main
 517
 518 unused but required by the engine
 519 ==================
 520 */
 521 void main ()
 522 {
 523
 524 }