qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431                 BADCVAR("g_grappling_hook");
 432                 BADCVAR("g_jetpack");
 433
 434 #undef BADPREFIX
 435 #undef BADCVAR
 436
 437                 if(pureadding)
 438                 {
 439                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 440                         if(strlen(cvar_purechanges) > 16384)
 441                         {
 442                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 443                                 pureadding = 0;
 444                         }
 445                 }
 446                 ++cvar_purechanges_count;
 447                 // WARNING: this variable is used for the server list
 448                 // NEVER dare to skip this code!
 449                 // Hacks to intentionally appearing as "pure server" even though you DO have
 450                 // modified settings may be punished by removal from the server list.
 451                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 452                 // though.
 453         }
 454         buf_del(h);
 455         if(cvar_changes == "")
 456                 cvar_changes = "// this server runs at default server settings\n";
 457         else
 458                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 459         cvar_changes = strzone(cvar_changes);
 460         if(cvar_purechanges == "")
 461                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 462         else
 463                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 464         cvar_purechanges = strzone(cvar_purechanges);
 465 }
 466
 467 void detect_maptype()
 468 {
 469 #if 0
 470         vector o, v;
 471         float i;
 472
 473         for(;;)
 474         {
 475                 o = world.mins;
 476                 o_x += random() * (world.maxs_x - world.mins_x);
 477                 o_y += random() * (world.maxs_y - world.mins_y);
 478                 o_z += random() * (world.maxs_z - world.mins_z);
 479
 480                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 481                 if(trace_fraction == 1)
 482                         continue;
 483
 484                 v = trace_endpos;
 485
 486                 for(i = 0; i < 64; i += 4)
 487                 {
 488                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 489         if(trace_fraction == 1)
 490                 continue;
 491                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 492                 }
 493
 494                 break;
 495         }
 496 #endif
 497 }
 498
 499 entity randomseed;
 500 float RandomSeed_Send(entity to, float sf)
 501 {
 502         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 503         WriteShort(MSG_ENTITY, self.cnt);
 504         return TRUE;
 505 }
 506 void RandomSeed_Think()
 507 {
 508         self.cnt = bound(0, floor(random() * 65536), 65535);
 509         self.nextthink = time + 5;
 510
 511         self.SendFlags |= 1;
 512 }
 513 void RandomSeed_Spawn()
 514 {
 515         randomseed = spawn();
 516         randomseed.think = RandomSeed_Think;
 517         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 518
 519         entity oldself;
 520         oldself = self;
 521         self = randomseed;
 522         self.think(); // sets random seed and nextthink
 523         self = oldself;
 524 }
 525
 526 void spawnfunc___init_dedicated_server(void)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e;
 538         e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = spawn();
 543         e.classname = "info_player_deathmatch"; // safeguard against player joining
 544
 545         self.classname = "worldspawn"; // safeguard against various stuff ;)
 546
 547         // needs to be done so early because of the constants they create
 548         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 549         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 550         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 551         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void Nagger_Init();
 560 void ClientInit_Spawn();
 561 void WeaponStats_Init();
 562 void WeaponStats_Shutdown();
 563 void spawnfunc_worldspawn (void)
 564 {
 565         float fd, l, i, j, n;
 566         string s;
 567
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         if(world_already_spawned)
 573                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 574         world_already_spawned = TRUE;
 575
 576         remove = remove_safely; // during spawning, watch what you remove!
 577
 578         check_unacceptable_compiler_bugs();
 579
 580         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 581
 582         compressShortVector_init();
 583
 584         entity head;
 585         head = nextent(world);
 586         maxclients = 0;
 587         while(head)
 588         {
 589                 ++maxclients;
 590                 head = nextent(head);
 591         }
 592
 593         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 594
 595         // needs to be done so early because of the constants they create
 596         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_norecoil)
 707                         s = strcat(s, ":norecoil");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_powerups == 0)
 711                         s = strcat(s, ":no_powerups");
 712                 if(autocvar_g_powerups > 0)
 713                         s = strcat(s, ":powerups");
 714
 715                 GameLogEcho(s);
 716                 GameLogEcho(":gameinfo:end");
 717         }
 718         else
 719                 matchid = strzone(ftos(random()));
 720
 721         cvar_set("nextmap", "");
 722
 723         SetDefaultAlpha();
 724
 725         if(autocvar_g_campaign)
 726                 CampaignPostInit();
 727
 728         fteqcc_testbugs();
 729
 730         Ban_LoadBans();
 731
 732         MapInfo_Enumerate();
 733         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 734
 735         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 736         {
 737                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 738                 if(fd != -1)
 739                 {
 740                         while((s = fgets(fd)))
 741                         {
 742                                 l = tokenize_console(s);
 743                                 if(l < 2)
 744                                         continue;
 745                                 if(argv(0) == "cd")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 748                                         print("  cdtrack ", argv(2), "\n");
 749                                 }
 750                                 else if(argv(0) == "fog")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 753                                         print("  \"fog\" \"", s, "\"\n");
 754                                 }
 755                                 else if(argv(0) == "set")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) != "//")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 764                                 }
 765                         }
 766                         fclose(fd);
 767                 }
 768         }
 769
 770         WeaponStats_Init();
 771
 772         WEPSET_ADDSTAT();
 773         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 774         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 775         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 776         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 777         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 778         Nagger_Init();
 779
 780         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 781         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 782         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 783         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 784         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 795         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         // g_movementspeed hack
 800         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 801         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 802         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 803         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 804
 805         // secrets
 806         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 807         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 808
 809         // misc
 810         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 811
 812         next_pingtime = time + 5;
 813
 814         detect_maptype();
 815
 816         // set up information replies for clients and server to use
 817         lsmaps_reply = strzone(getlsmaps());
 818         for(i = 0; i < 10; ++i)
 819         {
 820                 s = getrecords(i);
 821                 if (s)
 822                         records_reply[i] = strzone(s);
 823         }
 824         ladder_reply = strzone(getladder());
 825         rankings_reply = strzone(getrankings());
 826
 827         // begin other init
 828         ClientInit_Spawn();
 829         RandomSeed_Spawn();
 830         PingPLReport_Spawn();
 831
 832         CheatInit();
 833
 834         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 835
 836         // fill sv_curl_serverpackages from .serverpackage files
 837         if(autocvar_sv_curl_serverpackages_auto)
 838         {
 839                 s = "";
 840                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 841                 for(i = 0; i < n; ++i)
 842                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 843                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 844                                 s = strcat(s, " ", argv(i));
 845                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 846                 if(fd >= 0)
 847                 {
 848                         j = search_getsize(fd);
 849                         for(i = 0; i < j; ++i)
 850                                 s = strcat(s, " ", search_getfilename(fd, i));
 851                         search_end(fd);
 852                 }
 853                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 854                 if(fd >= 0)
 855                 {
 856                         j = search_getsize(fd);
 857                         for(i = 0; i < j; ++i)
 858                                 s = strcat(s, " ", search_getfilename(fd, i));
 859                         search_end(fd);
 860                 }
 861                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 862         }
 863
 864         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 865         modname = "Xonotic";
 866         // physics/balance/config changes that count as mod
 867         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 868                 modname = cvar_string("g_mod_physics");
 869         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 870                 modname = cvar_string("g_mod_balance");
 871         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 872                 modname = cvar_string("g_mod_config");
 873         // extra mutators that deserve to count as mod
 874         MUTATOR_CALLHOOK(SetModname);
 875
 876         // save it for later
 877         modname = strzone(modname);
 878
 879         WinningConditionHelper(); // set worldstatus
 880
 881         world_initialized = 1;
 882 }
 883
 884 void spawnfunc_light (void)
 885 {
 886         //makestatic (self); // Who the f___ did that?
 887         remove(self);
 888 }
 889
 890 string GetGametype()
 891 {
 892         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 893 }
 894
 895 string getmapname_stored;
 896 string GetMapname()
 897 {
 898         return mapname;
 899 }
 900
 901 float Map_Count, Map_Current;
 902 string Map_Current_Name;
 903
 904 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 905 float GetMaplistPosition()
 906 {
 907         float pos, idx;
 908         string map;
 909
 910         map = GetMapname();
 911         idx = autocvar_g_maplist_index;
 912
 913         if(idx >= 0)
 914                 if(idx < Map_Count)
 915                         if(map == argv(idx))
 916                                 return idx;
 917
 918         for(pos = 0; pos < Map_Count; ++pos)
 919                 if(map == argv(pos))
 920                         return pos;
 921
 922         // resume normal maplist rotation if current map is not in g_maplist
 923         return idx;
 924 }
 925
 926 float MapHasRightSize(string map)
 927 {
 928         float fh;
 929         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 930         if(autocvar_g_maplist_check_waypoints)
 931         {
 932                 dprint("checkwp "); dprint(map);
 933                 if(!fexists(strcat("maps/", map, ".waypoints")))
 934                 {
 935                         dprint(": no waypoints\n");
 936                         return FALSE;
 937                 }
 938                 dprint(": has waypoints\n");
 939         }
 940
 941         // open map size restriction file
 942         dprint("opensize "); dprint(map);
 943         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 944         if(fh >= 0)
 945         {
 946                 float mapmin, mapmax;
 947                 dprint(": ok, ");
 948                 mapmin = stof(fgets(fh));
 949                 mapmax = stof(fgets(fh));
 950                 fclose(fh);
 951                 if(player_count < mapmin)
 952                 {
 953                         dprint("not enough\n");
 954                         return FALSE;
 955                 }
 956                 if(player_count > mapmax)
 957                 {
 958                         dprint("too many\n");
 959                         return FALSE;
 960                 }
 961                 dprint("right size\n");
 962                 return TRUE;
 963         }
 964         dprint(": not found\n");
 965         return TRUE;
 966 }
 967
 968 string Map_Filename(float position)
 969 {
 970         return strcat("maps/", argv(position), ".bsp");
 971 }
 972
 973 string strwords(string s, float w)
 974 {
 975         float endpos;
 976         for(endpos = 0; w && endpos >= 0; --w)
 977                 endpos = strstrofs(s, " ", endpos + 1);
 978         if(endpos < 0)
 979                 return s;
 980         else
 981                 return substring(s, 0, endpos);
 982 }
 983
 984 float strhasword(string s, string w)
 985 {
 986         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 987 }
 988
 989 void Map_MarkAsRecent(string m)
 990 {
 991         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 992 }
 993
 994 float Map_IsRecent(string m)
 995 {
 996         return strhasword(autocvar_g_maplist_mostrecent, m);
 997 }
 998
 999 float Map_Check(float position, float pass)
1000 {
1001         string filename;
1002         string map_next;
1003         map_next = argv(position);
1004         if(pass <= 1)
1005         {
1006                 if(Map_IsRecent(map_next))
1007                         return 0;
1008         }
1009         filename = Map_Filename(position);
1010         if(MapInfo_CheckMap(map_next))
1011         {
1012                 if(pass == 2)
1013                         return 1;
1014                 if(MapHasRightSize(map_next))
1015                         return 1;
1016                 return 0;
1017         }
1018         else
1019                 dprint( "Couldn't select '", filename, "'..\n" );
1020
1021         return 0;
1022 }
1023
1024 void Map_Goto_SetStr(string nextmapname)
1025 {
1026         if(getmapname_stored != "")
1027                 strunzone(getmapname_stored);
1028         if(nextmapname == "")
1029                 getmapname_stored = "";
1030         else
1031                 getmapname_stored = strzone(nextmapname);
1032 }
1033
1034 void Map_Goto_SetFloat(float position)
1035 {
1036         cvar_set("g_maplist_index", ftos(position));
1037         Map_Goto_SetStr(argv(position));
1038 }
1039
1040 void Map_Goto(float reinit)
1041 {
1042         MapInfo_LoadMap(getmapname_stored, reinit);
1043 }
1044
1045 // return codes of map selectors:
1046 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1047 //   -2 = permanent failure
1048 float() MaplistMethod_Iterate = // usual method
1049 {
1050         float pass, i;
1051
1052         for(pass = 1; pass <= 2; ++pass)
1053         {
1054                 for(i = 1; i < Map_Count; ++i)
1055                 {
1056                         float mapindex;
1057                         mapindex = mod(i + Map_Current, Map_Count);
1058                         if(Map_Check(mapindex, pass))
1059                                 return mapindex;
1060                 }
1061         }
1062         return -1;
1063 }
1064
1065 float() MaplistMethod_Repeat = // fallback method
1066 {
1067         if(Map_Check(Map_Current, 2))
1068                 return Map_Current;
1069         return -2;
1070 }
1071
1072 float() MaplistMethod_Random = // random map selection
1073 {
1074         float i, imax;
1075
1076         imax = 42;
1077
1078         for(i = 0; i <= imax; ++i)
1079         {
1080                 float mapindex;
1081                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1082                 if(Map_Check(mapindex, 1))
1083                         return mapindex;
1084         }
1085         return -1;
1086 }
1087
1088 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1089 // the exponent sets a bias on the map selection:
1090 // the higher the exponent, the less likely "shortly repeated" same maps are
1091 {
1092         float i, j, imax, insertpos;
1093
1094         imax = 42;
1095
1096         for(i = 0; i <= imax; ++i)
1097         {
1098                 string newlist;
1099
1100                 // now reinsert this at another position
1101                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1102                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1103                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1104                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1105
1106                 // insert the current map there
1107                 newlist = "";
1108                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1109                         newlist = strcat(newlist, " ", argv(j));
1110                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1111                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1112                         newlist = strcat(newlist, " ", argv(j));
1113                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1114                 cvar_set("g_maplist", newlist);
1115                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1116
1117                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1118                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1119                 if(Map_Check(Map_Current, 1))
1120                         return Map_Current;
1121         }
1122         return -1;
1123 }
1124
1125 void Maplist_Init()
1126 {
1127         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1128         if(Map_Count == 0)
1129         {
1130                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1131                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1132                 if(autocvar_g_maplist_shuffle)
1133                         ShuffleMaplist();
1134                 localcmd("\nmenu_cmd sync\n");
1135                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1136         }
1137         if(Map_Count == 0)
1138                 error("empty maplist, cannot select a new map");
1139         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1140
1141         if(Map_Current_Name)
1142                 strunzone(Map_Current_Name);
1143         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1144         // this may or may not be correct, but who cares, in the worst case a map
1145         // isn't chosen in the first pass that should have been
1146 }
1147
1148 string GetNextMap()
1149 {
1150         float nextMap;
1151
1152         Maplist_Init();
1153         nextMap = -1;
1154
1155         if(nextMap == -1)
1156                 if(autocvar_g_maplist_shuffle > 0)
1157                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1158
1159         if(nextMap == -1)
1160                 if(autocvar_g_maplist_selectrandom)
1161                         nextMap = MaplistMethod_Random();
1162
1163         if(nextMap == -1)
1164                 nextMap = MaplistMethod_Iterate();
1165
1166         if(nextMap == -1)
1167                 nextMap = MaplistMethod_Repeat();
1168
1169         if(nextMap >= 0)
1170         {
1171                 Map_Goto_SetFloat(nextMap);
1172                 return getmapname_stored;
1173         }
1174
1175         return "";
1176 }
1177
1178 float DoNextMapOverride(float reinit)
1179 {
1180         if(autocvar_g_campaign)
1181         {
1182                 CampaignPostIntermission();
1183                 alreadychangedlevel = TRUE;
1184                 return TRUE;
1185         }
1186         if(autocvar_quit_when_empty)
1187         {
1188                 if(player_count <= currentbots)
1189                 {
1190                         localcmd("quit\n");
1191                         alreadychangedlevel = TRUE;
1192                         return TRUE;
1193                 }
1194         }
1195         if(autocvar_quit_and_redirect != "")
1196         {
1197                 redirection_target = strzone(autocvar_quit_and_redirect);
1198                 alreadychangedlevel = TRUE;
1199                 return TRUE;
1200         }
1201         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1202         {
1203                 localcmd("restart\n");
1204                 alreadychangedlevel = TRUE;
1205                 return TRUE;
1206         }
1207         if(autocvar_nextmap != "")
1208                 if(MapInfo_CheckMap(autocvar_nextmap))
1209                 {
1210                         Map_Goto_SetStr(autocvar_nextmap);
1211                         Map_Goto(reinit);
1212                         alreadychangedlevel = TRUE;
1213                         return TRUE;
1214                 }
1215         if(!reinit && autocvar_lastlevel)
1216         {
1217                 cvar_settemp_restore();
1218                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1219                 alreadychangedlevel = TRUE;
1220                 return TRUE;
1221         }
1222         return FALSE;
1223 }
1224
1225 void GotoNextMap(float reinit)
1226 {
1227         //string nextmap;
1228         //float n, nummaps;
1229         //string s;
1230         if (alreadychangedlevel)
1231                 return;
1232         alreadychangedlevel = TRUE;
1233
1234         {
1235                 string nextMap;
1236                 float allowReset;
1237
1238                 for(allowReset = 1; allowReset >= 0; --allowReset)
1239                 {
1240                         nextMap = GetNextMap();
1241                         if(nextMap != "")
1242                                 break;
1243
1244                         if(allowReset)
1245                         {
1246                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1247                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1248                                 if(autocvar_g_maplist_shuffle)
1249                                         ShuffleMaplist();
1250                                 localcmd("\nmenu_cmd sync\n");
1251                         }
1252                         else
1253                         {
1254                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1255                         }
1256                 }
1257                 Map_Goto(reinit);
1258         }
1259 }
1260
1261
1262 /*
1263 ============
1264 IntermissionThink
1265
1266 When the player presses attack or jump, change to the next level
1267 ============
1268 */
1269 .float autoscreenshot;
1270 void() MapVote_Start;
1271 void() MapVote_Think;
1272 float mapvote_initialized;
1273 void IntermissionThink()
1274 {
1275         FixIntermissionClient(self);
1276
1277         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1278         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1279
1280         if( (server_screenshot || client_screenshot)
1281                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1282         {
1283                 self.autoscreenshot = -1;
1284                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1285                 return;
1286         }
1287
1288         if (time < intermission_exittime)
1289                 return;
1290
1291         if(!mapvote_initialized)
1292                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1293                         return;
1294
1295         MapVote_Start();
1296 }
1297
1298 /*
1299 ============
1300 FindIntermission
1301
1302 Returns the entity to view from
1303 ============
1304 */
1305 /*
1306 entity FindIntermission()
1307 {
1308         local   entity spot;
1309         local   float cyc;
1310
1311 // look for info_intermission first
1312         spot = find (world, classname, "info_intermission");
1313         if (spot)
1314         {       // pick a random one
1315                 cyc = random() * 4;
1316                 while (cyc > 1)
1317                 {
1318                         spot = find (spot, classname, "info_intermission");
1319                         if (!spot)
1320                                 spot = find (spot, classname, "info_intermission");
1321                         cyc = cyc - 1;
1322                 }
1323                 return spot;
1324         }
1325
1326 // then look for the start position
1327         spot = find (world, classname, "info_player_start");
1328         if (spot)
1329                 return spot;
1330
1331 // testinfo_player_start is only found in regioned levels
1332         spot = find (world, classname, "testplayerstart");
1333         if (spot)
1334                 return spot;
1335
1336 // then look for the start position
1337         spot = find (world, classname, "info_player_deathmatch");
1338         if (spot)
1339                 return spot;
1340
1341         //objerror ("FindIntermission: no spot");
1342         return world;
1343 }
1344 */
1345
1346 /*
1347 ===============================================================================
1348
1349 RULES
1350
1351 ===============================================================================
1352 */
1353
1354 void DumpStats(float final)
1355 {
1356         float file;
1357         string s;
1358         float to_console;
1359         float to_eventlog;
1360         float to_file;
1361         float i;
1362
1363         to_console = autocvar_sv_logscores_console;
1364         to_eventlog = autocvar_sv_eventlog;
1365         to_file = autocvar_sv_logscores_file;
1366
1367         if(!final)
1368         {
1369                 to_console = TRUE; // always print printstats replies
1370                 to_eventlog = FALSE; // but never print them to the event log
1371         }
1372
1373         if(to_eventlog)
1374                 if(autocvar_sv_eventlog_console)
1375                         to_console = FALSE; // otherwise we get the output twice
1376
1377         if(final)
1378                 s = ":scores:";
1379         else
1380                 s = ":status:";
1381         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1382
1383         if(to_console)
1384                 print(s, "\n");
1385         if(to_eventlog)
1386                 GameLogEcho(s);
1387
1388         file = -1;
1389         if(to_file)
1390         {
1391                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1392                 if(file == -1)
1393                         to_file = FALSE;
1394                 else
1395                         fputs(file, strcat(s, "\n"));
1396         }
1397
1398         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1399         if(to_console)
1400                 print(s, "\n");
1401         if(to_eventlog)
1402                 GameLogEcho(s);
1403         if(to_file)
1404                 fputs(file, strcat(s, "\n"));
1405
1406         FOR_EACH_CLIENT(other)
1407         {
1408                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1409                 {
1410                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1411                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1412                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1413                                 s = strcat(s, ftos(other.team), ":");
1414                         else
1415                                 s = strcat(s, "spectator:");
1416
1417                         if(to_console)
1418                                 print(s, other.netname, "\n");
1419                         if(to_eventlog)
1420                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1421                         if(to_file)
1422                                 fputs(file, strcat(s, other.netname, "\n"));
1423                 }
1424         }
1425
1426         if(teamplay)
1427         {
1428                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1429                 if(to_console)
1430                         print(s, "\n");
1431                 if(to_eventlog)
1432                         GameLogEcho(s);
1433                 if(to_file)
1434                         fputs(file, strcat(s, "\n"));
1435
1436                 for(i = 1; i < 16; ++i)
1437                 {
1438                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1439                         s = strcat(s, ":", ftos(i));
1440                         if(to_console)
1441                                 print(s, "\n");
1442                         if(to_eventlog)
1443                                 GameLogEcho(s);
1444                         if(to_file)
1445                                 fputs(file, strcat(s, "\n"));
1446                 }
1447         }
1448
1449         if(to_console)
1450                 print(":end\n");
1451         if(to_eventlog)
1452                 GameLogEcho(":end");
1453         if(to_file)
1454         {
1455                 fputs(file, ":end\n");
1456                 fclose(file);
1457         }
1458 }
1459
1460 void FixIntermissionClient(entity e)
1461 {
1462         string s;
1463         if(!e.autoscreenshot) // initial call
1464         {
1465                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1466                 e.health = -2342;
1467                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1468                 e.solid = SOLID_NOT;
1469                 e.movetype = MOVETYPE_NONE;
1470                 e.takedamage = DAMAGE_NO;
1471                 if(e.weaponentity)
1472                 {
1473                         e.weaponentity.effects = EF_NODRAW;
1474                         if (e.weaponentity.weaponentity)
1475                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1476                 }
1477                 if(IS_REAL_CLIENT(e))
1478                 {
1479                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1480                         s = autocvar_sv_intermission_cdtrack;
1481                         if(s != "")
1482                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1483                         msg_entity = e;
1484                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1485                 }
1486         }
1487 }
1488
1489 /*
1490 go to the next level for deathmatch
1491 only called if a time or frag limit has expired
1492 */
1493 void NextLevel()
1494 {
1495         gameover = TRUE;
1496
1497         intermission_running = 1;
1498
1499 // enforce a wait time before allowing changelevel
1500         if(player_count > 0)
1501                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1502         else
1503                 intermission_exittime = -1;
1504
1505         /*
1506         WriteByte (MSG_ALL, SVC_CDTRACK);
1507         WriteByte (MSG_ALL, 3);
1508         WriteByte (MSG_ALL, 3);
1509         // done in FixIntermission
1510         */
1511
1512         //pos = FindIntermission ();
1513
1514         VoteReset();
1515
1516         DumpStats(TRUE);
1517
1518         // send statistics
1519         entity e;
1520         PlayerStats_EndMatch(1);
1521         FOR_EACH_CLIENT(e)
1522                 PlayerStats_AddGlobalInfo(e);
1523         PlayerStats_Shutdown();
1524         WeaponStats_Shutdown();
1525
1526         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1527
1528         if(autocvar_sv_eventlog)
1529                 GameLogEcho(":gameover");
1530
1531         GameLogClose();
1532
1533         FOR_EACH_PLAYER(other) {
1534                 FixIntermissionClient(other);
1535                 if(other.winning)
1536                         bprint(other.netname, " ^7wins.\n");
1537         }
1538
1539         if(autocvar_g_campaign)
1540                 CampaignPreIntermission();
1541
1542         // update lsmaps in case the gametype changed, this way people can easily list maps for it
1543         if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
1544         lsmaps_reply = strzone(getlsmaps());
1545
1546         MUTATOR_CALLHOOK(MatchEnd);
1547
1548         localcmd("\nsv_hook_gameend\n");
1549 }
1550
1551 /*
1552 ============
1553 CheckRules_Player
1554
1555 Exit deathmatch games upon conditions
1556 ============
1557 */
1558 void CheckRules_Player()
1559 {
1560         if (gameover)   // someone else quit the game already
1561                 return;
1562
1563         if(self.deadflag == DEAD_NO)
1564                 self.play_time += frametime;
1565
1566         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1567         //   (div0: and that in CheckRules_World please)
1568 }
1569
1570 float checkrules_equality;
1571 float checkrules_suddendeathwarning;
1572 float checkrules_suddendeathend;
1573 float checkrules_overtimesadded; //how many overtimes have been already added
1574
1575 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1576 float WINNING_YES = 1; // winner found
1577 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1578 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1579
1580 float InitiateSuddenDeath()
1581 {
1582         // Check first whether normal overtimes could be added before initiating suddendeath mode
1583         // - for this timelimit_overtime needs to be >0 of course
1584         // - also check the winning condition calculated in the previous frame and only add normal overtime
1585         //   again, if at the point at which timelimit would be extended again, still no winner was found
1586         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1587         {
1588                 return 1; // need to call InitiateOvertime later
1589         }
1590         else
1591         {
1592                 if(!checkrules_suddendeathend)
1593                 {
1594                         if(autocvar_g_campaign)
1595                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1596                         else
1597                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1598                         if(g_race && !g_race_qualifying)
1599                                 race_StartCompleting();
1600                 }
1601                 return 0;
1602         }
1603 }
1604
1605 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1606 {
1607         ++checkrules_overtimesadded;
1608         //add one more overtime by simply extending the timelimit
1609         float tl;
1610         tl = autocvar_timelimit;
1611         tl += autocvar_timelimit_overtime;
1612         cvar_set("timelimit", ftos(tl));
1613
1614         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1615 }
1616
1617 float GetWinningCode(float fraglimitreached, float equality)
1618 {
1619         if(autocvar_g_campaign == 1)
1620                 if(fraglimitreached)
1621                         return WINNING_YES;
1622                 else
1623                         return WINNING_NO;
1624
1625         else
1626                 if(equality)
1627                         if(fraglimitreached)
1628                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1629                         else
1630                                 return WINNING_NEVER;
1631                 else
1632                         if(fraglimitreached)
1633                                 return WINNING_YES;
1634                         else
1635                                 return WINNING_NO;
1636 }
1637
1638 // set the .winning flag for exactly those players with a given field value
1639 void SetWinners(.float field, float value)
1640 {
1641         entity head;
1642         FOR_EACH_PLAYER(head)
1643                 head.winning = (head.field == value);
1644 }
1645
1646 // set the .winning flag for those players with a given field value
1647 void AddWinners(.float field, float value)
1648 {
1649         entity head;
1650         FOR_EACH_PLAYER(head)
1651                 if(head.field == value)
1652                         head.winning = 1;
1653 }
1654
1655 // clear the .winning flags
1656 void ClearWinners(void)
1657 {
1658         entity head;
1659         FOR_EACH_PLAYER(head)
1660                 head.winning = 0;
1661 }
1662
1663 // Onslaught winning condition:
1664 // game terminates if only one team has a working generator (or none)
1665 float WinningCondition_Onslaught()
1666 {
1667         entity head;
1668         float t1, t2, t3, t4;
1669
1670         WinningConditionHelper(); // set worldstatus
1671
1672         if(inWarmupStage)
1673                 return WINNING_NO;
1674
1675         // first check if the game has ended
1676         t1 = t2 = t3 = t4 = 0;
1677         head = find(world, classname, "onslaught_generator");
1678         while (head)
1679         {
1680                 if (head.health > 0)
1681                 {
1682                         if (head.team == NUM_TEAM_1) t1 = 1;
1683                         if (head.team == NUM_TEAM_2) t2 = 1;
1684                         if (head.team == NUM_TEAM_3) t3 = 1;
1685                         if (head.team == NUM_TEAM_4) t4 = 1;
1686                 }
1687                 head = find(head, classname, "onslaught_generator");
1688         }
1689         if (t1 + t2 + t3 + t4 < 2)
1690         {
1691                 // game over, only one team remains (or none)
1692                 ClearWinners();
1693                 if (t1) SetWinners(team, NUM_TEAM_1);
1694                 if (t2) SetWinners(team, NUM_TEAM_2);
1695                 if (t3) SetWinners(team, NUM_TEAM_3);
1696                 if (t4) SetWinners(team, NUM_TEAM_4);
1697                 dprint("Have a winner, ending game.\n");
1698                 return WINNING_YES;
1699         }
1700
1701         // Two or more teams remain
1702         return WINNING_NO;
1703 }
1704
1705 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1706 // they win. Otherwise the defending team wins once the timelimit passes.
1707 void assault_new_round();
1708 float WinningCondition_Assault()
1709 {
1710         float status;
1711
1712         WinningConditionHelper(); // set worldstatus
1713
1714         status = WINNING_NO;
1715         // as the timelimit has not yet passed just assume the defending team will win
1716         if(assault_attacker_team == NUM_TEAM_1)
1717         {
1718                 SetWinners(team, NUM_TEAM_2);
1719         }
1720         else
1721         {
1722                 SetWinners(team, NUM_TEAM_1);
1723         }
1724
1725         entity ent;
1726         ent = find(world, classname, "target_assault_roundend");
1727         if(ent)
1728         {
1729                 if(ent.winning) // round end has been triggered by attacking team
1730                 {
1731                         bprint("ASSAULT: round completed...\n");
1732                         SetWinners(team, assault_attacker_team);
1733
1734                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1735
1736                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1737                         {
1738                                 status = WINNING_YES;
1739                         }
1740                         else
1741                         {
1742                                 entity oldself;
1743                                 oldself = self;
1744                                 self = ent;
1745                                 assault_new_round();
1746                                 self = oldself;
1747                         }
1748                 }
1749         }
1750
1751         return status;
1752 }
1753
1754 // LMS winning condition: game terminates if and only if there's at most one
1755 // one player who's living lives. Top two scores being equal cancels the time
1756 // limit.
1757 float WinningCondition_LMS()
1758 {
1759         entity head, head2;
1760         float have_player;
1761         float have_players;
1762         float l;
1763
1764         have_player = FALSE;
1765         have_players = FALSE;
1766         l = LMS_NewPlayerLives();
1767
1768         head = find(world, classname, "player");
1769         if(head)
1770                 have_player = TRUE;
1771         head2 = find(head, classname, "player");
1772         if(head2)
1773                 have_players = TRUE;
1774
1775         if(have_player)
1776         {
1777                 // we have at least one player
1778                 if(have_players)
1779                 {
1780                         // two or more active players - continue with the game
1781                 }
1782                 else
1783                 {
1784                         // exactly one player?
1785
1786                         ClearWinners();
1787                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1788
1789                         if(l)
1790                         {
1791                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1792                                 return WINNING_NO;
1793                         }
1794                         else
1795                         {
1796                                 // a winner!
1797                                 // and assign him his first place
1798                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1799                                 return WINNING_YES;
1800                         }
1801                 }
1802         }
1803         else
1804         {
1805                 // nobody is playing at all...
1806                 if(l)
1807                 {
1808                         // wait for players...
1809                 }
1810                 else
1811                 {
1812                         // SNAFU (maybe a draw game?)
1813                         ClearWinners();
1814                         dprint("No players, ending game.\n");
1815                         return WINNING_YES;
1816                 }
1817         }
1818
1819         // When we get here, we have at least two players who are actually LIVING,
1820         // now check if the top two players have equal score.
1821         WinningConditionHelper();
1822
1823         ClearWinners();
1824         if(WinningConditionHelper_winner)
1825                 WinningConditionHelper_winner.winning = TRUE;
1826         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1827                 return WINNING_NEVER;
1828
1829         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1830         return WINNING_NO;
1831 }
1832
1833 void ShuffleMaplist()
1834 {
1835         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1836 }
1837
1838 float leaderfrags;
1839 float WinningCondition_Scores(float limit, float leadlimit)
1840 {
1841         float limitreached;
1842
1843         // TODO make everything use THIS winning condition (except LMS)
1844         WinningConditionHelper();
1845
1846         if(teamplay)
1847         {
1848                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1849                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1850                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1851                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1852         }
1853
1854         ClearWinners();
1855         if(WinningConditionHelper_winner)
1856                 WinningConditionHelper_winner.winning = 1;
1857         if(WinningConditionHelper_winnerteam >= 0)
1858                 SetWinners(team, WinningConditionHelper_winnerteam);
1859
1860         if(WinningConditionHelper_lowerisbetter)
1861         {
1862                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1863                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1864                 limit = -limit;
1865         }
1866
1867         if(WinningConditionHelper_zeroisworst)
1868                 leadlimit = 0; // not supported in this mode
1869
1870         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1871         // these modes always score in increments of 1, thus this makes sense
1872         {
1873                 if(leaderfrags != WinningConditionHelper_topscore)
1874                 {
1875                         leaderfrags = WinningConditionHelper_topscore;
1876
1877                         if (limit)
1878                         if (leaderfrags == limit - 1)
1879                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1880                         else if (leaderfrags == limit - 2)
1881                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1882                         else if (leaderfrags == limit - 3)
1883                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1884                 }
1885         }
1886
1887         limitreached = FALSE;
1888         if(limit)
1889                 if(WinningConditionHelper_topscore >= limit)
1890                         limitreached = TRUE;
1891         if(leadlimit)
1892         {
1893                 float leadlimitreached;
1894                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1895                 if(autocvar_leadlimit_and_fraglimit)
1896                         limitreached = (limitreached && leadlimitreached);
1897                 else
1898                         limitreached = (limitreached || leadlimitreached);
1899         }
1900
1901         if(limit)
1902                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1903
1904         return GetWinningCode(
1905                 WinningConditionHelper_topscore && limitreached,
1906                 WinningConditionHelper_equality
1907         );
1908 }
1909
1910 float WinningCondition_Race(float fraglimit)
1911 {
1912         float wc;
1913         entity p;
1914         float n, c;
1915
1916         n = 0;
1917         c = 0;
1918         FOR_EACH_PLAYER(p)
1919         {
1920                 ++n;
1921                 if(p.race_completed)
1922                         ++c;
1923         }
1924         if(n && (n == c))
1925                 return WINNING_YES;
1926         wc = WinningCondition_Scores(fraglimit, 0);
1927
1928         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1929         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1930         // do NOT support equality when the laps are all raced!
1931                 return WINNING_STARTSUDDENDEATHOVERTIME;
1932         else
1933                 return WINNING_NEVER;
1934 }
1935
1936 float WinningCondition_QualifyingThenRace(float limit)
1937 {
1938         float wc;
1939         wc = WinningCondition_Scores(limit, 0);
1940
1941         // NEVER initiate overtime
1942         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1943         {
1944                 return WINNING_YES;
1945         }
1946
1947         return wc;
1948 }
1949
1950 float WinningCondition_RanOutOfSpawns()
1951 {
1952         entity head;
1953
1954         if(have_team_spawns <= 0)
1955                 return WINNING_NO;
1956
1957         if(autocvar_g_spawn_useallspawns <= 0)
1958                 return WINNING_NO;
1959
1960         if(!some_spawn_has_been_used)
1961                 return WINNING_NO;
1962
1963         team1_score = team2_score = team3_score = team4_score = 0;
1964
1965         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1966         {
1967                 if(head.team == NUM_TEAM_1)
1968                         team1_score = 1;
1969                 else if(head.team == NUM_TEAM_2)
1970                         team2_score = 1;
1971                 else if(head.team == NUM_TEAM_3)
1972                         team3_score = 1;
1973                 else if(head.team == NUM_TEAM_4)
1974                         team4_score = 1;
1975         }
1976
1977         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1978         {
1979                 if(head.team == NUM_TEAM_1)
1980                         team1_score = 1;
1981                 else if(head.team == NUM_TEAM_2)
1982                         team2_score = 1;
1983                 else if(head.team == NUM_TEAM_3)
1984                         team3_score = 1;
1985                 else if(head.team == NUM_TEAM_4)
1986                         team4_score = 1;
1987         }
1988
1989         ClearWinners();
1990         if(team1_score + team2_score + team3_score + team4_score == 0)
1991         {
1992                 checkrules_equality = TRUE;
1993                 return WINNING_YES;
1994         }
1995         else if(team1_score + team2_score + team3_score + team4_score == 1)
1996         {
1997                 float t, i;
1998                 if(team1_score)
1999                         t = NUM_TEAM_1;
2000                 else if(team2_score)
2001                         t = NUM_TEAM_2;
2002                 else if(team3_score)
2003                         t = NUM_TEAM_3;
2004                 else // if(team4_score)
2005                         t = NUM_TEAM_4;
2006                 CheckAllowedTeams(world);
2007                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2008                 {
2009                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2010                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2011                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2012                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2013                 }
2014
2015                 AddWinners(team, t);
2016                 return WINNING_YES;
2017         }
2018         else
2019                 return WINNING_NO;
2020 }
2021
2022 /*
2023 ============
2024 CheckRules_World
2025
2026 Exit deathmatch games upon conditions
2027 ============
2028 */
2029 void ReadyRestart();
2030 void CheckRules_World()
2031 {
2032         float timelimit;
2033         float fraglimit;
2034         float leadlimit;
2035
2036         VoteThink();
2037         MapVote_Think();
2038
2039         SetDefaultAlpha();
2040
2041         /*
2042         MapVote_Think should now do that part
2043         if (intermission_running)
2044                 if (time >= intermission_exittime + 60)
2045                 {
2046                         if(!DoNextMapOverride())
2047                                 GotoNextMap();
2048                         return;
2049                 }
2050         */
2051
2052         if (gameover)   // someone else quit the game already
2053         {
2054                 if(player_count == 0) // Nobody there? Then let's go to the next map
2055                         MapVote_Start();
2056                         // this will actually check the player count in the next frame
2057                         // again, but this shouldn't hurt
2058                 return;
2059         }
2060
2061         timelimit = autocvar_timelimit * 60;
2062         fraglimit = autocvar_fraglimit;
2063         leadlimit = autocvar_leadlimit;
2064
2065         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2066         {
2067                 if(timelimit > 0)
2068                         timelimit = 0; // timelimit is not made for warmup
2069                 if(fraglimit > 0)
2070                         fraglimit = 0; // no fraglimit for now
2071                 leadlimit = 0; // no leadlimit for now
2072         }
2073
2074         if(timelimit > 0)
2075         {
2076                 timelimit += game_starttime;
2077         }
2078         else if (timelimit < 0)
2079         {
2080                 // endmatch
2081                 NextLevel();
2082                 return;
2083         }
2084
2085         if(g_onslaught)
2086                 timelimit = 0; // ONS has its own overtime rule
2087
2088         float wantovertime;
2089         wantovertime = 0;
2090
2091         if(timelimit > game_starttime)
2092                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2093         else
2094                 game_completion_ratio = 0;
2095
2096         if(checkrules_suddendeathend)
2097         {
2098                 if(!checkrules_suddendeathwarning)
2099                 {
2100                         checkrules_suddendeathwarning = TRUE;
2101                         if(g_race && !g_race_qualifying)
2102                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2103                         else
2104                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2105                 }
2106         }
2107         else
2108         {
2109                 if (timelimit && time >= timelimit)
2110                 {
2111                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2112                         {
2113                                 float totalplayers;
2114                                 float playerswithlaps;
2115                                 float readyplayers;
2116                                 entity head;
2117                                 totalplayers = playerswithlaps = readyplayers = 0;
2118                                 FOR_EACH_PLAYER(head)
2119                                 {
2120                                         ++totalplayers;
2121                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2122                                                 ++playerswithlaps;
2123                                         if(head.ready)
2124                                                 ++readyplayers;
2125                                 }
2126
2127                                 // at least 2 of the players have completed a lap: start the RACE
2128                                 // otherwise, the players should end the qualifying on their own
2129                                 if(readyplayers || playerswithlaps >= 2)
2130                                 {
2131                                         checkrules_suddendeathend = 0;
2132                                         ReadyRestart(); // go to race
2133                                         return;
2134                                 }
2135                                 else
2136                                         wantovertime |= InitiateSuddenDeath();
2137                         }
2138                         else
2139                                 wantovertime |= InitiateSuddenDeath();
2140                 }
2141         }
2142
2143         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2144         {
2145                 NextLevel();
2146                 return;
2147         }
2148
2149         float checkrules_status;
2150         checkrules_status = WinningCondition_RanOutOfSpawns();
2151         if(checkrules_status == WINNING_YES)
2152         {
2153                 bprint("Hey! Someone ran out of spawns!\n");
2154         }
2155         else if(g_race && !g_race_qualifying && timelimit >= 0)
2156         {
2157                 checkrules_status = WinningCondition_Race(fraglimit);
2158                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2159         }
2160         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2161         {
2162                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2163                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2164         }
2165         else if(g_assault)
2166         {
2167                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2168         }
2169         else if(g_lms)
2170         {
2171                 checkrules_status = WinningCondition_LMS();
2172         }
2173         else if (g_onslaught)
2174         {
2175                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2176         }
2177         else
2178         {
2179                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2180                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2181         }
2182
2183         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2184         {
2185                 checkrules_status = WINNING_NEVER;
2186                 checkrules_overtimesadded = -1;
2187                 wantovertime |= InitiateSuddenDeath();
2188         }
2189
2190         if(checkrules_status == WINNING_NEVER)
2191                 // equality cases! Nobody wins if the overtime ends in a draw.
2192                 ClearWinners();
2193
2194         if(wantovertime)
2195         {
2196                 if(checkrules_status == WINNING_NEVER)
2197                         InitiateOvertime();
2198                 else
2199                         checkrules_status = WINNING_YES;
2200         }
2201
2202         if(checkrules_suddendeathend)
2203                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2204                         checkrules_status = WINNING_YES;
2205
2206         if(checkrules_status == WINNING_YES)
2207         {
2208                 //print("WINNING\n");
2209                 NextLevel();
2210         }
2211 }
2212
2213 float mapvote_nextthink;
2214 float mapvote_initialized;
2215 float mapvote_keeptwotime;
2216 float mapvote_timeout;
2217 string mapvote_message;
2218 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2219 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2220 float mapvote_screenshot_dirs_count;
2221
2222 float mapvote_count;
2223 float mapvote_count_real;
2224 string mapvote_maps[MAPVOTE_COUNT];
2225 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2226 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2227 float mapvote_maps_suggested[MAPVOTE_COUNT];
2228 string mapvote_suggestions[MAPVOTE_COUNT];
2229 float mapvote_suggestion_ptr;
2230 float mapvote_voters;
2231 float mapvote_selections[MAPVOTE_COUNT];
2232 float mapvote_run;
2233 float mapvote_detail;
2234 float mapvote_abstain;
2235 .float mapvote;
2236
2237 void MapVote_ClearAllVotes()
2238 {
2239         FOR_EACH_CLIENT(other)
2240                 other.mapvote = 0;
2241 }
2242
2243 string MapVote_Suggest(string m)
2244 {
2245         float i;
2246         if(m == "")
2247                 return "That's not how to use this command.";
2248         if(!autocvar_g_maplist_votable_suggestions)
2249                 return "Suggestions are not accepted on this server.";
2250         if(mapvote_initialized)
2251                 return "Can't suggest - voting is already in progress!";
2252         m = MapInfo_FixName(m);
2253         if not(m)
2254                 return "The map you suggested is not available on this server.";
2255         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2256                 if(Map_IsRecent(m))
2257                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2258
2259         if(!MapInfo_CheckMap(m))
2260                 return "The map you suggested does not support the current game mode.";
2261         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2262                 if(mapvote_suggestions[i] == m)
2263                         return "This map was already suggested.";
2264         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2265         {
2266                 i = floor(random() * mapvote_suggestion_ptr);
2267         }
2268         else
2269         {
2270                 i = mapvote_suggestion_ptr;
2271                 mapvote_suggestion_ptr += 1;
2272         }
2273         if(mapvote_suggestions[i] != "")
2274                 strunzone(mapvote_suggestions[i]);
2275         mapvote_suggestions[i] = strzone(m);
2276         if(autocvar_sv_eventlog)
2277                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2278         return strcat("Suggestion of ", m, " accepted.");
2279 }
2280
2281 void MapVote_AddVotable(string nextMap, float isSuggestion)
2282 {
2283         float j, i, o;
2284         string pakfile, mapfile;
2285
2286         if(nextMap == "")
2287                 return;
2288         for(j = 0; j < mapvote_count; ++j)
2289                 if(mapvote_maps[j] == nextMap)
2290                         return;
2291         // suggestions might be no longer valid/allowed after gametype switch!
2292         if(isSuggestion)
2293                 if(!MapInfo_CheckMap(nextMap))
2294                         return;
2295         mapvote_maps[mapvote_count] = strzone(nextMap);
2296         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2297
2298         pakfile = string_null;
2299         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2300         {
2301                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2302                 pakfile = whichpack(strcat(mapfile, ".tga"));
2303                 if(pakfile == "")
2304                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2305                 if(pakfile == "")
2306                         pakfile = whichpack(strcat(mapfile, ".png"));
2307                 if(pakfile != "")
2308                         break;
2309         }
2310         if(i >= mapvote_screenshot_dirs_count)
2311                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2312         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2313                 pakfile = substring(pakfile, o, -1);
2314
2315         mapvote_maps_screenshot_dir[mapvote_count] = i;
2316         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2317
2318         mapvote_count += 1;
2319 }
2320
2321 void MapVote_Spawn();
2322 void MapVote_Init()
2323 {
2324         float i;
2325         float nmax, smax;
2326
2327         MapVote_ClearAllVotes();
2328
2329         mapvote_count = 0;
2330         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2331         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2332
2333         if(mapvote_abstain)
2334                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2335         else
2336                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2337         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2338
2339         // we need this for AddVotable, as that cycles through the screenshot dirs
2340         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2341         if(mapvote_screenshot_dirs_count == 0)
2342                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2343         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2344         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2345                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2346
2347         if(mapvote_suggestion_ptr)
2348                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2349                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2350
2351         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2352                 MapVote_AddVotable(GetNextMap(), FALSE);
2353
2354         if(mapvote_count == 0)
2355         {
2356                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2357                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2358                 if(autocvar_g_maplist_shuffle)
2359                         ShuffleMaplist();
2360                 localcmd("\nmenu_cmd sync\n");
2361                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2362                         MapVote_AddVotable(GetNextMap(), FALSE);
2363         }
2364
2365         mapvote_count_real = mapvote_count;
2366         if(mapvote_abstain)
2367                 MapVote_AddVotable("don't care", 0);
2368
2369         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2370
2371         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2372         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2373         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2374                 mapvote_keeptwotime = 0;
2375         mapvote_message = "Choose a map and press its key!";
2376
2377         MapVote_Spawn();
2378 }
2379
2380 void MapVote_SendPicture(float id)
2381 {
2382         msg_entity = self;
2383         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2384         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2385         WriteByte(MSG_ONE, id);
2386         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2387 }
2388
2389 float MapVote_GetMapMask()
2390 {
2391         float mask, i, power;
2392         mask = 0;
2393         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2394                 if(mapvote_maps[i] != "")
2395                         mask |= power;
2396         return mask;
2397 }
2398
2399 entity mapvote_ent;
2400 float MapVote_SendEntity(entity to, float sf)
2401 {
2402         float i;
2403
2404         if(sf & 1)
2405                 sf &~= 2; // if we send 1, we don't need to also send 2
2406
2407         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2408         WriteByte(MSG_ENTITY, sf);
2409
2410         if(sf & 1)
2411         {
2412                 // flag 1 == initialization
2413                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2414                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2415                 WriteString(MSG_ENTITY, "");
2416                 WriteByte(MSG_ENTITY, mapvote_count);
2417                 WriteByte(MSG_ENTITY, mapvote_abstain);
2418                 WriteByte(MSG_ENTITY, mapvote_detail);
2419                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2420                 if(mapvote_count <= 8)
2421                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2422                 else
2423                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2424                 for(i = 0; i < mapvote_count; ++i)
2425                         if(mapvote_maps[i] != "")
2426                         {
2427                                 if(mapvote_abstain && i == mapvote_count - 1)
2428                                 {
2429                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2430                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2431                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2432                                 }
2433                                 else
2434                                 {
2435                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2436                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2437                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2438                                 }
2439                         }
2440         }
2441
2442         if(sf & 2)
2443         {
2444                 // flag 2 == update of mask
2445                 if(mapvote_count <= 8)
2446                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2447                 else
2448                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2449         }
2450
2451         if(sf & 4)
2452         {
2453                 if(mapvote_detail)
2454                         for(i = 0; i < mapvote_count; ++i)
2455                                 if(mapvote_maps[i] != "")
2456                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2457
2458                 WriteByte(MSG_ENTITY, to.mapvote);
2459         }
2460
2461         return TRUE;
2462 }
2463
2464 void MapVote_Spawn()
2465 {
2466         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2467 }
2468
2469 void MapVote_TouchMask()
2470 {
2471         mapvote_ent.SendFlags |= 2;
2472 }
2473
2474 void MapVote_TouchVotes(entity voter)
2475 {
2476         mapvote_ent.SendFlags |= 4;
2477 }
2478
2479 float MapVote_Finished(float mappos)
2480 {
2481         string result;
2482         float i;
2483         float didntvote;
2484
2485         if(autocvar_sv_eventlog)
2486         {
2487                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2488                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2489                 didntvote = mapvote_voters;
2490                 for(i = 0; i < mapvote_count; ++i)
2491                         if(mapvote_maps[i] != "")
2492                         {
2493                                 didntvote -= mapvote_selections[i];
2494                                 if(i != mappos)
2495                                 {
2496                                         result = strcat(result, ":", mapvote_maps[i]);
2497                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2498                                 }
2499                         }
2500                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2501
2502                 GameLogEcho(result);
2503                 if(mapvote_maps_suggested[mappos])
2504                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2505         }
2506
2507         FOR_EACH_REALCLIENT(other)
2508                 FixClientCvars(other);
2509
2510         Map_Goto_SetStr(mapvote_maps[mappos]);
2511         Map_Goto(0);
2512         alreadychangedlevel = TRUE;
2513         return TRUE;
2514 }
2515 void MapVote_CheckRules_1()
2516 {
2517         float i;
2518
2519         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2520         {
2521                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2522                 mapvote_selections[i] = 0;
2523         }
2524
2525         mapvote_voters = 0;
2526         FOR_EACH_REALCLIENT(other)
2527         {
2528                 ++mapvote_voters;
2529                 if(other.mapvote)
2530                 {
2531                         i = other.mapvote - 1;
2532                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2533                         mapvote_selections[i] = mapvote_selections[i] + 1;
2534                 }
2535         }
2536 }
2537
2538 float MapVote_CheckRules_2()
2539 {
2540         float i;
2541         float firstPlace, secondPlace;
2542         float firstPlaceVotes, secondPlaceVotes;
2543         float mapvote_voters_real;
2544         string result;
2545
2546         if(mapvote_count_real == 1)
2547                 return MapVote_Finished(0);
2548
2549         mapvote_voters_real = mapvote_voters;
2550         if(mapvote_abstain)
2551                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2552
2553         RandomSelection_Init();
2554         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2555                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2556         firstPlace = RandomSelection_chosen_float;
2557         firstPlaceVotes = RandomSelection_best_priority;
2558         //dprint("First place: ", ftos(firstPlace), "\n");
2559         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2560
2561         RandomSelection_Init();
2562         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2563                 if(i != firstPlace)
2564                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2565         secondPlace = RandomSelection_chosen_float;
2566         secondPlaceVotes = RandomSelection_best_priority;
2567         //dprint("Second place: ", ftos(secondPlace), "\n");
2568         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2569
2570         if(firstPlace == -1)
2571                 error("No first place in map vote... WTF?");
2572
2573         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2574                 return MapVote_Finished(firstPlace);
2575
2576         if(mapvote_keeptwotime)
2577                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2578                 {
2579                         float didntvote;
2580                         MapVote_TouchMask();
2581                         mapvote_message = "Now decide between the TOP TWO!";
2582                         mapvote_keeptwotime = 0;
2583                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2584                         result = strcat(result, ":", ftos(firstPlaceVotes));
2585                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2586                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2587                         didntvote = mapvote_voters;
2588                         for(i = 0; i < mapvote_count; ++i)
2589                                 if(mapvote_maps[i] != "")
2590                                 {
2591                                         didntvote -= mapvote_selections[i];
2592                                         if(i != firstPlace)
2593                                                 if(i != secondPlace)
2594                                                 {
2595                                                         result = strcat(result, ":", mapvote_maps[i]);
2596                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2597                                                         if(i < mapvote_count_real)
2598                                                         {
2599                                                                 strunzone(mapvote_maps[i]);
2600                                                                 mapvote_maps[i] = "";
2601                                                                 strunzone(mapvote_maps_pakfile[i]);
2602                                                                 mapvote_maps_pakfile[i] = "";
2603                                                         }
2604                                                 }
2605                                 }
2606                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2607                         if(autocvar_sv_eventlog)
2608                                 GameLogEcho(result);
2609                 }
2610
2611         return FALSE;
2612 }
2613 void MapVote_Tick()
2614 {
2615         float keeptwo;
2616         float totalvotes;
2617
2618         keeptwo = mapvote_keeptwotime;
2619         MapVote_CheckRules_1(); // count
2620         if(MapVote_CheckRules_2()) // decide
2621                 return;
2622
2623         totalvotes = 0;
2624         FOR_EACH_REALCLIENT(other)
2625         {
2626                 // hide scoreboard again
2627                 if(other.health != 2342)
2628                 {
2629                         other.health = 2342;
2630                         other.impulse = 0;
2631                         if(IS_REAL_CLIENT(other))
2632                         {
2633                                 msg_entity = other;
2634                                 WriteByte(MSG_ONE, SVC_FINALE);
2635                                 WriteString(MSG_ONE, "");
2636                         }
2637                 }
2638
2639                 // clear possibly invalid votes
2640                 if(mapvote_maps[other.mapvote - 1] == "")
2641                         other.mapvote = 0;
2642                 // use impulses as new vote
2643                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2644                         if(mapvote_maps[other.impulse - 1] != "")
2645                         {
2646                                 other.mapvote = other.impulse;
2647                                 MapVote_TouchVotes(other);
2648                         }
2649                 other.impulse = 0;
2650
2651                 if(other.mapvote)
2652                         ++totalvotes;
2653         }
2654
2655         MapVote_CheckRules_1(); // just count
2656 }
2657 void MapVote_Start()
2658 {
2659         if(mapvote_run)
2660                 return;
2661
2662         // wait for stats to be sent first
2663         if(!playerstats_waitforme)
2664                 return;
2665
2666         MapInfo_Enumerate();
2667         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2668                 mapvote_run = TRUE;
2669 }
2670 void MapVote_Think()
2671 {
2672         if(!mapvote_run)
2673                 return;
2674
2675         if(alreadychangedlevel)
2676                 return;
2677
2678         if(time < mapvote_nextthink)
2679                 return;
2680         //dprint("tick\n");
2681
2682         mapvote_nextthink = time + 0.5;
2683
2684         if(!mapvote_initialized)
2685         {
2686                 if(autocvar_rescan_pending == 1)
2687                 {
2688                         cvar_set("rescan_pending", "2");
2689                         localcmd("fs_rescan\nrescan_pending 3\n");
2690                         return;
2691                 }
2692                 else if(autocvar_rescan_pending == 2)
2693                 {
2694                         return;
2695                 }
2696                 else if(autocvar_rescan_pending == 3)
2697                 {
2698                         // now build missing mapinfo files
2699                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2700                                 return;
2701
2702                         // we're done, start the timer
2703                         cvar_set("rescan_pending", "0");
2704                 }
2705
2706                 mapvote_initialized = TRUE;
2707                 if(DoNextMapOverride(0))
2708                         return;
2709                 if(!autocvar_g_maplist_votable || player_count <= 0)
2710                 {
2711                         GotoNextMap(0);
2712                         return;
2713                 }
2714                 MapVote_Init();
2715         }
2716
2717         MapVote_Tick();
2718 }
2719
2720 string GotoMap(string m)
2721 {
2722         if(!MapInfo_CheckMap(m))
2723                 return "The map you chose is not available on this server.";
2724         cvar_set("nextmap", m);
2725         cvar_set("timelimit", "-1");
2726         if(mapvote_initialized || alreadychangedlevel)
2727         {
2728                 if(DoNextMapOverride(0))
2729                         return "Map switch initiated.";
2730                 else
2731                         return "Hm... no. For some reason I like THIS map more.";
2732         }
2733         else
2734                 return "Map switch will happen after scoreboard.";
2735 }
2736
2737
2738 void EndFrame()
2739 {
2740         float altime;
2741         FOR_EACH_REALCLIENT(self)
2742         {
2743                 if(IS_SPEC(self))
2744                 {
2745                         if(self.enemy.typehitsound)
2746                                 self.typehit_time = time;
2747                         else if(self.enemy.hitsound)
2748                                 self.hit_time = time;
2749                 }
2750                 else
2751                 {
2752                         if(self.typehitsound)
2753                                 self.typehit_time = time;
2754                         else if(self.hitsound)
2755                                 self.hit_time = time;
2756                 }
2757         }
2758         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2759         // add 1 frametime because after this, engine SV_Physics
2760         // increases time by a frametime and then networks the frame
2761         // add another frametime because client shows everything with
2762         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2763         // needed!
2764         FOR_EACH_CLIENT(self)
2765         {
2766                 self.hitsound = FALSE;
2767                 self.typehitsound = FALSE;
2768                 antilag_record(self, altime);
2769         }
2770 }
2771
2772
2773 /*
2774  * RedirectionThink:
2775  * returns TRUE if redirecting
2776  */
2777 float redirection_timeout;
2778 float redirection_nextthink;
2779 float RedirectionThink()
2780 {
2781         float clients_found;
2782
2783         if(redirection_target == "")
2784                 return FALSE;
2785
2786         if(!redirection_timeout)
2787         {
2788                 cvar_set("sv_public", "-2");
2789                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2790                 if(redirection_target == "self")
2791                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2792                 else
2793                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2794         }
2795
2796         if(time < redirection_nextthink)
2797                 return TRUE;
2798
2799         redirection_nextthink = time + 1;
2800
2801         clients_found = 0;
2802         FOR_EACH_REALCLIENT(self)
2803         {
2804                 // TODO add timer
2805                 print("Redirecting: sending connect command to ", self.netname, "\n");
2806                 if(redirection_target == "self")
2807                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2808                 else
2809                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2810                 ++clients_found;
2811         }
2812
2813         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2814
2815         if(time > redirection_timeout || clients_found == 0)
2816                 localcmd("\nwait; wait; wait; quit\n");
2817
2818         return TRUE;
2819 }
2820
2821 void TargetMusic_RestoreGame();
2822 void RestoreGame()
2823 {
2824         // Loaded from a save game
2825         // some things then break, so let's work around them...
2826
2827         // Progs DB (capture records)
2828         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2829
2830         // Mapinfo
2831         MapInfo_Shutdown();
2832         MapInfo_Enumerate();
2833         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2834         WeaponStats_Init();
2835
2836         TargetMusic_RestoreGame();
2837 }
2838
2839 void Shutdown()
2840 {
2841         entity e;
2842
2843         gameover = 2;
2844
2845         if(world_initialized > 0)
2846         {
2847                 world_initialized = 0;
2848                 print("Saving persistent data...\n");
2849                 Ban_SaveBans();
2850
2851                 PlayerStats_EndMatch(0);
2852                 FOR_EACH_CLIENT(e)
2853                         PlayerStats_AddGlobalInfo(e);
2854                 PlayerStats_Shutdown();
2855
2856                 if(!cheatcount_total)
2857                 {
2858                         if(autocvar_sv_db_saveasdump)
2859                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2860                         else
2861                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2862                 }
2863                 if(autocvar_developer)
2864                 {
2865                         if(autocvar_sv_db_saveasdump)
2866                                 db_dump(TemporaryDB, "server-temp.db");
2867                         else
2868                                 db_save(TemporaryDB, "server-temp.db");
2869                 }
2870                 CheatShutdown(); // must be after cheatcount check
2871                 db_close(ServerProgsDB);
2872                 db_close(TemporaryDB);
2873                 print("done!\n");
2874                 // tell the bot system the game is ending now
2875                 bot_endgame();
2876
2877                 WeaponStats_Shutdown();
2878                 MapInfo_Shutdown();
2879         }
2880         else if(world_initialized == 0)
2881         {
2882                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2883         }
2884 }