qcsrc/server/items/items.qc

   1 #include "items.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/gamemode/cts/cts.qh>
   6 #include <common/items/_mod.qh>
   7 #include <common/mapobjects/subs.qh>
   8 #include <common/mapobjects/triggers.qh>
   9 #include <common/monsters/_mod.qh>
  10 #include <common/mutators/mutator/buffs/buffs.qh>
  11 #include <common/mutators/mutator/buffs/sv_buffs.qh>
  12 #include <common/mutators/mutator/powerups/_mod.qh>
  13 #include <common/mutators/mutator/status_effects/_mod.qh>
  14 #include <common/net_linked.qh>
  15 #include <common/notifications/all.qh>
  16 #include <common/resources/resources.qh>
  17 #include <common/util.qh>
  18 #include <common/weapons/_all.qh>
  19 #include <common/wepent.qh>
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22 #include <server/bot/api.qh>
  23 #include <server/command/vote.qh>
  24 #include <server/damage.qh>
  25 #include <server/mutators/_mod.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/common.qh>
  28 #include <server/weapons/selection.qh>
  29 #include <server/weapons/weaponsystem.qh>
  30 #include <server/world.qh>
  31
  32 bool ItemSend(entity this, entity to, int sf)
  33 {
  34         if(this.gravity)
  35                 sf |= ISF_DROP;
  36         else
  37                 sf &= ~ISF_DROP;
  38
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
  40         WriteByte(MSG_ENTITY, sf);
  41
  42         //WriteByte(MSG_ENTITY, this.cnt);
  43         if(sf & ISF_LOCATION)
  44         {
  45                 WriteVector(MSG_ENTITY, this.origin);
  46         }
  47
  48         if(sf & ISF_ANGLES)
  49         {
  50                 WriteAngleVector(MSG_ENTITY, this.angles);
  51         }
  52
  53         // sets size on the client, unused on server
  54         //if(sf & ISF_SIZE)
  55
  56         if(sf & ISF_STATUS)
  57                 WriteByte(MSG_ENTITY, this.ItemStatus);
  58
  59         if(sf & ISF_MODEL)
  60         {
  61                 WriteShort(MSG_ENTITY, bound(0, this.fade_end, 32767));
  62                 WriteShort(MSG_ENTITY, bound(0, this.fade_start, 32767));
  63
  64                 if(this.mdl == "")
  65                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
  66
  67                 WriteString(MSG_ENTITY, this.mdl);
  68                 WriteByte(MSG_ENTITY, bound(0, this.skin, 255));
  69         }
  70
  71         if(sf & ISF_COLORMAP)
  72         {
  73                 WriteShort(MSG_ENTITY, this.colormap);
  74                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
  75                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
  76                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
  77         }
  78
  79         if(sf & ISF_DROP)
  80         {
  81                 WriteVector(MSG_ENTITY, this.velocity);
  82         }
  83
  84         return true;
  85 }
  86
  87 void ItemUpdate(entity this)
  88 {
  89         this.oldorigin = this.origin;
  90         this.SendFlags |= ISF_LOCATION;
  91 }
  92
  93 void UpdateItemAfterTeleport(entity this)
  94 {
  95         if(getSendEntity(this) == ItemSend)
  96                 ItemUpdate(this);
  97 }
  98
  99 bool have_pickup_item(entity this)
 100 {
 101         if (this.itemdef.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
 102                 return false;
 103
 104         if(this.itemdef.instanceOfPowerup)
 105         {
 106                 if(autocvar_g_powerups > 0)
 107                         return true;
 108                 if(autocvar_g_powerups == 0)
 109                         return false;
 110         }
 111         else
 112         {
 113                 if(autocvar_g_pickup_items > 0)
 114                         return true;
 115                 if(autocvar_g_pickup_items == 0)
 116                         return false;
 117                 if(g_weaponarena)
 118                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 119                                 return false;
 120         }
 121         return true;
 122 }
 123
 124 void Item_Show(entity e, int mode)
 125 {
 126         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 127         e.ItemStatus &= ~ITS_STAYWEP;
 128         entity def = e.itemdef;
 129         if (mode > 0)
 130         {
 131                 // make the item look normal, and be touchable
 132                 e.model = e.mdl;
 133                 e.solid = SOLID_TRIGGER;
 134                 e.spawnshieldtime = 1;
 135                 e.ItemStatus |= ITS_AVAILABLE;
 136         }
 137         else if (mode < 0)
 138         {
 139                 // hide the item completely
 140                 e.model = string_null;
 141                 e.solid = SOLID_NOT;
 142                 e.spawnshieldtime = 1;
 143                 e.ItemStatus &= ~ITS_AVAILABLE;
 144         }
 145         else
 146         {
 147                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 148                         || e.team // weapon stay isn't supported for teamed weapons
 149                         ;
 150                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 151                 {
 152                         // make the item translucent and not touchable
 153                         e.model = e.mdl;
 154                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 155                         e.effects |= EF_STARDUST;
 156                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 157                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 158                 }
 159                 else
 160                 {
 161                         //setmodel(e, "null");
 162                         e.solid = SOLID_NOT;
 163                         e.colormod = '0 0 0';
 164                         //e.glowmod = e.colormod;
 165                         e.spawnshieldtime = 1;
 166                         e.ItemStatus &= ~ITS_AVAILABLE;
 167                 }
 168         }
 169
 170         if (def.m_glow)
 171                 e.ItemStatus |= ITS_GLOW;
 172
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175
 176         if (autocvar_g_fullbrightitems)
 177                 e.ItemStatus |= ITS_ALLOWFB;
 178         else
 179                 e.ItemStatus &= ~ITS_ALLOWFB;
 180
 181         if (autocvar_sv_simple_items)
 182                 e.ItemStatus |= ITS_ALLOWSI;
 183
 184         // relink entity (because solid may have changed)
 185         setorigin(e, e.origin);
 186         e.SendFlags |= ISF_STATUS;
 187 }
 188
 189 void Item_Think(entity this)
 190 {
 191         this.nextthink = time;
 192         if(this.origin != this.oldorigin)
 193                 ItemUpdate(this);
 194 }
 195
 196 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 197 bool Item_ItemsTime_Allow(GameItem it);
 198 float Item_ItemsTime_UpdateTime(entity e, float t);
 199 void Item_ItemsTime_SetTime(entity e, float t);
 200 void Item_ItemsTime_SetTimesForAllPlayers();
 201
 202 void Item_Respawn(entity this)
 203 {
 204         Item_Show(this, 1);
 205         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 206
 207         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 208         {
 209                 float t = Item_ItemsTime_UpdateTime(this, 0);
 210                 Item_ItemsTime_SetTime(this, t);
 211                 Item_ItemsTime_SetTimesForAllPlayers();
 212         }
 213
 214         setthink(this, Item_Think);
 215         this.nextthink = time;
 216
 217         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 218         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 219 }
 220
 221 void Item_RespawnCountdown(entity this)
 222 {
 223         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 224         {
 225                 if(this.waypointsprite_attached)
 226                         WaypointSprite_Kill(this.waypointsprite_attached);
 227                 Item_Respawn(this);
 228         }
 229         else
 230         {
 231                 this.nextthink = time + 1;
 232                 this.item_respawncounter += 1;
 233                 if(this.item_respawncounter == 1)
 234                 {
 235                         do {
 236                                 {
 237                                         entity wi = REGISTRY_GET(Weapons, this.weapon);
 238                                         if (wi != WEP_Null) {
 239                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 240                                                 wp.wp_extra = wi.m_id;
 241                                                 break;
 242                                         }
 243                                 }
 244                                 {
 245                                         entity ii = this.itemdef;
 246                                         if (ii != NULL) {
 247                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 248                                                 wp.wp_extra = ii.m_id;
 249                                                 break;
 250                                         }
 251                                 }
 252                         } while (0);
 253                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 254                         if(this.waypointsprite_attached)
 255                         {
 256                                 GameItem def = this.itemdef;
 257                                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 258                                         WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 259                                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 260                         }
 261                 }
 262
 263                 if(this.waypointsprite_attached)
 264                 {
 265                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 266                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 267                                 {
 268                                         msg_entity = it;
 269                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM, 0); // play respawn sound
 270                                 }
 271                         });
 272
 273                         WaypointSprite_Ping(this.waypointsprite_attached);
 274                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 275                 }
 276         }
 277 }
 278
 279 void Item_RespawnThink(entity this)
 280 {
 281         this.nextthink = time;
 282         if(this.origin != this.oldorigin)
 283                 ItemUpdate(this);
 284
 285         if(time >= this.wait)
 286                 Item_Respawn(this);
 287 }
 288
 289 void Item_ScheduleRespawnIn(entity e, float t)
 290 {
 291         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 292         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 293         {
 294                 setthink(e, Item_RespawnCountdown);
 295                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 296                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 297                 e.item_respawncounter = 0;
 298                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 299                 {
 300                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 301                         Item_ItemsTime_SetTime(e, t);
 302                         Item_ItemsTime_SetTimesForAllPlayers();
 303                 }
 304         }
 305         else
 306         {
 307                 setthink(e, Item_RespawnThink);
 308                 e.nextthink = time;
 309                 e.scheduledrespawntime = time + t;
 310                 e.wait = time + t;
 311
 312                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 313                 {
 314                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 315                         Item_ItemsTime_SetTime(e, t);
 316                         Item_ItemsTime_SetTimesForAllPlayers();
 317                 }
 318         }
 319 }
 320
 321 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 322 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 323 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 324
 325 /// Adjust respawn time according to the number of players.
 326 float adjust_respawntime(float normal_respawntime) {
 327         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 328         float o = autocvar_g_pickup_respawntime_scaling_offset;
 329         float l = autocvar_g_pickup_respawntime_scaling_linear;
 330
 331         if (r == 0 && l == 1) {
 332                 return normal_respawntime;
 333         }
 334
 335         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 336         TeamBalance_GetTeamCounts(balance, NULL);
 337         int players = 0;
 338         for (int i = 1; i <= NUM_TEAMS; ++i)
 339         {
 340                 if (TeamBalance_IsTeamAllowed(balance, i))
 341                 {
 342                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 343                 }
 344         }
 345         TeamBalance_Destroy(balance);
 346
 347         if (players >= 2) {
 348                 return normal_respawntime * (r / (players + o) + l);
 349         } else {
 350                 return normal_respawntime;
 351         }
 352 }
 353
 354 void Item_ScheduleRespawn(entity e)
 355 {
 356         if(e.respawntime > 0)
 357         {
 358                 Item_Show(e, 0);
 359
 360                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 361                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 362
 363                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 364                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 365                 Item_ScheduleRespawnIn(e, respawn_in);
 366         }
 367         else // if respawntime is -1, this item does not respawn
 368                 Item_Show(e, -1);
 369 }
 370
 371 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 372         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 373
 374 void Item_ScheduleInitialRespawn(entity e)
 375 {
 376         Item_Show(e, 0);
 377
 378         float spawn_in;
 379         if (autocvar_g_pickup_respawntime_initial_random == 0)
 380         {
 381                 // range: respawntime .. respawntime + respawntimejitter
 382                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 383         }
 384         else
 385         {
 386                 float rnd;
 387                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 388                 {
 389                         static float shared_random = 0;
 390                         // NOTE this code works only if items are scheduled at the same time (normal case)
 391                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 392                         if (!shared_random || floor(time) > shared_random)
 393                                 shared_random = floor(time) + random();
 394                         rnd = shared_random - floor(time);
 395                 }
 396                 else
 397                         rnd = random();
 398
 399                 // range:
 400                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 401                 // else: 0 .. ITEM_RESPAWN_TICKS
 402                 // this is to prevent powerups spawning unexpectedly without waypoints
 403                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 404         }
 405
 406         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 407 }
 408
 409 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 410         entity ammo_entity)
 411 {
 412         if (num_weapons == 0)
 413         {
 414                 return;
 415         }
 416         int num_potential_weapons = tokenize_console(weapon_names);
 417         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 418         {
 419                 RandomSelection_Init();
 420                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 421                         ++weapon_index)
 422                 {
 423                         string weapon = argv(weapon_index);
 424                         FOREACH(Weapons, it != WEP_Null,
 425                         {
 426                                 // Finding a weapon which player doesn't have.
 427                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 428                                 {
 429                                         RandomSelection_AddEnt(it, 1, 1);
 430                                         break;
 431                                 }
 432                         });
 433                 }
 434                 if (RandomSelection_chosen_ent == NULL)
 435                 {
 436                         return;
 437                 }
 438                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 439                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
 440                 {
 441                         continue;
 442                 }
 443                 if (GetResource(receiver,
 444                         RandomSelection_chosen_ent.ammo_type) != 0)
 445                 {
 446                         continue;
 447                 }
 448                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 449                         GetResource(ammo_entity,
 450                         RandomSelection_chosen_ent.ammo_type));
 451         }
 452 }
 453
 454 bool Item_GiveAmmoTo(entity item, entity player, Resource res_type, float ammomax)
 455 {
 456         float amount = GetResource(item, res_type);
 457         if (amount == 0)
 458         {
 459                 return false;
 460         }
 461         float player_amount = GetResource(player, res_type);
 462         if (item.spawnshieldtime)
 463         {
 464                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 465                         return false;
 466         }
 467         else if (g_weapon_stay == 2)
 468         {
 469                 ammomax = min(amount, ammomax);
 470                 if(player_amount >= ammomax)
 471                         return false;
 472         }
 473         else
 474                 return false;
 475         if (amount < 0)
 476                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
 477         else
 478                 GiveResourceWithLimit(player, res_type, amount, ammomax);
 479         return true;
 480 }
 481
 482 void Item_NotifyWeapon(entity player, int wep)
 483 {
 484         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (it == player || (IS_SPEC(it) && it.enemy == player)), {
 485                 msg_entity = it;
 486                 WriteHeader(MSG_ONE, TE_CSQC_WEAPONPICKUP);
 487                 WriteByte(MSG_ONE, wep);
 488         });
 489 }
 490
 491 bool Item_GiveTo(entity item, entity player)
 492 {
 493         // if nothing happens to player, just return without taking the item
 494         int _switchweapon = 0;
 495         // in case the player has autoswitch enabled do the following:
 496         // if the player is using their best weapon before items are given, they
 497         // probably want to switch to an even better weapon after items are given
 498
 499         if(CS_CVAR(player).cvar_cl_autoswitch)
 500         {
 501                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 502                 {
 503                         .entity weaponentity = weaponentities[slot];
 504                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 505                         {
 506                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 507                                         _switchweapon |= BIT(slot);
 508
 509                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 510                                         _switchweapon |= BIT(slot);
 511                         }
 512                 }
 513         }
 514         bool pickedup = false;
 515         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
 516         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
 517         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
 518         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
 519         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
 520         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
 521         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
 522         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
 523         if (item.itemdef.instanceOfWeaponPickup)
 524         {
 525                 WepSet w, wp;
 526                 w = STAT(WEAPONS, item);
 527                 wp = w & ~STAT(WEAPONS, player);
 528
 529                 if (wp || (item.spawnshieldtime && item.pickup_anyway > 0))
 530                 {
 531                         pickedup = true;
 532                         FOREACH(Weapons, it != WEP_Null, {
 533                                 if(w & (it.m_wepset))
 534                                         Item_NotifyWeapon(player, it.m_id);
 535
 536                                 if(wp & (it.m_wepset))
 537                                 {
 538                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 539                                         {
 540                                                 .entity weaponentity = weaponentities[slot];
 541                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 542                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 543                                         }
 544                                         W_GiveWeapon(player, it.m_id);
 545                                 }
 546                         });
 547                 }
 548         }
 549
 550         if (item.itemdef.instanceOfPowerup)
 551         {
 552                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 553                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 554                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 555                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 556         }
 557
 558         int its;
 559         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 560         {
 561                 pickedup = true;
 562                 player.items |= its;
 563                 // TODO: we probably want to show a message in the console, but not this one!
 564                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 565         }
 566
 567         if (item.strength_finished)
 568         {
 569                 pickedup = true;
 570                 float t = max(StatusEffects_gettime(STATUSEFFECT_Strength, player), time);
 571                 if (autocvar_g_powerups_stack)
 572                         t += item.strength_finished;
 573                 else
 574                         t = max(t, time + item.strength_finished);
 575                 StatusEffects_apply(STATUSEFFECT_Strength, player, t, 0);
 576         }
 577         if (item.invincible_finished)
 578         {
 579                 pickedup = true;
 580                 float t = max(StatusEffects_gettime(STATUSEFFECT_Shield, player), time);
 581                 if (autocvar_g_powerups_stack)
 582                         t += item.invincible_finished;
 583                 else
 584                         t = max(t, time + item.invincible_finished);
 585                 StatusEffects_apply(STATUSEFFECT_Shield, player, t, 0);
 586         }
 587         if (item.speed_finished)
 588         {
 589                 pickedup = true;
 590                 float t = max(StatusEffects_gettime(STATUSEFFECT_Speed, player), time);
 591                 if (autocvar_g_powerups_stack)
 592                         t += item.speed_finished;
 593                 else
 594                         t = max(t, time + item.speed_finished);
 595                 StatusEffects_apply(STATUSEFFECT_Speed, player, t, 0);
 596         }
 597         if (item.invisibility_finished)
 598         {
 599                 pickedup = true;
 600                 float t = max(StatusEffects_gettime(STATUSEFFECT_Invisibility, player), time);
 601                 if (autocvar_g_powerups_stack)
 602                         t += item.invisibility_finished;
 603                 else
 604                         t = max(t, time + item.invisibility_finished);
 605                 StatusEffects_apply(STATUSEFFECT_Invisibility, player, t, 0);
 606         }
 607         if (item.superweapons_finished)
 608         {
 609                 pickedup = true;
 610                 StatusEffects_apply(STATUSEFFECT_Superweapons, player, max(StatusEffects_gettime(STATUSEFFECT_Superweapons, player), time) + item.superweapons_finished, 0);
 611         }
 612
 613         // always eat teamed entities
 614         if(item.team)
 615                 pickedup = true;
 616
 617         if (!pickedup)
 618                 return false;
 619
 620         // crude hack to enforce switching weapons
 621         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS_CVAR(player).cvar_cl_cts_noautoswitch)
 622         {
 623                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 624                 {
 625                         .entity weaponentity = weaponentities[slot];
 626                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 627                                 W_SwitchWeapon_Force(player, REGISTRY_GET(Weapons, item.weapon), weaponentity);
 628                 }
 629                 return true;
 630         }
 631
 632         if(_switchweapon)
 633         {
 634                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 635                 {
 636                         .entity weaponentity = weaponentities[slot];
 637                         if(_switchweapon & BIT(slot))
 638                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 639                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 640                 }
 641         }
 642
 643         return true;
 644 }
 645
 646 void Item_Touch(entity this, entity toucher)
 647 {
 648         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 649         if (Item_IsLoot(this))
 650         {
 651                 if (ITEM_TOUCH_NEEDKILL())
 652                 {
 653                         RemoveItem(this);
 654                         return;
 655                 }
 656         }
 657
 658         if(!(toucher.flags & FL_PICKUPITEMS)
 659         || STAT(FROZEN, toucher)
 660         || IS_DEAD(toucher)
 661         || (this.solid != SOLID_TRIGGER)
 662         || (this.owner == toucher)
 663         || (time < this.item_spawnshieldtime)
 664         ) { return; }
 665
 666         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 667         {
 668                 case MUT_ITEMTOUCH_RETURN: { return; }
 669                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 670         }
 671
 672         toucher = M_ARGV(1, entity);
 673
 674         if (Item_IsExpiring(this))
 675         {
 676                 this.strength_finished = max(0, this.strength_finished - time);
 677                 this.invincible_finished = max(0, this.invincible_finished - time);
 678                 this.speed_finished = max(0, this.speed_finished - time);
 679                 this.invisibility_finished = max(0, this.invisibility_finished - time);
 680                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 681         }
 682         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 683         if (!gave)
 684         {
 685                 if (Item_IsExpiring(this))
 686                 {
 687                         // undo what we did above
 688                         this.strength_finished += time;
 689                         this.invincible_finished += time;
 690                         this.speed_finished += time;
 691                         this.invisibility_finished += time;
 692                         this.superweapons_finished += time;
 693                 }
 694                 return;
 695         }
 696
 697 LABEL(pickup)
 698
 699         if(this.target && this.target != "" && this.target != "###item###") // defrag support
 700                 SUB_UseTargets(this, toucher, NULL);
 701
 702         STAT(LAST_PICKUP, toucher) = time;
 703
 704         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 705         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 706
 707         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 708         if (wasfreed(this))
 709         {
 710                 return;
 711         }
 712
 713         if (Item_IsLoot(this))
 714         {
 715                 delete(this);
 716                 return;
 717         }
 718         if (!this.spawnshieldtime)
 719         {
 720                 return;
 721         }
 722         entity e;
 723         if (this.team)
 724         {
 725                 RandomSelection_Init();
 726                 IL_EACH(g_items, it.team == this.team,
 727                 {
 728                         if (it.itemdef) // is a registered item
 729                         {
 730                                 Item_Show(it, -1);
 731                                 it.scheduledrespawntime = 0;
 732                                 RandomSelection_AddEnt(it, it.cnt, 0);
 733                         }
 734                 });
 735                 e = RandomSelection_chosen_ent;
 736                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 737         }
 738         else
 739                 e = this;
 740         Item_ScheduleRespawn(e);
 741 }
 742
 743 void Item_Reset(entity this)
 744 {
 745         Item_Show(this, !this.state);
 746
 747         if (Item_IsLoot(this))
 748         {
 749                 return;
 750         }
 751         setthink(this, Item_Think);
 752         this.nextthink = time;
 753         if (this.waypointsprite_attached)
 754         {
 755                 WaypointSprite_Kill(this.waypointsprite_attached);
 756         }
 757         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 758         {
 759                 Item_ScheduleInitialRespawn(this);
 760         }
 761 }
 762
 763 void Item_FindTeam(entity this)
 764 {
 765         if(!(this.effects & EF_NOGUNBOB)) // marker for item team search
 766                 return;
 767
 768         LOG_TRACE("Initializing item team ", ftos(this.team));
 769         RandomSelection_Init();
 770         IL_EACH(g_items, it.team == this.team,
 771         {
 772                 if(it.itemdef) // is a registered item
 773                         RandomSelection_AddEnt(it, it.cnt, 0);
 774         });
 775
 776         entity e = RandomSelection_chosen_ent;
 777         if (!e)
 778                 return;
 779
 780         IL_EACH(g_items, it.team == this.team,
 781         {
 782                 if(it.itemdef) // is a registered item
 783                 {
 784                         if(it != e)
 785                         {
 786                                 Item_Show(it, -1); // make it non-spawned
 787                                 if (it.waypointsprite_attached)
 788                                         WaypointSprite_Kill(it.waypointsprite_attached);
 789                                 it.nextthink = 0; // disable any scheduled powerup spawn
 790                         }
 791                         else
 792                                 Item_Reset(it);
 793
 794                         // leave 'this' marked so Item_FindTeam() works when called again via this.reset
 795                         if(it != this)
 796                                 it.effects &= ~EF_NOGUNBOB;
 797                 }
 798         });
 799 }
 800
 801 void Item_CopyFields(entity this, entity to)
 802 {
 803         setorigin(to, this.origin);
 804         to.spawnflags = this.spawnflags;
 805         to.noalign = Item_ShouldKeepPosition(this);
 806         to.cnt = this.cnt;
 807         to.team = this.team;
 808         to.spawnfunc_checked = true;
 809         // TODO: copy respawn times? this may not be desirable in some cases
 810         //to.respawntime = this.respawntime;
 811         //to.respawntimejitter = this.respawntimejitter;
 812 }
 813
 814 // Savage: used for item garbage-collection
 815 void RemoveItem(entity this)
 816 {
 817         if(wasfreed(this) || !this) { return; }
 818         if(this.waypointsprite_attached)
 819                 WaypointSprite_Kill(this.waypointsprite_attached);
 820         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 821         delete(this);
 822 }
 823
 824 // pickup evaluation functions
 825 // these functions decide how desirable an item is to the bots
 826
 827 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 828
 829 float weapon_pickupevalfunc(entity player, entity item)
 830 {
 831         // See if I have it already
 832         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
 833         {
 834                 // If I can pick it up
 835                 if(!item.spawnshieldtime)
 836                         return 0;
 837                 return ammo_pickupevalfunc(player, item);
 838         }
 839
 840         // reduce weapon value if bot already got a good arsenal
 841         float c = 1;
 842         int weapons_value = 0;
 843         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
 844                 weapons_value += it.bot_pickupbasevalue;
 845         });
 846         c -= bound(0, weapons_value / 20000, 1) * 0.5;
 847
 848         return item.bot_pickupbasevalue * c;
 849 }
 850
 851 float ammo_pickupevalfunc(entity player, entity item)
 852 {
 853         entity item_resource = NULL; // pointer to the resource that may be associated with the given item
 854         entity wpn = NULL;
 855         float c = 0;
 856         float rating = 0;
 857
 858         // detect needed ammo
 859         if(item.itemdef.instanceOfWeaponPickup)
 860         {
 861                 entity res = item.itemdef.m_weapon.ammo_type;
 862                 entity ammo = (res != RES_NONE) ? GetAmmoItem(res) : NULL;
 863                 if(!ammo)
 864                         return 0;
 865                 if(res != RES_NONE && GetResource(item, res))
 866                         item_resource = res;
 867
 868                 wpn = item;
 869                 rating = ammo.m_botvalue;
 870         }
 871         else
 872         {
 873                 FOREACH(Weapons, it != WEP_Null, {
 874                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
 875                                 continue;
 876                         if(it.ammo_type == RES_NONE)
 877                                 continue;
 878
 879                         if(GetResource(item, it.ammo_type))
 880                         {
 881                                 item_resource = it.ammo_type;
 882                                 break;
 883                         }
 884                 });
 885                 rating = item.bot_pickupbasevalue;
 886         }
 887
 888         float noammorating = 0.5;
 889
 890         if(item_resource && (GetResource(player, item_resource) < GetResourceLimit(player, item_resource)))
 891                 c = GetResource(item, item_resource) / max(noammorating, GetResource(player, item_resource));
 892
 893         rating *= min(c, 2);
 894         if(wpn)
 895                 rating += wpn.bot_pickupbasevalue * 0.1;
 896         return rating;
 897 }
 898
 899 float healtharmor_pickupevalfunc(entity player, entity item)
 900 {
 901         float c = 0;
 902         float rating = item.bot_pickupbasevalue;
 903
 904         float itemarmor = GetResource(item, RES_ARMOR);
 905         float itemhealth = GetResource(item, RES_HEALTH);
 906
 907         if(item.item_group)
 908         {
 909                 itemarmor *= min(4, item.item_group_count);
 910                 itemhealth *= min(4, item.item_group_count);
 911         }
 912
 913         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
 914                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
 915
 916         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
 917                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
 918
 919         rating *= min(2, c);
 920         return rating;
 921 }
 922
 923 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 924 {
 925         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 926                 RemoveItem(this);
 927 }
 928
 929 void item_use(entity this, entity actor, entity trigger)
 930 {
 931         // use the touch function to handle collection
 932         gettouch(this)(this, actor);
 933 }
 934
 935 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
 936 {
 937         string itemname = def.m_name;
 938         Model itemmodel = def.m_model;
 939         Sound pickupsound = def.m_sound;
 940         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
 941         float pickupbasevalue = def.m_botvalue;
 942         int itemflags = def.m_itemflags;
 943
 944         startitem_failed = false;
 945
 946         this.item_model_ent = itemmodel;
 947         this.item_pickupsound_ent = pickupsound;
 948
 949         if(def.m_iteminit)
 950                 def.m_iteminit(def, this);
 951
 952         if(!this.pickup_anyway && def.m_pickupanyway)
 953                 this.pickup_anyway = def.m_pickupanyway();
 954
 955         int itemid = def.m_itemid;
 956         this.items = itemid;
 957         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
 958         this.weapon = weaponid;
 959
 960         if(!this.fade_end)
 961         {
 962                 this.fade_start = autocvar_g_items_mindist;
 963                 this.fade_end = autocvar_g_items_maxdist;
 964         }
 965
 966         if(weaponid)
 967                 STAT(WEAPONS, this) = WepSet_FromWeapon(REGISTRY_GET(Weapons, weaponid));
 968
 969         this.flags = FL_ITEM | itemflags;
 970         IL_PUSH(g_items, this);
 971
 972         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
 973         {
 974                 startitem_failed = true;
 975                 delete(this);
 976                 return;
 977         }
 978
 979         if (Item_IsLoot(this))
 980         {
 981                 this.reset = RemoveItem;
 982                 set_movetype(this, MOVETYPE_TOSS);
 983
 984                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 985                 setthink(this, RemoveItem);
 986                 this.nextthink = time + autocvar_g_items_dropped_lifetime;
 987
 988                 this.takedamage = DAMAGE_YES;
 989                 this.event_damage = Item_Damage;
 990                 // enable this to have thrown items burn in lava
 991                 //this.damagedbycontents = true;
 992                 //IL_PUSH(g_damagedbycontents, this);
 993
 994                 if (Item_IsExpiring(this))
 995                 {
 996                         // if item is worthless after a timer, have it expire then
 997                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
 998                 }
 999
1000                 // don't drop if in a NODROP zone (such as lava)
1001                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1002                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1003                 {
1004                         startitem_failed = true;
1005                         delete(this);
1006                         return;
1007                 }
1008         }
1009         else
1010         {
1011                 // must be done after def.m_iteminit() as that may set ITEM_FLAG_MUTATORBLOCKED
1012                 if(!have_pickup_item(this))
1013                 {
1014                         startitem_failed = true;
1015                         delete(this);
1016                         return;
1017                 }
1018
1019                 // must be done before Item_Reset() and after MUTATORBLOCKED check (blocked items may have null func ptrs)
1020                 if(!this.respawntime) // both need to be set
1021                 {
1022                         this.respawntime = defaultrespawntime ? defaultrespawntime : def.m_respawntime();
1023                         this.respawntimejitter = defaultrespawntimejitter ? defaultrespawntimejitter : def.m_respawntimejitter();
1024                 }
1025
1026                 if(this.angles != '0 0 0')
1027                         this.SendFlags |= ISF_ANGLES;
1028
1029                 if(q3compat && !this.team)
1030                 {
1031                         string t = GetField_fullspawndata(this, "team");
1032                         // bones_was_here: this hack is cheaper than changing to a .string strcmp()
1033                         if(t) this.team = crc16(false, t);
1034                 }
1035
1036                 this.reset = this.team ? Item_FindTeam : Item_Reset;
1037                 // it's a level item
1038                 if(this.spawnflags & 1)
1039                         this.noalign = 1;
1040                 if (this.noalign > 0)
1041                         set_movetype(this, MOVETYPE_NONE);
1042                 else
1043                         set_movetype(this, MOVETYPE_TOSS);
1044                 // do item filtering according to game mode and other things
1045                 if (this.noalign <= 0)
1046                 {
1047                         // first nudge it off the floor a little bit to avoid math errors
1048                         setorigin(this, this.origin + '0 0 1');
1049                         // set item size before we spawn a spawnfunc_waypoint
1050                         setsize(this, def.m_mins, def.m_maxs);
1051                         this.SendFlags |= ISF_SIZE;
1052                         // note droptofloor returns false if stuck/or would fall too far
1053                         if (!this.noalign)
1054                                 droptofloor(this);
1055                         waypoint_spawnforitem(this);
1056                 }
1057
1058                 /*
1059                  * can't do it that way, as it would break maps
1060                  * TODO make a target_give like entity another way, that perhaps has
1061                  * the weapon name in a key
1062                 if(this.targetname)
1063                 {
1064                         // target_give not yet supported; maybe later
1065                         print("removed targeted ", this.classname, "\n");
1066                         startitem_failed = true;
1067                         delete(this);
1068                         return;
1069                 }
1070                 */
1071
1072                 if(this.targetname != "" && (this.spawnflags & 16))
1073                         this.use = item_use;
1074
1075                 if(autocvar_spawn_debug >= 2)
1076                 {
1077                         // why not flags & fl_item?
1078                         FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1079                                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1080                                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1081                                 error("Mapper sucks.");
1082                         });
1083                         this.is_item = true;
1084                 }
1085
1086                 weaponsInMap |= WepSet_FromWeapon(REGISTRY_GET(Weapons, weaponid));
1087
1088                 if (        def.instanceOfPowerup
1089                         ||  def.instanceOfWeaponPickup
1090                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1091                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1092                         || (itemid & (IT_KEY1 | IT_KEY2))
1093                 )
1094                 {
1095                         if(!this.target || this.target == "")
1096                                 this.target = "###item###"; // for finding the nearest item using findnearest
1097                 }
1098
1099                 Item_ItemsTime_SetTime(this, 0);
1100         }
1101
1102         this.bot_pickup = true;
1103         this.bot_pickupevalfunc = pickupevalfunc;
1104         this.bot_pickupbasevalue = pickupbasevalue;
1105         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1106         this.netname = itemname;
1107         settouch(this, Item_Touch);
1108         setmodel(this, MDL_Null); // precision set below
1109         //this.effects |= EF_LOWPRECISION;
1110
1111         // support skinned models for powerups
1112         if(!this.skin)
1113                 this.skin = def.m_skin;
1114
1115         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1116
1117         this.SendFlags |= ISF_SIZE;
1118
1119         if (!(this.spawnflags & 1024)) {
1120                 if(def.instanceOfPowerup)
1121                         this.ItemStatus |= ITS_ANIMATE1;
1122
1123                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1124                         this.ItemStatus |= ITS_ANIMATE2;
1125         }
1126
1127         if(Item_IsLoot(this))
1128                 this.gravity = 1;
1129         else
1130                 this.glowmod = def.m_color;
1131
1132         if(def.instanceOfWeaponPickup)
1133         {
1134                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1135                         this.colormap = 1024; // color shirt=0 pants=0 grey
1136                 if (!(this.spawnflags & 1024))
1137                         this.ItemStatus |= ITS_ANIMATE1;
1138                 this.SendFlags |= ISF_COLORMAP;
1139         }
1140
1141         this.state = 0;
1142         if(this.team)
1143         {
1144                 if(!this.cnt)
1145                         this.cnt = 1; // item probability weight
1146
1147                 this.effects |= EF_NOGUNBOB; // marker for item team search
1148                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1149         }
1150         else
1151                 Item_Reset(this);
1152
1153         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1154
1155         // call this hook after everything else has been done
1156         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1157         {
1158                 startitem_failed = true;
1159                 delete(this);
1160                 return;
1161         }
1162
1163         // we should be sure this item will spawn before loading its assets
1164         precache_model(this.model);
1165         precache_sound(this.item_pickupsound);
1166
1167         setItemGroup(this);
1168 }
1169
1170 void StartItem(entity this, GameItem def)
1171 {
1172         def = def.m_spawnfunc_hookreplace(def, this);
1173
1174         this.classname = def.m_canonical_spawnfunc;
1175
1176         _StartItem(
1177                 this,
1178                 this.itemdef = def,
1179                 0, // call def.m_respawntime() to get defaultrespawntime
1180                 0  // call def.m_respawntimejitter() to get defaultrespawntimejitter
1181         );
1182 }
1183
1184 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1185 int group_count = 1;
1186
1187 void setItemGroup(entity this)
1188 {
1189         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1190                 return;
1191
1192         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1193         {
1194                 if(!this.item_group)
1195                 {
1196                         if(!it.item_group)
1197                         {
1198                                 it.item_group = group_count;
1199                                 group_count++;
1200                         }
1201                         this.item_group = it.item_group;
1202                 }
1203                 else // spawning item is already part of a item_group X
1204                 {
1205                         if(!it.item_group)
1206                                 it.item_group = this.item_group;
1207                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1208                         {
1209                                 int grY = it.item_group;
1210                                 // move all items of item_group Y to item_group X
1211                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1212                                 {
1213                                         if(it.item_group == grY)
1214                                                 it.item_group = this.item_group;
1215                                 });
1216                         }
1217                 }
1218         });
1219 }
1220
1221 void setItemGroupCount()
1222 {
1223         for (int k = 1; k <= group_count; k++)
1224         {
1225                 int count = 0;
1226                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1227                 if (count)
1228                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1229         }
1230 }
1231
1232 void target_items_use(entity this, entity actor, entity trigger)
1233 {
1234         if(Item_IsLoot(actor))
1235         {
1236                 EXACTTRIGGER_TOUCH(this, trigger);
1237                 delete(actor);
1238                 return;
1239         }
1240
1241         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1242                 return;
1243
1244         if(trigger.solid == SOLID_TRIGGER)
1245         {
1246                 EXACTTRIGGER_TOUCH(this, trigger);
1247         }
1248
1249         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1250         {
1251                 delete(it);
1252         });
1253
1254         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1255                 centerprint(actor, this.message);
1256 }
1257
1258 spawnfunc(target_items)
1259 {
1260         this.use = target_items_use;
1261         if(!this.strength_finished)
1262                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1263         if(!this.invincible_finished)
1264                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1265         if(!this.speed_finished)
1266                 this.speed_finished = autocvar_g_balance_powerup_speed_time;
1267         if(!this.invisibility_finished)
1268                 this.invisibility_finished = autocvar_g_balance_powerup_invisibility_time;
1269         if(!this.superweapons_finished)
1270                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1271
1272         string str;
1273         int n = tokenize_console(this.netname);
1274         if(argv(0) == "give")
1275         {
1276                 str = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1277         }
1278         else
1279         {
1280                 for(int j = 0; j < n; ++j)
1281                 {
1282                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1283                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1284                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1285                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1286                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1287                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1288                         else if(argv(j) == "speed")                  this.items |= ITEM_Speed.m_itemid;
1289                         else if(argv(j) == "invisibility")           this.items |= ITEM_Invisibility.m_itemid;
1290                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1291                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1292                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1293                         else
1294                         {
1295                                 FOREACH(StatusEffect, it.instanceOfBuff,
1296                                 {
1297                                         string s = Buff_CompatName(argv(j));
1298                                         if(s == it.netname)
1299                                         {
1300                                                 this.buffdef = it;
1301                                                 if(!this.buffs_finished)
1302                                                         this.buffs_finished = it.m_time(it);
1303                                                 break;
1304                                         }
1305                                 });
1306                                 FOREACH(Weapons, it != WEP_Null, {
1307                                         string s = argv(j);
1308                                         if(s == it.netname || s == it.m_deprecated_netname)
1309                                         {
1310                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1311                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1312                                                         it.wr_init(it);
1313                                                 break;
1314                                         }
1315                                 });
1316                         }
1317                 }
1318
1319                 string itemprefix, valueprefix;
1320                 if(this.spawnflags == 0)
1321                 {
1322                         itemprefix = "";
1323                         valueprefix = "";
1324                 }
1325                 else if(this.spawnflags == 1)
1326                 {
1327                         itemprefix = "max ";
1328                         valueprefix = "max ";
1329                 }
1330                 else if(this.spawnflags == 2)
1331                 {
1332                         itemprefix = "min ";
1333                         valueprefix = "min ";
1334                 }
1335                 else if(this.spawnflags == 4)
1336                 {
1337                         itemprefix = "minus ";
1338                         valueprefix = "max ";
1339                 }
1340                 else
1341                 {
1342                         error("invalid spawnflags");
1343                         itemprefix = valueprefix = string_null;
1344                 }
1345
1346                 str = "";
1347                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1348                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1349                 str = sprintf("%s %s%d %s", str, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1350                 str = sprintf("%s %s%d %s", str, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1351                 str = sprintf("%s %s%d %s", str, valueprefix, this.invisibility_finished * boolean(this.items & ITEM_Invisibility.m_itemid), "invisibility");
1352                 str = sprintf("%s %s%d %s", str, valueprefix, this.speed_finished * boolean(this.items & ITEM_Speed.m_itemid), "speed");
1353                 str = sprintf("%s %s%d %s", str, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1354                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1355                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1356                 float res;
1357                 res = GetResource(this, RES_SHELLS);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "shells");
1358                 res = GetResource(this, RES_BULLETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "nails");
1359                 res = GetResource(this, RES_ROCKETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "rockets");
1360                 res = GetResource(this, RES_CELLS);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "cells");
1361                 res = GetResource(this, RES_PLASMA);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "plasma");
1362                 res = GetResource(this, RES_FUEL);    if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "fuel");
1363                 res = GetResource(this, RES_HEALTH);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "health");
1364                 res = GetResource(this, RES_ARMOR);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "armor");
1365                 FOREACH(StatusEffect, it.instanceOfBuff, str = sprintf("%s %s%d %s", str, valueprefix, this.buffs_finished * boolean(this.buffdef == it), it.netname));
1366                 FOREACH(Weapons, it != WEP_Null, str = sprintf("%s %s%d %s", str, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1367         }
1368         this.netname = strzone(str);
1369
1370         n = tokenize_console(this.netname);
1371         for(int j = 0; j < n; ++j)
1372         {
1373                 string cmd = argv(j);
1374                 FOREACH(Weapons, it != WEP_Null && (cmd == it.netname || cmd == it.m_deprecated_netname), {
1375                         it.wr_init(it);
1376                         break;
1377                 });
1378         }
1379 }
1380
1381 float GiveWeapon(entity e, float wpn, float op, float val)
1382 {
1383         WepSet v0, v1;
1384         WepSet s = WepSet_FromWeapon(REGISTRY_GET(Weapons, wpn));
1385         v0 = (STAT(WEAPONS, e) & s);
1386         switch(op)
1387         {
1388                 case OP_SET:
1389                         if(val > 0)
1390                                 STAT(WEAPONS, e) |= s;
1391                         else
1392                                 STAT(WEAPONS, e) &= ~s;
1393                         break;
1394                 case OP_MIN:
1395                 case OP_PLUS:
1396                         if(val > 0)
1397                                 STAT(WEAPONS, e) |= s;
1398                         break;
1399                 case OP_MAX:
1400                         if(val <= 0)
1401                                 STAT(WEAPONS, e) &= ~s;
1402                         break;
1403                 case OP_MINUS:
1404                         if(val > 0)
1405                                 STAT(WEAPONS, e) &= ~s;
1406                         break;
1407         }
1408         v1 = (STAT(WEAPONS, e) & s);
1409         return (v0 != v1);
1410 }
1411
1412 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1413 {
1414         bool had_buff = StatusEffects_active(thebuff, e);
1415         float new_buff_time = ((had_buff) ? StatusEffects_gettime(thebuff, e) : 0);
1416         switch (op)
1417         {
1418                 case OP_SET:
1419                         new_buff_time = val;
1420                         break;
1421                 case OP_MIN:
1422                         new_buff_time = max(new_buff_time, val);
1423                         break;
1424                 case OP_MAX:
1425                         new_buff_time = min(new_buff_time, val);
1426                         break;
1427                 case OP_PLUS:
1428                         new_buff_time += val;
1429                         break;
1430                 case OP_MINUS:
1431                         new_buff_time -= val;
1432                         break;
1433         }
1434         if(new_buff_time <= 0)
1435         {
1436                 if(had_buff) // only trigger removal mechanics if there is an effect to remove!
1437                         StatusEffects_remove(thebuff, e, STATUSEFFECT_REMOVE_NORMAL);
1438         }
1439         else
1440         {
1441                 buff_RemoveAll(e, STATUSEFFECT_REMOVE_CLEAR); // clear old buffs on the player first!
1442                 StatusEffects_apply(thebuff, e, new_buff_time, 0);
1443         }
1444         bool have_buff = StatusEffects_active(thebuff, e);
1445         return (had_buff != have_buff);
1446 }
1447
1448 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1449 {
1450         if(v1 == v0)
1451                 return;
1452         if(v1 <= v0 - t)
1453         {
1454                 if(snd_decr != NULL)
1455                         sound(e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1456         }
1457         else if(v0 >= v0 + t)
1458         {
1459                 if(snd_incr != NULL)
1460                         sound(e, ((snd_incr == SND_POWERUP) ? CH_TRIGGER_SINGLE : CH_TRIGGER), snd_incr, VOL_BASE, ATTEN_NORM);
1461         }
1462 }
1463
1464 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1465 {
1466         if(v0 < v1)
1467                 e.(rotfield) = max(e.(rotfield), time + rottime);
1468         else if(v0 > v1)
1469                 e.(regenfield) = max(e.(regenfield), time + regentime);
1470 }
1471 bool GiveResourceValue(entity e, Resource res_type, int op, int val)
1472 {
1473         int v0 = GetResource(e, res_type);
1474         float new_val = 0;
1475         switch (op)
1476         {
1477                 // min 100 cells = at least 100 cells
1478                 case OP_SET: new_val = val; break;
1479                 case OP_MIN: new_val = max(v0, val); break;
1480                 case OP_MAX: new_val = min(v0, val); break;
1481                 case OP_PLUS: new_val = v0 + val; break;
1482                 case OP_MINUS: new_val = v0 - val; break;
1483                 default: return false;
1484         }
1485
1486         return SetResourceExplicit(e, res_type, new_val);
1487 }
1488 bool GiveStatusEffect(entity e, StatusEffects this, int op, float val)
1489 {
1490         bool had_eff = StatusEffects_active(this, e);
1491         float new_eff_time = ((had_eff) ? StatusEffects_gettime(this, e) : 0);
1492         switch (op)
1493         {
1494                 case OP_SET:
1495                         new_eff_time = val;
1496                         break;
1497                 case OP_MIN:
1498                         new_eff_time = max(new_eff_time, val);
1499                         break;
1500                 case OP_MAX:
1501                         new_eff_time = min(new_eff_time, val);
1502                         break;
1503                 case OP_PLUS:
1504                         new_eff_time += val;
1505                         break;
1506                 case OP_MINUS:
1507                         new_eff_time -= val;
1508                         break;
1509         }
1510         if(new_eff_time <= 0)
1511         {
1512                 if(had_eff) // only trigger removal mechanics if there is an effect to remove!
1513                         StatusEffects_remove(this, e, STATUSEFFECT_REMOVE_NORMAL);
1514         }
1515         else
1516                 StatusEffects_apply(this, e, new_eff_time, 0);
1517         bool have_eff = StatusEffects_active(this, e);
1518         return (had_eff != have_eff);
1519 }
1520
1521 float GiveItems(entity e, float beginarg, float endarg)
1522 {
1523         float got, i, val, op;
1524         string cmd;
1525
1526         val = 999;
1527         op = OP_SET;
1528
1529         got = 0;
1530
1531         int _switchweapon = 0;
1532
1533         if(CS_CVAR(e).cvar_cl_autoswitch)
1534         {
1535                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1536                 {
1537                         .entity weaponentity = weaponentities[slot];
1538                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1539                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1540                                 _switchweapon |= BIT(slot);
1541                 }
1542         }
1543
1544         if(e.statuseffects)
1545         {
1546                 FOREACH(StatusEffect, true,
1547                 {
1548                         e.statuseffects.statuseffect_time[it.m_id] = max(0, e.statuseffects.statuseffect_time[it.m_id] - time);
1549                 });
1550         }
1551
1552         PREGIVE(e, items);
1553         PREGIVE_WEAPONS(e);
1554         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Strength);
1555         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Shield);
1556         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Speed);
1557         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Invisibility);
1558         //PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Superweapons);
1559         PREGIVE_RESOURCE(e, RES_BULLETS);
1560         PREGIVE_RESOURCE(e, RES_CELLS);
1561         PREGIVE_RESOURCE(e, RES_PLASMA);
1562         PREGIVE_RESOURCE(e, RES_SHELLS);
1563         PREGIVE_RESOURCE(e, RES_ROCKETS);
1564         PREGIVE_RESOURCE(e, RES_FUEL);
1565         PREGIVE_RESOURCE(e, RES_ARMOR);
1566         PREGIVE_RESOURCE(e, RES_HEALTH);
1567
1568         for(i = beginarg; i < endarg; ++i)
1569         {
1570                 cmd = argv(i);
1571
1572                 if(cmd == "0" || stof(cmd))
1573                 {
1574                         val = stof(cmd);
1575                         continue;
1576                 }
1577                 switch(cmd)
1578                 {
1579                         case "no":
1580                                 op = OP_MAX;
1581                                 val = 0;
1582                                 continue;
1583                         case "max":
1584                                 op = OP_MAX;
1585                                 continue;
1586                         case "min":
1587                                 op = OP_MIN;
1588                                 continue;
1589                         case "plus":
1590                                 op = OP_PLUS;
1591                                 continue;
1592                         case "minus":
1593                                 op = OP_MINUS;
1594                                 continue;
1595                         case "ALL":
1596                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1597                                 FOREACH(StatusEffect, it.instanceOfPowerups, got += GiveStatusEffect(e, it, op, val));
1598                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1599                         case "all":
1600                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1601                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1602                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1603                         case "allweapons":
1604                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1605                         //case "allbuffs": // all buffs makes a player god, do not want!
1606                                 //FOREACH(StatusEffect, it.instanceOfBuff, got += GiveBuff(e, it, op, val));
1607                         case "allammo":
1608                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1609                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1610                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1611                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1612                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1613                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1614                                 break;
1615                         case "unlimited_ammo":
1616                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1617                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1618                                 break;
1619                         case "unlimited_weapon_ammo":
1620                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1621                                 break;
1622                         case "unlimited_superweapons":
1623                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1624                                 break;
1625                         case "jetpack":
1626                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1627                                 break;
1628                         case "fuel_regen":
1629                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1630                                 break;
1631                         case "strength":
1632                                 got += GiveStatusEffect(e, STATUSEFFECT_Strength, op, val);
1633                                 break;
1634                         case "invincible":
1635                         case "shield":
1636                                 got += GiveStatusEffect(e, STATUSEFFECT_Shield, op, val);
1637                                 break;
1638                         case "speed":
1639                                 got += GiveStatusEffect(e, STATUSEFFECT_Speed, op, val);
1640                                 break;
1641                         case "invisibility":
1642                                 got += GiveStatusEffect(e, STATUSEFFECT_Invisibility, op, val);
1643                                 break;
1644                         case "superweapons":
1645                                 got += GiveStatusEffect(e, STATUSEFFECT_Superweapons, op, val);
1646                                 break;
1647                         case "cells":
1648                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1649                                 break;
1650                         case "plasma":
1651                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1652                                 break;
1653                         case "shells":
1654                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1655                                 break;
1656                         case "nails":
1657                         case "bullets":
1658                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1659                                 break;
1660                         case "rockets":
1661                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1662                                 break;
1663                         case "health":
1664                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1665                                 break;
1666                         case "armor":
1667                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1668                                 break;
1669                         case "fuel":
1670                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1671                                 break;
1672                         default:
1673                                 FOREACH(StatusEffect, it.instanceOfBuff && buff_Available(it) && Buff_CompatName(cmd) == it.netname,
1674                                 {
1675                                         got += GiveBuff(e, it, op, val);
1676                                         break;
1677                                 });
1678                                 FOREACH(Weapons, it != WEP_Null && (cmd == it.netname || cmd == it.m_deprecated_netname), {
1679                     got += GiveWeapon(e, it.m_id, op, val);
1680                     break;
1681                                 });
1682                                 break;
1683                 }
1684                 val = 999;
1685                 op = OP_SET;
1686         }
1687
1688         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1689         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1690         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1691         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1692         FOREACH(Weapons, it != WEP_Null, {
1693                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1694                 if(!(save_weapons & (it.m_wepset)))
1695                         if(STAT(WEAPONS, e) & (it.m_wepset))
1696                                 it.wr_init(it);
1697         });
1698         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Strength, SND_POWERUP, SND_POWEROFF);
1699         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Shield, SND_POWERUP, SND_POWEROFF);
1700         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Speed, SND_POWERUP, SND_POWEROFF);
1701         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Invisibility, SND_POWERUP, SND_POWEROFF);
1702         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1703         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1704         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1705         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1706         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1707         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1708         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1709         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1710
1711         if(!StatusEffects_active(STATUSEFFECT_Superweapons, e))
1712         {
1713                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1714                         StatusEffects_apply(STATUSEFFECT_Superweapons, e, autocvar_g_balance_superweapons_time, 0);
1715         }
1716
1717         if(e.statuseffects)
1718         {
1719                 FOREACH(StatusEffect, true,
1720                 {
1721                         if(e.statuseffects.statuseffect_time[it.m_id] <= 0)
1722                                 e.statuseffects.statuseffect_time[it.m_id] = 0;
1723                         else
1724                                 e.statuseffects.statuseffect_time[it.m_id] += time;
1725                 });
1726
1727                 StatusEffects_update(e);
1728         }
1729
1730         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1731         {
1732                 .entity weaponentity = weaponentities[slot];
1733                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1734                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1735                         _switchweapon |= BIT(slot);
1736         }
1737
1738         if(_switchweapon)
1739         {
1740                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1741                 {
1742                         .entity weaponentity = weaponentities[slot];
1743                         if(_switchweapon & BIT(slot))
1744                         {
1745                                 Weapon wep = w_getbestweapon(e, weaponentity);
1746                                 if(wep != e.(weaponentity).m_switchweapon)
1747                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1748                         }
1749                 }
1750         }
1751
1752         return got;
1753 }