qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(targ != attacker) // not for suicides
 124         if(g_weaponarena_random)
 125         {
 126                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 127                 float culprit;
 128                 culprit = DEATH_WEAPONOF(deathtype);
 129                 if(!culprit)
 130                         culprit = attacker.weapon;
 131                 else if(!(attacker.weapons & WepSet_FromWeapon(culprit)))
 132                         culprit = attacker.weapon;
 133
 134                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 135                 {
 136                         // no exchange
 137                 }
 138                 else
 139                 {
 140                         if(!GiveFrags_randomweapons)
 141                         {
 142                                 GiveFrags_randomweapons = spawn();
 143                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 144                         }
 145
 146                         if(inWarmupStage)
 147                                 GiveFrags_randomweapons.weapons = warmup_start_weapons;
 148                         else
 149                                 GiveFrags_randomweapons.weapons = start_weapons;
 150
 151                         // all others (including the culprit): remove
 152                         GiveFrags_randomweapons.weapons &= ~attacker.weapons;
 153                         GiveFrags_randomweapons.weapons &= ~WepSet_FromWeapon(culprit);
 154
 155                         // among the remaining ones, choose one by random
 156                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 157
 158                         if(GiveFrags_randomweapons.weapons)
 159                         {
 160                                 attacker.weapons |= GiveFrags_randomweapons.weapons;
 161                                 attacker.weapons &= ~WepSet_FromWeapon(culprit);
 162                         }
 163                 }
 164
 165                 // after a frag, choose another random weapon set
 166                 if not(attacker.weapons & WepSet_FromWeapon(attacker.weapon))
 167                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 168         }
 169
 170         // FIXME fix the mess this is (we have REAL points now!)
 171         entity oldself;
 172         oldself = self;
 173         self = attacker;
 174         frag_attacker = attacker;
 175         frag_target = targ;
 176         frag_score = f;
 177         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 178         {
 179                 f = frag_score;
 180                 self = oldself;
 181         }
 182         else
 183         {
 184                 self = oldself;
 185         }
 186
 187         attacker.totalfrags += f;
 188
 189         if(f)
 190                 UpdateFrags(attacker, f);
 191 }
 192
 193 string AppendItemcodes(string s, entity player)
 194 {
 195         float w;
 196         w = player.weapon;
 197         //if(w == 0)
 198         //      w = player.switchweapon;
 199         if(w == 0)
 200                 w = player.cnt; // previous weapon!
 201         s = strcat(s, ftos(w));
 202         if(time < player.strength_finished)
 203                 s = strcat(s, "S");
 204         if(time < player.invincible_finished)
 205                 s = strcat(s, "I");
 206         if(player.flagcarried != world)
 207                 s = strcat(s, "F");
 208         if(player.BUTTON_CHAT)
 209                 s = strcat(s, "T");
 210         if(player.kh_next)
 211                 s = strcat(s, "K");
 212         return s;
 213 }
 214
 215 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 216 {
 217         string s;
 218         if(!autocvar_sv_eventlog)
 219                 return;
 220         s = strcat(":kill:", mode);
 221         s = strcat(s, ":", ftos(killer.playerid));
 222         s = strcat(s, ":", ftos(killed.playerid));
 223         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 224         s = strcat(s, ":items=");
 225         s = AppendItemcodes(s, killer);
 226         if(killed != killer)
 227         {
 228                 s = strcat(s, ":victimitems=");
 229                 s = AppendItemcodes(s, killed);
 230         }
 231         GameLogEcho(s);
 232 }
 233
 234 void Obituary_SpecialDeath(
 235         entity notif_target,
 236         float murder,
 237         float deathtype,
 238         string s1, string s2, string s3,
 239         float f1, float f2, float f3)
 240 {
 241         if(DEATH_ISSPECIAL(deathtype))
 242         {
 243                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
 244                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 245
 246                 if(murder)
 247                 {
 248                         if(deathent.death_msgmurder)
 249                         {
 250                                 Send_Notification_WOVA(
 251                                         NOTIF_ONE,
 252                                         notif_target,
 253                                         MSG_MULTI,
 254                                         deathent.death_msgmurder.nent_id,
 255                                         s1, s2, s3, "",
 256                                         f1, f2, f3, 0
 257                                 );
 258                                 Send_Notification_WOVA(
 259                                         NOTIF_ALL_EXCEPT,
 260                                         notif_target,
 261                                         MSG_INFO,
 262                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 263                                         s1, s2, s3, "",
 264                                         f1, f2, f3, 0
 265                                 );
 266                         }
 267                 }
 268                 else
 269                 {
 270                         if(deathent.death_msgself)
 271                         {
 272                                 Send_Notification_WOVA(
 273                                         NOTIF_ONE,
 274                                         notif_target,
 275                                         MSG_MULTI,
 276                                         deathent.death_msgself.nent_id,
 277                                         s1, s2, s3, "",
 278                                         f1, f2, f3, 0
 279                                 );
 280                                 Send_Notification_WOVA(
 281                                         NOTIF_ALL_EXCEPT,
 282                                         notif_target,
 283                                         MSG_INFO,
 284                                         deathent.death_msgself.nent_msginfo.nent_id,
 285                                         s1, s2, s3, "",
 286                                         f1, f2, f3, 0
 287                                 );
 288                         }
 289                 }
 290         }
 291         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 292 }
 293
 294 float w_deathtype;
 295 float Obituary_WeaponDeath(
 296         entity notif_target,
 297         float murder,
 298         float deathtype,
 299         string s1, string s2, string s3,
 300         float f1, float f2)
 301 {
 302         float death_weapon = DEATH_WEAPONOF(deathtype);
 303         if(death_weapon)
 304         {
 305                 w_deathtype = deathtype;
 306                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 307                 w_deathtype = FALSE;
 308
 309                 if(death_message)
 310                 {
 311                         Send_Notification_WOVA(
 312                                 NOTIF_ONE,
 313                                 notif_target,
 314                                 MSG_MULTI,
 315                                 death_message,
 316                                 s1, s2, s3, "",
 317                                 f1, f2, 0, 0
 318                         );
 319                         Send_Notification_WOVA(
 320                                 NOTIF_ALL_EXCEPT,
 321                                 notif_target,
 322                                 MSG_INFO,
 323                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 324                                 s1, s2, s3, "",
 325                                 f1, f2, 0, 0
 326                         );
 327                 }
 328                 else
 329                 {
 330                         dprint(sprintf(
 331                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 332                                 deathtype,
 333                                 death_weapon
 334                         ));
 335                 }
 336
 337                 return TRUE;
 338         }
 339         return FALSE;
 340 }
 341
 342 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 343 {
 344         // Sanity check
 345         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 346
 347         // Declarations
 348         float notif_firstblood = FALSE;
 349         float kill_count_to_attacker, kill_count_to_target;
 350
 351         // Set final information for the death
 352         targ.death_origin = targ.origin;
 353         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 354         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 355
 356         #ifdef NOTIFICATIONS_DEBUG
 357         Debug_Notification(
 358                 sprintf(
 359                         "Obituary(%s, %s, %s, %s = %d);\n",
 360                         attacker.netname,
 361                         inflictor.netname,
 362                         targ.netname,
 363                         Deathtype_Name(deathtype),
 364                         deathtype
 365                 )
 366         );
 367         #endif
 368
 369         // =======
 370         // SUICIDE
 371         // =======
 372         if(targ == attacker)
 373         {
 374                 if(DEATH_ISSPECIAL(deathtype))
 375                 {
 376                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 377                         {
 378                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 379                         }
 380                         else
 381                         {
 382                                 switch(deathtype)
 383                                 {
 384                                         case DEATH_MIRRORDAMAGE:
 385                                         {
 386                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 387                                                 break;
 388                                         }
 389
 390                                         default:
 391                                         {
 392                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 393                                                 break;
 394                                         }
 395                                 }
 396                         }
 397                 }
 398                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 399                 {
 400                         backtrace("SUICIDE: what the hell happened here?\n");
 401                         return;
 402                 }
 403                 LogDeath("suicide", deathtype, targ, targ);
 404                 GiveFrags(attacker, targ, -1, deathtype);
 405         }
 406
 407         // ======
 408         // MURDER
 409         // ======
 410         else if(IS_PLAYER(attacker))
 411         {
 412                 if(!IsDifferentTeam(attacker, targ))
 413                 {
 414                         LogDeath("tk", deathtype, attacker, targ);
 415                         GiveFrags(attacker, targ, -1, deathtype);
 416
 417                         attacker.killcount = 0;
 418
 419                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 420                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 421                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 422
 423                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 424                         // No need for specific death/weapon messages...
 425                 }
 426                 else
 427                 {
 428                         LogDeath("frag", deathtype, attacker, targ);
 429                         GiveFrags(attacker, targ, 1, deathtype);
 430
 431                         attacker.taunt_soundtime = time + 1;
 432                         attacker.killcount = attacker.killcount + 1;
 433
 434                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 435                                 case counta: \
 436                                 { \
 437                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 439                                         break; \
 440                                 }
 441                         switch(attacker.killcount)
 442                         {
 443                                 KILL_SPREE_LIST
 444                                 default: break;
 445                         }
 446                         #undef SPREE_ITEM
 447
 448                         if(!checkrules_firstblood)
 449                         {
 450                                 checkrules_firstblood = TRUE;
 451                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 452                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 453                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 454
 455                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 456                                 kill_count_to_attacker = -1;
 457                                 kill_count_to_target = -2;
 458                         }
 459                         else
 460                         {
 461                                 kill_count_to_attacker = attacker.killcount;
 462                                 kill_count_to_target = 0;
 463                         }
 464
 465                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 466                         if(targ.istypefrag)
 467                         {
 468                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 469                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 470                                 else
 471                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 472
 473                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 474                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 475                                 else
 476                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 477                         }
 478                         else
 479                         {
 480                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 481                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 482                                 else
 483                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 484
 485                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 486                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 487                                 else
 488                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 489                         }
 490
 491                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 492                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 493                 }
 494         }
 495
 496         // =============
 497         // ACCIDENT/TRAP
 498         // =============
 499         else
 500         {
 501                 switch(deathtype)
 502                 {
 503                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 504                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 505                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 506                         /*case DEATH_HURTTRIGGER:
 507                         {
 508                                 s1 = targ.netname;
 509                                 s2 = inflictor.message;
 510                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 511                                 break;
 512                         }*/
 513
 514                         case DEATH_CUSTOM:
 515                         {
 516                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 517                                         targ.netname,
 518                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 519                                         deathlocation,
 520                                         targ.killcount,
 521                                         0,
 522                                         0);
 523                                 break;
 524                         }
 525
 526                         default:
 527                         {
 528                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 529                                 break;
 530                         }
 531                 }
 532
 533                 LogDeath("accident", deathtype, targ, targ);
 534                 GiveFrags(targ, targ, -1, deathtype);
 535
 536                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 537                 {
 538                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 539                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 540                 }
 541         }
 542
 543         // reset target kill count
 544         if(targ.killcount) { targ.killcount = 0; }
 545 }
 546
 547 void Ice_Think()
 548 {
 549         setorigin(self, self.owner.origin - '0 0 16');
 550         self.nextthink = time;
 551 }
 552
 553 void Freeze (entity targ, float freeze_time, float frozen_type, float show_waypoint)
 554 {
 555         if(!IS_PLAYER(targ) && !(targ.flags & FL_MONSTER)) // only specified entities can be freezed
 556                 return;
 557
 558         if(targ.frozen)
 559                 return;
 560
 561         targ.frozen = frozen_type;
 562         targ.revive_progress = 0;
 563         targ.health = 1;
 564         targ.revive_speed = freeze_time;
 565
 566         entity ice, head;
 567         ice = spawn();
 568         ice.owner = targ;
 569         ice.classname = "ice";
 570         ice.scale = targ.scale;
 571         ice.think = Ice_Think;
 572         ice.nextthink = time;
 573         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 574         setmodel(ice, "models/ice/ice.md3");
 575         ice.alpha = 1;
 576         ice.colormod = Team_ColorRGB(targ.team);
 577         ice.glowmod = ice.colormod;
 578         targ.iceblock = ice;
 579
 580         entity oldself;
 581         oldself = self;
 582         self = ice;
 583         Ice_Think();
 584         self = oldself;
 585
 586         RemoveGrapplingHook(targ);
 587
 588         FOR_EACH_PLAYER(head)
 589         if(head.hook.aiment == targ)
 590                 RemoveGrapplingHook(head);
 591
 592         // add waypoint
 593         if(show_waypoint)
 594                 WaypointSprite_Spawn("frozen", 0, 0, targ, '0 0 64', world, targ.team, targ, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 595 }
 596
 597 void Unfreeze (entity targ)
 598 {
 599         if(targ.frozen) // only reset health if target was frozen
 600                 targ.health = ((IS_PLAYER(targ)) ? autocvar_g_balance_health_start : targ.max_health);
 601
 602         entity head;
 603         targ.frozen = 0;
 604         targ.revive_progress = 0;
 605
 606         WaypointSprite_Kill(targ.waypointsprite_attached);
 607
 608         FOR_EACH_PLAYER(head)
 609         if(head.hook.aiment == targ)
 610                 RemoveGrapplingHook(head);
 611
 612         // remove the ice block
 613         if(targ.iceblock)
 614                 remove(targ.iceblock);
 615         targ.iceblock = world;
 616 }
 617
 618 // these are updated by each Damage call for use in button triggering and such
 619 entity damage_targ;
 620 entity damage_inflictor;
 621 entity damage_attacker;
 622
 623 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 624 {
 625         float mirrordamage;
 626         float mirrorforce;
 627         float complainteamdamage = 0;
 628         entity attacker_save;
 629         mirrordamage = 0;
 630         mirrorforce = 0;
 631
 632         if (gameover || targ.killcount == -666)
 633                 return;
 634
 635         entity oldself;
 636         oldself = self;
 637         self = targ;
 638         damage_targ = targ;
 639         damage_inflictor = inflictor;
 640         damage_attacker = attacker;
 641                 attacker_save = attacker;
 642
 643         if(IS_PLAYER(targ))
 644                 if(targ.hook)
 645                         if(targ.hook.aiment)
 646                                 if(targ.hook.aiment == attacker)
 647                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 648
 649         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 650         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 651         {
 652                 if(IS_PLAYER(targ))
 653                         if not(IsDifferentTeam(targ, attacker))
 654                         {
 655                                 self = oldself;
 656                                 return;
 657                         }
 658         }
 659
 660         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 661         {
 662                 // These are ALWAYS lethal
 663                 // No damage modification here
 664                 // Instead, prepare the victim for his death...
 665                 targ.armorvalue = 0;
 666                 targ.spawnshieldtime = 0;
 667                 targ.health = 0.9; // this is < 1
 668                 targ.flags -= targ.flags & FL_GODMODE;
 669                 damage = 100000;
 670         }
 671         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 672         {
 673                 // no processing
 674         }
 675         else
 676         {
 677                 // nullify damage if teamplay is on
 678                 if(deathtype != DEATH_TELEFRAG)
 679                 if(IS_PLAYER(attacker))
 680                 {
 681                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 682                         {
 683                                 damage = 0;
 684                                 force = '0 0 0';
 685                         }
 686                         else if(!IsDifferentTeam(attacker, targ))
 687                         {
 688                                 if(autocvar_teamplay_mode == 1)
 689                                         damage = 0;
 690                                 else if(attacker != targ)
 691                                 {
 692                                         if(autocvar_teamplay_mode == 3)
 693                                                 damage = 0;
 694                                         else if(autocvar_teamplay_mode == 4)
 695                                         {
 696                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 697                                                 {
 698                                                         attacker.dmg_team = attacker.dmg_team + damage;
 699                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 700                                                         if(complainteamdamage > 0)
 701                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 702                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 703                                                         damage = autocvar_g_friendlyfire * damage;
 704                                                         // mirrordamage will be used LATER
 705
 706                                                         if(autocvar_g_mirrordamage_virtual)
 707                                                         {
 708                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 709                                                                 attacker.dmg_take += v_x;
 710                                                                 attacker.dmg_save += v_y;
 711                                                                 attacker.dmg_inflictor = inflictor;
 712                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 713                                                                 mirrorforce = 0;
 714                                                         }
 715
 716                                                         if(autocvar_g_friendlyfire_virtual)
 717                                                         {
 718                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 719                                                                 targ.dmg_take += v_x;
 720                                                                 targ.dmg_save += v_y;
 721                                                                 targ.dmg_inflictor = inflictor;
 722                                                                 damage = 0;
 723                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 724                                                                         force = '0 0 0';
 725                                                         }
 726                                                 }
 727                                                 else
 728                                                         damage = 0;
 729                                         }
 730                                 }
 731                         }
 732                 }
 733
 734                 if not(DEATH_ISSPECIAL(deathtype))
 735                 {
 736                         damage *= g_weapondamagefactor;
 737                         mirrordamage *= g_weapondamagefactor;
 738                         complainteamdamage *= g_weapondamagefactor;
 739                         force = force * g_weaponforcefactor;
 740                         mirrorforce *= g_weaponforcefactor;
 741                 }
 742
 743                 if(((targ.frozen == 2 && attacker.monsterid != MON_SPIDER) || (targ.frozen == 1)) && deathtype != DEATH_HURTTRIGGER)
 744                 {
 745                         damage = 0;
 746                         force *= 0.2;
 747                 }
 748
 749                 // should this be changed at all? If so, in what way?
 750                 frag_attacker = attacker;
 751                 frag_target = targ;
 752                 frag_damage = damage;
 753                 frag_force = force;
 754                 frag_deathtype = deathtype;
 755                 frag_mirrordamage = mirrordamage;
 756                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 757                 damage = frag_damage;
 758                 mirrordamage = frag_mirrordamage;
 759                 force = frag_force;
 760
 761                 if not(g_minstagib)
 762                 {
 763                         // apply strength multiplier
 764                         if (attacker.items & IT_STRENGTH)
 765                         {
 766                                 if(targ == attacker)
 767                                 {
 768                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 769                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 770                                 }
 771                                 else
 772                                 {
 773                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 774                                         force = force * autocvar_g_balance_powerup_strength_force;
 775                                 }
 776                         }
 777
 778                         // apply invincibility multiplier
 779                         if (targ.items & IT_INVINCIBLE)
 780                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 781                 }
 782
 783                 if (targ == attacker)
 784                 {
 785                         if(g_cts && !autocvar_g_cts_selfdamage)
 786                                 damage = 0;
 787                         else
 788                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 789                 }
 790
 791                 // count the damage
 792                 if(attacker)
 793                 if(!targ.deadflag)
 794                 if(targ.takedamage == DAMAGE_AIM)
 795                 if(targ != attacker)
 796                 {
 797                         entity victim;
 798                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 799                                 victim = targ.owner;
 800                         else
 801                                 victim = targ;
 802
 803                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET || victim.flags & FL_MONSTER)
 804                         {
 805                                 if(IsDifferentTeam(victim, attacker))
 806                                 {
 807                                         if(damage > 0)
 808                                         {
 809                                                 if(deathtype != DEATH_FIRE)
 810                                                 {
 811                                                         if(victim.BUTTON_CHAT)
 812                                                                 attacker.typehitsound += 1;
 813                                                         else
 814                                                                 attacker.hitsound += 1;
 815                                                 }
 816
 817                                                 damage_goodhits += 1;
 818                                                 damage_gooddamage += damage;
 819
 820                                                 if not(DEATH_ISSPECIAL(deathtype))
 821                                                 {
 822                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 823                                                         if(IsFlying(victim))
 824                                                                 yoda = 1;
 825                                                 }
 826                                         }
 827                                 }
 828                                 else
 829                                 {
 830                                         if(deathtype != DEATH_FIRE)
 831                                         {
 832                                                 attacker.typehitsound += 1;
 833                                         }
 834                                         if(complainteamdamage > 0)
 835                                                 if(time > attacker.teamkill_complain)
 836                                                 {
 837                                                         attacker.teamkill_complain = time + 5;
 838                                                         attacker.teamkill_soundtime = time + 0.4;
 839                                                         attacker.teamkill_soundsource = targ;
 840                                                 }
 841                                 }
 842                         }
 843                 }
 844         }
 845
 846         // apply push
 847         if (self.damageforcescale)
 848         if (vlen(force))
 849         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
 850         {
 851                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 852                 if(self.movetype == MOVETYPE_PHYSICS)
 853                 {
 854                         entity farcent;
 855                         farcent = spawn();
 856                         farcent.classname = "farce";
 857                         farcent.enemy = self;
 858                         farcent.movedir = farce * 10;
 859                         if(self.mass)
 860                                 farcent.movedir = farcent.movedir * self.mass;
 861                         farcent.origin = hitloc;
 862                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 863                         farcent.nextthink = time + 0.1;
 864                         farcent.think = SUB_Remove;
 865                 }
 866                 else
 867                         self.velocity = self.velocity + farce;
 868                 self.flags &= ~FL_ONGROUND;
 869                 UpdateCSQCProjectile(self);
 870         }
 871         // apply damage
 872         if (damage != 0 || (self.damageforcescale && vlen(force)))
 873         if (self.event_damage)
 874                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 875         self = oldself;
 876
 877         // apply mirror damage if any
 878         if(mirrordamage > 0 || mirrorforce > 0)
 879         {
 880                 attacker = attacker_save;
 881
 882                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 883                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 884         }
 885 }
 886
 887 float RadiusDamage_running;
 888 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 889         // Returns total damage applies to creatures
 890 {
 891         entity  targ;
 892         vector  blastorigin;
 893         vector  force;
 894         float   total_damage_to_creatures;
 895         entity  next;
 896         float   tfloordmg;
 897         float   tfloorforce;
 898
 899         float stat_damagedone;
 900
 901         if(RadiusDamage_running)
 902         {
 903                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 904                 return 0;
 905         }
 906
 907         RadiusDamage_running = 1;
 908
 909         tfloordmg = autocvar_g_throughfloor_damage;
 910         tfloorforce = autocvar_g_throughfloor_force;
 911
 912         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 913         total_damage_to_creatures = 0;
 914
 915         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 916                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 917                 {
 918                         force = inflictor.velocity;
 919                         if(vlen(force) == 0)
 920                                 force = '0 0 -1';
 921                         else
 922                                 force = normalize(force);
 923                         if(forceintensity >= 0)
 924                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 925                         else
 926                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 927                 }
 928
 929         stat_damagedone = 0;
 930
 931         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 932         while (targ)
 933         {
 934                 next = targ.chain;
 935                 if (targ != inflictor)
 936                         if (ignore != targ) if(targ.takedamage)
 937                         {
 938                                 vector nearest;
 939                                 vector diff;
 940                                 float power;
 941
 942                                 // LordHavoc: measure distance to nearest point on target (not origin)
 943                                 // (this guarentees 100% damage on a touch impact)
 944                                 nearest = targ.WarpZone_findradius_nearest;
 945                                 diff = targ.WarpZone_findradius_dist;
 946                                 // round up a little on the damage to ensure full damage on impacts
 947                                 // and turn the distance into a fraction of the radius
 948                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 949                                 //bprint(" ");
 950                                 //bprint(ftos(power));
 951                                 //if (targ == attacker)
 952                                 //      print(ftos(power), "\n");
 953                                 if (power > 0)
 954                                 {
 955                                         float finaldmg;
 956                                         if (power > 1)
 957                                                 power = 1;
 958                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 959                                         if (finaldmg > 0)
 960                                         {
 961                                                 float a;
 962                                                 float c;
 963                                                 vector hitloc;
 964                                                 vector myblastorigin;
 965                                                 vector center;
 966
 967                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 968
 969                                                 // if it's a player, use the view origin as reference
 970                                                 center = CENTER_OR_VIEWOFS(targ);
 971
 972                                                 force = normalize(center - myblastorigin);
 973                                                 force = force * (finaldmg / coredamage) * forceintensity;
 974                                                 hitloc = nearest;
 975
 976                                                 if(targ != directhitentity)
 977                                                 {
 978                                                         float hits;
 979                                                         float total;
 980                                                         float hitratio;
 981                                                         float mininv_f, mininv_d;
 982
 983                                                         // test line of sight to multiple positions on box,
 984                                                         // and do damage if any of them hit
 985                                                         hits = 0;
 986
 987                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 988                                                         // so for a given max stddev:
 989                                                         // n = (1 / (2 * max stddev of hitratio))^2
 990
 991                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 992                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 993
 994                                                         if(autocvar_g_throughfloor_debug)
 995                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
 996
 997                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
 998
 999                                                         if(autocvar_g_throughfloor_debug)
1000                                                                 print(sprintf(" steps=%f", total));
1001
1002                                                         if (IS_PLAYER(targ))
1003                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1004                                                         else
1005                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1006
1007                                                         if(autocvar_g_throughfloor_debug)
1008                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1009
1010                                                         for(c = 0; c < total; ++c)
1011                                                         {
1012                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1013                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1014                                                                 if (trace_fraction == 1 || trace_ent == targ)
1015                                                                 {
1016                                                                         ++hits;
1017                                                                         if (hits > 1)
1018                                                                                 hitloc = hitloc + nearest;
1019                                                                         else
1020                                                                                 hitloc = nearest;
1021                                                                 }
1022                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1023                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1024                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1025                                                         }
1026
1027                                                         nearest = hitloc * (1 / max(1, hits));
1028                                                         hitratio = (hits / total);
1029                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1030                                                         finaldmg = finaldmg * a;
1031                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1032                                                         force = force * a;
1033
1034                                                         if(autocvar_g_throughfloor_debug)
1035                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1036                                                 }
1037
1038                                                 // laser force adjustments :P
1039                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1040                                                 {
1041                                                         if (targ == attacker)
1042                                                         {
1043                                                                 vector vel;
1044
1045                                                                 float force_zscale;
1046                                                                 float force_velocitybiasramp;
1047                                                                 float force_velocitybias;
1048
1049                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1050                                                                 if(deathtype & HITTYPE_SECONDARY)
1051                                                                 {
1052                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1053                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1054                                                                 }
1055                                                                 else
1056                                                                 {
1057                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1058                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1059                                                                 }
1060
1061                                                                 vel = targ.velocity;
1062                                                                 vel_z = 0;
1063                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1064                                                                 force =
1065                                                                         vlen(force)
1066                                                                         *
1067                                                                         normalize(normalize(force) + vel);
1068
1069                                                                 force_z *= force_zscale;
1070                                                         }
1071                                                         else
1072                                                         {
1073                                                                 if(deathtype & HITTYPE_SECONDARY)
1074                                                                 {
1075                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1076                                                                 }
1077                                                                 else
1078                                                                 {
1079                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1080                                                                 }
1081                                                         }
1082                                                 }
1083
1084                                                 //if (targ == attacker)
1085                                                 //{
1086                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1087                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1088                                                 //      print(" (", ftos(a), ")\n");
1089                                                 //}
1090                                                 if(finaldmg || vlen(force))
1091                                                 {
1092                                                         if(targ.iscreature)
1093                                                         {
1094                                                                 total_damage_to_creatures += finaldmg;
1095
1096                                                                 if(accuracy_isgooddamage(attacker, targ))
1097                                                                         stat_damagedone += finaldmg;
1098                                                         }
1099
1100                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1101                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1102                                                         else
1103                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1104                                                 }
1105                                         }
1106                                 }
1107                         }
1108                 targ = next;
1109         }
1110
1111         RadiusDamage_running = 0;
1112
1113         if(!DEATH_ISSPECIAL(deathtype))
1114                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1115
1116         return total_damage_to_creatures;
1117 }
1118
1119 .float fire_damagepersec;
1120 .float fire_endtime;
1121 .float fire_deathtype;
1122 .entity fire_owner;
1123 .float fire_hitsound;
1124 .entity fire_burner;
1125
1126 void fireburner_think();
1127
1128 float Fire_IsBurning(entity e)
1129 {
1130         return (time < e.fire_endtime);
1131 }
1132
1133 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1134 {
1135         float dps;
1136         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1137
1138         if(IS_PLAYER(e))
1139         {
1140                 if(e.deadflag)
1141                         return -1;
1142         }
1143         else
1144         {
1145                 if(!e.fire_burner)
1146                 {
1147                         // print("adding a fire burner to ", e.classname, "\n");
1148                         e.fire_burner = spawn();
1149                         e.fire_burner.classname = "fireburner";
1150                         e.fire_burner.think = fireburner_think;
1151                         e.fire_burner.nextthink = time;
1152                         e.fire_burner.owner = e;
1153                 }
1154         }
1155
1156         t = max(t, 0.1);
1157         dps = d / t;
1158         if(Fire_IsBurning(e))
1159         {
1160                 mintime = e.fire_endtime - time;
1161                 maxtime = max(mintime, t);
1162
1163                 mindps = e.fire_damagepersec;
1164                 maxdps = max(mindps, dps);
1165
1166                 if(maxtime > mintime || maxdps > mindps)
1167                 {
1168                         // Constraints:
1169
1170                         // damage we have right now
1171                         mindamage = mindps * mintime;
1172
1173                         // damage we want to get
1174                         maxdamage = mindamage + d;
1175
1176                         // but we can't exceed maxtime * maxdps!
1177                         totaldamage = min(maxdamage, maxtime * maxdps);
1178
1179                         // LEMMA:
1180                         // Look at:
1181                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1182                         // We see:
1183                         // totaldamage <= maxtime * maxdps
1184                         // ==> totaldamage / maxdps <= maxtime.
1185                         // We also see:
1186                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1187                         //                     >= min(mintime, maxtime)
1188                         // ==> totaldamage / maxdps >= mintime.
1189
1190                         /*
1191                         // how long do we damage then?
1192                         // at least as long as before
1193                         // but, never exceed maxdps
1194                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1195                         */
1196
1197                         // alternate:
1198                         // at most as long as maximum allowed
1199                         // but, never below mindps
1200                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1201
1202                         // assuming t > mintime, dps > mindps:
1203                         // we get d = t * dps = maxtime * maxdps
1204                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1205                         // totaldamage / maxdps = maxtime
1206                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1207                         // FROM THIS:
1208                         // a) totaltime = max(mintime, maxtime) = maxtime
1209                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1210
1211                         // assuming t <= mintime:
1212                         // we get maxtime = mintime
1213                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1214                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1215
1216                         // assuming dps <= mindps:
1217                         // we get mindps = maxdps.
1218                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1219                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1220                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1221
1222                         e.fire_damagepersec = totaldamage / totaltime;
1223                         e.fire_endtime = time + totaltime;
1224                         if(totaldamage > 1.2 * mindamage)
1225                         {
1226                                 e.fire_deathtype = dt;
1227                                 if(e.fire_owner != o)
1228                                 {
1229                                         e.fire_owner = o;
1230                                         e.fire_hitsound = FALSE;
1231                                 }
1232                         }
1233                         if(accuracy_isgooddamage(o, e))
1234                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1235                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1236                 }
1237                 else
1238                         return 0;
1239         }
1240         else
1241         {
1242                 e.fire_damagepersec = dps;
1243                 e.fire_endtime = time + t;
1244                 e.fire_deathtype = dt;
1245                 e.fire_owner = o;
1246                 e.fire_hitsound = FALSE;
1247                 if(accuracy_isgooddamage(o, e))
1248                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1249                 return d;
1250         }
1251 }
1252
1253 void Fire_ApplyDamage(entity e)
1254 {
1255         float t, d, hi, ty;
1256         entity o;
1257
1258         if not(Fire_IsBurning(e))
1259                 return;
1260
1261         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1262         if(IS_NOT_A_CLIENT(o))
1263                 o = e.fire_owner;
1264
1265         // water and slime stop fire
1266         if(e.waterlevel)
1267         if(e.watertype != CONTENT_LAVA)
1268                 e.fire_endtime = 0;
1269
1270         // ice stops fire
1271         if(e.frozen)
1272                 e.fire_endtime = 0;
1273
1274         t = min(frametime, e.fire_endtime - time);
1275         d = e.fire_damagepersec * t;
1276
1277         hi = e.fire_owner.hitsound;
1278         ty = e.fire_owner.typehitsound;
1279         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1280         if(e.fire_hitsound && e.fire_owner)
1281         {
1282                 e.fire_owner.hitsound = hi;
1283                 e.fire_owner.typehitsound = ty;
1284         }
1285         e.fire_hitsound = TRUE;
1286
1287         if not(IS_INDEPENDENT_PLAYER(e))
1288         FOR_EACH_PLAYER(other) if(e != other)
1289         {
1290                 if(IS_PLAYER(other))
1291                 if(other.deadflag == DEAD_NO)
1292                 if not(IS_INDEPENDENT_PLAYER(other))
1293                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1294                 {
1295                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1296                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1297                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1298                 }
1299         }
1300 }
1301
1302 void Fire_ApplyEffect(entity e)
1303 {
1304         if(Fire_IsBurning(e))
1305                 e.effects |= EF_FLAME;
1306         else
1307                 e.effects &= ~EF_FLAME;
1308 }
1309
1310 void fireburner_think()
1311 {
1312         // for players, this is done in the regular loop
1313         if(wasfreed(self.owner))
1314         {
1315                 remove(self);
1316                 return;
1317         }
1318         Fire_ApplyEffect(self.owner);
1319         if(!Fire_IsBurning(self.owner))
1320         {
1321                 self.owner.fire_burner = world;
1322                 remove(self);
1323                 return;
1324         }
1325         Fire_ApplyDamage(self.owner);
1326         self.nextthink = time;
1327 }