qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/world.qh>
  27
  28 // =============================================
  29 //  Server side voting code, reworked by Samual
  30 //  Last updated: December 27th, 2011
  31 // =============================================
  32
  33 //  Nagger for players to know status of voting
  34 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  35 {
  36         int nags, i, f, b;
  37         entity e;
  38         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  39
  40         // bits:
  41         //   1 = ready
  42         //   2 = player needs to ready up
  43         //   4 = vote
  44         //   8 = player needs to vote
  45         //  16 = warmup
  46         // sendflags:
  47         //  64 = vote counts
  48         // 128 = vote string
  49
  50         nags = 0;
  51         if (readycount)
  52         {
  53                 nags |= BIT(0);
  54                 if (to.ready == 0) nags |= BIT(1);
  55         }
  56         if (vote_called)
  57         {
  58                 nags |= BIT(2);
  59                 if (to.vote_selection == 0) nags |= BIT(3);
  60         }
  61         if (warmup_stage) nags |= BIT(4);
  62
  63         if (sendflags & BIT(6)) nags |= BIT(6);
  64
  65         if (sendflags & BIT(7)) nags |= BIT(7);
  66
  67         if (!(nags & 4))  // no vote called? send no string
  68                 nags &= ~(BIT(6) | BIT(7));
  69
  70         WriteByte(MSG_ENTITY, nags);
  71
  72         if (nags & BIT(6))
  73         {
  74                 WriteByte(MSG_ENTITY, vote_accept_count);
  75                 WriteByte(MSG_ENTITY, vote_reject_count);
  76                 WriteByte(MSG_ENTITY, vote_needed_overall);
  77                 WriteChar(MSG_ENTITY, to.vote_selection);
  78         }
  79
  80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if (nags & 1)
  83         {
  84                 for (i = 1; i <= maxclients; i += 8)
  85                 {
  86                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  87                                 if (!IS_REAL_CLIENT(e) || e.ready)
  88                                         f |= b;
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteReset()
 128 {
 129         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 130
 131         if (vote_called)
 132         {
 133                 strfree(vote_called_command);
 134                 strfree(vote_called_display);
 135                 strfree(vote_caller_name);
 136         }
 137
 138         vote_called = VOTE_NULL;
 139         vote_caller = NULL;
 140         vote_endtime = 0;
 141
 142         vote_parsed_command = string_null;
 143         vote_parsed_display = string_null;
 144
 145         Nagger_VoteChanged();
 146 }
 147
 148 void VoteStop(entity stopper)
 149 {
 150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 154         VoteReset();
 155 }
 156
 157 void VoteAccept()
 158 {
 159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 160
 161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 162         else localcmd(strcat(vote_called_command, "\n"));
 163
 164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 165
 166         VoteReset();
 167         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 168 }
 169
 170 void VoteReject()
 171 {
 172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 173         VoteReset();
 174         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 175 }
 176
 177 void VoteTimeout()
 178 {
 179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 180         VoteReset();
 181         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 182 }
 183
 184 void VoteSpam(float notvoters, float mincount, string result)
 185 {
 186         bprint(strcat(
 187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 188                 strcat("^2:^1", ftos(vote_reject_count)),
 189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 192
 193         if (autocvar_sv_eventlog)
 194         {
 195                 GameLogEcho(strcat(
 196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 197                         strcat(":", ftos(vote_reject_count)),
 198                         strcat(":", ftos(vote_abstain_count)),
 199                         strcat(":", ftos(notvoters)),
 200                         strcat(":", ftos(mincount))));
 201         }
 202 }
 203
 204 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 205
 206 void VoteCount(float first_count)
 207 {
 208         // declarations
 209         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 210
 211         float vote_player_count = 0, notvoters = 0;
 212         float vote_real_player_count = 0, vote_real_accept_count = 0;
 213         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 214         float vote_needed_of_voted, final_needed_votes;
 215         float vote_factor_overall, vote_factor_of_voted;
 216
 217         Nagger_VoteCountChanged();
 218
 219         // add up all the votes from each connected client
 220         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 221                 ++vote_player_count;
 222                 if (IS_PLAYER(it))   ++vote_real_player_count;
 223                 switch (it.vote_selection)
 224                 {
 225                         case VOTE_SELECT_REJECT:
 226                         { ++vote_reject_count;
 227                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 228                         }
 229                         case VOTE_SELECT_ACCEPT:
 230                         { ++vote_accept_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 232                         }
 233                         case VOTE_SELECT_ABSTAIN:
 234                         { ++vote_abstain_count;
 235                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 236                         }
 237                         default: break;
 238                 }
 239         });
 240
 241         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 242         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 243         {
 244                 if (vote_caller)   vote_caller.vote_waittime = 0;
 245                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 246                 VoteReset();
 247                 return;
 248         }
 249
 250         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 251         if (!spectators_allowed && (vote_real_player_count > 0))
 252         {
 253                 vote_accept_count = vote_real_accept_count;
 254                 vote_reject_count = vote_real_reject_count;
 255                 vote_abstain_count = vote_real_abstain_count;
 256                 vote_player_count = vote_real_player_count;
 257         }
 258
 259         // people who have no opinion in any way :D
 260         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 261
 262         // determine the goal for the vote to be passed or rejected normally
 263         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 264         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 265
 266         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 267         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 268         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 269
 270         // are there any players at all on the server? it could be an admin vote
 271         if (vote_player_count == 0 && first_count)
 272         {
 273                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 274                 VoteAccept();
 275                 return;
 276         }
 277
 278         // since there ARE players, finally calculate the result of the vote
 279         if (vote_accept_count >= vote_needed_overall)
 280         {
 281                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 282                 VoteAccept();
 283                 return;
 284         }
 285
 286         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 287         {
 288                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 289                 VoteReject();
 290                 return;
 291         }
 292
 293         // there is not enough votes in either direction, now lets just calculate what the voters have said
 294         if (time > vote_endtime)
 295         {
 296                 final_needed_votes = vote_needed_overall;
 297
 298                 if (autocvar_sv_vote_majority_factor_of_voted)
 299                 {
 300                         if (vote_accept_count >= vote_needed_of_voted)
 301                         {
 302                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 303                                 VoteAccept();
 304                                 return;
 305                         }
 306
 307                         if (vote_accept_count + vote_reject_count > 0)
 308                         {
 309                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 310                                 VoteReject();
 311                                 return;
 312                         }
 313
 314                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 315                 }
 316
 317                 // it didn't pass or fail, so not enough votes to even make a decision.
 318                 VoteSpam(notvoters, final_needed_votes, "timeout");
 319                 VoteTimeout();
 320         }
 321 }
 322
 323 void VoteThink()
 324 {
 325         if (vote_endtime > 0)        // a vote was called
 326         {
 327                 if (time > vote_endtime) // time is up
 328                         VoteCount(false);
 329         }
 330 }
 331
 332
 333 // =======================
 334 //  Game logic for warmup
 335 // =======================
 336
 337 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 338 void reset_map(bool dorespawn)
 339 {
 340         if (time <= game_starttime)
 341         {
 342                 if (game_stopped)
 343                         return;
 344                 if (round_handler_IsActive())
 345                         round_handler_Reset(game_starttime);
 346         }
 347
 348         if (shuffleteams_on_reset_map)
 349         {
 350                 shuffleteams();
 351                 shuffleteams_on_reset_map = false;
 352         }
 353
 354         FOREACH_CLIENT(IS_PLAYER(it),
 355         {
 356                 if (STAT(FROZEN, it))
 357                         Unfreeze(it, false);
 358                 player_powerups_remove_all(it);
 359                 entity store = PS(it);
 360                 if (store)
 361                 {
 362                         Inventory_clear(store.inventory);
 363                         Inventory_update(store);
 364                 }
 365         });
 366
 367         MUTATOR_CALLHOOK(reset_map_global);
 368
 369         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 370         {
 371                 if(IS_CLIENT(it))
 372                         continue;
 373                 if (it.reset)
 374                 {
 375                         it.reset(it);
 376                         continue;
 377                 }
 378                 if (it.team_saved) it.team = it.team_saved;
 379                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 380         });
 381
 382         // Waypoints and assault start come LAST
 383         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 384                 if (it.reset2) it.reset2(it);
 385         });
 386
 387         // Moving the player reset code here since the player-reset depends
 388         // on spawnpoint entities which have to be reset first --blub
 389         if (dorespawn)
 390         {
 391                 if (!MUTATOR_CALLHOOK(reset_map_players))
 392                 {
 393                         //if (restart_mapalreadyrestarted || (time < game_starttime))
 394                         //{
 395                                 FOREACH_CLIENT(IS_PLAYER(it),
 396                                 {
 397                                         /*
 398                                         only reset players if a restart countdown is active
 399                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 400                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 401                                         sv_ready_restart_after_countdown is not used and countdown is still running
 402                                         */
 403                                         // PlayerScore_Clear(it);
 404                                         CS(it).killcount = 0;
 405                                         // stop the player from moving so that he stands still once he gets respawned
 406                                         it.velocity = '0 0 0';
 407                                         it.avelocity = '0 0 0';
 408                                         CS(it).movement = '0 0 0';
 409                                         PutClientInServer(it);
 410                                 });
 411                         //}
 412                 }
 413         }
 414 }
 415
 416 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 417 void ReadyRestart_think(entity this)
 418 {
 419         restart_mapalreadyrestarted = true;
 420         reset_map(true);
 421         Score_ClearAll();
 422         delete(this);
 423 }
 424
 425 // Forces a restart of the game without actually reloading the map // this is a mess...
 426 void ReadyRestart_force()
 427 {
 428         if (time <= game_starttime && game_stopped)
 429                 return;
 430
 431         bprint("^1Server is restarting...\n");
 432
 433         VoteReset();
 434
 435         // clear overtime, we have to decrease timelimit to its original value again.
 436         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 437                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 439
 440         if(!warmup_stage)
 441                 game_starttime = time + RESTART_COUNTDOWN;
 442         else
 443                 game_starttime = time; // No countdown in warmup
 444
 445         // clear player attributes
 446         FOREACH_CLIENT(IS_PLAYER(it), {
 447                 it.alivetime = 0;
 448                 CS(it).killcount = 0;
 449                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 450                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 451         });
 452
 453         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 454
 455         // disable the warmup global for the server
 456         if(!warmup_stage)
 457                 localcmd("\nsv_hook_warmupend\n");
 458
 459         // reset the .ready status of all players (also spectators)
 460         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 461         readycount = 0;
 462         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 463
 464         // lock teams with lockonrestart
 465         if (autocvar_teamplay_lockonrestart && teamplay)
 466                 lockteams = !warmup_stage;
 467
 468         // initiate the restart-countdown-announcer entity
 469         if (sv_ready_restart_after_countdown && !warmup_stage)
 470         {
 471                 entity restart_timer = new_pure(restart_timer);
 472                 setthink(restart_timer, ReadyRestart_think);
 473                 restart_timer.nextthink = game_starttime;
 474         }
 475
 476         // after a restart every players number of allowed timeouts gets reset, too
 477         if (autocvar_sv_timeout)
 478         {
 479                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 480         }
 481
 482         if (!sv_ready_restart_after_countdown || warmup_stage) reset_map(true);
 483         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 484 }
 485
 486 void ReadyRestart()
 487 {
 488         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 489         else localcmd("\nsv_hook_readyrestart\n");
 490
 491         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 492         // Otherwise scores could be manipulated during the countdown.
 493         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 494         ReadyRestart_force();
 495 }
 496
 497 // Count the players who are ready and determine whether or not to restart the match
 498 void ReadyCount()
 499 {
 500         float ready_needed_factor, ready_needed_count;
 501         float t_ready = 0, t_players = 0;
 502
 503         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 504                 ++t_players;
 505                 if (it.ready) ++t_ready;
 506         });
 507
 508         readycount = t_ready;
 509
 510         Nagger_ReadyCounted();
 511
 512         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 513         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 514
 515         if (readycount >= ready_needed_count)
 516         {
 517                 warmup_stage = 0;
 518                 ReadyRestart();
 519         }
 520 }
 521
 522
 523 // ======================================
 524 //  Supporting functions for VoteCommand
 525 // ======================================
 526
 527 float Votecommand_check_assignment(entity caller, float assignment)
 528 {
 529         float from_server = (!caller);
 530
 531         if ((assignment == VC_ASGNMNT_BOTH)
 532             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 533             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 534
 535         return false;
 536 }
 537
 538 string VoteCommand_extractcommand(string input, float startpos, int argc)
 539 {
 540         string output;
 541
 542         if ((argc - 1) < startpos) output = "";
 543         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 544
 545         return output;
 546 }
 547
 548 float VoteCommand_checknasty(string vote_command)
 549 {
 550         if ((strstrofs(vote_command, ";", 0) >= 0)
 551             || (strstrofs(vote_command, "\n", 0) >= 0)
 552             || (strstrofs(vote_command, "\r", 0) >= 0)
 553             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 554
 555         return true;
 556 }
 557
 558 // NOTE: requires input to be surrounded by spaces
 559 string VoteCommand_checkreplacements(string input)
 560 {
 561         string output = input;
 562         // allow gotomap replacements
 563         output = strreplace(" map ", " gotomap ", output);
 564         output = strreplace(" chmap ", " gotomap ", output);
 565         return output;
 566 }
 567
 568 float VoteCommand_checkinlist(string vote_command, string list)
 569 {
 570         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 571
 572         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 573
 574         return false;
 575 }
 576
 577 string ValidateMap(string validated_map, entity caller)
 578 {
 579         validated_map = MapInfo_FixName(validated_map);
 580
 581         if (!validated_map)
 582         {
 583                 print_to(caller, "This map is not available on this server.");
 584                 return string_null;
 585         }
 586
 587         if (!autocvar_sv_vote_override_mostrecent && caller)
 588         {
 589                 if (Map_IsRecent(validated_map))
 590                 {
 591                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 592                         return string_null;
 593                 }
 594         }
 595
 596         if (!MapInfo_CheckMap(validated_map))
 597         {
 598                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 599                 return string_null;
 600         }
 601
 602         return validated_map;
 603 }
 604
 605 float VoteCommand_checkargs(float startpos, int argc)
 606 {
 607         float p, q, check, minargs;
 608         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 609         string cmdrestriction = "";  // No we don't.
 610         string charlist, arg;
 611         float checkmate;
 612
 613         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 614                 cmdrestriction = cvar_string(cvarname);
 615         else
 616                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 617
 618         if (cmdrestriction == "") return true;
 619
 620         ++startpos;  // skip command name
 621
 622         // check minimum arg count
 623
 624         // 0 args: argc == startpos
 625         // 1 args: argc == startpos + 1
 626         // ...
 627
 628         minargs = stof(cmdrestriction);
 629         if (argc - startpos < minargs) return false;
 630
 631         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 632
 633         for ( ; ; )
 634         {
 635                 // we know that at any time, startpos <= argc - minargs
 636                 // so this means: argc-minargs >= startpos >= argc, thus
 637                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 638                 // have been seen already
 639
 640                 if (startpos >= argc) // all args checked? GOOD
 641                         break;
 642
 643                 if (p < 0)            // no more args? FAIL
 644                 {
 645                         // exception: exactly minargs left, this one included
 646                         if (argc - startpos == minargs) break;
 647
 648                         // otherwise fail
 649                         return false;
 650                 }
 651
 652                 // cut to next semicolon
 653                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 654                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 655                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 656
 657                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 658                 // charlist = strreplace("^^", ";", charlist);
 659
 660                 if (charlist != "")
 661                 {
 662                         // verify the arg only contains allowed chars
 663                         arg = argv(startpos);
 664                         checkmate = strlen(arg);
 665                         for (check = 0; check < checkmate; ++check)
 666                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 667                         // not allowed character
 668                         // all characters are allowed. FINE.
 669                 }
 670
 671                 ++startpos;
 672                 --minargs;
 673                 p = q;
 674         }
 675
 676         return true;
 677 }
 678
 679 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 680 {
 681         string first_command = argv(startpos);
 682         int missing_chars = argv_start_index(startpos);
 683
 684         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 685                 return 0;
 686
 687         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 688
 689         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 690
 691         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 692         {
 693                 case MUT_VOTEPARSE_CONTINUE: { break; }
 694                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 695                 case MUT_VOTEPARSE_INVALID: { return -1; }
 696                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 697         }
 698
 699         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 700         {
 701                 case "kick":
 702                 case "kickban":    // catch all kick/kickban commands
 703                 {
 704                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 705                         float accepted = VerifyClientEntity(victim, true, false);
 706
 707                         if (accepted > 0)
 708                         {
 709                                 string reason = "No reason provided";
 710                                 if(argc > next_token)
 711                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 712
 713                                 string command_arguments = reason;
 714                                 if (first_command == "kickban")
 715                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 716
 717                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 718                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 719                         }
 720                         else
 721                         {
 722                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 723                                 return 0;
 724                         }
 725
 726                         break;
 727                 }
 728
 729                 case "map":
 730                 case "chmap":
 731                 case "gotomap":  // re-direct all map selection commands to gotomap
 732                 {
 733                         vote_command = ValidateMap(argv(startpos + 1), caller);
 734                         if (!vote_command)  return -1;
 735                         vote_parsed_command = strcat("gotomap ", vote_command);
 736                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 737
 738                         break;
 739                 }
 740
 741                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 742                 // maybe fallback instead of aborting if map name is invalid?
 743                 case "nextmap":
 744                 {
 745                         vote_command = ValidateMap(argv(startpos + 1), caller);
 746                         if (!vote_command)  return -1;
 747                         vote_parsed_command = strcat("nextmap ", vote_command);
 748                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 749
 750                         break;
 751                 }
 752
 753                 case "timelimit": // include restrictions on the maximum votable time limit
 754                 {
 755                         float timelimit_vote = stof(argv(startpos + 1));
 756                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 757                         {
 758                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 759                                 return -1;
 760                         }
 761                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 762                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 763                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 764
 765                         break;
 766                 }
 767
 768                 case "restart":
 769                 {
 770                         // add a delay so that vote result can be seen and announcer can be heard
 771                         // if the vote is accepted
 772                         vote_parsed_command = strcat("defer 1 ", vote_command);
 773                         vote_parsed_display = strzone(strcat("^1", vote_command));
 774
 775                         break;
 776                 }
 777
 778                 default:
 779                 {
 780                         vote_parsed_command = vote_command;
 781                         vote_parsed_display = strzone(strcat("^1", vote_command));
 782
 783                         break;
 784                 }
 785         }
 786
 787         return 1;
 788 }
 789
 790
 791 // =======================
 792 //  Command Sub-Functions
 793 // =======================
 794
 795 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 796 {
 797         switch (request)
 798         {
 799                 case CMD_REQUEST_COMMAND:
 800                 {
 801                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 802                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 803                         {
 804                                 print_to(caller, "^1You have already voted.");
 805                         }
 806
 807                         else  // everything went okay, continue changing vote
 808                         {
 809                                 print_to(caller, "^1You abstained from your vote.");
 810                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 811                                 msg_entity = caller;
 812                                 if (!autocvar_sv_vote_singlecount)
 813                                         VoteCount(false);
 814                         }
 815
 816                         return;
 817                 }
 818
 819                 default:
 820                 case CMD_REQUEST_USAGE:
 821                 {
 822                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 823                         print_to(caller, "  No arguments required.");
 824                         return;
 825                 }
 826         }
 827 }
 828
 829 void print_available_commands_to(entity caller)
 830 {
 831         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 832 }
 833
 834 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 835 {
 836         switch (request)
 837         {
 838                 case CMD_REQUEST_COMMAND:
 839                 {
 840                         float tmp_playercount = 0;
 841                         int parse_error;
 842
 843                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 844
 845                         if (!autocvar_sv_vote_call && caller)
 846                         {
 847                                 print_to(caller, "^1Vote calling is not allowed.");
 848                         }
 849                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 850                         {
 851                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 852                         }
 853                         else if (vote_called)
 854                         {
 855                                 print_to(caller, "^1There is already a vote called.");
 856                         }
 857                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 858                         {
 859                                 print_to(caller, "^1Only players can call a vote.");
 860                         }
 861                         else if (caller && !IS_CLIENT(caller))
 862                         {
 863                                 print_to(caller, "^1Only connected clients can vote.");
 864                         }
 865                         else if (timeout_status && vote_command != "timein")
 866                         {
 867                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 868                         }
 869                         else if (caller && (time < caller.vote_waittime))
 870                         {
 871                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 872                         }
 873                         else if (!VoteCommand_checknasty(vote_command))
 874                         {
 875                                 print_to(caller, "^1Syntax error in command.");
 876                         }
 877                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 878                         {
 879                                 if(parse_error == 0)
 880                                 {
 881                                         if (vote_called_command == "")
 882                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 883                                         else
 884                                                 print_to(caller, "^1This command is not acceptable or not available.");
 885                                 }
 886                         }
 887                         else  // everything went okay, continue with calling the vote
 888                         {
 889                                 vote_caller = caller;  // remember who called the vote
 890                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 891                                 vote_called = VOTE_NORMAL;
 892                                 vote_called_command = strzone(vote_parsed_command);
 893                                 vote_called_display = strzone(vote_parsed_display);
 894                                 vote_endtime = time + autocvar_sv_vote_timeout;
 895
 896                                 if (caller)
 897                                 {
 898                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 899                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 900                                         msg_entity = caller;
 901                                 }
 902
 903                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 904
 905                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 906                                 if (autocvar_sv_eventlog)
 907                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 908                                 Nagger_VoteChanged();
 909                                 VoteCount(true);  // needed if you are the only one
 910
 911                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 912                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 913                         }
 914
 915                         return;
 916                 }
 917
 918                 default:
 919                 case CMD_REQUEST_USAGE:
 920                 {
 921                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 922                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 923                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 924                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 925                         print_available_commands_to(caller);
 926                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 927                         return;
 928                 }
 929         }
 930 }
 931
 932 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 933 {
 934         switch (request)
 935         {
 936                 case CMD_REQUEST_COMMAND:
 937                 {
 938                         if (autocvar_sv_vote_master)
 939                         {
 940                                 switch (strtolower(argv(2)))
 941                                 {
 942                                         case "do":
 943                                         {
 944                                                 int parse_error;
 945                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 946
 947                                                 if (!caller.vote_master)
 948                                                         print_to(caller, "^1You do not have vote master privileges.");
 949                                                 else if (!VoteCommand_checknasty(vote_command))
 950                                                 {
 951                                                         print_to(caller, "^1Syntax error in command.");
 952                                                 }
 953                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 954                                                 {
 955                                                         if(parse_error == 0)
 956                                                         {
 957                                                                 if (vote_called_command == "")
 958                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 959                                                                 else
 960                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 961                                                         }
 962                                                 }
 963                                                 else  // everything went okay, proceed with command
 964                                                 {
 965                                                         localcmd(strcat(vote_parsed_command, "\n"));
 966                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 967                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 968                                                         if (autocvar_sv_eventlog)
 969                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 970                                                 }
 971
 972                                                 return;
 973                                         }
 974
 975                                         case "login":
 976                                         {
 977                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 978                                                 else if (caller.vote_master)
 979                                                 {
 980                                                         print_to(caller, "^1You are already logged in as vote master.");
 981                                                 }
 982                                                 else if (autocvar_sv_vote_master_password != argv(3))
 983                                                 {
 984                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 985                                                 }
 986                                                 else  // everything went okay, proceed with giving this player master privilages
 987                                                 {
 988                                                         caller.vote_master = true;
 989                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 990                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 991                                                         if (autocvar_sv_eventlog)
 992                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 993                                                 }
 994
 995                                                 return;
 996                                         }
 997
 998                                         default:  // calling a vote for master
 999                                         {
1000                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1001                                                 else if (vote_called)
1002                                                 {
1003                                                         print_to(caller, "^1There is already a vote called.");
1004                                                 }
1005                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1006                                                 {
1007                                                         print_to(caller, "^1Only players can call a vote.");
1008                                                 }
1009                                                 else if (timeout_status)
1010                                                 {
1011                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1012                                                 }
1013                                                 else  // everything went okay, continue with creating vote
1014                                                 {
1015                                                         vote_caller = caller;
1016                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1017                                                         vote_called = VOTE_MASTER;
1018                                                         vote_called_command = strzone("XXX");
1019                                                         vote_called_display = strzone("^3master");
1020                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1021
1022                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1023                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1024
1025                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1026                                                         if (autocvar_sv_eventlog)
1027                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1028                                                         Nagger_VoteChanged();
1029                                                         VoteCount(true);  // needed if you are the only one
1030                                                 }
1031
1032                                                 return;
1033                                         }
1034                                 }
1035                         }
1036                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1037
1038                         return;
1039                 }
1040
1041                 default:
1042                 case CMD_REQUEST_USAGE:
1043                 {
1044                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1045                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1046                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1047                         return;
1048                 }
1049         }
1050 }
1051
1052 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1053 {
1054         switch (request)
1055         {
1056                 case CMD_REQUEST_COMMAND:
1057                 {
1058                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1059                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1060                         {
1061                                 print_to(caller, "^1You have already voted.");
1062                         }
1063                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1064                         {
1065                                 VoteStop(caller);
1066                         }
1067
1068                         else  // everything went okay, continue changing vote
1069                         {
1070                                 print_to(caller, "^1You rejected the vote.");
1071                                 caller.vote_selection = VOTE_SELECT_REJECT;
1072                                 msg_entity = caller;
1073                                 if (!autocvar_sv_vote_singlecount)
1074                                         VoteCount(false);
1075                         }
1076
1077                         return;
1078                 }
1079
1080                 default:
1081                 case CMD_REQUEST_USAGE:
1082                 {
1083                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1084                         print_to(caller, "  No arguments required.");
1085                         return;
1086                 }
1087         }
1088 }
1089
1090 void VoteCommand_status(int request, entity caller)  // BOTH
1091 {
1092         switch (request)
1093         {
1094                 case CMD_REQUEST_COMMAND:
1095                 {
1096                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1097                         else print_to(caller, "^1No vote called.");
1098
1099                         return;
1100                 }
1101
1102                 default:
1103                 case CMD_REQUEST_USAGE:
1104                 {
1105                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1106                         print_to(caller, "  No arguments required.");
1107                         return;
1108                 }
1109         }
1110 }
1111
1112 void VoteCommand_stop(int request, entity caller)  // BOTH
1113 {
1114         switch (request)
1115         {
1116                 case CMD_REQUEST_COMMAND:
1117                 {
1118                         if (!vote_called)   print_to(caller, "^1No vote called.");
1119                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1120                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1121                         return;
1122                 }
1123
1124                 default:
1125                 case CMD_REQUEST_USAGE:
1126                 {
1127                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1128                         print_to(caller, "  No arguments required.");
1129                         return;
1130                 }
1131         }
1132 }
1133
1134 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1135 {
1136         switch (request)
1137         {
1138                 case CMD_REQUEST_COMMAND:
1139                 {
1140                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1141                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1142                         {
1143                                 print_to(caller, "^1You have already voted.");
1144                         }
1145                         else  // everything went okay, continue changing vote
1146                         {
1147                                 print_to(caller, "^1You accepted the vote.");
1148                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1149                                 msg_entity = caller;
1150                                 if (!autocvar_sv_vote_singlecount)
1151                                         VoteCount(false);
1152                         }
1153
1154                         return;
1155                 }
1156
1157                 default:
1158                 case CMD_REQUEST_USAGE:
1159                 {
1160                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1161                         print_to(caller, "  No arguments required.");
1162                         return;
1163                 }
1164         }
1165 }
1166
1167 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1168 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1169 void VoteCommand_(int request)
1170 {
1171     switch(request)
1172     {
1173         case CMD_REQUEST_COMMAND:
1174         {
1175
1176             return;
1177         }
1178
1179         default:
1180         case CMD_REQUEST_USAGE:
1181         {
1182             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1183             print_to(caller, "  No arguments required.");
1184             return;
1185         }
1186     }
1187 }
1188 */
1189
1190
1191 // ================================
1192 //  Macro system for vote commands
1193 // ================================
1194
1195 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1196 #define VOTE_COMMANDS(request, caller, arguments, command) \
1197         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1198         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1199         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1200         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1201         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1202         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1203         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1204         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1205         /* nothing */
1206
1207 void VoteCommand_macro_help(entity caller, int argc)
1208 {
1209         string command_origin = GetCommandPrefix(caller);
1210
1211         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1212         {
1213                 print_to(caller, "\nVoting commands:\n");
1214                 #define VOTE_COMMAND(name, function, description, assignment) \
1215                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1216
1217                 VOTE_COMMANDS(0, caller, 0, "");
1218                 #undef VOTE_COMMAND
1219
1220                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1221                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1222                 print_available_commands_to(caller);
1223         }
1224         else  // usage for individual command
1225         {
1226                 #define VOTE_COMMAND(name, function, description, assignment) \
1227                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1228
1229                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1230                 #undef VOTE_COMMAND
1231
1232                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1233                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1234                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1235                 else if (argv(2) != "")
1236                         print_to(caller, "No documentation exists for this vote");
1237         }
1238 }
1239
1240 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1241 {
1242         #define VOTE_COMMAND(name, function, description, assignment) \
1243                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1244
1245         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1246         #undef VOTE_COMMAND
1247
1248         return false;
1249 }
1250
1251
1252 // ======================================
1253 //  Main function handling vote commands
1254 // ======================================
1255
1256 void VoteCommand(int request, entity caller, int argc, string vote_command)
1257 {
1258         // Guide for working with argc arguments by example:
1259         // argc:   1    - 2      - 3     - 4
1260         // argv:   0    - 1      - 2     - 3
1261         // cmd     vote - master - login - password
1262
1263         switch (request)
1264         {
1265                 case CMD_REQUEST_COMMAND:
1266                 {
1267                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1268                 }
1269
1270                 default:
1271                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1272                 case CMD_REQUEST_USAGE:
1273                 {
1274                         VoteCommand_macro_help(caller, argc);
1275                         return;
1276                 }
1277         }
1278 }