qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <server/client.qh>
   4 #include <server/defs.qh>
   5 #include <server/gamelog.qh>
   6 #include <server/miscfunctions.qh>
   7
   8 #include <common/command/_mod.qh>
   9 #include "vote.qh"
  10
  11 #include "common.qh"
  12
  13 #include "../g_damage.qh"
  14 #include "../g_world.qh"
  15 #include "../teamplay.qh"
  16 #include "../race.qh"
  17 #include "../round_handler.qh"
  18 #include "../scores.qh"
  19
  20 #include <server/mutators/_mod.qh>
  21 #include <common/gamemodes/_mod.qh>
  22
  23 #include <common/constants.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/mapinfo.qh>
  26 #include <common/notifications/all.qh>
  27 #include <common/playerstats.qh>
  28 #include <common/util.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags, i, f, b;
  39         entity e;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         nags = 0;
  53         if (readycount)
  54         {
  55                 nags |= BIT(0);
  56                 if (to.ready == 0) nags |= BIT(1);
  57         }
  58         if (vote_called)
  59         {
  60                 nags |= BIT(2);
  61                 if (to.vote_selection == 0) nags |= BIT(3);
  62         }
  63         if (warmup_stage) nags |= BIT(4);
  64
  65         if (sendflags & BIT(6)) nags |= BIT(6);
  66
  67         if (sendflags & BIT(7)) nags |= BIT(7);
  68
  69         if (!(nags & 4))  // no vote called? send no string
  70                 nags &= ~(BIT(6) | BIT(7));
  71
  72         WriteByte(MSG_ENTITY, nags);
  73
  74         if (nags & BIT(6))
  75         {
  76                 WriteByte(MSG_ENTITY, vote_accept_count);
  77                 WriteByte(MSG_ENTITY, vote_reject_count);
  78                 WriteByte(MSG_ENTITY, vote_needed_overall);
  79                 WriteChar(MSG_ENTITY, to.vote_selection);
  80         }
  81
  82         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  83
  84         if (nags & 1)
  85         {
  86                 for (i = 1; i <= maxclients; i += 8)
  87                 {
  88                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  89                                 if (!IS_REAL_CLIENT(e) || e.ready)
  90                                         f |= b;
  91                         WriteByte(MSG_ENTITY, f);
  92                 }
  93         }
  94
  95         return true;
  96 }
  97
  98 void Nagger_Init()
  99 {
 100         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 101 }
 102
 103 void Nagger_VoteChanged()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(7);
 106 }
 107
 108 void Nagger_VoteCountChanged()
 109 {
 110         if (nagger) nagger.SendFlags |= BIT(6);
 111 }
 112
 113 void Nagger_ReadyCounted()
 114 {
 115         if (nagger) nagger.SendFlags |= BIT(0);
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller, false);
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 132
 133         if (vote_called)
 134         {
 135                 strfree(vote_called_command);
 136                 strfree(vote_called_display);
 137                 strfree(vote_caller_name);
 138         }
 139
 140         vote_called = VOTE_NULL;
 141         vote_caller = NULL;
 142         vote_endtime = 0;
 143
 144         vote_parsed_command = string_null;
 145         vote_parsed_display = string_null;
 146
 147         Nagger_VoteChanged();
 148 }
 149
 150 void VoteStop(entity stopper)
 151 {
 152         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 153         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 156         VoteReset();
 157 }
 158
 159 void VoteAccept()
 160 {
 161         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 162
 163         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 164         else localcmd(strcat(vote_called_command, "\n"));
 165
 166         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 167
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 170 }
 171
 172 void VoteReject()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteTimeout()
 180 {
 181         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 182         VoteReset();
 183         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 184 }
 185
 186 void VoteSpam(float notvoters, float mincount, string result)
 187 {
 188         bprint(strcat(
 189                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 190                 strcat("^2:^1", ftos(vote_reject_count)),
 191                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 192                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 193                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 194
 195         if (autocvar_sv_eventlog)
 196         {
 197                 GameLogEcho(strcat(
 198                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 199                         strcat(":", ftos(vote_reject_count)),
 200                         strcat(":", ftos(vote_abstain_count)),
 201                         strcat(":", ftos(notvoters)),
 202                         strcat(":", ftos(mincount))));
 203         }
 204 }
 205
 206 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 207
 208 void VoteCount(float first_count)
 209 {
 210         // declarations
 211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         Nagger_VoteCountChanged();
 220
 221         // add up all the votes from each connected client
 222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 223                 ++vote_player_count;
 224                 if (IS_PLAYER(it))   ++vote_real_player_count;
 225                 switch (it.vote_selection)
 226                 {
 227                         case VOTE_SELECT_REJECT:
 228                         { ++vote_reject_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 230                         }
 231                         case VOTE_SELECT_ACCEPT:
 232                         { ++vote_accept_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 234                         }
 235                         case VOTE_SELECT_ABSTAIN:
 236                         { ++vote_abstain_count;
 237                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 238                         }
 239                         default: break;
 240                 }
 241         });
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if (vote_caller)   vote_caller.vote_waittime = 0;
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if (!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if (vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if (vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if (time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if (autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if (vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if (vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if (vote_endtime > 0)        // a vote was called
 328         {
 329                 if (time > vote_endtime) // time is up
 330                         VoteCount(false);
 331         }
 332 }
 333
 334
 335 // =======================
 336 //  Game logic for warmup
 337 // =======================
 338
 339 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 340 void reset_map(bool dorespawn)
 341 {
 342         if (time <= game_starttime)
 343         {
 344                 if (game_stopped)
 345                         return;
 346                 if (round_handler_IsActive())
 347                         round_handler_Reset(game_starttime);
 348         }
 349
 350         if (shuffleteams_on_reset_map)
 351         {
 352                 shuffleteams();
 353                 shuffleteams_on_reset_map = false;
 354         }
 355         MUTATOR_CALLHOOK(reset_map_global);
 356
 357         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 358         {
 359                 if(IS_CLIENT(it))
 360                         continue;
 361                 if (it.reset)
 362                 {
 363                         it.reset(it);
 364                         continue;
 365                 }
 366                 if (it.team_saved) it.team = it.team_saved;
 367                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 368         });
 369
 370         // Waypoints and assault start come LAST
 371         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 372                 if (it.reset2) it.reset2(it);
 373         });
 374
 375         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
 376
 377         // Moving the player reset code here since the player-reset depends
 378         // on spawnpoint entities which have to be reset first --blub
 379         if (dorespawn)
 380         {
 381                 if (!MUTATOR_CALLHOOK(reset_map_players))
 382                 {
 383                         if (restart_mapalreadyrestarted || (time < game_starttime))
 384                         {
 385                                 FOREACH_CLIENT(IS_PLAYER(it),
 386                                 {
 387                                         /*
 388                                         only reset players if a restart countdown is active
 389                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 390                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 391                                         sv_ready_restart_after_countdown is not used and countdown is still running
 392                                         */
 393                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 394                                         // PlayerScore_Clear(it);
 395                                         CS(it).killcount = 0;
 396                                         // stop the player from moving so that he stands still once he gets respawned
 397                                         it.velocity = '0 0 0';
 398                                         it.avelocity = '0 0 0';
 399                                         CS(it).movement = '0 0 0';
 400                                         PutClientInServer(it);
 401                                 });
 402                         }
 403                 }
 404         }
 405 }
 406
 407 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 408 void ReadyRestart_think(entity this)
 409 {
 410         restart_mapalreadyrestarted = true;
 411         reset_map(true);
 412         Score_ClearAll();
 413         delete(this);
 414 }
 415
 416 // Forces a restart of the game without actually reloading the map // this is a mess...
 417 void ReadyRestart_force()
 418 {
 419         if (time <= game_starttime && game_stopped)
 420                 return;
 421
 422         bprint("^1Server is restarting...\n");
 423
 424         VoteReset();
 425
 426         // clear overtime, we have to decrease timelimit to its original value again.
 427         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 428                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 429         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 430
 431         readyrestart_happened = true;
 432         game_starttime = time + RESTART_COUNTDOWN;
 433
 434         // clear player attributes
 435         FOREACH_CLIENT(IS_PLAYER(it), {
 436                 it.alivetime = 0;
 437                 CS(it).killcount = 0;
 438                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 439                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 440         });
 441
 442         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 443
 444         // disable the warmup global for the server
 445         if(warmup_stage)
 446                 localcmd("\nsv_hook_warmupend\n");
 447         warmup_stage = 0;                // once the game is restarted the game is in match stage
 448
 449         // reset the .ready status of all players (also spectators)
 450         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 451         readycount = 0;
 452         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 453
 454         // lock teams with lockonrestart
 455         if (autocvar_teamplay_lockonrestart && teamplay)
 456         {
 457                 lockteams = true;
 458                 bprint("^1The teams are now locked.\n");
 459         }
 460
 461         // initiate the restart-countdown-announcer entity
 462         if (sv_ready_restart_after_countdown)
 463         {
 464                 entity restart_timer = new_pure(restart_timer);
 465                 setthink(restart_timer, ReadyRestart_think);
 466                 restart_timer.nextthink = game_starttime;
 467         }
 468
 469         // after a restart every players number of allowed timeouts gets reset, too
 470         if (autocvar_sv_timeout)
 471         {
 472                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 473         }
 474
 475         if (!sv_ready_restart_after_countdown) reset_map(true);
 476         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 477 }
 478
 479 void ReadyRestart()
 480 {
 481         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 482         else localcmd("\nsv_hook_readyrestart\n");
 483
 484         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 485         // Otherwise scores could be manipulated during the countdown.
 486         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 487         ReadyRestart_force();
 488 }
 489
 490 // Count the players who are ready and determine whether or not to restart the match
 491 void ReadyCount()
 492 {
 493         float ready_needed_factor, ready_needed_count;
 494         float t_ready = 0, t_players = 0;
 495
 496         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 497                 ++t_players;
 498                 if (it.ready) ++t_ready;
 499         });
 500
 501         readycount = t_ready;
 502
 503         Nagger_ReadyCounted();
 504
 505         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 506         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 507
 508         if (readycount >= ready_needed_count) ReadyRestart();
 509 }
 510
 511
 512 // ======================================
 513 //  Supporting functions for VoteCommand
 514 // ======================================
 515
 516 float Votecommand_check_assignment(entity caller, float assignment)
 517 {
 518         float from_server = (!caller);
 519
 520         if ((assignment == VC_ASGNMNT_BOTH)
 521             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 522             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 523
 524         return false;
 525 }
 526
 527 string VoteCommand_extractcommand(string input, float startpos, int argc)
 528 {
 529         string output;
 530
 531         if ((argc - 1) < startpos) output = "";
 532         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 533
 534         return output;
 535 }
 536
 537 float VoteCommand_checknasty(string vote_command)
 538 {
 539         if ((strstrofs(vote_command, ";", 0) >= 0)
 540             || (strstrofs(vote_command, "\n", 0) >= 0)
 541             || (strstrofs(vote_command, "\r", 0) >= 0)
 542             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 543
 544         return true;
 545 }
 546
 547 // NOTE: requires input to be surrounded by spaces
 548 string VoteCommand_checkreplacements(string input)
 549 {
 550         string output = input;
 551         // allow gotomap replacements
 552         output = strreplace(" map ", " gotomap ", output);
 553         output = strreplace(" chmap ", " gotomap ", output);
 554         return output;
 555 }
 556
 557 float VoteCommand_checkinlist(string vote_command, string list)
 558 {
 559         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 560
 561         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 562
 563         return false;
 564 }
 565
 566 string ValidateMap(string validated_map, entity caller)
 567 {
 568         validated_map = MapInfo_FixName(validated_map);
 569
 570         if (!validated_map)
 571         {
 572                 print_to(caller, "This map is not available on this server.");
 573                 return string_null;
 574         }
 575
 576         if (!autocvar_sv_vote_override_mostrecent && caller)
 577         {
 578                 if (Map_IsRecent(validated_map))
 579                 {
 580                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 581                         return string_null;
 582                 }
 583         }
 584
 585         if (!MapInfo_CheckMap(validated_map))
 586         {
 587                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 588                 return string_null;
 589         }
 590
 591         return validated_map;
 592 }
 593
 594 float VoteCommand_checkargs(float startpos, int argc)
 595 {
 596         float p, q, check, minargs;
 597         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 598         string cmdrestriction = "";  // No we don't.
 599         string charlist, arg;
 600         float checkmate;
 601
 602         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 603                 cmdrestriction = cvar_string(cvarname);
 604         else
 605                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 606
 607         if (cmdrestriction == "") return true;
 608
 609         ++startpos;  // skip command name
 610
 611         // check minimum arg count
 612
 613         // 0 args: argc == startpos
 614         // 1 args: argc == startpos + 1
 615         // ...
 616
 617         minargs = stof(cmdrestriction);
 618         if (argc - startpos < minargs) return false;
 619
 620         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 621
 622         for ( ; ; )
 623         {
 624                 // we know that at any time, startpos <= argc - minargs
 625                 // so this means: argc-minargs >= startpos >= argc, thus
 626                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 627                 // have been seen already
 628
 629                 if (startpos >= argc) // all args checked? GOOD
 630                         break;
 631
 632                 if (p < 0)            // no more args? FAIL
 633                 {
 634                         // exception: exactly minargs left, this one included
 635                         if (argc - startpos == minargs) break;
 636
 637                         // otherwise fail
 638                         return false;
 639                 }
 640
 641                 // cut to next semicolon
 642                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 643                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 644                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 645
 646                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 647                 // charlist = strreplace("^^", ";", charlist);
 648
 649                 if (charlist != "")
 650                 {
 651                         // verify the arg only contains allowed chars
 652                         arg = argv(startpos);
 653                         checkmate = strlen(arg);
 654                         for (check = 0; check < checkmate; ++check)
 655                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 656                         // not allowed character
 657                         // all characters are allowed. FINE.
 658                 }
 659
 660                 ++startpos;
 661                 --minargs;
 662                 p = q;
 663         }
 664
 665         return true;
 666 }
 667
 668 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 669 {
 670         string first_command = argv(startpos);
 671         int missing_chars = argv_start_index(startpos);
 672
 673         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 674                 return 0;
 675
 676         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 677
 678         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 679
 680         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 681         {
 682                 case MUT_VOTEPARSE_CONTINUE: { break; }
 683                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 684                 case MUT_VOTEPARSE_INVALID: { return -1; }
 685                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 686         }
 687
 688         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 689         {
 690                 case "kick":
 691                 case "kickban":    // catch all kick/kickban commands
 692                 {
 693                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 694                         float accepted = VerifyClientEntity(victim, true, false);
 695
 696                         if (accepted > 0)
 697                         {
 698                                 string reason = "No reason provided";
 699                                 if(argc > next_token)
 700                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 701
 702                                 string command_arguments = reason;
 703                                 if (first_command == "kickban")
 704                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 705
 706                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 707                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 708                         }
 709                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 710
 711                         break;
 712                 }
 713
 714                 case "map":
 715                 case "chmap":
 716                 case "gotomap":  // re-direct all map selection commands to gotomap
 717                 {
 718                         vote_command = ValidateMap(argv(startpos + 1), caller);
 719                         if (!vote_command)  return -1;
 720                         vote_parsed_command = strcat("gotomap ", vote_command);
 721                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 722
 723                         break;
 724                 }
 725
 726                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 727                 // maybe fallback instead of aborting if map name is invalid?
 728                 case "nextmap":
 729                 {
 730                         vote_command = ValidateMap(argv(startpos + 1), caller);
 731                         if (!vote_command)  return -1;
 732                         vote_parsed_command = strcat("nextmap ", vote_command);
 733                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 734
 735                         break;
 736                 }
 737
 738                 case "timelimit": // include restrictions on the maximum votable time limit
 739                 {
 740                         float timelimit_vote = stof(argv(startpos + 1));
 741                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 742                         {
 743                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 744                                 return -1;
 745                         }
 746                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 747                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 748                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 749
 750                         break;
 751                 }
 752
 753                 case "restart":
 754                 {
 755                         // add a delay so that vote result can be seen and announcer can be heard
 756                         // if the vote is accepted
 757                         vote_parsed_command = strcat("defer 1 ", vote_command);
 758                         vote_parsed_display = strzone(strcat("^1", vote_command));
 759
 760                         break;
 761                 }
 762
 763                 default:
 764                 {
 765                         vote_parsed_command = vote_command;
 766                         vote_parsed_display = strzone(strcat("^1", vote_command));
 767
 768                         break;
 769                 }
 770         }
 771
 772         return 1;
 773 }
 774
 775
 776 // =======================
 777 //  Command Sub-Functions
 778 // =======================
 779
 780 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 781 {
 782         switch (request)
 783         {
 784                 case CMD_REQUEST_COMMAND:
 785                 {
 786                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 787                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 788                         {
 789                                 print_to(caller, "^1You have already voted.");
 790                         }
 791
 792                         else  // everything went okay, continue changing vote
 793                         {
 794                                 print_to(caller, "^1You abstained from your vote.");
 795                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 796                                 msg_entity = caller;
 797                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 798
 799                         return;
 800                 }
 801
 802                 default:
 803                 case CMD_REQUEST_USAGE:
 804                 {
 805                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 806                         print_to(caller, "  No arguments required.");
 807                         return;
 808                 }
 809         }
 810 }
 811
 812 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 813 {
 814         switch (request)
 815         {
 816                 case CMD_REQUEST_COMMAND:
 817                 {
 818                         float tmp_playercount = 0;
 819                         int parse_error;
 820
 821                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 822
 823                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 824                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 825                         {
 826                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 827                         }
 828                         else if (vote_called)
 829                         {
 830                                 print_to(caller, "^1There is already a vote called.");
 831                         }
 832                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 833                         {
 834                                 print_to(caller, "^1Only players can call a vote.");
 835                         }
 836                         else if (caller && !IS_CLIENT(caller))
 837                         {
 838                                 print_to(caller, "^1Only connected clients can vote.");
 839                         }
 840                         else if (timeout_status && vote_command != "timein")
 841                         {
 842                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 843                         }
 844                         else if (caller && (time < caller.vote_waittime))
 845                         {
 846                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 847                         }
 848                         else if (!VoteCommand_checknasty(vote_command))
 849                         {
 850                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 851                         }
 852                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 853                         {
 854                                 if(parse_error == 0)
 855                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 856                         }
 857                         else  // everything went okay, continue with calling the vote
 858                         {
 859                                 vote_caller = caller;  // remember who called the vote
 860                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 861                                 vote_called = VOTE_NORMAL;
 862                                 vote_called_command = strzone(vote_parsed_command);
 863                                 vote_called_display = strzone(vote_parsed_display);
 864                                 vote_endtime = time + autocvar_sv_vote_timeout;
 865
 866                                 if (caller)
 867                                 {
 868                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 869                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 870                                         msg_entity = caller;
 871                                 }
 872
 873                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 874
 875                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 876                                 if (autocvar_sv_eventlog)
 877                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 878                                 Nagger_VoteChanged();
 879                                 VoteCount(true);  // needed if you are the only one
 880
 881                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 882                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 883                         }
 884
 885                         return;
 886                 }
 887
 888                 default:
 889                 case CMD_REQUEST_USAGE:
 890                 {
 891                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 892                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 893                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 894                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 895                         return;
 896                 }
 897         }
 898 }
 899
 900 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 901 {
 902         switch (request)
 903         {
 904                 case CMD_REQUEST_COMMAND:
 905                 {
 906                         if (autocvar_sv_vote_master)
 907                         {
 908                                 switch (strtolower(argv(2)))
 909                                 {
 910                                         case "do":
 911                                         {
 912                                                 int parse_error;
 913                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 914
 915                                                 if (!caller.vote_master)
 916                                                         print_to(caller, "^1You do not have vote master privileges.");
 917                                                 else if (!VoteCommand_checknasty(vote_command))
 918                                                 {
 919                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 920                                                 }
 921                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 922                                                 {
 923                                                         if(parse_error == 0)
 924                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 925                                                 }
 926                                                 else  // everything went okay, proceed with command
 927                                                 {
 928                                                         localcmd(strcat(vote_parsed_command, "\n"));
 929                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 930                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 931                                                         if (autocvar_sv_eventlog)
 932                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 933                                                 }
 934
 935                                                 return;
 936                                         }
 937
 938                                         case "login":
 939                                         {
 940                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 941                                                 else if (caller.vote_master)
 942                                                 {
 943                                                         print_to(caller, "^1You are already logged in as vote master.");
 944                                                 }
 945                                                 else if (autocvar_sv_vote_master_password != argv(3))
 946                                                 {
 947                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 948                                                 }
 949                                                 else  // everything went okay, proceed with giving this player master privilages
 950                                                 {
 951                                                         caller.vote_master = true;
 952                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 953                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 954                                                         if (autocvar_sv_eventlog)
 955                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 956                                                 }
 957
 958                                                 return;
 959                                         }
 960
 961                                         default:  // calling a vote for master
 962                                         {
 963                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 964                                                 else if (vote_called)
 965                                                 {
 966                                                         print_to(caller, "^1There is already a vote called.");
 967                                                 }
 968                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 969                                                 {
 970                                                         print_to(caller, "^1Only players can call a vote.");
 971                                                 }
 972                                                 else if (timeout_status)
 973                                                 {
 974                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 975                                                 }
 976                                                 else  // everything went okay, continue with creating vote
 977                                                 {
 978                                                         vote_caller = caller;
 979                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 980                                                         vote_called = VOTE_MASTER;
 981                                                         vote_called_command = strzone("XXX");
 982                                                         vote_called_display = strzone("^3master");
 983                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 984
 985                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 986                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 987
 988                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 989                                                         if (autocvar_sv_eventlog)
 990                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 991                                                         Nagger_VoteChanged();
 992                                                         VoteCount(true);  // needed if you are the only one
 993                                                 }
 994
 995                                                 return;
 996                                         }
 997                                 }
 998                         }
 999                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1000
1001                         return;
1002                 }
1003
1004                 default:
1005                 case CMD_REQUEST_USAGE:
1006                 {
1007                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1008                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1009                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1010                         return;
1011                 }
1012         }
1013 }
1014
1015 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1016 {
1017         switch (request)
1018         {
1019                 case CMD_REQUEST_COMMAND:
1020                 {
1021                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1022                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1023                         {
1024                                 print_to(caller, "^1You have already voted.");
1025                         }
1026                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1027                         {
1028                                 VoteStop(caller);
1029                         }
1030
1031                         else  // everything went okay, continue changing vote
1032                         {
1033                                 print_to(caller, "^1You rejected the vote.");
1034                                 caller.vote_selection = VOTE_SELECT_REJECT;
1035                                 msg_entity = caller;
1036                                 if (!autocvar_sv_vote_singlecount)
1037                                         VoteCount(false);
1038                         }
1039
1040                         return;
1041                 }
1042
1043                 default:
1044                 case CMD_REQUEST_USAGE:
1045                 {
1046                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1047                         print_to(caller, "  No arguments required.");
1048                         return;
1049                 }
1050         }
1051 }
1052
1053 void VoteCommand_status(int request, entity caller)  // BOTH
1054 {
1055         switch (request)
1056         {
1057                 case CMD_REQUEST_COMMAND:
1058                 {
1059                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1060                         else print_to(caller, "^1No vote called.");
1061
1062                         return;
1063                 }
1064
1065                 default:
1066                 case CMD_REQUEST_USAGE:
1067                 {
1068                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1069                         print_to(caller, "  No arguments required.");
1070                         return;
1071                 }
1072         }
1073 }
1074
1075 void VoteCommand_stop(int request, entity caller)  // BOTH
1076 {
1077         switch (request)
1078         {
1079                 case CMD_REQUEST_COMMAND:
1080                 {
1081                         if (!vote_called)   print_to(caller, "^1No vote called.");
1082                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1083                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1084                         return;
1085                 }
1086
1087                 default:
1088                 case CMD_REQUEST_USAGE:
1089                 {
1090                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1091                         print_to(caller, "  No arguments required.");
1092                         return;
1093                 }
1094         }
1095 }
1096
1097 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1098 {
1099         switch (request)
1100         {
1101                 case CMD_REQUEST_COMMAND:
1102                 {
1103                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1104                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1105                         {
1106                                 print_to(caller, "^1You have already voted.");
1107                         }
1108                         else  // everything went okay, continue changing vote
1109                         {
1110                                 print_to(caller, "^1You accepted the vote.");
1111                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1112                                 msg_entity = caller;
1113                                 if (!autocvar_sv_vote_singlecount)
1114                                         VoteCount(false);
1115                         }
1116
1117                         return;
1118                 }
1119
1120                 default:
1121                 case CMD_REQUEST_USAGE:
1122                 {
1123                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1124                         print_to(caller, "  No arguments required.");
1125                         return;
1126                 }
1127         }
1128 }
1129
1130 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1131 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1132 void VoteCommand_(int request)
1133 {
1134     switch(request)
1135     {
1136         case CMD_REQUEST_COMMAND:
1137         {
1138
1139             return;
1140         }
1141
1142         default:
1143         case CMD_REQUEST_USAGE:
1144         {
1145             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1146             print_to(caller, "  No arguments required.");
1147             return;
1148         }
1149     }
1150 }
1151 */
1152
1153
1154 // ================================
1155 //  Macro system for vote commands
1156 // ================================
1157
1158 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1159 #define VOTE_COMMANDS(request, caller, arguments, command) \
1160         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1161         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1162         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1163         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1164         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1165         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1166         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1167         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1168         /* nothing */
1169
1170 void VoteCommand_macro_help(entity caller, int argc)
1171 {
1172         string command_origin = GetCommandPrefix(caller);
1173
1174         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1175         {
1176                 print_to(caller, "\nVoting commands:\n");
1177                 #define VOTE_COMMAND(name, function, description, assignment) \
1178                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1179
1180                 VOTE_COMMANDS(0, caller, 0, "");
1181 #undef VOTE_COMMAND
1182
1183                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1184                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1185                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1186         }
1187         else  // usage for individual command
1188         {
1189                 #define VOTE_COMMAND(name, function, description, assignment) \
1190                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1191
1192                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1193 #undef VOTE_COMMAND
1194
1195                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1196                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1197                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1198                 else
1199                         print_to(caller, "No documentation exists for this vote");
1200         }
1201 }
1202
1203 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1204 {
1205         #define VOTE_COMMAND(name, function, description, assignment) \
1206                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1207
1208         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1209 #undef VOTE_COMMAND
1210
1211         return false;
1212 }
1213
1214
1215 // ======================================
1216 //  Main function handling vote commands
1217 // ======================================
1218
1219 void VoteCommand(int request, entity caller, int argc, string vote_command)
1220 {
1221         // Guide for working with argc arguments by example:
1222         // argc:   1    - 2      - 3     - 4
1223         // argv:   0    - 1      - 2     - 3
1224         // cmd     vote - master - login - password
1225
1226         switch (request)
1227         {
1228                 case CMD_REQUEST_COMMAND:
1229                 {
1230                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1231                 }
1232
1233                 default:
1234                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1235                 case CMD_REQUEST_USAGE:
1236                 {
1237                         VoteCommand_macro_help(caller, argc);
1238                         return;
1239                 }
1240         }
1241 }