qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/weapons/accuracy.qh>
  27 #include <server/world.qh>
  28
  29 // =============================================
  30 //  Server side voting code, reworked by Samual
  31 //  Last updated: December 27th, 2011
  32 // =============================================
  33
  34 //  Nagger for players to know status of voting
  35 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  36 {
  37         int nags, i, f, b;
  38         entity e;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         nags = 0;
  52         if (readycount)
  53         {
  54                 nags |= BIT(0);
  55                 if (to.ready == 0) nags |= BIT(1);
  56         }
  57         if (vote_called)
  58         {
  59                 nags |= BIT(2);
  60                 if (to.vote_selection == 0) nags |= BIT(3);
  61         }
  62         if (warmup_stage) nags |= BIT(4);
  63
  64         if (sendflags & BIT(6)) nags |= BIT(6);
  65
  66         if (sendflags & BIT(7)) nags |= BIT(7);
  67
  68         if (!(nags & 4))  // no vote called? send no string
  69                 nags &= ~(BIT(6) | BIT(7));
  70
  71         WriteByte(MSG_ENTITY, nags);
  72
  73         if (nags & BIT(6))
  74         {
  75                 WriteByte(MSG_ENTITY, vote_accept_count);
  76                 WriteByte(MSG_ENTITY, vote_reject_count);
  77                 WriteByte(MSG_ENTITY, vote_needed_overall);
  78                 WriteChar(MSG_ENTITY, to.vote_selection);
  79         }
  80
  81         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  82
  83         if (nags & 1)
  84         {
  85                 for (i = 1; i <= maxclients; i += 8)
  86                 {
  87                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  88                                 if (!IS_REAL_CLIENT(e) || e.ready)
  89                                         f |= b;
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteReset()
 129 {
 130         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 131
 132         if (vote_called)
 133         {
 134                 strfree(vote_called_command);
 135                 strfree(vote_called_display);
 136                 strfree(vote_caller_name);
 137         }
 138
 139         vote_called = VOTE_NULL;
 140         vote_caller = NULL;
 141         vote_endtime = 0;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 206
 207 void VoteCount(float first_count)
 208 {
 209         // declarations
 210         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 211
 212         float vote_player_count = 0, notvoters = 0;
 213         float vote_real_player_count = 0, vote_real_accept_count = 0;
 214         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 215         float vote_needed_of_voted, final_needed_votes;
 216         float vote_factor_overall, vote_factor_of_voted;
 217
 218         Nagger_VoteCountChanged();
 219
 220         // add up all the votes from each connected client
 221         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 222                 ++vote_player_count;
 223                 if (IS_PLAYER(it))   ++vote_real_player_count;
 224                 switch (it.vote_selection)
 225                 {
 226                         case VOTE_SELECT_REJECT:
 227                         { ++vote_reject_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 229                         }
 230                         case VOTE_SELECT_ACCEPT:
 231                         { ++vote_accept_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 233                         }
 234                         case VOTE_SELECT_ABSTAIN:
 235                         { ++vote_abstain_count;
 236                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 237                         }
 238                         default: break;
 239                 }
 240         });
 241
 242         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 243         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 244         {
 245                 if (vote_caller)   vote_caller.vote_waittime = 0;
 246                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 247                 VoteReset();
 248                 return;
 249         }
 250
 251         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 252         if (!spectators_allowed && (vote_real_player_count > 0))
 253         {
 254                 vote_accept_count = vote_real_accept_count;
 255                 vote_reject_count = vote_real_reject_count;
 256                 vote_abstain_count = vote_real_abstain_count;
 257                 vote_player_count = vote_real_player_count;
 258         }
 259
 260         // people who have no opinion in any way :D
 261         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 262
 263         // determine the goal for the vote to be passed or rejected normally
 264         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 265         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 266
 267         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 268         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 269         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 270
 271         // are there any players at all on the server? it could be an admin vote
 272         if (vote_player_count == 0 && first_count)
 273         {
 274                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 275                 VoteAccept();
 276                 return;
 277         }
 278
 279         // since there ARE players, finally calculate the result of the vote
 280         if (vote_accept_count >= vote_needed_overall)
 281         {
 282                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 288         {
 289                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 290                 VoteReject();
 291                 return;
 292         }
 293
 294         // there is not enough votes in either direction, now lets just calculate what the voters have said
 295         if (time > vote_endtime)
 296         {
 297                 final_needed_votes = vote_needed_overall;
 298
 299                 if (autocvar_sv_vote_majority_factor_of_voted)
 300                 {
 301                         if (vote_accept_count >= vote_needed_of_voted)
 302                         {
 303                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 304                                 VoteAccept();
 305                                 return;
 306                         }
 307
 308                         if (vote_accept_count + vote_reject_count > 0)
 309                         {
 310                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 311                                 VoteReject();
 312                                 return;
 313                         }
 314
 315                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 316                 }
 317
 318                 // it didn't pass or fail, so not enough votes to even make a decision.
 319                 VoteSpam(notvoters, final_needed_votes, "timeout");
 320                 VoteTimeout();
 321         }
 322 }
 323
 324 void VoteThink()
 325 {
 326         if (vote_endtime > 0)        // a vote was called
 327         {
 328                 if (time > vote_endtime) // time is up
 329                         VoteCount(false);
 330         }
 331 }
 332
 333
 334 // =======================
 335 //  Game logic for warmup
 336 // =======================
 337
 338 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 339 void reset_map(bool dorespawn, bool is_fake_round_start)
 340 {
 341         if (time <= game_starttime)
 342         {
 343                 if (game_stopped)
 344                         return;
 345
 346                 if (!is_fake_round_start)
 347                         PlayerStats_GameReport_Reset_All();
 348                 if (round_handler_IsActive())
 349                         round_handler_Reset(game_starttime);
 350         }
 351
 352         if (shuffleteams_on_reset_map)
 353         {
 354                 shuffleteams();
 355                 shuffleteams_on_reset_map = false;
 356         }
 357
 358         FOREACH_CLIENT(true, {
 359                 if (time <= game_starttime)
 360                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 361                 if (!IS_PLAYER(it))
 362                         continue;
 363                 if (STAT(FROZEN, it))
 364                         Unfreeze(it, false);
 365                 player_powerups_remove_all(it);
 366                 entity store = PS(it);
 367                 if (store)
 368                 {
 369                         Inventory_clear(store.inventory);
 370                         Inventory_update(store);
 371                 }
 372         });
 373
 374         MUTATOR_CALLHOOK(reset_map_global);
 375
 376         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 377         {
 378                 if(IS_CLIENT(it))
 379                         continue;
 380                 if (it.reset)
 381                 {
 382                         it.reset(it);
 383                         continue;
 384                 }
 385                 if (it.team_saved) it.team = it.team_saved;
 386                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 387         });
 388
 389         // Waypoints and assault start come LAST
 390         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 391                 if (it.reset2) it.reset2(it);
 392         });
 393
 394         // Moving the player reset code here since the player-reset depends
 395         // on spawnpoint entities which have to be reset first --blub
 396         if (dorespawn)
 397         {
 398                 if (!MUTATOR_CALLHOOK(reset_map_players))
 399                 {
 400                         FOREACH_CLIENT(IS_PLAYER(it),
 401                         {
 402                                 // PlayerScore_Clear(it);
 403                                 CS(it).killcount = 0;
 404                                 // stop the player from moving so that he stands still once he gets respawned
 405                                 it.velocity = '0 0 0';
 406                                 it.avelocity = '0 0 0';
 407                                 CS(it).movement = '0 0 0';
 408                                 PutClientInServer(it);
 409                         });
 410                 }
 411         }
 412 }
 413
 414 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 415 void ReadyRestart_think(entity this)
 416 {
 417         reset_map(true, false);
 418         Score_ClearAll();
 419         delete(this);
 420 }
 421
 422 // Forces a restart of the game without actually reloading the map // this is a mess...
 423 void ReadyRestart_force(bool is_fake_round_start)
 424 {
 425         if (time <= game_starttime && game_stopped)
 426                 return;
 427         if (!is_fake_round_start)
 428                 bprint("^1Match is restarting...\n");
 429
 430         VoteReset();
 431
 432         // clear overtime, we have to decrease timelimit to its original value again.
 433         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 434                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 435         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 436
 437         if(warmup_stage)
 438                 game_starttime = time; // Warmup: No countdown in warmup
 439         else
 440                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 441
 442         // clear player attributes
 443         FOREACH_CLIENT(IS_PLAYER(it), {
 444                 it.alivetime = 0;
 445                 CS(it).killcount = 0;
 446         });
 447
 448         // if we're ending the warmup stage call the corresponding hook
 449         if(!is_fake_round_start && !warmup_stage)
 450                 localcmd("\nsv_hook_warmupend\n");
 451
 452         // reset the .ready status of all players (also spectators)
 453         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 454         readycount = 0;
 455         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 456
 457         // lock teams with lockonrestart
 458         if (autocvar_teamplay_lockonrestart && teamplay)
 459                 lockteams = !warmup_stage;
 460
 461         // initiate the restart-countdown-announcer entity
 462         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 463         {
 464                 entity restart_timer = new_pure(restart_timer);
 465                 setthink(restart_timer, ReadyRestart_think);
 466                 restart_timer.nextthink = game_starttime;
 467         }
 468
 469         // after a restart every players number of allowed timeouts gets reset, too
 470         if (autocvar_sv_timeout)
 471         {
 472                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 473         }
 474
 475         if (!sv_ready_restart_after_countdown || warmup_stage) reset_map(true, is_fake_round_start);
 476         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 477 }
 478
 479 void ReadyRestart(bool forceWarmupEnd)
 480 {
 481         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 482         else localcmd("\nsv_hook_readyrestart\n");
 483
 484         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 485         // Otherwise scores could be manipulated during the countdown.
 486         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 487
 488         if(forceWarmupEnd)
 489                 warmup_stage = 0; // forcefully end warmup and go to match stage
 490         else
 491                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 492
 493         ReadyRestart_force(false);
 494 }
 495
 496 // Count the players who are ready and determine whether or not to restart the match
 497 void ReadyCount()
 498 {
 499         float ready_needed_factor, ready_needed_count;
 500         float t_ready = 0, t_players = 0;
 501
 502         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME_JOINED(it)), {
 503                 ++t_players;
 504                 if (it.ready) ++t_ready;
 505         });
 506
 507         readycount = t_ready;
 508
 509         Nagger_ReadyCounted();
 510
 511         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 512         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 513
 514         if (readycount >= ready_needed_count) ReadyRestart(true);
 515 }
 516
 517
 518 // ======================================
 519 //  Supporting functions for VoteCommand
 520 // ======================================
 521
 522 float Votecommand_check_assignment(entity caller, float assignment)
 523 {
 524         float from_server = (!caller);
 525
 526         if ((assignment == VC_ASGNMNT_BOTH)
 527             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 528             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 529
 530         return false;
 531 }
 532
 533 string VoteCommand_extractcommand(string input, float startpos, int argc)
 534 {
 535         string output;
 536
 537         if ((argc - 1) < startpos) output = "";
 538         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 539
 540         return output;
 541 }
 542
 543 float VoteCommand_checknasty(string vote_command)
 544 {
 545         if ((strstrofs(vote_command, ";", 0) >= 0)
 546             || (strstrofs(vote_command, "\n", 0) >= 0)
 547             || (strstrofs(vote_command, "\r", 0) >= 0)
 548             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 549
 550         return true;
 551 }
 552
 553 // NOTE: requires input to be surrounded by spaces
 554 string VoteCommand_checkreplacements(string input)
 555 {
 556         string output = input;
 557         // allow gotomap replacements
 558         output = strreplace(" map ", " gotomap ", output);
 559         output = strreplace(" chmap ", " gotomap ", output);
 560         return output;
 561 }
 562
 563 float VoteCommand_checkinlist(string vote_command, string list)
 564 {
 565         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 566
 567         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 568
 569         return false;
 570 }
 571
 572 string ValidateMap(string validated_map, entity caller)
 573 {
 574         validated_map = MapInfo_FixName(validated_map);
 575
 576         if (!validated_map)
 577         {
 578                 print_to(caller, "This map is not available on this server.");
 579                 return string_null;
 580         }
 581
 582         if (!autocvar_sv_vote_override_mostrecent && caller)
 583         {
 584                 if (Map_IsRecent(validated_map))
 585                 {
 586                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 587                         return string_null;
 588                 }
 589         }
 590
 591         if (!MapInfo_CheckMap(validated_map))
 592         {
 593                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 594                 return string_null;
 595         }
 596
 597         return validated_map;
 598 }
 599
 600 float VoteCommand_checkargs(float startpos, int argc)
 601 {
 602         float p, q, check, minargs;
 603         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 604         string cmdrestriction = "";  // No we don't.
 605         string charlist, arg;
 606         float checkmate;
 607
 608         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 609                 cmdrestriction = cvar_string(cvarname);
 610         else
 611                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 612
 613         if (cmdrestriction == "") return true;
 614
 615         ++startpos;  // skip command name
 616
 617         // check minimum arg count
 618
 619         // 0 args: argc == startpos
 620         // 1 args: argc == startpos + 1
 621         // ...
 622
 623         minargs = stof(cmdrestriction);
 624         if (argc - startpos < minargs) return false;
 625
 626         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 627
 628         for ( ; ; )
 629         {
 630                 // we know that at any time, startpos <= argc - minargs
 631                 // so this means: argc-minargs >= startpos >= argc, thus
 632                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 633                 // have been seen already
 634
 635                 if (startpos >= argc) // all args checked? GOOD
 636                         break;
 637
 638                 if (p < 0)            // no more args? FAIL
 639                 {
 640                         // exception: exactly minargs left, this one included
 641                         if (argc - startpos == minargs) break;
 642
 643                         // otherwise fail
 644                         return false;
 645                 }
 646
 647                 // cut to next semicolon
 648                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 649                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 650                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 651
 652                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 653                 // charlist = strreplace("^^", ";", charlist);
 654
 655                 if (charlist != "")
 656                 {
 657                         // verify the arg only contains allowed chars
 658                         arg = argv(startpos);
 659                         checkmate = strlen(arg);
 660                         for (check = 0; check < checkmate; ++check)
 661                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 662                         // not allowed character
 663                         // all characters are allowed. FINE.
 664                 }
 665
 666                 ++startpos;
 667                 --minargs;
 668                 p = q;
 669         }
 670
 671         return true;
 672 }
 673
 674 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 675 {
 676         string first_command = argv(startpos);
 677         int missing_chars = argv_start_index(startpos);
 678
 679         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 680                 return 0;
 681
 682         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 683
 684         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 685
 686         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 687         {
 688                 case MUT_VOTEPARSE_CONTINUE: { break; }
 689                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 690                 case MUT_VOTEPARSE_INVALID: { return -1; }
 691                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 692         }
 693
 694         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 695         {
 696                 case "kick":
 697                 case "kickban":    // catch all kick/kickban commands
 698                 {
 699                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 700                         float accepted = VerifyClientEntity(victim, true, false);
 701
 702                         if (accepted > 0)
 703                         {
 704                                 string reason = "No reason provided";
 705                                 if(argc > next_token)
 706                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 707
 708                                 string command_arguments = reason;
 709                                 if (first_command == "kickban")
 710                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 711
 712                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 713                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 714                         }
 715                         else
 716                         {
 717                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 718                                 return 0;
 719                         }
 720
 721                         break;
 722                 }
 723
 724                 case "map":
 725                 case "chmap":
 726                 case "gotomap":  // re-direct all map selection commands to gotomap
 727                 {
 728                         vote_command = ValidateMap(argv(startpos + 1), caller);
 729                         if (!vote_command)  return -1;
 730                         vote_parsed_command = strcat("gotomap ", vote_command);
 731                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 732
 733                         break;
 734                 }
 735
 736                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 737                 // maybe fallback instead of aborting if map name is invalid?
 738                 case "nextmap":
 739                 {
 740                         vote_command = ValidateMap(argv(startpos + 1), caller);
 741                         if (!vote_command)  return -1;
 742                         vote_parsed_command = strcat("nextmap ", vote_command);
 743                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 744
 745                         break;
 746                 }
 747
 748                 case "timelimit": // include restrictions on the maximum votable time limit
 749                 {
 750                         float timelimit_vote = stof(argv(startpos + 1));
 751                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 752                         {
 753                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 754                                 return -1;
 755                         }
 756                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 757                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 758                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 759
 760                         break;
 761                 }
 762
 763                 case "restart": // re-direct all match restarting to resetmatch
 764                         vote_command = "resetmatch"; // fall-through
 765                 case "resetmatch":
 766                 {
 767                         vote_parsed_command = vote_command;
 768                         vote_parsed_display = strzone(strcat("^1", vote_command));
 769
 770                         break;
 771                 }
 772
 773                 case "allready":
 774                 {
 775                         if(!warmup_stage) {
 776                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 777                                 return -1;
 778                         }
 779
 780                         vote_parsed_command = vote_command;
 781                         vote_parsed_display = strzone(strcat("^1", vote_command));
 782                         break;
 783                 }
 784
 785                 default:
 786                 {
 787                         vote_parsed_command = vote_command;
 788                         vote_parsed_display = strzone(strcat("^1", vote_command));
 789
 790                         break;
 791                 }
 792         }
 793
 794         return 1;
 795 }
 796
 797
 798 // =======================
 799 //  Command Sub-Functions
 800 // =======================
 801
 802 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 803 {
 804         switch (request)
 805         {
 806                 case CMD_REQUEST_COMMAND:
 807                 {
 808                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 809                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 810                         {
 811                                 print_to(caller, "^1You have already voted.");
 812                         }
 813
 814                         else  // everything went okay, continue changing vote
 815                         {
 816                                 print_to(caller, "^1You abstained from your vote.");
 817                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 818                                 msg_entity = caller;
 819                                 if (!autocvar_sv_vote_singlecount)
 820                                         VoteCount(false);
 821                         }
 822
 823                         return;
 824                 }
 825
 826                 default:
 827                 case CMD_REQUEST_USAGE:
 828                 {
 829                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 830                         print_to(caller, "  No arguments required.");
 831                         return;
 832                 }
 833         }
 834 }
 835
 836 void print_available_commands_to(entity caller)
 837 {
 838         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 839 }
 840
 841 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 842 {
 843         switch (request)
 844         {
 845                 case CMD_REQUEST_COMMAND:
 846                 {
 847                         float tmp_playercount = 0;
 848                         int parse_error;
 849
 850                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 851
 852                         if (!autocvar_sv_vote_call && caller)
 853                         {
 854                                 print_to(caller, "^1Vote calling is not allowed.");
 855                         }
 856                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 857                         {
 858                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 859                         }
 860                         else if (vote_called)
 861                         {
 862                                 print_to(caller, "^1There is already a vote called.");
 863                         }
 864                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 865                         {
 866                                 print_to(caller, "^1Only players can call a vote.");
 867                         }
 868                         else if (caller && !IS_CLIENT(caller))
 869                         {
 870                                 print_to(caller, "^1Only connected clients can vote.");
 871                         }
 872                         else if (timeout_status && vote_command != "timein")
 873                         {
 874                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 875                         }
 876                         else if (caller && (time < caller.vote_waittime))
 877                         {
 878                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 879                         }
 880                         else if (!VoteCommand_checknasty(vote_command))
 881                         {
 882                                 print_to(caller, "^1Syntax error in command.");
 883                         }
 884                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 885                         {
 886                                 if(parse_error == 0)
 887                                 {
 888                                         if (vote_called_command == "")
 889                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 890                                         else
 891                                                 print_to(caller, "^1This command is not acceptable or not available.");
 892                                 }
 893                         }
 894                         else  // everything went okay, continue with calling the vote
 895                         {
 896                                 vote_caller = caller;  // remember who called the vote
 897                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 898                                 vote_called = VOTE_NORMAL;
 899                                 vote_called_command = strzone(vote_parsed_command);
 900                                 vote_called_display = strzone(vote_parsed_display);
 901                                 vote_endtime = time + autocvar_sv_vote_timeout;
 902
 903                                 if (caller)
 904                                 {
 905                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 906                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 907                                         msg_entity = caller;
 908                                 }
 909
 910                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 911
 912                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 913                                 if (autocvar_sv_eventlog)
 914                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 915                                 Nagger_VoteChanged();
 916                                 VoteCount(true);  // needed if you are the only one
 917
 918                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 919                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 920                         }
 921
 922                         return;
 923                 }
 924
 925                 default:
 926                 case CMD_REQUEST_USAGE:
 927                 {
 928                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 929                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 930                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 931                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 932                         print_available_commands_to(caller);
 933                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 934                         return;
 935                 }
 936         }
 937 }
 938
 939 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 940 {
 941         switch (request)
 942         {
 943                 case CMD_REQUEST_COMMAND:
 944                 {
 945                         if (autocvar_sv_vote_master)
 946                         {
 947                                 switch (strtolower(argv(2)))
 948                                 {
 949                                         case "do":
 950                                         {
 951                                                 int parse_error;
 952                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 953
 954                                                 if (!caller.vote_master)
 955                                                         print_to(caller, "^1You do not have vote master privileges.");
 956                                                 else if (!VoteCommand_checknasty(vote_command))
 957                                                 {
 958                                                         print_to(caller, "^1Syntax error in command.");
 959                                                 }
 960                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 961                                                 {
 962                                                         if(parse_error == 0)
 963                                                         {
 964                                                                 if (vote_called_command == "")
 965                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 966                                                                 else
 967                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 968                                                         }
 969                                                 }
 970                                                 else  // everything went okay, proceed with command
 971                                                 {
 972                                                         localcmd(strcat(vote_parsed_command, "\n"));
 973                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 974                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 975                                                         if (autocvar_sv_eventlog)
 976                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 977                                                 }
 978
 979                                                 return;
 980                                         }
 981
 982                                         case "login":
 983                                         {
 984                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 985                                                 else if (caller.vote_master)
 986                                                 {
 987                                                         print_to(caller, "^1You are already logged in as vote master.");
 988                                                 }
 989                                                 else if (autocvar_sv_vote_master_password != argv(3))
 990                                                 {
 991                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 992                                                 }
 993                                                 else  // everything went okay, proceed with giving this player master privilages
 994                                                 {
 995                                                         caller.vote_master = true;
 996                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 997                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 998                                                         if (autocvar_sv_eventlog)
 999                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1000                                                 }
1001
1002                                                 return;
1003                                         }
1004
1005                                         default:  // calling a vote for master
1006                                         {
1007                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1008                                                 else if (vote_called)
1009                                                 {
1010                                                         print_to(caller, "^1There is already a vote called.");
1011                                                 }
1012                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1013                                                 {
1014                                                         print_to(caller, "^1Only players can call a vote.");
1015                                                 }
1016                                                 else if (timeout_status)
1017                                                 {
1018                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1019                                                 }
1020                                                 else  // everything went okay, continue with creating vote
1021                                                 {
1022                                                         vote_caller = caller;
1023                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1024                                                         vote_called = VOTE_MASTER;
1025                                                         vote_called_command = strzone("XXX");
1026                                                         vote_called_display = strzone("^3master");
1027                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1028
1029                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1030                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1031
1032                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1033                                                         if (autocvar_sv_eventlog)
1034                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1035                                                         Nagger_VoteChanged();
1036                                                         VoteCount(true);  // needed if you are the only one
1037                                                 }
1038
1039                                                 return;
1040                                         }
1041                                 }
1042                         }
1043                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1044
1045                         return;
1046                 }
1047
1048                 default:
1049                 case CMD_REQUEST_USAGE:
1050                 {
1051                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1052                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1053                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1054                         return;
1055                 }
1056         }
1057 }
1058
1059 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1060 {
1061         switch (request)
1062         {
1063                 case CMD_REQUEST_COMMAND:
1064                 {
1065                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1066                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1067                         {
1068                                 print_to(caller, "^1You have already voted.");
1069                         }
1070                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1071                         {
1072                                 VoteStop(caller);
1073                         }
1074
1075                         else  // everything went okay, continue changing vote
1076                         {
1077                                 print_to(caller, "^1You rejected the vote.");
1078                                 caller.vote_selection = VOTE_SELECT_REJECT;
1079                                 msg_entity = caller;
1080                                 if (!autocvar_sv_vote_singlecount)
1081                                         VoteCount(false);
1082                         }
1083
1084                         return;
1085                 }
1086
1087                 default:
1088                 case CMD_REQUEST_USAGE:
1089                 {
1090                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1091                         print_to(caller, "  No arguments required.");
1092                         return;
1093                 }
1094         }
1095 }
1096
1097 void VoteCommand_status(int request, entity caller)  // BOTH
1098 {
1099         switch (request)
1100         {
1101                 case CMD_REQUEST_COMMAND:
1102                 {
1103                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1104                         else print_to(caller, "^1No vote called.");
1105
1106                         return;
1107                 }
1108
1109                 default:
1110                 case CMD_REQUEST_USAGE:
1111                 {
1112                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1113                         print_to(caller, "  No arguments required.");
1114                         return;
1115                 }
1116         }
1117 }
1118
1119 void VoteCommand_stop(int request, entity caller)  // BOTH
1120 {
1121         switch (request)
1122         {
1123                 case CMD_REQUEST_COMMAND:
1124                 {
1125                         if (!vote_called)   print_to(caller, "^1No vote called.");
1126                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1127                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1128                         return;
1129                 }
1130
1131                 default:
1132                 case CMD_REQUEST_USAGE:
1133                 {
1134                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1135                         print_to(caller, "  No arguments required.");
1136                         return;
1137                 }
1138         }
1139 }
1140
1141 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1142 {
1143         switch (request)
1144         {
1145                 case CMD_REQUEST_COMMAND:
1146                 {
1147                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1148                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1149                         {
1150                                 print_to(caller, "^1You have already voted.");
1151                         }
1152                         else  // everything went okay, continue changing vote
1153                         {
1154                                 print_to(caller, "^1You accepted the vote.");
1155                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1156                                 msg_entity = caller;
1157                                 if (!autocvar_sv_vote_singlecount)
1158                                         VoteCount(false);
1159                         }
1160
1161                         return;
1162                 }
1163
1164                 default:
1165                 case CMD_REQUEST_USAGE:
1166                 {
1167                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1168                         print_to(caller, "  No arguments required.");
1169                         return;
1170                 }
1171         }
1172 }
1173
1174 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1175 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1176 void VoteCommand_(int request)
1177 {
1178     switch(request)
1179     {
1180         case CMD_REQUEST_COMMAND:
1181         {
1182
1183             return;
1184         }
1185
1186         default:
1187         case CMD_REQUEST_USAGE:
1188         {
1189             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1190             print_to(caller, "  No arguments required.");
1191             return;
1192         }
1193     }
1194 }
1195 */
1196
1197
1198 // ================================
1199 //  Macro system for vote commands
1200 // ================================
1201
1202 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1203 #define VOTE_COMMANDS(request, caller, arguments, command) \
1204         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1205         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1206         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1207         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1208         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1209         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1210         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1211         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1212         /* nothing */
1213
1214 void VoteCommand_macro_help(entity caller, int argc)
1215 {
1216         string command_origin = GetCommandPrefix(caller);
1217
1218         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1219         {
1220                 print_to(caller, "\nVoting commands:\n");
1221                 #define VOTE_COMMAND(name, function, description, assignment) \
1222                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1223
1224                 VOTE_COMMANDS(0, caller, 0, "");
1225                 #undef VOTE_COMMAND
1226
1227                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1228                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1229                 print_available_commands_to(caller);
1230         }
1231         else  // usage for individual command
1232         {
1233                 #define VOTE_COMMAND(name, function, description, assignment) \
1234                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1235
1236                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1237                 #undef VOTE_COMMAND
1238
1239                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1240                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1241                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1242                 else if (argv(2) != "")
1243                         print_to(caller, "No documentation exists for this vote");
1244         }
1245 }
1246
1247 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1248 {
1249         #define VOTE_COMMAND(name, function, description, assignment) \
1250                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1251
1252         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1253         #undef VOTE_COMMAND
1254
1255         return false;
1256 }
1257
1258
1259 // ======================================
1260 //  Main function handling vote commands
1261 // ======================================
1262
1263 void VoteCommand(int request, entity caller, int argc, string vote_command)
1264 {
1265         // Guide for working with argc arguments by example:
1266         // argc:   1    - 2      - 3     - 4
1267         // argv:   0    - 1      - 2     - 3
1268         // cmd     vote - master - login - password
1269
1270         switch (request)
1271         {
1272                 case CMD_REQUEST_COMMAND:
1273                 {
1274                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1275                 }
1276
1277                 default:
1278                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1279                 case CMD_REQUEST_USAGE:
1280                 {
1281                         VoteCommand_macro_help(caller, argc);
1282                         return;
1283                 }
1284         }
1285 }