qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3 #include "../_all.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/mutators_include.qh"
  14
  15 #include "../../common/constants.qh"
  16 #include "../../common/mapinfo.qh"
  17 #include "../../common/notifications.qh"
  18 #include "../../common/playerstats.qh"
  19 #include "../../common/util.qh"
  20
  21 // =============================================
  22 //  Server side voting code, reworked by Samual
  23 //  Last updated: December 27th, 2011
  24 // =============================================
  25
  26 //  Nagger for players to know status of voting
  27 float Nagger_SendEntity(entity to, float sendflags)
  28 {
  29         int nags, i, f, b;
  30         entity e;
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  32
  33         // bits:
  34         //   1 = ready
  35         //   2 = player needs to ready up
  36         //   4 = vote
  37         //   8 = player needs to vote
  38         //  16 = warmup
  39         // sendflags:
  40         //  64 = vote counts
  41         // 128 = vote string
  42
  43         nags = 0;
  44         if(readycount)
  45         {
  46                 nags |= 1;
  47                 if(to.ready == 0)
  48                         nags |= 2;
  49         }
  50         if(vote_called)
  51         {
  52                 nags |= 4;
  53                 if(to.vote_selection == 0)
  54                         nags |= 8;
  55         }
  56         if(warmup_stage)
  57                 nags |= 16;
  58
  59         if(sendflags & 64)
  60                 nags |= 64;
  61
  62         if(sendflags & 128)
  63                 nags |= 128;
  64
  65         if(!(nags & 4)) // no vote called? send no string
  66                 nags &= ~(64 | 128);
  67
  68         WriteByte(MSG_ENTITY, nags);
  69
  70         if(nags & 64)
  71         {
  72                 WriteByte(MSG_ENTITY, vote_accept_count);
  73                 WriteByte(MSG_ENTITY, vote_reject_count);
  74                 WriteByte(MSG_ENTITY, vote_needed_overall);
  75                 WriteChar(MSG_ENTITY, to.vote_selection);
  76         }
  77
  78         if(nags & 128)
  79                 WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if(nags & 1)
  82         {
  83                 for(i = 1; i <= maxclients; i += 8)
  84                 {
  85                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  86                                 if(!IS_REAL_CLIENT(e) || e.ready)
  87                                         f |= b;
  88                         WriteByte(MSG_ENTITY, f);
  89                 }
  90         }
  91
  92         return true;
  93 }
  94
  95 void Nagger_Init()
  96 {
  97         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  98 }
  99
 100 void Nagger_VoteChanged()
 101 {
 102         if(nagger)
 103                 nagger.SendFlags |= 128;
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if(nagger)
 109                 nagger.SendFlags |= 64;
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if(nagger)
 115                 nagger.SendFlags |= 1;
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller))
 122                 return vote_caller.netname;
 123         return vote_caller_name;
 124 }
 125
 126 // =======================
 127 //  Game logic for voting
 128 // =======================
 129
 130 void VoteReset()
 131 {
 132         entity tmp_player;
 133
 134         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 135
 136         if(vote_called)
 137         {
 138                 strunzone(vote_called_command);
 139                 strunzone(vote_called_display);
 140                 strunzone(vote_caller_name);
 141         }
 142
 143         vote_called = VOTE_NULL;
 144         vote_caller = world;
 145         vote_caller_name = string_null;
 146         vote_endtime = 0;
 147
 148         vote_called_command = string_null;
 149         vote_called_display = string_null;
 150
 151         vote_parsed_command = string_null;
 152         vote_parsed_display = string_null;
 153
 154         Nagger_VoteChanged();
 155 }
 156
 157 void VoteStop(entity stopper)
 158 {
 159         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 160         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 161
 162         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 163         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 164
 165         VoteReset();
 166 }
 167
 168 void VoteAccept()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 171
 172         if((vote_called == VOTE_MASTER) && vote_caller)
 173                 vote_caller.vote_master = 1;
 174         else
 175                 localcmd(strcat(vote_called_command, "\n"));
 176
 177         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 178
 179         VoteReset();
 180         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 181 }
 182
 183 void VoteReject()
 184 {
 185         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 186         VoteReset();
 187         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 188 }
 189
 190 void VoteTimeout()
 191 {
 192         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 193         VoteReset();
 194         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 195 }
 196
 197 void VoteSpam(float notvoters, float mincount, string result)
 198 {
 199         bprint(strcat(
 200                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 201                 strcat("^2:^1", ftos(vote_reject_count)),
 202                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 203                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 204                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 205
 206         if(autocvar_sv_eventlog)
 207         {
 208                 GameLogEcho(strcat(
 209                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 210                         strcat(":", ftos(vote_reject_count)),
 211                         strcat(":", ftos(vote_abstain_count)),
 212                         strcat(":", ftos(notvoters)),
 213                         strcat(":", ftos(mincount))));
 214         }
 215 }
 216
 217 void VoteCount(float first_count)
 218 {
 219         // declarations
 220         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 221
 222         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 223                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 224                                 || (autocvar_sv_vote_nospectators == 0));
 225
 226         float vote_player_count = 0, notvoters = 0;
 227         float vote_real_player_count = 0, vote_real_accept_count = 0;
 228         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 229         float vote_needed_of_voted, final_needed_votes;
 230         float vote_factor_overall, vote_factor_of_voted;
 231
 232         entity tmp_player;
 233
 234         Nagger_VoteCountChanged();
 235
 236         // add up all the votes from each connected client
 237         FOR_EACH_REALCLIENT(tmp_player)
 238         {
 239                 ++vote_player_count;
 240                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 241
 242                 switch(tmp_player.vote_selection)
 243                 {
 244                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 245                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
 246                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 247                         default: break;
 248                 }
 249         }
 250
 251         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 252         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 253         {
 254                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 255                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 256                 VoteReset();
 257                 return;
 258         }
 259
 260         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 261         if(!spectators_allowed && (vote_real_player_count > 0))
 262         {
 263                 vote_accept_count = vote_real_accept_count;
 264                 vote_reject_count = vote_real_reject_count;
 265                 vote_abstain_count = vote_real_abstain_count;
 266                 vote_player_count = vote_real_player_count;
 267         }
 268
 269         // people who have no opinion in any way :D
 270         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 271
 272         // determine the goal for the vote to be passed or rejected normally
 273         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 274         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 275
 276         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 277         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 278         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 279
 280         // are there any players at all on the server? it could be an admin vote
 281         if(vote_player_count == 0 && first_count)
 282         {
 283                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         // since there ARE players, finally calculate the result of the vote
 289         if(vote_accept_count >= vote_needed_overall)
 290         {
 291                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 292                 VoteAccept();
 293                 return;
 294         }
 295
 296         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 297         {
 298                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 299                 VoteReject();
 300                 return;
 301         }
 302
 303         // there is not enough votes in either direction, now lets just calculate what the voters have said
 304         if(time > vote_endtime)
 305         {
 306                 final_needed_votes = vote_needed_overall;
 307
 308                 if(autocvar_sv_vote_majority_factor_of_voted)
 309                 {
 310                         if(vote_accept_count >= vote_needed_of_voted)
 311                         {
 312                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 313                                 VoteAccept();
 314                                 return;
 315                         }
 316
 317                         if(vote_accept_count + vote_reject_count > 0)
 318                         {
 319                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 320                                 VoteReject();
 321                                 return;
 322                         }
 323
 324                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 325                 }
 326
 327                 // it didn't pass or fail, so not enough votes to even make a decision.
 328                 VoteSpam(notvoters, final_needed_votes, "timeout");
 329                 VoteTimeout();
 330         }
 331 }
 332
 333 void VoteThink()
 334 {
 335         if(vote_endtime > 0) // a vote was called
 336         if(time > vote_endtime) // time is up
 337         {
 338                 VoteCount(false);
 339         }
 340
 341         return;
 342 }
 343
 344
 345 // =======================
 346 //  Game logic for warmup
 347 // =======================
 348
 349 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 350 void reset_map(float dorespawn)
 351 {
 352         entity oldself;
 353         oldself = self;
 354
 355         if(time <= game_starttime && round_handler_IsActive())
 356                 round_handler_Reset(game_starttime);
 357
 358         MUTATOR_CALLHOOK(reset_map_global);
 359
 360         // ALL the times need to be reset before .reset()ing each item
 361         // since Item_Reset schedules respawn of superweapons and powerups
 362         for(self = world; (self = nextent(self)); )
 363         if(IS_NOT_A_CLIENT(self))
 364         {
 365                 if(self.reset)
 366                         Item_ItemsTime_SetTime(self, 0);
 367         }
 368
 369         for(self = world; (self = nextent(self)); )
 370         if(IS_NOT_A_CLIENT(self))
 371         {
 372                 if(self.reset)
 373                 {
 374                         self.reset();
 375                         continue;
 376                 }
 377
 378                 if(self.team_saved)
 379                         self.team = self.team_saved;
 380
 381                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
 382                         remove(self);
 383         }
 384
 385         // Waypoints and assault start come LAST
 386         for(self = world; (self = nextent(self)); )
 387         if(IS_NOT_A_CLIENT(self))
 388         {
 389                 if(self.reset2)
 390                 {
 391                         self.reset2();
 392                         continue;
 393                 }
 394         }
 395
 396         Item_ItemsTime_SetTimesForAllPlayers();
 397
 398         FOR_EACH_PLAYER(self)
 399         if(self.frozen)
 400                 Unfreeze(self);
 401
 402         // Moving the player reset code here since the player-reset depends
 403         // on spawnpoint entities which have to be reset first --blub
 404         if(dorespawn)
 405         if(!MUTATOR_CALLHOOK(reset_map_players))
 406         FOR_EACH_CLIENT(self) // reset all players
 407         {
 408                 /*
 409                 only reset players if a restart countdown is active
 410                 this can either be due to cvar sv_ready_restart_after_countdown having set
 411                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 412                 sv_ready_restart_after_countdown is not used and countdown is still running
 413                 */
 414                 if (restart_mapalreadyrestarted || (time < game_starttime))
 415                 {
 416                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 417                         if (IS_PLAYER(self)) {
 418                                 //PlayerScore_Clear(self);
 419                                 self.killcount = 0;
 420                                 //stop the player from moving so that he stands still once he gets respawned
 421                                 self.velocity = '0 0 0';
 422                                 self.avelocity = '0 0 0';
 423                                 self.movement = '0 0 0';
 424                                 PutClientInServer();
 425                         }
 426                 }
 427         }
 428
 429         if(g_keyhunt)
 430                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 431
 432         self = oldself;
 433 }
 434
 435 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 436 void ReadyRestart_think()
 437 {
 438         restart_mapalreadyrestarted = 1;
 439         reset_map(true);
 440         Score_ClearAll();
 441         remove(self);
 442
 443         return;
 444 }
 445
 446 // Forces a restart of the game without actually reloading the map // this is a mess...
 447 void ReadyRestart_force()
 448 {
 449         entity tmp_player, restart_timer;
 450
 451         bprint("^1Server is restarting...\n");
 452
 453         VoteReset();
 454
 455         // clear overtime, we have to decrease timelimit to its original value again.
 456         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 457
 458         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 459
 460         readyrestart_happened = 1;
 461         game_starttime = time + RESTART_COUNTDOWN;
 462
 463         // clear player attributes
 464         FOR_EACH_CLIENT(tmp_player)
 465         {
 466                 tmp_player.alivetime = 0;
 467                 tmp_player.killcount = 0;
 468                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 469         }
 470
 471         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 472
 473         // disable the warmup global for the server
 474         warmup_stage = 0; // once the game is restarted the game is in match stage
 475
 476         // reset the .ready status of all players (also spectators)
 477         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 478         readycount = 0;
 479         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 480
 481         // lock teams with lockonrestart
 482         if(autocvar_teamplay_lockonrestart && teamplay)
 483         {
 484                 lockteams = 1;
 485                 bprint("^1The teams are now locked.\n");
 486         }
 487
 488         //initiate the restart-countdown-announcer entity
 489         if(autocvar_sv_ready_restart_after_countdown)
 490         {
 491                 restart_timer = spawn();
 492                 restart_timer.think = ReadyRestart_think;
 493                 restart_timer.nextthink = game_starttime;
 494         }
 495
 496         // after a restart every players number of allowed timeouts gets reset, too
 497         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 498
 499         //reset map immediately if this cvar is not set
 500         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
 501
 502         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 503 }
 504
 505 void ReadyRestart()
 506 {
 507         // no arena, assault support yet...
 508         if(g_assault | gameover | intermission_running | race_completing)
 509                 localcmd("restart\n");
 510         else
 511                 localcmd("\nsv_hook_gamerestart\n");
 512
 513         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 514         // Otherwise scores could be manipulated during the countdown.
 515         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 516
 517         ReadyRestart_force();
 518
 519         return;
 520 }
 521
 522 // Count the players who are ready and determine whether or not to restart the match
 523 void ReadyCount()
 524 {
 525         entity tmp_player;
 526         float ready_needed_factor, ready_needed_count;
 527         float t_ready = 0, t_players = 0;
 528
 529         FOR_EACH_REALCLIENT(tmp_player)
 530         {
 531                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 532                 {
 533                         ++t_players;
 534                         if(tmp_player.ready) { ++t_ready; }
 535                 }
 536         }
 537
 538         readycount = t_ready;
 539
 540         Nagger_ReadyCounted();
 541
 542         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 543         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 544
 545         if(readycount >= ready_needed_count)
 546         {
 547                 ReadyRestart();
 548         }
 549
 550         return;
 551 }
 552
 553
 554 // ======================================
 555 //  Supporting functions for VoteCommand
 556 // ======================================
 557
 558 float Votecommand_check_assignment(entity caller, float assignment)
 559 {
 560         float from_server = (!caller);
 561
 562         if((assignment == VC_ASGNMNT_BOTH)
 563                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 564                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 565         {
 566                 return true;
 567         }
 568
 569         return false;
 570 }
 571
 572 string VoteCommand_extractcommand(string input, float startpos, float argc)
 573 {
 574         string output;
 575
 576         if((argc - 1) < startpos)
 577                 output = "";
 578         else
 579                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 580
 581         return output;
 582 }
 583
 584 float VoteCommand_checknasty(string vote_command)
 585 {
 586         if((strstrofs(vote_command, ";", 0) >= 0)
 587                 || (strstrofs(vote_command, "\n", 0) >= 0)
 588                 || (strstrofs(vote_command, "\r", 0) >= 0)
 589                 || (strstrofs(vote_command, "$", 0) >= 0))
 590                 return false;
 591
 592         return true;
 593 }
 594
 595 float VoteCommand_checkinlist(string vote_command, string list)
 596 {
 597         string l = strcat(" ", list, " ");
 598
 599         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 600                 return true;
 601
 602         return false;
 603 }
 604
 605 string ValidateMap(string validated_map, entity caller)
 606 {
 607         validated_map = MapInfo_FixName(validated_map);
 608
 609         if (!validated_map)
 610         {
 611                 print_to(caller, "This map is not available on this server.");
 612                 return string_null;
 613         }
 614
 615         if(!autocvar_sv_vote_override_mostrecent && caller)
 616         {
 617                 if(Map_IsRecent(validated_map))
 618                 {
 619                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 620                         return string_null;
 621                 }
 622         }
 623
 624         if(!MapInfo_CheckMap(validated_map))
 625         {
 626                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 627                 return string_null;
 628         }
 629
 630         return validated_map;
 631 }
 632
 633 float VoteCommand_checkargs(float startpos, float argc)
 634 {
 635         float p, q, check, minargs;
 636         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 637         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 638         string charlist, arg;
 639         float checkmate;
 640
 641         if(cmdrestriction == "")
 642                 return true;
 643
 644         ++startpos; // skip command name
 645
 646         // check minimum arg count
 647
 648         // 0 args: argc == startpos
 649         // 1 args: argc == startpos + 1
 650         // ...
 651
 652         minargs = stof(cmdrestriction);
 653         if(argc - startpos < minargs)
 654                 return false;
 655
 656         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 657
 658         for (;;)
 659         {
 660                 // we know that at any time, startpos <= argc - minargs
 661                 // so this means: argc-minargs >= startpos >= argc, thus
 662                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 663                 // have been seen already
 664
 665                 if(startpos >= argc) // all args checked? GOOD
 666                         break;
 667
 668                 if(p < 0) // no more args? FAIL
 669                 {
 670                         // exception: exactly minargs left, this one included
 671                         if(argc - startpos == minargs)
 672                                 break;
 673
 674                         // otherwise fail
 675                         return false;
 676                 }
 677
 678                 // cut to next semicolon
 679                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 680                 if(q < 0)
 681                         charlist = substring(cmdrestriction, p+1, -1);
 682                 else
 683                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 684
 685                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 686                 // charlist = strreplace("^^", ";", charlist);
 687
 688                 if(charlist != "")
 689                 {
 690                         // verify the arg only contains allowed chars
 691                         arg = argv(startpos);
 692                         checkmate = strlen(arg);
 693                         for(check = 0; check < checkmate; ++check)
 694                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 695                                         return false; // not allowed character
 696                         // all characters are allowed. FINE.
 697                 }
 698
 699                 ++startpos;
 700                 --minargs;
 701                 p = q;
 702         }
 703
 704         return true;
 705 }
 706
 707 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 708 {
 709         string first_command;
 710
 711         first_command = argv(startpos);
 712
 713         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 714                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 715                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 716         );*/
 717
 718         if(
 719                 (autocvar_sv_vote_limit > 0)
 720                 &&
 721                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 722         )
 723                 return false;
 724
 725         if (!VoteCommand_checkinlist(first_command, vote_list))
 726                 return false;
 727
 728         if (!VoteCommand_checkargs(startpos, argc))
 729                 return false;
 730
 731         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 732         {
 733                 case "kick":
 734                 case "kickban": // catch all kick/kickban commands
 735                 {
 736                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 737                         float accepted = VerifyClientEntity(victim, true, false);
 738
 739                         if(accepted > 0)
 740                         {
 741                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 742                                 string command_arguments;
 743
 744                                 if(first_command == "kickban")
 745                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 746                                 else
 747                                         command_arguments = reason;
 748
 749                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 750                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 751                         }
 752                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 753
 754                         break;
 755                 }
 756
 757                 case "map":
 758                 case "chmap":
 759                 case "gotomap": // re-direct all map selection commands to gotomap
 760                 {
 761                         vote_command = ValidateMap(argv(startpos + 1), caller);
 762                         if (!vote_command) { return false; }
 763                         vote_parsed_command = strcat("gotomap ", vote_command);
 764                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 765
 766                         break;
 767                 }
 768
 769                 default:
 770                 {
 771                         vote_parsed_command = vote_command;
 772                         vote_parsed_display = strzone(strcat("^1", vote_command));
 773
 774                         break;
 775                 }
 776         }
 777
 778         return true;
 779 }
 780
 781
 782 // =======================
 783 //  Command Sub-Functions
 784 // =======================
 785
 786 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 787 {
 788         switch(request)
 789         {
 790                 case CMD_REQUEST_COMMAND:
 791                 {
 792                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 793                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 794
 795                         else // everything went okay, continue changing vote
 796                         {
 797                                 print_to(caller, "^1You abstained from your vote.");
 798                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 799                                 msg_entity = caller;
 800                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 801                         }
 802
 803                         return;
 804                 }
 805
 806                 default:
 807                 case CMD_REQUEST_USAGE:
 808                 {
 809                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 810                         print_to(caller, "  No arguments required.");
 811                         return;
 812                 }
 813         }
 814 }
 815
 816 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 817 {
 818         switch(request)
 819         {
 820                 case CMD_REQUEST_COMMAND:
 821                 {
 822                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 823                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 824                                 || (autocvar_sv_vote_nospectators == 0));
 825
 826                         float tmp_playercount = 0;
 827                         entity tmp_player;
 828
 829                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 830
 831                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 832                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 833                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 834                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 835                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
 836                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 837                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 838                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 839                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 840
 841                         else // everything went okay, continue with calling the vote
 842                         {
 843                                 vote_caller = caller; // remember who called the vote
 844                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 845                                 vote_called = VOTE_NORMAL;
 846                                 vote_called_command = strzone(vote_parsed_command);
 847                                 vote_called_display = strzone(vote_parsed_display);
 848                                 vote_endtime = time + autocvar_sv_vote_timeout;
 849
 850                                 if(caller)
 851                                 {
 852                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 853                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 854                                         msg_entity = caller;
 855                                 }
 856
 857                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 858                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 859
 860                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 861                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 862                                 Nagger_VoteChanged();
 863                                 VoteCount(true); // needed if you are the only one
 864                         }
 865
 866                         return;
 867                 }
 868
 869                 default:
 870                 case CMD_REQUEST_USAGE:
 871                 {
 872                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 873                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 874                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 875                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 876                         return;
 877                 }
 878         }
 879 }
 880
 881 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 882 {
 883         switch(request)
 884         {
 885                 case CMD_REQUEST_COMMAND:
 886                 {
 887                         if(autocvar_sv_vote_master)
 888                         {
 889                                 switch(strtolower(argv(2)))
 890                                 {
 891                                         case "do":
 892                                         {
 893                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 894
 895                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 896                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 897                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 898
 899                                                 else // everything went okay, proceed with command
 900                                                 {
 901                                                         localcmd(strcat(vote_parsed_command, "\n"));
 902                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 903                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 904                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 905                                                 }
 906
 907                                                 return;
 908                                         }
 909
 910                                         case "login":
 911                                         {
 912                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 913                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 914                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 915
 916                                                 else // everything went okay, proceed with giving this player master privilages
 917                                                 {
 918                                                         caller.vote_master = true;
 919                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 920                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 921                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 922                                                 }
 923
 924                                                 return;
 925                                         }
 926
 927                                         default: // calling a vote for master
 928                                         {
 929                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 930                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 931                                                         || (autocvar_sv_vote_nospectators == 0));
 932
 933                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 934                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 935                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 936                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 937
 938                                                 else // everything went okay, continue with creating vote
 939                                                 {
 940                                                         vote_caller = caller;
 941                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 942                                                         vote_called = VOTE_MASTER;
 943                                                         vote_called_command = strzone("XXX");
 944                                                         vote_called_display = strzone("^3master");
 945                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 946
 947                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 948                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 949
 950                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 951                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 952                                                         Nagger_VoteChanged();
 953                                                         VoteCount(true); // needed if you are the only one
 954                                                 }
 955
 956                                                 return;
 957                                         }
 958                                 }
 959                         }
 960                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 961
 962                         return;
 963                 }
 964
 965                 default:
 966                 case CMD_REQUEST_USAGE:
 967                 {
 968                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 969                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 970                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 971                         return;
 972                 }
 973         }
 974 }
 975
 976 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 977 {
 978         switch(request)
 979         {
 980                 case CMD_REQUEST_COMMAND:
 981                 {
 982                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 983                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 984                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 985
 986                         else // everything went okay, continue changing vote
 987                         {
 988                                 print_to(caller, "^1You rejected the vote.");
 989                                 caller.vote_selection = VOTE_SELECT_REJECT;
 990                                 msg_entity = caller;
 991                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 992                         }
 993
 994                         return;
 995                 }
 996
 997                 default:
 998                 case CMD_REQUEST_USAGE:
 999                 {
1000                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1001                         print_to(caller, "  No arguments required.");
1002                         return;
1003                 }
1004         }
1005 }
1006
1007 void VoteCommand_status(float request, entity caller) // BOTH
1008 {
1009         switch(request)
1010         {
1011                 case CMD_REQUEST_COMMAND:
1012                 {
1013                         if(vote_called)
1014                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1015                         else
1016                                 print_to(caller, "^1No vote called.");
1017
1018                         return;
1019                 }
1020
1021                 default:
1022                 case CMD_REQUEST_USAGE:
1023                 {
1024                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1025                         print_to(caller, "  No arguments required.");
1026                         return;
1027                 }
1028         }
1029 }
1030
1031 void VoteCommand_stop(float request, entity caller) // BOTH
1032 {
1033         switch(request)
1034         {
1035                 case CMD_REQUEST_COMMAND:
1036                 {
1037                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1038                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1039                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1040
1041                         return;
1042                 }
1043
1044                 default:
1045                 case CMD_REQUEST_USAGE:
1046                 {
1047                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1048                         print_to(caller, "  No arguments required.");
1049                         return;
1050                 }
1051         }
1052 }
1053
1054 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1055 {
1056         switch(request)
1057         {
1058                 case CMD_REQUEST_COMMAND:
1059                 {
1060                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1061                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1062
1063                         else // everything went okay, continue changing vote
1064                         {
1065                                 print_to(caller, "^1You accepted the vote.");
1066                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1067                                 msg_entity = caller;
1068                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1069                         }
1070
1071                         return;
1072                 }
1073
1074                 default:
1075                 case CMD_REQUEST_USAGE:
1076                 {
1077                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1078                         print_to(caller, "  No arguments required.");
1079                         return;
1080                 }
1081         }
1082 }
1083
1084 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1085 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1086 void VoteCommand_(float request)
1087 {
1088         switch(request)
1089         {
1090                 case CMD_REQUEST_COMMAND:
1091                 {
1092
1093                         return;
1094                 }
1095
1096                 default:
1097                 case CMD_REQUEST_USAGE:
1098                 {
1099                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1100                         print_to(caller, "  No arguments required.");
1101                         return;
1102                 }
1103         }
1104 }
1105 */
1106
1107
1108 // ================================
1109 //  Macro system for vote commands
1110 // ================================
1111
1112 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1113 #define VOTE_COMMANDS(request,caller,arguments,command) \
1114         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1115         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1116         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1117         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1118         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1119         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1120         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1121         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1122         /* nothing */
1123
1124 void VoteCommand_macro_help(entity caller, float argc)
1125 {
1126         string command_origin = GetCommandPrefix(caller);
1127
1128         if(argc == 2 || argv(2) == "help") // help display listing all commands
1129         {
1130                 print_to(caller, "\nVoting commands:\n");
1131                 #define VOTE_COMMAND(name,function,description,assignment) \
1132                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1133
1134                 VOTE_COMMANDS(0, caller, 0, "");
1135                 #undef VOTE_COMMAND
1136
1137                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1138                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1139                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1140         }
1141         else // usage for individual command
1142         {
1143                 #define VOTE_COMMAND(name,function,description,assignment) \
1144                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1145
1146                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1147                 #undef VOTE_COMMAND
1148         }
1149
1150         return;
1151 }
1152
1153 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1154 {
1155         #define VOTE_COMMAND(name,function,description,assignment) \
1156                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1157
1158         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1159         #undef VOTE_COMMAND
1160
1161         return false;
1162 }
1163
1164
1165 // ======================================
1166 //  Main function handling vote commands
1167 // ======================================
1168
1169 void VoteCommand(float request, entity caller, float argc, string vote_command)
1170 {
1171         // Guide for working with argc arguments by example:
1172         // argc:   1    - 2      - 3     - 4
1173         // argv:   0    - 1      - 2     - 3
1174         // cmd     vote - master - login - password
1175
1176         switch(request)
1177         {
1178                 case CMD_REQUEST_COMMAND:
1179                 {
1180                         if(VoteCommand_macro_command(caller, argc, vote_command))
1181                                 return;
1182                 }
1183
1184                 default:
1185                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1186                 case CMD_REQUEST_USAGE:
1187                 {
1188                         VoteCommand_macro_help(caller, argc);
1189                         return;
1190                 }
1191         }
1192 }