qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "secret.qh"
  21 #include "teamplay.qh"
  22 #include "waypointsprites.qh"
  23 #include "weapons/weaponstats.qh"
  24 #include "../common/buffs.qh"
  25 #include "../common/constants.qh"
  26 #include "../common/deathtypes.qh"
  27 #include "../common/mapinfo.qh"
  28 #include "../common/monsters/monsters.qh"
  29 #include "../common/monsters/sv_monsters.qh"
  30 #include "../common/notifications.qh"
  31 #include "../common/playerstats.qh"
  32 #include "../common/stats.qh"
  33 #include "../common/teams.qh"
  34 #include "../common/util.qh"
  35 #include "../common/weapons/weapons.qh"
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if(autocvar_g_running_guns)
 100         {
 101                 default_player_alpha = -1;
 102                 default_weapon_alpha = +1;
 103         }
 104         else if(g_cloaked)
 105         {
 106                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 107                 default_weapon_alpha = default_player_alpha;
 108         }
 109         else
 110         {
 111                 default_player_alpha = autocvar_g_player_alpha;
 112                 if(default_player_alpha == 0)
 113                         default_player_alpha = 1;
 114                 default_weapon_alpha = default_player_alpha;
 115         }
 116 }
 117
 118 void GotoFirstMap()
 119 {
 120         float n;
 121         if(autocvar__sv_init)
 122         {
 123                 // cvar_set("_sv_init", "0");
 124                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 125                 // to this "init" map on a dedicated server will cause no permanent
 126                 // harm
 127                 if(autocvar_g_maplist_shuffle)
 128                         ShuffleMaplist();
 129                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 130                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 131
 132                 MapInfo_Enumerate();
 133                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 134
 135                 if(!DoNextMapOverride(1))
 136                         GotoNextMap(1);
 137
 138                 return;
 139         }
 140
 141         if(time < 5)
 142         {
 143                 self.nextthink = time;
 144         }
 145         else
 146         {
 147                 self.nextthink = time + 1;
 148                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 149         }
 150 }
 151
 152 void cvar_changes_init()
 153 {
 154         float h;
 155         string k, v, d;
 156         float n, i, adding, pureadding;
 157
 158         if(cvar_changes)
 159                 strunzone(cvar_changes);
 160         cvar_changes = string_null;
 161         if(cvar_purechanges)
 162                 strunzone(cvar_purechanges);
 163         cvar_purechanges = string_null;
 164         cvar_purechanges_count = 0;
 165
 166         h = buf_create();
 167         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 168         n = buf_getsize(h);
 169
 170         adding = true;
 171         pureadding = true;
 172
 173         for(i = 0; i < n; ++i)
 174         {
 175                 k = bufstr_get(h, i);
 176
 177 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 178 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 179 #define BADCVAR(p) if(k == p) continue
 180
 181                 // general excludes and namespaces for server admin used cvars
 182                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 183
 184                 // internal
 185                 BADPREFIX("csqc_");
 186                 BADPREFIX("cvar_check_");
 187                 BADCVAR("gamecfg");
 188                 BADCVAR("g_configversion");
 189                 BADCVAR("g_maplist_index");
 190                 BADCVAR("halflifebsp");
 191                 BADPREFIX("sv_world");
 192
 193                 // client
 194                 BADPREFIX("chase_");
 195                 BADPREFIX("cl_");
 196                 BADPREFIX("con_");
 197                 BADPREFIX("scoreboard_");
 198                 BADPREFIX("g_campaign");
 199                 BADPREFIX("g_waypointsprite_");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("hud_");
 203                 BADPREFIX("m_");
 204                 BADPREFIX("menu_");
 205                 BADPREFIX("net_slist_");
 206                 BADPREFIX("r_");
 207                 BADPREFIX("sbar_");
 208                 BADPREFIX("scr_");
 209                 BADPREFIX("snd_");
 210                 BADPREFIX("show");
 211                 BADPREFIX("sensitivity");
 212                 BADPREFIX("userbind");
 213                 BADPREFIX("v_");
 214                 BADPREFIX("vid_");
 215                 BADPREFIX("crosshair");
 216                 BADCVAR("mod_q3bsp_lightmapmergepower");
 217                 BADCVAR("mod_q3bsp_nolightmaps");
 218                 BADCVAR("fov");
 219                 BADCVAR("mastervolume");
 220                 BADCVAR("volume");
 221                 BADCVAR("bgmvolume");
 222
 223                 // private
 224                 BADCVAR("developer");
 225                 BADCVAR("log_dest_udp");
 226                 BADCVAR("net_address");
 227                 BADCVAR("net_address_ipv6");
 228                 BADCVAR("port");
 229                 BADCVAR("savedgamecfg");
 230                 BADCVAR("serverconfig");
 231                 BADCVAR("sv_autoscreenshot");
 232                 BADCVAR("sv_heartbeatperiod");
 233                 BADCVAR("sv_vote_master_password");
 234                 BADCVAR("sys_colortranslation");
 235                 BADCVAR("sys_specialcharactertranslation");
 236                 BADCVAR("timeformat");
 237                 BADCVAR("timestamps");
 238                 BADPREFIX("developer_");
 239                 BADPREFIX("g_ban_");
 240                 BADPREFIX("g_banned_list");
 241                 BADPREFIX("g_chat_flood_");
 242                 BADPREFIX("g_ghost_items");
 243                 BADPREFIX("g_playerstats_");
 244                 BADPREFIX("g_respawn_ghosts");
 245                 BADPREFIX("g_voice_flood_");
 246                 BADPREFIX("log_file");
 247                 BADPREFIX("rcon_");
 248                 BADPREFIX("sv_allowdownloads");
 249                 BADPREFIX("sv_autodemo");
 250                 BADPREFIX("sv_curl_");
 251                 BADPREFIX("sv_eventlog");
 252                 BADPREFIX("sv_logscores_");
 253                 BADPREFIX("sv_master");
 254                 BADPREFIX("sv_weaponstats_");
 255                 BADPREFIX("sv_waypointsprite_");
 256                 BADCVAR("rescan_pending");
 257
 258                 // these can contain player IDs, so better hide
 259                 BADPREFIX("g_forced_team_");
 260
 261                 // mapinfo
 262                 BADCVAR("fraglimit");
 263                 BADCVAR("g_assault");
 264                 BADCVAR("g_ca");
 265                 BADCVAR("g_ca_teams");
 266                 BADCVAR("g_ctf");
 267                 BADCVAR("g_cts");
 268                 BADCVAR("g_dm");
 269                 BADCVAR("g_domination");
 270                 BADCVAR("g_domination_default_teams");
 271                 BADCVAR("g_freezetag");
 272                 BADCVAR("g_freezetag_teams");
 273                 BADCVAR("g_keepaway");
 274                 BADCVAR("g_keyhunt");
 275                 BADCVAR("g_keyhunt_teams");
 276                 BADCVAR("g_lms");
 277                 BADCVAR("g_nexball");
 278                 BADCVAR("g_onslaught");
 279                 BADCVAR("g_race");
 280                 BADCVAR("g_race_qualifying_timelimit");
 281                 BADCVAR("g_tdm");
 282                 BADCVAR("g_tdm_teams");
 283                 BADCVAR("leadlimit");
 284                 BADCVAR("nextmap");
 285                 BADCVAR("teamplay");
 286                 BADCVAR("timelimit");
 287
 288                 // long
 289                 BADCVAR("hostname");
 290                 BADCVAR("g_maplist");
 291                 BADCVAR("g_maplist_mostrecent");
 292                 BADCVAR("sv_motd");
 293
 294                 v = cvar_string(k);
 295                 d = cvar_defstring(k);
 296                 if(v == d)
 297                         continue;
 298
 299                 if(adding)
 300                 {
 301                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 302                         if(strlen(cvar_changes) > 16384)
 303                         {
 304                                 cvar_changes = "// too many settings have been changed to show them here\n";
 305                                 adding = 0;
 306                         }
 307                 }
 308
 309                 // now check if the changes are actually gameplay relevant
 310
 311                 // does nothing visible
 312                 BADCVAR("captureleadlimit_override");
 313                 BADCVAR("g_balance_kill_delay");
 314                 BADCVAR("g_ca_point_limit");
 315                 BADCVAR("g_ca_point_leadlimit");
 316                 BADCVAR("g_ctf_captimerecord_always");
 317                 BADCVAR("g_ctf_flag_glowtrails");
 318                 BADCVAR("g_ctf_flag_pickup_verbosename");
 319                 BADCVAR("g_domination_point_leadlimit");
 320                 BADCVAR("g_forced_respawn");
 321                 BADCVAR("g_freezetag_point_limit");
 322                 BADCVAR("g_freezetag_point_leadlimit");
 323                 BADCVAR("g_keyhunt_point_leadlimit");
 324                 BADPREFIX("g_mod_");
 325                 BADCVAR("g_invasion_point_limit");
 326                 BADCVAR("g_nexball_goalleadlimit");
 327                 BADCVAR("g_tdm_point_limit");
 328                 BADCVAR("g_tdm_point_leadlimit");
 329                 BADCVAR("leadlimit_and_fraglimit");
 330                 BADCVAR("leadlimit_override");
 331                 BADCVAR("pausable");
 332                 BADCVAR("sv_allow_fullbright");
 333                 BADCVAR("sv_checkforpacketsduringsleep");
 334                 BADCVAR("sv_fraginfo");
 335                 BADCVAR("sv_timeout");
 336                 BADPREFIX("sv_timeout_");
 337                 BADPREFIX("crypto_");
 338                 BADPREFIX("g_chat_");
 339                 BADPREFIX("g_ctf_captimerecord_");
 340                 BADPREFIX("g_maplist_votable_");
 341                 BADPREFIX("net_");
 342                 BADPREFIX("prvm_");
 343                 BADPREFIX("skill_");
 344                 BADPREFIX("sv_cullentities_");
 345                 BADPREFIX("sv_fraginfo_");
 346                 BADPREFIX("sv_maxidle_");
 347                 BADPREFIX("sv_vote_");
 348                 BADPREFIX("timelimit_");
 349                 BADCVAR("gameversion");
 350                 BADPREFIX("gameversion_");
 351                 BADCVAR("sv_namechangetimer");
 352
 353                 // allowed changes to server admins (please sync this to server.cfg)
 354                 // vi commands:
 355                 //   :/"impure"/,$d
 356                 //   :g!,^\/\/[^ /],d
 357                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 358                 //   :%!sort
 359                 // yes, this does contain some redundant stuff, don't really care
 360                 BADCVAR("bot_config_file");
 361                 BADCVAR("bot_number");
 362                 BADCVAR("bot_prefix");
 363                 BADCVAR("bot_suffix");
 364                 BADCVAR("capturelimit_override");
 365                 BADCVAR("fraglimit_override");
 366                 BADCVAR("gametype");
 367                 BADCVAR("g_antilag");
 368                 BADCVAR("g_balance_teams");
 369                 BADCVAR("g_balance_teams_prevent_imbalance");
 370                 BADCVAR("g_balance_teams_scorefactor");
 371                 BADCVAR("g_ban_sync_trusted_servers");
 372                 BADCVAR("g_ban_sync_uri");
 373                 BADCVAR("g_ca_teams_override");
 374                 BADCVAR("g_ctf_ignore_frags");
 375                 BADCVAR("g_domination_point_limit");
 376                 BADCVAR("g_freezetag_teams_override");
 377                 BADCVAR("g_friendlyfire");
 378                 BADCVAR("g_fullbrightitems");
 379                 BADCVAR("g_fullbrightplayers");
 380                 BADCVAR("g_keyhunt_point_limit");
 381                 BADCVAR("g_keyhunt_teams_override");
 382                 BADCVAR("g_lms_lives_override");
 383                 BADCVAR("g_maplist");
 384                 BADCVAR("g_maplist_check_waypoints");
 385                 BADCVAR("g_maplist_mostrecent_count");
 386                 BADCVAR("g_maplist_shuffle");
 387                 BADCVAR("g_maplist_votable");
 388                 BADCVAR("g_maplist_votable_abstain");
 389                 BADCVAR("g_maplist_votable_nodetail");
 390                 BADCVAR("g_maplist_votable_suggestions");
 391                 BADCVAR("g_maxplayers");
 392                 BADCVAR("g_mirrordamage");
 393                 BADCVAR("g_nexball_goallimit");
 394                 BADCVAR("g_powerups");
 395                 BADCVAR("g_start_delay");
 396                 BADCVAR("g_warmup");
 397                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 398                 BADCVAR("hostname");
 399                 BADCVAR("log_file");
 400                 BADCVAR("maxplayers");
 401                 BADCVAR("minplayers");
 402                 BADCVAR("net_address");
 403                 BADCVAR("port");
 404                 BADCVAR("rcon_password");
 405                 BADCVAR("rcon_restricted_commands");
 406                 BADCVAR("rcon_restricted_password");
 407                 BADCVAR("skill");
 408                 BADCVAR("sv_adminnick");
 409                 BADCVAR("sv_autoscreenshot");
 410                 BADCVAR("sv_autotaunt");
 411                 BADCVAR("sv_curl_defaulturl");
 412                 BADCVAR("sv_defaultcharacter");
 413                 BADCVAR("sv_defaultplayercolors");
 414                 BADCVAR("sv_defaultplayermodel");
 415                 BADCVAR("sv_defaultplayerskin");
 416                 BADCVAR("sv_maxidle");
 417                 BADCVAR("sv_maxrate");
 418                 BADCVAR("sv_motd");
 419                 BADCVAR("sv_public");
 420                 BADCVAR("sv_ready_restart");
 421                 BADCVAR("sv_status_privacy");
 422                 BADCVAR("sv_taunt");
 423                 BADCVAR("sv_vote_call");
 424                 BADCVAR("sv_vote_commands");
 425                 BADCVAR("sv_vote_majority_factor");
 426                 BADCVAR("sv_vote_master");
 427                 BADCVAR("sv_vote_master_commands");
 428                 BADCVAR("sv_vote_master_password");
 429                 BADCVAR("sv_vote_simple_majority_factor");
 430                 BADCVAR("teamplay_mode");
 431                 BADCVAR("timelimit_override");
 432                 BADCVAR("g_spawnshieldtime");
 433                 BADPREFIX("g_warmup_");
 434                 BADPREFIX("sv_ready_restart_");
 435
 436                 // mutators that announce themselves properly to the server browser
 437                 BADCVAR("g_instagib");
 438                 BADCVAR("g_new_toys");
 439                 BADCVAR("g_nix");
 440                 BADCVAR("g_grappling_hook");
 441                 BADCVAR("g_jetpack");
 442
 443 #undef BADPREFIX
 444 #undef BADCVAR
 445
 446                 if(pureadding)
 447                 {
 448                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 449                         if(strlen(cvar_purechanges) > 16384)
 450                         {
 451                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 452                                 pureadding = 0;
 453                         }
 454                 }
 455                 ++cvar_purechanges_count;
 456                 // WARNING: this variable is used for the server list
 457                 // NEVER dare to skip this code!
 458                 // Hacks to intentionally appearing as "pure server" even though you DO have
 459                 // modified settings may be punished by removal from the server list.
 460                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 461                 // though.
 462         }
 463         buf_del(h);
 464         if(cvar_changes == "")
 465                 cvar_changes = "// this server runs at default server settings\n";
 466         else
 467                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 468         cvar_changes = strzone(cvar_changes);
 469         if(cvar_purechanges == "")
 470                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 471         else
 472                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 473         cvar_purechanges = strzone(cvar_purechanges);
 474 }
 475
 476 void detect_maptype()
 477 {
 478 #if 0
 479         vector o, v;
 480         float i;
 481
 482         for (;;)
 483         {
 484                 o = world.mins;
 485                 o.x += random() * (world.maxs.x - world.mins.x);
 486                 o.y += random() * (world.maxs.y - world.mins.y);
 487                 o.z += random() * (world.maxs.z - world.mins.z);
 488
 489                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 490                 if(trace_fraction == 1)
 491                         continue;
 492
 493                 v = trace_endpos;
 494
 495                 for(i = 0; i < 64; i += 4)
 496                 {
 497                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 498         if(trace_fraction == 1)
 499                 continue;
 500                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 501                 }
 502
 503                 break;
 504         }
 505 #endif
 506 }
 507
 508 entity randomseed;
 509 float RandomSeed_Send(entity to, int sf)
 510 {
 511         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 512         WriteShort(MSG_ENTITY, self.cnt);
 513         return true;
 514 }
 515 void RandomSeed_Think()
 516 {
 517         self.cnt = bound(0, floor(random() * 65536), 65535);
 518         self.nextthink = time + 5;
 519
 520         self.SendFlags |= 1;
 521 }
 522 void RandomSeed_Spawn()
 523 {
 524         randomseed = spawn();
 525         randomseed.think = RandomSeed_Think;
 526         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 527
 528         entity oldself;
 529         oldself = self;
 530         self = randomseed;
 531         self.think(); // sets random seed and nextthink
 532         self = oldself;
 533 }
 534
 535 void spawnfunc___init_dedicated_server(void)
 536 {
 537         // handler for _init/_init map (only for dedicated server initialization)
 538
 539         world_initialized = -1; // don't complain
 540         cvar = cvar_normal;
 541         cvar_string = cvar_string_normal;
 542         cvar_set = cvar_set_normal;
 543
 544         remove = remove_unsafely;
 545
 546         entity e;
 547         e = spawn();
 548         e.think = GotoFirstMap;
 549         e.nextthink = time; // this is usually 1 at this point
 550
 551         e = spawn();
 552         e.classname = "info_player_deathmatch"; // safeguard against player joining
 553
 554         self.classname = "worldspawn"; // safeguard against various stuff ;)
 555
 556         // needs to be done so early because of the constants they create
 557         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 558         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 559         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 560         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 561         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 562         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 563
 564         MapInfo_Enumerate();
 565         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 566 }
 567
 568 void Map_MarkAsRecent(string m);
 569 float world_already_spawned;
 570 void Nagger_Init();
 571 void Item_ItemsTime_Init();
 572 void ClientInit_Spawn();
 573 void WeaponStats_Init();
 574 void WeaponStats_Shutdown();
 575 void spawnfunc_worldspawn (void)
 576 {
 577         float fd, l, j, n;
 578         string s;
 579
 580         cvar = cvar_normal;
 581         cvar_string = cvar_string_normal;
 582         cvar_set = cvar_set_normal;
 583
 584         if(world_already_spawned)
 585                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 586         world_already_spawned = true;
 587
 588         remove = remove_safely; // during spawning, watch what you remove!
 589
 590         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 591
 592         compressShortVector_init();
 593
 594         entity head;
 595         head = nextent(world);
 596         maxclients = 0;
 597         while(head)
 598         {
 599                 ++maxclients;
 600                 head = nextent(head);
 601         }
 602
 603         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 604
 605         // needs to be done so early because of the constants they create
 606         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 607         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 608         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 609         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 610         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 611         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 612
 613         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 614
 615         TemporaryDB = db_create();
 616
 617         // 0 normal
 618         lightstyle(0, "m");
 619
 620         // 1 FLICKER (first variety)
 621         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 622
 623         // 2 SLOW STRONG PULSE
 624         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 625
 626         // 3 CANDLE (first variety)
 627         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 628
 629         // 4 FAST STROBE
 630         lightstyle(4, "mamamamamama");
 631
 632         // 5 GENTLE PULSE 1
 633         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 634
 635         // 6 FLICKER (second variety)
 636         lightstyle(6, "nmonqnmomnmomomno");
 637
 638         // 7 CANDLE (second variety)
 639         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 640
 641         // 8 CANDLE (third variety)
 642         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 643
 644         // 9 SLOW STROBE (fourth variety)
 645         lightstyle(9, "aaaaaaaazzzzzzzz");
 646
 647         // 10 FLUORESCENT FLICKER
 648         lightstyle(10, "mmamammmmammamamaaamammma");
 649
 650         // 11 SLOW PULSE NOT FADE TO BLACK
 651         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 652
 653         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 654
 655         // 63 testing
 656         lightstyle(63, "a");
 657
 658         if(autocvar_g_campaign)
 659                 CampaignPreInit();
 660
 661         Map_MarkAsRecent(mapname);
 662
 663         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 664
 665         precache_model ("null"); // we need this one before InitGameplayMode
 666         InitGameplayMode();
 667         readlevelcvars();
 668         GrappleHookInit();
 669
 670         player_count = 0;
 671         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 672         if(bot_waypoints_for_items == 1)
 673                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 674                         bot_waypoints_for_items = 0;
 675
 676         precache();
 677
 678         WaypointSprite_Init();
 679
 680         GameLogInit(); // prepare everything
 681         // NOTE for matchid:
 682         // changing the logic generating it is okay. But:
 683         // it HAS to stay <= 64 chars
 684         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 685         if(autocvar_sv_eventlog)
 686         {
 687                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 688                 matchid = strzone(s);
 689
 690                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 691                 s = ":gameinfo:mutators:LIST";
 692
 693                 ret_string = s;
 694                 MUTATOR_CALLHOOK(BuildMutatorsString);
 695                 s = ret_string;
 696
 697                 // simple, probably not good in the mutator system
 698                 if(autocvar_g_grappling_hook)
 699                         s = strcat(s, ":grappling_hook");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(!autocvar_g_use_ammunition)
 703                         s = strcat(s, ":no_use_ammunition");
 704
 705                 // initialiation stuff, not good in the mutator system
 706                 if(autocvar_g_pickup_items == 0)
 707                         s = strcat(s, ":no_pickup_items");
 708                 if(autocvar_g_pickup_items > 0)
 709                         s = strcat(s, ":pickup_items");
 710
 711                 // initialiation stuff, not good in the mutator system
 712                 if(autocvar_g_weaponarena != "0")
 713                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_norecoil)
 717                         s = strcat(s, ":norecoil");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_powerups == 0)
 721                         s = strcat(s, ":no_powerups");
 722                 if(autocvar_g_powerups > 0)
 723                         s = strcat(s, ":powerups");
 724
 725                 GameLogEcho(s);
 726                 GameLogEcho(":gameinfo:end");
 727         }
 728         else
 729                 matchid = strzone(ftos(random()));
 730
 731         cvar_set("nextmap", "");
 732
 733         SetDefaultAlpha();
 734
 735         if(autocvar_g_campaign)
 736                 CampaignPostInit();
 737
 738         Ban_LoadBans();
 739
 740         MapInfo_Enumerate();
 741         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 742
 743         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 744         {
 745                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 746                 if(fd != -1)
 747                 {
 748                         while((s = fgets(fd)))
 749                         {
 750                                 l = tokenize_console(s);
 751                                 if(l < 2)
 752                                         continue;
 753                                 if(argv(0) == "cd")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 756                                         print("  cdtrack ", argv(2), "\n");
 757                                 }
 758                                 else if(argv(0) == "fog")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 761                                         print("  \"fog\" \"", s, "\"\n");
 762                                 }
 763                                 else if(argv(0) == "set")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 766                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 767                                 }
 768                                 else if(argv(0) != "//")
 769                                 {
 770                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 771                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 772                                 }
 773                         }
 774                         fclose(fd);
 775                 }
 776         }
 777
 778         WeaponStats_Init();
 779
 780         WepSet_AddStat();
 781         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 782         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 783         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 784         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 785         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 786         Nagger_Init();
 787
 788         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 789         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 790         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 791         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 792         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 793         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 794         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 795         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 796         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 797         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 798         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 799         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 800         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 801         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 802         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 803
 804         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 805         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 806
 807         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 808
 809         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 810
 811         // items time
 812         addstat(STAT_ARMOR_LARGE_TIME, AS_FLOAT, item_armor_large_time);
 813         addstat(STAT_HEALTH_MEGA_TIME, AS_FLOAT, item_health_mega_time);
 814         addstat(STAT_INVISIBLE_TIME, AS_FLOAT, item_invisible_time);
 815         addstat(STAT_SPEED_TIME, AS_FLOAT, item_speed_time);
 816         addstat(STAT_EXTRALIFE_TIME, AS_FLOAT, item_extralife_time);
 817         addstat(STAT_STRENGTH_TIME, AS_FLOAT, item_strength_time);
 818         addstat(STAT_SHIELD_TIME, AS_FLOAT, item_shield_time);
 819         addstat(STAT_FUELREGEN_TIME, AS_FLOAT, item_fuelregen_time);
 820         addstat(STAT_JETPACK_TIME, AS_FLOAT, item_jetpack_time);
 821         addstat(STAT_SUPERWEAPONS_TIME, AS_FLOAT, item_superweapons_time);
 822         Item_ItemsTime_Init();
 823
 824         // freeze attacks
 825         addstat(STAT_FROZEN, AS_INT, frozen);
 826         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 827
 828         // g_movementspeed hack
 829         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 830         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 831         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 832         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 833
 834         // secrets
 835         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 836         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 837
 838         // monsters
 839         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 840         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 841
 842         // misc
 843         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 844
 845         next_pingtime = time + 5;
 846
 847         detect_maptype();
 848
 849         // set up information replies for clients and server to use
 850         maplist_reply = strzone(getmaplist());
 851         lsmaps_reply = strzone(getlsmaps());
 852         monsterlist_reply = strzone(getmonsterlist());
 853         for(int i = 0; i < 10; ++i)
 854         {
 855                 s = getrecords(i);
 856                 if (s)
 857                         records_reply[i] = strzone(s);
 858         }
 859         ladder_reply = strzone(getladder());
 860         rankings_reply = strzone(getrankings());
 861
 862         // begin other init
 863         ClientInit_Spawn();
 864         RandomSeed_Spawn();
 865         PingPLReport_Spawn();
 866
 867         CheatInit();
 868
 869         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 870
 871         // fill sv_curl_serverpackages from .serverpackage files
 872         if(autocvar_sv_curl_serverpackages_auto)
 873         {
 874                 s = "";
 875                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 876                 for(int i = 0; i < n; ++i)
 877                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 878                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 879                                 s = strcat(s, " ", argv(i));
 880                 fd = search_begin("*-serverpackage.txt", true, false);
 881                 if(fd >= 0)
 882                 {
 883                         j = search_getsize(fd);
 884                         for(int i = 0; i < j; ++i)
 885                                 s = strcat(s, " ", search_getfilename(fd, i));
 886                         search_end(fd);
 887                 }
 888                 fd = search_begin("*.serverpackage", true, false);
 889                 if(fd >= 0)
 890                 {
 891                         j = search_getsize(fd);
 892                         for(int i = 0; i < j; ++i)
 893                                 s = strcat(s, " ", search_getfilename(fd, i));
 894                         search_end(fd);
 895                 }
 896                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 897         }
 898
 899         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 900         modname = "Xonotic";
 901         // physics/balance/config changes that count as mod
 902         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 903                 modname = cvar_string("g_mod_physics");
 904         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 905                 modname = cvar_string("g_mod_balance");
 906         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 907                 modname = cvar_string("g_mod_config");
 908         // extra mutators that deserve to count as mod
 909         MUTATOR_CALLHOOK(SetModname);
 910
 911         // save it for later
 912         modname = strzone(modname);
 913
 914         WinningConditionHelper(); // set worldstatus
 915
 916         world_initialized = 1;
 917 }
 918
 919 void spawnfunc_light (void)
 920 {
 921         //makestatic (self); // Who the f___ did that?
 922         remove(self);
 923 }
 924
 925 string GetGametype()
 926 {
 927         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 928 }
 929
 930 string GetMapname()
 931 {
 932         return mapname;
 933 }
 934
 935 float Map_Count, Map_Current;
 936 string Map_Current_Name;
 937
 938 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 939 float GetMaplistPosition()
 940 {
 941         float pos, idx;
 942         string map;
 943
 944         map = GetMapname();
 945         idx = autocvar_g_maplist_index;
 946
 947         if(idx >= 0)
 948                 if(idx < Map_Count)
 949                         if(map == argv(idx))
 950                                 return idx;
 951
 952         for(pos = 0; pos < Map_Count; ++pos)
 953                 if(map == argv(pos))
 954                         return pos;
 955
 956         // resume normal maplist rotation if current map is not in g_maplist
 957         return idx;
 958 }
 959
 960 float MapHasRightSize(string map)
 961 {
 962         float fh;
 963         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 964         if(autocvar_g_maplist_check_waypoints)
 965         {
 966                 dprint("checkwp "); dprint(map);
 967                 if(!fexists(strcat("maps/", map, ".waypoints")))
 968                 {
 969                         dprint(": no waypoints\n");
 970                         return false;
 971                 }
 972                 dprint(": has waypoints\n");
 973         }
 974
 975         // open map size restriction file
 976         dprint("opensize "); dprint(map);
 977         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 978         if(fh >= 0)
 979         {
 980                 float mapmin, mapmax;
 981                 dprint(": ok, ");
 982                 mapmin = stof(fgets(fh));
 983                 mapmax = stof(fgets(fh));
 984                 fclose(fh);
 985                 if(player_count < mapmin)
 986                 {
 987                         dprint("not enough\n");
 988                         return false;
 989                 }
 990                 if(player_count > mapmax)
 991                 {
 992                         dprint("too many\n");
 993                         return false;
 994                 }
 995                 dprint("right size\n");
 996                 return true;
 997         }
 998         dprint(": not found\n");
 999         return true;
1000 }
1001
1002 string Map_Filename(float position)
1003 {
1004         return strcat("maps/", argv(position), ".bsp");
1005 }
1006
1007 string strwords(string s, float w)
1008 {
1009         float endpos;
1010         for(endpos = 0; w && endpos >= 0; --w)
1011                 endpos = strstrofs(s, " ", endpos + 1);
1012         if(endpos < 0)
1013                 return s;
1014         else
1015                 return substring(s, 0, endpos);
1016 }
1017
1018 float strhasword(string s, string w)
1019 {
1020         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1021 }
1022
1023 void Map_MarkAsRecent(string m)
1024 {
1025         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1026 }
1027
1028 float Map_IsRecent(string m)
1029 {
1030         return strhasword(autocvar_g_maplist_mostrecent, m);
1031 }
1032
1033 float Map_Check(float position, float pass)
1034 {
1035         string filename;
1036         string map_next;
1037         map_next = argv(position);
1038         if(pass <= 1)
1039         {
1040                 if(Map_IsRecent(map_next))
1041                         return 0;
1042         }
1043         filename = Map_Filename(position);
1044         if(MapInfo_CheckMap(map_next))
1045         {
1046                 if(pass == 2)
1047                         return 1;
1048                 if(MapHasRightSize(map_next))
1049                         return 1;
1050                 return 0;
1051         }
1052         else
1053                 dprint( "Couldn't select '", filename, "'..\n" );
1054
1055         return 0;
1056 }
1057
1058 void Map_Goto_SetStr(string nextmapname)
1059 {
1060         if(getmapname_stored != "")
1061                 strunzone(getmapname_stored);
1062         if(nextmapname == "")
1063                 getmapname_stored = "";
1064         else
1065                 getmapname_stored = strzone(nextmapname);
1066 }
1067
1068 void Map_Goto_SetFloat(float position)
1069 {
1070         cvar_set("g_maplist_index", ftos(position));
1071         Map_Goto_SetStr(argv(position));
1072 }
1073
1074 void Map_Goto(float reinit)
1075 {
1076         MapInfo_LoadMap(getmapname_stored, reinit);
1077 }
1078
1079 // return codes of map selectors:
1080 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1081 //   -2 = permanent failure
1082 float() MaplistMethod_Iterate = // usual method
1083 {
1084         float pass, i;
1085
1086         dprint("Trying MaplistMethod_Iterate\n");
1087
1088         for(pass = 1; pass <= 2; ++pass)
1089         {
1090                 for(i = 1; i < Map_Count; ++i)
1091                 {
1092                         float mapindex;
1093                         mapindex = (i + Map_Current) % Map_Count;
1094                         if(Map_Check(mapindex, pass))
1095                                 return mapindex;
1096                 }
1097         }
1098         return -1;
1099 }
1100
1101 float() MaplistMethod_Repeat = // fallback method
1102 {
1103         dprint("Trying MaplistMethod_Repeat\n");
1104
1105         if(Map_Check(Map_Current, 2))
1106                 return Map_Current;
1107         return -2;
1108 }
1109
1110 float() MaplistMethod_Random = // random map selection
1111 {
1112         float i, imax;
1113
1114         dprint("Trying MaplistMethod_Random\n");
1115
1116         imax = 42;
1117
1118         for(i = 0; i <= imax; ++i)
1119         {
1120                 float mapindex;
1121                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1122                 if(Map_Check(mapindex, 1))
1123                         return mapindex;
1124         }
1125         return -1;
1126 }
1127
1128 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1129 // the exponent sets a bias on the map selection:
1130 // the higher the exponent, the less likely "shortly repeated" same maps are
1131 {
1132         float i, j, imax, insertpos;
1133
1134         dprint("Trying MaplistMethod_Shuffle\n");
1135
1136         imax = 42;
1137
1138         for(i = 0; i <= imax; ++i)
1139         {
1140                 string newlist;
1141
1142                 // now reinsert this at another position
1143                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1144                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1145                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1146                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1147
1148                 // insert the current map there
1149                 newlist = "";
1150                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1151                         newlist = strcat(newlist, " ", argv(j));
1152                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1153                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1154                         newlist = strcat(newlist, " ", argv(j));
1155                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1156                 cvar_set("g_maplist", newlist);
1157                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1158
1159                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1160                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1161                 if(Map_Check(Map_Current, 1))
1162                         return Map_Current;
1163         }
1164         return -1;
1165 }
1166
1167 void Maplist_Init()
1168 {
1169         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1170         float i;
1171         for (i = 0; i < Map_Count; ++i)
1172                 if (Map_Check(i, 2))
1173                         break;
1174         if (i == Map_Count)
1175         {
1176                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1177                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1178                 if(autocvar_g_maplist_shuffle)
1179                         ShuffleMaplist();
1180                 localcmd("\nmenu_cmd sync\n");
1181                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1182         }
1183         if(Map_Count == 0)
1184                 error("empty maplist, cannot select a new map");
1185         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1186
1187         if(Map_Current_Name)
1188                 strunzone(Map_Current_Name);
1189         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1190         // this may or may not be correct, but who cares, in the worst case a map
1191         // isn't chosen in the first pass that should have been
1192 }
1193
1194 string GetNextMap()
1195 {
1196         float nextMap;
1197
1198         Maplist_Init();
1199         nextMap = -1;
1200
1201         if(nextMap == -1)
1202                 if(autocvar_g_maplist_shuffle > 0)
1203                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1204
1205         if(nextMap == -1)
1206                 if(autocvar_g_maplist_selectrandom)
1207                         nextMap = MaplistMethod_Random();
1208
1209         if(nextMap == -1)
1210                 nextMap = MaplistMethod_Iterate();
1211
1212         if(nextMap == -1)
1213                 nextMap = MaplistMethod_Repeat();
1214
1215         if(nextMap >= 0)
1216         {
1217                 Map_Goto_SetFloat(nextMap);
1218                 return getmapname_stored;
1219         }
1220
1221         return "";
1222 }
1223
1224 float DoNextMapOverride(float reinit)
1225 {
1226         if(autocvar_g_campaign)
1227         {
1228                 CampaignPostIntermission();
1229                 alreadychangedlevel = true;
1230                 return true;
1231         }
1232         if(autocvar_quit_when_empty)
1233         {
1234                 if(player_count <= currentbots)
1235                 {
1236                         localcmd("quit\n");
1237                         alreadychangedlevel = true;
1238                         return true;
1239                 }
1240         }
1241         if(autocvar_quit_and_redirect != "")
1242         {
1243                 redirection_target = strzone(autocvar_quit_and_redirect);
1244                 alreadychangedlevel = true;
1245                 return true;
1246         }
1247         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1248         {
1249                 localcmd("restart\n");
1250                 alreadychangedlevel = true;
1251                 return true;
1252         }
1253         if(autocvar_nextmap != "")
1254         {
1255                 string m;
1256                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1257                 cvar_set("nextmap",m);
1258
1259                 if(!m || gametypevote)
1260                         return false;
1261                 if(autocvar_sv_vote_gametype)
1262                 {
1263                         Map_Goto_SetStr(m);
1264                         return false;
1265                 }
1266
1267                 if(MapInfo_CheckMap(m))
1268                 {
1269                         Map_Goto_SetStr(m);
1270                         Map_Goto(reinit);
1271                         alreadychangedlevel = true;
1272                         return true;
1273                 }
1274         }
1275         if(!reinit && autocvar_lastlevel)
1276         {
1277                 cvar_settemp_restore();
1278                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1279                 alreadychangedlevel = true;
1280                 return true;
1281         }
1282         return false;
1283 }
1284
1285 void GotoNextMap(float reinit)
1286 {
1287         //string nextmap;
1288         //float n, nummaps;
1289         //string s;
1290         if (alreadychangedlevel)
1291                 return;
1292         alreadychangedlevel = true;
1293
1294         string nextMap;
1295
1296         nextMap = GetNextMap();
1297         if(nextMap == "")
1298                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1299         Map_Goto(reinit);
1300 }
1301
1302
1303 /*
1304 ============
1305 IntermissionThink
1306
1307 When the player presses attack or jump, change to the next level
1308 ============
1309 */
1310 .float autoscreenshot;
1311 void IntermissionThink()
1312 {
1313         FixIntermissionClient(self);
1314
1315         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1316         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1317
1318         if( (server_screenshot || client_screenshot)
1319                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1320         {
1321                 self.autoscreenshot = -1;
1322                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1323                 return;
1324         }
1325
1326         if (time < intermission_exittime)
1327                 return;
1328
1329         if(!mapvote_initialized)
1330                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1331                         return;
1332
1333         MapVote_Start();
1334 }
1335
1336 /*
1337 ============
1338 FindIntermission
1339
1340 Returns the entity to view from
1341 ============
1342 */
1343 /*
1344 entity FindIntermission()
1345 {
1346         local   entity spot;
1347         local   float cyc;
1348
1349 // look for info_intermission first
1350         spot = find (world, classname, "info_intermission");
1351         if (spot)
1352         {       // pick a random one
1353                 cyc = random() * 4;
1354                 while (cyc > 1)
1355                 {
1356                         spot = find (spot, classname, "info_intermission");
1357                         if (!spot)
1358                                 spot = find (spot, classname, "info_intermission");
1359                         cyc = cyc - 1;
1360                 }
1361                 return spot;
1362         }
1363
1364 // then look for the start position
1365         spot = find (world, classname, "info_player_start");
1366         if (spot)
1367                 return spot;
1368
1369 // testinfo_player_start is only found in regioned levels
1370         spot = find (world, classname, "testplayerstart");
1371         if (spot)
1372                 return spot;
1373
1374 // then look for the start position
1375         spot = find (world, classname, "info_player_deathmatch");
1376         if (spot)
1377                 return spot;
1378
1379         //objerror ("FindIntermission: no spot");
1380         return world;
1381 }
1382 */
1383
1384 /*
1385 ===============================================================================
1386
1387 RULES
1388
1389 ===============================================================================
1390 */
1391
1392 void DumpStats(float final)
1393 {
1394         float file;
1395         string s;
1396         float to_console;
1397         float to_eventlog;
1398         float to_file;
1399         float i;
1400
1401         to_console = autocvar_sv_logscores_console;
1402         to_eventlog = autocvar_sv_eventlog;
1403         to_file = autocvar_sv_logscores_file;
1404
1405         if(!final)
1406         {
1407                 to_console = true; // always print printstats replies
1408                 to_eventlog = false; // but never print them to the event log
1409         }
1410
1411         if(to_eventlog)
1412                 if(autocvar_sv_eventlog_console)
1413                         to_console = false; // otherwise we get the output twice
1414
1415         if(final)
1416                 s = ":scores:";
1417         else
1418                 s = ":status:";
1419         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1420
1421         if(to_console)
1422                 print(s, "\n");
1423         if(to_eventlog)
1424                 GameLogEcho(s);
1425
1426         file = -1;
1427         if(to_file)
1428         {
1429                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1430                 if(file == -1)
1431                         to_file = false;
1432                 else
1433                         fputs(file, strcat(s, "\n"));
1434         }
1435
1436         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1437         if(to_console)
1438                 print(s, "\n");
1439         if(to_eventlog)
1440                 GameLogEcho(s);
1441         if(to_file)
1442                 fputs(file, strcat(s, "\n"));
1443
1444         FOR_EACH_CLIENT(other)
1445         {
1446                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1447                 {
1448                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1449                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1450                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1451                                 s = strcat(s, ftos(other.team), ":");
1452                         else
1453                                 s = strcat(s, "spectator:");
1454
1455                         if(to_console)
1456                                 print(s, other.netname, "\n");
1457                         if(to_eventlog)
1458                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1459                         if(to_file)
1460                                 fputs(file, strcat(s, other.netname, "\n"));
1461                 }
1462         }
1463
1464         if(teamplay)
1465         {
1466                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1467                 if(to_console)
1468                         print(s, "\n");
1469                 if(to_eventlog)
1470                         GameLogEcho(s);
1471                 if(to_file)
1472                         fputs(file, strcat(s, "\n"));
1473
1474                 for(i = 1; i < 16; ++i)
1475                 {
1476                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1477                         s = strcat(s, ":", ftos(i));
1478                         if(to_console)
1479                                 print(s, "\n");
1480                         if(to_eventlog)
1481                                 GameLogEcho(s);
1482                         if(to_file)
1483                                 fputs(file, strcat(s, "\n"));
1484                 }
1485         }
1486
1487         if(to_console)
1488                 print(":end\n");
1489         if(to_eventlog)
1490                 GameLogEcho(":end");
1491         if(to_file)
1492         {
1493                 fputs(file, ":end\n");
1494                 fclose(file);
1495         }
1496 }
1497
1498 void FixIntermissionClient(entity e)
1499 {
1500         string s;
1501         if(!e.autoscreenshot) // initial call
1502         {
1503                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1504                 e.health = -2342;
1505                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1506                 e.solid = SOLID_NOT;
1507                 e.movetype = MOVETYPE_NONE;
1508                 e.takedamage = DAMAGE_NO;
1509                 if(e.weaponentity)
1510                 {
1511                         e.weaponentity.effects = EF_NODRAW;
1512                         if (e.weaponentity.weaponentity)
1513                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1514                 }
1515                 if(IS_REAL_CLIENT(e))
1516                 {
1517                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1518                         s = autocvar_sv_intermission_cdtrack;
1519                         if(s != "")
1520                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1521                         msg_entity = e;
1522                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1523                 }
1524         }
1525 }
1526
1527 /*
1528 go to the next level for deathmatch
1529 only called if a time or frag limit has expired
1530 */
1531 void NextLevel()
1532 {
1533         gameover = true;
1534
1535         intermission_running = 1;
1536
1537 // enforce a wait time before allowing changelevel
1538         if(player_count > 0)
1539                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1540         else
1541                 intermission_exittime = -1;
1542
1543         /*
1544         WriteByte (MSG_ALL, SVC_CDTRACK);
1545         WriteByte (MSG_ALL, 3);
1546         WriteByte (MSG_ALL, 3);
1547         // done in FixIntermission
1548         */
1549
1550         //pos = FindIntermission ();
1551
1552         VoteReset();
1553
1554         DumpStats(true);
1555
1556         // send statistics
1557         PlayerStats_GameReport(true);
1558         WeaponStats_Shutdown();
1559
1560         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1561
1562         if(autocvar_sv_eventlog)
1563                 GameLogEcho(":gameover");
1564
1565         GameLogClose();
1566
1567         FOR_EACH_PLAYER(other) {
1568                 FixIntermissionClient(other);
1569                 if(other.winning)
1570                         bprint(other.netname, " ^7wins.\n");
1571         }
1572
1573         if(autocvar_g_campaign)
1574                 CampaignPreIntermission();
1575
1576         MUTATOR_CALLHOOK(MatchEnd);
1577
1578         localcmd("\nsv_hook_gameend\n");
1579 }
1580
1581 /*
1582 ============
1583 CheckRules_Player
1584
1585 Exit deathmatch games upon conditions
1586 ============
1587 */
1588 void CheckRules_Player()
1589 {
1590         if (gameover)   // someone else quit the game already
1591                 return;
1592
1593         if(self.deadflag == DEAD_NO)
1594                 self.play_time += frametime;
1595
1596         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1597         //   (div0: and that in CheckRules_World please)
1598 }
1599
1600
1601 float InitiateSuddenDeath()
1602 {
1603         // Check first whether normal overtimes could be added before initiating suddendeath mode
1604         // - for this timelimit_overtime needs to be >0 of course
1605         // - also check the winning condition calculated in the previous frame and only add normal overtime
1606         //   again, if at the point at which timelimit would be extended again, still no winner was found
1607         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1608         {
1609                 return 1; // need to call InitiateOvertime later
1610         }
1611         else
1612         {
1613                 if(!checkrules_suddendeathend)
1614                 {
1615                         if(autocvar_g_campaign)
1616                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1617                         else
1618                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1619                         if(g_race && !g_race_qualifying)
1620                                 race_StartCompleting();
1621                 }
1622                 return 0;
1623         }
1624 }
1625
1626 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1627 {
1628         ++checkrules_overtimesadded;
1629         //add one more overtime by simply extending the timelimit
1630         float tl;
1631         tl = autocvar_timelimit;
1632         tl += autocvar_timelimit_overtime;
1633         cvar_set("timelimit", ftos(tl));
1634
1635         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1636 }
1637
1638 float GetWinningCode(float fraglimitreached, float equality)
1639 {
1640         if(autocvar_g_campaign == 1)
1641                 if(fraglimitreached)
1642                         return WINNING_YES;
1643                 else
1644                         return WINNING_NO;
1645
1646         else
1647                 if(equality)
1648                         if(fraglimitreached)
1649                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1650                         else
1651                                 return WINNING_NEVER;
1652                 else
1653                         if(fraglimitreached)
1654                                 return WINNING_YES;
1655                         else
1656                                 return WINNING_NO;
1657 }
1658
1659 // set the .winning flag for exactly those players with a given field value
1660 void SetWinners(.float field, float value)
1661 {
1662         entity head;
1663         FOR_EACH_PLAYER(head)
1664                 head.winning = (head.(field) == value);
1665 }
1666
1667 // set the .winning flag for those players with a given field value
1668 void AddWinners(.float field, float value)
1669 {
1670         entity head;
1671         FOR_EACH_PLAYER(head)
1672                 if (head.(field) == value)
1673                         head.winning = 1;
1674 }
1675
1676 // clear the .winning flags
1677 void ClearWinners(void)
1678 {
1679         entity head;
1680         FOR_EACH_PLAYER(head)
1681                 head.winning = 0;
1682 }
1683
1684 // Onslaught winning condition:
1685 // game terminates if only one team has a working generator (or none)
1686 float WinningCondition_Onslaught()
1687 {
1688         entity head;
1689         float t1, t2, t3, t4;
1690
1691         WinningConditionHelper(); // set worldstatus
1692
1693         if(warmup_stage)
1694                 return WINNING_NO;
1695
1696         // first check if the game has ended
1697         t1 = t2 = t3 = t4 = 0;
1698         head = find(world, classname, "onslaught_generator");
1699         while (head)
1700         {
1701                 if (head.health > 0)
1702                 {
1703                         if (head.team == NUM_TEAM_1) t1 = 1;
1704                         if (head.team == NUM_TEAM_2) t2 = 1;
1705                         if (head.team == NUM_TEAM_3) t3 = 1;
1706                         if (head.team == NUM_TEAM_4) t4 = 1;
1707                 }
1708                 head = find(head, classname, "onslaught_generator");
1709         }
1710         if (t1 + t2 + t3 + t4 < 2)
1711         {
1712                 // game over, only one team remains (or none)
1713                 ClearWinners();
1714                 if (t1) SetWinners(team, NUM_TEAM_1);
1715                 if (t2) SetWinners(team, NUM_TEAM_2);
1716                 if (t3) SetWinners(team, NUM_TEAM_3);
1717                 if (t4) SetWinners(team, NUM_TEAM_4);
1718                 dprint("Have a winner, ending game.\n");
1719                 return WINNING_YES;
1720         }
1721
1722         // Two or more teams remain
1723         return WINNING_NO;
1724 }
1725
1726 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1727 // they win. Otherwise the defending team wins once the timelimit passes.
1728 void assault_new_round();
1729 float WinningCondition_Assault()
1730 {
1731         float status;
1732
1733         WinningConditionHelper(); // set worldstatus
1734
1735         status = WINNING_NO;
1736         // as the timelimit has not yet passed just assume the defending team will win
1737         if(assault_attacker_team == NUM_TEAM_1)
1738         {
1739                 SetWinners(team, NUM_TEAM_2);
1740         }
1741         else
1742         {
1743                 SetWinners(team, NUM_TEAM_1);
1744         }
1745
1746         entity ent;
1747         ent = find(world, classname, "target_assault_roundend");
1748         if(ent)
1749         {
1750                 if(ent.winning) // round end has been triggered by attacking team
1751                 {
1752                         bprint("ASSAULT: round completed...\n");
1753                         SetWinners(team, assault_attacker_team);
1754
1755                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1756
1757                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1758                         {
1759                                 status = WINNING_YES;
1760                         }
1761                         else
1762                         {
1763                                 entity oldself;
1764                                 oldself = self;
1765                                 self = ent;
1766                                 assault_new_round();
1767                                 self = oldself;
1768                         }
1769                 }
1770         }
1771
1772         return status;
1773 }
1774
1775 // LMS winning condition: game terminates if and only if there's at most one
1776 // one player who's living lives. Top two scores being equal cancels the time
1777 // limit.
1778 float WinningCondition_LMS()
1779 {
1780         entity head, head2;
1781         float have_player;
1782         float have_players;
1783         float l;
1784
1785         have_player = false;
1786         have_players = false;
1787         l = LMS_NewPlayerLives();
1788
1789         head = find(world, classname, "player");
1790         if(head)
1791                 have_player = true;
1792         head2 = find(head, classname, "player");
1793         if(head2)
1794                 have_players = true;
1795
1796         if(have_player)
1797         {
1798                 // we have at least one player
1799                 if(have_players)
1800                 {
1801                         // two or more active players - continue with the game
1802                 }
1803                 else
1804                 {
1805                         // exactly one player?
1806
1807                         ClearWinners();
1808                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1809
1810                         if(l)
1811                         {
1812                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1813                                 return WINNING_NO;
1814                         }
1815                         else
1816                         {
1817                                 // a winner!
1818                                 // and assign him his first place
1819                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1820                                 return WINNING_YES;
1821                         }
1822                 }
1823         }
1824         else
1825         {
1826                 // nobody is playing at all...
1827                 if(l)
1828                 {
1829                         // wait for players...
1830                 }
1831                 else
1832                 {
1833                         // SNAFU (maybe a draw game?)
1834                         ClearWinners();
1835                         dprint("No players, ending game.\n");
1836                         return WINNING_YES;
1837                 }
1838         }
1839
1840         // When we get here, we have at least two players who are actually LIVING,
1841         // now check if the top two players have equal score.
1842         WinningConditionHelper();
1843
1844         ClearWinners();
1845         if(WinningConditionHelper_winner)
1846                 WinningConditionHelper_winner.winning = true;
1847         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1848                 return WINNING_NEVER;
1849
1850         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1851         return WINNING_NO;
1852 }
1853
1854 void ShuffleMaplist()
1855 {
1856         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1857 }
1858
1859 float leaderfrags;
1860 float WinningCondition_Scores(float limit, float leadlimit)
1861 {
1862         float limitreached;
1863
1864         // TODO make everything use THIS winning condition (except LMS)
1865         WinningConditionHelper();
1866
1867         if(teamplay)
1868         {
1869                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1870                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1871                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1872                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1873         }
1874
1875         ClearWinners();
1876         if(WinningConditionHelper_winner)
1877                 WinningConditionHelper_winner.winning = 1;
1878         if(WinningConditionHelper_winnerteam >= 0)
1879                 SetWinners(team, WinningConditionHelper_winnerteam);
1880
1881         if(WinningConditionHelper_lowerisbetter)
1882         {
1883                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1884                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1885                 limit = -limit;
1886         }
1887
1888         if(WinningConditionHelper_zeroisworst)
1889                 leadlimit = 0; // not supported in this mode
1890
1891         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1892         // these modes always score in increments of 1, thus this makes sense
1893         {
1894                 if(leaderfrags != WinningConditionHelper_topscore)
1895                 {
1896                         leaderfrags = WinningConditionHelper_topscore;
1897
1898                         if (limit)
1899                         if (leaderfrags == limit - 1)
1900                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1901                         else if (leaderfrags == limit - 2)
1902                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1903                         else if (leaderfrags == limit - 3)
1904                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1905                 }
1906         }
1907
1908         limitreached = false;
1909         if(limit)
1910                 if(WinningConditionHelper_topscore >= limit)
1911                         limitreached = true;
1912         if(leadlimit)
1913         {
1914                 float leadlimitreached;
1915                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1916                 if(autocvar_leadlimit_and_fraglimit)
1917                         limitreached = (limitreached && leadlimitreached);
1918                 else
1919                         limitreached = (limitreached || leadlimitreached);
1920         }
1921
1922         if(limit)
1923                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1924
1925         return GetWinningCode(
1926                 WinningConditionHelper_topscore && limitreached,
1927                 WinningConditionHelper_equality
1928         );
1929 }
1930
1931 float WinningCondition_Race(float fraglimit)
1932 {
1933         float wc;
1934         entity p;
1935         float n, c;
1936
1937         n = 0;
1938         c = 0;
1939         FOR_EACH_PLAYER(p)
1940         {
1941                 ++n;
1942                 if(p.race_completed)
1943                         ++c;
1944         }
1945         if(n && (n == c))
1946                 return WINNING_YES;
1947         wc = WinningCondition_Scores(fraglimit, 0);
1948
1949         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1950         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1951         // do NOT support equality when the laps are all raced!
1952                 return WINNING_STARTSUDDENDEATHOVERTIME;
1953         else
1954                 return WINNING_NEVER;
1955 }
1956
1957 float WinningCondition_QualifyingThenRace(float limit)
1958 {
1959         float wc;
1960         wc = WinningCondition_Scores(limit, 0);
1961
1962         // NEVER initiate overtime
1963         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1964         {
1965                 return WINNING_YES;
1966         }
1967
1968         return wc;
1969 }
1970
1971 float WinningCondition_RanOutOfSpawns()
1972 {
1973         entity head;
1974
1975         if(have_team_spawns <= 0)
1976                 return WINNING_NO;
1977
1978         if(!autocvar_g_spawn_useallspawns)
1979                 return WINNING_NO;
1980
1981         if(!some_spawn_has_been_used)
1982                 return WINNING_NO;
1983
1984         team1_score = team2_score = team3_score = team4_score = 0;
1985
1986         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1987         {
1988                 if(head.team == NUM_TEAM_1)
1989                         team1_score = 1;
1990                 else if(head.team == NUM_TEAM_2)
1991                         team2_score = 1;
1992                 else if(head.team == NUM_TEAM_3)
1993                         team3_score = 1;
1994                 else if(head.team == NUM_TEAM_4)
1995                         team4_score = 1;
1996         }
1997
1998         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1999         {
2000                 if(head.team == NUM_TEAM_1)
2001                         team1_score = 1;
2002                 else if(head.team == NUM_TEAM_2)
2003                         team2_score = 1;
2004                 else if(head.team == NUM_TEAM_3)
2005                         team3_score = 1;
2006                 else if(head.team == NUM_TEAM_4)
2007                         team4_score = 1;
2008         }
2009
2010         ClearWinners();
2011         if(team1_score + team2_score + team3_score + team4_score == 0)
2012         {
2013                 checkrules_equality = true;
2014                 return WINNING_YES;
2015         }
2016         else if(team1_score + team2_score + team3_score + team4_score == 1)
2017         {
2018                 float t, i;
2019                 if(team1_score)
2020                         t = NUM_TEAM_1;
2021                 else if(team2_score)
2022                         t = NUM_TEAM_2;
2023                 else if(team3_score)
2024                         t = NUM_TEAM_3;
2025                 else // if(team4_score)
2026                         t = NUM_TEAM_4;
2027                 CheckAllowedTeams(world);
2028                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2029                 {
2030                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2031                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2032                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2033                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2034                 }
2035
2036                 AddWinners(team, t);
2037                 return WINNING_YES;
2038         }
2039         else
2040                 return WINNING_NO;
2041 }
2042
2043 /*
2044 ============
2045 CheckRules_World
2046
2047 Exit deathmatch games upon conditions
2048 ============
2049 */
2050 void CheckRules_World()
2051 {
2052         float timelimit;
2053         float fraglimit;
2054         float leadlimit;
2055
2056         VoteThink();
2057         MapVote_Think();
2058
2059         SetDefaultAlpha();
2060
2061         if (gameover)   // someone else quit the game already
2062         {
2063                 if(player_count == 0) // Nobody there? Then let's go to the next map
2064                         MapVote_Start();
2065                         // this will actually check the player count in the next frame
2066                         // again, but this shouldn't hurt
2067                 return;
2068         }
2069
2070         timelimit = autocvar_timelimit * 60;
2071         fraglimit = autocvar_fraglimit;
2072         leadlimit = autocvar_leadlimit;
2073
2074         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2075         {
2076                 if(timelimit > 0)
2077                         timelimit = 0; // timelimit is not made for warmup
2078                 if(fraglimit > 0)
2079                         fraglimit = 0; // no fraglimit for now
2080                 leadlimit = 0; // no leadlimit for now
2081         }
2082
2083         if(timelimit > 0)
2084         {
2085                 timelimit += game_starttime;
2086         }
2087         else if (timelimit < 0)
2088         {
2089                 // endmatch
2090                 NextLevel();
2091                 return;
2092         }
2093
2094         if(g_onslaught)
2095                 timelimit = 0; // ONS has its own overtime rule
2096
2097         float wantovertime;
2098         wantovertime = 0;
2099
2100         if(timelimit > game_starttime)
2101                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2102         else
2103                 game_completion_ratio = 0;
2104
2105         if(checkrules_suddendeathend)
2106         {
2107                 if(!checkrules_suddendeathwarning)
2108                 {
2109                         checkrules_suddendeathwarning = true;
2110                         if(g_race && !g_race_qualifying)
2111                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2112                         else
2113                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2114                 }
2115         }
2116         else
2117         {
2118                 if (timelimit && time >= timelimit)
2119                 {
2120                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2121                         {
2122                                 float totalplayers;
2123                                 float playerswithlaps;
2124                                 float readyplayers;
2125                                 entity head;
2126                                 totalplayers = playerswithlaps = readyplayers = 0;
2127                                 FOR_EACH_PLAYER(head)
2128                                 {
2129                                         ++totalplayers;
2130                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2131                                                 ++playerswithlaps;
2132                                         if(head.ready)
2133                                                 ++readyplayers;
2134                                 }
2135
2136                                 // at least 2 of the players have completed a lap: start the RACE
2137                                 // otherwise, the players should end the qualifying on their own
2138                                 if(readyplayers || playerswithlaps >= 2)
2139                                 {
2140                                         checkrules_suddendeathend = 0;
2141                                         ReadyRestart(); // go to race
2142                                         return;
2143                                 }
2144                                 else
2145                                         wantovertime |= InitiateSuddenDeath();
2146                         }
2147                         else
2148                                 wantovertime |= InitiateSuddenDeath();
2149                 }
2150         }
2151
2152         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2153         {
2154                 NextLevel();
2155                 return;
2156         }
2157
2158         float checkrules_status;
2159         checkrules_status = WinningCondition_RanOutOfSpawns();
2160         if(checkrules_status == WINNING_YES)
2161         {
2162                 bprint("Hey! Someone ran out of spawns!\n");
2163         }
2164         else if(g_race && !g_race_qualifying && timelimit >= 0)
2165         {
2166                 checkrules_status = WinningCondition_Race(fraglimit);
2167                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2168         }
2169         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2170         {
2171                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2172                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2173         }
2174         else if(g_assault)
2175         {
2176                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2177         }
2178         else if(g_lms)
2179         {
2180                 checkrules_status = WinningCondition_LMS();
2181         }
2182         else if (g_onslaught)
2183         {
2184                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2185         }
2186         else
2187         {
2188                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2189                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2190         }
2191
2192         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2193         {
2194                 checkrules_status = WINNING_NEVER;
2195                 checkrules_overtimesadded = -1;
2196                 wantovertime |= InitiateSuddenDeath();
2197         }
2198
2199         if(checkrules_status == WINNING_NEVER)
2200                 // equality cases! Nobody wins if the overtime ends in a draw.
2201                 ClearWinners();
2202
2203         if(wantovertime)
2204         {
2205                 if(checkrules_status == WINNING_NEVER)
2206                         InitiateOvertime();
2207                 else
2208                         checkrules_status = WINNING_YES;
2209         }
2210
2211         if(checkrules_suddendeathend)
2212                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2213                         checkrules_status = WINNING_YES;
2214
2215         if(checkrules_status == WINNING_YES)
2216         {
2217                 //print("WINNING\n");
2218                 NextLevel();
2219         }
2220 }
2221
2222 string GotoMap(string m)
2223 {
2224         m = GameTypeVote_MapInfo_FixName(m);
2225         if (!m)
2226                 return "The map you suggested is not available on this server.";
2227         if (!autocvar_sv_vote_gametype)
2228         if(!MapInfo_CheckMap(m))
2229                 return "The map you suggested does not support the current game mode.";
2230         cvar_set("nextmap", m);
2231         cvar_set("timelimit", "-1");
2232         if(mapvote_initialized || alreadychangedlevel)
2233         {
2234                 if(DoNextMapOverride(0))
2235                         return "Map switch initiated.";
2236                 else
2237                         return "Hm... no. For some reason I like THIS map more.";
2238         }
2239         else
2240                 return "Map switch will happen after scoreboard.";
2241 }
2242
2243
2244 void EndFrame()
2245 {
2246         anticheat_endframe();
2247
2248         float altime;
2249         FOR_EACH_REALCLIENT(self)
2250         {
2251                 entity e = IS_SPEC(self) ? self.enemy : self;
2252                 if(e.typehitsound)
2253                         self.typehit_time = time;
2254                 else if(e.damage_dealt)
2255                 {
2256                         self.hit_time = time;
2257                         self.damage_dealt_total += ceil(e.damage_dealt);
2258                 }
2259         }
2260         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2261         // add 1 frametime because after this, engine SV_Physics
2262         // increases time by a frametime and then networks the frame
2263         // add another frametime because client shows everything with
2264         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2265         // needed!
2266         FOR_EACH_CLIENT(self)
2267         {
2268                 self.typehitsound = false;
2269                 self.damage_dealt = 0;
2270                 antilag_record(self, altime);
2271         }
2272         FOR_EACH_MONSTER(self)
2273                 antilag_record(self, altime);
2274 }
2275
2276
2277 /*
2278  * RedirectionThink:
2279  * returns true if redirecting
2280  */
2281 float redirection_timeout;
2282 float redirection_nextthink;
2283 float RedirectionThink()
2284 {
2285         float clients_found;
2286
2287         if(redirection_target == "")
2288                 return false;
2289
2290         if(!redirection_timeout)
2291         {
2292                 cvar_set("sv_public", "-2");
2293                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2294                 if(redirection_target == "self")
2295                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2296                 else
2297                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2298         }
2299
2300         if(time < redirection_nextthink)
2301                 return true;
2302
2303         redirection_nextthink = time + 1;
2304
2305         clients_found = 0;
2306         FOR_EACH_REALCLIENT(self)
2307         {
2308                 // TODO add timer
2309                 print("Redirecting: sending connect command to ", self.netname, "\n");
2310                 if(redirection_target == "self")
2311                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2312                 else
2313                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2314                 ++clients_found;
2315         }
2316
2317         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2318
2319         if(time > redirection_timeout || clients_found == 0)
2320                 localcmd("\nwait; wait; wait; quit\n");
2321
2322         return true;
2323 }
2324
2325 void TargetMusic_RestoreGame();
2326 void RestoreGame()
2327 {
2328         // Loaded from a save game
2329         // some things then break, so let's work around them...
2330
2331         // Progs DB (capture records)
2332         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2333
2334         // Mapinfo
2335         MapInfo_Shutdown();
2336         MapInfo_Enumerate();
2337         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2338         WeaponStats_Init();
2339
2340         TargetMusic_RestoreGame();
2341 }
2342
2343 void Shutdown()
2344 {
2345         gameover = 2;
2346
2347         if(world_initialized > 0)
2348         {
2349                 world_initialized = 0;
2350                 print("Saving persistent data...\n");
2351                 Ban_SaveBans();
2352
2353                 // playerstats with unfinished match
2354                 PlayerStats_GameReport(false);
2355
2356                 if(!cheatcount_total)
2357                 {
2358                         if(autocvar_sv_db_saveasdump)
2359                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2360                         else
2361                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2362                 }
2363                 if(autocvar_developer)
2364                 {
2365                         if(autocvar_sv_db_saveasdump)
2366                                 db_dump(TemporaryDB, "server-temp.db");
2367                         else
2368                                 db_save(TemporaryDB, "server-temp.db");
2369                 }
2370                 CheatShutdown(); // must be after cheatcount check
2371                 db_close(ServerProgsDB);
2372                 db_close(TemporaryDB);
2373                 print("done!\n");
2374                 // tell the bot system the game is ending now
2375                 bot_endgame();
2376
2377                 WeaponStats_Shutdown();
2378                 MapInfo_Shutdown();
2379         }
2380         else if(world_initialized == 0)
2381         {
2382                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2383         }
2384 }