qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431                 BADCVAR("g_grappling_hook");
 432                 BADCVAR("g_jetpack");
 433
 434 #undef BADPREFIX
 435 #undef BADCVAR
 436
 437                 if(pureadding)
 438                 {
 439                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 440                         if(strlen(cvar_purechanges) > 16384)
 441                         {
 442                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 443                                 pureadding = 0;
 444                         }
 445                 }
 446                 ++cvar_purechanges_count;
 447                 // WARNING: this variable is used for the server list
 448                 // NEVER dare to skip this code!
 449                 // Hacks to intentionally appearing as "pure server" even though you DO have
 450                 // modified settings may be punished by removal from the server list.
 451                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 452                 // though.
 453         }
 454         buf_del(h);
 455         if(cvar_changes == "")
 456                 cvar_changes = "// this server runs at default server settings\n";
 457         else
 458                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 459         cvar_changes = strzone(cvar_changes);
 460         if(cvar_purechanges == "")
 461                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 462         else
 463                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 464         cvar_purechanges = strzone(cvar_purechanges);
 465 }
 466
 467 void detect_maptype()
 468 {
 469 #if 0
 470         vector o, v;
 471         float i;
 472
 473         for(;;)
 474         {
 475                 o = world.mins;
 476                 o_x += random() * (world.maxs_x - world.mins_x);
 477                 o_y += random() * (world.maxs_y - world.mins_y);
 478                 o_z += random() * (world.maxs_z - world.mins_z);
 479
 480                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 481                 if(trace_fraction == 1)
 482                         continue;
 483
 484                 v = trace_endpos;
 485
 486                 for(i = 0; i < 64; i += 4)
 487                 {
 488                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 489         if(trace_fraction == 1)
 490                 continue;
 491                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 492                 }
 493
 494                 break;
 495         }
 496 #endif
 497 }
 498
 499 entity randomseed;
 500 float RandomSeed_Send(entity to, float sf)
 501 {
 502         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 503         WriteShort(MSG_ENTITY, self.cnt);
 504         return TRUE;
 505 }
 506 void RandomSeed_Think()
 507 {
 508         self.cnt = bound(0, floor(random() * 65536), 65535);
 509         self.nextthink = time + 5;
 510
 511         self.SendFlags |= 1;
 512 }
 513 void RandomSeed_Spawn()
 514 {
 515         randomseed = spawn();
 516         randomseed.think = RandomSeed_Think;
 517         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 518
 519         entity oldself;
 520         oldself = self;
 521         self = randomseed;
 522         self.think(); // sets random seed and nextthink
 523         self = oldself;
 524 }
 525
 526 void spawnfunc___init_dedicated_server(void)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e;
 538         e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = spawn();
 543         e.classname = "info_player_deathmatch"; // safeguard against player joining
 544
 545         self.classname = "worldspawn"; // safeguard against various stuff ;)
 546
 547         // needs to be done so early because of the constants they create
 548         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 549         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 550         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 551         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void Nagger_Init();
 560 void ClientInit_Spawn();
 561 void WeaponStats_Init();
 562 void WeaponStats_Shutdown();
 563 void spawnfunc_worldspawn (void)
 564 {
 565         float fd, l, i, j, n;
 566         string s, col;
 567
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         if(world_already_spawned)
 573                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 574         world_already_spawned = TRUE;
 575
 576         remove = remove_safely; // during spawning, watch what you remove!
 577
 578         check_unacceptable_compiler_bugs();
 579
 580         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 581
 582         compressShortVector_init();
 583
 584         entity head;
 585         head = nextent(world);
 586         maxclients = 0;
 587         while(head)
 588         {
 589                 ++maxclients;
 590                 head = nextent(head);
 591         }
 592
 593         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 594
 595         // needs to be done so early because of the constants they create
 596         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_norecoil)
 707                         s = strcat(s, ":norecoil");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_powerups == 0)
 711                         s = strcat(s, ":no_powerups");
 712                 if(autocvar_g_powerups > 0)
 713                         s = strcat(s, ":powerups");
 714
 715                 GameLogEcho(s);
 716                 GameLogEcho(":gameinfo:end");
 717         }
 718         else
 719                 matchid = strzone(ftos(random()));
 720
 721         cvar_set("nextmap", "");
 722
 723         SetDefaultAlpha();
 724
 725         if(autocvar_g_campaign)
 726                 CampaignPostInit();
 727
 728         fteqcc_testbugs();
 729
 730         Ban_LoadBans();
 731
 732         MapInfo_Enumerate();
 733         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 734
 735         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 736         {
 737                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 738                 if(fd != -1)
 739                 {
 740                         while((s = fgets(fd)))
 741                         {
 742                                 l = tokenize_console(s);
 743                                 if(l < 2)
 744                                         continue;
 745                                 if(argv(0) == "cd")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 748                                         print("  cdtrack ", argv(2), "\n");
 749                                 }
 750                                 else if(argv(0) == "fog")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 753                                         print("  \"fog\" \"", s, "\"\n");
 754                                 }
 755                                 else if(argv(0) == "set")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) != "//")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 764                                 }
 765                         }
 766                         fclose(fd);
 767                 }
 768         }
 769
 770         WeaponStats_Init();
 771
 772         WEPSET_ADDSTAT();
 773         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 774         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 775         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 776         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 777         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 778         Nagger_Init();
 779
 780         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 781         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 782         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 783         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 784         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 795         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         // freeze attacks
 800         addstat(STAT_FROZEN, AS_INT, frozen);
 801         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 802
 803         // g_movementspeed hack
 804         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 805         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 806         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 807         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 808
 809         // secrets
 810         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 811         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 812
 813         // monsters
 814         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 815         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 816
 817         // misc
 818         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 819
 820         next_pingtime = time + 5;
 821
 822         detect_maptype();
 823
 824         // set up information replies for clients and server to use
 825         lsmaps_reply = "^7Maps available: ";
 826         lsnewmaps_reply = "^7Maps without a record set: ";
 827         for(i = 0, j = 0; i < MapInfo_count; ++i)
 828         {
 829                 if(MapInfo_Get_ByID(i))
 830                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 831                         {
 832                                 if(mod(i, 2))
 833                                         col = "^2";
 834                                 else
 835                                         col = "^3";
 836
 837                                 ++j;
 838
 839                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 840
 841                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 842                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 843                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 844                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 845                         }
 846         }
 847
 848         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 849         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 850
 851         maplist_reply = "^7Maps in list: ";
 852         n = tokenize_console(autocvar_g_maplist);
 853         for(i = 0, j = 0; i < n; ++i)
 854         {
 855                 if(MapInfo_CheckMap(argv(i)))
 856                 {
 857                         if(mod(j, 2))
 858                                 col = "^2";
 859                         else
 860                                 col = "^3";
 861                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 862                         ++j;
 863                 }
 864         }
 865         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 866         MapInfo_ClearTemps();
 867
 868         for(i = 0; i < 10; ++i)
 869         {
 870                 s = getrecords(i);
 871                 if (s)
 872                         records_reply[i] = strzone(s);
 873         }
 874
 875         ladder_reply = strzone(getladder());
 876
 877         rankings_reply = strzone(getrankings());
 878
 879         // begin other init
 880         ClientInit_Spawn();
 881         RandomSeed_Spawn();
 882         PingPLReport_Spawn();
 883
 884         CheatInit();
 885
 886         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 887
 888         // fill sv_curl_serverpackages from .serverpackage files
 889         if(autocvar_sv_curl_serverpackages_auto)
 890         {
 891                 s = "";
 892                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 893                 for(i = 0; i < n; ++i)
 894                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 895                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 896                                 s = strcat(s, " ", argv(i));
 897                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 898                 if(fd >= 0)
 899                 {
 900                         j = search_getsize(fd);
 901                         for(i = 0; i < j; ++i)
 902                                 s = strcat(s, " ", search_getfilename(fd, i));
 903                         search_end(fd);
 904                 }
 905                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 906                 if(fd >= 0)
 907                 {
 908                         j = search_getsize(fd);
 909                         for(i = 0; i < j; ++i)
 910                                 s = strcat(s, " ", search_getfilename(fd, i));
 911                         search_end(fd);
 912                 }
 913                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 914         }
 915
 916         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 917         modname = "Xonotic";
 918         // physics/balance/config changes that count as mod
 919         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 920                 modname = cvar_string("g_mod_physics");
 921         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 922                 modname = cvar_string("g_mod_balance");
 923         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 924                 modname = cvar_string("g_mod_config");
 925         // extra mutators that deserve to count as mod
 926         MUTATOR_CALLHOOK(SetModname);
 927
 928         // save it for later
 929         modname = strzone(modname);
 930
 931         WinningConditionHelper(); // set worldstatus
 932
 933         world_initialized = 1;
 934 }
 935
 936 void spawnfunc_light (void)
 937 {
 938         //makestatic (self); // Who the f___ did that?
 939         remove(self);
 940 }
 941
 942 string GetGametype()
 943 {
 944         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 945 }
 946
 947 string getmapname_stored;
 948 string GetMapname()
 949 {
 950         return mapname;
 951 }
 952
 953 float Map_Count, Map_Current;
 954 string Map_Current_Name;
 955
 956 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 957 float GetMaplistPosition()
 958 {
 959         float pos, idx;
 960         string map;
 961
 962         map = GetMapname();
 963         idx = autocvar_g_maplist_index;
 964
 965         if(idx >= 0)
 966                 if(idx < Map_Count)
 967                         if(map == argv(idx))
 968                                 return idx;
 969
 970         for(pos = 0; pos < Map_Count; ++pos)
 971                 if(map == argv(pos))
 972                         return pos;
 973
 974         // resume normal maplist rotation if current map is not in g_maplist
 975         return idx;
 976 }
 977
 978 float MapHasRightSize(string map)
 979 {
 980         float fh;
 981         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 982         if(autocvar_g_maplist_check_waypoints)
 983         {
 984                 dprint("checkwp "); dprint(map);
 985                 if(!fexists(strcat("maps/", map, ".waypoints")))
 986                 {
 987                         dprint(": no waypoints\n");
 988                         return FALSE;
 989                 }
 990                 dprint(": has waypoints\n");
 991         }
 992
 993         // open map size restriction file
 994         dprint("opensize "); dprint(map);
 995         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 996         if(fh >= 0)
 997         {
 998                 float mapmin, mapmax;
 999                 dprint(": ok, ");
1000                 mapmin = stof(fgets(fh));
1001                 mapmax = stof(fgets(fh));
1002                 fclose(fh);
1003                 if(player_count < mapmin)
1004                 {
1005                         dprint("not enough\n");
1006                         return FALSE;
1007                 }
1008                 if(player_count > mapmax)
1009                 {
1010                         dprint("too many\n");
1011                         return FALSE;
1012                 }
1013                 dprint("right size\n");
1014                 return TRUE;
1015         }
1016         dprint(": not found\n");
1017         return TRUE;
1018 }
1019
1020 string Map_Filename(float position)
1021 {
1022         return strcat("maps/", argv(position), ".bsp");
1023 }
1024
1025 string strwords(string s, float w)
1026 {
1027         float endpos;
1028         for(endpos = 0; w && endpos >= 0; --w)
1029                 endpos = strstrofs(s, " ", endpos + 1);
1030         if(endpos < 0)
1031                 return s;
1032         else
1033                 return substring(s, 0, endpos);
1034 }
1035
1036 float strhasword(string s, string w)
1037 {
1038         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1039 }
1040
1041 void Map_MarkAsRecent(string m)
1042 {
1043         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1044 }
1045
1046 float Map_IsRecent(string m)
1047 {
1048         return strhasword(autocvar_g_maplist_mostrecent, m);
1049 }
1050
1051 float Map_Check(float position, float pass)
1052 {
1053         string filename;
1054         string map_next;
1055         map_next = argv(position);
1056         if(pass <= 1)
1057         {
1058                 if(Map_IsRecent(map_next))
1059                         return 0;
1060         }
1061         filename = Map_Filename(position);
1062         if(MapInfo_CheckMap(map_next))
1063         {
1064                 if(pass == 2)
1065                         return 1;
1066                 if(MapHasRightSize(map_next))
1067                         return 1;
1068                 return 0;
1069         }
1070         else
1071                 dprint( "Couldn't select '", filename, "'..\n" );
1072
1073         return 0;
1074 }
1075
1076 void Map_Goto_SetStr(string nextmapname)
1077 {
1078         if(getmapname_stored != "")
1079                 strunzone(getmapname_stored);
1080         if(nextmapname == "")
1081                 getmapname_stored = "";
1082         else
1083                 getmapname_stored = strzone(nextmapname);
1084 }
1085
1086 void Map_Goto_SetFloat(float position)
1087 {
1088         cvar_set("g_maplist_index", ftos(position));
1089         Map_Goto_SetStr(argv(position));
1090 }
1091
1092 void Map_Goto(float reinit)
1093 {
1094         MapInfo_LoadMap(getmapname_stored, reinit);
1095 }
1096
1097 // return codes of map selectors:
1098 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1099 //   -2 = permanent failure
1100 float() MaplistMethod_Iterate = // usual method
1101 {
1102         float pass, i;
1103
1104         for(pass = 1; pass <= 2; ++pass)
1105         {
1106                 for(i = 1; i < Map_Count; ++i)
1107                 {
1108                         float mapindex;
1109                         mapindex = mod(i + Map_Current, Map_Count);
1110                         if(Map_Check(mapindex, pass))
1111                                 return mapindex;
1112                 }
1113         }
1114         return -1;
1115 }
1116
1117 float() MaplistMethod_Repeat = // fallback method
1118 {
1119         if(Map_Check(Map_Current, 2))
1120                 return Map_Current;
1121         return -2;
1122 }
1123
1124 float() MaplistMethod_Random = // random map selection
1125 {
1126         float i, imax;
1127
1128         imax = 42;
1129
1130         for(i = 0; i <= imax; ++i)
1131         {
1132                 float mapindex;
1133                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1134                 if(Map_Check(mapindex, 1))
1135                         return mapindex;
1136         }
1137         return -1;
1138 }
1139
1140 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1141 // the exponent sets a bias on the map selection:
1142 // the higher the exponent, the less likely "shortly repeated" same maps are
1143 {
1144         float i, j, imax, insertpos;
1145
1146         imax = 42;
1147
1148         for(i = 0; i <= imax; ++i)
1149         {
1150                 string newlist;
1151
1152                 // now reinsert this at another position
1153                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1154                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1155                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1156                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1157
1158                 // insert the current map there
1159                 newlist = "";
1160                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1161                         newlist = strcat(newlist, " ", argv(j));
1162                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1163                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1164                         newlist = strcat(newlist, " ", argv(j));
1165                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1166                 cvar_set("g_maplist", newlist);
1167                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1168
1169                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1170                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1171                 if(Map_Check(Map_Current, 1))
1172                         return Map_Current;
1173         }
1174         return -1;
1175 }
1176
1177 void Maplist_Init()
1178 {
1179         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1180         if(Map_Count == 0)
1181         {
1182                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1183                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1184                 if(autocvar_g_maplist_shuffle)
1185                         ShuffleMaplist();
1186                 localcmd("\nmenu_cmd sync\n");
1187                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1188         }
1189         if(Map_Count == 0)
1190                 error("empty maplist, cannot select a new map");
1191         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1192
1193         if(Map_Current_Name)
1194                 strunzone(Map_Current_Name);
1195         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1196         // this may or may not be correct, but who cares, in the worst case a map
1197         // isn't chosen in the first pass that should have been
1198 }
1199
1200 string GetNextMap()
1201 {
1202         float nextMap;
1203
1204         Maplist_Init();
1205         nextMap = -1;
1206
1207         if(nextMap == -1)
1208                 if(autocvar_g_maplist_shuffle > 0)
1209                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1210
1211         if(nextMap == -1)
1212                 if(autocvar_g_maplist_selectrandom)
1213                         nextMap = MaplistMethod_Random();
1214
1215         if(nextMap == -1)
1216                 nextMap = MaplistMethod_Iterate();
1217
1218         if(nextMap == -1)
1219                 nextMap = MaplistMethod_Repeat();
1220
1221         if(nextMap >= 0)
1222         {
1223                 Map_Goto_SetFloat(nextMap);
1224                 return getmapname_stored;
1225         }
1226
1227         return "";
1228 }
1229
1230 float DoNextMapOverride(float reinit)
1231 {
1232         if(autocvar_g_campaign)
1233         {
1234                 CampaignPostIntermission();
1235                 alreadychangedlevel = TRUE;
1236                 return TRUE;
1237         }
1238         if(autocvar_quit_when_empty)
1239         {
1240                 if(player_count <= currentbots)
1241                 {
1242                         localcmd("quit\n");
1243                         alreadychangedlevel = TRUE;
1244                         return TRUE;
1245                 }
1246         }
1247         if(autocvar_quit_and_redirect != "")
1248         {
1249                 redirection_target = strzone(autocvar_quit_and_redirect);
1250                 alreadychangedlevel = TRUE;
1251                 return TRUE;
1252         }
1253         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1254         {
1255                 localcmd("restart\n");
1256                 alreadychangedlevel = TRUE;
1257                 return TRUE;
1258         }
1259         if(autocvar_nextmap != "")
1260                 if(MapInfo_CheckMap(autocvar_nextmap))
1261                 {
1262                         Map_Goto_SetStr(autocvar_nextmap);
1263                         Map_Goto(reinit);
1264                         alreadychangedlevel = TRUE;
1265                         return TRUE;
1266                 }
1267         if(!reinit && autocvar_lastlevel)
1268         {
1269                 cvar_settemp_restore();
1270                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1271                 alreadychangedlevel = TRUE;
1272                 return TRUE;
1273         }
1274         return FALSE;
1275 }
1276
1277 void GotoNextMap(float reinit)
1278 {
1279         //string nextmap;
1280         //float n, nummaps;
1281         //string s;
1282         if (alreadychangedlevel)
1283                 return;
1284         alreadychangedlevel = TRUE;
1285
1286         {
1287                 string nextMap;
1288                 float allowReset;
1289
1290                 for(allowReset = 1; allowReset >= 0; --allowReset)
1291                 {
1292                         nextMap = GetNextMap();
1293                         if(nextMap != "")
1294                                 break;
1295
1296                         if(allowReset)
1297                         {
1298                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1299                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1300                                 if(autocvar_g_maplist_shuffle)
1301                                         ShuffleMaplist();
1302                                 localcmd("\nmenu_cmd sync\n");
1303                         }
1304                         else
1305                         {
1306                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1307                         }
1308                 }
1309                 Map_Goto(reinit);
1310         }
1311 }
1312
1313
1314 /*
1315 ============
1316 IntermissionThink
1317
1318 When the player presses attack or jump, change to the next level
1319 ============
1320 */
1321 .float autoscreenshot;
1322 void() MapVote_Start;
1323 void() MapVote_Think;
1324 float mapvote_initialized;
1325 void IntermissionThink()
1326 {
1327         FixIntermissionClient(self);
1328
1329         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1330         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1331
1332         if( (server_screenshot || client_screenshot)
1333                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1334         {
1335                 self.autoscreenshot = -1;
1336                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1337                 return;
1338         }
1339
1340         if (time < intermission_exittime)
1341                 return;
1342
1343         if(!mapvote_initialized)
1344                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1345                         return;
1346
1347         MapVote_Start();
1348 }
1349
1350 /*
1351 ============
1352 FindIntermission
1353
1354 Returns the entity to view from
1355 ============
1356 */
1357 /*
1358 entity FindIntermission()
1359 {
1360         local   entity spot;
1361         local   float cyc;
1362
1363 // look for info_intermission first
1364         spot = find (world, classname, "info_intermission");
1365         if (spot)
1366         {       // pick a random one
1367                 cyc = random() * 4;
1368                 while (cyc > 1)
1369                 {
1370                         spot = find (spot, classname, "info_intermission");
1371                         if (!spot)
1372                                 spot = find (spot, classname, "info_intermission");
1373                         cyc = cyc - 1;
1374                 }
1375                 return spot;
1376         }
1377
1378 // then look for the start position
1379         spot = find (world, classname, "info_player_start");
1380         if (spot)
1381                 return spot;
1382
1383 // testinfo_player_start is only found in regioned levels
1384         spot = find (world, classname, "testplayerstart");
1385         if (spot)
1386                 return spot;
1387
1388 // then look for the start position
1389         spot = find (world, classname, "info_player_deathmatch");
1390         if (spot)
1391                 return spot;
1392
1393         //objerror ("FindIntermission: no spot");
1394         return world;
1395 }
1396 */
1397
1398 /*
1399 ===============================================================================
1400
1401 RULES
1402
1403 ===============================================================================
1404 */
1405
1406 void DumpStats(float final)
1407 {
1408         float file;
1409         string s;
1410         float to_console;
1411         float to_eventlog;
1412         float to_file;
1413         float i;
1414
1415         to_console = autocvar_sv_logscores_console;
1416         to_eventlog = autocvar_sv_eventlog;
1417         to_file = autocvar_sv_logscores_file;
1418
1419         if(!final)
1420         {
1421                 to_console = TRUE; // always print printstats replies
1422                 to_eventlog = FALSE; // but never print them to the event log
1423         }
1424
1425         if(to_eventlog)
1426                 if(autocvar_sv_eventlog_console)
1427                         to_console = FALSE; // otherwise we get the output twice
1428
1429         if(final)
1430                 s = ":scores:";
1431         else
1432                 s = ":status:";
1433         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1434
1435         if(to_console)
1436                 print(s, "\n");
1437         if(to_eventlog)
1438                 GameLogEcho(s);
1439
1440         file = -1;
1441         if(to_file)
1442         {
1443                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1444                 if(file == -1)
1445                         to_file = FALSE;
1446                 else
1447                         fputs(file, strcat(s, "\n"));
1448         }
1449
1450         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1451         if(to_console)
1452                 print(s, "\n");
1453         if(to_eventlog)
1454                 GameLogEcho(s);
1455         if(to_file)
1456                 fputs(file, strcat(s, "\n"));
1457
1458         FOR_EACH_CLIENT(other)
1459         {
1460                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1461                 {
1462                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1463                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1464                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1465                                 s = strcat(s, ftos(other.team), ":");
1466                         else
1467                                 s = strcat(s, "spectator:");
1468
1469                         if(to_console)
1470                                 print(s, other.netname, "\n");
1471                         if(to_eventlog)
1472                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1473                         if(to_file)
1474                                 fputs(file, strcat(s, other.netname, "\n"));
1475                 }
1476         }
1477
1478         if(teamplay)
1479         {
1480                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1481                 if(to_console)
1482                         print(s, "\n");
1483                 if(to_eventlog)
1484                         GameLogEcho(s);
1485                 if(to_file)
1486                         fputs(file, strcat(s, "\n"));
1487
1488                 for(i = 1; i < 16; ++i)
1489                 {
1490                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1491                         s = strcat(s, ":", ftos(i));
1492                         if(to_console)
1493                                 print(s, "\n");
1494                         if(to_eventlog)
1495                                 GameLogEcho(s);
1496                         if(to_file)
1497                                 fputs(file, strcat(s, "\n"));
1498                 }
1499         }
1500
1501         if(to_console)
1502                 print(":end\n");
1503         if(to_eventlog)
1504                 GameLogEcho(":end");
1505         if(to_file)
1506         {
1507                 fputs(file, ":end\n");
1508                 fclose(file);
1509         }
1510 }
1511
1512 void FixIntermissionClient(entity e)
1513 {
1514         string s;
1515         if(!e.autoscreenshot) // initial call
1516         {
1517                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1518                 e.health = -2342;
1519                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1520                 e.solid = SOLID_NOT;
1521                 e.movetype = MOVETYPE_NONE;
1522                 e.takedamage = DAMAGE_NO;
1523                 if(e.weaponentity)
1524                 {
1525                         e.weaponentity.effects = EF_NODRAW;
1526                         if (e.weaponentity.weaponentity)
1527                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1528                 }
1529                 if(IS_REAL_CLIENT(e))
1530                 {
1531                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1532                         s = autocvar_sv_intermission_cdtrack;
1533                         if(s != "")
1534                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1535                         msg_entity = e;
1536                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1537                 }
1538         }
1539 }
1540
1541 /*
1542 go to the next level for deathmatch
1543 only called if a time or frag limit has expired
1544 */
1545 void NextLevel()
1546 {
1547         gameover = TRUE;
1548
1549         intermission_running = 1;
1550
1551 // enforce a wait time before allowing changelevel
1552         if(player_count > 0)
1553                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1554         else
1555                 intermission_exittime = -1;
1556
1557         /*
1558         WriteByte (MSG_ALL, SVC_CDTRACK);
1559         WriteByte (MSG_ALL, 3);
1560         WriteByte (MSG_ALL, 3);
1561         // done in FixIntermission
1562         */
1563
1564         //pos = FindIntermission ();
1565
1566         VoteReset();
1567
1568         DumpStats(TRUE);
1569
1570         // send statistics
1571         entity e;
1572         PlayerStats_EndMatch(1);
1573         FOR_EACH_CLIENT(e)
1574                 PlayerStats_AddGlobalInfo(e);
1575         PlayerStats_Shutdown();
1576         WeaponStats_Shutdown();
1577
1578         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1579
1580         if(autocvar_sv_eventlog)
1581                 GameLogEcho(":gameover");
1582
1583         GameLogClose();
1584
1585         FOR_EACH_PLAYER(other) {
1586                 FixIntermissionClient(other);
1587                 if(other.winning)
1588                         bprint(other.netname, " ^7wins.\n");
1589         }
1590
1591         if(autocvar_g_campaign)
1592                 CampaignPreIntermission();
1593
1594         MUTATOR_CALLHOOK(MatchEnd);
1595
1596         localcmd("\nsv_hook_gameend\n");
1597 }
1598
1599 /*
1600 ============
1601 CheckRules_Player
1602
1603 Exit deathmatch games upon conditions
1604 ============
1605 */
1606 void CheckRules_Player()
1607 {
1608         if (gameover)   // someone else quit the game already
1609                 return;
1610
1611         if(self.deadflag == DEAD_NO)
1612                 self.play_time += frametime;
1613
1614         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1615         //   (div0: and that in CheckRules_World please)
1616 }
1617
1618 float checkrules_equality;
1619 float checkrules_suddendeathwarning;
1620 float checkrules_suddendeathend;
1621 float checkrules_overtimesadded; //how many overtimes have been already added
1622
1623 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1624 float WINNING_YES = 1; // winner found
1625 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1626 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1627
1628 float InitiateSuddenDeath()
1629 {
1630         // Check first whether normal overtimes could be added before initiating suddendeath mode
1631         // - for this timelimit_overtime needs to be >0 of course
1632         // - also check the winning condition calculated in the previous frame and only add normal overtime
1633         //   again, if at the point at which timelimit would be extended again, still no winner was found
1634         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1635         {
1636                 return 1; // need to call InitiateOvertime later
1637         }
1638         else
1639         {
1640                 if(!checkrules_suddendeathend)
1641                 {
1642                         if(autocvar_g_campaign)
1643                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1644                         else
1645                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1646                         if(g_race && !g_race_qualifying)
1647                                 race_StartCompleting();
1648                 }
1649                 return 0;
1650         }
1651 }
1652
1653 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1654 {
1655         ++checkrules_overtimesadded;
1656         //add one more overtime by simply extending the timelimit
1657         float tl;
1658         tl = autocvar_timelimit;
1659         tl += autocvar_timelimit_overtime;
1660         cvar_set("timelimit", ftos(tl));
1661
1662         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1663 }
1664
1665 float GetWinningCode(float fraglimitreached, float equality)
1666 {
1667         if(autocvar_g_campaign == 1)
1668                 if(fraglimitreached)
1669                         return WINNING_YES;
1670                 else
1671                         return WINNING_NO;
1672
1673         else
1674                 if(equality)
1675                         if(fraglimitreached)
1676                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1677                         else
1678                                 return WINNING_NEVER;
1679                 else
1680                         if(fraglimitreached)
1681                                 return WINNING_YES;
1682                         else
1683                                 return WINNING_NO;
1684 }
1685
1686 // set the .winning flag for exactly those players with a given field value
1687 void SetWinners(.float field, float value)
1688 {
1689         entity head;
1690         FOR_EACH_PLAYER(head)
1691                 head.winning = (head.field == value);
1692 }
1693
1694 // set the .winning flag for those players with a given field value
1695 void AddWinners(.float field, float value)
1696 {
1697         entity head;
1698         FOR_EACH_PLAYER(head)
1699                 if(head.field == value)
1700                         head.winning = 1;
1701 }
1702
1703 // clear the .winning flags
1704 void ClearWinners(void)
1705 {
1706         entity head;
1707         FOR_EACH_PLAYER(head)
1708                 head.winning = 0;
1709 }
1710
1711 // Onslaught winning condition:
1712 // game terminates if only one team has a working generator (or none)
1713 float WinningCondition_Onslaught()
1714 {
1715         entity head;
1716         float t1, t2, t3, t4;
1717
1718         WinningConditionHelper(); // set worldstatus
1719
1720         if(inWarmupStage)
1721                 return WINNING_NO;
1722
1723         // first check if the game has ended
1724         t1 = t2 = t3 = t4 = 0;
1725         head = find(world, classname, "onslaught_generator");
1726         while (head)
1727         {
1728                 if (head.health > 0)
1729                 {
1730                         if (head.team == NUM_TEAM_1) t1 = 1;
1731                         if (head.team == NUM_TEAM_2) t2 = 1;
1732                         if (head.team == NUM_TEAM_3) t3 = 1;
1733                         if (head.team == NUM_TEAM_4) t4 = 1;
1734                 }
1735                 head = find(head, classname, "onslaught_generator");
1736         }
1737         if (t1 + t2 + t3 + t4 < 2)
1738         {
1739                 // game over, only one team remains (or none)
1740                 ClearWinners();
1741                 if (t1) SetWinners(team, NUM_TEAM_1);
1742                 if (t2) SetWinners(team, NUM_TEAM_2);
1743                 if (t3) SetWinners(team, NUM_TEAM_3);
1744                 if (t4) SetWinners(team, NUM_TEAM_4);
1745                 dprint("Have a winner, ending game.\n");
1746                 return WINNING_YES;
1747         }
1748
1749         // Two or more teams remain
1750         return WINNING_NO;
1751 }
1752
1753 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1754 // they win. Otherwise the defending team wins once the timelimit passes.
1755 void assault_new_round();
1756 float WinningCondition_Assault()
1757 {
1758         float status;
1759
1760         WinningConditionHelper(); // set worldstatus
1761
1762         status = WINNING_NO;
1763         // as the timelimit has not yet passed just assume the defending team will win
1764         if(assault_attacker_team == NUM_TEAM_1)
1765         {
1766                 SetWinners(team, NUM_TEAM_2);
1767         }
1768         else
1769         {
1770                 SetWinners(team, NUM_TEAM_1);
1771         }
1772
1773         entity ent;
1774         ent = find(world, classname, "target_assault_roundend");
1775         if(ent)
1776         {
1777                 if(ent.winning) // round end has been triggered by attacking team
1778                 {
1779                         bprint("ASSAULT: round completed...\n");
1780                         SetWinners(team, assault_attacker_team);
1781
1782                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1783
1784                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1785                         {
1786                                 status = WINNING_YES;
1787                         }
1788                         else
1789                         {
1790                                 entity oldself;
1791                                 oldself = self;
1792                                 self = ent;
1793                                 assault_new_round();
1794                                 self = oldself;
1795                         }
1796                 }
1797         }
1798
1799         return status;
1800 }
1801
1802 // LMS winning condition: game terminates if and only if there's at most one
1803 // one player who's living lives. Top two scores being equal cancels the time
1804 // limit.
1805 float WinningCondition_LMS()
1806 {
1807         entity head, head2;
1808         float have_player;
1809         float have_players;
1810         float l;
1811
1812         have_player = FALSE;
1813         have_players = FALSE;
1814         l = LMS_NewPlayerLives();
1815
1816         head = find(world, classname, "player");
1817         if(head)
1818                 have_player = TRUE;
1819         head2 = find(head, classname, "player");
1820         if(head2)
1821                 have_players = TRUE;
1822
1823         if(have_player)
1824         {
1825                 // we have at least one player
1826                 if(have_players)
1827                 {
1828                         // two or more active players - continue with the game
1829                 }
1830                 else
1831                 {
1832                         // exactly one player?
1833
1834                         ClearWinners();
1835                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1836
1837                         if(l)
1838                         {
1839                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1840                                 return WINNING_NO;
1841                         }
1842                         else
1843                         {
1844                                 // a winner!
1845                                 // and assign him his first place
1846                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1847                                 return WINNING_YES;
1848                         }
1849                 }
1850         }
1851         else
1852         {
1853                 // nobody is playing at all...
1854                 if(l)
1855                 {
1856                         // wait for players...
1857                 }
1858                 else
1859                 {
1860                         // SNAFU (maybe a draw game?)
1861                         ClearWinners();
1862                         dprint("No players, ending game.\n");
1863                         return WINNING_YES;
1864                 }
1865         }
1866
1867         // When we get here, we have at least two players who are actually LIVING,
1868         // now check if the top two players have equal score.
1869         WinningConditionHelper();
1870
1871         ClearWinners();
1872         if(WinningConditionHelper_winner)
1873                 WinningConditionHelper_winner.winning = TRUE;
1874         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1875                 return WINNING_NEVER;
1876
1877         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1878         return WINNING_NO;
1879 }
1880
1881 void ShuffleMaplist()
1882 {
1883         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1884 }
1885
1886 float leaderfrags;
1887 float WinningCondition_Scores(float limit, float leadlimit)
1888 {
1889         float limitreached;
1890
1891         // TODO make everything use THIS winning condition (except LMS)
1892         WinningConditionHelper();
1893
1894         if(teamplay)
1895         {
1896                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1897                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1898                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1899                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1900         }
1901
1902         ClearWinners();
1903         if(WinningConditionHelper_winner)
1904                 WinningConditionHelper_winner.winning = 1;
1905         if(WinningConditionHelper_winnerteam >= 0)
1906                 SetWinners(team, WinningConditionHelper_winnerteam);
1907
1908         if(WinningConditionHelper_lowerisbetter)
1909         {
1910                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1911                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1912                 limit = -limit;
1913         }
1914
1915         if(WinningConditionHelper_zeroisworst)
1916                 leadlimit = 0; // not supported in this mode
1917
1918         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1919         // these modes always score in increments of 1, thus this makes sense
1920         {
1921                 if(leaderfrags != WinningConditionHelper_topscore)
1922                 {
1923                         leaderfrags = WinningConditionHelper_topscore;
1924
1925                         if (limit)
1926                         if (leaderfrags == limit - 1)
1927                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1928                         else if (leaderfrags == limit - 2)
1929                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1930                         else if (leaderfrags == limit - 3)
1931                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1932                 }
1933         }
1934
1935         limitreached = FALSE;
1936         if(limit)
1937                 if(WinningConditionHelper_topscore >= limit)
1938                         limitreached = TRUE;
1939         if(leadlimit)
1940         {
1941                 float leadlimitreached;
1942                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1943                 if(autocvar_leadlimit_and_fraglimit)
1944                         limitreached = (limitreached && leadlimitreached);
1945                 else
1946                         limitreached = (limitreached || leadlimitreached);
1947         }
1948
1949         if(limit)
1950                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1951
1952         return GetWinningCode(
1953                 WinningConditionHelper_topscore && limitreached,
1954                 WinningConditionHelper_equality
1955         );
1956 }
1957
1958 float WinningCondition_Race(float fraglimit)
1959 {
1960         float wc;
1961         entity p;
1962         float n, c;
1963
1964         n = 0;
1965         c = 0;
1966         FOR_EACH_PLAYER(p)
1967         {
1968                 ++n;
1969                 if(p.race_completed)
1970                         ++c;
1971         }
1972         if(n && (n == c))
1973                 return WINNING_YES;
1974         wc = WinningCondition_Scores(fraglimit, 0);
1975
1976         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1977         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1978         // do NOT support equality when the laps are all raced!
1979                 return WINNING_STARTSUDDENDEATHOVERTIME;
1980         else
1981                 return WINNING_NEVER;
1982 }
1983
1984 float WinningCondition_QualifyingThenRace(float limit)
1985 {
1986         float wc;
1987         wc = WinningCondition_Scores(limit, 0);
1988
1989         // NEVER initiate overtime
1990         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1991         {
1992                 return WINNING_YES;
1993         }
1994
1995         return wc;
1996 }
1997
1998 float WinningCondition_RanOutOfSpawns()
1999 {
2000         entity head;
2001
2002         if(have_team_spawns <= 0)
2003                 return WINNING_NO;
2004
2005         if(autocvar_g_spawn_useallspawns <= 0)
2006                 return WINNING_NO;
2007
2008         if(!some_spawn_has_been_used)
2009                 return WINNING_NO;
2010
2011         team1_score = team2_score = team3_score = team4_score = 0;
2012
2013         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2014         {
2015                 if(head.team == NUM_TEAM_1)
2016                         team1_score = 1;
2017                 else if(head.team == NUM_TEAM_2)
2018                         team2_score = 1;
2019                 else if(head.team == NUM_TEAM_3)
2020                         team3_score = 1;
2021                 else if(head.team == NUM_TEAM_4)
2022                         team4_score = 1;
2023         }
2024
2025         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2026         {
2027                 if(head.team == NUM_TEAM_1)
2028                         team1_score = 1;
2029                 else if(head.team == NUM_TEAM_2)
2030                         team2_score = 1;
2031                 else if(head.team == NUM_TEAM_3)
2032                         team3_score = 1;
2033                 else if(head.team == NUM_TEAM_4)
2034                         team4_score = 1;
2035         }
2036
2037         ClearWinners();
2038         if(team1_score + team2_score + team3_score + team4_score == 0)
2039         {
2040                 checkrules_equality = TRUE;
2041                 return WINNING_YES;
2042         }
2043         else if(team1_score + team2_score + team3_score + team4_score == 1)
2044         {
2045                 float t, i;
2046                 if(team1_score)
2047                         t = NUM_TEAM_1;
2048                 else if(team2_score)
2049                         t = NUM_TEAM_2;
2050                 else if(team3_score)
2051                         t = NUM_TEAM_3;
2052                 else // if(team4_score)
2053                         t = NUM_TEAM_4;
2054                 CheckAllowedTeams(world);
2055                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2056                 {
2057                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2058                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2059                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2060                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2061                 }
2062
2063                 AddWinners(team, t);
2064                 return WINNING_YES;
2065         }
2066         else
2067                 return WINNING_NO;
2068 }
2069
2070 /*
2071 ============
2072 CheckRules_World
2073
2074 Exit deathmatch games upon conditions
2075 ============
2076 */
2077 void ReadyRestart();
2078 void CheckRules_World()
2079 {
2080         float timelimit;
2081         float fraglimit;
2082         float leadlimit;
2083
2084         VoteThink();
2085         MapVote_Think();
2086
2087         SetDefaultAlpha();
2088
2089         /*
2090         MapVote_Think should now do that part
2091         if (intermission_running)
2092                 if (time >= intermission_exittime + 60)
2093                 {
2094                         if(!DoNextMapOverride())
2095                                 GotoNextMap();
2096                         return;
2097                 }
2098         */
2099
2100         if (gameover)   // someone else quit the game already
2101         {
2102                 if(player_count == 0) // Nobody there? Then let's go to the next map
2103                         MapVote_Start();
2104                         // this will actually check the player count in the next frame
2105                         // again, but this shouldn't hurt
2106                 return;
2107         }
2108
2109         timelimit = autocvar_timelimit * 60;
2110         fraglimit = autocvar_fraglimit;
2111         leadlimit = autocvar_leadlimit;
2112
2113         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2114         {
2115                 if(timelimit > 0)
2116                         timelimit = 0; // timelimit is not made for warmup
2117                 if(fraglimit > 0)
2118                         fraglimit = 0; // no fraglimit for now
2119                 leadlimit = 0; // no leadlimit for now
2120         }
2121
2122         if(timelimit > 0)
2123         {
2124                 timelimit += game_starttime;
2125         }
2126         else if (timelimit < 0)
2127         {
2128                 // endmatch
2129                 NextLevel();
2130                 return;
2131         }
2132
2133         if(g_onslaught)
2134                 timelimit = 0; // ONS has its own overtime rule
2135
2136         float wantovertime;
2137         wantovertime = 0;
2138
2139         if(timelimit > game_starttime)
2140                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2141         else
2142                 game_completion_ratio = 0;
2143
2144         if(checkrules_suddendeathend)
2145         {
2146                 if(!checkrules_suddendeathwarning)
2147                 {
2148                         checkrules_suddendeathwarning = TRUE;
2149                         if(g_race && !g_race_qualifying)
2150                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2151                         else
2152                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2153                 }
2154         }
2155         else
2156         {
2157                 if (timelimit && time >= timelimit)
2158                 {
2159                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2160                         {
2161                                 float totalplayers;
2162                                 float playerswithlaps;
2163                                 float readyplayers;
2164                                 entity head;
2165                                 totalplayers = playerswithlaps = readyplayers = 0;
2166                                 FOR_EACH_PLAYER(head)
2167                                 {
2168                                         ++totalplayers;
2169                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2170                                                 ++playerswithlaps;
2171                                         if(head.ready)
2172                                                 ++readyplayers;
2173                                 }
2174
2175                                 // at least 2 of the players have completed a lap: start the RACE
2176                                 // otherwise, the players should end the qualifying on their own
2177                                 if(readyplayers || playerswithlaps >= 2)
2178                                 {
2179                                         checkrules_suddendeathend = 0;
2180                                         ReadyRestart(); // go to race
2181                                         return;
2182                                 }
2183                                 else
2184                                         wantovertime |= InitiateSuddenDeath();
2185                         }
2186                         else
2187                                 wantovertime |= InitiateSuddenDeath();
2188                 }
2189         }
2190
2191         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2192         {
2193                 NextLevel();
2194                 return;
2195         }
2196
2197         float checkrules_status;
2198         checkrules_status = WinningCondition_RanOutOfSpawns();
2199         if(checkrules_status == WINNING_YES)
2200         {
2201                 bprint("Hey! Someone ran out of spawns!\n");
2202         }
2203         else if(g_race && !g_race_qualifying && timelimit >= 0)
2204         {
2205                 checkrules_status = WinningCondition_Race(fraglimit);
2206                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2207         }
2208         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2209         {
2210                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2211                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2212         }
2213         else if(g_assault)
2214         {
2215                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2216         }
2217         else if(g_lms)
2218         {
2219                 checkrules_status = WinningCondition_LMS();
2220         }
2221         else if (g_onslaught)
2222         {
2223                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2224         }
2225         else
2226         {
2227                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2228                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2229         }
2230
2231         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2232         {
2233                 checkrules_status = WINNING_NEVER;
2234                 checkrules_overtimesadded = -1;
2235                 wantovertime |= InitiateSuddenDeath();
2236         }
2237
2238         if(checkrules_status == WINNING_NEVER)
2239                 // equality cases! Nobody wins if the overtime ends in a draw.
2240                 ClearWinners();
2241
2242         if(wantovertime)
2243         {
2244                 if(checkrules_status == WINNING_NEVER)
2245                         InitiateOvertime();
2246                 else
2247                         checkrules_status = WINNING_YES;
2248         }
2249
2250         if(checkrules_suddendeathend)
2251                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2252                         checkrules_status = WINNING_YES;
2253
2254         if(checkrules_status == WINNING_YES)
2255         {
2256                 //print("WINNING\n");
2257                 NextLevel();
2258         }
2259 }
2260
2261 float mapvote_nextthink;
2262 float mapvote_initialized;
2263 float mapvote_keeptwotime;
2264 float mapvote_timeout;
2265 string mapvote_message;
2266 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2267 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2268 float mapvote_screenshot_dirs_count;
2269
2270 float mapvote_count;
2271 float mapvote_count_real;
2272 string mapvote_maps[MAPVOTE_COUNT];
2273 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2274 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2275 float mapvote_maps_suggested[MAPVOTE_COUNT];
2276 string mapvote_suggestions[MAPVOTE_COUNT];
2277 float mapvote_suggestion_ptr;
2278 float mapvote_voters;
2279 float mapvote_selections[MAPVOTE_COUNT];
2280 float mapvote_run;
2281 float mapvote_detail;
2282 float mapvote_abstain;
2283 .float mapvote;
2284
2285 void MapVote_ClearAllVotes()
2286 {
2287         FOR_EACH_CLIENT(other)
2288                 other.mapvote = 0;
2289 }
2290
2291 string MapVote_Suggest(string m)
2292 {
2293         float i;
2294         if(m == "")
2295                 return "That's not how to use this command.";
2296         if(!autocvar_g_maplist_votable_suggestions)
2297                 return "Suggestions are not accepted on this server.";
2298         if(mapvote_initialized)
2299                 return "Can't suggest - voting is already in progress!";
2300         m = MapInfo_FixName(m);
2301         if not(m)
2302                 return "The map you suggested is not available on this server.";
2303         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2304                 if(Map_IsRecent(m))
2305                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2306
2307         if(!MapInfo_CheckMap(m))
2308                 return "The map you suggested does not support the current game mode.";
2309         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2310                 if(mapvote_suggestions[i] == m)
2311                         return "This map was already suggested.";
2312         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2313         {
2314                 i = floor(random() * mapvote_suggestion_ptr);
2315         }
2316         else
2317         {
2318                 i = mapvote_suggestion_ptr;
2319                 mapvote_suggestion_ptr += 1;
2320         }
2321         if(mapvote_suggestions[i] != "")
2322                 strunzone(mapvote_suggestions[i]);
2323         mapvote_suggestions[i] = strzone(m);
2324         if(autocvar_sv_eventlog)
2325                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2326         return strcat("Suggestion of ", m, " accepted.");
2327 }
2328
2329 void MapVote_AddVotable(string nextMap, float isSuggestion)
2330 {
2331         float j, i, o;
2332         string pakfile, mapfile;
2333
2334         if(nextMap == "")
2335                 return;
2336         for(j = 0; j < mapvote_count; ++j)
2337                 if(mapvote_maps[j] == nextMap)
2338                         return;
2339         // suggestions might be no longer valid/allowed after gametype switch!
2340         if(isSuggestion)
2341                 if(!MapInfo_CheckMap(nextMap))
2342                         return;
2343         mapvote_maps[mapvote_count] = strzone(nextMap);
2344         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2345
2346         pakfile = string_null;
2347         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2348         {
2349                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2350                 pakfile = whichpack(strcat(mapfile, ".tga"));
2351                 if(pakfile == "")
2352                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2353                 if(pakfile == "")
2354                         pakfile = whichpack(strcat(mapfile, ".png"));
2355                 if(pakfile != "")
2356                         break;
2357         }
2358         if(i >= mapvote_screenshot_dirs_count)
2359                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2360         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2361                 pakfile = substring(pakfile, o, -1);
2362
2363         mapvote_maps_screenshot_dir[mapvote_count] = i;
2364         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2365
2366         mapvote_count += 1;
2367 }
2368
2369 void MapVote_Spawn();
2370 void MapVote_Init()
2371 {
2372         float i;
2373         float nmax, smax;
2374
2375         MapVote_ClearAllVotes();
2376
2377         mapvote_count = 0;
2378         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2379         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2380
2381         if(mapvote_abstain)
2382                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2383         else
2384                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2385         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2386
2387         // we need this for AddVotable, as that cycles through the screenshot dirs
2388         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2389         if(mapvote_screenshot_dirs_count == 0)
2390                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2391         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2392         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2393                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2394
2395         if(mapvote_suggestion_ptr)
2396                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2397                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2398
2399         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2400                 MapVote_AddVotable(GetNextMap(), FALSE);
2401
2402         if(mapvote_count == 0)
2403         {
2404                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2405                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2406                 if(autocvar_g_maplist_shuffle)
2407                         ShuffleMaplist();
2408                 localcmd("\nmenu_cmd sync\n");
2409                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2410                         MapVote_AddVotable(GetNextMap(), FALSE);
2411         }
2412
2413         mapvote_count_real = mapvote_count;
2414         if(mapvote_abstain)
2415                 MapVote_AddVotable("don't care", 0);
2416
2417         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2418
2419         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2420         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2421         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2422                 mapvote_keeptwotime = 0;
2423         mapvote_message = "Choose a map and press its key!";
2424
2425         MapVote_Spawn();
2426 }
2427
2428 void MapVote_SendPicture(float id)
2429 {
2430         msg_entity = self;
2431         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2432         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2433         WriteByte(MSG_ONE, id);
2434         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2435 }
2436
2437 float MapVote_GetMapMask()
2438 {
2439         float mask, i, power;
2440         mask = 0;
2441         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2442                 if(mapvote_maps[i] != "")
2443                         mask |= power;
2444         return mask;
2445 }
2446
2447 entity mapvote_ent;
2448 float MapVote_SendEntity(entity to, float sf)
2449 {
2450         float i;
2451
2452         if(sf & 1)
2453                 sf &~= 2; // if we send 1, we don't need to also send 2
2454
2455         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2456         WriteByte(MSG_ENTITY, sf);
2457
2458         if(sf & 1)
2459         {
2460                 // flag 1 == initialization
2461                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2462                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2463                 WriteString(MSG_ENTITY, "");
2464                 WriteByte(MSG_ENTITY, mapvote_count);
2465                 WriteByte(MSG_ENTITY, mapvote_abstain);
2466                 WriteByte(MSG_ENTITY, mapvote_detail);
2467                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2468                 if(mapvote_count <= 8)
2469                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2470                 else
2471                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2472                 for(i = 0; i < mapvote_count; ++i)
2473                         if(mapvote_maps[i] != "")
2474                         {
2475                                 if(mapvote_abstain && i == mapvote_count - 1)
2476                                 {
2477                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2478                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2479                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2480                                 }
2481                                 else
2482                                 {
2483                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2484                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2485                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2486                                 }
2487                         }
2488         }
2489
2490         if(sf & 2)
2491         {
2492                 // flag 2 == update of mask
2493                 if(mapvote_count <= 8)
2494                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2495                 else
2496                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2497         }
2498
2499         if(sf & 4)
2500         {
2501                 if(mapvote_detail)
2502                         for(i = 0; i < mapvote_count; ++i)
2503                                 if(mapvote_maps[i] != "")
2504                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2505
2506                 WriteByte(MSG_ENTITY, to.mapvote);
2507         }
2508
2509         return TRUE;
2510 }
2511
2512 void MapVote_Spawn()
2513 {
2514         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2515 }
2516
2517 void MapVote_TouchMask()
2518 {
2519         mapvote_ent.SendFlags |= 2;
2520 }
2521
2522 void MapVote_TouchVotes(entity voter)
2523 {
2524         mapvote_ent.SendFlags |= 4;
2525 }
2526
2527 float MapVote_Finished(float mappos)
2528 {
2529         string result;
2530         float i;
2531         float didntvote;
2532
2533         if(autocvar_sv_eventlog)
2534         {
2535                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2536                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2537                 didntvote = mapvote_voters;
2538                 for(i = 0; i < mapvote_count; ++i)
2539                         if(mapvote_maps[i] != "")
2540                         {
2541                                 didntvote -= mapvote_selections[i];
2542                                 if(i != mappos)
2543                                 {
2544                                         result = strcat(result, ":", mapvote_maps[i]);
2545                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2546                                 }
2547                         }
2548                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2549
2550                 GameLogEcho(result);
2551                 if(mapvote_maps_suggested[mappos])
2552                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2553         }
2554
2555         FOR_EACH_REALCLIENT(other)
2556                 FixClientCvars(other);
2557
2558         Map_Goto_SetStr(mapvote_maps[mappos]);
2559         Map_Goto(0);
2560         alreadychangedlevel = TRUE;
2561         return TRUE;
2562 }
2563 void MapVote_CheckRules_1()
2564 {
2565         float i;
2566
2567         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2568         {
2569                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2570                 mapvote_selections[i] = 0;
2571         }
2572
2573         mapvote_voters = 0;
2574         FOR_EACH_REALCLIENT(other)
2575         {
2576                 ++mapvote_voters;
2577                 if(other.mapvote)
2578                 {
2579                         i = other.mapvote - 1;
2580                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2581                         mapvote_selections[i] = mapvote_selections[i] + 1;
2582                 }
2583         }
2584 }
2585
2586 float MapVote_CheckRules_2()
2587 {
2588         float i;
2589         float firstPlace, secondPlace;
2590         float firstPlaceVotes, secondPlaceVotes;
2591         float mapvote_voters_real;
2592         string result;
2593
2594         if(mapvote_count_real == 1)
2595                 return MapVote_Finished(0);
2596
2597         mapvote_voters_real = mapvote_voters;
2598         if(mapvote_abstain)
2599                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2600
2601         RandomSelection_Init();
2602         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2603                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2604         firstPlace = RandomSelection_chosen_float;
2605         firstPlaceVotes = RandomSelection_best_priority;
2606         //dprint("First place: ", ftos(firstPlace), "\n");
2607         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2608
2609         RandomSelection_Init();
2610         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2611                 if(i != firstPlace)
2612                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2613         secondPlace = RandomSelection_chosen_float;
2614         secondPlaceVotes = RandomSelection_best_priority;
2615         //dprint("Second place: ", ftos(secondPlace), "\n");
2616         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2617
2618         if(firstPlace == -1)
2619                 error("No first place in map vote... WTF?");
2620
2621         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2622                 return MapVote_Finished(firstPlace);
2623
2624         if(mapvote_keeptwotime)
2625                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2626                 {
2627                         float didntvote;
2628                         MapVote_TouchMask();
2629                         mapvote_message = "Now decide between the TOP TWO!";
2630                         mapvote_keeptwotime = 0;
2631                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2632                         result = strcat(result, ":", ftos(firstPlaceVotes));
2633                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2634                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2635                         didntvote = mapvote_voters;
2636                         for(i = 0; i < mapvote_count; ++i)
2637                                 if(mapvote_maps[i] != "")
2638                                 {
2639                                         didntvote -= mapvote_selections[i];
2640                                         if(i != firstPlace)
2641                                                 if(i != secondPlace)
2642                                                 {
2643                                                         result = strcat(result, ":", mapvote_maps[i]);
2644                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2645                                                         if(i < mapvote_count_real)
2646                                                         {
2647                                                                 strunzone(mapvote_maps[i]);
2648                                                                 mapvote_maps[i] = "";
2649                                                                 strunzone(mapvote_maps_pakfile[i]);
2650                                                                 mapvote_maps_pakfile[i] = "";
2651                                                         }
2652                                                 }
2653                                 }
2654                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2655                         if(autocvar_sv_eventlog)
2656                                 GameLogEcho(result);
2657                 }
2658
2659         return FALSE;
2660 }
2661 void MapVote_Tick()
2662 {
2663         float keeptwo;
2664         float totalvotes;
2665
2666         keeptwo = mapvote_keeptwotime;
2667         MapVote_CheckRules_1(); // count
2668         if(MapVote_CheckRules_2()) // decide
2669                 return;
2670
2671         totalvotes = 0;
2672         FOR_EACH_REALCLIENT(other)
2673         {
2674                 // hide scoreboard again
2675                 if(other.health != 2342)
2676                 {
2677                         other.health = 2342;
2678                         other.impulse = 0;
2679                         if(IS_REAL_CLIENT(other))
2680                         {
2681                                 msg_entity = other;
2682                                 WriteByte(MSG_ONE, SVC_FINALE);
2683                                 WriteString(MSG_ONE, "");
2684                         }
2685                 }
2686
2687                 // clear possibly invalid votes
2688                 if(mapvote_maps[other.mapvote - 1] == "")
2689                         other.mapvote = 0;
2690                 // use impulses as new vote
2691                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2692                         if(mapvote_maps[other.impulse - 1] != "")
2693                         {
2694                                 other.mapvote = other.impulse;
2695                                 MapVote_TouchVotes(other);
2696                         }
2697                 other.impulse = 0;
2698
2699                 if(other.mapvote)
2700                         ++totalvotes;
2701         }
2702
2703         MapVote_CheckRules_1(); // just count
2704 }
2705 void MapVote_Start()
2706 {
2707         if(mapvote_run)
2708                 return;
2709
2710         // wait for stats to be sent first
2711         if(!playerstats_waitforme)
2712                 return;
2713
2714         MapInfo_Enumerate();
2715         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2716                 mapvote_run = TRUE;
2717 }
2718 void MapVote_Think()
2719 {
2720         if(!mapvote_run)
2721                 return;
2722
2723         if(alreadychangedlevel)
2724                 return;
2725
2726         if(time < mapvote_nextthink)
2727                 return;
2728         //dprint("tick\n");
2729
2730         mapvote_nextthink = time + 0.5;
2731
2732         if(!mapvote_initialized)
2733         {
2734                 if(autocvar_rescan_pending == 1)
2735                 {
2736                         cvar_set("rescan_pending", "2");
2737                         localcmd("fs_rescan\nrescan_pending 3\n");
2738                         return;
2739                 }
2740                 else if(autocvar_rescan_pending == 2)
2741                 {
2742                         return;
2743                 }
2744                 else if(autocvar_rescan_pending == 3)
2745                 {
2746                         // now build missing mapinfo files
2747                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2748                                 return;
2749
2750                         // we're done, start the timer
2751                         cvar_set("rescan_pending", "0");
2752                 }
2753
2754                 mapvote_initialized = TRUE;
2755                 if(DoNextMapOverride(0))
2756                         return;
2757                 if(!autocvar_g_maplist_votable || player_count <= 0)
2758                 {
2759                         GotoNextMap(0);
2760                         return;
2761                 }
2762                 MapVote_Init();
2763         }
2764
2765         MapVote_Tick();
2766 }
2767
2768 string GotoMap(string m)
2769 {
2770         if(!MapInfo_CheckMap(m))
2771                 return "The map you chose is not available on this server.";
2772         cvar_set("nextmap", m);
2773         cvar_set("timelimit", "-1");
2774         if(mapvote_initialized || alreadychangedlevel)
2775         {
2776                 if(DoNextMapOverride(0))
2777                         return "Map switch initiated.";
2778                 else
2779                         return "Hm... no. For some reason I like THIS map more.";
2780         }
2781         else
2782                 return "Map switch will happen after scoreboard.";
2783 }
2784
2785
2786 void EndFrame()
2787 {
2788         float altime;
2789         FOR_EACH_REALCLIENT(self)
2790         {
2791                 if(IS_SPEC(self))
2792                 {
2793                         if(self.enemy.typehitsound)
2794                                 self.typehit_time = time;
2795                         else if(self.enemy.hitsound)
2796                                 self.hit_time = time;
2797                 }
2798                 else
2799                 {
2800                         if(self.typehitsound)
2801                                 self.typehit_time = time;
2802                         else if(self.hitsound)
2803                                 self.hit_time = time;
2804                 }
2805         }
2806         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2807         // add 1 frametime because after this, engine SV_Physics
2808         // increases time by a frametime and then networks the frame
2809         // add another frametime because client shows everything with
2810         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2811         // needed!
2812         FOR_EACH_CLIENT(self)
2813         {
2814                 self.hitsound = FALSE;
2815                 self.typehitsound = FALSE;
2816                 antilag_record(self, altime);
2817         }
2818 }
2819
2820
2821 /*
2822  * RedirectionThink:
2823  * returns TRUE if redirecting
2824  */
2825 float redirection_timeout;
2826 float redirection_nextthink;
2827 float RedirectionThink()
2828 {
2829         float clients_found;
2830
2831         if(redirection_target == "")
2832                 return FALSE;
2833
2834         if(!redirection_timeout)
2835         {
2836                 cvar_set("sv_public", "-2");
2837                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2838                 if(redirection_target == "self")
2839                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2840                 else
2841                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2842         }
2843
2844         if(time < redirection_nextthink)
2845                 return TRUE;
2846
2847         redirection_nextthink = time + 1;
2848
2849         clients_found = 0;
2850         FOR_EACH_REALCLIENT(self)
2851         {
2852                 // TODO add timer
2853                 print("Redirecting: sending connect command to ", self.netname, "\n");
2854                 if(redirection_target == "self")
2855                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2856                 else
2857                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2858                 ++clients_found;
2859         }
2860
2861         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2862
2863         if(time > redirection_timeout || clients_found == 0)
2864                 localcmd("\nwait; wait; wait; quit\n");
2865
2866         return TRUE;
2867 }
2868
2869 void TargetMusic_RestoreGame();
2870 void RestoreGame()
2871 {
2872         // Loaded from a save game
2873         // some things then break, so let's work around them...
2874
2875         // Progs DB (capture records)
2876         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2877
2878         // Mapinfo
2879         MapInfo_Shutdown();
2880         MapInfo_Enumerate();
2881         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2882         WeaponStats_Init();
2883
2884         TargetMusic_RestoreGame();
2885 }
2886
2887 void Shutdown()
2888 {
2889         entity e;
2890
2891         gameover = 2;
2892
2893         if(world_initialized > 0)
2894         {
2895                 world_initialized = 0;
2896                 print("Saving persistent data...\n");
2897                 Ban_SaveBans();
2898
2899                 PlayerStats_EndMatch(0);
2900                 FOR_EACH_CLIENT(e)
2901                         PlayerStats_AddGlobalInfo(e);
2902                 PlayerStats_Shutdown();
2903
2904                 if(!cheatcount_total)
2905                 {
2906                         if(autocvar_sv_db_saveasdump)
2907                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2908                         else
2909                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2910                 }
2911                 if(autocvar_developer)
2912                 {
2913                         if(autocvar_sv_db_saveasdump)
2914                                 db_dump(TemporaryDB, "server-temp.db");
2915                         else
2916                                 db_save(TemporaryDB, "server-temp.db");
2917                 }
2918                 CheatShutdown(); // must be after cheatcount check
2919                 db_close(ServerProgsDB);
2920                 db_close(TemporaryDB);
2921                 print("done!\n");
2922                 // tell the bot system the game is ending now
2923                 bot_endgame();
2924
2925                 WeaponStats_Shutdown();
2926                 MapInfo_Shutdown();
2927         }
2928         else if(world_initialized == 0)
2929         {
2930                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2931         }
2932 }