qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void fteqcc_testbugs()
  85 {
  86         float a, b;
  87
  88         if(!autocvar_developer_fteqccbugs)
  89                 return;
  90
  91         dprint("*** fteqcc test: checking for bugs...\n");
  92
  93         a = 1;
  94         b = 5;
  95         if(sqrt(a) - sqrt(b - a) == 0)
  96                 dprint("*** fteqcc test: found same-function-twice bug\n");
  97         else
  98                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  99
 100         world.cnt = -10;
 101         world.enemy = world;
 102         world.enemy.cnt += 10;
 103         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 104                 dprint("*** fteqcc test: found += bug\n");
 105         else
 106                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 107         world.cnt = 0;
 108 }
 109
 110 void GotoFirstMap()
 111 {
 112         float n;
 113         if(autocvar__sv_init)
 114         {
 115                 // cvar_set("_sv_init", "0");
 116                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 117                 // to this "init" map on a dedicated server will cause no permanent
 118                 // harm
 119                 if(autocvar_g_maplist_shuffle)
 120                         ShuffleMaplist();
 121                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 122                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 self.nextthink = time;
 136         }
 137         else
 138         {
 139                 self.nextthink = time + 1;
 140                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         if(cvar_changes)
 151                 strunzone(cvar_changes);
 152         cvar_changes = string_null;
 153         if(cvar_purechanges)
 154                 strunzone(cvar_purechanges);
 155         cvar_purechanges = string_null;
 156         cvar_purechanges_count = 0;
 157
 158         h = buf_create();
 159         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 160         n = buf_getsize(h);
 161
 162         adding = TRUE;
 163         pureadding = TRUE;
 164
 165         for(i = 0; i < n; ++i)
 166         {
 167                 k = bufstr_get(h, i);
 168
 169 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 170 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 171 #define BADCVAR(p) if(k == p) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("g_maplist_index");
 182                 BADCVAR("halflifebsp");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_leadlimit");
 307                 BADCVAR("g_ctf_captimerecord_always");
 308                 BADCVAR("g_ctf_flag_glowtrails");
 309                 BADCVAR("g_ctf_flag_pickup_verbosename");
 310                 BADCVAR("g_domination_point_leadlimit");
 311                 BADCVAR("g_forced_respawn");
 312                 BADCVAR("g_keyhunt_point_leadlimit");
 313                 BADPREFIX("g_mod_");
 314                 BADCVAR("g_nexball_goalleadlimit");
 315                 BADCVAR("leadlimit_and_fraglimit");
 316                 BADCVAR("leadlimit_override");
 317                 BADCVAR("pausable");
 318                 BADCVAR("sv_allow_fullbright");
 319                 BADCVAR("sv_checkforpacketsduringsleep");
 320                 BADCVAR("sv_fraginfo");
 321                 BADCVAR("sv_timeout");
 322                 BADPREFIX("sv_timeout_");
 323                 BADPREFIX("crypto_");
 324                 BADPREFIX("g_chat_");
 325                 BADPREFIX("g_ctf_captimerecord_");
 326                 BADPREFIX("g_maplist_votable_");
 327                 BADPREFIX("net_");
 328                 BADPREFIX("prvm_");
 329                 BADPREFIX("skill_");
 330                 BADPREFIX("sv_cullentities_");
 331                 BADPREFIX("sv_fraginfo_");
 332                 BADPREFIX("sv_maxidle_");
 333                 BADPREFIX("sv_vote_");
 334                 BADPREFIX("timelimit_");
 335                 BADCVAR("gameversion");
 336                 BADPREFIX("gameversion_");
 337                 BADCVAR("sv_namechangetimer");
 338
 339                 // allowed changes to server admins (please sync this to server.cfg)
 340                 // vi commands:
 341                 //   :/"impure"/,$d
 342                 //   :g!,^\/\/[^ /],d
 343                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 344                 //   :%!sort
 345                 // yes, this does contain some redundant stuff, don't really care
 346                 BADCVAR("bot_config_file");
 347                 BADCVAR("bot_number");
 348                 BADCVAR("bot_prefix");
 349                 BADCVAR("bot_suffix");
 350                 BADCVAR("capturelimit_override");
 351                 BADCVAR("fraglimit_override");
 352                 BADCVAR("gametype");
 353                 BADCVAR("g_antilag");
 354                 BADCVAR("g_balance_teams");
 355                 BADCVAR("g_balance_teams_prevent_imbalance");
 356                 BADCVAR("g_balance_teams_scorefactor");
 357                 BADCVAR("g_ban_sync_trusted_servers");
 358                 BADCVAR("g_ban_sync_uri");
 359                 BADCVAR("g_ca_teams_override");
 360                 BADCVAR("g_ctf_ignore_frags");
 361                 BADCVAR("g_domination_point_limit");
 362                 BADCVAR("g_freezetag_teams_override");
 363                 BADCVAR("g_friendlyfire");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_maxplayers");
 378                 BADCVAR("g_mirrordamage");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_powerups");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("g_warmup");
 383                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 384                 BADCVAR("hostname");
 385                 BADCVAR("log_file");
 386                 BADCVAR("maxplayers");
 387                 BADCVAR("minplayers");
 388                 BADCVAR("net_address");
 389                 BADCVAR("port");
 390                 BADCVAR("rcon_password");
 391                 BADCVAR("rcon_restricted_commands");
 392                 BADCVAR("rcon_restricted_password");
 393                 BADCVAR("skill");
 394                 BADCVAR("sv_adminnick");
 395                 BADCVAR("sv_autoscreenshot");
 396                 BADCVAR("sv_autotaunt");
 397                 BADCVAR("sv_curl_defaulturl");
 398                 BADCVAR("sv_defaultcharacter");
 399                 BADCVAR("sv_defaultplayercolors");
 400                 BADCVAR("sv_defaultplayermodel");
 401                 BADCVAR("sv_defaultplayerskin");
 402                 BADCVAR("sv_maxidle");
 403                 BADCVAR("sv_maxrate");
 404                 BADCVAR("sv_motd");
 405                 BADCVAR("sv_public");
 406                 BADCVAR("sv_ready_restart");
 407                 BADCVAR("sv_status_privacy");
 408                 BADCVAR("sv_taunt");
 409                 BADCVAR("sv_vote_call");
 410                 BADCVAR("sv_vote_commands");
 411                 BADCVAR("sv_vote_majority_factor");
 412                 BADCVAR("sv_vote_master");
 413                 BADCVAR("sv_vote_master_commands");
 414                 BADCVAR("sv_vote_master_password");
 415                 BADCVAR("sv_vote_simple_majority_factor");
 416                 BADCVAR("teamplay_mode");
 417                 BADCVAR("timelimit_override");
 418                 BADCVAR("g_spawnshieldtime");
 419                 BADPREFIX("g_warmup_");
 420                 BADPREFIX("sv_ready_restart_");
 421
 422                 // mutators that announce themselves properly to the server browser
 423                 BADCVAR("g_minstagib");
 424                 BADCVAR("g_new_toys");
 425                 BADCVAR("g_nix");
 426                 BADCVAR("g_grappling_hook");
 427                 BADCVAR("g_jetpack");
 428
 429 #undef BADPREFIX
 430 #undef BADCVAR
 431
 432                 if(pureadding)
 433                 {
 434                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 435                         if(strlen(cvar_purechanges) > 16384)
 436                         {
 437                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 438                                 pureadding = 0;
 439                         }
 440                 }
 441                 ++cvar_purechanges_count;
 442                 // WARNING: this variable is used for the server list
 443                 // NEVER dare to skip this code!
 444                 // Hacks to intentionally appearing as "pure server" even though you DO have
 445                 // modified settings may be punished by removal from the server list.
 446                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 447                 // though.
 448         }
 449         buf_del(h);
 450         if(cvar_changes == "")
 451                 cvar_changes = "// this server runs at default server settings\n";
 452         else
 453                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 454         cvar_changes = strzone(cvar_changes);
 455         if(cvar_purechanges == "")
 456                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 457         else
 458                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 459         cvar_purechanges = strzone(cvar_purechanges);
 460 }
 461
 462 void detect_maptype()
 463 {
 464 #if 0
 465         vector o, v;
 466         float i;
 467
 468         for(;;)
 469         {
 470                 o = world.mins;
 471                 o_x += random() * (world.maxs_x - world.mins_x);
 472                 o_y += random() * (world.maxs_y - world.mins_y);
 473                 o_z += random() * (world.maxs_z - world.mins_z);
 474
 475                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 476                 if(trace_fraction == 1)
 477                         continue;
 478
 479                 v = trace_endpos;
 480
 481                 for(i = 0; i < 64; i += 4)
 482                 {
 483                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 484         if(trace_fraction == 1)
 485                 continue;
 486                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 487                 }
 488
 489                 break;
 490         }
 491 #endif
 492 }
 493
 494 entity randomseed;
 495 float RandomSeed_Send(entity to, float sf)
 496 {
 497         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 498         WriteShort(MSG_ENTITY, self.cnt);
 499         return TRUE;
 500 }
 501 void RandomSeed_Think()
 502 {
 503         self.cnt = bound(0, floor(random() * 65536), 65535);
 504         self.nextthink = time + 5;
 505
 506         self.SendFlags |= 1;
 507 }
 508 void RandomSeed_Spawn()
 509 {
 510         randomseed = spawn();
 511         randomseed.think = RandomSeed_Think;
 512         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 513
 514         entity oldself;
 515         oldself = self;
 516         self = randomseed;
 517         self.think(); // sets random seed and nextthink
 518         self = oldself;
 519 }
 520
 521 void spawnfunc___init_dedicated_server(void)
 522 {
 523         // handler for _init/_init map (only for dedicated server initialization)
 524
 525         world_initialized = -1; // don't complain
 526         cvar = cvar_normal;
 527         cvar_string = cvar_string_normal;
 528         cvar_set = cvar_set_normal;
 529
 530         remove = remove_unsafely;
 531
 532         entity e;
 533         e = spawn();
 534         e.think = GotoFirstMap;
 535         e.nextthink = time; // this is usually 1 at this point
 536
 537         e = spawn();
 538         e.classname = "info_player_deathmatch"; // safeguard against player joining
 539
 540         self.classname = "worldspawn"; // safeguard against various stuff ;)
 541
 542         // needs to be done so early because of the constants they create
 543         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 544         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
 545         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 546         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 547         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 548         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 549         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void spawnfunc_worldspawn (void)
 562 {
 563         float fd, l, i, j, n;
 564         string s;
 565
 566         cvar = cvar_normal;
 567         cvar_string = cvar_string_normal;
 568         cvar_set = cvar_set_normal;
 569
 570         if(world_already_spawned)
 571                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 572         world_already_spawned = TRUE;
 573
 574         remove = remove_safely; // during spawning, watch what you remove!
 575
 576         check_unacceptable_compiler_bugs();
 577
 578         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 579
 580         compressShortVector_init();
 581
 582         entity head;
 583         head = nextent(world);
 584         maxclients = 0;
 585         while(head)
 586         {
 587                 ++maxclients;
 588                 head = nextent(head);
 589         }
 590
 591         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 592
 593         // needs to be done so early because of the constants they create
 594         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 595         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
 596         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 601
 602         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 603
 604         TemporaryDB = db_create();
 605
 606         // 0 normal
 607         lightstyle(0, "m");
 608
 609         // 1 FLICKER (first variety)
 610         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 611
 612         // 2 SLOW STRONG PULSE
 613         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 614
 615         // 3 CANDLE (first variety)
 616         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 617
 618         // 4 FAST STROBE
 619         lightstyle(4, "mamamamamama");
 620
 621         // 5 GENTLE PULSE 1
 622         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 623
 624         // 6 FLICKER (second variety)
 625         lightstyle(6, "nmonqnmomnmomomno");
 626
 627         // 7 CANDLE (second variety)
 628         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 629
 630         // 8 CANDLE (third variety)
 631         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 632
 633         // 9 SLOW STROBE (fourth variety)
 634         lightstyle(9, "aaaaaaaazzzzzzzz");
 635
 636         // 10 FLUORESCENT FLICKER
 637         lightstyle(10, "mmamammmmammamamaaamammma");
 638
 639         // 11 SLOW PULSE NOT FADE TO BLACK
 640         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 641
 642         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 643
 644         // 63 testing
 645         lightstyle(63, "a");
 646
 647         if(autocvar_g_campaign)
 648                 CampaignPreInit();
 649
 650         Map_MarkAsRecent(mapname);
 651
 652         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 653
 654         precache_model ("null"); // we need this one before InitGameplayMode
 655         InitGameplayMode();
 656         readlevelcvars();
 657         GrappleHookInit();
 658         ElectroInit();
 659         LaserInit();
 660
 661         player_count = 0;
 662         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 663         if(bot_waypoints_for_items == 1)
 664                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 665                         bot_waypoints_for_items = 0;
 666
 667         precache();
 668
 669         WaypointSprite_Init();
 670
 671         GameLogInit(); // prepare everything
 672         // NOTE for matchid:
 673         // changing the logic generating it is okay. But:
 674         // it HAS to stay <= 64 chars
 675         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 676         if(autocvar_sv_eventlog)
 677         {
 678                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 679                 matchid = strzone(s);
 680
 681                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 682                 s = ":gameinfo:mutators:LIST";
 683
 684                 ret_string = s;
 685                 MUTATOR_CALLHOOK(BuildMutatorsString);
 686                 s = ret_string;
 687
 688                 // simple, probably not good in the mutator system
 689                 if(autocvar_g_grappling_hook)
 690                         s = strcat(s, ":grappling_hook");
 691
 692                 // initialiation stuff, not good in the mutator system
 693                 if(!autocvar_g_use_ammunition)
 694                         s = strcat(s, ":no_use_ammunition");
 695
 696                 // initialiation stuff, not good in the mutator system
 697                 if(autocvar_g_pickup_items == 0)
 698                         s = strcat(s, ":no_pickup_items");
 699                 if(autocvar_g_pickup_items > 0)
 700                         s = strcat(s, ":pickup_items");
 701
 702                 // initialiation stuff, not good in the mutator system
 703                 if(autocvar_g_weaponarena != "0")
 704                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 705
 706                 // TODO to mutator system
 707                 if(autocvar_g_norecoil)
 708                         s = strcat(s, ":norecoil");
 709
 710                 // TODO to mutator system
 711                 if(autocvar_g_powerups == 0)
 712                         s = strcat(s, ":no_powerups");
 713                 if(autocvar_g_powerups > 0)
 714                         s = strcat(s, ":powerups");
 715
 716                 GameLogEcho(s);
 717                 GameLogEcho(":gameinfo:end");
 718         }
 719         else
 720                 matchid = strzone(ftos(random()));
 721
 722         cvar_set("nextmap", "");
 723
 724         SetDefaultAlpha();
 725
 726         if(autocvar_g_campaign)
 727                 CampaignPostInit();
 728
 729         fteqcc_testbugs();
 730
 731         Ban_LoadBans();
 732
 733         MapInfo_Enumerate();
 734         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 735
 736         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 737         {
 738                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 739                 if(fd != -1)
 740                 {
 741                         while((s = fgets(fd)))
 742                         {
 743                                 l = tokenize_console(s);
 744                                 if(l < 2)
 745                                         continue;
 746                                 if(argv(0) == "cd")
 747                                 {
 748                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 749                                         print("  cdtrack ", argv(2), "\n");
 750                                 }
 751                                 else if(argv(0) == "fog")
 752                                 {
 753                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 754                                         print("  \"fog\" \"", s, "\"\n");
 755                                 }
 756                                 else if(argv(0) == "set")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) != "//")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 764                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 765                                 }
 766                         }
 767                         fclose(fd);
 768                 }
 769         }
 770
 771         WeaponStats_Init();
 772
 773         WepSet_AddStat();
 774         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 775         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 776         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 777         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 778         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 779         Nagger_Init();
 780
 781         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 782         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 783         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 784         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 785         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 786         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 787         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 788         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 789         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 790         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 791         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 792         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 793         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 794
 795         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 796         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 797
 798         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 799
 800         // freeze attacks
 801         addstat(STAT_FROZEN, AS_INT, frozen);
 802         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 803
 804         // g_movementspeed hack
 805         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 806         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 807         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 808         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 809
 810         // secrets
 811         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 812         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 813
 814         // monsters
 815         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 816         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 817
 818         // misc
 819         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 820
 821         next_pingtime = time + 5;
 822
 823         detect_maptype();
 824
 825         // set up information replies for clients and server to use
 826         maplist_reply = strzone(getmaplist());
 827         lsmaps_reply = strzone(getlsmaps());
 828         monsterlist_reply = strzone(getmonsterlist());
 829         for(i = 0; i < 10; ++i)
 830         {
 831                 s = getrecords(i);
 832                 if (s)
 833                         records_reply[i] = strzone(s);
 834         }
 835         ladder_reply = strzone(getladder());
 836         rankings_reply = strzone(getrankings());
 837
 838         // begin other init
 839         ClientInit_Spawn();
 840         RandomSeed_Spawn();
 841         PingPLReport_Spawn();
 842
 843         CheatInit();
 844
 845         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 846
 847         // fill sv_curl_serverpackages from .serverpackage files
 848         if(autocvar_sv_curl_serverpackages_auto)
 849         {
 850                 s = "";
 851                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 852                 for(i = 0; i < n; ++i)
 853                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 854                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 855                                 s = strcat(s, " ", argv(i));
 856                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 857                 if(fd >= 0)
 858                 {
 859                         j = search_getsize(fd);
 860                         for(i = 0; i < j; ++i)
 861                                 s = strcat(s, " ", search_getfilename(fd, i));
 862                         search_end(fd);
 863                 }
 864                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 865                 if(fd >= 0)
 866                 {
 867                         j = search_getsize(fd);
 868                         for(i = 0; i < j; ++i)
 869                                 s = strcat(s, " ", search_getfilename(fd, i));
 870                         search_end(fd);
 871                 }
 872                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 873         }
 874
 875         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 876         modname = "Xonotic";
 877         // physics/balance/config changes that count as mod
 878         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 879                 modname = cvar_string("g_mod_physics");
 880         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 881                 modname = cvar_string("g_mod_balance");
 882         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 883                 modname = cvar_string("g_mod_config");
 884         // extra mutators that deserve to count as mod
 885         MUTATOR_CALLHOOK(SetModname);
 886
 887         // save it for later
 888         modname = strzone(modname);
 889
 890         WinningConditionHelper(); // set worldstatus
 891
 892         world_initialized = 1;
 893 }
 894
 895 void spawnfunc_light (void)
 896 {
 897         //makestatic (self); // Who the f___ did that?
 898         remove(self);
 899 }
 900
 901 string GetGametype()
 902 {
 903         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 904 }
 905
 906 string GetMapname()
 907 {
 908         return mapname;
 909 }
 910
 911 float Map_Count, Map_Current;
 912 string Map_Current_Name;
 913
 914 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 915 float GetMaplistPosition()
 916 {
 917         float pos, idx;
 918         string map;
 919
 920         map = GetMapname();
 921         idx = autocvar_g_maplist_index;
 922
 923         if(idx >= 0)
 924                 if(idx < Map_Count)
 925                         if(map == argv(idx))
 926                                 return idx;
 927
 928         for(pos = 0; pos < Map_Count; ++pos)
 929                 if(map == argv(pos))
 930                         return pos;
 931
 932         // resume normal maplist rotation if current map is not in g_maplist
 933         return idx;
 934 }
 935
 936 float MapHasRightSize(string map)
 937 {
 938         float fh;
 939         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 940         if(autocvar_g_maplist_check_waypoints)
 941         {
 942                 dprint("checkwp "); dprint(map);
 943                 if(!fexists(strcat("maps/", map, ".waypoints")))
 944                 {
 945                         dprint(": no waypoints\n");
 946                         return FALSE;
 947                 }
 948                 dprint(": has waypoints\n");
 949         }
 950
 951         // open map size restriction file
 952         dprint("opensize "); dprint(map);
 953         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 954         if(fh >= 0)
 955         {
 956                 float mapmin, mapmax;
 957                 dprint(": ok, ");
 958                 mapmin = stof(fgets(fh));
 959                 mapmax = stof(fgets(fh));
 960                 fclose(fh);
 961                 if(player_count < mapmin)
 962                 {
 963                         dprint("not enough\n");
 964                         return FALSE;
 965                 }
 966                 if(player_count > mapmax)
 967                 {
 968                         dprint("too many\n");
 969                         return FALSE;
 970                 }
 971                 dprint("right size\n");
 972                 return TRUE;
 973         }
 974         dprint(": not found\n");
 975         return TRUE;
 976 }
 977
 978 string Map_Filename(float position)
 979 {
 980         return strcat("maps/", argv(position), ".bsp");
 981 }
 982
 983 string strwords(string s, float w)
 984 {
 985         float endpos;
 986         for(endpos = 0; w && endpos >= 0; --w)
 987                 endpos = strstrofs(s, " ", endpos + 1);
 988         if(endpos < 0)
 989                 return s;
 990         else
 991                 return substring(s, 0, endpos);
 992 }
 993
 994 float strhasword(string s, string w)
 995 {
 996         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 997 }
 998
 999 void Map_MarkAsRecent(string m)
1000 {
1001         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1002 }
1003
1004 float Map_IsRecent(string m)
1005 {
1006         return strhasword(autocvar_g_maplist_mostrecent, m);
1007 }
1008
1009 float Map_Check(float position, float pass)
1010 {
1011         string filename;
1012         string map_next;
1013         map_next = argv(position);
1014         if(pass <= 1)
1015         {
1016                 if(Map_IsRecent(map_next))
1017                         return 0;
1018         }
1019         filename = Map_Filename(position);
1020         if(MapInfo_CheckMap(map_next))
1021         {
1022                 if(pass == 2)
1023                         return 1;
1024                 if(MapHasRightSize(map_next))
1025                         return 1;
1026                 return 0;
1027         }
1028         else
1029                 dprint( "Couldn't select '", filename, "'..\n" );
1030
1031         return 0;
1032 }
1033
1034 void Map_Goto_SetStr(string nextmapname)
1035 {
1036         if(getmapname_stored != "")
1037                 strunzone(getmapname_stored);
1038         if(nextmapname == "")
1039                 getmapname_stored = "";
1040         else
1041                 getmapname_stored = strzone(nextmapname);
1042 }
1043
1044 void Map_Goto_SetFloat(float position)
1045 {
1046         cvar_set("g_maplist_index", ftos(position));
1047         Map_Goto_SetStr(argv(position));
1048 }
1049
1050 void Map_Goto(float reinit)
1051 {
1052         MapInfo_LoadMap(getmapname_stored, reinit);
1053 }
1054
1055 // return codes of map selectors:
1056 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1057 //   -2 = permanent failure
1058 float() MaplistMethod_Iterate = // usual method
1059 {
1060         float pass, i;
1061
1062         dprint("Trying MaplistMethod_Iterate\n");
1063
1064         for(pass = 1; pass <= 2; ++pass)
1065         {
1066                 for(i = 1; i < Map_Count; ++i)
1067                 {
1068                         float mapindex;
1069                         mapindex = mod(i + Map_Current, Map_Count);
1070                         if(Map_Check(mapindex, pass))
1071                                 return mapindex;
1072                 }
1073         }
1074         return -1;
1075 }
1076
1077 float() MaplistMethod_Repeat = // fallback method
1078 {
1079         dprint("Trying MaplistMethod_Repeat\n");
1080
1081         if(Map_Check(Map_Current, 2))
1082                 return Map_Current;
1083         return -2;
1084 }
1085
1086 float() MaplistMethod_Random = // random map selection
1087 {
1088         float i, imax;
1089
1090         dprint("Trying MaplistMethod_Random\n");
1091
1092         imax = 42;
1093
1094         for(i = 0; i <= imax; ++i)
1095         {
1096                 float mapindex;
1097                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1098                 if(Map_Check(mapindex, 1))
1099                         return mapindex;
1100         }
1101         return -1;
1102 }
1103
1104 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1105 // the exponent sets a bias on the map selection:
1106 // the higher the exponent, the less likely "shortly repeated" same maps are
1107 {
1108         float i, j, imax, insertpos;
1109
1110         dprint("Trying MaplistMethod_Shuffle\n");
1111
1112         imax = 42;
1113
1114         for(i = 0; i <= imax; ++i)
1115         {
1116                 string newlist;
1117
1118                 // now reinsert this at another position
1119                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1120                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1121                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1122                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1123
1124                 // insert the current map there
1125                 newlist = "";
1126                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1127                         newlist = strcat(newlist, " ", argv(j));
1128                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1129                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1130                         newlist = strcat(newlist, " ", argv(j));
1131                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1132                 cvar_set("g_maplist", newlist);
1133                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1134
1135                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1136                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1137                 if(Map_Check(Map_Current, 1))
1138                         return Map_Current;
1139         }
1140         return -1;
1141 }
1142
1143 void Maplist_Init()
1144 {
1145         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1146         float i;
1147         for (i = 0; i < Map_Count; ++i)
1148                 if (Map_Check(i, 2))
1149                         break;
1150         if (i == Map_Count)
1151         {
1152                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1153                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1154                 if(autocvar_g_maplist_shuffle)
1155                         ShuffleMaplist();
1156                 localcmd("\nmenu_cmd sync\n");
1157                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1158         }
1159         if(Map_Count == 0)
1160                 error("empty maplist, cannot select a new map");
1161         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1162
1163         if(Map_Current_Name)
1164                 strunzone(Map_Current_Name);
1165         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1166         // this may or may not be correct, but who cares, in the worst case a map
1167         // isn't chosen in the first pass that should have been
1168 }
1169
1170 string GetNextMap()
1171 {
1172         float nextMap;
1173
1174         Maplist_Init();
1175         nextMap = -1;
1176
1177         if(nextMap == -1)
1178                 if(autocvar_g_maplist_shuffle > 0)
1179                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1180
1181         if(nextMap == -1)
1182                 if(autocvar_g_maplist_selectrandom)
1183                         nextMap = MaplistMethod_Random();
1184
1185         if(nextMap == -1)
1186                 nextMap = MaplistMethod_Iterate();
1187
1188         if(nextMap == -1)
1189                 nextMap = MaplistMethod_Repeat();
1190
1191         if(nextMap >= 0)
1192         {
1193                 Map_Goto_SetFloat(nextMap);
1194                 return getmapname_stored;
1195         }
1196
1197         return "";
1198 }
1199
1200 float DoNextMapOverride(float reinit)
1201 {
1202         if(autocvar_g_campaign)
1203         {
1204                 CampaignPostIntermission();
1205                 alreadychangedlevel = TRUE;
1206                 return TRUE;
1207         }
1208         if(autocvar_quit_when_empty)
1209         {
1210                 if(player_count <= currentbots)
1211                 {
1212                         localcmd("quit\n");
1213                         alreadychangedlevel = TRUE;
1214                         return TRUE;
1215                 }
1216         }
1217         if(autocvar_quit_and_redirect != "")
1218         {
1219                 redirection_target = strzone(autocvar_quit_and_redirect);
1220                 alreadychangedlevel = TRUE;
1221                 return TRUE;
1222         }
1223         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1224         {
1225                 localcmd("restart\n");
1226                 alreadychangedlevel = TRUE;
1227                 return TRUE;
1228         }
1229         if(autocvar_nextmap != "")
1230         {
1231                 string m;
1232                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1233                 cvar_set("nextmap",m);
1234
1235                 if(!m || gametypevote)
1236                         return FALSE;
1237                 if(autocvar_sv_vote_gametype)
1238                 {
1239                         Map_Goto_SetStr(m);
1240                         return FALSE;
1241                 }
1242
1243                 if(MapInfo_CheckMap(m))
1244                 {
1245                         Map_Goto_SetStr(m);
1246                         Map_Goto(reinit);
1247                         alreadychangedlevel = TRUE;
1248                         return TRUE;
1249                 }
1250         }
1251         if(!reinit && autocvar_lastlevel)
1252         {
1253                 cvar_settemp_restore();
1254                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1255                 alreadychangedlevel = TRUE;
1256                 return TRUE;
1257         }
1258         return FALSE;
1259 }
1260
1261 void GotoNextMap(float reinit)
1262 {
1263         //string nextmap;
1264         //float n, nummaps;
1265         //string s;
1266         if (alreadychangedlevel)
1267                 return;
1268         alreadychangedlevel = TRUE;
1269
1270         string nextMap;
1271
1272         nextMap = GetNextMap();
1273         if(nextMap == "")
1274                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1275         Map_Goto(reinit);
1276 }
1277
1278
1279 /*
1280 ============
1281 IntermissionThink
1282
1283 When the player presses attack or jump, change to the next level
1284 ============
1285 */
1286 .float autoscreenshot;
1287 void IntermissionThink()
1288 {
1289         FixIntermissionClient(self);
1290
1291         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1292         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1293
1294         if( (server_screenshot || client_screenshot)
1295                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1296         {
1297                 self.autoscreenshot = -1;
1298                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1299                 return;
1300         }
1301
1302         if (time < intermission_exittime)
1303                 return;
1304
1305         if(!mapvote_initialized)
1306                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1307                         return;
1308
1309         MapVote_Start();
1310 }
1311
1312 /*
1313 ============
1314 FindIntermission
1315
1316 Returns the entity to view from
1317 ============
1318 */
1319 /*
1320 entity FindIntermission()
1321 {
1322         local   entity spot;
1323         local   float cyc;
1324
1325 // look for info_intermission first
1326         spot = find (world, classname, "info_intermission");
1327         if (spot)
1328         {       // pick a random one
1329                 cyc = random() * 4;
1330                 while (cyc > 1)
1331                 {
1332                         spot = find (spot, classname, "info_intermission");
1333                         if (!spot)
1334                                 spot = find (spot, classname, "info_intermission");
1335                         cyc = cyc - 1;
1336                 }
1337                 return spot;
1338         }
1339
1340 // then look for the start position
1341         spot = find (world, classname, "info_player_start");
1342         if (spot)
1343                 return spot;
1344
1345 // testinfo_player_start is only found in regioned levels
1346         spot = find (world, classname, "testplayerstart");
1347         if (spot)
1348                 return spot;
1349
1350 // then look for the start position
1351         spot = find (world, classname, "info_player_deathmatch");
1352         if (spot)
1353                 return spot;
1354
1355         //objerror ("FindIntermission: no spot");
1356         return world;
1357 }
1358 */
1359
1360 /*
1361 ===============================================================================
1362
1363 RULES
1364
1365 ===============================================================================
1366 */
1367
1368 void DumpStats(float final)
1369 {
1370         float file;
1371         string s;
1372         float to_console;
1373         float to_eventlog;
1374         float to_file;
1375         float i;
1376
1377         to_console = autocvar_sv_logscores_console;
1378         to_eventlog = autocvar_sv_eventlog;
1379         to_file = autocvar_sv_logscores_file;
1380
1381         if(!final)
1382         {
1383                 to_console = TRUE; // always print printstats replies
1384                 to_eventlog = FALSE; // but never print them to the event log
1385         }
1386
1387         if(to_eventlog)
1388                 if(autocvar_sv_eventlog_console)
1389                         to_console = FALSE; // otherwise we get the output twice
1390
1391         if(final)
1392                 s = ":scores:";
1393         else
1394                 s = ":status:";
1395         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1396
1397         if(to_console)
1398                 print(s, "\n");
1399         if(to_eventlog)
1400                 GameLogEcho(s);
1401
1402         file = -1;
1403         if(to_file)
1404         {
1405                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1406                 if(file == -1)
1407                         to_file = FALSE;
1408                 else
1409                         fputs(file, strcat(s, "\n"));
1410         }
1411
1412         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1413         if(to_console)
1414                 print(s, "\n");
1415         if(to_eventlog)
1416                 GameLogEcho(s);
1417         if(to_file)
1418                 fputs(file, strcat(s, "\n"));
1419
1420         FOR_EACH_CLIENT(other)
1421         {
1422                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1423                 {
1424                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1425                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1426                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1427                                 s = strcat(s, ftos(other.team), ":");
1428                         else
1429                                 s = strcat(s, "spectator:");
1430
1431                         if(to_console)
1432                                 print(s, other.netname, "\n");
1433                         if(to_eventlog)
1434                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1435                         if(to_file)
1436                                 fputs(file, strcat(s, other.netname, "\n"));
1437                 }
1438         }
1439
1440         if(teamplay)
1441         {
1442                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1443                 if(to_console)
1444                         print(s, "\n");
1445                 if(to_eventlog)
1446                         GameLogEcho(s);
1447                 if(to_file)
1448                         fputs(file, strcat(s, "\n"));
1449
1450                 for(i = 1; i < 16; ++i)
1451                 {
1452                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1453                         s = strcat(s, ":", ftos(i));
1454                         if(to_console)
1455                                 print(s, "\n");
1456                         if(to_eventlog)
1457                                 GameLogEcho(s);
1458                         if(to_file)
1459                                 fputs(file, strcat(s, "\n"));
1460                 }
1461         }
1462
1463         if(to_console)
1464                 print(":end\n");
1465         if(to_eventlog)
1466                 GameLogEcho(":end");
1467         if(to_file)
1468         {
1469                 fputs(file, ":end\n");
1470                 fclose(file);
1471         }
1472 }
1473
1474 void FixIntermissionClient(entity e)
1475 {
1476         string s;
1477         if(!e.autoscreenshot) // initial call
1478         {
1479                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1480                 e.health = -2342;
1481                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1482                 e.solid = SOLID_NOT;
1483                 e.movetype = MOVETYPE_NONE;
1484                 e.takedamage = DAMAGE_NO;
1485                 if(e.weaponentity)
1486                 {
1487                         e.weaponentity.effects = EF_NODRAW;
1488                         if (e.weaponentity.weaponentity)
1489                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1490                 }
1491                 if(IS_REAL_CLIENT(e))
1492                 {
1493                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1494                         s = autocvar_sv_intermission_cdtrack;
1495                         if(s != "")
1496                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1497                         msg_entity = e;
1498                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1499                 }
1500         }
1501 }
1502
1503 /*
1504 go to the next level for deathmatch
1505 only called if a time or frag limit has expired
1506 */
1507 void NextLevel()
1508 {
1509         gameover = TRUE;
1510
1511         intermission_running = 1;
1512
1513 // enforce a wait time before allowing changelevel
1514         if(player_count > 0)
1515                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1516         else
1517                 intermission_exittime = -1;
1518
1519         /*
1520         WriteByte (MSG_ALL, SVC_CDTRACK);
1521         WriteByte (MSG_ALL, 3);
1522         WriteByte (MSG_ALL, 3);
1523         // done in FixIntermission
1524         */
1525
1526         //pos = FindIntermission ();
1527
1528         VoteReset();
1529
1530         DumpStats(TRUE);
1531
1532         // send statistics
1533         entity e;
1534         PlayerStats_EndMatch(1);
1535         FOR_EACH_CLIENT(e)
1536                 PlayerStats_AddGlobalInfo(e);
1537         PlayerStats_Shutdown();
1538         WeaponStats_Shutdown();
1539
1540         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1541
1542         if(autocvar_sv_eventlog)
1543                 GameLogEcho(":gameover");
1544
1545         GameLogClose();
1546
1547         FOR_EACH_PLAYER(other) {
1548                 FixIntermissionClient(other);
1549                 if(other.winning)
1550                         bprint(other.netname, " ^7wins.\n");
1551         }
1552
1553         if(autocvar_g_campaign)
1554                 CampaignPreIntermission();
1555
1556         MUTATOR_CALLHOOK(MatchEnd);
1557
1558         localcmd("\nsv_hook_gameend\n");
1559 }
1560
1561 /*
1562 ============
1563 CheckRules_Player
1564
1565 Exit deathmatch games upon conditions
1566 ============
1567 */
1568 void CheckRules_Player()
1569 {
1570         if (gameover)   // someone else quit the game already
1571                 return;
1572
1573         if(self.deadflag == DEAD_NO)
1574                 self.play_time += frametime;
1575
1576         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1577         //   (div0: and that in CheckRules_World please)
1578 }
1579
1580 float checkrules_equality;
1581 float checkrules_suddendeathwarning;
1582 float checkrules_suddendeathend;
1583 float checkrules_overtimesadded; //how many overtimes have been already added
1584
1585 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1586 const float WINNING_YES = 1; // winner found
1587 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1588 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1589
1590 float InitiateSuddenDeath()
1591 {
1592         // Check first whether normal overtimes could be added before initiating suddendeath mode
1593         // - for this timelimit_overtime needs to be >0 of course
1594         // - also check the winning condition calculated in the previous frame and only add normal overtime
1595         //   again, if at the point at which timelimit would be extended again, still no winner was found
1596         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1597         {
1598                 return 1; // need to call InitiateOvertime later
1599         }
1600         else
1601         {
1602                 if(!checkrules_suddendeathend)
1603                 {
1604                         if(autocvar_g_campaign)
1605                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1606                         else
1607                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1608                         if(g_race && !g_race_qualifying)
1609                                 race_StartCompleting();
1610                 }
1611                 return 0;
1612         }
1613 }
1614
1615 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1616 {
1617         ++checkrules_overtimesadded;
1618         //add one more overtime by simply extending the timelimit
1619         float tl;
1620         tl = autocvar_timelimit;
1621         tl += autocvar_timelimit_overtime;
1622         cvar_set("timelimit", ftos(tl));
1623
1624         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1625 }
1626
1627 float GetWinningCode(float fraglimitreached, float equality)
1628 {
1629         if(autocvar_g_campaign == 1)
1630                 if(fraglimitreached)
1631                         return WINNING_YES;
1632                 else
1633                         return WINNING_NO;
1634
1635         else
1636                 if(equality)
1637                         if(fraglimitreached)
1638                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1639                         else
1640                                 return WINNING_NEVER;
1641                 else
1642                         if(fraglimitreached)
1643                                 return WINNING_YES;
1644                         else
1645                                 return WINNING_NO;
1646 }
1647
1648 // set the .winning flag for exactly those players with a given field value
1649 void SetWinners(.float field, float value)
1650 {
1651         entity head;
1652         FOR_EACH_PLAYER(head)
1653                 head.winning = (head.field == value);
1654 }
1655
1656 // set the .winning flag for those players with a given field value
1657 void AddWinners(.float field, float value)
1658 {
1659         entity head;
1660         FOR_EACH_PLAYER(head)
1661                 if(head.field == value)
1662                         head.winning = 1;
1663 }
1664
1665 // clear the .winning flags
1666 void ClearWinners(void)
1667 {
1668         entity head;
1669         FOR_EACH_PLAYER(head)
1670                 head.winning = 0;
1671 }
1672
1673 // Onslaught winning condition:
1674 // game terminates if only one team has a working generator (or none)
1675 float WinningCondition_Onslaught()
1676 {
1677         entity head;
1678         float t1, t2, t3, t4;
1679
1680         WinningConditionHelper(); // set worldstatus
1681
1682         if(warmup_stage)
1683                 return WINNING_NO;
1684
1685         // first check if the game has ended
1686         t1 = t2 = t3 = t4 = 0;
1687         head = find(world, classname, "onslaught_generator");
1688         while (head)
1689         {
1690                 if (head.health > 0)
1691                 {
1692                         if (head.team == NUM_TEAM_1) t1 = 1;
1693                         if (head.team == NUM_TEAM_2) t2 = 1;
1694                         if (head.team == NUM_TEAM_3) t3 = 1;
1695                         if (head.team == NUM_TEAM_4) t4 = 1;
1696                 }
1697                 head = find(head, classname, "onslaught_generator");
1698         }
1699         if (t1 + t2 + t3 + t4 < 2)
1700         {
1701                 // game over, only one team remains (or none)
1702                 ClearWinners();
1703                 if (t1) SetWinners(team, NUM_TEAM_1);
1704                 if (t2) SetWinners(team, NUM_TEAM_2);
1705                 if (t3) SetWinners(team, NUM_TEAM_3);
1706                 if (t4) SetWinners(team, NUM_TEAM_4);
1707                 dprint("Have a winner, ending game.\n");
1708                 return WINNING_YES;
1709         }
1710
1711         // Two or more teams remain
1712         return WINNING_NO;
1713 }
1714
1715 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1716 // they win. Otherwise the defending team wins once the timelimit passes.
1717 void assault_new_round();
1718 float WinningCondition_Assault()
1719 {
1720         float status;
1721
1722         WinningConditionHelper(); // set worldstatus
1723
1724         status = WINNING_NO;
1725         // as the timelimit has not yet passed just assume the defending team will win
1726         if(assault_attacker_team == NUM_TEAM_1)
1727         {
1728                 SetWinners(team, NUM_TEAM_2);
1729         }
1730         else
1731         {
1732                 SetWinners(team, NUM_TEAM_1);
1733         }
1734
1735         entity ent;
1736         ent = find(world, classname, "target_assault_roundend");
1737         if(ent)
1738         {
1739                 if(ent.winning) // round end has been triggered by attacking team
1740                 {
1741                         bprint("ASSAULT: round completed...\n");
1742                         SetWinners(team, assault_attacker_team);
1743
1744                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1745
1746                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1747                         {
1748                                 status = WINNING_YES;
1749                         }
1750                         else
1751                         {
1752                                 entity oldself;
1753                                 oldself = self;
1754                                 self = ent;
1755                                 assault_new_round();
1756                                 self = oldself;
1757                         }
1758                 }
1759         }
1760
1761         return status;
1762 }
1763
1764 // LMS winning condition: game terminates if and only if there's at most one
1765 // one player who's living lives. Top two scores being equal cancels the time
1766 // limit.
1767 float WinningCondition_LMS()
1768 {
1769         entity head, head2;
1770         float have_player;
1771         float have_players;
1772         float l;
1773
1774         have_player = FALSE;
1775         have_players = FALSE;
1776         l = LMS_NewPlayerLives();
1777
1778         head = find(world, classname, "player");
1779         if(head)
1780                 have_player = TRUE;
1781         head2 = find(head, classname, "player");
1782         if(head2)
1783                 have_players = TRUE;
1784
1785         if(have_player)
1786         {
1787                 // we have at least one player
1788                 if(have_players)
1789                 {
1790                         // two or more active players - continue with the game
1791                 }
1792                 else
1793                 {
1794                         // exactly one player?
1795
1796                         ClearWinners();
1797                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1798
1799                         if(l)
1800                         {
1801                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1802                                 return WINNING_NO;
1803                         }
1804                         else
1805                         {
1806                                 // a winner!
1807                                 // and assign him his first place
1808                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1809                                 return WINNING_YES;
1810                         }
1811                 }
1812         }
1813         else
1814         {
1815                 // nobody is playing at all...
1816                 if(l)
1817                 {
1818                         // wait for players...
1819                 }
1820                 else
1821                 {
1822                         // SNAFU (maybe a draw game?)
1823                         ClearWinners();
1824                         dprint("No players, ending game.\n");
1825                         return WINNING_YES;
1826                 }
1827         }
1828
1829         // When we get here, we have at least two players who are actually LIVING,
1830         // now check if the top two players have equal score.
1831         WinningConditionHelper();
1832
1833         ClearWinners();
1834         if(WinningConditionHelper_winner)
1835                 WinningConditionHelper_winner.winning = TRUE;
1836         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1837                 return WINNING_NEVER;
1838
1839         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1840         return WINNING_NO;
1841 }
1842
1843 void ShuffleMaplist()
1844 {
1845         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1846 }
1847
1848 float leaderfrags;
1849 float WinningCondition_Scores(float limit, float leadlimit)
1850 {
1851         float limitreached;
1852
1853         // TODO make everything use THIS winning condition (except LMS)
1854         WinningConditionHelper();
1855
1856         if(teamplay)
1857         {
1858                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1859                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1860                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1861                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1862         }
1863
1864         ClearWinners();
1865         if(WinningConditionHelper_winner)
1866                 WinningConditionHelper_winner.winning = 1;
1867         if(WinningConditionHelper_winnerteam >= 0)
1868                 SetWinners(team, WinningConditionHelper_winnerteam);
1869
1870         if(WinningConditionHelper_lowerisbetter)
1871         {
1872                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1873                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1874                 limit = -limit;
1875         }
1876
1877         if(WinningConditionHelper_zeroisworst)
1878                 leadlimit = 0; // not supported in this mode
1879
1880         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1881         // these modes always score in increments of 1, thus this makes sense
1882         {
1883                 if(leaderfrags != WinningConditionHelper_topscore)
1884                 {
1885                         leaderfrags = WinningConditionHelper_topscore;
1886
1887                         if (limit)
1888                         if (leaderfrags == limit - 1)
1889                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1890                         else if (leaderfrags == limit - 2)
1891                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1892                         else if (leaderfrags == limit - 3)
1893                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1894                 }
1895         }
1896
1897         limitreached = FALSE;
1898         if(limit)
1899                 if(WinningConditionHelper_topscore >= limit)
1900                         limitreached = TRUE;
1901         if(leadlimit)
1902         {
1903                 float leadlimitreached;
1904                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1905                 if(autocvar_leadlimit_and_fraglimit)
1906                         limitreached = (limitreached && leadlimitreached);
1907                 else
1908                         limitreached = (limitreached || leadlimitreached);
1909         }
1910
1911         if(limit)
1912                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1913
1914         return GetWinningCode(
1915                 WinningConditionHelper_topscore && limitreached,
1916                 WinningConditionHelper_equality
1917         );
1918 }
1919
1920 float WinningCondition_Race(float fraglimit)
1921 {
1922         float wc;
1923         entity p;
1924         float n, c;
1925
1926         n = 0;
1927         c = 0;
1928         FOR_EACH_PLAYER(p)
1929         {
1930                 ++n;
1931                 if(p.race_completed)
1932                         ++c;
1933         }
1934         if(n && (n == c))
1935                 return WINNING_YES;
1936         wc = WinningCondition_Scores(fraglimit, 0);
1937
1938         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1939         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1940         // do NOT support equality when the laps are all raced!
1941                 return WINNING_STARTSUDDENDEATHOVERTIME;
1942         else
1943                 return WINNING_NEVER;
1944 }
1945
1946 float WinningCondition_QualifyingThenRace(float limit)
1947 {
1948         float wc;
1949         wc = WinningCondition_Scores(limit, 0);
1950
1951         // NEVER initiate overtime
1952         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1953         {
1954                 return WINNING_YES;
1955         }
1956
1957         return wc;
1958 }
1959
1960 float WinningCondition_RanOutOfSpawns()
1961 {
1962         entity head;
1963
1964         if(have_team_spawns <= 0)
1965                 return WINNING_NO;
1966
1967         if(autocvar_g_spawn_useallspawns <= 0)
1968                 return WINNING_NO;
1969
1970         if(!some_spawn_has_been_used)
1971                 return WINNING_NO;
1972
1973         team1_score = team2_score = team3_score = team4_score = 0;
1974
1975         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1976         {
1977                 if(head.team == NUM_TEAM_1)
1978                         team1_score = 1;
1979                 else if(head.team == NUM_TEAM_2)
1980                         team2_score = 1;
1981                 else if(head.team == NUM_TEAM_3)
1982                         team3_score = 1;
1983                 else if(head.team == NUM_TEAM_4)
1984                         team4_score = 1;
1985         }
1986
1987         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1988         {
1989                 if(head.team == NUM_TEAM_1)
1990                         team1_score = 1;
1991                 else if(head.team == NUM_TEAM_2)
1992                         team2_score = 1;
1993                 else if(head.team == NUM_TEAM_3)
1994                         team3_score = 1;
1995                 else if(head.team == NUM_TEAM_4)
1996                         team4_score = 1;
1997         }
1998
1999         ClearWinners();
2000         if(team1_score + team2_score + team3_score + team4_score == 0)
2001         {
2002                 checkrules_equality = TRUE;
2003                 return WINNING_YES;
2004         }
2005         else if(team1_score + team2_score + team3_score + team4_score == 1)
2006         {
2007                 float t, i;
2008                 if(team1_score)
2009                         t = NUM_TEAM_1;
2010                 else if(team2_score)
2011                         t = NUM_TEAM_2;
2012                 else if(team3_score)
2013                         t = NUM_TEAM_3;
2014                 else // if(team4_score)
2015                         t = NUM_TEAM_4;
2016                 CheckAllowedTeams(world);
2017                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2018                 {
2019                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2020                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2021                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2022                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2023                 }
2024
2025                 AddWinners(team, t);
2026                 return WINNING_YES;
2027         }
2028         else
2029                 return WINNING_NO;
2030 }
2031
2032 /*
2033 ============
2034 CheckRules_World
2035
2036 Exit deathmatch games upon conditions
2037 ============
2038 */
2039 void ReadyRestart();
2040 void CheckRules_World()
2041 {
2042         float timelimit;
2043         float fraglimit;
2044         float leadlimit;
2045
2046         VoteThink();
2047         MapVote_Think();
2048
2049         SetDefaultAlpha();
2050
2051         if (gameover)   // someone else quit the game already
2052         {
2053                 if(player_count == 0) // Nobody there? Then let's go to the next map
2054                         MapVote_Start();
2055                         // this will actually check the player count in the next frame
2056                         // again, but this shouldn't hurt
2057                 return;
2058         }
2059
2060         timelimit = autocvar_timelimit * 60;
2061         fraglimit = autocvar_fraglimit;
2062         leadlimit = autocvar_leadlimit;
2063
2064         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2065         {
2066                 if(timelimit > 0)
2067                         timelimit = 0; // timelimit is not made for warmup
2068                 if(fraglimit > 0)
2069                         fraglimit = 0; // no fraglimit for now
2070                 leadlimit = 0; // no leadlimit for now
2071         }
2072
2073         if(timelimit > 0)
2074         {
2075                 timelimit += game_starttime;
2076         }
2077         else if (timelimit < 0)
2078         {
2079                 // endmatch
2080                 NextLevel();
2081                 return;
2082         }
2083
2084         if(g_onslaught)
2085                 timelimit = 0; // ONS has its own overtime rule
2086
2087         float wantovertime;
2088         wantovertime = 0;
2089
2090         if(timelimit > game_starttime)
2091                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2092         else
2093                 game_completion_ratio = 0;
2094
2095         if(checkrules_suddendeathend)
2096         {
2097                 if(!checkrules_suddendeathwarning)
2098                 {
2099                         checkrules_suddendeathwarning = TRUE;
2100                         if(g_race && !g_race_qualifying)
2101                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2102                         else
2103                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2104                 }
2105         }
2106         else
2107         {
2108                 if (timelimit && time >= timelimit)
2109                 {
2110                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2111                         {
2112                                 float totalplayers;
2113                                 float playerswithlaps;
2114                                 float readyplayers;
2115                                 entity head;
2116                                 totalplayers = playerswithlaps = readyplayers = 0;
2117                                 FOR_EACH_PLAYER(head)
2118                                 {
2119                                         ++totalplayers;
2120                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2121                                                 ++playerswithlaps;
2122                                         if(head.ready)
2123                                                 ++readyplayers;
2124                                 }
2125
2126                                 // at least 2 of the players have completed a lap: start the RACE
2127                                 // otherwise, the players should end the qualifying on their own
2128                                 if(readyplayers || playerswithlaps >= 2)
2129                                 {
2130                                         checkrules_suddendeathend = 0;
2131                                         ReadyRestart(); // go to race
2132                                         return;
2133                                 }
2134                                 else
2135                                         wantovertime |= InitiateSuddenDeath();
2136                         }
2137                         else
2138                                 wantovertime |= InitiateSuddenDeath();
2139                 }
2140         }
2141
2142         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2143         {
2144                 NextLevel();
2145                 return;
2146         }
2147
2148         float checkrules_status;
2149         checkrules_status = WinningCondition_RanOutOfSpawns();
2150         if(checkrules_status == WINNING_YES)
2151         {
2152                 bprint("Hey! Someone ran out of spawns!\n");
2153         }
2154         else if(g_race && !g_race_qualifying && timelimit >= 0)
2155         {
2156                 checkrules_status = WinningCondition_Race(fraglimit);
2157                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2158         }
2159         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2160         {
2161                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2162                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2163         }
2164         else if(g_assault)
2165         {
2166                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2167         }
2168         else if(g_lms)
2169         {
2170                 checkrules_status = WinningCondition_LMS();
2171         }
2172         else if (g_onslaught)
2173         {
2174                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2175         }
2176         else
2177         {
2178                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2179                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2180         }
2181
2182         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2183         {
2184                 checkrules_status = WINNING_NEVER;
2185                 checkrules_overtimesadded = -1;
2186                 wantovertime |= InitiateSuddenDeath();
2187         }
2188
2189         if(checkrules_status == WINNING_NEVER)
2190                 // equality cases! Nobody wins if the overtime ends in a draw.
2191                 ClearWinners();
2192
2193         if(wantovertime)
2194         {
2195                 if(checkrules_status == WINNING_NEVER)
2196                         InitiateOvertime();
2197                 else
2198                         checkrules_status = WINNING_YES;
2199         }
2200
2201         if(checkrules_suddendeathend)
2202                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2203                         checkrules_status = WINNING_YES;
2204
2205         if(checkrules_status == WINNING_YES)
2206         {
2207                 //print("WINNING\n");
2208                 NextLevel();
2209         }
2210 }
2211
2212 string GotoMap(string m)
2213 {
2214         m = GameTypeVote_MapInfo_FixName(m);
2215         if (!m)
2216                 return "The map you suggested is not available on this server.";
2217         if (!autocvar_sv_vote_gametype)
2218         if(!MapInfo_CheckMap(m))
2219                 return "The map you suggested does not support the current game mode.";
2220         cvar_set("nextmap", m);
2221         cvar_set("timelimit", "-1");
2222         if(mapvote_initialized || alreadychangedlevel)
2223         {
2224                 if(DoNextMapOverride(0))
2225                         return "Map switch initiated.";
2226                 else
2227                         return "Hm... no. For some reason I like THIS map more.";
2228         }
2229         else
2230                 return "Map switch will happen after scoreboard.";
2231 }
2232
2233
2234 void EndFrame()
2235 {
2236         anticheat_endframe();
2237
2238         float altime;
2239         FOR_EACH_REALCLIENT(self)
2240         {
2241                 if(IS_SPEC(self))
2242                 {
2243                         if(self.enemy.typehitsound)
2244                                 self.typehit_time = time;
2245                         else if(self.enemy.hitsound)
2246                                 self.hit_time = time;
2247                 }
2248                 else
2249                 {
2250                         if(self.typehitsound)
2251                                 self.typehit_time = time;
2252                         else if(self.hitsound)
2253                                 self.hit_time = time;
2254                 }
2255         }
2256         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2257         // add 1 frametime because after this, engine SV_Physics
2258         // increases time by a frametime and then networks the frame
2259         // add another frametime because client shows everything with
2260         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2261         // needed!
2262         FOR_EACH_CLIENT(self)
2263         {
2264                 self.hitsound = FALSE;
2265                 self.typehitsound = FALSE;
2266                 antilag_record(self, altime);
2267         }
2268 }
2269
2270
2271 /*
2272  * RedirectionThink:
2273  * returns TRUE if redirecting
2274  */
2275 float redirection_timeout;
2276 float redirection_nextthink;
2277 float RedirectionThink()
2278 {
2279         float clients_found;
2280
2281         if(redirection_target == "")
2282                 return FALSE;
2283
2284         if(!redirection_timeout)
2285         {
2286                 cvar_set("sv_public", "-2");
2287                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2288                 if(redirection_target == "self")
2289                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2290                 else
2291                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2292         }
2293
2294         if(time < redirection_nextthink)
2295                 return TRUE;
2296
2297         redirection_nextthink = time + 1;
2298
2299         clients_found = 0;
2300         FOR_EACH_REALCLIENT(self)
2301         {
2302                 // TODO add timer
2303                 print("Redirecting: sending connect command to ", self.netname, "\n");
2304                 if(redirection_target == "self")
2305                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2306                 else
2307                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2308                 ++clients_found;
2309         }
2310
2311         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2312
2313         if(time > redirection_timeout || clients_found == 0)
2314                 localcmd("\nwait; wait; wait; quit\n");
2315
2316         return TRUE;
2317 }
2318
2319 void TargetMusic_RestoreGame();
2320 void RestoreGame()
2321 {
2322         // Loaded from a save game
2323         // some things then break, so let's work around them...
2324
2325         // Progs DB (capture records)
2326         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2327
2328         // Mapinfo
2329         MapInfo_Shutdown();
2330         MapInfo_Enumerate();
2331         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2332         WeaponStats_Init();
2333
2334         TargetMusic_RestoreGame();
2335 }
2336
2337 void Shutdown()
2338 {
2339         entity e;
2340
2341         gameover = 2;
2342
2343         if(world_initialized > 0)
2344         {
2345                 world_initialized = 0;
2346                 print("Saving persistent data...\n");
2347                 Ban_SaveBans();
2348
2349                 PlayerStats_EndMatch(0);
2350                 FOR_EACH_CLIENT(e)
2351                         PlayerStats_AddGlobalInfo(e);
2352                 PlayerStats_Shutdown();
2353
2354                 if(!cheatcount_total)
2355                 {
2356                         if(autocvar_sv_db_saveasdump)
2357                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2358                         else
2359                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2360                 }
2361                 if(autocvar_developer)
2362                 {
2363                         if(autocvar_sv_db_saveasdump)
2364                                 db_dump(TemporaryDB, "server-temp.db");
2365                         else
2366                                 db_save(TemporaryDB, "server-temp.db");
2367                 }
2368                 CheatShutdown(); // must be after cheatcount check
2369                 db_close(ServerProgsDB);
2370                 db_close(TemporaryDB);
2371                 print("done!\n");
2372                 // tell the bot system the game is ending now
2373                 bot_endgame();
2374
2375                 WeaponStats_Shutdown();
2376                 MapInfo_Shutdown();
2377         }
2378         else if(world_initialized == 0)
2379         {
2380                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2381         }
2382 }