qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/weapons/accuracy.qh>
  27 #include <server/world.qh>
  28
  29 // =============================================
  30 //  Server side voting code, reworked by Samual
  31 //  Last updated: December 27th, 2011
  32 // =============================================
  33
  34 //  Nagger for players to know status of voting
  35 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  36 {
  37         int nags, i, f, b;
  38         entity e;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         nags = 0;
  52         if (readycount)
  53         {
  54                 nags |= BIT(0);
  55                 if (to.ready == 0) nags |= BIT(1);
  56         }
  57         if (vote_called)
  58         {
  59                 nags |= BIT(2);
  60                 if (to.vote_selection == 0) nags |= BIT(3);
  61         }
  62         if (warmup_stage) nags |= BIT(4);
  63
  64         if (sendflags & BIT(6)) nags |= BIT(6);
  65
  66         if (sendflags & BIT(7)) nags |= BIT(7);
  67
  68         if (!(nags & 4))  // no vote called? send no string
  69                 nags &= ~(BIT(6) | BIT(7));
  70
  71         WriteByte(MSG_ENTITY, nags);
  72
  73         if (nags & BIT(6))
  74         {
  75                 WriteByte(MSG_ENTITY, vote_accept_count);
  76                 WriteByte(MSG_ENTITY, vote_reject_count);
  77                 WriteByte(MSG_ENTITY, vote_needed_overall);
  78                 WriteChar(MSG_ENTITY, to.vote_selection);
  79         }
  80
  81         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  82
  83         if (nags & 1)
  84         {
  85                 for (i = 1; i <= maxclients; i += 8)
  86                 {
  87                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  88                                 if (!IS_REAL_CLIENT(e) || e.ready)
  89                                         f |= b;
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteReset()
 129 {
 130         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 131
 132         if (vote_called)
 133         {
 134                 strfree(vote_called_command);
 135                 strfree(vote_called_display);
 136                 strfree(vote_caller_name);
 137         }
 138
 139         vote_called = VOTE_NULL;
 140         vote_caller = NULL;
 141         vote_endtime = 0;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 206
 207 void VoteCount(float first_count)
 208 {
 209         // declarations
 210         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 211
 212         float vote_player_count = 0, notvoters = 0;
 213         float vote_real_player_count = 0, vote_real_accept_count = 0;
 214         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 215         float vote_needed_of_voted, final_needed_votes;
 216         float vote_factor_overall, vote_factor_of_voted;
 217
 218         Nagger_VoteCountChanged();
 219
 220         // add up all the votes from each connected client
 221         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 222                 ++vote_player_count;
 223                 if (IS_PLAYER(it))   ++vote_real_player_count;
 224                 switch (it.vote_selection)
 225                 {
 226                         case VOTE_SELECT_REJECT:
 227                         { ++vote_reject_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 229                         }
 230                         case VOTE_SELECT_ACCEPT:
 231                         { ++vote_accept_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 233                         }
 234                         case VOTE_SELECT_ABSTAIN:
 235                         { ++vote_abstain_count;
 236                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 237                         }
 238                         default: break;
 239                 }
 240         });
 241
 242         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 243         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 244         {
 245                 if (vote_caller)   vote_caller.vote_waittime = 0;
 246                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 247                 VoteReset();
 248                 return;
 249         }
 250
 251         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 252         if (!spectators_allowed && (vote_real_player_count > 0))
 253         {
 254                 vote_accept_count = vote_real_accept_count;
 255                 vote_reject_count = vote_real_reject_count;
 256                 vote_abstain_count = vote_real_abstain_count;
 257                 vote_player_count = vote_real_player_count;
 258         }
 259
 260         // people who have no opinion in any way :D
 261         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 262
 263         // determine the goal for the vote to be passed or rejected normally
 264         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 265         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 266
 267         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 268         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 269         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 270
 271         // are there any players at all on the server? it could be an admin vote
 272         if (vote_player_count == 0 && first_count)
 273         {
 274                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 275                 VoteAccept();
 276                 return;
 277         }
 278
 279         // since there ARE players, finally calculate the result of the vote
 280         if (vote_accept_count >= vote_needed_overall)
 281         {
 282                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 288         {
 289                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 290                 VoteReject();
 291                 return;
 292         }
 293
 294         // there is not enough votes in either direction, now lets just calculate what the voters have said
 295         if (time > vote_endtime)
 296         {
 297                 final_needed_votes = vote_needed_overall;
 298
 299                 if (autocvar_sv_vote_majority_factor_of_voted)
 300                 {
 301                         if (vote_accept_count >= vote_needed_of_voted)
 302                         {
 303                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 304                                 VoteAccept();
 305                                 return;
 306                         }
 307
 308                         if (vote_accept_count + vote_reject_count > 0)
 309                         {
 310                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 311                                 VoteReject();
 312                                 return;
 313                         }
 314
 315                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 316                 }
 317
 318                 // it didn't pass or fail, so not enough votes to even make a decision.
 319                 VoteSpam(notvoters, final_needed_votes, "timeout");
 320                 VoteTimeout();
 321         }
 322 }
 323
 324 void VoteThink()
 325 {
 326         if (vote_endtime > 0)        // a vote was called
 327         {
 328                 if (time > vote_endtime) // time is up
 329                         VoteCount(false);
 330         }
 331 }
 332
 333
 334 // =======================
 335 //  Game logic for warmup
 336 // =======================
 337
 338 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 339 void reset_map(bool dorespawn, bool is_fake_round_start)
 340 {
 341         if (time <= game_starttime)
 342         {
 343                 if (game_stopped)
 344                         return;
 345
 346                 if (!is_fake_round_start)
 347                 {
 348                         Score_ClearAll();
 349                         PlayerStats_GameReport_Reset_All();
 350                 }
 351
 352                 if (round_handler_IsActive())
 353                         round_handler_Reset(game_starttime);
 354         }
 355
 356         if (shuffleteams_on_reset_map)
 357         {
 358                 shuffleteams();
 359                 shuffleteams_on_reset_map = false;
 360         }
 361
 362         FOREACH_CLIENT(true, {
 363                 if (time <= game_starttime)
 364                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 365                 if (!IS_PLAYER(it))
 366                         continue;
 367                 if (STAT(FROZEN, it))
 368                         Unfreeze(it, false);
 369                 player_powerups_remove_all(it);
 370                 entity store = PS(it);
 371                 if (store)
 372                 {
 373                         Inventory_clear(store.inventory);
 374                         Inventory_update(store);
 375                 }
 376         });
 377
 378         MUTATOR_CALLHOOK(reset_map_global);
 379
 380         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 381         {
 382                 if(IS_CLIENT(it))
 383                         continue;
 384                 if (it.reset)
 385                 {
 386                         it.reset(it);
 387                         continue;
 388                 }
 389                 if (it.team_saved) it.team = it.team_saved;
 390                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 391         });
 392
 393         // Waypoints and assault start come LAST
 394         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 395                 if (it.reset2) it.reset2(it);
 396         });
 397
 398         // Moving the player reset code here since the player-reset depends
 399         // on spawnpoint entities which have to be reset first --blub
 400         if (dorespawn)
 401         {
 402                 if (!MUTATOR_CALLHOOK(reset_map_players))
 403                 {
 404                         FOREACH_CLIENT(IS_PLAYER(it),
 405                         {
 406                                 // PlayerScore_Clear(it);
 407                                 CS(it).killcount = 0;
 408                                 // stop the player from moving so that he stands still once he gets respawned
 409                                 it.velocity = '0 0 0';
 410                                 it.avelocity = '0 0 0';
 411                                 CS(it).movement = '0 0 0';
 412                                 PutClientInServer(it);
 413                         });
 414                 }
 415         }
 416 }
 417
 418 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 419 void ReadyRestart_think(entity this)
 420 {
 421         reset_map(true, false);
 422         delete(this);
 423 }
 424
 425 // Forces a restart of the game without actually reloading the map // this is a mess...
 426 void ReadyRestart_force(bool is_fake_round_start)
 427 {
 428         if (time <= game_starttime && game_stopped)
 429                 return;
 430         if (!is_fake_round_start)
 431                 bprint("^1Match is restarting...\n");
 432
 433         VoteReset();
 434
 435         // clear overtime, we have to decrease timelimit to its original value again.
 436         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 437                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 439
 440         if(warmup_stage)
 441                 game_starttime = time; // Warmup: No countdown in warmup
 442         else if (autocvar_g_campaign)
 443                 game_starttime = time + 3;
 444         else
 445                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 446
 447         // clear player attributes
 448         FOREACH_CLIENT(IS_PLAYER(it), {
 449                 it.alivetime = 0;
 450                 CS(it).killcount = 0;
 451         });
 452
 453         // if we're ending the warmup stage call the corresponding hook
 454         if(!is_fake_round_start && !warmup_stage)
 455                 localcmd("\nsv_hook_warmupend\n");
 456
 457         // reset the .ready status of all players (also spectators)
 458         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 459         readycount = 0;
 460         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 461
 462         // lock teams with lockonrestart
 463         if (autocvar_teamplay_lockonrestart && teamplay)
 464                 lockteams = !warmup_stage;
 465
 466         // initiate the restart-countdown-announcer entity
 467         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 468         {
 469                 entity restart_timer = new_pure(restart_timer);
 470                 setthink(restart_timer, ReadyRestart_think);
 471                 restart_timer.nextthink = game_starttime;
 472         }
 473
 474         // after a restart every players number of allowed timeouts gets reset, too
 475         if (autocvar_sv_timeout)
 476         {
 477                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 478         }
 479
 480         if (!sv_ready_restart_after_countdown || warmup_stage)
 481                 reset_map(true, is_fake_round_start);
 482
 483         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 484 }
 485
 486 void ReadyRestart(bool forceWarmupEnd)
 487 {
 488         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 489         else localcmd("\nsv_hook_readyrestart\n");
 490
 491         if(forceWarmupEnd || autocvar_g_campaign)
 492                 warmup_stage = 0; // forcefully end warmup and go to match stage
 493         else
 494                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 495
 496         ReadyRestart_force(false);
 497 }
 498
 499 // Count the players who are ready and determine whether or not to restart the match
 500 void ReadyCount()
 501 {
 502         float ready_needed_factor, ready_needed_count;
 503         float t_ready = 0, t_players = 0;
 504
 505         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME_JOINED(it)), {
 506                 ++t_players;
 507                 if (it.ready) ++t_ready;
 508         });
 509
 510         readycount = t_ready;
 511
 512         Nagger_ReadyCounted();
 513
 514         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 515         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 516
 517         if (readycount >= ready_needed_count) ReadyRestart(true);
 518 }
 519
 520
 521 // ======================================
 522 //  Supporting functions for VoteCommand
 523 // ======================================
 524
 525 float Votecommand_check_assignment(entity caller, float assignment)
 526 {
 527         float from_server = (!caller);
 528
 529         if ((assignment == VC_ASGNMNT_BOTH)
 530             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 531             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 532
 533         return false;
 534 }
 535
 536 string VoteCommand_extractcommand(string input, float startpos, int argc)
 537 {
 538         string output;
 539
 540         if ((argc - 1) < startpos) output = "";
 541         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 542
 543         return output;
 544 }
 545
 546 float VoteCommand_checknasty(string vote_command)
 547 {
 548         if ((strstrofs(vote_command, ";", 0) >= 0)
 549             || (strstrofs(vote_command, "\n", 0) >= 0)
 550             || (strstrofs(vote_command, "\r", 0) >= 0)
 551             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 552
 553         return true;
 554 }
 555
 556 // NOTE: requires input to be surrounded by spaces
 557 string VoteCommand_checkreplacements(string input)
 558 {
 559         string output = input;
 560         // allow gotomap replacements
 561         output = strreplace(" map ", " gotomap ", output);
 562         output = strreplace(" chmap ", " gotomap ", output);
 563         return output;
 564 }
 565
 566 float VoteCommand_checkinlist(string vote_command, string list)
 567 {
 568         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 569
 570         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 571
 572         return false;
 573 }
 574
 575 string ValidateMap(string validated_map, entity caller)
 576 {
 577         validated_map = MapInfo_FixName(validated_map);
 578
 579         if (!validated_map)
 580         {
 581                 print_to(caller, "This map is not available on this server.");
 582                 return string_null;
 583         }
 584
 585         if (!autocvar_sv_vote_override_mostrecent && caller)
 586         {
 587                 if (Map_IsRecent(validated_map))
 588                 {
 589                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 590                         return string_null;
 591                 }
 592         }
 593
 594         if (!MapInfo_CheckMap(validated_map))
 595         {
 596                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 597                 return string_null;
 598         }
 599
 600         return validated_map;
 601 }
 602
 603 float VoteCommand_checkargs(float startpos, int argc)
 604 {
 605         float p, q, check, minargs;
 606         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 607         string cmdrestriction = "";  // No we don't.
 608         string charlist, arg;
 609         float checkmate;
 610
 611         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 612                 cmdrestriction = cvar_string(cvarname);
 613         else
 614                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 615
 616         if (cmdrestriction == "") return true;
 617
 618         ++startpos;  // skip command name
 619
 620         // check minimum arg count
 621
 622         // 0 args: argc == startpos
 623         // 1 args: argc == startpos + 1
 624         // ...
 625
 626         minargs = stof(cmdrestriction);
 627         if (argc - startpos < minargs) return false;
 628
 629         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 630
 631         for ( ; ; )
 632         {
 633                 // we know that at any time, startpos <= argc - minargs
 634                 // so this means: argc-minargs >= startpos >= argc, thus
 635                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 636                 // have been seen already
 637
 638                 if (startpos >= argc) // all args checked? GOOD
 639                         break;
 640
 641                 if (p < 0)            // no more args? FAIL
 642                 {
 643                         // exception: exactly minargs left, this one included
 644                         if (argc - startpos == minargs) break;
 645
 646                         // otherwise fail
 647                         return false;
 648                 }
 649
 650                 // cut to next semicolon
 651                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 652                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 653                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 654
 655                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 656                 // charlist = strreplace("^^", ";", charlist);
 657
 658                 if (charlist != "")
 659                 {
 660                         // verify the arg only contains allowed chars
 661                         arg = argv(startpos);
 662                         checkmate = strlen(arg);
 663                         for (check = 0; check < checkmate; ++check)
 664                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 665                         // not allowed character
 666                         // all characters are allowed. FINE.
 667                 }
 668
 669                 ++startpos;
 670                 --minargs;
 671                 p = q;
 672         }
 673
 674         return true;
 675 }
 676
 677 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 678 {
 679         string first_command = argv(startpos);
 680         int missing_chars = argv_start_index(startpos);
 681
 682         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 683                 return 0;
 684
 685         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 686
 687         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 688
 689         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 690         {
 691                 case MUT_VOTEPARSE_CONTINUE: { break; }
 692                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 693                 case MUT_VOTEPARSE_INVALID: { return -1; }
 694                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 695         }
 696
 697         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 698         {
 699                 case "kick":
 700                 case "kickban":    // catch all kick/kickban commands
 701                 {
 702                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 703                         float accepted = VerifyClientEntity(victim, true, false);
 704
 705                         if (accepted > 0)
 706                         {
 707                                 string reason = "No reason provided";
 708                                 if(argc > next_token)
 709                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 710
 711                                 string command_arguments = reason;
 712                                 if (first_command == "kickban")
 713                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 714
 715                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 716                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 717                         }
 718                         else
 719                         {
 720                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 721                                 return 0;
 722                         }
 723
 724                         break;
 725                 }
 726
 727                 case "map":
 728                 case "chmap":
 729                 case "gotomap":  // re-direct all map selection commands to gotomap
 730                 {
 731                         vote_command = ValidateMap(argv(startpos + 1), caller);
 732                         if (!vote_command)  return -1;
 733                         vote_parsed_command = strcat("gotomap ", vote_command);
 734                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 735
 736                         break;
 737                 }
 738
 739                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 740                 // maybe fallback instead of aborting if map name is invalid?
 741                 case "nextmap":
 742                 {
 743                         vote_command = ValidateMap(argv(startpos + 1), caller);
 744                         if (!vote_command)  return -1;
 745                         vote_parsed_command = strcat("nextmap ", vote_command);
 746                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 747
 748                         break;
 749                 }
 750
 751                 case "timelimit": // include restrictions on the maximum votable time limit
 752                 {
 753                         float timelimit_vote = stof(argv(startpos + 1));
 754                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 755                         {
 756                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 757                                 return -1;
 758                         }
 759                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 760                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 761                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 762
 763                         break;
 764                 }
 765
 766                 case "restart":
 767                 {
 768                         // add a delay so that vote result can be seen and announcer can be heard
 769                         // if the vote is accepted
 770                         vote_parsed_command = strcat("defer 1 ", vote_command);
 771                         vote_parsed_display = strzone(strcat("^1", vote_command));
 772
 773                         break;
 774                 }
 775
 776                 case "allready":
 777                 {
 778                         if(!warmup_stage) {
 779                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 780                                 return -1;
 781                         }
 782
 783                         vote_parsed_command = vote_command;
 784                         vote_parsed_display = strzone(strcat("^1", vote_command));
 785                         break;
 786                 }
 787
 788                 default:
 789                 {
 790                         vote_parsed_command = vote_command;
 791                         vote_parsed_display = strzone(strcat("^1", vote_command));
 792
 793                         break;
 794                 }
 795         }
 796
 797         return 1;
 798 }
 799
 800
 801 // =======================
 802 //  Command Sub-Functions
 803 // =======================
 804
 805 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 806 {
 807         switch (request)
 808         {
 809                 case CMD_REQUEST_COMMAND:
 810                 {
 811                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 812                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 813                         {
 814                                 print_to(caller, "^1You have already voted.");
 815                         }
 816
 817                         else  // everything went okay, continue changing vote
 818                         {
 819                                 print_to(caller, "^1You abstained from your vote.");
 820                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 821                                 msg_entity = caller;
 822                                 if (!autocvar_sv_vote_singlecount)
 823                                         VoteCount(false);
 824                         }
 825
 826                         return;
 827                 }
 828
 829                 default:
 830                 case CMD_REQUEST_USAGE:
 831                 {
 832                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 833                         print_to(caller, "  No arguments required.");
 834                         return;
 835                 }
 836         }
 837 }
 838
 839 void print_available_commands_to(entity caller)
 840 {
 841         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 842 }
 843
 844 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 845 {
 846         switch (request)
 847         {
 848                 case CMD_REQUEST_COMMAND:
 849                 {
 850                         float tmp_playercount = 0;
 851                         int parse_error;
 852
 853                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 854
 855                         if (!autocvar_sv_vote_call && caller)
 856                         {
 857                                 print_to(caller, "^1Vote calling is not allowed.");
 858                         }
 859                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 860                         {
 861                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 862                         }
 863                         else if (vote_called)
 864                         {
 865                                 print_to(caller, "^1There is already a vote called.");
 866                         }
 867                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 868                         {
 869                                 print_to(caller, "^1Only players can call a vote.");
 870                         }
 871                         else if (caller && !IS_CLIENT(caller))
 872                         {
 873                                 print_to(caller, "^1Only connected clients can vote.");
 874                         }
 875                         else if (timeout_status && vote_command != "timein")
 876                         {
 877                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 878                         }
 879                         else if (caller && (time < caller.vote_waittime))
 880                         {
 881                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 882                         }
 883                         else if (!VoteCommand_checknasty(vote_command))
 884                         {
 885                                 print_to(caller, "^1Syntax error in command.");
 886                         }
 887                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 888                         {
 889                                 if(parse_error == 0)
 890                                 {
 891                                         if (vote_called_command == "")
 892                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 893                                         else
 894                                                 print_to(caller, "^1This command is not acceptable or not available.");
 895                                 }
 896                         }
 897                         else  // everything went okay, continue with calling the vote
 898                         {
 899                                 vote_caller = caller;  // remember who called the vote
 900                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 901                                 vote_called = VOTE_NORMAL;
 902                                 vote_called_command = strzone(vote_parsed_command);
 903                                 vote_called_display = strzone(vote_parsed_display);
 904                                 vote_endtime = time + autocvar_sv_vote_timeout;
 905
 906                                 if (caller)
 907                                 {
 908                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 909                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 910                                         msg_entity = caller;
 911                                 }
 912
 913                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 914
 915                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 916                                 if (autocvar_sv_eventlog)
 917                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 918                                 Nagger_VoteChanged();
 919                                 VoteCount(true);  // needed if you are the only one
 920
 921                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 922                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 923                         }
 924
 925                         return;
 926                 }
 927
 928                 default:
 929                 case CMD_REQUEST_USAGE:
 930                 {
 931                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 932                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 933                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 934                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 935                         print_available_commands_to(caller);
 936                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 937                         return;
 938                 }
 939         }
 940 }
 941
 942 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 943 {
 944         switch (request)
 945         {
 946                 case CMD_REQUEST_COMMAND:
 947                 {
 948                         if (autocvar_sv_vote_master)
 949                         {
 950                                 switch (strtolower(argv(2)))
 951                                 {
 952                                         case "do":
 953                                         {
 954                                                 int parse_error;
 955                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 956
 957                                                 if (!caller.vote_master)
 958                                                         print_to(caller, "^1You do not have vote master privileges.");
 959                                                 else if (!VoteCommand_checknasty(vote_command))
 960                                                 {
 961                                                         print_to(caller, "^1Syntax error in command.");
 962                                                 }
 963                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 964                                                 {
 965                                                         if(parse_error == 0)
 966                                                         {
 967                                                                 if (vote_called_command == "")
 968                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 969                                                                 else
 970                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 971                                                         }
 972                                                 }
 973                                                 else  // everything went okay, proceed with command
 974                                                 {
 975                                                         localcmd(strcat(vote_parsed_command, "\n"));
 976                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 977                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 978                                                         if (autocvar_sv_eventlog)
 979                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 980                                                 }
 981
 982                                                 return;
 983                                         }
 984
 985                                         case "login":
 986                                         {
 987                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 988                                                 else if (caller.vote_master)
 989                                                 {
 990                                                         print_to(caller, "^1You are already logged in as vote master.");
 991                                                 }
 992                                                 else if (autocvar_sv_vote_master_password != argv(3))
 993                                                 {
 994                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 995                                                 }
 996                                                 else  // everything went okay, proceed with giving this player master privilages
 997                                                 {
 998                                                         caller.vote_master = true;
 999                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1000                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1001                                                         if (autocvar_sv_eventlog)
1002                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1003                                                 }
1004
1005                                                 return;
1006                                         }
1007
1008                                         default:  // calling a vote for master
1009                                         {
1010                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1011                                                 else if (vote_called)
1012                                                 {
1013                                                         print_to(caller, "^1There is already a vote called.");
1014                                                 }
1015                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1016                                                 {
1017                                                         print_to(caller, "^1Only players can call a vote.");
1018                                                 }
1019                                                 else if (timeout_status)
1020                                                 {
1021                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1022                                                 }
1023                                                 else  // everything went okay, continue with creating vote
1024                                                 {
1025                                                         vote_caller = caller;
1026                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1027                                                         vote_called = VOTE_MASTER;
1028                                                         vote_called_command = strzone("XXX");
1029                                                         vote_called_display = strzone("^3master");
1030                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1031
1032                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1033                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1034
1035                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1036                                                         if (autocvar_sv_eventlog)
1037                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1038                                                         Nagger_VoteChanged();
1039                                                         VoteCount(true);  // needed if you are the only one
1040                                                 }
1041
1042                                                 return;
1043                                         }
1044                                 }
1045                         }
1046                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1047
1048                         return;
1049                 }
1050
1051                 default:
1052                 case CMD_REQUEST_USAGE:
1053                 {
1054                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1055                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1056                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1057                         return;
1058                 }
1059         }
1060 }
1061
1062 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1063 {
1064         switch (request)
1065         {
1066                 case CMD_REQUEST_COMMAND:
1067                 {
1068                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1069                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1070                         {
1071                                 print_to(caller, "^1You have already voted.");
1072                         }
1073                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1074                         {
1075                                 VoteStop(caller);
1076                         }
1077
1078                         else  // everything went okay, continue changing vote
1079                         {
1080                                 print_to(caller, "^1You rejected the vote.");
1081                                 caller.vote_selection = VOTE_SELECT_REJECT;
1082                                 msg_entity = caller;
1083                                 if (!autocvar_sv_vote_singlecount)
1084                                         VoteCount(false);
1085                         }
1086
1087                         return;
1088                 }
1089
1090                 default:
1091                 case CMD_REQUEST_USAGE:
1092                 {
1093                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1094                         print_to(caller, "  No arguments required.");
1095                         return;
1096                 }
1097         }
1098 }
1099
1100 void VoteCommand_status(int request, entity caller)  // BOTH
1101 {
1102         switch (request)
1103         {
1104                 case CMD_REQUEST_COMMAND:
1105                 {
1106                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1107                         else print_to(caller, "^1No vote called.");
1108
1109                         return;
1110                 }
1111
1112                 default:
1113                 case CMD_REQUEST_USAGE:
1114                 {
1115                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1116                         print_to(caller, "  No arguments required.");
1117                         return;
1118                 }
1119         }
1120 }
1121
1122 void VoteCommand_stop(int request, entity caller)  // BOTH
1123 {
1124         switch (request)
1125         {
1126                 case CMD_REQUEST_COMMAND:
1127                 {
1128                         if (!vote_called)   print_to(caller, "^1No vote called.");
1129                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1130                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1131                         return;
1132                 }
1133
1134                 default:
1135                 case CMD_REQUEST_USAGE:
1136                 {
1137                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1138                         print_to(caller, "  No arguments required.");
1139                         return;
1140                 }
1141         }
1142 }
1143
1144 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1145 {
1146         switch (request)
1147         {
1148                 case CMD_REQUEST_COMMAND:
1149                 {
1150                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1151                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1152                         {
1153                                 print_to(caller, "^1You have already voted.");
1154                         }
1155                         else  // everything went okay, continue changing vote
1156                         {
1157                                 print_to(caller, "^1You accepted the vote.");
1158                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1159                                 msg_entity = caller;
1160                                 if (!autocvar_sv_vote_singlecount)
1161                                         VoteCount(false);
1162                         }
1163
1164                         return;
1165                 }
1166
1167                 default:
1168                 case CMD_REQUEST_USAGE:
1169                 {
1170                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1171                         print_to(caller, "  No arguments required.");
1172                         return;
1173                 }
1174         }
1175 }
1176
1177 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1178 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1179 void VoteCommand_(int request)
1180 {
1181     switch(request)
1182     {
1183         case CMD_REQUEST_COMMAND:
1184         {
1185
1186             return;
1187         }
1188
1189         default:
1190         case CMD_REQUEST_USAGE:
1191         {
1192             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1193             print_to(caller, "  No arguments required.");
1194             return;
1195         }
1196     }
1197 }
1198 */
1199
1200
1201 // ================================
1202 //  Macro system for vote commands
1203 // ================================
1204
1205 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1206 #define VOTE_COMMANDS(request, caller, arguments, command) \
1207         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1208         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1209         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1210         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1211         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1212         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1213         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1214         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1215         /* nothing */
1216
1217 void VoteCommand_macro_help(entity caller, int argc)
1218 {
1219         string command_origin = GetCommandPrefix(caller);
1220
1221         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1222         {
1223                 print_to(caller, "\nVoting commands:\n");
1224                 #define VOTE_COMMAND(name, function, description, assignment) \
1225                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1226
1227                 VOTE_COMMANDS(0, caller, 0, "");
1228                 #undef VOTE_COMMAND
1229
1230                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1231                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1232                 print_available_commands_to(caller);
1233         }
1234         else  // usage for individual command
1235         {
1236                 #define VOTE_COMMAND(name, function, description, assignment) \
1237                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1238
1239                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1240                 #undef VOTE_COMMAND
1241
1242                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1243                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1244                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1245                 else if (argv(2) != "")
1246                         print_to(caller, "No documentation exists for this vote");
1247         }
1248 }
1249
1250 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1251 {
1252         #define VOTE_COMMAND(name, function, description, assignment) \
1253                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1254
1255         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1256         #undef VOTE_COMMAND
1257
1258         return false;
1259 }
1260
1261
1262 // ======================================
1263 //  Main function handling vote commands
1264 // ======================================
1265
1266 void VoteCommand(int request, entity caller, int argc, string vote_command)
1267 {
1268         // Guide for working with argc arguments by example:
1269         // argc:   1    - 2      - 3     - 4
1270         // argv:   0    - 1      - 2     - 3
1271         // cmd     vote - master - login - password
1272
1273         switch (request)
1274         {
1275                 case CMD_REQUEST_COMMAND:
1276                 {
1277                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1278                 }
1279
1280                 default:
1281                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1282                 case CMD_REQUEST_USAGE:
1283                 {
1284                         VoteCommand_macro_help(caller, argc);
1285                         return;
1286                 }
1287         }
1288 }