qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/gamemodes/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/triggers.qh>
  10 #include <common/minigames/sv_minigames.qh>
  11 #include <common/monsters/_mod.qh>
  12 #include <common/monsters/sv_monsters.qh>
  13 #include <common/monsters/sv_spawn.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/physics/player.qh>
  16 #include <common/teams.qh>
  17 #include <common/util.qh>
  18 #include <common/vehicles/all.qh>
  19 #include <lib/warpzone/common.qh>
  20 #include <server/bot/api.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/chat.qh>
  24 #include <server/cheats.qh>
  25 #include <server/client.qh>
  26 #include <server/clientkill.qh>
  27 #include <server/command/common.qh>
  28 #include <server/command/getreplies.qh>
  29 #include <server/command/vote.qh>
  30 #include <server/ipban.qh>
  31 #include <server/mapvoting.qh>
  32 #include <server/mutators/_mod.qh>
  33 #include <server/player.qh>
  34 #include <server/scores.qh>
  35 #include <server/teamplay.qh>
  36 #include <server/world.qh>
  37
  38 // =========================================================
  39 //  Server side networked commands code, reworked by Samual
  40 //  Last updated: December 28th, 2011
  41 // =========================================================
  42
  43 bool SV_ParseClientCommand_floodcheck(entity this)
  44 {
  45         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  46
  47         if (!timeout_status)  // not while paused
  48         {
  49                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  50                 {
  51                         store.cmd_floodcount += 1;
  52                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  53                 }
  54                 else
  55                 {
  56                         store.cmd_floodtime = time;
  57                         store.cmd_floodcount = 1;
  58                 }
  59         }
  60         return true;  // continue, as we're not flooding yet
  61 }
  62
  63
  64 // =======================
  65 //  Command Sub-Functions
  66 // =======================
  67
  68 void ClientCommand_autoswitch(entity caller, int request, int argc)
  69 {
  70         switch (request)
  71         {
  72                 case CMD_REQUEST_COMMAND:
  73                 {
  74                         if (argv(1) != "")
  75                         {
  76                                 CS_CVAR(caller).autoswitch = InterpretBoolean(argv(1));
  77                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS_CVAR(caller).autoswitch ? "on" : "off"), ".\n"));
  78                                 return;
  79                         }
  80                 }
  81
  82                 default:
  83                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  84                 case CMD_REQUEST_USAGE:
  85                 {
  86                         sprint(caller, "\nUsage:^3 cmd autoswitch <selection>\n");
  87                         sprint(caller, "  Where <selection> controls if autoswitch is on or off.\n");
  88                         return;
  89                 }
  90         }
  91 }
  92
  93 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
  94 {
  95         switch (request)
  96         {
  97                 case CMD_REQUEST_COMMAND:
  98                 {
  99                         if (argv(1) != "")
 100                         {
 101                                 if (IS_CLIENT(caller))
 102                                 {
 103                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 104
 105                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 106                                         {
 107                                                 CS(caller).version_mismatch = true;
 108                                                 ClientKill_TeamChange(caller, -2);  // observe
 109                                         }
 110                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 111                                         {
 112                                                 // JoinBestTeam(caller, false, true);
 113                                         }
 114                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 115                                         {
 116                                                 TRANSMUTE(Observer, caller);  // really?
 117                                                 stuffcmd(caller, "menu_showteamselect\n");
 118                                         }
 119                                 }
 120
 121                                 return;
 122                         }
 123                 }
 124
 125                 default:
 126                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 127                 case CMD_REQUEST_USAGE:
 128                 {
 129                         sprint(caller, "\nUsage:^3 cmd clientversion <version>\n");
 130                         sprint(caller, "  Where <version> is the game version reported by caller.\n");
 131                         return;
 132                 }
 133         }
 134 }
 135
 136 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 137 {
 138         switch (request)
 139         {
 140                 case CMD_REQUEST_COMMAND:
 141                 {
 142                         if (argv(1) != "")
 143                         {
 144                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 145
 146                                 return;
 147                         }
 148                 }
 149
 150                 default:
 151                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 152                 case CMD_REQUEST_USAGE:
 153                 {
 154                         sprint(caller, "\nUsage:^3 cmd mv_getpicture <mapid>\n");
 155                         sprint(caller, "  Where <mapid> is the id number of the map to request an image of on the map vote selection menu.\n");
 156                         return;
 157                 }
 158         }
 159 }
 160
 161 void ClientCommand_wpeditor(entity caller, int request, int argc)
 162 {
 163         switch (request)
 164         {
 165                 case CMD_REQUEST_COMMAND:
 166                 {
 167                         if (!waypointeditor_enabled)
 168                         {
 169                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 170                                 return;
 171                         }
 172
 173                         if (argv(1) != "")
 174                         {
 175                                 if (argv(1) == "spawn")
 176                                 {
 177                                         string s = argv(2);
 178                                         if (!IS_PLAYER(caller))
 179                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 180                                         else
 181                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 182                                         return;
 183                                 }
 184                                 else if (argv(1) == "remove")
 185                                 {
 186                                         if (!IS_PLAYER(caller))
 187                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 188                                         else
 189                                                 waypoint_remove_fromeditor(caller);
 190                                         return;
 191                                 }
 192                                 else if (argv(1) == "hardwire")
 193                                 {
 194                                         string s = argv(2);
 195                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 196                                         return;
 197                                 }
 198                                 else if (argv(1) == "lock")
 199                                 {
 200                                         waypoint_lock(caller);
 201                                         return;
 202                                 }
 203                                 else if (argv(1) == "unreachable")
 204                                 {
 205                                         if (!IS_PLAYER(caller))
 206                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 207                                         else
 208                                                 waypoint_unreachable(caller);
 209                                         return;
 210                                 }
 211                                 else if (argv(1) == "saveall")
 212                                 {
 213                                         waypoint_saveall();
 214                                         return;
 215                                 }
 216                                 else if (argv(1) == "relinkall")
 217                                 {
 218                                         waypoint_schedulerelinkall();
 219                                         return;
 220                                 }
 221                                 else if (argv(1) == "symaxis")
 222                                 {
 223                                         if (argv(2) == "set" || argv(2) == "get")
 224                                         {
 225                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 226                                                 return;
 227                                         }
 228                                 }
 229                                 else if (argv(1) == "symorigin")
 230                                 {
 231                                         if (argv(2) == "set" || argv(2) == "get")
 232                                         {
 233                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 234                                                 return;
 235                                         }
 236                                 }
 237                         }
 238                 }
 239
 240                 default:
 241                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 242                 case CMD_REQUEST_USAGE:
 243                 {
 244                         sprint(caller, "\nUsage:^3 cmd wpeditor <action>\n");
 245                         sprint(caller, "  Where <action> can be:\n");
 246                         sprint(caller, "   ^2spawn^7: spawns a waypoint at player's position\n");
 247                         sprint(caller, "   ^2remove^7: removes player's nearest waypoint\n");
 248                         sprint(caller, "   ^2unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 249                         sprint(caller, "   ^2saveall^7: saves all waypoints and links to file\n");
 250                         sprint(caller, "   ^2relinkall^7: relinks all waypoints as if they were respawned\n");
 251                         sprint(caller, "   ^2spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 252                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 253                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 254                         sprint(caller, "   ^2spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 255                         sprint(caller, "   ^2spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 256                         sprint(caller, "   ^2spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 257                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 258                         sprint(caller, "   ^2hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 259                         sprint(caller, "   ^2hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 260                         sprint(caller, "   ^2lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 261                         sprint(caller, "   ^2symorigin get|set\n");
 262                         sprint(caller, "   ^2symorigin get|set <p1> <p2> ... <pX>\n");
 263                         sprint(caller, "   ^2symaxis get|set <p1> <p2>\n");
 264                         sprint(caller, "   ^7 where <p1> <p2> ... <pX> are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 265                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 266                         sprint(caller, "  See ^5wpeditor_menu^7 for a selectable list of various commands and useful settings to edit waypoints.\n");
 267                         return;
 268                 }
 269         }
 270 }
 271
 272 void ClientCommand_join(entity caller, int request)
 273 {
 274         switch (request)
 275         {
 276                 case CMD_REQUEST_COMMAND:
 277                 {
 278                         if (!game_stopped && !game_timeout && IS_CLIENT(caller) && !IS_PLAYER(caller))
 279                         {
 280                                 if (joinAllowed(caller))
 281                                         Join(caller);
 282                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 283                                         CS(caller).autojoin_checked = -1;
 284                         }
 285
 286                         return;  // never fall through to usage
 287                 }
 288
 289                 default:
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         sprint(caller, "\nUsage:^3 cmd join\n");
 293                         sprint(caller, "  No arguments required.\n");
 294                         return;
 295                 }
 296         }
 297 }
 298
 299 void ClientCommand_kill(entity caller, int request)
 300 {
 301         switch (request)
 302         {
 303                 case CMD_REQUEST_COMMAND:
 304                 {
 305                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 306                                 return; // no point warning about this, command does nothing
 307
 308                         if(GetResource(caller, RES_HEALTH) <= 0)
 309                         {
 310                                 sprint(caller, "Can't die - you are already dead!\n");
 311                                 return;
 312                         }
 313
 314                         ClientKill(caller);
 315
 316                         return;  // never fall through to usage
 317                 }
 318
 319                 default:
 320                 case CMD_REQUEST_USAGE:
 321                 {
 322                         sprint(caller, "\nUsage:^3 cmd kill\n");
 323                         sprint(caller, "  No arguments required.\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void ClientCommand_physics(entity caller, int request, int argc)
 330 {
 331         switch (request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         string command = strtolower(argv(1));
 336
 337                         if (!autocvar_g_physics_clientselect)
 338                         {
 339                                 sprint(caller, "Client physics selection is currently disabled.\n");
 340                                 return;
 341                         }
 342
 343                         if (command == "list" || command == "help")
 344                         {
 345                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 346                                 return;
 347                         }
 348
 349                         if (Physics_Valid(command) || command == "default")
 350                         {
 351                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 352                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 353                                 return;
 354                         }
 355                 }
 356
 357                 default:
 358                         sprint(caller, strcat("Current physics set: ^3", CS_CVAR(caller).cvar_cl_physics, "\n"));
 359                 case CMD_REQUEST_USAGE:
 360                 {
 361                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 362                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 363                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 364                         return;
 365                 }
 366         }
 367 }
 368
 369 void ClientCommand_ready(entity caller, int request)
 370 {
 371         switch (request)
 372         {
 373                 case CMD_REQUEST_COMMAND:
 374                 {
 375                         if (IS_CLIENT(caller) && caller.last_ready < time - 3) // anti-spam
 376                         {
 377                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 378                                 {
 379                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 380                                         {
 381                                                 if (time < game_starttime) // game is already restarting
 382                                                         return;
 383                                                 if (caller.ready)            // toggle
 384                                                 {
 385                                                         caller.ready = false;
 386                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 387                                                                 bprint("\{1}", playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
 388                                                 }
 389                                                 else
 390                                                 {
 391                                                         caller.ready = true;
 392                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 393                                                                 bprint("\{1}", playername(caller.netname, caller.team, false), "^2 is ready\n");
 394                                                 }
 395
 396                                                 caller.last_ready = time;
 397
 398                                                 // cannot reset the game while a timeout is active!
 399                                                 if (!timeout_status) ReadyCount();
 400                                         }
 401                                         else
 402                                         {
 403                                                 sprint(caller, "^1Game has already been restarted\n");
 404                                         }
 405                                 }
 406                         }
 407                         return;  // never fall through to usage
 408                 }
 409
 410                 default:
 411                 case CMD_REQUEST_USAGE:
 412                 {
 413                         sprint(caller, "\nUsage:^3 cmd ready\n");
 414                         sprint(caller, "  No arguments required.\n");
 415                         return;
 416                 }
 417         }
 418 }
 419
 420 void ClientCommand_say(entity caller, int request, int argc, string command)
 421 {
 422         switch (request)
 423         {
 424                 case CMD_REQUEST_COMMAND:
 425                 {
 426                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 427                         return;  // never fall through to usage
 428                 }
 429
 430                 default:
 431                 case CMD_REQUEST_USAGE:
 432                 {
 433                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 434                         sprint(caller, "  Where <message> is the string of text to say.\n");
 435                         return;
 436                 }
 437         }
 438 }
 439
 440 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 441 {
 442         switch (request)
 443         {
 444                 case CMD_REQUEST_COMMAND:
 445                 {
 446                         if (argc >= 2)
 447                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 448                         return;  // never fall through to usage
 449                 }
 450
 451                 default:
 452                 case CMD_REQUEST_USAGE:
 453                 {
 454                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 455                         sprint(caller, "  Where <message> is the string of text to say.\n");
 456                         return;
 457                 }
 458         }
 459 }
 460
 461 .bool team_selected;
 462 void ClientCommand_selectteam(entity caller, int request, int argc)
 463 {
 464         switch (request)
 465         {
 466                 case CMD_REQUEST_COMMAND:
 467                 {
 468                         if (argv(1) == "")
 469                         {
 470                                 return;
 471                         }
 472                         if (!IS_CLIENT(caller))
 473                         {
 474                                 return;
 475                         }
 476                         if (!teamplay)
 477                         {
 478                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 479                                 return;
 480                         }
 481                         if (Player_GetForcedTeamIndex(caller) > 0)
 482                         {
 483                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 484                                 return;
 485                         }
 486                         if (lockteams)
 487                         {
 488                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 489                                 return;
 490                         }
 491
 492                         float team_num = Team_ColorToTeam(argv(1));
 493                         if (team_num == -1) // invalid
 494                                 return;
 495                         if (caller.team == team_num && team_num && !IS_DEAD(caller))
 496                         {
 497                                 sprint(caller, "^7You already are on that team.\n");
 498                                 return;
 499                         }
 500                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 501                         {
 502                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 503                                 return;
 504                         }
 505                         if (team_num && autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 506                         {
 507                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 508                                 TeamBalance_GetTeamCounts(balance, caller);
 509                                 if ((Team_IndexToBit(Team_TeamToIndex(team_num)) &
 510                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 511                                 {
 512                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 513                                         TeamBalance_Destroy(balance);
 514                                         return;
 515                                 }
 516                                 TeamBalance_Destroy(balance);
 517                         }
 518                         if (team_num)
 519                                 ClientKill_TeamChange(caller, team_num);
 520                         else // auto
 521                                 ClientKill_TeamChange(caller, -1);
 522
 523                         if (!IS_PLAYER(caller))
 524                         {
 525                                 caller.team_selected = true; // avoids asking again for team selection on join
 526                         }
 527                         return;
 528                 }
 529                 default:
 530                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 531                 case CMD_REQUEST_USAGE:
 532                 {
 533                         sprint(caller, "\nUsage:^3 cmd selectteam <team>\n");
 534                         sprint(caller, "  Where <team> is the prefered team to try and join.\n");
 535                         sprint(caller, "  Full list of options here: red, blue, yellow, pink, auto.\n");
 536                         return;
 537                 }
 538         }
 539 }
 540
 541 void ClientCommand_selfstuff(entity caller, int request, string command)
 542 {
 543         switch (request)
 544         {
 545                 case CMD_REQUEST_COMMAND:
 546                 {
 547                         if (argv(1) != "")
 548                         {
 549                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 550                                 return;
 551                         }
 552                 }
 553
 554                 default:
 555                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 556                 case CMD_REQUEST_USAGE:
 557                 {
 558                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 559                         sprint(caller, "  Where <command> is the string to be stuffed to your client.\n");
 560                         return;
 561                 }
 562         }
 563 }
 564
 565 void ClientCommand_sentcvar(entity caller, int request, int argc)
 566 {
 567         switch (request)
 568         {
 569                 case CMD_REQUEST_COMMAND:
 570                 {
 571                         if (argc >= 3)
 572                         {
 573                         // NOTE: client-side settings do not exist on the server, this functionality has been deprecated
 574                         #if 0
 575                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 576                                 {
 577                                         string s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 578                                         tokenize_console(s);
 579                                 }
 580                         #endif
 581
 582                                 GetCvars(caller, CS_CVAR(caller), 1);
 583
 584                                 return;
 585                         }
 586                 }
 587
 588                 default:
 589                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 590                 case CMD_REQUEST_USAGE:
 591                 {
 592                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar> <arguments>\n");
 593                         sprint(caller, "  Where <cvar> is the cvar plus arguments to send to the server.\n");
 594                         return;
 595                 }
 596         }
 597 }
 598
 599 void ClientCommand_spectate(entity caller, int request)
 600 {
 601         switch (request)
 602         {
 603                 case CMD_REQUEST_COMMAND:
 604                 {
 605                         if (!intermission_running && IS_CLIENT(caller) && !game_timeout)
 606                         {
 607                                 if(argv(1) != "")
 608                                 {
 609                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 610                                         {
 611                                                 entity client = GetFilteredEntity(argv(1));
 612                                                 int spec_accepted = VerifyClientEntity(client, false, false);
 613                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 614                                                 {
 615                                                         bool caller_is_observer = (IS_OBSERVER(caller));
 616                                                         Spectate(caller, client);
 617                                                         if (caller_is_observer)
 618                                                                 TRANSMUTE(Spectator, caller);
 619                                                 }
 620                                                 else
 621                                                         sprint(caller, "Can't spectate ", argv(1), "^7\n");
 622                                         }
 623                                         else
 624                                                 sprint(caller, "cmd spectate <client> only works when you are spectator/observer\n");
 625                                         return;
 626                                 }
 627
 628                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 629
 630                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 631
 632                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 633                                 if (autocvar_sv_spectate == 1)
 634                                         ClientKill_TeamChange(caller, -2); // observe
 635                         }
 636                         return; // never fall through to usage
 637                 }
 638
 639                 default:
 640                 case CMD_REQUEST_USAGE:
 641                 {
 642                         sprint(caller, "\nUsage:^3 cmd spectate [<client>]\n");
 643                         sprint(caller, "  Where <client> can be the player to spectate.\n");
 644                         return;
 645                 }
 646         }
 647 }
 648
 649 void ClientCommand_sounds(entity caller, int request)
 650 {
 651         switch (request)
 652         {
 653                 case CMD_REQUEST_COMMAND:
 654                 {
 655                         sprint(caller, strcat("Available sounds: \n\n", autocvar_sv_chat_sounds_list, "\n"));
 656                         return; // never fall through to usage
 657                 }
 658
 659                 default:
 660                 case CMD_REQUEST_USAGE:
 661                 {
 662                         sprint(caller, "\nUsage:^3 cmd sounds\n");
 663                         return;
 664                 }
 665         }
 666 }
 667
 668 void ClientCommand_suggestmap(entity caller, int request, int argc)
 669 {
 670         switch (request)
 671         {
 672                 case CMD_REQUEST_COMMAND:
 673                 {
 674                         if (argv(1) != "")
 675                         {
 676                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 677                                 return;
 678                         }
 679                 }
 680
 681                 default:
 682                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 683                 case CMD_REQUEST_USAGE:
 684                 {
 685                         sprint(caller, "\nUsage:^3 cmd suggestmap <map>\n");
 686                         sprint(caller, "  Where <map> is the name of the map to suggest.\n");
 687                         return;
 688                 }
 689         }
 690 }
 691
 692 void ClientCommand_tell(entity caller, int request, int argc, string command)
 693 {
 694         switch (request)
 695         {
 696                 case CMD_REQUEST_COMMAND:
 697                 {
 698                         if (argc >= 3)
 699                         {
 700                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 701                                 {
 702                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 703                                         return;
 704                                 }
 705
 706                                 entity tell_to = GetIndexedEntity(argc, 1);
 707                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 708
 709                                 if (tell_accepted > 0)   // the target is a real client
 710                                 {
 711                                         if (tell_to != caller) // and we're allowed to send to them :D
 712                                         {
 713                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 714                                                 // In this case when the player name contains utf8 chars
 715                                                 // the message gets partially trimmed in the beginning.
 716                                                 // Potentially this bug affects any substring call that uses
 717                                                 // argv_start_index and argv_end_index.
 718
 719                                                 string utf8_enable_save = cvar_string("utf8_enable");
 720                                                 cvar_set("utf8_enable", "0");
 721                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 722                                                 cvar_set("utf8_enable", utf8_enable_save);
 723
 724                                                 Say(caller, false, tell_to, msg, true);
 725                                                 return;
 726                                         }
 727                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 728                                 }
 729                                 else if (argv(1) == "#0")
 730                                 {
 731                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 732                                         return;
 733                                 }
 734                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 735                         }
 736                 }
 737
 738                 default:
 739                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 740                 case CMD_REQUEST_USAGE:
 741                 {
 742                         sprint(caller, "\nUsage:^3 cmd tell <client> <message>\n");
 743                         sprint(caller, "  Where <client> is the entity number or name of the player to send <message> to.\n");
 744                         return;
 745                 }
 746         }
 747 }
 748
 749 void ClientCommand_voice(entity caller, int request, int argc, string command)
 750 {
 751         switch (request)
 752         {
 753                 case CMD_REQUEST_COMMAND:
 754                 {
 755                         if (argv(1) != "")
 756                         {
 757                                 entity e = GetVoiceMessage(argv(1));
 758                                 if (!e)
 759                                 {
 760                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 761                                         return;
 762                                 }
 763                                 if (IS_DEAD(caller))
 764                                 {
 765                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 766                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 767                                         return;
 768                                 }
 769                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 770                                 {
 771                                         // observers/spectators have no player model of their own to play taunts from
 772                                         // again, allow them to see warnings
 773                                         return;
 774                                 }
 775                                 string msg = "";
 776                                 if (argc >= 3)
 777                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 778                                 VoiceMessage(caller, e, msg);
 779
 780                                 return;
 781                         }
 782                 }
 783
 784                 default:
 785                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 786                 case CMD_REQUEST_USAGE:
 787                 {
 788                         sprint(caller, "\nUsage:^3 cmd voice <voicetype> [<message>]\n");
 789                         sprint(caller, "  <voicetype> is the type of voice message, it can be one of these:\n");
 790                         sprint(caller, sprintf("   %s\n", allvoicesamples));
 791                         sprint(caller, "  and <message> is the text message to send.\n");
 792                         return;
 793                 }
 794         }
 795 }
 796
 797 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 798 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 799 void ClientCommand_(entity caller, int request)
 800 {
 801     switch(request)
 802     {
 803         case CMD_REQUEST_COMMAND:
 804         {
 805
 806             return; // never fall through to usage
 807         }
 808
 809         default:
 810         case CMD_REQUEST_USAGE:
 811         {
 812             sprint(caller, "\nUsage:^3 cmd \n");
 813             sprint(caller, "  No arguments required.\n");
 814             return;
 815         }
 816     }
 817 }
 818 */
 819
 820
 821 // =====================================
 822 //  Macro system for networked commands
 823 // =====================================
 824
 825 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 826 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 827         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 828         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 829         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 830         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 831         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 832         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 833         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 834         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 835         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 836         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 837         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 838         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 839         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments), "New system for sending a client cvar to the server") \
 840         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 841         CLIENT_COMMAND("sounds", ClientCommand_sounds(ent, request), "Get list of commsnds") \
 842         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 843         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 844         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 845         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 846         /* nothing */
 847
 848 void ClientCommand_macro_help(entity caller)
 849 {
 850         #define CLIENT_COMMAND(name, function, description) \
 851                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 852
 853         CLIENT_COMMANDS(NULL, 0, 0, "");
 854 #undef CLIENT_COMMAND
 855 }
 856
 857 float ClientCommand_macro_command(int argc, entity caller, string command)
 858 {
 859         #define CLIENT_COMMAND(name, function, description) \
 860                 { if (name == strtolower(argv(0))) { function; return true; } }
 861
 862         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 863 #undef CLIENT_COMMAND
 864
 865         return false;
 866 }
 867
 868 float ClientCommand_macro_usage(int argc, entity caller)
 869 {
 870         #define CLIENT_COMMAND(name, function, description) \
 871                 { if (name == strtolower(argv(1))) { function; return true; } }
 872
 873         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 874 #undef CLIENT_COMMAND
 875
 876         return false;
 877 }
 878
 879 void ClientCommand_macro_write_aliases(float fh)
 880 {
 881         #define CLIENT_COMMAND(name, function, description) \
 882                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 883
 884         CLIENT_COMMANDS(NULL, 0, 0, "");
 885 #undef CLIENT_COMMAND
 886 }
 887
 888 // ======================================
 889 //  Main Function Called By Engine (cmd)
 890 // ======================================
 891 // If this function exists, server game code parses clientcommand before the engine code gets it.
 892
 893 void SV_ParseClientCommand(entity this, string command)
 894 {
 895         // If invalid UTF-8, don't even parse it
 896         string command2 = "";
 897         float len = strlen(command);
 898         float i;
 899         for (i = 0; i < len; ++i)
 900                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 901         if (command != command2) return;
 902
 903         // if we're banned, don't even parse the command
 904         if (Ban_MaybeEnforceBanOnce(this)) return;
 905
 906         int argc = tokenize_console(command);
 907
 908         // Guide for working with argc arguments by example:
 909         // argc:   1    - 2      - 3     - 4
 910         // argv:   0    - 1      - 2     - 3
 911         // cmd     vote - master - login - password
 912
 913         // for floodcheck
 914         switch (strtolower(argv(0)))
 915         {
 916                 // exempt commands which are not subject to floodcheck
 917                 case "begin": break;                               // handled by engine in host_cmd.c
 918                 case "download": break;                            // handled by engine in cl_parse.c
 919                 case "mv_getpicture": break;                       // handled by server in this file
 920                 case "wpeditor": break;                            // handled by server in this file
 921                 case "pause": break;                               // handled by engine in host_cmd.c
 922                 case "prespawn": break;                            // handled by engine in host_cmd.c
 923                 case "sentcvar": break;                            // handled by server in this file
 924                 case "spawn": break;                               // handled by engine in host_cmd.c
 925                 case "color": case "topcolor": case "bottomcolor": // handled by engine in host_cmd.c
 926                         if(!IS_CLIENT(this)) // on connection
 927                         {
 928                                 // since gamecode doesn't have any calls earlier than this, do the connecting message here
 929                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
 930                         }
 931                         if(teamplay)
 932                                 return;
 933                         break;
 934                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 935
 936                 default:
 937                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 938                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 939         }
 940
 941         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 942         if (argv(0) == "help")
 943         {
 944                 if (argc == 1)
 945                 {
 946                         sprint(this, "\nClient networked commands:\n");
 947                         ClientCommand_macro_help(this);
 948
 949                         sprint(this, "\nCommon networked commands:\n");
 950                         CommonCommand_macro_help(this);
 951
 952                         sprint(this, "\nUsage:^3 cmd <command>^7, where possible commands are listed above.\n");
 953                         sprint(this, "For help about a specific command, type cmd help <command>\n");
 954                         return;
 955                 }
 956                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 957                 {
 958                         return;
 959                 }
 960                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 961                 {
 962                         return;
 963                 }
 964         }
 965         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 966         {
 967                 return;  // handled by a mutator
 968         }
 969         else if (CheatCommand(this, argc))
 970         {
 971                 return;  // handled by server/cheats.qc
 972         }
 973         else if (CommonCommand_macro_command(argc, this, command))
 974         {
 975                 return;                                          // handled by server/command/common.qc
 976         }
 977         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 978         {
 979                 return;                                          // handled by one of the above ClientCommand_* functions
 980         }
 981         else
 982         {
 983                 clientcommand(this, command);
 984         }
 985 }