qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405
 406                 // allowed changes to server admins (please sync this to server.cfg)
 407                 // vi commands:
 408                 //   :/"impure"/,$d
 409                 //   :g!,^\/\/[^ /],d
 410                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 411                 //   :%!sort
 412                 // yes, this does contain some redundant stuff, don't really care
 413                 BADCVAR("bot_config_file");
 414                 BADCVAR("bot_number");
 415                 BADCVAR("bot_prefix");
 416                 BADCVAR("bot_suffix");
 417                 BADCVAR("capturelimit_override");
 418                 BADCVAR("fraglimit_override");
 419                 BADCVAR("gametype");
 420                 BADCVAR("g_antilag");
 421                 BADCVAR("g_balance_teams");
 422                 BADCVAR("g_balance_teams_force");
 423                 BADCVAR("g_ban_sync_trusted_servers");
 424                 BADCVAR("g_ban_sync_uri");
 425                 BADCVAR("g_ctf_capture_limit");
 426                 BADCVAR("g_ctf_ignore_frags");
 427                 BADCVAR("g_ctf_win_mode");
 428                 BADCVAR("g_domination_point_limit");
 429                 BADCVAR("g_friendlyfire");
 430                 BADCVAR("g_fullbrightitems");
 431                 BADCVAR("g_fullbrightplayers");
 432                 BADCVAR("g_keyhunt_point_limit");
 433                 BADCVAR("g_keyhunt_teams_override");
 434                 BADCVAR("g_lms_lives_override");
 435                 BADCVAR("g_maplist");
 436                 BADCVAR("g_maplist_check_waypoints");
 437                 BADCVAR("g_maplist_mostrecent_count");
 438                 BADCVAR("g_maplist_shuffle");
 439                 BADCVAR("g_maplist_votable");
 440                 BADCVAR("g_maplist_votable_abstain");
 441                 BADCVAR("g_maplist_votable_nodetail");
 442                 BADCVAR("g_maplist_votable_suggestions");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("g_minstagib");
 445                 BADCVAR("g_mirrordamage");
 446                 BADCVAR("g_nexball_goallimit");
 447                 BADCVAR("g_powerups");
 448                 BADCVAR("g_runematch_point_limit");
 449                 BADCVAR("g_start_delay");
 450                 BADCVAR("g_warmup");
 451                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 452                 BADCVAR("hostname");
 453                 BADCVAR("log_file");
 454                 BADCVAR("maxplayers");
 455                 BADCVAR("minplayers");
 456                 BADCVAR("net_address");
 457                 BADCVAR("port");
 458                 BADCVAR("rcon_password");
 459                 BADCVAR("rcon_restricted_commands");
 460                 BADCVAR("rcon_restricted_password");
 461                 BADCVAR("skill");
 462                 BADCVAR("sv_adminnick");
 463                 BADCVAR("sv_autoscreenshot");
 464                 BADCVAR("sv_autotaunt");
 465                 BADCVAR("sv_curl_defaulturl");
 466                 BADCVAR("sv_defaultcharacter");
 467                 BADCVAR("sv_defaultplayercolors");
 468                 BADCVAR("sv_defaultplayermodel");
 469                 BADCVAR("sv_defaultplayerskin");
 470                 BADCVAR("sv_maxidle");
 471                 BADCVAR("sv_maxrate");
 472                 BADCVAR("sv_motd");
 473                 BADCVAR("sv_public");
 474                 BADCVAR("sv_ready_restart");
 475                 BADCVAR("sv_status_privacy");
 476                 BADCVAR("sv_taunt");
 477                 BADCVAR("sv_vote_call");
 478                 BADCVAR("sv_vote_commands");
 479                 BADCVAR("sv_vote_majority_factor");
 480                 BADCVAR("sv_vote_master");
 481                 BADCVAR("sv_vote_master_commands");
 482                 BADCVAR("sv_vote_master_password");
 483                 BADCVAR("sv_vote_simple_majority_factor");
 484                 BADCVAR("sys_ticrate");
 485                 BADCVAR("teamplay_mode");
 486                 BADCVAR("timelimit_override");
 487                 BADPREFIX("g_warmup_");
 488                 BADPREFIX("sv_ready_restart_");
 489
 490                 if(autocvar_g_minstagib)
 491                 {
 492                         BADCVAR("g_grappling_hook");
 493                         BADCVAR("g_jetpack");
 494                 }
 495 #undef BADPREFIX
 496 #undef BADCVAR
 497
 498                 if(pureadding)
 499                 {
 500                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 501                         if(strlen(cvar_purechanges) > 16384)
 502                         {
 503                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 504                                 pureadding = 0;
 505                         }
 506                 }
 507                 ++cvar_purechanges_count;
 508                 // WARNING: this variable is used for the server list
 509                 // NEVER dare to skip this code!
 510                 // Hacks to intentionally appearing as "pure server" even though you DO have
 511                 // modified settings may be punished by removal from the server list.
 512                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 513                 // though.
 514         }
 515         buf_del(h);
 516         if(cvar_changes == "")
 517                 cvar_changes = "// this server runs at default server settings\n";
 518         else
 519                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 520         cvar_changes = strzone(cvar_changes);
 521         if(cvar_purechanges == "")
 522                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 523         else
 524                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 525         cvar_purechanges = strzone(cvar_purechanges);
 526 }
 527
 528 void detect_maptype()
 529 {
 530 #if 0
 531         vector o, v;
 532         float i;
 533
 534         for(;;)
 535         {
 536                 o = world.mins;
 537                 o_x += random() * (world.maxs_x - world.mins_x);
 538                 o_y += random() * (world.maxs_y - world.mins_y);
 539                 o_z += random() * (world.maxs_z - world.mins_z);
 540
 541                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 542                 if(trace_fraction == 1)
 543                         continue;
 544
 545                 v = trace_endpos;
 546
 547                 for(i = 0; i < 64; i += 4)
 548                 {
 549                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 550         if(trace_fraction == 1)
 551                 continue;
 552                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 553                 }
 554
 555                 break;
 556         }
 557 #endif
 558 }
 559
 560 entity randomseed;
 561 float RandomSeed_Send(entity to, float sf)
 562 {
 563         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 564         WriteShort(MSG_ENTITY, self.cnt);
 565         return TRUE;
 566 }
 567 void RandomSeed_Think()
 568 {
 569         self.cnt = bound(0, floor(random() * 65536), 65535);
 570         self.nextthink = time + 5;
 571
 572         self.SendFlags |= 1;
 573 }
 574 void RandomSeed_Spawn()
 575 {
 576         randomseed = spawn();
 577         randomseed.think = RandomSeed_Think;
 578         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 579
 580         entity oldself;
 581         oldself = self;
 582         self = randomseed;
 583         self.think(); // sets random seed and nextthink
 584         self = oldself;
 585 }
 586
 587 void spawnfunc___init_dedicated_server(void)
 588 {
 589         // handler for _init/_init map (only for dedicated server initialization)
 590
 591         world_initialized = -1; // don't complain
 592         cvar = cvar_normal;
 593         cvar_string = cvar_string_normal;
 594         cvar_set = cvar_set_normal;
 595
 596         remove = remove_unsafely;
 597
 598         entity e;
 599         e = spawn();
 600         e.think = GotoFirstMap;
 601         e.nextthink = time; // this is usually 1 at this point
 602
 603         e = spawn();
 604         e.classname = "info_player_deathmatch"; // safeguard against player joining
 605
 606         self.classname = "worldspawn"; // safeguard against various stuff ;)
 607
 608         MapInfo_Enumerate();
 609         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 610 }
 611
 612 void Map_MarkAsRecent(string m);
 613 float world_already_spawned;
 614 void RegisterWeapons();
 615 void Nagger_Init();
 616 void ClientInit_Spawn();
 617 void WeaponStats_Init();
 618 void WeaponStats_Shutdown();
 619 void spawnfunc_worldspawn (void)
 620 {
 621         float fd, l, i, j, n;
 622         string s, col;
 623
 624         cvar = cvar_normal;
 625         cvar_string = cvar_string_normal;
 626         cvar_set = cvar_set_normal;
 627
 628         if(world_already_spawned)
 629                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 630         world_already_spawned = TRUE;
 631
 632         remove = remove_safely; // during spawning, watch what you remove!
 633
 634         check_unacceptable_compiler_bugs();
 635
 636         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 637
 638         compressShortVector_init();
 639
 640         allowed_to_spawn = TRUE;
 641
 642         entity head;
 643         head = nextent(world);
 644         maxclients = 0;
 645         while(head)
 646         {
 647                 ++maxclients;
 648                 head = nextent(head);
 649         }
 650
 651         // needs to be done so early as they would still spawn
 652         RegisterWeapons();
 653
 654         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 655
 656         TemporaryDB = db_create();
 657
 658         // 0 normal
 659         lightstyle(0, "m");
 660
 661         // 1 FLICKER (first variety)
 662         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 663
 664         // 2 SLOW STRONG PULSE
 665         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 666
 667         // 3 CANDLE (first variety)
 668         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 669
 670         // 4 FAST STROBE
 671         lightstyle(4, "mamamamamama");
 672
 673         // 5 GENTLE PULSE 1
 674         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 675
 676         // 6 FLICKER (second variety)
 677         lightstyle(6, "nmonqnmomnmomomno");
 678
 679         // 7 CANDLE (second variety)
 680         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 681
 682         // 8 CANDLE (third variety)
 683         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 684
 685         // 9 SLOW STROBE (fourth variety)
 686         lightstyle(9, "aaaaaaaazzzzzzzz");
 687
 688         // 10 FLUORESCENT FLICKER
 689         lightstyle(10, "mmamammmmammamamaaamammma");
 690
 691         // 11 SLOW PULSE NOT FADE TO BLACK
 692         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 693
 694         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 695
 696         // 63 testing
 697         lightstyle(63, "a");
 698
 699         if(autocvar_g_campaign)
 700                 CampaignPreInit();
 701
 702         Map_MarkAsRecent(mapname);
 703
 704         precache_model ("null"); // we need this one before InitGameplayMode
 705         InitGameplayMode();
 706         readlevelcvars();
 707         GrappleHookInit();
 708         ElectroInit();
 709         LaserInit();
 710
 711         player_count = 0;
 712         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 713         if(bot_waypoints_for_items == 1)
 714                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 715                         bot_waypoints_for_items = 0;
 716
 717         precache();
 718
 719         WaypointSprite_Init();
 720
 721         //if (g_domination)
 722         //      dom_init();
 723
 724         GameLogInit(); // prepare everything
 725         // NOTE for matchid:
 726         // changing the logic generating it is okay. But:
 727         // it HAS to stay <= 64 chars
 728         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 729         if(autocvar_sv_eventlog)
 730         {
 731                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 732                 matchid = strzone(s);
 733
 734                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 735                 s = ":gameinfo:mutators:LIST";
 736
 737                 ret_string = s;
 738                 MUTATOR_CALLHOOK(BuildMutatorsString);
 739                 s = ret_string;
 740
 741                 // simple, probably not good in the mutator system
 742                 if(autocvar_g_grappling_hook)
 743                         s = strcat(s, ":grappling_hook");
 744
 745                 // initialiation stuff, not good in the mutator system
 746                 if(!autocvar_g_use_ammunition)
 747                         s = strcat(s, ":no_use_ammunition");
 748
 749                 // initialiation stuff, not good in the mutator system
 750                 if(!autocvar_g_pickup_items)
 751                         s = strcat(s, ":no_pickup_items");
 752
 753                 // initialiation stuff, not good in the mutator system
 754                 if(autocvar_g_weaponarena != "0")
 755                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 756
 757                 // TODO to mutator system
 758                 if(autocvar_g_norecoil)
 759                         s = strcat(s, ":norecoil");
 760
 761                 // TODO to mutator system
 762                 if(autocvar_g_midair)
 763                         s = strcat(s, ":midair");
 764
 765                 // TODO to mutator system
 766                 if(autocvar_g_minstagib)
 767                         s = strcat(s, ":minstagib");
 768
 769                 // TODO to mutator system
 770                 if(!autocvar_g_powerups)
 771                         s = strcat(s, ":no_powerups");
 772
 773                 GameLogEcho(s);
 774                 GameLogEcho(":gameinfo:end");
 775         }
 776         else
 777                 matchid = strzone(ftos(random()));
 778
 779         cvar_set("nextmap", "");
 780
 781         SetDefaultAlpha();
 782
 783         if(autocvar_g_campaign)
 784                 CampaignPostInit();
 785
 786         fteqcc_testbugs();
 787
 788         Ban_LoadBans();
 789
 790         MapInfo_Enumerate();
 791         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 792
 793         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 794         {
 795                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 796                 if(fd != -1)
 797                 {
 798                         while((s = fgets(fd)))
 799                         {
 800                                 l = tokenize_console(s);
 801                                 if(l < 2)
 802                                         continue;
 803                                 if(argv(0) == "cd")
 804                                 {
 805                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 806                                         print("  cdtrack ", argv(2), "\n");
 807                                 }
 808                                 else if(argv(0) == "fog")
 809                                 {
 810                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 811                                         print("  \"fog\" \"", s, "\"\n");
 812                                 }
 813                                 else if(argv(0) == "set")
 814                                 {
 815                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 816                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 817                                 }
 818                                 else if(argv(0) != "//")
 819                                 {
 820                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 821                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 822                                 }
 823                         }
 824                         fclose(fd);
 825                 }
 826         }
 827
 828         WeaponStats_Init();
 829
 830         addstat(STAT_WEAPONS, AS_INT, weapons);
 831         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 832         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 833         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 834         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 835         Nagger_Init();
 836
 837         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 838         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 839         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 840         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 841         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 842         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 843         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 844         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 845         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 846         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 847         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 848         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 849
 850         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 851         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 852
 853         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 854
 855         if(g_ca || g_freezetag)
 856         {
 857                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 858                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 859                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 860                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 861         }
 862         if(g_freezetag)
 863         {
 864                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 865                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 866         }
 867
 868         // g_movementspeed hack
 869         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 870         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 871         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 872         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 873
 874         // secrets
 875         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 876         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 877
 878         next_pingtime = time + 5;
 879
 880         detect_maptype();
 881
 882         lsmaps_reply = "^7Maps available: ";
 883         lsnewmaps_reply = "^7Maps without a record set: ";
 884         for(i = 0, j = 0; i < MapInfo_count; ++i)
 885         {
 886                 if(MapInfo_Get_ByID(i))
 887                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 888                         {
 889                                 if(mod(i, 2))
 890                                         col = "^2";
 891                                 else
 892                                         col = "^3";
 893                                 ++j;
 894                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 895                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 896                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 897                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 898                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 899                         }
 900         }
 901         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 902         if (!g_race && !g_cts)
 903                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 904         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 905
 906         maplist_reply = "^7Maps in list: ";
 907         n = tokenize_console(autocvar_g_maplist);
 908         for(i = 0, j = 0; i < n; ++i)
 909         {
 910                 if(MapInfo_CheckMap(argv(i)))
 911                 {
 912                         if(mod(j, 2))
 913                                 col = "^2";
 914                         else
 915                                 col = "^3";
 916                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 917                         ++j;
 918                 }
 919         }
 920         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 921         MapInfo_ClearTemps();
 922
 923         for(i = 0; i < 10; ++i)
 924         {
 925                 records_reply[i] = strzone(getrecords(i));
 926         }
 927         if(g_cts)
 928                 ladder_reply = strzone(getladder());
 929
 930         rankings_reply = strzone(getrankings());
 931
 932         ClientInit_Spawn();
 933         RandomSeed_Spawn();
 934         PingPLReport_Spawn();
 935
 936         CheatInit();
 937
 938         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 939
 940         // fill sv_curl_serverpackages from .serverpackage files
 941         if(autocvar_sv_curl_serverpackages_auto)
 942         {
 943                 s = "";
 944                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 945                 for(i = 0; i < n; ++i)
 946                         if(substring(argv(i), -14, -1) != ".serverpackage")
 947                                 s = strcat(s, " ", argv(i));
 948                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 949                 if(fd >= 0)
 950                 {
 951                         j = search_getsize(fd);
 952                         for(i = 0; i < j; ++i)
 953                                 s = strcat(s, " ", search_getfilename(fd, i));
 954                         search_end(fd);
 955                 }
 956                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 957         }
 958
 959         PlayerStats_Init();
 960
 961         world_initialized = 1;
 962 }
 963
 964 void spawnfunc_light (void)
 965 {
 966         //makestatic (self); // Who the f___ did that?
 967         remove(self);
 968 }
 969
 970 string GetGametype()
 971 {
 972         return GametypeNameFromType(game);
 973 }
 974
 975 string getmapname_stored;
 976 string GetMapname()
 977 {
 978         return mapname;
 979 }
 980
 981 float Map_Count, Map_Current;
 982 string Map_Current_Name;
 983
 984 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 985 float GetMaplistPosition()
 986 {
 987         float pos, idx;
 988         string map;
 989
 990         map = GetMapname();
 991         idx = autocvar_g_maplist_index;
 992
 993         if(idx >= 0)
 994                 if(idx < Map_Count)
 995                         if(map == argv(idx))
 996                                 return idx;
 997
 998         for(pos = 0; pos < Map_Count; ++pos)
 999                 if(map == argv(pos))
1000                         return pos;
1001
1002         // resume normal maplist rotation if current map is not in g_maplist
1003         return idx;
1004 }
1005
1006 float MapHasRightSize(string map)
1007 {
1008         float fh;
1009         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1010         if(autocvar_g_maplist_check_waypoints)
1011         {
1012                 dprint("checkwp "); dprint(map);
1013                 if(!fexists(strcat("maps/", map, ".waypoints")))
1014                 {
1015                         dprint(": no waypoints\n");
1016                         return FALSE;
1017                 }
1018                 dprint(": has waypoints\n");
1019         }
1020
1021         // open map size restriction file
1022         dprint("opensize "); dprint(map);
1023         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1024         if(fh >= 0)
1025         {
1026                 float mapmin, mapmax;
1027                 dprint(": ok, ");
1028                 mapmin = stof(fgets(fh));
1029                 mapmax = stof(fgets(fh));
1030                 fclose(fh);
1031                 if(player_count < mapmin)
1032                 {
1033                         dprint("not enough\n");
1034                         return FALSE;
1035                 }
1036                 if(player_count > mapmax)
1037                 {
1038                         dprint("too many\n");
1039                         return FALSE;
1040                 }
1041                 dprint("right size\n");
1042                 return TRUE;
1043         }
1044         dprint(": not found\n");
1045         return TRUE;
1046 }
1047
1048 string Map_Filename(float position)
1049 {
1050         return strcat("maps/", argv(position), ".bsp");
1051 }
1052
1053 string strwords(string s, float w)
1054 {
1055         float endpos;
1056         for(endpos = 0; w && endpos >= 0; --w)
1057                 endpos = strstrofs(s, " ", endpos + 1);
1058         if(endpos < 0)
1059                 return s;
1060         else
1061                 return substring(s, 0, endpos);
1062 }
1063
1064 float strhasword(string s, string w)
1065 {
1066         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1067 }
1068
1069 void Map_MarkAsRecent(string m)
1070 {
1071         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1072 }
1073
1074 float Map_IsRecent(string m)
1075 {
1076         return strhasword(autocvar_g_maplist_mostrecent, m);
1077 }
1078
1079 float Map_Check(float position, float pass)
1080 {
1081         string filename;
1082         string map_next;
1083         map_next = argv(position);
1084         if(pass <= 1)
1085         {
1086                 if(Map_IsRecent(map_next))
1087                         return 0;
1088         }
1089         filename = Map_Filename(position);
1090         if(MapInfo_CheckMap(map_next))
1091         {
1092                 if(pass == 2)
1093                         return 1;
1094                 if(MapHasRightSize(map_next))
1095                         return 1;
1096                 return 0;
1097         }
1098         else
1099                 dprint( "Couldn't select '", filename, "'..\n" );
1100
1101         return 0;
1102 }
1103
1104 void Map_Goto_SetStr(string nextmapname)
1105 {
1106         if(getmapname_stored != "")
1107                 strunzone(getmapname_stored);
1108         if(nextmapname == "")
1109                 getmapname_stored = "";
1110         else
1111                 getmapname_stored = strzone(nextmapname);
1112 }
1113
1114 void Map_Goto_SetFloat(float position)
1115 {
1116         cvar_set("g_maplist_index", ftos(position));
1117         Map_Goto_SetStr(argv(position));
1118 }
1119
1120 void GameResetCfg()
1121 {
1122         // settings persist, except...
1123         localcmd("\nsettemp_restore\n");
1124 }
1125
1126 void Map_Goto()
1127 {
1128         GameResetCfg();
1129         MapInfo_LoadMap(getmapname_stored);
1130 }
1131
1132 // return codes of map selectors:
1133 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1134 //   -2 = permanent failure
1135 float() MaplistMethod_Iterate = // usual method
1136 {
1137         float pass, i;
1138
1139         for(pass = 1; pass <= 2; ++pass)
1140         {
1141                 for(i = 1; i < Map_Count; ++i)
1142                 {
1143                         float mapindex;
1144                         mapindex = mod(i + Map_Current, Map_Count);
1145                         if(Map_Check(mapindex, pass))
1146                                 return mapindex;
1147                 }
1148         }
1149         return -1;
1150 }
1151
1152 float() MaplistMethod_Repeat = // fallback method
1153 {
1154         if(Map_Check(Map_Current, 2))
1155                 return Map_Current;
1156         return -2;
1157 }
1158
1159 float() MaplistMethod_Random = // random map selection
1160 {
1161         float i, imax;
1162
1163         imax = 42;
1164
1165         for(i = 0; i <= imax; ++i)
1166         {
1167                 float mapindex;
1168                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1169                 if(Map_Check(mapindex, 1))
1170                         return mapindex;
1171         }
1172         return -1;
1173 }
1174
1175 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1176 // the exponent sets a bias on the map selection:
1177 // the higher the exponent, the less likely "shortly repeated" same maps are
1178 {
1179         float i, j, imax, insertpos;
1180
1181         imax = 42;
1182
1183         for(i = 0; i <= imax; ++i)
1184         {
1185                 string newlist;
1186
1187                 // now reinsert this at another position
1188                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1189                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1190                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1191                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1192
1193                 // insert the current map there
1194                 newlist = "";
1195                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1196                         newlist = strcat(newlist, " ", argv(j));
1197                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1198                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1199                         newlist = strcat(newlist, " ", argv(j));
1200                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1201                 cvar_set("g_maplist", newlist);
1202                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1203
1204                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1205                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1206                 if(Map_Check(Map_Current, 1))
1207                         return Map_Current;
1208         }
1209         return -1;
1210 }
1211
1212 void Maplist_Init()
1213 {
1214         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1215         if(Map_Count == 0)
1216         {
1217                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1218                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1219                 if(autocvar_g_maplist_shuffle)
1220                         ShuffleMaplist();
1221                 localcmd("\nmenu_cmd sync\n");
1222                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1223         }
1224         if(Map_Count == 0)
1225                 error("empty maplist, cannot select a new map");
1226         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1227
1228         if(Map_Current_Name)
1229                 strunzone(Map_Current_Name);
1230         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1231         // this may or may not be correct, but who cares, in the worst case a map
1232         // isn't chosen in the first pass that should have been
1233 }
1234
1235 string GetNextMap()
1236 {
1237         float nextMap;
1238
1239         Maplist_Init();
1240         nextMap = -1;
1241
1242         if(nextMap == -1)
1243                 if(autocvar_g_maplist_shuffle > 0)
1244                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1245
1246         if(nextMap == -1)
1247                 if(autocvar_g_maplist_selectrandom)
1248                         nextMap = MaplistMethod_Random();
1249
1250         if(nextMap == -1)
1251                 nextMap = MaplistMethod_Iterate();
1252
1253         if(nextMap == -1)
1254                 nextMap = MaplistMethod_Repeat();
1255
1256         if(nextMap >= 0)
1257         {
1258                 Map_Goto_SetFloat(nextMap);
1259                 return getmapname_stored;
1260         }
1261
1262         return "";
1263 }
1264
1265 float DoNextMapOverride()
1266 {
1267         if(autocvar_g_campaign)
1268         {
1269                 CampaignPostIntermission();
1270                 alreadychangedlevel = TRUE;
1271                 return TRUE;
1272         }
1273         if(autocvar_quit_when_empty)
1274         {
1275                 if(player_count <= currentbots)
1276                 {
1277                         localcmd("quit\n");
1278                         alreadychangedlevel = TRUE;
1279                         return TRUE;
1280                 }
1281         }
1282         if(autocvar_quit_and_redirect != "")
1283         {
1284                 redirection_target = strzone(autocvar_quit_and_redirect);
1285                 alreadychangedlevel = TRUE;
1286                 return TRUE;
1287         }
1288         if (autocvar_samelevel) // if samelevel is set, stay on same level
1289         {
1290                 localcmd("restart\n");
1291                 alreadychangedlevel = TRUE;
1292                 return TRUE;
1293         }
1294         if(autocvar_nextmap != "")
1295                 if(MapInfo_CheckMap(autocvar_nextmap))
1296                 {
1297                         Map_Goto_SetStr(autocvar_nextmap);
1298                         Map_Goto();
1299                         alreadychangedlevel = TRUE;
1300                         return TRUE;
1301                 }
1302         if(autocvar_lastlevel)
1303         {
1304                 GameResetCfg();
1305                 localcmd("set lastlevel 0\ntogglemenu\n");
1306                 alreadychangedlevel = TRUE;
1307                 return TRUE;
1308         }
1309         return FALSE;
1310 }
1311
1312 void GotoNextMap()
1313 {
1314         //string nextmap;
1315         //float n, nummaps;
1316         //string s;
1317         if (alreadychangedlevel)
1318                 return;
1319         alreadychangedlevel = TRUE;
1320
1321         {
1322                 string nextMap;
1323                 float allowReset;
1324
1325                 for(allowReset = 1; allowReset >= 0; --allowReset)
1326                 {
1327                         nextMap = GetNextMap();
1328                         if(nextMap != "")
1329                                 break;
1330
1331                         if(allowReset)
1332                         {
1333                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1334                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1335                                 if(autocvar_g_maplist_shuffle)
1336                                         ShuffleMaplist();
1337                                 localcmd("\nmenu_cmd sync\n");
1338                         }
1339                         else
1340                         {
1341                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1342                         }
1343                 }
1344                 Map_Goto();
1345         }
1346 }
1347
1348
1349 /*
1350 ============
1351 IntermissionThink
1352
1353 When the player presses attack or jump, change to the next level
1354 ============
1355 */
1356 .float autoscreenshot;
1357 void() MapVote_Start;
1358 void() MapVote_Think;
1359 float mapvote_initialized;
1360 void IntermissionThink()
1361 {
1362         FixIntermissionClient(self);
1363
1364         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1365                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1366         {
1367                 self.autoscreenshot = -1;
1368                 if(clienttype(self) == CLIENTTYPE_REAL)
1369                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1370                 return;
1371         }
1372
1373         if (time < intermission_exittime)
1374                 return;
1375
1376         if(!mapvote_initialized)
1377                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1378                         return;
1379
1380         MapVote_Start();
1381 }
1382
1383 /*
1384 ============
1385 FindIntermission
1386
1387 Returns the entity to view from
1388 ============
1389 */
1390 /*
1391 entity FindIntermission()
1392 {
1393         local   entity spot;
1394         local   float cyc;
1395
1396 // look for info_intermission first
1397         spot = find (world, classname, "info_intermission");
1398         if (spot)
1399         {       // pick a random one
1400                 cyc = random() * 4;
1401                 while (cyc > 1)
1402                 {
1403                         spot = find (spot, classname, "info_intermission");
1404                         if (!spot)
1405                                 spot = find (spot, classname, "info_intermission");
1406                         cyc = cyc - 1;
1407                 }
1408                 return spot;
1409         }
1410
1411 // then look for the start position
1412         spot = find (world, classname, "info_player_start");
1413         if (spot)
1414                 return spot;
1415
1416 // testinfo_player_start is only found in regioned levels
1417         spot = find (world, classname, "testplayerstart");
1418         if (spot)
1419                 return spot;
1420
1421 // then look for the start position
1422         spot = find (world, classname, "info_player_deathmatch");
1423         if (spot)
1424                 return spot;
1425
1426         //objerror ("FindIntermission: no spot");
1427         return world;
1428 }
1429 */
1430
1431 /*
1432 ===============================================================================
1433
1434 RULES
1435
1436 ===============================================================================
1437 */
1438
1439 void DumpStats(float final)
1440 {
1441         float file;
1442         string s;
1443         float to_console;
1444         float to_eventlog;
1445         float to_file;
1446         float i;
1447
1448         to_console = autocvar_sv_logscores_console;
1449         to_eventlog = autocvar_sv_eventlog;
1450         to_file = autocvar_sv_logscores_file;
1451
1452         if(!final)
1453         {
1454                 to_console = TRUE; // always print printstats replies
1455                 to_eventlog = FALSE; // but never print them to the event log
1456         }
1457
1458         if(to_eventlog)
1459                 if(autocvar_sv_eventlog_console)
1460                         to_console = FALSE; // otherwise we get the output twice
1461
1462         if(final)
1463                 s = ":scores:";
1464         else
1465                 s = ":status:";
1466         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1467
1468         if(to_console)
1469                 print(s, "\n");
1470         if(to_eventlog)
1471                 GameLogEcho(s);
1472         if(to_file)
1473         {
1474                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1475                 if(file == -1)
1476                         to_file = FALSE;
1477                 else
1478                         fputs(file, strcat(s, "\n"));
1479         }
1480
1481         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1482         if(to_console)
1483                 print(s, "\n");
1484         if(to_eventlog)
1485                 GameLogEcho(s);
1486         if(to_file)
1487                 fputs(file, strcat(s, "\n"));
1488
1489         FOR_EACH_CLIENT(other)
1490         {
1491                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1492                 {
1493                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1494                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1495                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1496                                 s = strcat(s, ftos(other.team), ":");
1497                         else
1498                                 s = strcat(s, "spectator:");
1499
1500                         if(to_console)
1501                                 print(s, other.netname, "\n");
1502                         if(to_eventlog)
1503                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1504                         if(to_file)
1505                                 fputs(file, strcat(s, other.netname, "\n"));
1506                 }
1507         }
1508
1509         if(teamplay)
1510         {
1511                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1512                 if(to_console)
1513                         print(s, "\n");
1514                 if(to_eventlog)
1515                         GameLogEcho(s);
1516                 if(to_file)
1517                         fputs(file, strcat(s, "\n"));
1518
1519                 for(i = 1; i < 16; ++i)
1520                 {
1521                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1522                         s = strcat(s, ":", ftos(i));
1523                         if(to_console)
1524                                 print(s, "\n");
1525                         if(to_eventlog)
1526                                 GameLogEcho(s);
1527                         if(to_file)
1528                                 fputs(file, strcat(s, "\n"));
1529                 }
1530         }
1531
1532         if(to_console)
1533                 print(":end\n");
1534         if(to_eventlog)
1535                 GameLogEcho(":end");
1536         if(to_file)
1537         {
1538                 fputs(file, ":end\n");
1539                 fclose(file);
1540         }
1541 }
1542
1543 void FixIntermissionClient(entity e)
1544 {
1545         string s;
1546         if(!e.autoscreenshot) // initial call
1547         {
1548                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1549                 e.health = -2342;
1550                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1551                 e.solid = SOLID_NOT;
1552                 e.movetype = MOVETYPE_NONE;
1553                 e.takedamage = DAMAGE_NO;
1554                 if(e.weaponentity)
1555                 {
1556                         e.weaponentity.effects = EF_NODRAW;
1557                         if (e.weaponentity.weaponentity)
1558                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1559                 }
1560                 if(clienttype(e) == CLIENTTYPE_REAL)
1561                 {
1562                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1563                         s = autocvar_sv_intermission_cdtrack;
1564                         if(s != "")
1565                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1566                         msg_entity = e;
1567                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1568                 }
1569         }
1570 }
1571
1572
1573 /*
1574 go to the next level for deathmatch
1575 only called if a time or frag limit has expired
1576 */
1577 void NextLevel()
1578 {
1579         gameover = TRUE;
1580
1581         intermission_running = 1;
1582
1583 // enforce a wait time before allowing changelevel
1584         if(player_count > 0)
1585                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1586         else
1587                 intermission_exittime = -1;
1588
1589         /*
1590         WriteByte (MSG_ALL, SVC_CDTRACK);
1591         WriteByte (MSG_ALL, 3);
1592         WriteByte (MSG_ALL, 3);
1593         // done in FixIntermission
1594         */
1595
1596         //pos = FindIntermission ();
1597
1598         VoteReset();
1599
1600         DumpStats(TRUE);
1601
1602         // send statistics
1603         entity e;
1604         PlayerStats_EndMatch(1);
1605         FOR_EACH_CLIENT(e)
1606                 PlayerStats_AddGlobalInfo(e);
1607         PlayerStats_Shutdown();
1608         WeaponStats_Shutdown();
1609
1610         if(autocvar_sv_eventlog)
1611                 GameLogEcho(":gameover");
1612
1613         GameLogClose();
1614
1615         FOR_EACH_PLAYER(other) {
1616                 FixIntermissionClient(other);
1617                 if(other.winning)
1618                         bprint(other.netname, " ^7wins.\n");
1619         }
1620
1621         if(autocvar_g_campaign)
1622                 CampaignPreIntermission();
1623
1624         localcmd("\nsv_hook_gameend\n");
1625 }
1626
1627 /*
1628 ============
1629 CheckRules_Player
1630
1631 Exit deathmatch games upon conditions
1632 ============
1633 */
1634 void CheckRules_Player()
1635 {
1636         if (gameover)   // someone else quit the game already
1637                 return;
1638
1639         if(self.deadflag == DEAD_NO)
1640                 self.play_time += frametime;
1641
1642         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1643         //   (div0: and that in CheckRules_World please)
1644 }
1645
1646 float checkrules_equality;
1647 float checkrules_suddendeathwarning;
1648 float checkrules_suddendeathend;
1649 float checkrules_overtimesadded; //how many overtimes have been already added
1650
1651 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1652 float WINNING_YES = 1; // winner found
1653 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1654 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1655
1656 float InitiateSuddenDeath()
1657 {
1658         // Check first whether normal overtimes could be added before initiating suddendeath mode
1659         // - for this timelimit_overtime needs to be >0 of course
1660         // - also check the winning condition calculated in the previous frame and only add normal overtime
1661         //   again, if at the point at which timelimit would be extended again, still no winner was found
1662         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1663         {
1664                 return 1; // need to call InitiateOvertime later
1665         }
1666         else
1667         {
1668                 if(!checkrules_suddendeathend)
1669                 {
1670                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1671                         if(g_race && !g_race_qualifying)
1672                                 race_StartCompleting();
1673                 }
1674                 return 0;
1675         }
1676 }
1677
1678 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1679 {
1680         ++checkrules_overtimesadded;
1681         //add one more overtime by simply extending the timelimit
1682         float tl;
1683         tl = autocvar_timelimit;
1684         tl += autocvar_timelimit_overtime;
1685         cvar_set("timelimit", ftos(tl));
1686         string minutesPlural;
1687         if (autocvar_timelimit_overtime == 1)
1688                 minutesPlural = " ^3minute";
1689         else
1690                 minutesPlural = " ^3minutes";
1691
1692         bcenterprint(
1693                 strcat(
1694                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1695                         ftos(autocvar_timelimit_overtime),
1696                         minutesPlural,
1697                         " to the game!"
1698                 )
1699         );
1700 }
1701
1702 float GetWinningCode(float fraglimitreached, float equality)
1703 {
1704         if(autocvar_g_campaign == 1)
1705                 if(fraglimitreached)
1706                         return WINNING_YES;
1707                 else
1708                         return WINNING_NO;
1709
1710         else
1711                 if(equality)
1712                         if(fraglimitreached)
1713                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1714                         else
1715                                 return WINNING_NEVER;
1716                 else
1717                         if(fraglimitreached)
1718                                 return WINNING_YES;
1719                         else
1720                                 return WINNING_NO;
1721 }
1722
1723 // set the .winning flag for exactly those players with a given field value
1724 void SetWinners(.float field, float value)
1725 {
1726         entity head;
1727         FOR_EACH_PLAYER(head)
1728                 head.winning = (head.field == value);
1729 }
1730
1731 // set the .winning flag for those players with a given field value
1732 void AddWinners(.float field, float value)
1733 {
1734         entity head;
1735         FOR_EACH_PLAYER(head)
1736                 if(head.field == value)
1737                         head.winning = 1;
1738 }
1739
1740 // clear the .winning flags
1741 void ClearWinners(void)
1742 {
1743         entity head;
1744         FOR_EACH_PLAYER(head)
1745                 head.winning = 0;
1746 }
1747
1748 // Onslaught winning condition:
1749 // game terminates if only one team has a working generator (or none)
1750 float WinningCondition_Onslaught()
1751 {
1752         entity head;
1753         float t1, t2, t3, t4;
1754
1755         WinningConditionHelper(); // set worldstatus
1756
1757         if(inWarmupStage)
1758                 return WINNING_NO;
1759
1760         // first check if the game has ended
1761         t1 = t2 = t3 = t4 = 0;
1762         head = find(world, classname, "onslaught_generator");
1763         while (head)
1764         {
1765                 if (head.health > 0)
1766                 {
1767                         if (head.team == COLOR_TEAM1) t1 = 1;
1768                         if (head.team == COLOR_TEAM2) t2 = 1;
1769                         if (head.team == COLOR_TEAM3) t3 = 1;
1770                         if (head.team == COLOR_TEAM4) t4 = 1;
1771                 }
1772                 head = find(head, classname, "onslaught_generator");
1773         }
1774         if (t1 + t2 + t3 + t4 < 2)
1775         {
1776                 // game over, only one team remains (or none)
1777                 ClearWinners();
1778                 if (t1) SetWinners(team, COLOR_TEAM1);
1779                 if (t2) SetWinners(team, COLOR_TEAM2);
1780                 if (t3) SetWinners(team, COLOR_TEAM3);
1781                 if (t4) SetWinners(team, COLOR_TEAM4);
1782                 dprint("Have a winner, ending game.\n");
1783                 return WINNING_YES;
1784         }
1785
1786         // Two or more teams remain
1787         return WINNING_NO;
1788 }
1789
1790 float LMS_NewPlayerLives()
1791 {
1792         float fl;
1793         fl = autocvar_fraglimit;
1794         if(fl == 0)
1795                 fl = 999;
1796
1797         // first player has left the game for dying too much? Nobody else can get in.
1798         if(lms_lowest_lives < 1)
1799                 return 0;
1800
1801         if(!autocvar_g_lms_join_anytime)
1802                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1803                         return 0;
1804
1805         return bound(1, lms_lowest_lives, fl);
1806 }
1807
1808 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1809 // they win. Otherwise the defending team wins once the timelimit passes.
1810 void assault_new_round();
1811 float WinningCondition_Assault()
1812 {
1813         float status;
1814
1815         WinningConditionHelper(); // set worldstatus
1816
1817         status = WINNING_NO;
1818         // as the timelimit has not yet passed just assume the defending team will win
1819         if(assault_attacker_team == COLOR_TEAM1)
1820         {
1821                 SetWinners(team, COLOR_TEAM2);
1822         }
1823         else
1824         {
1825                 SetWinners(team, COLOR_TEAM1);
1826         }
1827
1828         entity ent;
1829         ent = find(world, classname, "target_assault_roundend");
1830         if(ent)
1831         {
1832                 if(ent.winning) // round end has been triggered by attacking team
1833                 {
1834                         bprint("ASSAULT: round completed...\n");
1835                         SetWinners(team, assault_attacker_team);
1836
1837                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1838
1839                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1840                         {
1841                                 status = WINNING_YES;
1842                         }
1843                         else
1844                         {
1845                                 entity oldself;
1846                                 oldself = self;
1847                                 self = ent;
1848                                 assault_new_round();
1849                                 self = oldself;
1850                         }
1851                 }
1852         }
1853
1854         return status;
1855 }
1856
1857 // LMS winning condition: game terminates if and only if there's at most one
1858 // one player who's living lives. Top two scores being equal cancels the time
1859 // limit.
1860 float WinningCondition_LMS()
1861 {
1862         entity head, head2;
1863         float have_player;
1864         float have_players;
1865         float l;
1866
1867         have_player = FALSE;
1868         have_players = FALSE;
1869         l = LMS_NewPlayerLives();
1870
1871         head = find(world, classname, "player");
1872         if(head)
1873                 have_player = TRUE;
1874         head2 = find(head, classname, "player");
1875         if(head2)
1876                 have_players = TRUE;
1877
1878         if(have_player)
1879         {
1880                 // we have at least one player
1881                 if(have_players)
1882                 {
1883                         // two or more active players - continue with the game
1884                 }
1885                 else
1886                 {
1887                         // exactly one player?
1888
1889                         ClearWinners();
1890                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1891
1892                         if(l)
1893                         {
1894                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1895                                 return WINNING_NO;
1896                         }
1897                         else
1898                         {
1899                                 // a winner!
1900                                 // and assign him his first place
1901                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1902                                 return WINNING_YES;
1903                         }
1904                 }
1905         }
1906         else
1907         {
1908                 // nobody is playing at all...
1909                 if(l)
1910                 {
1911                         // wait for players...
1912                 }
1913                 else
1914                 {
1915                         // SNAFU (maybe a draw game?)
1916                         ClearWinners();
1917                         dprint("No players, ending game.\n");
1918                         return WINNING_YES;
1919                 }
1920         }
1921
1922         // When we get here, we have at least two players who are actually LIVING,
1923         // now check if the top two players have equal score.
1924         WinningConditionHelper();
1925
1926         ClearWinners();
1927         if(WinningConditionHelper_winner)
1928                 WinningConditionHelper_winner.winning = TRUE;
1929         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1930                 return WINNING_NEVER;
1931
1932         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1933         return WINNING_NO;
1934 }
1935
1936 void ShuffleMaplist()
1937 {
1938         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1939 }
1940
1941 float leaderfrags;
1942 float WinningCondition_Scores(float limit, float leadlimit)
1943 {
1944         float limitreached;
1945
1946         // TODO make everything use THIS winning condition (except LMS)
1947         WinningConditionHelper();
1948
1949         if(teamplay)
1950         {
1951                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1952                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1953                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1954                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1955         }
1956
1957         ClearWinners();
1958         if(WinningConditionHelper_winner)
1959                 WinningConditionHelper_winner.winning = 1;
1960         if(WinningConditionHelper_winnerteam >= 0)
1961                 SetWinners(team, WinningConditionHelper_winnerteam);
1962
1963         if(WinningConditionHelper_lowerisbetter)
1964         {
1965                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1966                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1967                 limit = -limit;
1968         }
1969
1970         if(WinningConditionHelper_zeroisworst)
1971                 leadlimit = 0; // not supported in this mode
1972
1973         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1974         // these modes always score in increments of 1, thus this makes sense
1975         {
1976                 if(leaderfrags != WinningConditionHelper_topscore)
1977                 {
1978                         leaderfrags = WinningConditionHelper_topscore;
1979
1980                         if (limit)
1981                         if (leaderfrags == limit - 1)
1982                                 Announce("1fragleft");
1983                         else if (leaderfrags == limit - 2)
1984                                 Announce("2fragsleft");
1985                         else if (leaderfrags == limit - 3)
1986                                 Announce("3fragsleft");
1987                 }
1988         }
1989
1990         limitreached = FALSE;
1991         if(limit)
1992                 if(WinningConditionHelper_topscore >= limit)
1993                         limitreached = TRUE;
1994         if(leadlimit)
1995         {
1996                 float leadlimitreached;
1997                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1998                 if(autocvar_leadlimit_and_fraglimit)
1999                         limitreached = (limitreached && leadlimitreached);
2000                 else
2001                         limitreached = (limitreached || leadlimitreached);
2002         }
2003
2004         return GetWinningCode(
2005                 WinningConditionHelper_topscore && limitreached,
2006                 WinningConditionHelper_equality
2007         );
2008 }
2009
2010 float WinningCondition_Race(float fraglimit)
2011 {
2012         float wc;
2013         entity p;
2014         float n, c;
2015
2016         n = 0;
2017         c = 0;
2018         FOR_EACH_PLAYER(p)
2019         {
2020                 ++n;
2021                 if(p.race_completed)
2022                         ++c;
2023         }
2024         if(n && (n == c))
2025                 return WINNING_YES;
2026         wc = WinningCondition_Scores(fraglimit, 0);
2027
2028         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2029         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2030         // do NOT support equality when the laps are all raced!
2031                 return WINNING_STARTSUDDENDEATHOVERTIME;
2032         else
2033                 return WINNING_NEVER;
2034         return wc;
2035 }
2036
2037 void ReadyRestart();
2038 float WinningCondition_QualifyingThenRace(float limit)
2039 {
2040         float wc;
2041         wc = WinningCondition_Scores(limit, 0);
2042
2043         // NEVER initiate overtime
2044         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2045         {
2046                 return WINNING_YES;
2047         }
2048
2049         return wc;
2050 }
2051
2052 float WinningCondition_RanOutOfSpawns()
2053 {
2054         entity head;
2055
2056         if(have_team_spawns <= 0)
2057                 return WINNING_NO;
2058
2059         if(autocvar_g_spawn_useallspawns <= 0)
2060                 return WINNING_NO;
2061
2062         if(!some_spawn_has_been_used)
2063                 return WINNING_NO;
2064
2065         team1_score = team2_score = team3_score = team4_score = 0;
2066
2067         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2068         {
2069                 if(head.team == COLOR_TEAM1)
2070                         team1_score = 1;
2071                 else if(head.team == COLOR_TEAM2)
2072                         team2_score = 1;
2073                 else if(head.team == COLOR_TEAM3)
2074                         team3_score = 1;
2075                 else if(head.team == COLOR_TEAM4)
2076                         team4_score = 1;
2077         }
2078
2079         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2080         {
2081                 if(head.team == COLOR_TEAM1)
2082                         team1_score = 1;
2083                 else if(head.team == COLOR_TEAM2)
2084                         team2_score = 1;
2085                 else if(head.team == COLOR_TEAM3)
2086                         team3_score = 1;
2087                 else if(head.team == COLOR_TEAM4)
2088                         team4_score = 1;
2089         }
2090
2091         ClearWinners();
2092         if(team1_score + team2_score + team3_score + team4_score == 0)
2093         {
2094                 checkrules_equality = TRUE;
2095                 return WINNING_YES;
2096         }
2097         else if(team1_score + team2_score + team3_score + team4_score == 1)
2098         {
2099                 float t, i;
2100                 if(team1_score) t = COLOR_TEAM1;
2101                 if(team2_score) t = COLOR_TEAM2;
2102                 if(team3_score) t = COLOR_TEAM3;
2103                 if(team4_score) t = COLOR_TEAM4;
2104                 CheckAllowedTeams(world);
2105                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2106                 {
2107                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2108                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2109                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2110                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2111                 }
2112
2113                 AddWinners(team, t);
2114                 return WINNING_YES;
2115         }
2116         else
2117                 return WINNING_NO;
2118 }
2119
2120 /*
2121 ============
2122 CheckRules_World
2123
2124 Exit deathmatch games upon conditions
2125 ============
2126 */
2127 void CheckRules_World()
2128 {
2129         float timelimit;
2130         float fraglimit;
2131         float leadlimit;
2132
2133         VoteThink();
2134         MapVote_Think();
2135
2136         SetDefaultAlpha();
2137
2138         /*
2139         MapVote_Think should now do that part
2140         if (intermission_running)
2141                 if (time >= intermission_exittime + 60)
2142                 {
2143                         if(!DoNextMapOverride())
2144                                 GotoNextMap();
2145                         return;
2146                 }
2147         */
2148
2149         if (gameover)   // someone else quit the game already
2150         {
2151                 if(player_count == 0) // Nobody there? Then let's go to the next map
2152                         MapVote_Start();
2153                         // this will actually check the player count in the next frame
2154                         // again, but this shouldn't hurt
2155                 return;
2156         }
2157
2158         timelimit = autocvar_timelimit * 60;
2159         fraglimit = autocvar_fraglimit;
2160         leadlimit = autocvar_leadlimit;
2161
2162         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2163         {
2164                 if(timelimit > 0)
2165                         timelimit = 0; // timelimit is not made for warmup
2166                 if(fraglimit > 0)
2167                         fraglimit = 0; // no fraglimit for now
2168                 leadlimit = 0; // no leadlimit for now
2169         }
2170
2171         if(g_onslaught)
2172                 timelimit = 0; // ONS has its own overtime rule
2173
2174         if(timelimit > 0)
2175         {
2176                 timelimit += game_starttime;
2177         }
2178         else if (timelimit < 0)
2179         {
2180                 // endmatch
2181                 NextLevel();
2182                 return;
2183         }
2184
2185         float wantovertime;
2186         wantovertime = 0;
2187
2188         if(checkrules_suddendeathend)
2189         {
2190                 if(!checkrules_suddendeathwarning)
2191                 {
2192                         checkrules_suddendeathwarning = TRUE;
2193                         if(g_race && !g_race_qualifying)
2194                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2195                         else
2196                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2197                 }
2198         }
2199         else
2200         {
2201                 if (timelimit && time >= timelimit)
2202                 {
2203                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2204                         {
2205                                 float totalplayers;
2206                                 float playerswithlaps;
2207                                 float readyplayers;
2208                                 entity head;
2209                                 totalplayers = playerswithlaps = readyplayers = 0;
2210                                 FOR_EACH_PLAYER(head)
2211                                 {
2212                                         ++totalplayers;
2213                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2214                                                 ++playerswithlaps;
2215                                         if(head.ready)
2216                                                 ++readyplayers;
2217                                 }
2218
2219                                 // at least 2 of the players have completed a lap: start the RACE
2220                                 // otherwise, the players should end the qualifying on their own
2221                                 if(readyplayers || playerswithlaps >= 2)
2222                                 {
2223                                         checkrules_suddendeathend = 0;
2224                                         ReadyRestart(); // go to race
2225                                         return;
2226                                 }
2227                                 else
2228                                         wantovertime |= InitiateSuddenDeath();
2229                         }
2230                         else
2231                                 wantovertime |= InitiateSuddenDeath();
2232                 }
2233         }
2234
2235         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2236         {
2237                 NextLevel();
2238                 return;
2239         }
2240
2241         float checkrules_status;
2242         checkrules_status = WinningCondition_RanOutOfSpawns();
2243         if(checkrules_status == WINNING_YES)
2244         {
2245                 bprint("Hey! Someone ran out of spawns!\n");
2246         }
2247         else if(g_race && !g_race_qualifying && timelimit >= 0)
2248         {
2249                 checkrules_status = WinningCondition_Race(fraglimit);
2250                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2251         }
2252         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2253         {
2254                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2255                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2256         }
2257         else if(g_assault)
2258         {
2259                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2260         }
2261         else if(g_lms)
2262         {
2263                 checkrules_status = WinningCondition_LMS();
2264         }
2265         else if (g_onslaught)
2266         {
2267                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2268         }
2269         else
2270         {
2271                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2272                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2273         }
2274
2275         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2276         {
2277                 checkrules_status = WINNING_NEVER;
2278                 checkrules_overtimesadded = -1;
2279                 wantovertime |= InitiateSuddenDeath();
2280         }
2281
2282         if(checkrules_status == WINNING_NEVER)
2283                 // equality cases! Nobody wins if the overtime ends in a draw.
2284                 ClearWinners();
2285
2286         if(wantovertime)
2287         {
2288                 if(checkrules_status == WINNING_NEVER)
2289                         InitiateOvertime();
2290                 else
2291                         checkrules_status = WINNING_YES;
2292         }
2293
2294         if(checkrules_suddendeathend)
2295                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2296                         checkrules_status = WINNING_YES;
2297
2298         if(checkrules_status == WINNING_YES)
2299         {
2300                 //print("WINNING\n");
2301                 NextLevel();
2302         }
2303 }
2304
2305 float mapvote_nextthink;
2306 float mapvote_initialized;
2307 float mapvote_keeptwotime;
2308 float mapvote_timeout;
2309 string mapvote_message;
2310 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2311 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2312 float mapvote_screenshot_dirs_count;
2313
2314 float mapvote_count;
2315 float mapvote_count_real;
2316 string mapvote_maps[MAPVOTE_COUNT];
2317 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2318 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2319 float mapvote_maps_suggested[MAPVOTE_COUNT];
2320 string mapvote_suggestions[MAPVOTE_COUNT];
2321 float mapvote_suggestion_ptr;
2322 float mapvote_voters;
2323 float mapvote_votes[MAPVOTE_COUNT];
2324 float mapvote_run;
2325 float mapvote_detail;
2326 float mapvote_abstain;
2327 .float mapvote;
2328
2329 void MapVote_ClearAllVotes()
2330 {
2331         FOR_EACH_CLIENT(other)
2332                 other.mapvote = 0;
2333 }
2334
2335 string MapVote_Suggest(string m)
2336 {
2337         float i;
2338         if(m == "")
2339                 return "That's not how to use this command.";
2340         if(!autocvar_g_maplist_votable_suggestions)
2341                 return "Suggestions are not accepted on this server.";
2342         if(mapvote_initialized)
2343                 return "Can't suggest - voting is already in progress!";
2344         m = MapInfo_FixName(m);
2345         if(!m)
2346                 return "The map you suggested is not available on this server.";
2347         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2348                 if(Map_IsRecent(m))
2349                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2350
2351         if(!MapInfo_CheckMap(m))
2352                 return "The map you suggested does not support the current game mode.";
2353         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2354                 if(mapvote_suggestions[i] == m)
2355                         return "This map was already suggested.";
2356         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2357         {
2358                 i = floor(random() * mapvote_suggestion_ptr);
2359         }
2360         else
2361         {
2362                 i = mapvote_suggestion_ptr;
2363                 mapvote_suggestion_ptr += 1;
2364         }
2365         if(mapvote_suggestions[i] != "")
2366                 strunzone(mapvote_suggestions[i]);
2367         mapvote_suggestions[i] = strzone(m);
2368         if(autocvar_sv_eventlog)
2369                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2370         return strcat("Suggestion of ", m, " accepted.");
2371 }
2372
2373 void MapVote_AddVotable(string nextMap, float isSuggestion)
2374 {
2375         float j, i, o;
2376         string pakfile, mapfile;
2377
2378         if(nextMap == "")
2379                 return;
2380         for(j = 0; j < mapvote_count; ++j)
2381                 if(mapvote_maps[j] == nextMap)
2382                         return;
2383         // suggestions might be no longer valid/allowed after gametype switch!
2384         if(isSuggestion)
2385                 if(!MapInfo_CheckMap(nextMap))
2386                         return;
2387         mapvote_maps[mapvote_count] = strzone(nextMap);
2388         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2389
2390         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2391         {
2392                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2393                 pakfile = whichpack(strcat(mapfile, ".tga"));
2394                 if(pakfile == "")
2395                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2396                 if(pakfile == "")
2397                         pakfile = whichpack(strcat(mapfile, ".png"));
2398                 if(pakfile != "")
2399                         break;
2400         }
2401         if(i >= mapvote_screenshot_dirs_count)
2402                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2403         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2404                 pakfile = substring(pakfile, o, -1);
2405
2406         mapvote_maps_screenshot_dir[mapvote_count] = i;
2407         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2408
2409         mapvote_count += 1;
2410 }
2411
2412 void MapVote_Spawn();
2413 void MapVote_Init()
2414 {
2415         float i;
2416         float nmax, smax;
2417
2418         MapVote_ClearAllVotes();
2419
2420         mapvote_count = 0;
2421         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2422         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2423
2424         if(mapvote_abstain)
2425                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2426         else
2427                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2428         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2429
2430         // we need this for AddVotable, as that cycles through the screenshot dirs
2431         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2432         if(mapvote_screenshot_dirs_count == 0)
2433                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2434         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2435         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2436                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2437
2438         if(mapvote_suggestion_ptr)
2439                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2440                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2441
2442         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2443                 MapVote_AddVotable(GetNextMap(), FALSE);
2444
2445         if(mapvote_count == 0)
2446         {
2447                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2448                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2449                 if(autocvar_g_maplist_shuffle)
2450                         ShuffleMaplist();
2451                 localcmd("\nmenu_cmd sync\n");
2452                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2453                         MapVote_AddVotable(GetNextMap(), FALSE);
2454         }
2455
2456         mapvote_count_real = mapvote_count;
2457         if(mapvote_abstain)
2458                 MapVote_AddVotable("don't care", 0);
2459
2460         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2461
2462         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2463         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2464         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2465                 mapvote_keeptwotime = 0;
2466         mapvote_message = "Choose a map and press its key!";
2467
2468         MapVote_Spawn();
2469 }
2470
2471 void MapVote_SendPicture(float id)
2472 {
2473         msg_entity = self;
2474         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2475         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2476         WriteByte(MSG_ONE, id);
2477         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2478 }
2479
2480 float GameCommand_MapVote(string cmd)
2481 {
2482         if(!intermission_running)
2483                 return FALSE;
2484
2485         if(cmd == "mv_getpic")
2486         {
2487                 MapVote_SendPicture(stof(argv(1)));
2488                 return TRUE;
2489         }
2490
2491         return FALSE;
2492 }
2493
2494 float MapVote_GetMapMask()
2495 {
2496         float mask, i, power;
2497         mask = 0;
2498         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2499                 if(mapvote_maps[i] != "")
2500                         mask |= power;
2501         return mask;
2502 }
2503
2504 entity mapvote_ent;
2505 float MapVote_SendEntity(entity to, float sf)
2506 {
2507         float i;
2508
2509         if(sf & 1)
2510                 sf &~= 2; // if we send 1, we don't need to also send 2
2511
2512         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2513         WriteByte(MSG_ENTITY, sf);
2514
2515         if(sf & 1)
2516         {
2517                 // flag 1 == initialization
2518                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2519                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2520                 WriteString(MSG_ENTITY, "");
2521                 WriteByte(MSG_ENTITY, mapvote_count);
2522                 WriteByte(MSG_ENTITY, mapvote_abstain);
2523                 WriteByte(MSG_ENTITY, mapvote_detail);
2524                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2525                 if(mapvote_count <= 8)
2526                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2527                 else
2528                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2529                 for(i = 0; i < mapvote_count; ++i)
2530                         if(mapvote_maps[i] != "")
2531                         {
2532                                 if(mapvote_abstain && i == mapvote_count - 1)
2533                                 {
2534                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2535                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2536                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2537                                 }
2538                                 else
2539                                 {
2540                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2541                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2542                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2543                                 }
2544                         }
2545         }
2546
2547         if(sf & 2)
2548         {
2549                 // flag 2 == update of mask
2550                 if(mapvote_count <= 8)
2551                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2552                 else
2553                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2554         }
2555
2556         if(sf & 4)
2557         {
2558                 if(mapvote_detail)
2559                         for(i = 0; i < mapvote_count; ++i)
2560                                 if(mapvote_maps[i] != "")
2561                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2562
2563                 WriteByte(MSG_ENTITY, to.mapvote);
2564         }
2565
2566         return TRUE;
2567 }
2568
2569 void MapVote_Spawn()
2570 {
2571         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2572 }
2573
2574 void MapVote_TouchMask()
2575 {
2576         mapvote_ent.SendFlags |= 2;
2577 }
2578
2579 void MapVote_TouchVotes(entity voter)
2580 {
2581         mapvote_ent.SendFlags |= 4;
2582 }
2583
2584 float MapVote_Finished(float mappos)
2585 {
2586         string result;
2587         float i;
2588         float didntvote;
2589
2590         if(autocvar_sv_eventlog)
2591         {
2592                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2593                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2594                 didntvote = mapvote_voters;
2595                 for(i = 0; i < mapvote_count; ++i)
2596                         if(mapvote_maps[i] != "")
2597                         {
2598                                 didntvote -= mapvote_votes[i];
2599                                 if(i != mappos)
2600                                 {
2601                                         result = strcat(result, ":", mapvote_maps[i]);
2602                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2603                                 }
2604                         }
2605                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2606
2607                 GameLogEcho(result);
2608                 if(mapvote_maps_suggested[mappos])
2609                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2610         }
2611
2612         FOR_EACH_REALCLIENT(other)
2613                 FixClientCvars(other);
2614
2615         Map_Goto_SetStr(mapvote_maps[mappos]);
2616         Map_Goto();
2617         alreadychangedlevel = TRUE;
2618         return TRUE;
2619 }
2620 void MapVote_CheckRules_1()
2621 {
2622         float i;
2623
2624         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2625         {
2626                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2627                 mapvote_votes[i] = 0;
2628         }
2629
2630         mapvote_voters = 0;
2631         FOR_EACH_REALCLIENT(other)
2632         {
2633                 ++mapvote_voters;
2634                 if(other.mapvote)
2635                 {
2636                         i = other.mapvote - 1;
2637                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2638                         mapvote_votes[i] = mapvote_votes[i] + 1;
2639                 }
2640         }
2641 }
2642
2643 float MapVote_CheckRules_2()
2644 {
2645         float i;
2646         float firstPlace, secondPlace;
2647         float firstPlaceVotes, secondPlaceVotes;
2648         float mapvote_voters_real;
2649         string result;
2650
2651         if(mapvote_count_real == 1)
2652                 return MapVote_Finished(0);
2653
2654         mapvote_voters_real = mapvote_voters;
2655         if(mapvote_abstain)
2656                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2657
2658         RandomSelection_Init();
2659         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2660                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2661         firstPlace = RandomSelection_chosen_float;
2662         firstPlaceVotes = RandomSelection_best_priority;
2663         //dprint("First place: ", ftos(firstPlace), "\n");
2664         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2665
2666         RandomSelection_Init();
2667         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2668                 if(i != firstPlace)
2669                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2670         secondPlace = RandomSelection_chosen_float;
2671         secondPlaceVotes = RandomSelection_best_priority;
2672         //dprint("Second place: ", ftos(secondPlace), "\n");
2673         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2674
2675         if(firstPlace == -1)
2676                 error("No first place in map vote... WTF?");
2677
2678         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2679                 return MapVote_Finished(firstPlace);
2680
2681         if(mapvote_keeptwotime)
2682                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2683                 {
2684                         float didntvote;
2685                         MapVote_TouchMask();
2686                         mapvote_message = "Now decide between the TOP TWO!";
2687                         mapvote_keeptwotime = 0;
2688                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2689                         result = strcat(result, ":", ftos(firstPlaceVotes));
2690                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2691                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2692                         didntvote = mapvote_voters;
2693                         for(i = 0; i < mapvote_count; ++i)
2694                                 if(mapvote_maps[i] != "")
2695                                 {
2696                                         didntvote -= mapvote_votes[i];
2697                                         if(i != firstPlace)
2698                                                 if(i != secondPlace)
2699                                                 {
2700                                                         result = strcat(result, ":", mapvote_maps[i]);
2701                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2702                                                         if(i < mapvote_count_real)
2703                                                         {
2704                                                                 strunzone(mapvote_maps[i]);
2705                                                                 mapvote_maps[i] = "";
2706                                                                 strunzone(mapvote_maps_pakfile[i]);
2707                                                                 mapvote_maps_pakfile[i] = "";
2708                                                         }
2709                                                 }
2710                                 }
2711                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2712                         if(autocvar_sv_eventlog)
2713                                 GameLogEcho(result);
2714                 }
2715
2716         return FALSE;
2717 }
2718 void MapVote_Tick()
2719 {
2720         float keeptwo;
2721         float totalvotes;
2722
2723         keeptwo = mapvote_keeptwotime;
2724         MapVote_CheckRules_1(); // count
2725         if(MapVote_CheckRules_2()) // decide
2726                 return;
2727
2728         totalvotes = 0;
2729         FOR_EACH_REALCLIENT(other)
2730         {
2731                 // hide scoreboard again
2732                 if(other.health != 2342)
2733                 {
2734                         other.health = 2342;
2735                         other.impulse = 0;
2736                         if(clienttype(other) == CLIENTTYPE_REAL)
2737                         {
2738                                 msg_entity = other;
2739                                 WriteByte(MSG_ONE, SVC_FINALE);
2740                                 WriteString(MSG_ONE, "");
2741                         }
2742                 }
2743
2744                 // clear possibly invalid votes
2745                 if(mapvote_maps[other.mapvote - 1] == "")
2746                         other.mapvote = 0;
2747                 // use impulses as new vote
2748                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2749                         if(mapvote_maps[other.impulse - 1] != "")
2750                         {
2751                                 other.mapvote = other.impulse;
2752                                 MapVote_TouchVotes(other);
2753                         }
2754                 other.impulse = 0;
2755
2756                 if(other.mapvote)
2757                         ++totalvotes;
2758         }
2759
2760         MapVote_CheckRules_1(); // just count
2761 }
2762 void MapVote_Start()
2763 {
2764         if(mapvote_run)
2765                 return;
2766
2767         // wait for stats to be sent first
2768         if(!playerstats_waitforme)
2769                 return;
2770
2771         MapInfo_Enumerate();
2772         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2773                 mapvote_run = TRUE;
2774 }
2775 void MapVote_Think()
2776 {
2777         if(!mapvote_run)
2778                 return;
2779
2780         if(alreadychangedlevel)
2781                 return;
2782
2783         if(time < mapvote_nextthink)
2784                 return;
2785         //dprint("tick\n");
2786
2787         mapvote_nextthink = time + 0.5;
2788
2789         if(!mapvote_initialized)
2790         {
2791                 if(autocvar_rescan_pending == 1)
2792                 {
2793                         cvar_set("rescan_pending", "2");
2794                         localcmd("fs_rescan\nrescan_pending 3\n");
2795                         return;
2796                 }
2797                 else if(autocvar_rescan_pending == 2)
2798                 {
2799                         return;
2800                 }
2801                 else if(autocvar_rescan_pending == 3)
2802                 {
2803                         // now build missing mapinfo files
2804                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2805                                 return;
2806
2807                         // we're done, start the timer
2808                         cvar_set("rescan_pending", "0");
2809                 }
2810
2811                 mapvote_initialized = TRUE;
2812                 if(DoNextMapOverride())
2813                         return;
2814                 if(!autocvar_g_maplist_votable || player_count <= 0)
2815                 {
2816                         GotoNextMap();
2817                         return;
2818                 }
2819                 MapVote_Init();
2820         }
2821
2822         MapVote_Tick();
2823 }
2824
2825 string GotoMap(string m)
2826 {
2827         if(!MapInfo_CheckMap(m))
2828                 return "The map you chose is not available on this server.";
2829         cvar_set("nextmap", m);
2830         cvar_set("timelimit", "-1");
2831         if(mapvote_initialized || alreadychangedlevel)
2832         {
2833                 if(DoNextMapOverride())
2834                         return "Map switch initiated.";
2835                 else
2836                         return "Hm... no. For some reason I like THIS map more.";
2837         }
2838         else
2839                 return "Map switch will happen after scoreboard.";
2840 }
2841
2842
2843 void EndFrame()
2844 {
2845         float altime;
2846         FOR_EACH_REALCLIENT(self)
2847         {
2848                 if(self.classname == "spectator")
2849                 {
2850                         if(self.enemy.typehitsound)
2851                                 self.typehit_time = time;
2852                         else if(self.enemy.hitsound)
2853                                 self.hit_time = time;
2854                 }
2855                 else
2856                 {
2857                         if(self.typehitsound)
2858                                 self.typehit_time = time;
2859                         else if(self.hitsound)
2860                                 self.hit_time = time;
2861                 }
2862         }
2863         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2864         // add 1 frametime because after this, engine SV_Physics
2865         // increases time by a frametime and then networks the frame
2866         // add another frametime because client shows everything with
2867         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2868         // needed!
2869         FOR_EACH_CLIENT(self)
2870         {
2871                 self.hitsound = FALSE;
2872                 self.typehitsound = FALSE;
2873                 antilag_record(self, altime);
2874         }
2875 }
2876
2877
2878 /*
2879  * RedirectionThink:
2880  * returns TRUE if redirecting
2881  */
2882 float redirection_timeout;
2883 float redirection_nextthink;
2884 float RedirectionThink()
2885 {
2886         float clients_found;
2887
2888         if(redirection_target == "")
2889                 return FALSE;
2890
2891         if(!redirection_timeout)
2892         {
2893                 cvar_set("sv_public", "-2");
2894                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2895                 if(redirection_target == "self")
2896                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2897                 else
2898                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2899         }
2900
2901         if(time < redirection_nextthink)
2902                 return TRUE;
2903
2904         redirection_nextthink = time + 1;
2905
2906         clients_found = 0;
2907         FOR_EACH_REALCLIENT(self)
2908         {
2909                 print("Redirecting: sending connect command to ", self.netname, "\n");
2910                 if(redirection_target == "self")
2911                         stuffcmd(self, "\ndisconnect; reconnect\n");
2912                 else
2913                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2914                 ++clients_found;
2915         }
2916
2917         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2918
2919         if(time > redirection_timeout || clients_found == 0)
2920                 localcmd("\nwait; wait; wait; quit\n");
2921
2922         return TRUE;
2923 }
2924
2925 void TargetMusic_RestoreGame();
2926 void RestoreGame()
2927 {
2928         // Loaded from a save game
2929         // some things then break, so let's work around them...
2930
2931         // Progs DB (capture records)
2932         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2933
2934         // Mapinfo
2935         MapInfo_Shutdown();
2936         MapInfo_Enumerate();
2937         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2938         WeaponStats_Init();
2939
2940         TargetMusic_RestoreGame();
2941 }
2942
2943 void SV_Shutdown()
2944 {
2945         entity e;
2946
2947         if(gameover > 1) // shutting down already?
2948                 return;
2949
2950         gameover = 2; // 2 = server shutting down
2951
2952         if(world_initialized > 0)
2953         {
2954                 world_initialized = 0;
2955                 print("Saving persistent data...\n");
2956                 Ban_SaveBans();
2957
2958                 PlayerStats_EndMatch(0);
2959                 FOR_EACH_CLIENT(e)
2960                         PlayerStats_AddGlobalInfo(e);
2961                 PlayerStats_Shutdown();
2962
2963                 if(!cheatcount_total)
2964                 {
2965                         if(autocvar_sv_db_saveasdump)
2966                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2967                         else
2968                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2969                 }
2970                 if(autocvar_developer)
2971                 {
2972                         if(autocvar_sv_db_saveasdump)
2973                                 db_dump(TemporaryDB, "server-temp.db");
2974                         else
2975                                 db_save(TemporaryDB, "server-temp.db");
2976                 }
2977                 CheatShutdown(); // must be after cheatcount check
2978                 db_close(ServerProgsDB);
2979                 db_close(TemporaryDB);
2980                 print("done!\n");
2981                 // tell the bot system the game is ending now
2982                 bot_endgame();
2983
2984                 WeaponStats_Shutdown();
2985                 MapInfo_Shutdown();
2986         }
2987         else if(world_initialized == 0)
2988         {
2989                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2990         }
2991 }