qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/effects/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/monsters/sv_monsters.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/teams.qh>
  11 #include <common/util.qh>
  12 #include <server/anticheat.qh>
  13 #include <server/bot/api.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/_mod.qh>
  17 #include <server/command/banning.qh>
  18 #include <server/command/cmd.qh>
  19 #include <server/command/common.qh>
  20 #include <server/command/getreplies.qh>
  21 #include <server/command/radarmap.qh>
  22 #include <server/intermission.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mapvoting.qh>
  25 #include <server/mutators/_mod.qh>
  26 #include <server/player.qh>
  27 #include <server/scores_rules.qh>
  28 #include <server/teamplay.qh>
  29 #include <server/world.qh>
  30
  31 //  used by GameCommand_make_mapinfo()
  32 void make_mapinfo_Think(entity this)
  33 {
  34         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  35         {
  36                 LOG_INFO("Done rebuiling mapinfos.");
  37                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  38                 delete(this);
  39         }
  40         else
  41         {
  42                 setthink(this, make_mapinfo_Think);
  43                 this.nextthink = time;
  44         }
  45 }
  46
  47 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  48 void changematchtime(float delta, float mi, float ma)
  49 {
  50         float cur;
  51         float update;
  52         float lim;
  53
  54         if (delta == 0) return;
  55         if (autocvar_timelimit < 0) return;
  56
  57         if (mi <= 10) mi = 10;  // at least ten sec in the future
  58         cur = time - game_starttime;
  59         if (cur > 0) mi += cur; // from current time!
  60
  61         lim = autocvar_timelimit * 60;
  62
  63         if (delta > 0)
  64         {
  65                 if (lim == 0) return; // cannot increase any further
  66                 else if (lim < ma) update = min(ma, lim + delta);
  67                 else                  // already above maximum: FAIL
  68                         return;
  69         }
  70         else
  71         {
  72                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  73                         update = max(mi, ma);
  74                 else if (lim > mi) // above minimum: decrease
  75                         update = max(mi, lim + delta);
  76                 else               // already below minimum: FAIL
  77                         return;
  78         }
  79
  80         cvar_set("timelimit", ftos(update / 60));
  81 }
  82
  83
  84 // =======================
  85 //  Command Sub-Functions
  86 // =======================
  87
  88 void GameCommand_adminmsg(int request, int argc)
  89 {
  90         switch (request)
  91         {
  92                 case CMD_REQUEST_COMMAND:
  93                 {
  94                         if (!world_initialized)
  95                         {
  96                                 LOG_HELPF("This command works only when the server is running.");
  97                                 return;
  98                         }
  99                         entity client;
 100                         float accepted;
 101
 102                         string targets = strreplace(",", " ", argv(1));
 103                         string original_targets = strreplace(" ", ", ", targets);
 104                         string admin_message = argv(2);
 105                         float infobartime = stof(argv(3));
 106
 107                         string successful, t;
 108                         successful = string_null;
 109
 110                         if ((targets) && (admin_message))
 111                         {
 112                                 for ( ; targets; )
 113                                 {
 114                                         t = car(targets);
 115                                         targets = cdr(targets);
 116
 117                                         // Check to see if the player is a valid target
 118                                         client = GetFilteredEntity(t);
 119                                         accepted = VerifyClientEntity(client, true, false);
 120
 121                                         if (accepted <= 0)
 122                                         {
 123                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 124                                                 continue;
 125                                         }
 126
 127                                         // send the centerprint/console print or infomessage
 128                                         if (infobartime)
 129                                         {
 130                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 131                                         }
 132                                         else
 133                                         {
 134                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 135                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 136                                         }
 137
 138                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
 139                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
 140                                         continue;
 141                                 }
 142
 143                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 144                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 145
 146                                 return;
 147                         }
 148                 }
 149
 150                 default:
 151                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 152                 case CMD_REQUEST_USAGE:
 153                 {
 154                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
 155                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
 156                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
 157                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 158                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 159                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 160                         return;
 161                 }
 162         }
 163 }
 164
 165 void GameCommand_allready(int request)
 166 {
 167         switch (request)
 168         {
 169                 case CMD_REQUEST_COMMAND:
 170                 {
 171                         if (!world_initialized)
 172                         {
 173                                 LOG_HELPF("This command works only when the server is running.");
 174                                 return;
 175                         }
 176                         if(warmup_stage)
 177                         {
 178                                 ReadyRestart(true);
 179                         }
 180                         else
 181                                 LOG_INFO("Not in warmup.");
 182
 183                         return;
 184                 }
 185
 186                 default:
 187                 case CMD_REQUEST_USAGE:
 188                 {
 189                         LOG_HELP("Usage:^3 sv_cmd allready");
 190                         LOG_HELP("  No arguments required.");
 191                         return;
 192                 }
 193         }
 194 }
 195
 196 void GameCommand_allspec(int request, int argc)
 197 {
 198         switch (request)
 199         {
 200                 case CMD_REQUEST_COMMAND:
 201                 {
 202                         if (!world_initialized)
 203                         {
 204                                 LOG_HELPF("This command works only when the server is running.");
 205                                 return;
 206                         }
 207                         string reason = argv(1);
 208                         int n = 0;
 209                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 210                                 PutObserverInServer(it, true, true);
 211                                 ++n;
 212                         });
 213                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 214                         else   LOG_INFO("No players found to spectate.");
 215                         return;
 216                 }
 217
 218                 default:
 219                 case CMD_REQUEST_USAGE:
 220                 {
 221                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
 222                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
 223                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void GameCommand_anticheat(int request, int argc)
 230 {
 231         switch (request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         if (!world_initialized)
 236                         {
 237                                 LOG_HELPF("This command works only when the server is running.");
 238                                 return;
 239                         }
 240                         entity client = GetIndexedEntity(argc, 1);
 241                         float accepted = VerifyClientEntity(client, false, false);
 242
 243                         if (accepted > 0)
 244                         {
 245                                 anticheat_report_to_eventlog(client);
 246                                 return;
 247                         }
 248                         else
 249                         {
 250                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 251                         }
 252                 }
 253
 254                 default:
 255                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 256                 case CMD_REQUEST_USAGE:
 257                 {
 258                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
 259                         LOG_HELP("  <client> is the entity number or name of the player.");
 260                         return;
 261                 }
 262         }
 263 }
 264
 265 void GameCommand_bbox(int request)
 266 {
 267         switch (request)
 268         {
 269                 case CMD_REQUEST_COMMAND:
 270                 {
 271                         vector size_min = '0 0 0';
 272                         vector size_max = '0 0 0';
 273                         tracebox('1 0 0' * world.absmin.x,
 274                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 275                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 276                                 '1 0 0' * world.absmax.x,
 277                                 MOVE_WORLDONLY,
 278                                 NULL);
 279                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 280
 281                         tracebox('0 1 0' * world.absmin.y,
 282                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 283                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 284                                 '0 1 0' * world.absmax.y,
 285                                 MOVE_WORLDONLY,
 286                                 NULL);
 287                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 288
 289                         tracebox('0 0 1' * world.absmin.z,
 290                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 291                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 292                                 '0 0 1' * world.absmax.z,
 293                                 MOVE_WORLDONLY,
 294                                 NULL);
 295                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 296
 297                         tracebox('1 0 0' * world.absmax.x,
 298                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 299                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 300                                 '1 0 0' * world.absmin.x,
 301                                 MOVE_WORLDONLY,
 302                                 NULL);
 303                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 304
 305                         tracebox('0 1 0' * world.absmax.y,
 306                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 307                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 308                                 '0 1 0' * world.absmin.y,
 309                                 MOVE_WORLDONLY,
 310                                 NULL);
 311                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 312
 313                         tracebox('0 0 1' * world.absmax.z,
 314                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 315                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 316                                 '0 0 1' * world.absmin.z,
 317                                 MOVE_WORLDONLY,
 318                                 NULL);
 319                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 320
 321                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 322                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 323                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 324                         return;
 325                 }
 326
 327                 default:
 328                 case CMD_REQUEST_USAGE:
 329                 {
 330                         LOG_HELP("Usage:^3 sv_cmd bbox");
 331                         LOG_HELP("  No arguments required.");
 332                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 333                         return;
 334                 }
 335         }
 336 }
 337
 338 void GameCommand_bot_cmd(int request, int argc, string command)
 339 {
 340         switch (request)
 341         {
 342                 case CMD_REQUEST_COMMAND:
 343                 {
 344                         if (!world_initialized)
 345                         {
 346                                 LOG_HELPF("This command works only when the server is running.");
 347                                 return;
 348                         }
 349                         entity bot;
 350
 351                         if (argv(1) == "reset")
 352                         {
 353                                 bot_resetqueues();
 354                                 return;
 355                         }
 356                         else if (argv(1) == "setbots")
 357                         {
 358                                 cvar_settemp("bot_vs_human", "0");
 359                                 cvar_settemp("minplayers", "0");
 360                                 cvar_settemp("minplayers_per_team", "0");
 361                                 cvar_settemp("bot_number", "0");
 362                                 bot_fixcount(false);  // Kill all bots.
 363                                 cvar_settemp("bot_number", argv(2));
 364                                 if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
 365                                 return;
 366                         }
 367                         else if (argv(1) == "load" && argc == 3)
 368                         {
 369                                 float fh, i;
 370                                 string s;
 371                                 fh = fopen(argv(2), FILE_READ);
 372                                 if (fh < 0)
 373                                 {
 374                                         LOG_INFO("cannot open the file");
 375                                         return;
 376                                 }
 377
 378                                 i = 0;
 379                                 while ((s = fgets(fh)))
 380                                 {
 381                                         argc = tokenize_console(s);
 382
 383                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 384                                         {
 385                                                 if (argv(2) == "reset")
 386                                                 {
 387                                                         bot_resetqueues();
 388                                                 }
 389                                                 else if (argv(2) == "setbots")
 390                                                 {
 391                                                         cvar_settemp("bot_vs_human", "0");
 392                                                         cvar_settemp("minplayers", "0");
 393                                                         cvar_settemp("minplayers_per_team", "0");
 394                                                         cvar_settemp("bot_number", "0");
 395                                                         bot_fixcount(false);  // Kill all bots.
 396                                                         cvar_settemp("bot_number", argv(3));
 397                                                         if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
 398                                                 }
 399                                                 else
 400                                                 {
 401                                                         if(argv(2) == "*" || argv(2) == "all")
 402                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 403                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 404                                                                 });
 405                                                         else
 406                                                         {
 407                                                                 bot = find_bot_by_number(stof(argv(2)));
 408                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 409                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 410                                                         }
 411                                                 }
 412                                         }
 413                                         else
 414                                         {
 415                                                 localcmd(strcat(s, "\n"));
 416                                         }
 417
 418                                         ++i;
 419                                 }
 420                                 LOG_INFO(ftos(i), " commands read");
 421                                 fclose(fh);
 422                                 return;
 423                         }
 424                         else if (argv(1) == "help")
 425                         {
 426                                 if (argv(2)) bot_cmdhelp(argv(2));
 427                                 else bot_list_commands();
 428                                 return;
 429                         }
 430                         else if (argc >= 3)  // this comes last
 431                         {
 432                                 if(argv(1) == "*" || argv(1) == "all")
 433                                 {
 434                                         int bot_num = 0;
 435                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 436                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 437                                                 bot_num++;
 438                                         });
 439                                         if(bot_num)
 440                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 441                                         return;
 442                                 }
 443                                 else
 444                                 {
 445                                         bot = find_bot_by_number(stof(argv(1)));
 446                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 447                                         if (bot)
 448                                         {
 449                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 450                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 451                                                 return;
 452                                         }
 453                                         else
 454                                         {
 455                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 456                                         }
 457                                 }
 458                         }
 459                 }
 460
 461                 default:
 462                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 463                 case CMD_REQUEST_USAGE:
 464                 {
 465                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
 466                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
 467                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 468                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
 469                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc say something");
 470                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 471                         LOG_HELP("          sv_cmd bot_cmd * pause");
 472                         return;
 473                 }
 474         }
 475 }
 476
 477 void GameCommand_cointoss(int request, int argc)
 478 {
 479         switch (request)
 480         {
 481                 case CMD_REQUEST_COMMAND:
 482                 {
 483                         if (!world_initialized)
 484                         {
 485                                 LOG_HELPF("This command works only when the server is running.");
 486                                 return;
 487                         }
 488                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 489                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 490                         string choice = ((random() > 0.5) ? result1 : result2);
 491
 492                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 493                         return;
 494                 }
 495
 496                 default:
 497                 case CMD_REQUEST_USAGE:
 498                 {
 499                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
 500                         LOG_HELP("  Where <result1> and <result2> are user created options.");
 501                         return;
 502                 }
 503         }
 504 }
 505
 506 void GameCommand_database(int request, int argc)
 507 {
 508         switch (request)
 509         {
 510                 case CMD_REQUEST_COMMAND:
 511                 {
 512                         if (argc == 3)
 513                         {
 514                                 if (argv(1) == "save")
 515                                 {
 516                                         db_save(ServerProgsDB, argv(2));
 517                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 518                                         return;
 519                                 }
 520                                 else if (argv(1) == "dump")
 521                                 {
 522                                         db_dump(ServerProgsDB, argv(2));
 523                                         LOG_INFO("DB dumped.");  // wtf does this do?
 524                                         return;
 525                                 }
 526                                 else if (argv(1) == "load")
 527                                 {
 528                                         db_close(ServerProgsDB);
 529                                         ServerProgsDB = db_load(argv(2));
 530                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 531                                         return;
 532                                 }
 533                         }
 534                 }
 535
 536                 default:
 537                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 538                 case CMD_REQUEST_USAGE:
 539                 {
 540                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
 541                         LOG_HELP("  Where <action> is the command to complete,");
 542                         LOG_HELP("  and <filename> is what it acts upon.");
 543                         LOG_HELP("  Full list of commands here: save, dump, load.");
 544                         return;
 545                 }
 546         }
 547 }
 548
 549 void GameCommand_defer_clear(int request, int argc)
 550 {
 551         switch (request)
 552         {
 553                 case CMD_REQUEST_COMMAND:
 554                 {
 555                         if (!world_initialized)
 556                         {
 557                                 LOG_HELPF("This command works only when the server is running.");
 558                                 return;
 559                         }
 560                         entity client;
 561                         float accepted;
 562
 563                         if (argc >= 2)
 564                         {
 565                                 client = GetIndexedEntity(argc, 1);
 566                                 accepted = VerifyClientEntity(client, true, false);
 567
 568                                 if (accepted > 0)
 569                                 {
 570                                         stuffcmd(client, "defer clear\n");
 571                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
 572                                 }
 573                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 574
 575                                 return;
 576                         }
 577                 }
 578
 579                 default:
 580                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 581                 case CMD_REQUEST_USAGE:
 582                 {
 583                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
 584                         LOG_HELP("  <client> is the entity number or name of the player.");
 585                         LOG_HELP("See also: ^2defer_clear_all^7");
 586                         return;
 587                 }
 588         }
 589 }
 590
 591 void GameCommand_defer_clear_all(int request)
 592 {
 593         switch (request)
 594         {
 595                 case CMD_REQUEST_COMMAND:
 596                 {
 597                         if (!world_initialized)
 598                         {
 599                                 LOG_HELPF("This command works only when the server is running.");
 600                                 return;
 601                         }
 602                         int n = 0;
 603                         int argc;
 604
 605                         FOREACH_CLIENT(true, {
 606                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 607                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 608                                 ++n;
 609                         });
 610                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 611                         return;
 612                 }
 613
 614                 default:
 615                 case CMD_REQUEST_USAGE:
 616                 {
 617                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 618                         LOG_HELP("  No arguments required.");
 619                         LOG_HELP("See also: ^2defer_clear^7");
 620                         return;
 621                 }
 622         }
 623 }
 624
 625 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 626 {
 627         switch (request)
 628         {
 629                 case CMD_REQUEST_COMMAND:
 630                 {
 631                         if (argv(1))
 632                         {
 633                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 634                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 635                                 return;
 636                         }
 637                 }
 638
 639                 default:
 640                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 641                 case CMD_REQUEST_USAGE:
 642                 {
 643                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
 644                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
 645                         LOG_HELP("  it will clear all records up to nth place.");
 646                         LOG_HELP("  if <map> is not provided it will use current map.");
 647                         return;
 648                 }
 649         }
 650 }
 651
 652 void print_Effect_Index(int d, string effect_name)
 653 {
 654         // this is inside a function to avoid expanding it on compilation everytime
 655         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 656         db_put(d, effect_name, "1");
 657 }
 658
 659 void GameCommand_effectindexdump(int request)
 660 {
 661         switch (request)
 662         {
 663                 case CMD_REQUEST_COMMAND:
 664                 {
 665                         float fh, d;
 666                         string s;
 667
 668                         d = db_create();
 669                         LOG_INFO("begin of effects list");
 670
 671                         print_Effect_Index(d, "TE_GUNSHOT");
 672                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 673                         print_Effect_Index(d, "TE_SPIKE");
 674                         print_Effect_Index(d, "TE_SPIKEQUAD");
 675                         print_Effect_Index(d, "TE_SUPERSPIKE");
 676                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 677                         print_Effect_Index(d, "TE_WIZSPIKE");
 678                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 679                         print_Effect_Index(d, "TE_EXPLOSION");
 680                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 681                         print_Effect_Index(d, "TE_TAREXPLOSION");
 682                         print_Effect_Index(d, "TE_TELEPORT");
 683                         print_Effect_Index(d, "TE_LAVASPLASH");
 684                         print_Effect_Index(d, "TE_SMALLFLASH");
 685                         print_Effect_Index(d, "TE_FLAMEJET");
 686                         print_Effect_Index(d, "EF_FLAME");
 687                         print_Effect_Index(d, "TE_BLOOD");
 688                         print_Effect_Index(d, "TE_SPARK");
 689                         print_Effect_Index(d, "TE_PLASMABURN");
 690                         print_Effect_Index(d, "TE_TEI_G3");
 691                         print_Effect_Index(d, "TE_TEI_SMOKE");
 692                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 693                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 694                         print_Effect_Index(d, "EF_STARDUST");
 695                         print_Effect_Index(d, "TR_ROCKET");
 696                         print_Effect_Index(d, "TR_GRENADE");
 697                         print_Effect_Index(d, "TR_BLOOD");
 698                         print_Effect_Index(d, "TR_WIZSPIKE");
 699                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 700                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 701                         print_Effect_Index(d, "TR_VORESPIKE");
 702                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 703                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 704                         print_Effect_Index(d, "TR_GLOWTRAIL");
 705                         print_Effect_Index(d, "TR_SEEKER");
 706                         print_Effect_Index(d, "SVC_PARTICLE");
 707
 708                         fh = fopen("effectinfo.txt", FILE_READ);
 709                         while ((s = fgets(fh)))
 710                         {
 711                                 tokenize_console(s);
 712                                 if (argv(0) == "effect")
 713                                 {
 714                                         if (db_get(d, argv(1)) != "1")
 715                                         {
 716                                                 int i = _particleeffectnum(argv(1));
 717                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 718                                                 db_put(d, argv(1), "1");
 719                                         }
 720                                 }
 721                         }
 722                         LOG_INFO("end of effects list");
 723
 724                         db_close(d);
 725                         return;
 726                 }
 727
 728                 default:
 729                 case CMD_REQUEST_USAGE:
 730                 {
 731                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 732                         LOG_HELP("  No arguments required.");
 733                         return;
 734                 }
 735         }
 736 }
 737
 738 void GameCommand_extendmatchtime(int request)
 739 {
 740         switch (request)
 741         {
 742                 case CMD_REQUEST_COMMAND:
 743                 {
 744                         if (!world_initialized)
 745                         {
 746                                 LOG_HELPF("This command works only when the server is running.");
 747                                 return;
 748                         }
 749                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 750                         return;
 751                 }
 752
 753                 default:
 754                 case CMD_REQUEST_USAGE:
 755                 {
 756                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 757                         LOG_HELP("  No arguments required.");
 758                         LOG_HELP("See also: ^2reducematchtime^7");
 759                         return;
 760                 }
 761         }
 762 }
 763
 764 void GameCommand_gametype(int request, int argc)
 765 {
 766         switch (request)
 767         {
 768                 case CMD_REQUEST_COMMAND:
 769                 {
 770                         if (!world_initialized)
 771                         {
 772                                 LOG_HELPF("This command works only when the server is running.");
 773                                 return;
 774                         }
 775                         if (argv(1) != "")
 776                         {
 777                                 string s = argv(1);
 778                                 Gametype t = MapInfo_Type_FromString(s, false, false);
 779
 780                                 if (t)
 781                                         GameTypeVote_SetGametype(t);
 782                                 else
 783                                         bprint("Failed to switch to ", s, ": this game type does not exist!\n");
 784
 785                                 return;
 786                         }
 787                 }
 788
 789                 default:
 790                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 791                 case CMD_REQUEST_USAGE:
 792                 {
 793                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
 794                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
 795                         LOG_HELP("See also: ^2gotomap^7");
 796                         return;
 797                 }
 798         }
 799 }
 800
 801 void GameCommand_gettaginfo(int request, int argc)
 802 {
 803         switch (request)
 804         {
 805                 case CMD_REQUEST_COMMAND:
 806                 {
 807                         entity tmp_entity;
 808                         float i;
 809                         vector v;
 810
 811                         if (argc >= 4)
 812                         {
 813                                 tmp_entity = spawn();
 814                                 if (argv(1) == "w")
 815                                 {
 816                                         .entity weaponentity = weaponentities[0];
 817                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 818                                 }
 819                                 else
 820                                 {
 821                                         precache_model(argv(1));
 822                                         _setmodel(tmp_entity, argv(1));
 823                                 }
 824                                 tmp_entity.frame = stof(argv(2));
 825                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 826                                 else i = gettagindex(tmp_entity, argv(3));
 827                                 if (i)
 828                                 {
 829                                         v = gettaginfo(tmp_entity, i);
 830                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
 831                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 832                                         );
 833                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 834                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 835                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 836                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 837                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 838                                         if (argc >= 6)
 839                                         {
 840                                                 v.y = -v.y;
 841                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 842                                         }
 843                                 }
 844                                 else
 845                                 {
 846                                         LOG_INFO("bone not found");
 847                                 }
 848
 849                                 delete(tmp_entity);
 850                                 return;
 851                         }
 852                 }
 853
 854                 default:
 855                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 856                 case CMD_REQUEST_USAGE:
 857                 {
 858                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
 859                         LOG_HELP("See also: ^2bbox, trace^7");
 860                         return;
 861                 }
 862         }
 863 }
 864
 865 void GameCommand_animbench(int request, int argc)
 866 {
 867         switch (request)
 868         {
 869                 case CMD_REQUEST_COMMAND:
 870                 {
 871                         entity tmp_entity;
 872
 873                         if (argc >= 4)
 874                         {
 875                                 tmp_entity = spawn();
 876                                 if (argv(1) == "w")
 877                                 {
 878                                         .entity weaponentity = weaponentities[0];
 879                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 880                                 }
 881                                 else
 882                                 {
 883                                         precache_model(argv(1));
 884                                         _setmodel(tmp_entity, argv(1));
 885                                 }
 886                                 float f1 = stof(argv(2));
 887                                 float f2 = stof(argv(3));
 888                                 float t0;
 889                                 float t1 = 0;
 890                                 float t2 = 0;
 891                                 float n = 0;
 892
 893                                 while (t1 + t2 < 1)
 894                                 {
 895                                         tmp_entity.frame = f1;
 896                                         t0 = gettime(GETTIME_HIRES);
 897                                         getsurfacepoint(tmp_entity, 0, 0);
 898                                         t1 += gettime(GETTIME_HIRES) - t0;
 899                                         tmp_entity.frame = f2;
 900                                         t0 = gettime(GETTIME_HIRES);
 901                                         getsurfacepoint(tmp_entity, 0, 0);
 902                                         t2 += gettime(GETTIME_HIRES) - t0;
 903                                         n += 1;
 904                                 }
 905                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 906                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 907
 908                                 delete(tmp_entity);
 909                                 return;
 910                         }
 911                 }
 912
 913                 default:
 914                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 915                 case CMD_REQUEST_USAGE:
 916                 {
 917                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
 918                         LOG_HELP("See also: ^2bbox, trace^7");
 919                         return;
 920                 }
 921         }
 922 }
 923
 924 void GameCommand_gotomap(int request, int argc)
 925 {
 926         switch (request)
 927         {
 928                 case CMD_REQUEST_COMMAND:
 929                 {
 930                         if (!world_initialized)
 931                         {
 932                                 LOG_HELPF("This command works only when the server is running.");
 933                                 return;
 934                         }
 935                         if (argv(1))
 936                         {
 937                                 LOG_INFO(GotoMap(argv(1)));
 938                                 return;
 939                         }
 940                 }
 941
 942                 default:
 943                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
 944                 case CMD_REQUEST_USAGE:
 945                 {
 946                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
 947                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
 948                         LOG_HELP("See also: ^2gametype^7");
 949                         return;
 950                 }
 951         }
 952 }
 953
 954 void GameCommand_lockteams(int request)
 955 {
 956         switch (request)
 957         {
 958                 case CMD_REQUEST_COMMAND:
 959                 {
 960                         if (!world_initialized)
 961                         {
 962                                 LOG_HELPF("This command works only when the server is running.");
 963                                 return;
 964                         }
 965                         if (teamplay)
 966                         {
 967                                 lockteams = 1;
 968                                 bprint("^1The teams are now locked.\n");
 969                         }
 970                         else
 971                         {
 972                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 973                         }
 974                         return;
 975                 }
 976
 977                 default:
 978                 case CMD_REQUEST_USAGE:
 979                 {
 980                         LOG_HELP("Usage:^3 sv_cmd lockteams");
 981                         LOG_HELP("  No arguments required.");
 982                         LOG_HELP("See also: ^2unlockteams^7");
 983                         return;
 984                 }
 985         }
 986 }
 987
 988 void GameCommand_make_mapinfo(int request)
 989 {
 990         switch (request)
 991         {
 992                 case CMD_REQUEST_COMMAND:
 993                 {
 994                         entity tmp_entity;
 995
 996                         tmp_entity = new(make_mapinfo);
 997                         setthink(tmp_entity, make_mapinfo_Think);
 998                         tmp_entity.nextthink = time;
 999                         MapInfo_Enumerate();
1000                         return;
1001                 }
1002
1003                 default:
1004                 case CMD_REQUEST_USAGE:
1005                 {
1006                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
1007                         LOG_HELP("  No arguments required.");
1008                         LOG_HELP("See also: ^2radarmap^7");
1009                         return;
1010                 }
1011         }
1012 }
1013
1014 void GameCommand_moveplayer(int request, int argc)
1015 {
1016         switch (request)
1017         {
1018                 case CMD_REQUEST_COMMAND:
1019                 {
1020                         if (!world_initialized)
1021                         {
1022                                 LOG_HELPF("This command works only when the server is running.");
1023                                 return;
1024                         }
1025                         float accepted;
1026                         entity client;
1027
1028                         string targets = strreplace(",", " ", argv(1));
1029                         string original_targets = strreplace(" ", ", ", targets);
1030                         string destination = argv(2);
1031                         if (destination == "spec")
1032                                 destination = "spectator";
1033
1034                         if ((targets) && (destination))
1035                         {
1036                                 string successful = string_null;
1037                                 string t;
1038                                 for ( ; targets; )
1039                                 {
1040                                         t = car(targets);
1041                                         targets = cdr(targets);
1042
1043                                         // Check to see if the player is a valid target
1044                                         client = GetFilteredEntity(t);
1045                                         accepted = VerifyClientEntity(client, false, false);
1046                                         string client_num_str = ftos(etof(client));
1047
1048                                         if (accepted <= 0)
1049                                         {
1050                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), ".");
1051                                         }
1052                                         else if (destination == "spectator")
1053                                         {
1054                                                 string pl_name = playername(client.netname, client.team, false);
1055                                                 if (!(IS_SPEC(client) || IS_OBSERVER(client)) || INGAME(client))
1056                                                 {
1057                                                         PutObserverInServer(client, true, true);
1058
1059                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1060                                                 }
1061                                                 else
1062                                                 {
1063                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already spectating.");
1064                                                 }
1065                                         }
1066                                         else
1067                                         {
1068                                                 if (!teamplay)
1069                                                 {
1070                                                         LOG_INFO("Can't change teams when currently not playing a team game.");
1071                                                         return;
1072                                                 }
1073
1074                                                 string pl_name = playername(client.netname, client.team, false);
1075                                                 if (IS_SPEC(client) || IS_OBSERVER(client))
1076                                                 {
1077                                                         // well technically we could, but should we allow that? :P
1078                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not in the game.");
1079                                                         continue;
1080                                                 }
1081
1082                                                 // set up
1083                                                 int save = Player_GetForcedTeamIndex(client);
1084                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1085
1086                                                 // find the team to move the player to
1087                                                 int team_num = Team_ColorToTeam(destination);
1088                                                 entity balance;
1089                                                 if (team_num == client.team)  // already on the destination team
1090                                                 {
1091                                                         // keep the forcing undone
1092                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already on the ",
1093                                                                 Team_ColoredFullName(team_num), ".");
1094                                                         continue;
1095                                                 }
1096                                                 else if (team_num == 0)  // auto team
1097                                                 {
1098                                                         balance = TeamBalance_CheckAllowedTeams(client);
1099                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1100                                                 }
1101                                                 else
1102                                                 {
1103                                                         balance = TeamBalance_CheckAllowedTeams(client);
1104                                                 }
1105                                                 Player_SetForcedTeamIndex(client, save);
1106
1107                                                 // Check to see if the destination team is even available
1108                                                 int team_id = Team_TeamToIndex(team_num);
1109                                                 if (team_id == -1)
1110                                                 {
1111                                                         LOG_INFO("Can't move player to ", destination, " team because it doesn't exist.");
1112                                                         TeamBalance_Destroy(balance);
1113                                                         return;
1114                                                 }
1115                                                 if (!IsTeamAvailable(team_num))
1116                                                 {
1117                                                         LOG_INFO("Can't move player to ", destination, " team because it isn't available.");
1118                                                         TeamBalance_Destroy(balance);
1119                                                         return;
1120                                                 }
1121                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1122                                                 {
1123                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not allowed to join the ",
1124                                                                 Team_ColoredFullName(team_num), ".");
1125                                                         TeamBalance_Destroy(balance);
1126                                                         continue;
1127                                                 }
1128                                                 TeamBalance_Destroy(balance);
1129
1130                                                 // If so, lets continue and finally move the player
1131                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1132                                                 if (MoveToTeam(client, team_id, 6))
1133                                                 {
1134                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1135                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") has been moved to the ",
1136                                                                 Team_ColoredFullName(team_num), ".");
1137                                                 }
1138                                                 else
1139                                                 {
1140                                                         LOG_INFO("Unable to move player #", client_num_str, " (", pl_name, ")");
1141                                                 }
1142                                         }
1143                                 } // loop end
1144
1145                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1146                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1147
1148                                 return;  // still correct parameters so return to avoid usage print
1149                         }
1150                 }
1151
1152                 default:
1153                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1154                 case CMD_REQUEST_USAGE:
1155                 {
1156                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1157                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1158                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1159                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1160                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1161                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1162                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1163                         return;
1164                 }
1165         }
1166 }
1167
1168 void GameCommand_nospectators(int request)
1169 {
1170         switch (request)
1171         {
1172                 case CMD_REQUEST_COMMAND:
1173                 {
1174                         if (!world_initialized)
1175                         {
1176                                 LOG_HELPF("This command works only when the server is running.");
1177                                 return;
1178                         }
1179                         blockSpectators = 1;
1180                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1181                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !INGAME(it), {
1182                                 CS(it).spectatortime = time;
1183                                 Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1184                         });
1185                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1186                         return;
1187                 }
1188
1189                 default:
1190                 case CMD_REQUEST_USAGE:
1191                 {
1192                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1193                         LOG_HELP("  No arguments required.");
1194                         return;
1195                 }
1196         }
1197 }
1198
1199 void GameCommand_printstats(int request)
1200 {
1201         switch (request)
1202         {
1203                 case CMD_REQUEST_COMMAND:
1204                 {
1205                         if (!world_initialized)
1206                         {
1207                                 LOG_HELPF("This command works only when the server is running.");
1208                                 return;
1209                         }
1210                         DumpStats(false);
1211                         LOG_INFO("stats dumped.");
1212                         return;
1213                 }
1214
1215                 default:
1216                 case CMD_REQUEST_USAGE:
1217                 {
1218                         LOG_HELP("Usage:^3 sv_cmd printstats");
1219                         LOG_HELP("  No arguments required.");
1220                         return;
1221                 }
1222         }
1223 }
1224
1225 void GameCommand_radarmap(int request, int argc)
1226 {
1227         switch (request)
1228         {
1229                 case CMD_REQUEST_COMMAND:
1230                 {
1231                         if (RadarMap_Make(argc)) return;
1232                 }
1233
1234                 default:
1235                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1236                 case CMD_REQUEST_USAGE:
1237                 {
1238                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1239                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1240                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1241                         LOG_HELP("See also: ^2make_mapinfo^7");
1242                         return;
1243                 }
1244         }
1245 }
1246
1247 void GameCommand_reducematchtime(int request)
1248 {
1249         switch (request)
1250         {
1251                 case CMD_REQUEST_COMMAND:
1252                 {
1253                         if (!world_initialized)
1254                         {
1255                                 LOG_HELPF("This command works only when the server is running.");
1256                                 return;
1257                         }
1258                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1259                         return;
1260                 }
1261
1262                 default:
1263                 case CMD_REQUEST_USAGE:
1264                 {
1265                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1266                         LOG_HELP("  No arguments required.");
1267                         LOG_HELP("See also: ^2extendmatchtime^7");
1268                         return;
1269                 }
1270         }
1271 }
1272
1273 void GameCommand_setbots(int request, int argc)
1274 {
1275         switch (request)
1276         {
1277                 case CMD_REQUEST_COMMAND:
1278                 {
1279                         if (argc >= 2)
1280                         {
1281                                 cvar_settemp("minplayers", "0");
1282                                 cvar_settemp("minplayers_per_team", "0");
1283                                 cvar_settemp("bot_number", argv(1));
1284                                 bot_fixcount(true);
1285                                 return;
1286                         }
1287                 }
1288
1289                 default:
1290                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1291                 case CMD_REQUEST_USAGE:
1292                 {
1293                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1294                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1295                         LOG_HELP("See also: ^2bot_cmd^7");
1296                         return;
1297                 }
1298         }
1299 }
1300
1301 void shuffleteams()
1302 {
1303         if (!teamplay)
1304         {
1305                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1306                 return;
1307         }
1308
1309         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1310                 if (Player_HasRealForcedTeam(it)) {
1311                         // we could theoretically assign forced players to their teams
1312                         // and shuffle the rest to fill the empty spots but in practise
1313                         // either all players or none are gonna have forced teams
1314                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1315                         return;
1316                 }
1317         });
1318
1319         int number_of_teams = 0;
1320         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1321         for (int i = 1; i <= NUM_TEAMS; ++i)
1322         {
1323                 if (TeamBalance_IsTeamAllowed(balance, i))
1324                 {
1325                         number_of_teams = max(i, number_of_teams);
1326                 }
1327         }
1328         TeamBalance_Destroy(balance);
1329
1330         int team_index = 0;
1331         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || INGAME(it), {
1332                 int target_team_index = team_index + 1;
1333                 if (Entity_GetTeamIndex(it) != target_team_index)
1334                 {
1335                         MoveToTeam(it, target_team_index, 6);
1336                 }
1337                 team_index = (team_index + 1) % number_of_teams;
1338         });
1339
1340         bprint("Successfully shuffled the players around randomly.\n");
1341 }
1342
1343 void GameCommand_shuffleteams(int request)
1344 {
1345         switch (request)
1346         {
1347                 case CMD_REQUEST_COMMAND:
1348                 {
1349                         if (!world_initialized)
1350                         {
1351                                 LOG_HELPF("This command works only when the server is running.");
1352                                 return;
1353                         }
1354                         if (shuffleteams_on_reset_map)
1355                         {
1356                                 bprint("Players will be shuffled when this round is over.\n");
1357                                 shuffleteams_on_reset_map = true;
1358                         }
1359                         else
1360                                 shuffleteams();
1361                         return;
1362                 }
1363
1364                 default:
1365                 case CMD_REQUEST_USAGE:
1366                 {
1367                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1368                         LOG_HELP("  No arguments required.");
1369                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1370                         return;
1371                 }
1372         }
1373 }
1374
1375 void GameCommand_resetmatch(int request)
1376 {
1377         switch (request)
1378         {
1379                 case CMD_REQUEST_COMMAND:
1380                 {
1381                         if (!world_initialized)
1382                         {
1383                                 LOG_HELPF("This command works only when the server is running.");
1384                                 return;
1385                         }
1386                         ReadyRestart(false);
1387                         return;
1388                 }
1389
1390                 default:
1391                 case CMD_REQUEST_USAGE:
1392                 {
1393                         LOG_HELP("Usage:^3 sv_cmd resetmatch");
1394                         LOG_HELP("  No arguments required.");
1395                         return;
1396                 }
1397         }
1398 }
1399
1400 void GameCommand_stuffto(int request, int argc)
1401 {
1402         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1403         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1404         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1405
1406 #ifdef STUFFTO_ENABLED
1407                 switch (request)
1408                 {
1409                         case CMD_REQUEST_COMMAND:
1410                         {
1411                                 if (!world_initialized)
1412                                 {
1413                                         LOG_HELPF("This command works only when the server is running.");
1414                                         return;
1415                                 }
1416                                 if (argv(2))
1417                                 {
1418                                         entity client = GetIndexedEntity(argc, 1);
1419                                         float accepted = VerifyClientEntity(client, true, false);
1420
1421                                         if (accepted > 0)
1422                                         {
1423                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1424                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1425                                         }
1426                                         else
1427                                         {
1428                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1429                                         }
1430
1431                                         return;
1432                                 }
1433                         }
1434
1435                         default:
1436                                 LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1437                         case CMD_REQUEST_USAGE:
1438                         {
1439                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1440                                 LOG_HELP("  <client> is the entity number or name of the player,");
1441                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1442                                 return;
1443                         }
1444                 }
1445 #else
1446                 if (request)
1447                 {
1448                         LOG_HELP("stuffto command is not enabled on this server.");
1449                         return;
1450                 }
1451 #endif
1452 }
1453
1454 void GameCommand_trace(int request, int argc)
1455 {
1456         switch (request)
1457         {
1458                 case CMD_REQUEST_COMMAND:
1459                 {
1460                         entity e;
1461                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1462                         float i, f, safe, unsafe, dq, dqf;
1463
1464                         switch (argv(1))
1465                         {
1466                                 case "debug":
1467                                 {
1468                                         float hitcount = 0;
1469                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1470                                         float worst_endpos_bug = 0;
1471                                         for ( ; ; )
1472                                         {
1473                                                 org = world.mins;
1474                                                 delta = world.maxs - world.mins;
1475
1476                                                 start.x = org.x + random() * delta.x;
1477                                                 start.y = org.y + random() * delta.y;
1478                                                 start.z = org.z + random() * delta.z;
1479
1480                                                 end.x = org.x + random() * delta.x;
1481                                                 end.y = org.y + random() * delta.y;
1482                                                 end.z = org.z + random() * delta.z;
1483
1484                                                 start = stov(vtos(start));
1485                                                 end = stov(vtos(end));
1486
1487                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1488                                                 if (!trace_startsolid && trace_fraction < 1)
1489                                                 {
1490                                                         p = trace_endpos;
1491                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1492                                                         if (trace_startsolid)
1493                                                         {
1494                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1495                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1496
1497                                                                 // how much do we need to back off?
1498                                                                 safe = 1;
1499                                                                 unsafe = 0;
1500                                                                 for ( ; ; )
1501                                                                 {
1502                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1503                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1504                                                                         if (trace_startsolid)
1505                                                                         {
1506                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1507                                                                                 unsafe = (safe + unsafe) * 0.5;
1508                                                                         }
1509                                                                         else
1510                                                                         {
1511                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1512                                                                                 safe = (safe + unsafe) * 0.5;
1513                                                                         }
1514                                                                 }
1515
1516                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1517                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1518
1519                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1520                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1521                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1522                                                                 if (++hitcount >= 10) break;
1523                                                         }
1524                                                         else
1525                                                         {
1526                                                                 q0 = p;
1527                                                                 dq = 0;
1528                                                                 dqf = 1;
1529                                                                 for ( ; ; )
1530                                                                 {
1531                                                                         q = p + normalize(end - p) * (dq + dqf);
1532                                                                         if (q == q0) break;
1533                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1534                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1535                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1536                                                                         dqf *= 0.5;
1537                                                                         q0 = q;
1538                                                                 }
1539                                                                 if (dq > worst_endpos_bug)
1540                                                                 {
1541                                                                         worst_endpos_bug = dq;
1542                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1543                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1544                                                                         if (++hitcount >= 10) break;
1545                                                                 }
1546                                                         }
1547                                                 }
1548                                         }
1549                                         return;
1550                                 }
1551
1552                                 case "debug2":
1553                                 {
1554                                         e = nextent(NULL);
1555                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1556                                         vv = trace_endpos;
1557                                         if (trace_fraction == 1)
1558                                         {
1559                                                 LOG_INFO("not above ground, aborting");
1560                                                 return;
1561                                         }
1562                                         f = 0;
1563                                         for (i = 0; i < 100000; ++i)
1564                                         {
1565                                                 dv = randomvec();
1566                                                 if (dv.z > 0) dv = -1 * dv;
1567                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1568                                                 if (trace_startsolid) LOG_INFO("bug 1");
1569                                                 if (trace_fraction == 1)
1570                                                 {
1571                                                         if (dv.z < f)
1572                                                         {
1573                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1574                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1575                                                                 f = dv.z;
1576                                                         }
1577                                                 }
1578                                         }
1579                                         LOG_INFO("highest possible dist: ", ftos(f));
1580                                         return;
1581                                 }
1582
1583                                 case "walk":
1584                                 {
1585                                         if (argc == 4 || argc == 5)
1586                                         {
1587                                                 e = nextent(NULL);
1588                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1589                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1590                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1591                                                         LOG_INFO("can walk");
1592                                                 else
1593                                                         LOG_INFO("cannot walk");
1594                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1595                                                 return;
1596                                         }
1597                                 }
1598
1599                                 case "showline":
1600                                 {
1601                                         if (argc == 4)
1602                                         {
1603                                                 vv = stov(argv(2));
1604                                                 dv = stov(argv(3));
1605                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1606                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1607                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1608                                                 return;
1609                                         }
1610                                 }
1611
1612                                 // no default case, just go straight to invalid
1613                         }
1614                 }
1615
1616                 default:
1617                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1618                 case CMD_REQUEST_USAGE:
1619                 {
1620                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1621                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1622                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1623                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1624                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1625                         return;
1626                 }
1627         }
1628 }
1629
1630 void GameCommand_unlockteams(int request)
1631 {
1632         switch (request)
1633         {
1634                 case CMD_REQUEST_COMMAND:
1635                 {
1636                         if (!world_initialized)
1637                         {
1638                                 LOG_HELPF("This command works only when the server is running.");
1639                                 return;
1640                         }
1641                         if (teamplay)
1642                         {
1643                                 lockteams = 0;
1644                                 bprint("^1The teams are now unlocked.\n");
1645                         }
1646                         else
1647                         {
1648                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1649                         }
1650                         return;
1651                 }
1652
1653                 default:
1654                 case CMD_REQUEST_USAGE:
1655                 {
1656                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1657                         LOG_HELP("  No arguments required.");
1658                         LOG_HELP("See also: ^2lockteams^7");
1659                         return;
1660                 }
1661         }
1662 }
1663
1664 void GameCommand_warp(int request, int argc)
1665 {
1666         switch (request)
1667         {
1668                 case CMD_REQUEST_COMMAND:
1669                 {
1670                         if (!world_initialized)
1671                         {
1672                                 LOG_HELPF("This command works only when the server is running.");
1673                                 return;
1674                         }
1675                         if (autocvar_g_campaign)
1676                         {
1677                                 if (argc >= 2)
1678                                 {
1679                                         CampaignLevelWarp(stof(argv(1)));
1680                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1681                                 }
1682                                 else
1683                                 {
1684                                         CampaignLevelWarp(-1);
1685                                         LOG_INFO("Successfully warped to next campaign level.");
1686                                 }
1687                         }
1688                         else
1689                         {
1690                                 LOG_INFO("Not in campaign, can't level warp");
1691                         }
1692                         return;
1693                 }
1694
1695                 default:
1696                 case CMD_REQUEST_USAGE:
1697                 {
1698                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1699                         LOG_HELP("  <level> is the level to change campaign mode to.");
1700                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1701                         return;
1702                 }
1703         }
1704 }
1705
1706 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1707 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1708 void GameCommand_(int request)
1709 {
1710     switch(request)
1711     {
1712         case CMD_REQUEST_COMMAND:
1713         {
1714                     if (!world_initialized)
1715                     {
1716                         LOG_HELPF("This command works only when the server is running.");
1717                         return;
1718                     }
1719
1720             return;
1721         }
1722
1723         default:
1724         case CMD_REQUEST_USAGE:
1725         {
1726             LOG_HELP("Usage:^3 sv_cmd ");
1727             LOG_HELP("  No arguments required.");
1728             return;
1729         }
1730     }
1731 }
1732 */
1733
1734
1735 // ==================================
1736 //  Macro system for server commands
1737 // ==================================
1738
1739 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1740 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1741 SERVER_COMMAND(allready, "Ends warmup and starts the match") { GameCommand_allready(request); }
1742 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1743 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1744 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1745 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1746 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1747 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1748 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1749 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1750 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1751 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1752 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1753 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1754 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1755 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1756 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1757 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1758 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1759 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1760 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1761 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1762 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1763 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1764 SERVER_COMMAND(resetmatch, "Soft restart the game without changing teams; goes back to warmup if enabled") { GameCommand_resetmatch(request); }
1765 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1766 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1767 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1768 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1769 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1770 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1771
1772 void GameCommand_macro_help()
1773 {
1774         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1775 }
1776
1777 float GameCommand_macro_command(int argc, string command)
1778 {
1779         string c = strtolower(argv(0));
1780         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1781                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1782                 return true;
1783         });
1784         return false;
1785 }
1786
1787 float GameCommand_macro_usage(int argc)
1788 {
1789         string c = strtolower(argv(1));
1790         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1791                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1792                 return true;
1793         });
1794         return false;
1795 }
1796
1797 void GameCommand_macro_write_aliases(float fh)
1798 {
1799         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1800 }
1801
1802
1803 // =========================================
1804 //  Main Function Called By Engine (sv_cmd)
1805 // =========================================
1806 // If this function exists, game code handles gamecommand instead of the engine code.
1807
1808 void GameCommand(string command)
1809 {
1810         int argc = tokenize_console(command);
1811
1812         // Guide for working with argc arguments by example:
1813         // argc:   1    - 2      - 3     - 4
1814         // argv:   0    - 1      - 2     - 3
1815         // cmd     vote - master - login - password
1816
1817         if (strtolower(argv(0)) == "help")
1818         {
1819                 if (argc == 1)
1820                 {
1821                         LOG_HELP("Server console commands:");
1822                         GameCommand_macro_help();
1823
1824                         LOG_HELP("\nBanning commands:");
1825                         BanCommand_macro_help();
1826
1827                         LOG_HELP("\nCommon networked commands:");
1828                         CommonCommand_macro_help(NULL);
1829
1830                         LOG_HELP("\nGeneric commands shared by all programs:");
1831                         GenericCommand_macro_help();
1832
1833                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1834                                 "For help about a specific command, type sv_cmd help <command>");
1835
1836                         return;
1837                 }
1838                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1839                 {
1840                         return;
1841                 }
1842                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1843                 {
1844                         return;
1845                 }
1846                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1847                 {
1848                         return;
1849                 }
1850                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1851                 {
1852                         return;
1853                 }
1854         }
1855         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1856         {
1857                 return;  // handled by a mutator
1858         }
1859         else if (BanCommand(command))
1860         {
1861                 return;  // handled by server/command/ipban.qc
1862         }
1863         else if (CommonCommand_macro_command(argc, NULL, command))
1864         {
1865                 return;  // handled by server/command/common.qc
1866         }
1867         else if (GenericCommand(command))
1868         {
1869                 return;                                        // handled by common/command/generic.qc
1870         }
1871         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1872         {
1873                 return;                                        // handled by one of the above GameCommand_* functions
1874         }
1875
1876         // nothing above caught the command, must be invalid
1877         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1878 }