qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(targ != attacker) // not for suicides
 124         if(g_weaponarena_random)
 125         {
 126                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 127                 float culprit;
 128                 culprit = DEATH_WEAPONOF(deathtype);
 129                 if(!culprit)
 130                         culprit = attacker.weapon;
 131                 else if(!(attacker.weapons & WepSet_FromWeapon(culprit)))
 132                         culprit = attacker.weapon;
 133
 134                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 135                 {
 136                         // no exchange
 137                 }
 138                 else
 139                 {
 140                         if(!GiveFrags_randomweapons)
 141                         {
 142                                 GiveFrags_randomweapons = spawn();
 143                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 144                         }
 145
 146                         if(inWarmupStage)
 147                                 GiveFrags_randomweapons.weapons = warmup_start_weapons;
 148                         else
 149                                 GiveFrags_randomweapons.weapons = start_weapons;
 150
 151                         // all others (including the culprit): remove
 152                         GiveFrags_randomweapons.weapons &= ~attacker.weapons;
 153                         GiveFrags_randomweapons.weapons &= ~WepSet_FromWeapon(culprit);
 154
 155                         // among the remaining ones, choose one by random
 156                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 157
 158                         if(GiveFrags_randomweapons.weapons)
 159                         {
 160                                 attacker.weapons |= GiveFrags_randomweapons.weapons;
 161                                 attacker.weapons &= ~WepSet_FromWeapon(culprit);
 162                         }
 163                 }
 164
 165                 // after a frag, choose another random weapon set
 166                 if not(attacker.weapons & WepSet_FromWeapon(attacker.weapon))
 167                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 168         }
 169
 170         // FIXME fix the mess this is (we have REAL points now!)
 171         entity oldself;
 172         oldself = self;
 173         self = attacker;
 174         frag_attacker = attacker;
 175         frag_target = targ;
 176         frag_score = f;
 177         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 178         {
 179                 f = frag_score;
 180                 self = oldself;
 181         }
 182         else
 183         {
 184                 self = oldself;
 185         }
 186
 187         attacker.totalfrags += f;
 188
 189         if(f)
 190                 UpdateFrags(attacker, f);
 191 }
 192
 193 string AppendItemcodes(string s, entity player)
 194 {
 195         float w;
 196         w = player.weapon;
 197         //if(w == 0)
 198         //      w = player.switchweapon;
 199         if(w == 0)
 200                 w = player.cnt; // previous weapon!
 201         s = strcat(s, ftos(w));
 202         if(time < player.strength_finished)
 203                 s = strcat(s, "S");
 204         if(time < player.invincible_finished)
 205                 s = strcat(s, "I");
 206         if(player.flagcarried != world)
 207                 s = strcat(s, "F");
 208         if(player.BUTTON_CHAT)
 209                 s = strcat(s, "T");
 210         if(player.kh_next)
 211                 s = strcat(s, "K");
 212         return s;
 213 }
 214
 215 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 216 {
 217         string s;
 218         if(!autocvar_sv_eventlog)
 219                 return;
 220         s = strcat(":kill:", mode);
 221         s = strcat(s, ":", ftos(killer.playerid));
 222         s = strcat(s, ":", ftos(killed.playerid));
 223         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 224         s = strcat(s, ":items=");
 225         s = AppendItemcodes(s, killer);
 226         if(killed != killer)
 227         {
 228                 s = strcat(s, ":victimitems=");
 229                 s = AppendItemcodes(s, killed);
 230         }
 231         GameLogEcho(s);
 232 }
 233
 234 void Obituary_SpecialDeath(
 235         entity notif_target,
 236         float murder,
 237         float deathtype,
 238         string s1, string s2, string s3,
 239         float f1, float f2, float f3)
 240 {
 241         if(DEATH_ISSPECIAL(deathtype))
 242         {
 243                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
 244                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 245
 246                 if(murder)
 247                 {
 248                         if(deathent.death_msgmurder)
 249                         {
 250                                 Send_Notification_WOVA(
 251                                         NOTIF_ONE,
 252                                         notif_target,
 253                                         MSG_MULTI,
 254                                         deathent.death_msgmurder.nent_id,
 255                                         s1, s2, s3, "",
 256                                         f1, f2, f3, 0
 257                                 );
 258                                 Send_Notification_WOVA(
 259                                         NOTIF_ALL_EXCEPT,
 260                                         notif_target,
 261                                         MSG_INFO,
 262                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 263                                         s1, s2, s3, "",
 264                                         f1, f2, f3, 0
 265                                 );
 266                         }
 267                 }
 268                 else
 269                 {
 270                         if(deathent.death_msgself)
 271                         {
 272                                 Send_Notification_WOVA(
 273                                         NOTIF_ONE,
 274                                         notif_target,
 275                                         MSG_MULTI,
 276                                         deathent.death_msgself.nent_id,
 277                                         s1, s2, s3, "",
 278                                         f1, f2, f3, 0
 279                                 );
 280                                 Send_Notification_WOVA(
 281                                         NOTIF_ALL_EXCEPT,
 282                                         notif_target,
 283                                         MSG_INFO,
 284                                         deathent.death_msgself.nent_msginfo.nent_id,
 285                                         s1, s2, s3, "",
 286                                         f1, f2, f3, 0
 287                                 );
 288                         }
 289                 }
 290         }
 291         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 292 }
 293
 294 float w_deathtype;
 295 float Obituary_WeaponDeath(
 296         entity notif_target,
 297         float murder,
 298         float deathtype,
 299         string s1, string s2, string s3,
 300         float f1, float f2)
 301 {
 302         float death_weapon = DEATH_WEAPONOF(deathtype);
 303         if(death_weapon)
 304         {
 305                 w_deathtype = deathtype;
 306                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 307                 w_deathtype = FALSE;
 308
 309                 if(death_message)
 310                 {
 311                         Send_Notification_WOVA(
 312                                 NOTIF_ONE,
 313                                 notif_target,
 314                                 MSG_MULTI,
 315                                 death_message,
 316                                 s1, s2, s3, "",
 317                                 f1, f2, 0, 0
 318                         );
 319                         Send_Notification_WOVA(
 320                                 NOTIF_ALL_EXCEPT,
 321                                 notif_target,
 322                                 MSG_INFO,
 323                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 324                                 s1, s2, s3, "",
 325                                 f1, f2, 0, 0
 326                         );
 327                 }
 328                 else
 329                 {
 330                         dprint(sprintf(
 331                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 332                                 deathtype,
 333                                 death_weapon
 334                         ));
 335                 }
 336
 337                 return TRUE;
 338         }
 339         return FALSE;
 340 }
 341
 342 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 343 {
 344         // Sanity check
 345         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 346
 347         // Declarations
 348         float notif_firstblood = FALSE;
 349         float kill_count_to_attacker, kill_count_to_target;
 350
 351         // Set final information for the death
 352         targ.death_origin = targ.origin;
 353         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 354         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 355
 356         #ifdef NOTIFICATIONS_DEBUG
 357         Debug_Notification(
 358                 sprintf(
 359                         "Obituary(%s, %s, %s, %s = %d);\n",
 360                         attacker.netname,
 361                         inflictor.netname,
 362                         targ.netname,
 363                         Deathtype_Name(deathtype),
 364                         deathtype
 365                 )
 366         );
 367         #endif
 368
 369         // =======
 370         // SUICIDE
 371         // =======
 372         if(targ == attacker)
 373         {
 374                 if(DEATH_ISSPECIAL(deathtype))
 375                 {
 376                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 377                         {
 378                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 379                         }
 380                         else
 381                         {
 382                                 switch(deathtype)
 383                                 {
 384                                         case DEATH_MIRRORDAMAGE:
 385                                         {
 386                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 387                                                 break;
 388                                         }
 389
 390                                         default:
 391                                         {
 392                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 393                                                 break;
 394                                         }
 395                                 }
 396                         }
 397                 }
 398                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 399                 {
 400                         backtrace("SUICIDE: what the hell happened here?\n");
 401                         return;
 402                 }
 403                 LogDeath("suicide", deathtype, targ, targ);
 404                 GiveFrags(attacker, targ, -1, deathtype);
 405         }
 406
 407         // ======
 408         // MURDER
 409         // ======
 410         else if(IS_PLAYER(attacker))
 411         {
 412                 if(!IsDifferentTeam(attacker, targ))
 413                 {
 414                         LogDeath("tk", deathtype, attacker, targ);
 415                         GiveFrags(attacker, targ, -1, deathtype);
 416
 417                         attacker.killcount = 0;
 418
 419                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 420                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 421                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 422
 423                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 424                         // No need for specific death/weapon messages...
 425                 }
 426                 else
 427                 {
 428                         LogDeath("frag", deathtype, attacker, targ);
 429                         GiveFrags(attacker, targ, 1, deathtype);
 430
 431                         attacker.taunt_soundtime = time + 1;
 432                         attacker.killcount = attacker.killcount + 1;
 433
 434                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 435                                 case counta: \
 436                                 { \
 437                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 439                                         break; \
 440                                 }
 441                         switch(attacker.killcount)
 442                         {
 443                                 KILL_SPREE_LIST
 444                                 default: break;
 445                         }
 446                         #undef SPREE_ITEM
 447
 448                         if(!checkrules_firstblood)
 449                         {
 450                                 checkrules_firstblood = TRUE;
 451                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 452                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 453                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 454
 455                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 456                                 kill_count_to_attacker = -1;
 457                                 kill_count_to_target = -2;
 458                         }
 459                         else
 460                         {
 461                                 kill_count_to_attacker = attacker.killcount;
 462                                 kill_count_to_target = 0;
 463                         }
 464
 465                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 466                         if(targ.istypefrag)
 467                         {
 468                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 469                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 470                                 else
 471                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 472
 473                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 474                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 475                                 else
 476                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 477                         }
 478                         else
 479                         {
 480                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 481                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 482                                 else
 483                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 484
 485                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 486                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 487                                 else
 488                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 489                         }
 490
 491                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 492                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 493                 }
 494         }
 495
 496         // =============
 497         // ACCIDENT/TRAP
 498         // =============
 499         else
 500         {
 501                 switch(deathtype)
 502                 {
 503                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 504                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 505                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 506                         /*case DEATH_HURTTRIGGER:
 507                         {
 508                                 s1 = targ.netname;
 509                                 s2 = inflictor.message;
 510                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 511                                 break;
 512                         }*/
 513
 514                         case DEATH_CUSTOM:
 515                         {
 516                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 517                                         targ.netname,
 518                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 519                                         deathlocation,
 520                                         targ.killcount,
 521                                         0,
 522                                         0);
 523                                 break;
 524                         }
 525
 526                         default:
 527                         {
 528                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 529                                 break;
 530                         }
 531                 }
 532
 533                 LogDeath("accident", deathtype, targ, targ);
 534                 GiveFrags(targ, targ, -1, deathtype);
 535
 536                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 537                 {
 538                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 539                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 540                 }
 541         }
 542
 543         // reset target kill count
 544         if(targ.killcount) { targ.killcount = 0; }
 545 }
 546
 547 // these are updated by each Damage call for use in button triggering and such
 548 entity damage_targ;
 549 entity damage_inflictor;
 550 entity damage_attacker;
 551
 552 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 553 {
 554         float mirrordamage;
 555         float mirrorforce;
 556         float complainteamdamage = 0;
 557         entity attacker_save;
 558         mirrordamage = 0;
 559         mirrorforce = 0;
 560
 561         if (gameover || targ.killcount == -666)
 562                 return;
 563
 564         entity oldself;
 565         oldself = self;
 566         self = targ;
 567         damage_targ = targ;
 568         damage_inflictor = inflictor;
 569         damage_attacker = attacker;
 570                 attacker_save = attacker;
 571
 572         if(IS_PLAYER(targ))
 573                 if(targ.hook)
 574                         if(targ.hook.aiment)
 575                                 if(targ.hook.aiment == attacker)
 576                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 577
 578         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 579         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 580         {
 581                 if(IS_PLAYER(targ))
 582                         if not(IsDifferentTeam(targ, attacker))
 583                         {
 584                                 self = oldself;
 585                                 return;
 586                         }
 587         }
 588
 589         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 590         {
 591                 // exit the vehicle before killing (fixes a crash)
 592                 if(IS_PLAYER(targ) && targ.vehicle)
 593                         vehicles_exit(VHEF_RELESE);
 594
 595                 // These are ALWAYS lethal
 596                 // No damage modification here
 597                 // Instead, prepare the victim for his death...
 598                 targ.armorvalue = 0;
 599                 targ.spawnshieldtime = 0;
 600                 targ.health = 0.9; // this is < 1
 601                 targ.flags -= targ.flags & FL_GODMODE;
 602                 damage = 100000;
 603         }
 604         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 605         {
 606                 // no processing
 607         }
 608         else
 609         {
 610                 // nullify damage if teamplay is on
 611                 if(deathtype != DEATH_TELEFRAG)
 612                 if(IS_PLAYER(attacker))
 613                 {
 614                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 615                         {
 616                                 damage = 0;
 617                                 force = '0 0 0';
 618                         }
 619                         else if(!IsDifferentTeam(attacker, targ))
 620                         {
 621                                 if(autocvar_teamplay_mode == 1)
 622                                         damage = 0;
 623                                 else if(attacker != targ)
 624                                 {
 625                                         if(autocvar_teamplay_mode == 3)
 626                                                 damage = 0;
 627                                         else if(autocvar_teamplay_mode == 4)
 628                                         {
 629                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 630                                                 {
 631                                                         attacker.dmg_team = attacker.dmg_team + damage;
 632                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 633                                                         if(complainteamdamage > 0)
 634                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 635                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 636                                                         damage = autocvar_g_friendlyfire * damage;
 637                                                         // mirrordamage will be used LATER
 638
 639                                                         if(autocvar_g_mirrordamage_virtual)
 640                                                         {
 641                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 642                                                                 attacker.dmg_take += v_x;
 643                                                                 attacker.dmg_save += v_y;
 644                                                                 attacker.dmg_inflictor = inflictor;
 645                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 646                                                                 mirrorforce = 0;
 647                                                         }
 648
 649                                                         if(autocvar_g_friendlyfire_virtual)
 650                                                         {
 651                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 652                                                                 targ.dmg_take += v_x;
 653                                                                 targ.dmg_save += v_y;
 654                                                                 targ.dmg_inflictor = inflictor;
 655                                                                 damage = 0;
 656                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 657                                                                         force = '0 0 0';
 658                                                         }
 659                                                 }
 660                                                 else
 661                                                         damage = 0;
 662                                         }
 663                                 }
 664                         }
 665                 }
 666
 667                 if not(DEATH_ISSPECIAL(deathtype))
 668                 {
 669                         damage *= g_weapondamagefactor;
 670                         mirrordamage *= g_weapondamagefactor;
 671                         complainteamdamage *= g_weapondamagefactor;
 672                         force = force * g_weaponforcefactor;
 673                         mirrorforce *= g_weaponforcefactor;
 674                 }
 675
 676                 // should this be changed at all? If so, in what way?
 677                 frag_attacker = attacker;
 678                 frag_target = targ;
 679                 frag_damage = damage;
 680                 frag_force = force;
 681         frag_deathtype = deathtype;
 682                 frag_mirrordamage = mirrordamage;
 683                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 684                 damage = frag_damage;
 685                 mirrordamage = frag_mirrordamage;
 686                 force = frag_force;
 687
 688                 if not(g_minstagib)
 689                 {
 690                         // apply strength multiplier
 691                         if (attacker.items & IT_STRENGTH)
 692                         {
 693                                 if(targ == attacker)
 694                                 {
 695                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 696                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 697                                 }
 698                                 else
 699                                 {
 700                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 701                                         force = force * autocvar_g_balance_powerup_strength_force;
 702                                 }
 703                         }
 704
 705                         // apply invincibility multiplier
 706                         if (targ.items & IT_INVINCIBLE)
 707                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 708                 }
 709
 710                 if (targ == attacker)
 711                 {
 712                         if(g_cts && !autocvar_g_cts_selfdamage)
 713                                 damage = 0;
 714                         else
 715                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 716                 }
 717
 718                 // count the damage
 719                 if(attacker)
 720                 if(!targ.deadflag)
 721                 if(targ.takedamage == DAMAGE_AIM)
 722                 if(targ != attacker)
 723                 {
 724                         entity victim;
 725                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 726                                 victim = targ.owner;
 727                         else
 728                                 victim = targ;
 729
 730                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 731                         {
 732                                 if(IsDifferentTeam(victim, attacker))
 733                                 {
 734                                         if(damage > 0)
 735                                         {
 736                                                 if(deathtype != DEATH_FIRE)
 737                                                 {
 738                                                         if(victim.BUTTON_CHAT)
 739                                                                 attacker.typehitsound += 1;
 740                                                         else
 741                                                                 attacker.hitsound += 1;
 742                                                 }
 743
 744                                                 damage_goodhits += 1;
 745                                                 damage_gooddamage += damage;
 746
 747                                                 if not(DEATH_ISSPECIAL(deathtype))
 748                                                 {
 749                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 750                                                         if(IsFlying(victim))
 751                                                                 yoda = 1;
 752                                                 }
 753                                         }
 754                                 }
 755                                 else
 756                                 {
 757                                         if(deathtype != DEATH_FIRE)
 758                                         {
 759                                                 attacker.typehitsound += 1;
 760                                         }
 761                                         if(complainteamdamage > 0)
 762                                                 if(time > attacker.teamkill_complain)
 763                                                 {
 764                                                         attacker.teamkill_complain = time + 5;
 765                                                         attacker.teamkill_soundtime = time + 0.4;
 766                                                         attacker.teamkill_soundsource = targ;
 767                                                 }
 768                                 }
 769                         }
 770                 }
 771         }
 772
 773         // apply push
 774         if (self.damageforcescale)
 775         if (vlen(force))
 776         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
 777         {
 778                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 779                 if(self.movetype == MOVETYPE_PHYSICS)
 780                 {
 781                         entity farcent;
 782                         farcent = spawn();
 783                         farcent.classname = "farce";
 784                         farcent.enemy = self;
 785                         farcent.movedir = farce * 10;
 786                         if(self.mass)
 787                                 farcent.movedir = farcent.movedir * self.mass;
 788                         farcent.origin = hitloc;
 789                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 790                         farcent.nextthink = time + 0.1;
 791                         farcent.think = SUB_Remove;
 792                 }
 793                 else
 794                         self.velocity = self.velocity + farce;
 795                 self.flags &= ~FL_ONGROUND;
 796                 UpdateCSQCProjectile(self);
 797         }
 798         // apply damage
 799         if (damage != 0 || (self.damageforcescale && vlen(force)))
 800         if (self.event_damage)
 801                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 802         self = oldself;
 803
 804         // apply mirror damage if any
 805         if(mirrordamage > 0 || mirrorforce > 0)
 806         {
 807                 attacker = attacker_save;
 808
 809                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 810                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 811         }
 812 }
 813
 814 float RadiusDamage_running;
 815 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 816         // Returns total damage applies to creatures
 817 {
 818         entity  targ;
 819         vector  blastorigin;
 820         vector  force;
 821         float   total_damage_to_creatures;
 822         entity  next;
 823         float   tfloordmg;
 824         float   tfloorforce;
 825
 826         float stat_damagedone;
 827
 828         if(RadiusDamage_running)
 829         {
 830                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 831                 return 0;
 832         }
 833
 834         RadiusDamage_running = 1;
 835
 836         tfloordmg = autocvar_g_throughfloor_damage;
 837         tfloorforce = autocvar_g_throughfloor_force;
 838
 839         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 840         total_damage_to_creatures = 0;
 841
 842         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 843                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 844                 {
 845                         force = inflictor.velocity;
 846                         if(vlen(force) == 0)
 847                                 force = '0 0 -1';
 848                         else
 849                                 force = normalize(force);
 850                         if(forceintensity >= 0)
 851                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 852                         else
 853                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 854                 }
 855
 856         stat_damagedone = 0;
 857
 858         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 859         while (targ)
 860         {
 861                 next = targ.chain;
 862                 if (targ != inflictor)
 863                         if (ignore != targ) if(targ.takedamage)
 864                         {
 865                                 vector nearest;
 866                                 vector diff;
 867                                 float power;
 868
 869                                 // LordHavoc: measure distance to nearest point on target (not origin)
 870                                 // (this guarentees 100% damage on a touch impact)
 871                                 nearest = targ.WarpZone_findradius_nearest;
 872                                 diff = targ.WarpZone_findradius_dist;
 873                                 // round up a little on the damage to ensure full damage on impacts
 874                                 // and turn the distance into a fraction of the radius
 875                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 876                                 //bprint(" ");
 877                                 //bprint(ftos(power));
 878                                 //if (targ == attacker)
 879                                 //      print(ftos(power), "\n");
 880                                 if (power > 0)
 881                                 {
 882                                         float finaldmg;
 883                                         if (power > 1)
 884                                                 power = 1;
 885                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 886                                         if (finaldmg > 0)
 887                                         {
 888                                                 float a;
 889                                                 float c;
 890                                                 vector hitloc;
 891                                                 vector myblastorigin;
 892                                                 vector center;
 893
 894                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 895
 896                                                 // if it's a player, use the view origin as reference
 897                                                 center = CENTER_OR_VIEWOFS(targ);
 898
 899                                                 force = normalize(center - myblastorigin);
 900                                                 force = force * (finaldmg / coredamage) * forceintensity;
 901                                                 hitloc = nearest;
 902
 903                                                 if(targ != directhitentity)
 904                                                 {
 905                                                         float hits;
 906                                                         float total;
 907                                                         float hitratio;
 908                                                         float mininv_f, mininv_d;
 909
 910                                                         // test line of sight to multiple positions on box,
 911                                                         // and do damage if any of them hit
 912                                                         hits = 0;
 913
 914                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 915                                                         // so for a given max stddev:
 916                                                         // n = (1 / (2 * max stddev of hitratio))^2
 917
 918                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 919                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 920
 921                                                         if(autocvar_g_throughfloor_debug)
 922                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
 923
 924                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
 925
 926                                                         if(autocvar_g_throughfloor_debug)
 927                                                                 print(sprintf(" steps=%f", total));
 928
 929                                                         if (IS_PLAYER(targ))
 930                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
 931                                                         else
 932                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
 933
 934                                                         if(autocvar_g_throughfloor_debug)
 935                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
 936
 937                                                         for(c = 0; c < total; ++c)
 938                                                         {
 939                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 940                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 941                                                                 if (trace_fraction == 1 || trace_ent == targ)
 942                                                                 {
 943                                                                         ++hits;
 944                                                                         if (hits > 1)
 945                                                                                 hitloc = hitloc + nearest;
 946                                                                         else
 947                                                                                 hitloc = nearest;
 948                                                                 }
 949                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 950                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 951                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 952                                                         }
 953
 954                                                         nearest = hitloc * (1 / max(1, hits));
 955                                                         hitratio = (hits / total);
 956                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 957                                                         finaldmg = finaldmg * a;
 958                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 959                                                         force = force * a;
 960
 961                                                         if(autocvar_g_throughfloor_debug)
 962                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
 963                                                 }
 964
 965                                                 // laser force adjustments :P
 966                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
 967                                                 {
 968                                                         if (targ == attacker)
 969                                                         {
 970                                                                 vector vel;
 971
 972                                                                 float force_zscale;
 973                                                                 float force_velocitybiasramp;
 974                                                                 float force_velocitybias;
 975
 976                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
 977                                                                 if(deathtype & HITTYPE_SECONDARY)
 978                                                                 {
 979                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
 980                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
 981                                                                 }
 982                                                                 else
 983                                                                 {
 984                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
 985                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
 986                                                                 }
 987
 988                                                                 vel = targ.velocity;
 989                                                                 vel_z = 0;
 990                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
 991                                                                 force =
 992                                                                         vlen(force)
 993                                                                         *
 994                                                                         normalize(normalize(force) + vel);
 995
 996                                                                 force_z *= force_zscale;
 997                                                         }
 998                                                         else
 999                                                         {
1000                                                                 if(deathtype & HITTYPE_SECONDARY)
1001                                                                 {
1002                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1003                                                                 }
1004                                                                 else
1005                                                                 {
1006                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1007                                                                 }
1008                                                         }
1009                                                 }
1010
1011                                                 //if (targ == attacker)
1012                                                 //{
1013                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1014                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1015                                                 //      print(" (", ftos(a), ")\n");
1016                                                 //}
1017                                                 if(finaldmg || vlen(force))
1018                                                 {
1019                                                         if(targ.iscreature)
1020                                                         {
1021                                                                 total_damage_to_creatures += finaldmg;
1022
1023                                                                 if(accuracy_isgooddamage(attacker, targ))
1024                                                                         stat_damagedone += finaldmg;
1025                                                         }
1026
1027                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1028                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1029                                                         else
1030                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1031                                                 }
1032                                         }
1033                                 }
1034                         }
1035                 targ = next;
1036         }
1037
1038         RadiusDamage_running = 0;
1039
1040         if(!DEATH_ISSPECIAL(deathtype))
1041                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1042
1043         return total_damage_to_creatures;
1044 }
1045
1046 .float fire_damagepersec;
1047 .float fire_endtime;
1048 .float fire_deathtype;
1049 .entity fire_owner;
1050 .float fire_hitsound;
1051 .entity fire_burner;
1052
1053 void fireburner_think();
1054
1055 float Fire_IsBurning(entity e)
1056 {
1057         return (time < e.fire_endtime);
1058 }
1059
1060 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1061 {
1062         float dps;
1063         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1064
1065         if(IS_PLAYER(e))
1066         {
1067                 if(e.deadflag)
1068                         return -1;
1069         }
1070         else
1071         {
1072                 if(!e.fire_burner)
1073                 {
1074                         // print("adding a fire burner to ", e.classname, "\n");
1075                         e.fire_burner = spawn();
1076                         e.fire_burner.classname = "fireburner";
1077                         e.fire_burner.think = fireburner_think;
1078                         e.fire_burner.nextthink = time;
1079                         e.fire_burner.owner = e;
1080                 }
1081         }
1082
1083         t = max(t, 0.1);
1084         dps = d / t;
1085         if(Fire_IsBurning(e))
1086         {
1087                 mintime = e.fire_endtime - time;
1088                 maxtime = max(mintime, t);
1089
1090                 mindps = e.fire_damagepersec;
1091                 maxdps = max(mindps, dps);
1092
1093                 if(maxtime > mintime || maxdps > mindps)
1094                 {
1095                         // Constraints:
1096
1097                         // damage we have right now
1098                         mindamage = mindps * mintime;
1099
1100                         // damage we want to get
1101                         maxdamage = mindamage + d;
1102
1103                         // but we can't exceed maxtime * maxdps!
1104                         totaldamage = min(maxdamage, maxtime * maxdps);
1105
1106                         // LEMMA:
1107                         // Look at:
1108                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1109                         // We see:
1110                         // totaldamage <= maxtime * maxdps
1111                         // ==> totaldamage / maxdps <= maxtime.
1112                         // We also see:
1113                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1114                         //                     >= min(mintime, maxtime)
1115                         // ==> totaldamage / maxdps >= mintime.
1116
1117                         /*
1118                         // how long do we damage then?
1119                         // at least as long as before
1120                         // but, never exceed maxdps
1121                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1122                         */
1123
1124                         // alternate:
1125                         // at most as long as maximum allowed
1126                         // but, never below mindps
1127                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1128
1129                         // assuming t > mintime, dps > mindps:
1130                         // we get d = t * dps = maxtime * maxdps
1131                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1132                         // totaldamage / maxdps = maxtime
1133                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1134                         // FROM THIS:
1135                         // a) totaltime = max(mintime, maxtime) = maxtime
1136                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1137
1138                         // assuming t <= mintime:
1139                         // we get maxtime = mintime
1140                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1141                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1142
1143                         // assuming dps <= mindps:
1144                         // we get mindps = maxdps.
1145                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1146                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1147                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1148
1149                         e.fire_damagepersec = totaldamage / totaltime;
1150                         e.fire_endtime = time + totaltime;
1151                         if(totaldamage > 1.2 * mindamage)
1152                         {
1153                                 e.fire_deathtype = dt;
1154                                 if(e.fire_owner != o)
1155                                 {
1156                                         e.fire_owner = o;
1157                                         e.fire_hitsound = FALSE;
1158                                 }
1159                         }
1160                         if(accuracy_isgooddamage(o, e))
1161                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1162                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1163                 }
1164                 else
1165                         return 0;
1166         }
1167         else
1168         {
1169                 e.fire_damagepersec = dps;
1170                 e.fire_endtime = time + t;
1171                 e.fire_deathtype = dt;
1172                 e.fire_owner = o;
1173                 e.fire_hitsound = FALSE;
1174                 if(accuracy_isgooddamage(o, e))
1175                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1176                 return d;
1177         }
1178 }
1179
1180 void Fire_ApplyDamage(entity e)
1181 {
1182         float t, d, hi, ty;
1183         entity o;
1184
1185         if not(Fire_IsBurning(e))
1186                 return;
1187
1188         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1189         if(IS_NOT_A_CLIENT(o))
1190                 o = e.fire_owner;
1191
1192         // water and slime stop fire
1193         if(e.waterlevel)
1194         if(e.watertype != CONTENT_LAVA)
1195                 e.fire_endtime = 0;
1196
1197         // ice stops fire
1198         if(e.freezetag_frozen)
1199                 e.fire_endtime = 0;
1200
1201         t = min(frametime, e.fire_endtime - time);
1202         d = e.fire_damagepersec * t;
1203
1204         hi = e.fire_owner.hitsound;
1205         ty = e.fire_owner.typehitsound;
1206         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1207         if(e.fire_hitsound && e.fire_owner)
1208         {
1209                 e.fire_owner.hitsound = hi;
1210                 e.fire_owner.typehitsound = ty;
1211         }
1212         e.fire_hitsound = TRUE;
1213
1214         if not(IS_INDEPENDENT_PLAYER(e))
1215         FOR_EACH_PLAYER(other) if(e != other)
1216         {
1217                 if(IS_PLAYER(other))
1218                 if(other.deadflag == DEAD_NO)
1219                 if not(IS_INDEPENDENT_PLAYER(other))
1220                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1221                 {
1222                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1223                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1224                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1225                 }
1226         }
1227 }
1228
1229 void Fire_ApplyEffect(entity e)
1230 {
1231         if(Fire_IsBurning(e))
1232                 e.effects |= EF_FLAME;
1233         else
1234                 e.effects &= ~EF_FLAME;
1235 }
1236
1237 void fireburner_think()
1238 {
1239         // for players, this is done in the regular loop
1240         if(wasfreed(self.owner))
1241         {
1242                 remove(self);
1243                 return;
1244         }
1245         Fire_ApplyEffect(self.owner);
1246         if(!Fire_IsBurning(self.owner))
1247         {
1248                 self.owner.fire_burner = world;
1249                 remove(self);
1250                 return;
1251         }
1252         Fire_ApplyDamage(self.owner);
1253         self.nextthink = time;
1254 }