]> git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/command/sv_cmd.qc
8cd6125ab12cf38afa5ad4b4edb96081bb7c7521
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / sv_cmd.qc
1 #include "sv_cmd.qh"
2
3 #include <common/constants.qh>
4 #include <common/effects/all.qh>
5 #include <common/gamemodes/_mod.qh>
6 #include <common/mapinfo.qh>
7 #include <common/monsters/sv_monsters.qh>
8 #include <common/net_linked.qh>
9 #include <common/notifications/all.qh>
10 #include <common/teams.qh>
11 #include <common/util.qh>
12 #include <server/anticheat.qh>
13 #include <server/bot/api.qh>
14 #include <server/campaign.qh>
15 #include <server/client.qh>
16 #include <server/command/_mod.qh>
17 #include <server/command/banning.qh>
18 #include <server/command/cmd.qh>
19 #include <server/command/common.qh>
20 #include <server/command/getreplies.qh>
21 #include <server/command/radarmap.qh>
22 #include <server/intermission.qh>
23 #include <server/ipban.qh>
24 #include <server/mutators/_mod.qh>
25 #include <server/player.qh>
26 #include <server/scores_rules.qh>
27 #include <server/teamplay.qh>
28 #include <server/world.qh>
29
30 //  used by GameCommand_make_mapinfo()
31 void make_mapinfo_Think(entity this)
32 {
33         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
34         {
35                 LOG_INFO("Done rebuiling mapinfos.");
36                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
37                 delete(this);
38         }
39         else
40         {
41                 setthink(this, make_mapinfo_Think);
42                 this.nextthink = time;
43         }
44 }
45
46 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
47 void changematchtime(float delta, float mi, float ma)
48 {
49         float cur;
50         float update;
51         float lim;
52
53         if (delta == 0) return;
54         if (autocvar_timelimit < 0) return;
55
56         if (mi <= 10) mi = 10;  // at least ten sec in the future
57         cur = time - game_starttime;
58         if (cur > 0) mi += cur; // from current time!
59
60         lim = autocvar_timelimit * 60;
61
62         if (delta > 0)
63         {
64                 if (lim == 0) return; // cannot increase any further
65                 else if (lim < ma) update = min(ma, lim + delta);
66                 else                  // already above maximum: FAIL
67                         return;
68         }
69         else
70         {
71                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
72                         update = max(mi, ma);
73                 else if (lim > mi) // above minimum: decrease
74                         update = max(mi, lim + delta);
75                 else               // already below minimum: FAIL
76                         return;
77         }
78
79         cvar_set("timelimit", ftos(update / 60));
80 }
81
82
83 // =======================
84 //  Command Sub-Functions
85 // =======================
86
87 void GameCommand_adminmsg(int request, int argc)
88 {
89         switch (request)
90         {
91                 case CMD_REQUEST_COMMAND:
92                 {
93                         if (!world_initialized)
94                         {
95                                 LOG_HELPF("This command works only when the server is running.");
96                                 return;
97                         }
98                         entity client;
99                         float accepted;
100
101                         string targets = strreplace(",", " ", argv(1));
102                         string original_targets = strreplace(" ", ", ", targets);
103                         string admin_message = argv(2);
104                         float infobartime = stof(argv(3));
105
106                         string successful, t;
107                         successful = string_null;
108
109                         if ((targets) && (admin_message))
110                         {
111                                 for ( ; targets; )
112                                 {
113                                         t = car(targets);
114                                         targets = cdr(targets);
115
116                                         // Check to see if the player is a valid target
117                                         client = GetFilteredEntity(t);
118                                         accepted = VerifyClientEntity(client, true, false);
119
120                                         if (accepted <= 0)
121                                         {
122                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
123                                                 continue;
124                                         }
125
126                                         // send the centerprint/console print or infomessage
127                                         if (infobartime)
128                                         {
129                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
130                                         }
131                                         else
132                                         {
133                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
134                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
135                                         }
136
137                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
138                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
139                                         continue;
140                                 }
141
142                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
143                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
144
145                                 return;
146                         }
147                 }
148
149                 default:
150                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
151                 case CMD_REQUEST_USAGE:
152                 {
153                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
154                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
155                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
156                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
157                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
158                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
159                         return;
160                 }
161         }
162 }
163
164 void GameCommand_allready(int request)
165 {
166         switch (request)
167         {
168                 case CMD_REQUEST_COMMAND:
169                 {
170                         if (!world_initialized)
171                         {
172                                 LOG_HELPF("This command works only when the server is running.");
173                                 return;
174                         }
175                         if(warmup_stage)
176                         {
177                                 ReadyRestart(true);
178                         }
179                         else
180                                 LOG_INFO("Not in warmup.");
181
182                         return;
183                 }
184
185                 default:
186                 case CMD_REQUEST_USAGE:
187                 {
188                         LOG_HELP("Usage:^3 sv_cmd allready");
189                         LOG_HELP("  No arguments required.");
190                         return;
191                 }
192         }
193 }
194
195 void GameCommand_allspec(int request, int argc)
196 {
197         switch (request)
198         {
199                 case CMD_REQUEST_COMMAND:
200                 {
201                         if (!world_initialized)
202                         {
203                                 LOG_HELPF("This command works only when the server is running.");
204                                 return;
205                         }
206                         string reason = argv(1);
207                         int n = 0;
208                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
209                                 PutObserverInServer(it, true, true);
210                                 ++n;
211                         });
212                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
213                         else   LOG_INFO("No players found to spectate.");
214                         return;
215                 }
216
217                 default:
218                 case CMD_REQUEST_USAGE:
219                 {
220                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
221                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
222                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
223                         return;
224                 }
225         }
226 }
227
228 void GameCommand_anticheat(int request, int argc)
229 {
230         switch (request)
231         {
232                 case CMD_REQUEST_COMMAND:
233                 {
234                         if (!world_initialized)
235                         {
236                                 LOG_HELPF("This command works only when the server is running.");
237                                 return;
238                         }
239                         entity client = GetIndexedEntity(argc, 1);
240                         float accepted = VerifyClientEntity(client, false, false);
241
242                         if (accepted > 0)
243                         {
244                                 anticheat_report_to_eventlog(client);
245                                 return;
246                         }
247                         else
248                         {
249                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
250                         }
251                 }
252
253                 default:
254                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
255                 case CMD_REQUEST_USAGE:
256                 {
257                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
258                         LOG_HELP("  <client> is the entity number or name of the player.");
259                         return;
260                 }
261         }
262 }
263
264 void GameCommand_bbox(int request)
265 {
266         switch (request)
267         {
268                 case CMD_REQUEST_COMMAND:
269                 {
270                         vector size_min = '0 0 0';
271                         vector size_max = '0 0 0';
272                         tracebox('1 0 0' * world.absmin.x,
273                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
274                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
275                                 '1 0 0' * world.absmax.x,
276                                 MOVE_WORLDONLY,
277                                 NULL);
278                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
279
280                         tracebox('0 1 0' * world.absmin.y,
281                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
282                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
283                                 '0 1 0' * world.absmax.y,
284                                 MOVE_WORLDONLY,
285                                 NULL);
286                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
287
288                         tracebox('0 0 1' * world.absmin.z,
289                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
290                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
291                                 '0 0 1' * world.absmax.z,
292                                 MOVE_WORLDONLY,
293                                 NULL);
294                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
295
296                         tracebox('1 0 0' * world.absmax.x,
297                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
298                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
299                                 '1 0 0' * world.absmin.x,
300                                 MOVE_WORLDONLY,
301                                 NULL);
302                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
303
304                         tracebox('0 1 0' * world.absmax.y,
305                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
306                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
307                                 '0 1 0' * world.absmin.y,
308                                 MOVE_WORLDONLY,
309                                 NULL);
310                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
311
312                         tracebox('0 0 1' * world.absmax.z,
313                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
314                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
315                                 '0 0 1' * world.absmin.z,
316                                 MOVE_WORLDONLY,
317                                 NULL);
318                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
319
320                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
321                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
322                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
323                         return;
324                 }
325
326                 default:
327                 case CMD_REQUEST_USAGE:
328                 {
329                         LOG_HELP("Usage:^3 sv_cmd bbox");
330                         LOG_HELP("  No arguments required.");
331                         LOG_HELP("See also: ^2gettaginfo, trace^7");
332                         return;
333                 }
334         }
335 }
336
337 void GameCommand_bot_cmd(int request, int argc, string command)
338 {
339         switch (request)
340         {
341                 case CMD_REQUEST_COMMAND:
342                 {
343                         if (!world_initialized)
344                         {
345                                 LOG_HELPF("This command works only when the server is running.");
346                                 return;
347                         }
348                         entity bot;
349
350                         if (argv(1) == "reset")
351                         {
352                                 bot_resetqueues();
353                                 return;
354                         }
355                         else if (argv(1) == "setbots")
356                         {
357                                 cvar_settemp("bot_vs_human", "0");
358                                 cvar_settemp("minplayers", "0");
359                                 cvar_settemp("minplayers_per_team", "0");
360                                 cvar_settemp("bot_number", "0");
361                                 bot_fixcount(false);  // Kill all bots.
362                                 cvar_settemp("bot_number", argv(2));
363                                 if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
364                                 return;
365                         }
366                         else if (argv(1) == "load" && argc == 3)
367                         {
368                                 float fh, i;
369                                 string s;
370                                 fh = fopen(argv(2), FILE_READ);
371                                 if (fh < 0)
372                                 {
373                                         LOG_INFO("cannot open the file");
374                                         return;
375                                 }
376
377                                 i = 0;
378                                 while ((s = fgets(fh)))
379                                 {
380                                         argc = tokenize_console(s);
381
382                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
383                                         {
384                                                 if (argv(2) == "reset")
385                                                 {
386                                                         bot_resetqueues();
387                                                 }
388                                                 else if (argv(2) == "setbots")
389                                                 {
390                                                         cvar_settemp("bot_vs_human", "0");
391                                                         cvar_settemp("minplayers", "0");
392                                                         cvar_settemp("minplayers_per_team", "0");
393                                                         cvar_settemp("bot_number", "0");
394                                                         bot_fixcount(false);  // Kill all bots.
395                                                         cvar_settemp("bot_number", argv(3));
396                                                         if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
397                                                 }
398                                                 else
399                                                 {
400                                                         if(argv(2) == "*" || argv(2) == "all")
401                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
402                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
403                                                                 });
404                                                         else
405                                                         {
406                                                                 bot = find_bot_by_number(stof(argv(2)));
407                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
408                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
409                                                         }
410                                                 }
411                                         }
412                                         else
413                                         {
414                                                 localcmd(strcat(s, "\n"));
415                                         }
416
417                                         ++i;
418                                 }
419                                 LOG_INFO(ftos(i), " commands read");
420                                 fclose(fh);
421                                 return;
422                         }
423                         else if (argv(1) == "help")
424                         {
425                                 if (argv(2)) bot_cmdhelp(argv(2));
426                                 else bot_list_commands();
427                                 return;
428                         }
429                         else if (argc >= 3)  // this comes last
430                         {
431                                 if(argv(1) == "*" || argv(1) == "all")
432                                 {
433                                         int bot_num = 0;
434                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
435                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
436                                                 bot_num++;
437                                         });
438                                         if(bot_num)
439                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
440                                         return;
441                                 }
442                                 else
443                                 {
444                                         bot = find_bot_by_number(stof(argv(1)));
445                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
446                                         if (bot)
447                                         {
448                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
449                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
450                                                 return;
451                                         }
452                                         else
453                                         {
454                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
455                                         }
456                                 }
457                         }
458                 }
459
460                 default:
461                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
462                 case CMD_REQUEST_USAGE:
463                 {
464                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
465                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
466                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
467                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
468                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc say something");
469                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
470                         LOG_HELP("          sv_cmd bot_cmd * pause");
471                         return;
472                 }
473         }
474 }
475
476 void GameCommand_cointoss(int request, int argc)
477 {
478         switch (request)
479         {
480                 case CMD_REQUEST_COMMAND:
481                 {
482                         if (!world_initialized)
483                         {
484                                 LOG_HELPF("This command works only when the server is running.");
485                                 return;
486                         }
487                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
488                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
489                         string choice = ((random() > 0.5) ? result1 : result2);
490
491                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
492                         return;
493                 }
494
495                 default:
496                 case CMD_REQUEST_USAGE:
497                 {
498                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
499                         LOG_HELP("  Where <result1> and <result2> are user created options.");
500                         return;
501                 }
502         }
503 }
504
505 void GameCommand_database(int request, int argc)
506 {
507         switch (request)
508         {
509                 case CMD_REQUEST_COMMAND:
510                 {
511                         if (argc == 3)
512                         {
513                                 if (argv(1) == "save")
514                                 {
515                                         db_save(ServerProgsDB, argv(2));
516                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
517                                         return;
518                                 }
519                                 else if (argv(1) == "dump")
520                                 {
521                                         db_dump(ServerProgsDB, argv(2));
522                                         LOG_INFO("DB dumped.");  // wtf does this do?
523                                         return;
524                                 }
525                                 else if (argv(1) == "load")
526                                 {
527                                         db_close(ServerProgsDB);
528                                         ServerProgsDB = db_load(argv(2));
529                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
530                                         return;
531                                 }
532                         }
533                 }
534
535                 default:
536                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
537                 case CMD_REQUEST_USAGE:
538                 {
539                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
540                         LOG_HELP("  Where <action> is the command to complete,");
541                         LOG_HELP("  and <filename> is what it acts upon.");
542                         LOG_HELP("  Full list of commands here: save, dump, load.");
543                         return;
544                 }
545         }
546 }
547
548 void GameCommand_defer_clear(int request, int argc)
549 {
550         switch (request)
551         {
552                 case CMD_REQUEST_COMMAND:
553                 {
554                         if (!world_initialized)
555                         {
556                                 LOG_HELPF("This command works only when the server is running.");
557                                 return;
558                         }
559                         entity client;
560                         float accepted;
561
562                         if (argc >= 2)
563                         {
564                                 client = GetIndexedEntity(argc, 1);
565                                 accepted = VerifyClientEntity(client, true, false);
566
567                                 if (accepted > 0)
568                                 {
569                                         stuffcmd(client, "defer clear\n");
570                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
571                                 }
572                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
573
574                                 return;
575                         }
576                 }
577
578                 default:
579                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
580                 case CMD_REQUEST_USAGE:
581                 {
582                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
583                         LOG_HELP("  <client> is the entity number or name of the player.");
584                         LOG_HELP("See also: ^2defer_clear_all^7");
585                         return;
586                 }
587         }
588 }
589
590 void GameCommand_defer_clear_all(int request)
591 {
592         switch (request)
593         {
594                 case CMD_REQUEST_COMMAND:
595                 {
596                         if (!world_initialized)
597                         {
598                                 LOG_HELPF("This command works only when the server is running.");
599                                 return;
600                         }
601                         int n = 0;
602                         int argc;
603
604                         FOREACH_CLIENT(true, {
605                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
606                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
607                                 ++n;
608                         });
609                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
610                         return;
611                 }
612
613                 default:
614                 case CMD_REQUEST_USAGE:
615                 {
616                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
617                         LOG_HELP("  No arguments required.");
618                         LOG_HELP("See also: ^2defer_clear^7");
619                         return;
620                 }
621         }
622 }
623
624 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
625 {
626         switch (request)
627         {
628                 case CMD_REQUEST_COMMAND:
629                 {
630                         if (argv(1))
631                         {
632                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
633                                 else race_deleteTime(GetMapname(), stof(argv(1)));
634                                 return;
635                         }
636                 }
637
638                 default:
639                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
640                 case CMD_REQUEST_USAGE:
641                 {
642                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
643                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
644                         LOG_HELP("  it will clear all records up to nth place.");
645                         LOG_HELP("  if <map> is not provided it will use current map.");
646                         return;
647                 }
648         }
649 }
650
651 void print_Effect_Index(int d, string effect_name)
652
653         // this is inside a function to avoid expanding it on compilation everytime
654         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
655         db_put(d, effect_name, "1");
656 }
657
658 void GameCommand_effectindexdump(int request)
659 {
660         switch (request)
661         {
662                 case CMD_REQUEST_COMMAND:
663                 {
664                         float fh, d;
665                         string s;
666
667                         d = db_create();
668                         LOG_INFO("begin of effects list");
669
670                         print_Effect_Index(d, "TE_GUNSHOT");
671                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
672                         print_Effect_Index(d, "TE_SPIKE");
673                         print_Effect_Index(d, "TE_SPIKEQUAD");
674                         print_Effect_Index(d, "TE_SUPERSPIKE");
675                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
676                         print_Effect_Index(d, "TE_WIZSPIKE");
677                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
678                         print_Effect_Index(d, "TE_EXPLOSION");
679                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
680                         print_Effect_Index(d, "TE_TAREXPLOSION");
681                         print_Effect_Index(d, "TE_TELEPORT");
682                         print_Effect_Index(d, "TE_LAVASPLASH");
683                         print_Effect_Index(d, "TE_SMALLFLASH");
684                         print_Effect_Index(d, "TE_FLAMEJET");
685                         print_Effect_Index(d, "EF_FLAME");
686                         print_Effect_Index(d, "TE_BLOOD");
687                         print_Effect_Index(d, "TE_SPARK");
688                         print_Effect_Index(d, "TE_PLASMABURN");
689                         print_Effect_Index(d, "TE_TEI_G3");
690                         print_Effect_Index(d, "TE_TEI_SMOKE");
691                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
692                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
693                         print_Effect_Index(d, "EF_STARDUST");
694                         print_Effect_Index(d, "TR_ROCKET");
695                         print_Effect_Index(d, "TR_GRENADE");
696                         print_Effect_Index(d, "TR_BLOOD");
697                         print_Effect_Index(d, "TR_WIZSPIKE");
698                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
699                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
700                         print_Effect_Index(d, "TR_VORESPIKE");
701                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
702                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
703                         print_Effect_Index(d, "TR_GLOWTRAIL");
704                         print_Effect_Index(d, "TR_SEEKER");
705                         print_Effect_Index(d, "SVC_PARTICLE");
706
707                         fh = fopen("effectinfo.txt", FILE_READ);
708                         while ((s = fgets(fh)))
709                         {
710                                 tokenize_console(s);
711                                 if (argv(0) == "effect")
712                                 {
713                                         if (db_get(d, argv(1)) != "1")
714                                         {
715                                                 int i = _particleeffectnum(argv(1));
716                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
717                                                 db_put(d, argv(1), "1");
718                                         }
719                                 }
720                         }
721                         LOG_INFO("end of effects list");
722
723                         db_close(d);
724                         return;
725                 }
726
727                 default:
728                 case CMD_REQUEST_USAGE:
729                 {
730                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
731                         LOG_HELP("  No arguments required.");
732                         return;
733                 }
734         }
735 }
736
737 void GameCommand_extendmatchtime(int request)
738 {
739         switch (request)
740         {
741                 case CMD_REQUEST_COMMAND:
742                 {
743                         if (!world_initialized)
744                         {
745                                 LOG_HELPF("This command works only when the server is running.");
746                                 return;
747                         }
748                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
749                         return;
750                 }
751
752                 default:
753                 case CMD_REQUEST_USAGE:
754                 {
755                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
756                         LOG_HELP("  No arguments required.");
757                         LOG_HELP("See also: ^2reducematchtime^7");
758                         return;
759                 }
760         }
761 }
762
763 void GameCommand_gametype(int request, int argc)
764 {
765         switch (request)
766         {
767                 case CMD_REQUEST_COMMAND:
768                 {
769                         if (!world_initialized)
770                         {
771                                 LOG_HELPF("This command works only when the server is running.");
772                                 return;
773                         }
774                         if (argv(1) != "")
775                         {
776                                 string s = argv(1);
777                                 Gametype t = MapInfo_Type_FromString(s, false, false);
778
779                                 if (t)
780                                         GameTypeVote_SetGametype(t);
781                                 else
782                                         bprint("Failed to switch to ", s, ": this game type does not exist!\n");
783
784                                 return;
785                         }
786                 }
787
788                 default:
789                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
790                 case CMD_REQUEST_USAGE:
791                 {
792                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
793                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
794                         LOG_HELP("See also: ^2gotomap^7");
795                         return;
796                 }
797         }
798 }
799
800 void GameCommand_gettaginfo(int request, int argc)
801 {
802         switch (request)
803         {
804                 case CMD_REQUEST_COMMAND:
805                 {
806                         entity tmp_entity;
807                         float i;
808                         vector v;
809
810                         if (argc >= 4)
811                         {
812                                 tmp_entity = spawn();
813                                 if (argv(1) == "w")
814                                 {
815                                         .entity weaponentity = weaponentities[0];
816                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
817                                 }
818                                 else
819                                 {
820                                         precache_model(argv(1));
821                                         _setmodel(tmp_entity, argv(1));
822                                 }
823                                 tmp_entity.frame = stof(argv(2));
824                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
825                                 else i = gettagindex(tmp_entity, argv(3));
826                                 if (i)
827                                 {
828                                         v = gettaginfo(tmp_entity, i);
829                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
830                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
831                                         );
832                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
833                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
834                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
835                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
836                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
837                                         if (argc >= 6)
838                                         {
839                                                 v.y = -v.y;
840                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
841                                         }
842                                 }
843                                 else
844                                 {
845                                         LOG_INFO("bone not found");
846                                 }
847
848                                 delete(tmp_entity);
849                                 return;
850                         }
851                 }
852
853                 default:
854                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
855                 case CMD_REQUEST_USAGE:
856                 {
857                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
858                         LOG_HELP("See also: ^2bbox, trace^7");
859                         return;
860                 }
861         }
862 }
863
864 void GameCommand_animbench(int request, int argc)
865 {
866         switch (request)
867         {
868                 case CMD_REQUEST_COMMAND:
869                 {
870                         entity tmp_entity;
871
872                         if (argc >= 4)
873                         {
874                                 tmp_entity = spawn();
875                                 if (argv(1) == "w")
876                                 {
877                                         .entity weaponentity = weaponentities[0];
878                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
879                                 }
880                                 else
881                                 {
882                                         precache_model(argv(1));
883                                         _setmodel(tmp_entity, argv(1));
884                                 }
885                                 float f1 = stof(argv(2));
886                                 float f2 = stof(argv(3));
887                                 float t0;
888                                 float t1 = 0;
889                                 float t2 = 0;
890                                 float n = 0;
891
892                                 while (t1 + t2 < 1)
893                                 {
894                                         tmp_entity.frame = f1;
895                                         t0 = gettime(GETTIME_HIRES);
896                                         getsurfacepoint(tmp_entity, 0, 0);
897                                         t1 += gettime(GETTIME_HIRES) - t0;
898                                         tmp_entity.frame = f2;
899                                         t0 = gettime(GETTIME_HIRES);
900                                         getsurfacepoint(tmp_entity, 0, 0);
901                                         t2 += gettime(GETTIME_HIRES) - t0;
902                                         n += 1;
903                                 }
904                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
905                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
906
907                                 delete(tmp_entity);
908                                 return;
909                         }
910                 }
911
912                 default:
913                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
914                 case CMD_REQUEST_USAGE:
915                 {
916                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
917                         LOG_HELP("See also: ^2bbox, trace^7");
918                         return;
919                 }
920         }
921 }
922
923 void GameCommand_gotomap(int request, int argc)
924 {
925         switch (request)
926         {
927                 case CMD_REQUEST_COMMAND:
928                 {
929                         if (!world_initialized)
930                         {
931                                 LOG_HELPF("This command works only when the server is running.");
932                                 return;
933                         }
934                         if (argv(1))
935                         {
936                                 LOG_INFO(GotoMap(argv(1)));
937                                 return;
938                         }
939                 }
940
941                 default:
942                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
943                 case CMD_REQUEST_USAGE:
944                 {
945                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
946                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
947                         LOG_HELP("See also: ^2gametype^7");
948                         return;
949                 }
950         }
951 }
952
953 void GameCommand_lockteams(int request)
954 {
955         switch (request)
956         {
957                 case CMD_REQUEST_COMMAND:
958                 {
959                         if (!world_initialized)
960                         {
961                                 LOG_HELPF("This command works only when the server is running.");
962                                 return;
963                         }
964                         if (teamplay)
965                         {
966                                 lockteams = 1;
967                                 bprint("^1The teams are now locked.\n");
968                         }
969                         else
970                         {
971                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
972                         }
973                         return;
974                 }
975
976                 default:
977                 case CMD_REQUEST_USAGE:
978                 {
979                         LOG_HELP("Usage:^3 sv_cmd lockteams");
980                         LOG_HELP("  No arguments required.");
981                         LOG_HELP("See also: ^2unlockteams^7");
982                         return;
983                 }
984         }
985 }
986
987 void GameCommand_make_mapinfo(int request)
988 {
989         switch (request)
990         {
991                 case CMD_REQUEST_COMMAND:
992                 {
993                         entity tmp_entity;
994
995                         tmp_entity = new(make_mapinfo);
996                         setthink(tmp_entity, make_mapinfo_Think);
997                         tmp_entity.nextthink = time;
998                         MapInfo_Enumerate();
999                         return;
1000                 }
1001
1002                 default:
1003                 case CMD_REQUEST_USAGE:
1004                 {
1005                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
1006                         LOG_HELP("  No arguments required.");
1007                         LOG_HELP("See also: ^2radarmap^7");
1008                         return;
1009                 }
1010         }
1011 }
1012
1013 void GameCommand_moveplayer(int request, int argc)
1014 {
1015         switch (request)
1016         {
1017                 case CMD_REQUEST_COMMAND:
1018                 {
1019                         if (!world_initialized)
1020                         {
1021                                 LOG_HELPF("This command works only when the server is running.");
1022                                 return;
1023                         }
1024                         float accepted;
1025                         entity client;
1026
1027                         string targets = strreplace(",", " ", argv(1));
1028                         string original_targets = strreplace(" ", ", ", targets);
1029                         string destination = argv(2);
1030                         if (destination == "spec")
1031                                 destination = "spectator";
1032
1033                         if ((targets) && (destination))
1034                         {
1035                                 string successful = string_null;
1036                                 string t;
1037                                 for ( ; targets; )
1038                                 {
1039                                         t = car(targets);
1040                                         targets = cdr(targets);
1041
1042                                         // Check to see if the player is a valid target
1043                                         client = GetFilteredEntity(t);
1044                                         accepted = VerifyClientEntity(client, false, false);
1045                                         string client_num_str = ftos(etof(client));
1046
1047                                         if (accepted <= 0)
1048                                         {
1049                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), ".");
1050                                         }
1051                                         else if (destination == "spectator")
1052                                         {
1053                                                 string pl_name = playername(client.netname, client.team, false);
1054                                                 if (!(IS_SPEC(client) || IS_OBSERVER(client)) || INGAME(client))
1055                                                 {
1056                                                         PutObserverInServer(client, true, true);
1057
1058                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1059                                                 }
1060                                                 else
1061                                                 {
1062                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already spectating.");
1063                                                 }
1064                                         }
1065                                         else
1066                                         {
1067                                                 if (!teamplay)
1068                                                 {
1069                                                         LOG_INFO("Can't change teams when currently not playing a team game.");
1070                                                         return;
1071                                                 }
1072
1073                                                 string pl_name = playername(client.netname, client.team, false);
1074                                                 if (IS_SPEC(client) || IS_OBSERVER(client))
1075                                                 {
1076                                                         // well technically we could, but should we allow that? :P
1077                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not in the game.");
1078                                                         continue;
1079                                                 }
1080
1081                                                 // set up
1082                                                 int save = Player_GetForcedTeamIndex(client);
1083                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1084
1085                                                 // find the team to move the player to
1086                                                 int team_num = Team_ColorToTeam(destination);
1087                                                 entity balance;
1088                                                 if (team_num == client.team)  // already on the destination team
1089                                                 {
1090                                                         // keep the forcing undone
1091                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already on the ", Team_ColoredFullName(team_num), "^7.");
1092                                                         continue;
1093                                                 }
1094                                                 else if (team_num == 0)  // auto team
1095                                                 {
1096                                                         balance = TeamBalance_CheckAllowedTeams(client);
1097                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1098                                                 }
1099                                                 else
1100                                                 {
1101                                                         balance = TeamBalance_CheckAllowedTeams(client);
1102                                                 }
1103                                                 Player_SetForcedTeamIndex(client, save);
1104
1105                                                 // Check to see if the destination team is even available
1106                                                 int team_id = Team_TeamToIndex(team_num);
1107                                                 if (team_id == -1)
1108                                                 {
1109                                                         LOG_INFO("Can't move player to ", destination, " team because it doesn't exist.");
1110                                                         TeamBalance_Destroy(balance);
1111                                                         return;
1112                                                 }
1113                                                 if (!IsTeamAvailable(team_num))
1114                                                 {
1115                                                         LOG_INFO("Can't move player to ", destination, " team because it isn't available.");
1116                                                         TeamBalance_Destroy(balance);
1117                                                         return;
1118                                                 }
1119                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1120                                                 {
1121                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not allowed to join the ", Team_ColoredFullName(team_num), "^7.");
1122                                                         TeamBalance_Destroy(balance);
1123                                                         continue;
1124                                                 }
1125                                                 TeamBalance_Destroy(balance);
1126
1127                                                 // If so, lets continue and finally move the player
1128                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1129                                                 if (MoveToTeam(client, team_id, 6))
1130                                                 {
1131                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1132                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") has been moved to the ", Team_ColoredFullName(team_num), "^7.");
1133                                                 }
1134                                                 else
1135                                                 {
1136                                                         LOG_INFO("Unable to move player #", client_num_str, " (", pl_name, ")");
1137                                                 }
1138                                         }
1139                                 } // loop end
1140
1141                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1142                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1143
1144                                 return;  // still correct parameters so return to avoid usage print
1145                         }
1146                 }
1147
1148                 default:
1149                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1150                 case CMD_REQUEST_USAGE:
1151                 {
1152                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1153                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1154                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1155                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1156                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1157                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1158                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1159                         return;
1160                 }
1161         }
1162 }
1163
1164 void GameCommand_nospectators(int request)
1165 {
1166         switch (request)
1167         {
1168                 case CMD_REQUEST_COMMAND:
1169                 {
1170                         if (!world_initialized)
1171                         {
1172                                 LOG_HELPF("This command works only when the server is running.");
1173                                 return;
1174                         }
1175                         blockSpectators = 1;
1176                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1177                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !INGAME(it), {
1178                                 CS(it).spectatortime = time;
1179                                 Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1180                         });
1181                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1182                         return;
1183                 }
1184
1185                 default:
1186                 case CMD_REQUEST_USAGE:
1187                 {
1188                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1189                         LOG_HELP("  No arguments required.");
1190                         return;
1191                 }
1192         }
1193 }
1194
1195 void GameCommand_printstats(int request)
1196 {
1197         switch (request)
1198         {
1199                 case CMD_REQUEST_COMMAND:
1200                 {
1201                         if (!world_initialized)
1202                         {
1203                                 LOG_HELPF("This command works only when the server is running.");
1204                                 return;
1205                         }
1206                         DumpStats(false);
1207                         LOG_INFO("stats dumped.");
1208                         return;
1209                 }
1210
1211                 default:
1212                 case CMD_REQUEST_USAGE:
1213                 {
1214                         LOG_HELP("Usage:^3 sv_cmd printstats");
1215                         LOG_HELP("  No arguments required.");
1216                         return;
1217                 }
1218         }
1219 }
1220
1221 void GameCommand_radarmap(int request, int argc)
1222 {
1223         switch (request)
1224         {
1225                 case CMD_REQUEST_COMMAND:
1226                 {
1227                         if (RadarMap_Make(argc)) return;
1228                 }
1229
1230                 default:
1231                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1232                 case CMD_REQUEST_USAGE:
1233                 {
1234                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1235                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1236                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1237                         LOG_HELP("See also: ^2make_mapinfo^7");
1238                         return;
1239                 }
1240         }
1241 }
1242
1243 void GameCommand_reducematchtime(int request)
1244 {
1245         switch (request)
1246         {
1247                 case CMD_REQUEST_COMMAND:
1248                 {
1249                         if (!world_initialized)
1250                         {
1251                                 LOG_HELPF("This command works only when the server is running.");
1252                                 return;
1253                         }
1254                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1255                         return;
1256                 }
1257
1258                 default:
1259                 case CMD_REQUEST_USAGE:
1260                 {
1261                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1262                         LOG_HELP("  No arguments required.");
1263                         LOG_HELP("See also: ^2extendmatchtime^7");
1264                         return;
1265                 }
1266         }
1267 }
1268
1269 void GameCommand_setbots(int request, int argc)
1270 {
1271         switch (request)
1272         {
1273                 case CMD_REQUEST_COMMAND:
1274                 {
1275                         if (argc >= 2)
1276                         {
1277                                 cvar_settemp("minplayers", "0");
1278                                 cvar_settemp("minplayers_per_team", "0");
1279                                 cvar_settemp("bot_number", argv(1));
1280                                 bot_fixcount(true);
1281                                 return;
1282                         }
1283                 }
1284
1285                 default:
1286                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1287                 case CMD_REQUEST_USAGE:
1288                 {
1289                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1290                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1291                         LOG_HELP("See also: ^2bot_cmd^7");
1292                         return;
1293                 }
1294         }
1295 }
1296
1297 void shuffleteams()
1298 {
1299         if (!teamplay)
1300         {
1301                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1302                 return;
1303         }
1304
1305         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1306                 if (Player_HasRealForcedTeam(it)) {
1307                         // we could theoretically assign forced players to their teams
1308                         // and shuffle the rest to fill the empty spots but in practise
1309                         // either all players or none are gonna have forced teams
1310                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1311                         return;
1312                 }
1313         });
1314
1315         int number_of_teams = 0;
1316         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1317         for (int i = 1; i <= NUM_TEAMS; ++i)
1318         {
1319                 if (TeamBalance_IsTeamAllowed(balance, i))
1320                 {
1321                         number_of_teams = max(i, number_of_teams);
1322                 }
1323         }
1324         TeamBalance_Destroy(balance);
1325
1326         int team_index = 0;
1327         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || INGAME(it), {
1328                 int target_team_index = team_index + 1;
1329                 if (Entity_GetTeamIndex(it) != target_team_index)
1330                 {
1331                         MoveToTeam(it, target_team_index, 6);
1332                 }
1333                 team_index = (team_index + 1) % number_of_teams;
1334         });
1335
1336         bprint("Successfully shuffled the players around randomly.\n");
1337 }
1338
1339 void GameCommand_shuffleteams(int request)
1340 {
1341         switch (request)
1342         {
1343                 case CMD_REQUEST_COMMAND:
1344                 {
1345                         if (!world_initialized)
1346                         {
1347                                 LOG_HELPF("This command works only when the server is running.");
1348                                 return;
1349                         }
1350                         if (shuffleteams_on_reset_map)
1351                         {
1352                                 bprint("Players will be shuffled when this round is over.\n");
1353                                 shuffleteams_on_reset_map = true;
1354                         }
1355                         else
1356                                 shuffleteams();
1357                         return;
1358                 }
1359
1360                 default:
1361                 case CMD_REQUEST_USAGE:
1362                 {
1363                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1364                         LOG_HELP("  No arguments required.");
1365                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1366                         return;
1367                 }
1368         }
1369 }
1370
1371 void GameCommand_resetmatch(int request)
1372 {
1373         switch (request)
1374         {
1375                 case CMD_REQUEST_COMMAND:
1376                 {
1377                         if (!world_initialized)
1378                         {
1379                                 LOG_HELPF("This command works only when the server is running.");
1380                                 return;
1381                         }
1382                         ReadyRestart(false);
1383                         return;
1384                 }
1385
1386                 default:
1387                 case CMD_REQUEST_USAGE:
1388                 {
1389                         LOG_HELP("Usage:^3 sv_cmd resetmatch");
1390                         LOG_HELP("  No arguments required.");
1391                         return;
1392                 }
1393         }
1394 }
1395
1396 void GameCommand_stuffto(int request, int argc)
1397 {
1398         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1399         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1400         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1401
1402 #ifdef STUFFTO_ENABLED
1403                 switch (request)
1404                 {
1405                         case CMD_REQUEST_COMMAND:
1406                         {
1407                                 if (!world_initialized)
1408                                 {
1409                                         LOG_HELPF("This command works only when the server is running.");
1410                                         return;
1411                                 }
1412                                 if (argv(2))
1413                                 {
1414                                         entity client = GetIndexedEntity(argc, 1);
1415                                         float accepted = VerifyClientEntity(client, true, false);
1416
1417                                         if (accepted > 0)
1418                                         {
1419                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1420                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1421                                         }
1422                                         else
1423                                         {
1424                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1425                                         }
1426
1427                                         return;
1428                                 }
1429                         }
1430
1431                         default:
1432                                 LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1433                         case CMD_REQUEST_USAGE:
1434                         {
1435                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1436                                 LOG_HELP("  <client> is the entity number or name of the player,");
1437                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1438                                 return;
1439                         }
1440                 }
1441 #else
1442                 if (request)
1443                 {
1444                         LOG_HELP("stuffto command is not enabled on this server.");
1445                         return;
1446                 }
1447 #endif
1448 }
1449
1450 void GameCommand_trace(int request, int argc)
1451 {
1452         switch (request)
1453         {
1454                 case CMD_REQUEST_COMMAND:
1455                 {
1456                         entity e;
1457                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1458                         float i, f, safe, unsafe, dq, dqf;
1459
1460                         switch (argv(1))
1461                         {
1462                                 case "debug":
1463                                 {
1464                                         float hitcount = 0;
1465                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1466                                         float worst_endpos_bug = 0;
1467                                         for ( ; ; )
1468                                         {
1469                                                 org = world.mins;
1470                                                 delta = world.maxs - world.mins;
1471
1472                                                 start.x = org.x + random() * delta.x;
1473                                                 start.y = org.y + random() * delta.y;
1474                                                 start.z = org.z + random() * delta.z;
1475
1476                                                 end.x = org.x + random() * delta.x;
1477                                                 end.y = org.y + random() * delta.y;
1478                                                 end.z = org.z + random() * delta.z;
1479
1480                                                 start = stov(vtos(start));
1481                                                 end = stov(vtos(end));
1482
1483                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1484                                                 if (!trace_startsolid && trace_fraction < 1)
1485                                                 {
1486                                                         p = trace_endpos;
1487                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1488                                                         if (trace_startsolid)
1489                                                         {
1490                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1491                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1492
1493                                                                 // how much do we need to back off?
1494                                                                 safe = 1;
1495                                                                 unsafe = 0;
1496                                                                 for ( ; ; )
1497                                                                 {
1498                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1499                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1500                                                                         if (trace_startsolid)
1501                                                                         {
1502                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1503                                                                                 unsafe = (safe + unsafe) * 0.5;
1504                                                                         }
1505                                                                         else
1506                                                                         {
1507                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1508                                                                                 safe = (safe + unsafe) * 0.5;
1509                                                                         }
1510                                                                 }
1511
1512                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1513                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1514
1515                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1516                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1517                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1518                                                                 if (++hitcount >= 10) break;
1519                                                         }
1520                                                         else
1521                                                         {
1522                                                                 q0 = p;
1523                                                                 dq = 0;
1524                                                                 dqf = 1;
1525                                                                 for ( ; ; )
1526                                                                 {
1527                                                                         q = p + normalize(end - p) * (dq + dqf);
1528                                                                         if (q == q0) break;
1529                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1530                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1531                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1532                                                                         dqf *= 0.5;
1533                                                                         q0 = q;
1534                                                                 }
1535                                                                 if (dq > worst_endpos_bug)
1536                                                                 {
1537                                                                         worst_endpos_bug = dq;
1538                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1539                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1540                                                                         if (++hitcount >= 10) break;
1541                                                                 }
1542                                                         }
1543                                                 }
1544                                         }
1545                                         return;
1546                                 }
1547
1548                                 case "debug2":
1549                                 {
1550                                         e = nextent(NULL);
1551                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1552                                         vv = trace_endpos;
1553                                         if (trace_fraction == 1)
1554                                         {
1555                                                 LOG_INFO("not above ground, aborting");
1556                                                 return;
1557                                         }
1558                                         f = 0;
1559                                         for (i = 0; i < 100000; ++i)
1560                                         {
1561                                                 dv = randomvec();
1562                                                 if (dv.z > 0) dv = -1 * dv;
1563                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1564                                                 if (trace_startsolid) LOG_INFO("bug 1");
1565                                                 if (trace_fraction == 1)
1566                                                 {
1567                                                         if (dv.z < f)
1568                                                         {
1569                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1570                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1571                                                                 f = dv.z;
1572                                                         }
1573                                                 }
1574                                         }
1575                                         LOG_INFO("highest possible dist: ", ftos(f));
1576                                         return;
1577                                 }
1578
1579                                 case "walk":
1580                                 {
1581                                         if (argc == 4 || argc == 5)
1582                                         {
1583                                                 e = nextent(NULL);
1584                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1585                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1586                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1587                                                         LOG_INFO("can walk");
1588                                                 else
1589                                                         LOG_INFO("cannot walk");
1590                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1591                                                 return;
1592                                         }
1593                                 }
1594
1595                                 case "showline":
1596                                 {
1597                                         if (argc == 4)
1598                                         {
1599                                                 vv = stov(argv(2));
1600                                                 dv = stov(argv(3));
1601                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1602                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1603                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1604                                                 return;
1605                                         }
1606                                 }
1607
1608                                 // no default case, just go straight to invalid
1609                         }
1610                 }
1611
1612                 default:
1613                         LOG_HELPF("Incorrect parameters for ^2%s^7", argv(0));
1614                 case CMD_REQUEST_USAGE:
1615                 {
1616                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1617                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1618                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1619                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1620                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1621                         return;
1622                 }
1623         }
1624 }
1625
1626 void GameCommand_unlockteams(int request)
1627 {
1628         switch (request)
1629         {
1630                 case CMD_REQUEST_COMMAND:
1631                 {
1632                         if (!world_initialized)
1633                         {
1634                                 LOG_HELPF("This command works only when the server is running.");
1635                                 return;
1636                         }
1637                         if (teamplay)
1638                         {
1639                                 lockteams = 0;
1640                                 bprint("^1The teams are now unlocked.\n");
1641                         }
1642                         else
1643                         {
1644                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1645                         }
1646                         return;
1647                 }
1648
1649                 default:
1650                 case CMD_REQUEST_USAGE:
1651                 {
1652                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1653                         LOG_HELP("  No arguments required.");
1654                         LOG_HELP("See also: ^2lockteams^7");
1655                         return;
1656                 }
1657         }
1658 }
1659
1660 void GameCommand_warp(int request, int argc)
1661 {
1662         switch (request)
1663         {
1664                 case CMD_REQUEST_COMMAND:
1665                 {
1666                         if (!world_initialized)
1667                         {
1668                                 LOG_HELPF("This command works only when the server is running.");
1669                                 return;
1670                         }
1671                         if (autocvar_g_campaign)
1672                         {
1673                                 if (argc >= 2)
1674                                 {
1675                                         CampaignLevelWarp(stof(argv(1)));
1676                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1677                                 }
1678                                 else
1679                                 {
1680                                         CampaignLevelWarp(-1);
1681                                         LOG_INFO("Successfully warped to next campaign level.");
1682                                 }
1683                         }
1684                         else
1685                         {
1686                                 LOG_INFO("Not in campaign, can't level warp");
1687                         }
1688                         return;
1689                 }
1690
1691                 default:
1692                 case CMD_REQUEST_USAGE:
1693                 {
1694                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1695                         LOG_HELP("  <level> is the level to change campaign mode to.");
1696                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1697                         return;
1698                 }
1699         }
1700 }
1701
1702 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1703 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1704 void GameCommand_(int request)
1705 {
1706     switch(request)
1707     {
1708         case CMD_REQUEST_COMMAND:
1709         {
1710                     if (!world_initialized)
1711                     {
1712                         LOG_HELPF("This command works only when the server is running.");
1713                         return;
1714                     }
1715
1716             return;
1717         }
1718
1719         default:
1720         case CMD_REQUEST_USAGE:
1721         {
1722             LOG_HELP("Usage:^3 sv_cmd ");
1723             LOG_HELP("  No arguments required.");
1724             return;
1725         }
1726     }
1727 }
1728 */
1729
1730
1731 // ==================================
1732 //  Macro system for server commands
1733 // ==================================
1734
1735 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1736 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1737 SERVER_COMMAND(allready, "Ends warmup and starts the match") { GameCommand_allready(request); }
1738 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1739 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1740 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1741 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1742 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1743 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1744 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1745 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1746 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1747 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1748 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1749 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1750 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1751 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1752 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1753 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1754 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1755 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1756 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1757 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1758 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1759 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1760 SERVER_COMMAND(resetmatch, "Soft restart the game without changing teams; goes back to warmup if enabled") { GameCommand_resetmatch(request); }
1761 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1762 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1763 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1764 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1765 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1766 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1767
1768 void GameCommand_macro_help()
1769 {
1770         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1771 }
1772
1773 float GameCommand_macro_command(int argc, string command)
1774 {
1775         string c = strtolower(argv(0));
1776         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1777                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1778                 return true;
1779         });
1780         return false;
1781 }
1782
1783 float GameCommand_macro_usage(int argc)
1784 {
1785         string c = strtolower(argv(1));
1786         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1787                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1788                 return true;
1789         });
1790         return false;
1791 }
1792
1793 void GameCommand_macro_write_aliases(float fh)
1794 {
1795         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1796 }
1797
1798
1799 // =========================================
1800 //  Main Function Called By Engine (sv_cmd)
1801 // =========================================
1802 // If this function exists, game code handles gamecommand instead of the engine code.
1803
1804 void GameCommand(string command)
1805 {
1806         int argc = tokenize_console(command);
1807
1808         // Guide for working with argc arguments by example:
1809         // argc:   1    - 2      - 3     - 4
1810         // argv:   0    - 1      - 2     - 3
1811         // cmd     vote - master - login - password
1812
1813         if (strtolower(argv(0)) == "help")
1814         {
1815                 if (argc == 1)
1816                 {
1817                         LOG_HELP("Server console commands:");
1818                         GameCommand_macro_help();
1819
1820                         LOG_HELP("\nBanning commands:");
1821                         BanCommand_macro_help();
1822
1823                         LOG_HELP("\nCommon networked commands:");
1824                         CommonCommand_macro_help(NULL);
1825
1826                         LOG_HELP("\nGeneric commands shared by all programs:");
1827                         GenericCommand_macro_help();
1828
1829                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1830                                 "For help about a specific command, type sv_cmd help <command>");
1831
1832                         return;
1833                 }
1834                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1835                 {
1836                         return;
1837                 }
1838                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1839                 {
1840                         return;
1841                 }
1842                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1843                 {
1844                         return;
1845                 }
1846                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1847                 {
1848                         return;
1849                 }
1850         }
1851         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1852         {
1853                 return;  // handled by a mutator
1854         }
1855         else if (BanCommand(command))
1856         {
1857                 return;  // handled by server/command/ipban.qc
1858         }
1859         else if (CommonCommand_macro_command(argc, NULL, command))
1860         {
1861                 return;  // handled by server/command/common.qc
1862         }
1863         else if (GenericCommand(command))
1864         {
1865                 return;                                        // handled by common/command/generic.qc
1866         }
1867         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1868         {
1869                 return;                                        // handled by one of the above GameCommand_* functions
1870         }
1871
1872         // nothing above caught the command, must be invalid
1873         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1874 }