qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/common.qh>
  56 #include <server/command/vote.qh>
  57 #include <server/compat/quake3.qh>
  58 #include <server/damage.qh>
  59 #include <server/gamelog.qh>
  60 #include <server/handicap.qh>
  61 #include <server/hook.qh>
  62 #include <server/impulse.qh>
  63 #include <server/intermission.qh>
  64 #include <server/ipban.qh>
  65 #include <server/main.qh>
  66 #include <server/mutators/_mod.qh>
  67 #include <server/player.qh>
  68 #include <server/portals.qh>
  69 #include <server/race.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 142                                         sf |= BIT(4); // show spectators
 143
 144         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 145         WriteByte(MSG_ENTITY, sf);
 146
 147         if (sf & BIT(1))
 148                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 149
 150         if(sf & BIT(4))
 151         {
 152                 float specs = CountSpectators(e, to);
 153                 WriteByte(MSG_ENTITY, specs);
 154                 WriteSpectators(e, to);
 155         }
 156
 157         return true;
 158 }
 159
 160 void ClientData_Attach(entity this)
 161 {
 162         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 163         CS(this).clientdata.drawonlytoclient = this;
 164         CS(this).clientdata.owner = this;
 165 }
 166
 167 void ClientData_Detach(entity this)
 168 {
 169         delete(CS(this).clientdata);
 170         CS(this).clientdata = NULL;
 171 }
 172
 173 void ClientData_Touch(entity e)
 174 {
 175         entity cd = CS(e).clientdata;
 176         if (cd) { cd.SendFlags = 1; }
 177
 178         // make it spectatable
 179         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 180         {
 181                 entity cd = CS(it).clientdata;
 182                 if (cd) { cd.SendFlags = 1; }
 183         });
 184 }
 185
 186
 187 /*
 188 =============
 189 CheckPlayerModel
 190
 191 Checks if the argument string can be a valid playermodel.
 192 Returns a valid one in doubt.
 193 =============
 194 */
 195 string FallbackPlayerModel;
 196 string CheckPlayerModel(string plyermodel) {
 197         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 198         {
 199                 // note: we cannot summon Don Strunzone here, some player may
 200                 // still have the model string set. In case anyone manages how
 201                 // to change a cvar default, we'll have a small leak here.
 202                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 203         }
 204         // only in right path
 205         if(substring(plyermodel, 0, 14) != "models/player/")
 206                 return FallbackPlayerModel;
 207         // only good file extensions
 208         if(substring(plyermodel, -4, 4) != ".iqm"
 209                 && substring(plyermodel, -4, 4) != ".zym"
 210                 && substring(plyermodel, -4, 4) != ".dpm"
 211                 && substring(plyermodel, -4, 4) != ".md3"
 212                 && substring(plyermodel, -4, 4) != ".psk")
 213         {
 214                 return FallbackPlayerModel;
 215         }
 216         // forbid the LOD models
 217         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 218                 return FallbackPlayerModel;
 219         if(plyermodel != strtolower(plyermodel))
 220                 return FallbackPlayerModel;
 221         // also, restrict to server models
 222         if(autocvar_sv_servermodelsonly)
 223         {
 224                 if(!fexists(plyermodel))
 225                         return FallbackPlayerModel;
 226         }
 227         return plyermodel;
 228 }
 229
 230 void setplayermodel(entity e, string modelname)
 231 {
 232         precache_model(modelname);
 233         _setmodel(e, modelname);
 234         player_setupanimsformodel(e);
 235         if(!autocvar_g_debug_globalsounds)
 236                 UpdatePlayerSounds(e);
 237 }
 238
 239 /** putting a client as observer in the server */
 240 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 241 {
 242         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 243         bool recount_ready = false;
 244         PlayerState_detach(this);
 245
 246         if (IS_PLAYER(this))
 247         {
 248                 if(GetResource(this, RES_HEALTH) >= 1)
 249                 {
 250                         // despawn effect
 251                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 252                 }
 253
 254                 // was a player, recount votes and ready status
 255                 if(IS_REAL_CLIENT(this))
 256                 {
 257                         if (vote_called) { VoteCount(false); }
 258                         this.ready = false;
 259                         recount_ready = true;
 260                 }
 261                 entcs_update_players(this);
 262         }
 263
 264         if (use_spawnpoint)
 265         {
 266                 entity spot = SelectSpawnPoint(this, true);
 267                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 268                 this.angles = vec2(spot.angles);
 269                 // offset it so that the spectator spawns higher off the ground, looks better this way
 270                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         }
 272         else // change origin to restore previous view origin
 273                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 274         this.fixangle = true;
 275
 276         if (IS_REAL_CLIENT(this))
 277         {
 278                 msg_entity = this;
 279                 WriteByte(MSG_ONE, SVC_SETVIEW);
 280                 WriteEntity(MSG_ONE, this);
 281         }
 282         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 283         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 284         if(!autocvar_g_debug_globalsounds)
 285         {
 286                 // needed for player sounds
 287                 this.model = "";
 288                 FixPlayermodel(this);
 289         }
 290         setmodel(this, MDL_Null);
 291         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 292         this.view_ofs = '0 0 0';
 293
 294         RemoveGrapplingHooks(this);
 295         Portal_ClearAll(this);
 296         Unfreeze(this, false);
 297         SetSpectatee(this, NULL);
 298
 299         if (this.alivetime)
 300         {
 301                 if (!warmup_stage)
 302                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 303                 this.alivetime = 0;
 304         }
 305
 306         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 307
 308         TRANSMUTE(Observer, this);
 309
 310         if(recount_ready) ReadyCount();
 311
 312         WaypointSprite_PlayerDead(this);
 313         accuracy_resend(this);
 314
 315         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 316                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 317
 318         CS(this).spectatortime = time;
 319         if(this.bot_attack)
 320                 IL_REMOVE(g_bot_targets, this);
 321         this.bot_attack = false;
 322         if(this.monster_attack)
 323                 IL_REMOVE(g_monster_targets, this);
 324         this.monster_attack = false;
 325         STAT(HUD, this) = HUD_NORMAL;
 326         this.iscreature = false;
 327         this.teleportable = TELEPORT_SIMPLE;
 328         if(this.damagedbycontents)
 329                 IL_REMOVE(g_damagedbycontents, this);
 330         this.damagedbycontents = false;
 331         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 332         SetSpectatee_status(this, etof(this));
 333         this.takedamage = DAMAGE_NO;
 334         this.solid = SOLID_NOT;
 335         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 336         this.flags = FL_CLIENT | FL_NOTARGET;
 337         this.effects = 0;
 338         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 339         this.pauserotarmor_finished = 0;
 340         this.pauserothealth_finished = 0;
 341         this.pauseregen_finished = 0;
 342         this.damageforcescale = 0;
 343         this.death_time = 0;
 344         this.respawn_flags = 0;
 345         this.respawn_time = 0;
 346         STAT(RESPAWN_TIME, this) = 0;
 347         this.alpha = 0;
 348         this.scale = 0;
 349         this.fade_time = 0;
 350         this.pain_finished = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         player_powerups_remove_all(this);
 367         this.items = 0;
 368         STAT(WEAPONS, this) = '0 0 0';
 369         this.drawonlytoclient = this;
 370
 371         this.viewloc = NULL;
 372
 373         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 374
 375         this.weaponmodel = "";
 376         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 377         {
 378                 this.weaponentities[slot] = NULL;
 379         }
 380         this.exteriorweaponentity = NULL;
 381         CS(this).killcount = FRAGS_SPECTATOR;
 382         this.velocity = '0 0 0';
 383         this.avelocity = '0 0 0';
 384         this.punchangle = '0 0 0';
 385         this.punchvector = '0 0 0';
 386         this.oldvelocity = this.velocity;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void PutPlayerInServer(entity this)
 538 {
 539         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 540
 541         PlayerState_attach(this);
 542         accuracy_resend(this);
 543
 544         if (this.team < 0)
 545                 TeamBalance_JoinBestTeam(this);
 546
 547         entity spot = SelectSpawnPoint(this, false);
 548         if (!spot) {
 549                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 550                 return; // spawn failed
 551         }
 552
 553         TRANSMUTE(Player, this);
 554
 555         CS(this).wasplayer = true;
 556         this.iscreature = true;
 557         this.teleportable = TELEPORT_NORMAL;
 558         if(!this.damagedbycontents)
 559                 IL_PUSH(g_damagedbycontents, this);
 560         this.damagedbycontents = true;
 561         set_movetype(this, MOVETYPE_WALK);
 562         this.solid = SOLID_SLIDEBOX;
 563         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 564         if (autocvar_g_playerclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 566         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 567                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 568         this.frags = FRAGS_PLAYER;
 569         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 570         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 571         if (autocvar__notarget)
 572                 this.flags |= FL_NOTARGET;
 573         this.takedamage = DAMAGE_AIM;
 574         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 575
 576         if (warmup_stage) {
 577                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 578                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 579                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 580                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 581                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 582                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 583                 SetResource(this, RES_HEALTH, warmup_start_health);
 584                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 585                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 586         } else {
 587                 SetResource(this, RES_SHELLS, start_ammo_shells);
 588                 SetResource(this, RES_BULLETS, start_ammo_nails);
 589                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 590                 SetResource(this, RES_CELLS, start_ammo_cells);
 591                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 592                 SetResource(this, RES_FUEL, start_ammo_fuel);
 593                 SetResource(this, RES_HEALTH, start_health);
 594                 SetResource(this, RES_ARMOR, start_armorvalue);
 595                 STAT(WEAPONS, this) = start_weapons;
 596                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 597                 {
 598                         GiveRandomWeapons(this, random_start_weapons_count,
 599                                 autocvar_g_random_start_weapons, random_start_ammo);
 600                 }
 601         }
 602         SetSpectatee_status(this, 0);
 603
 604         PS(this).dual_weapons = '0 0 0';
 605
 606         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 607                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 608
 609         this.items = start_items;
 610
 611         float shieldtime = time + autocvar_g_spawnshieldtime;
 612
 613         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 614         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 615         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 616         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 617         if (!sv_ready_restart_after_countdown && time < game_starttime)
 618         {
 619                 float f = game_starttime - time;
 620                 shieldtime += f;
 621                 this.pauserotarmor_finished += f;
 622                 this.pauserothealth_finished += f;
 623                 this.pauseregen_finished += f;
 624         }
 625
 626         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 627
 628         this.damageforcescale = autocvar_g_player_damageforcescale;
 629         this.death_time = 0;
 630         this.respawn_flags = 0;
 631         this.respawn_time = 0;
 632         STAT(RESPAWN_TIME, this) = 0;
 633         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 634         this.fade_time = 0;
 635         this.pain_finished = 0;
 636         this.pushltime = 0;
 637         setthink(this, func_null); // players have no think function
 638         this.nextthink = 0;
 639         this.dmg_team = 0;
 640         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 641
 642         this.deadflag = DEAD_NO;
 643
 644         this.angles = spot.angles;
 645         this.angles_z = 0; // never spawn tilted even if the spot says to
 646         if (IS_BOT_CLIENT(this))
 647         {
 648                 this.v_angle = this.angles;
 649                 bot_aim_reset(this);
 650         }
 651         this.fixangle = true; // turn this way immediately
 652         this.oldvelocity = this.velocity = '0 0 0';
 653         this.avelocity = '0 0 0';
 654         this.punchangle = '0 0 0';
 655         this.punchvector = '0 0 0';
 656
 657         STAT(REVIVE_PROGRESS, this) = 0;
 658         this.revival_time = 0;
 659
 660         STAT(AIR_FINISHED, this) = 0;
 661         this.waterlevel = WATERLEVEL_NONE;
 662         this.watertype = CONTENT_EMPTY;
 663
 664         entity spawnevent = new_pure(spawnevent);
 665         spawnevent.owner = this;
 666         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 667
 668         // Cut off any still running player sounds.
 669         stopsound(this, CH_PLAYER_SINGLE);
 670
 671         this.model = "";
 672         FixPlayermodel(this);
 673         this.drawonlytoclient = NULL;
 674
 675         this.viewloc = NULL;
 676
 677         for(int slot = 0; slot < MAX_AXH; ++slot)
 678         {
 679                 entity axh = this.(AuxiliaryXhair[slot]);
 680                 this.(AuxiliaryXhair[slot]) = NULL;
 681
 682                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 683                         delete(axh);
 684         }
 685
 686         this.spawnpoint_targ = NULL;
 687
 688         UNSET_DUCKED(this);
 689         this.view_ofs = STAT(PL_VIEW_OFS, this);
 690         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 691         this.spawnorigin = spot.origin;
 692         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 693         // don't reset back to last position, even if new position is stuck in solid
 694         this.oldorigin = this.origin;
 695         if(this.conveyor)
 696                 IL_REMOVE(g_conveyed, this);
 697         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 698         if(this.swampslug)
 699                 IL_REMOVE(g_swamped, this);
 700         this.swampslug = NULL;
 701         this.swamp_interval = 0;
 702         if(this.ladder_entity)
 703                 IL_REMOVE(g_ladderents, this);
 704         this.ladder_entity = NULL;
 705         IL_EACH(g_counters, it.realowner == this,
 706         {
 707                 delete(it);
 708         });
 709         STAT(HUD, this) = HUD_NORMAL;
 710
 711         this.event_damage = PlayerDamage;
 712         this.event_heal = PlayerHeal;
 713
 714         this.draggable = func_null;
 715
 716         if(!this.bot_attack)
 717                 IL_PUSH(g_bot_targets, this);
 718         this.bot_attack = true;
 719         if(!this.monster_attack)
 720                 IL_PUSH(g_monster_targets, this);
 721         this.monster_attack = true;
 722         navigation_dynamicgoal_init(this, false);
 723
 724         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 725
 726         // player was spectator
 727         if (CS(this).killcount == FRAGS_SPECTATOR) {
 728                 PlayerScore_Clear(this);
 729                 CS(this).killcount = 0;
 730                 CS(this).startplaytime = time;
 731         }
 732
 733         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 734         {
 735                 .entity weaponentity = weaponentities[slot];
 736                 CL_SpawnWeaponentity(this, weaponentity);
 737         }
 738         this.alpha = default_player_alpha;
 739         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 740         this.exteriorweaponentity.alpha = default_weapon_alpha;
 741
 742         this.speedrunning = false;
 743
 744         this.counter_cnt = 0;
 745         this.fragsfilter_cnt = 0;
 746
 747         target_voicescript_clear(this);
 748
 749         // reset fields the weapons may use
 750         FOREACH(Weapons, true, {
 751                 it.wr_resetplayer(it, this);
 752                         // reload all reloadable weapons
 753                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 754                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 755                         {
 756                                 .entity weaponentity = weaponentities[slot];
 757                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 758                         }
 759                 }
 760         });
 761
 762         Unfreeze(this, false);
 763
 764         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 765         {
 766                 string s = spot.target;
 767                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 768                         spot.target = string_null;
 769                 SUB_UseTargets(spot, this, NULL);
 770                 if(g_assault || g_race)
 771                         spot.target = s;
 772         }
 773
 774         if (autocvar_spawn_debug)
 775         {
 776                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 777                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 778         }
 779
 780         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 781         {
 782                 .entity weaponentity = weaponentities[slot];
 783                 entity w_ent = this.(weaponentity);
 784                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 785                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 786                 else
 787                         w_ent.m_switchweapon = WEP_Null;
 788                 w_ent.m_weapon = WEP_Null;
 789                 w_ent.weaponname = "";
 790                 w_ent.m_switchingweapon = WEP_Null;
 791                 w_ent.cnt = -1;
 792         }
 793
 794         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 795
 796         if (CS(this).impulse) ImpulseCommands(this);
 797
 798         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 799         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 800         {
 801                 .entity weaponentity = weaponentities[slot];
 802                 W_WeaponFrame(this, weaponentity);
 803         }
 804
 805         if (!warmup_stage && !this.alivetime)
 806                 this.alivetime = time;
 807
 808         antilag_clear(this, CS(this));
 809 }
 810
 811 /** Called when a client spawns in the server */
 812 void PutClientInServer(entity this)
 813 {
 814         if (IS_BOT_CLIENT(this)) {
 815                 TRANSMUTE(Player, this);
 816         } else if (IS_REAL_CLIENT(this)) {
 817                 msg_entity = this;
 818                 WriteByte(MSG_ONE, SVC_SETVIEW);
 819                 WriteEntity(MSG_ONE, this);
 820         }
 821         if (game_stopped)
 822                 TRANSMUTE(Observer, this);
 823
 824         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 825         SetSpectatee(this, NULL);
 826
 827         // reset player keys
 828         if(PS(this))
 829                 PS(this).itemkeys = 0;
 830
 831         MUTATOR_CALLHOOK(PutClientInServer, this);
 832
 833         if (IS_OBSERVER(this)) {
 834                 PutObserverInServer(this, false, use_spawnpoint);
 835         } else if (IS_PLAYER(this)) {
 836                 PutPlayerInServer(this);
 837         }
 838
 839         bot_relinkplayerlist();
 840 }
 841
 842 // TODO do we need all these fields, or should we stop autodetecting runtime
 843 // changes and just have a console command to update this?
 844 bool ClientInit_SendEntity(entity this, entity to, int sf)
 845 {
 846         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 847         return = true;
 848         msg_entity = to;
 849         // MSG_INIT replacement
 850         // TODO: make easier to use
 851         Registry_send_all();
 852         W_PROP_reload(MSG_ONE, to);
 853         ClientInit_misc(this);
 854         MUTATOR_CALLHOOK(Ent_Init);
 855 }
 856 void ClientInit_misc(entity this)
 857 {
 858         int channel = MSG_ONE;
 859         WriteHeader(channel, ENT_CLIENT_INIT);
 860         WriteByte(channel, g_nexball_meter_period * 32);
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 864         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 868         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 869
 870         if(autocvar_sv_foginterval && world.fog != "")
 871                 WriteString(channel, world.fog);
 872         else
 873                 WriteString(channel, "");
 874         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 875         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 876         WriteByte(channel, serverflags);
 877         WriteCoord(channel, autocvar_g_trueaim_minrange);
 878 }
 879
 880 void ClientInit_CheckUpdate(entity this)
 881 {
 882         this.nextthink = time;
 883         if(this.count != autocvar_g_balance_armor_blockpercent)
 884         {
 885                 this.count = autocvar_g_balance_armor_blockpercent;
 886                 this.SendFlags |= 1;
 887         }
 888         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 889         {
 890                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 891                 this.SendFlags |= 1;
 892         }
 893 }
 894
 895 void ClientInit_Spawn()
 896 {
 897         entity e = new_pure(clientinit);
 898         setthink(e, ClientInit_CheckUpdate);
 899         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 900
 901         ClientInit_CheckUpdate(e);
 902 }
 903
 904 /*
 905 =============
 906 SetNewParms
 907 =============
 908 */
 909 void SetNewParms ()
 910 {
 911         // initialize parms for a new player
 912         parm1 = -(86400 * 366);
 913
 914         MUTATOR_CALLHOOK(SetNewParms);
 915 }
 916
 917 /*
 918 =============
 919 SetChangeParms
 920 =============
 921 */
 922 void SetChangeParms (entity this)
 923 {
 924         // save parms for level change
 925         parm1 = CS(this).parm_idlesince - time;
 926
 927         MUTATOR_CALLHOOK(SetChangeParms);
 928 }
 929
 930 /*
 931 =============
 932 DecodeLevelParms
 933 =============
 934 */
 935 void DecodeLevelParms(entity this)
 936 {
 937         // load parms
 938         CS(this).parm_idlesince = parm1;
 939         if (CS(this).parm_idlesince == -(86400 * 366))
 940                 CS(this).parm_idlesince = time;
 941
 942         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 943         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 944
 945         MUTATOR_CALLHOOK(DecodeLevelParms);
 946 }
 947
 948 void FixClientCvars(entity e)
 949 {
 950         // send prediction settings to the client
 951         if(autocvar_g_antilag == 3) // client side hitscan
 952                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 953         if(autocvar_sv_gentle)
 954                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 955
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 957         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 958
 959         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 960
 961         MUTATOR_CALLHOOK(FixClientCvars, e);
 962 }
 963
 964 bool findinlist_abbrev(string tofind, string list)
 965 {
 966         if(list == "" || tofind == "")
 967                 return false; // empty list or search, just return
 968
 969         // this function allows abbreviated strings!
 970         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 971         {
 972                 return true;
 973         });
 974
 975         return false;
 976 }
 977
 978 bool PlayerInIPList(entity p, string iplist)
 979 {
 980         // some safety checks (never allow local?)
 981         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 982                 return false;
 983
 984         return findinlist_abbrev(p.netaddress, iplist);
 985 }
 986
 987 bool PlayerInIDList(entity p, string idlist)
 988 {
 989         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 990         if(!p.crypto_idfp)
 991                 return false;
 992
 993         return findinlist_abbrev(p.crypto_idfp, idlist);
 994 }
 995
 996 bool PlayerInList(entity player, string list)
 997 {
 998         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 999 }
1000
1001 #ifdef DP_EXT_PRECONNECT
1002 /*
1003 =============
1004 ClientPreConnect
1005
1006 Called once (not at each match start) when a client begins a connection to the server
1007 =============
1008 */
1009 void ClientPreConnect(entity this)
1010 {
1011         if(autocvar_sv_eventlog)
1012         {
1013                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1014                         this.playerid,
1015                         etof(this),
1016                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1017                 ));
1018         }
1019 }
1020 #endif
1021
1022 void SendWelcomemessage(entity this, bool force_centerprint)
1023 {
1024         msg_entity = this;
1025         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1026         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1027 }
1028
1029 // NOTE csqc uses the active mutators list sent by this function
1030 // to understand which mutators are enabled
1031 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1032 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1033 {
1034         WriteByte(msg_type, boolean(autocvar_g_campaign));
1035         if (boolean(autocvar_g_campaign))
1036         {
1037                 WriteString(msg_type, Campaign_GetTitle());
1038                 WriteByte(msg_type, Campaign_GetLevelNum());
1039                 WriteString(msg_type, Campaign_GetMessage());
1040                 return;
1041         }
1042         WriteByte(msg_type, force_centerprint);
1043         WriteString(msg_type, autocvar_hostname);
1044         WriteString(msg_type, autocvar_g_xonoticversion);
1045         WriteByte(msg_type, CS(this).version_mismatch);
1046         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1047
1048         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1049         string modifications = M_ARGV(0, string);
1050
1051         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1052                 modifications = strcat(modifications, ", No start weapons");
1053         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1054                 modifications = strcat(modifications, ", Low gravity");
1055         if(g_weapon_stay && !g_cts)
1056                 modifications = strcat(modifications, ", Weapons stay");
1057         if(autocvar_g_jetpack)
1058                 modifications = strcat(modifications, ", Jetpack");
1059         modifications = substring(modifications, 2, strlen(modifications) - 2);
1060
1061         WriteString(msg_type, modifications);
1062
1063         WriteString(msg_type, g_weaponarena_list);
1064
1065         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1066         {
1067                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1068                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1069         }
1070
1071         WriteString(msg_type, cache_mutatormsg);
1072
1073         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1074 }
1075
1076 /**
1077 =============
1078 ClientConnect
1079
1080 Called when a client connects to the server
1081 =============
1082 */
1083 void ClientConnect(entity this)
1084 {
1085         if (Ban_MaybeEnforceBanOnce(this)) return;
1086         assert(!IS_CLIENT(this), return);
1087         this.flags |= FL_CLIENT;
1088         assert(player_count >= 0, player_count = 0);
1089
1090         TRANSMUTE(Client, this);
1091         CS(this).version_nagtime = time + 10 + random() * 10;
1092
1093         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1094
1095         bot_clientconnect(this);
1096
1097         Player_DetermineForcedTeam(this);
1098
1099         TRANSMUTE(Observer, this);
1100
1101         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1102
1103         // always track bots, don't ask for cl_allow_uidtracking
1104         if (IS_BOT_CLIENT(this))
1105                 PlayerStats_GameReport_AddPlayer(this);
1106         else
1107                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1108
1109         if (autocvar_sv_eventlog)
1110                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1111
1112         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1113
1114         stuffcmd(this, clientstuff, "\n");
1115         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1116
1117         FixClientCvars(this);
1118
1119         // get version info from player
1120         stuffcmd(this, "cmd clientversion $gameversion\n");
1121
1122         // notify about available teams
1123         if (teamplay)
1124         {
1125                 entity balance = TeamBalance_CheckAllowedTeams(this);
1126                 int t = TeamBalance_GetAllowedTeams(balance);
1127                 TeamBalance_Destroy(balance);
1128                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1129         }
1130         else
1131         {
1132                 stuffcmd(this, "set _teams_available 0\n");
1133         }
1134
1135         bot_relinkplayerlist();
1136
1137         CS(this).spectatortime = time;
1138         if (blockSpectators)
1139         {
1140                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1141         }
1142
1143         CS(this).jointime = time;
1144
1145         if (IS_REAL_CLIENT(this))
1146         {
1147                 if (g_weaponarena_weapons == WEPSET(TUBA))
1148                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1149                 // quickmenu file must be put in a subfolder with an unique name
1150                 // to reduce chances of overriding custom client quickmenus
1151                 if (waypointeditor_enabled)
1152                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1153                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1154                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1155         }
1156
1157         if (!autocvar_sv_foginterval && world.fog != "")
1158                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1159
1160         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1161                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1162                         send_CSQC_teamnagger();
1163
1164         CSQCMODEL_AUTOINIT(this);
1165
1166         CS(this).model_randomizer = random();
1167
1168         if (IS_REAL_CLIENT(this))
1169                 sv_notice_join(this);
1170
1171         this.move_qcphysics = autocvar_sv_qcphysics;
1172
1173         // update physics stats (players can spawn before physics runs)
1174         Physics_UpdateStats(this);
1175
1176         IL_EACH(g_initforplayer, it.init_for_player, {
1177                 it.init_for_player(it, this);
1178         });
1179
1180         Handicap_Initialize(this);
1181
1182         MUTATOR_CALLHOOK(ClientConnect, this);
1183
1184         if (player_count == 1)
1185                 localcmd("\nsv_hook_firstjoin\n");
1186
1187         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1188                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1189 }
1190 /*
1191 =============
1192 ClientDisconnect
1193
1194 Called when a client disconnects from the server
1195 =============
1196 */
1197 .entity chatbubbleentity;
1198 void player_powerups_remove_all(entity this);
1199
1200 void ClientDisconnect(entity this)
1201 {
1202         assert(IS_CLIENT(this), return);
1203
1204         PlayerStats_GameReport_FinalizePlayer(this);
1205         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1206         if (CS(this).active_minigame) part_minigame(this);
1207         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1208
1209         if (autocvar_sv_eventlog)
1210                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1211
1212         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1213
1214         if(IS_SPEC(this))
1215                 SetSpectatee(this, NULL);
1216
1217         MUTATOR_CALLHOOK(ClientDisconnect, this);
1218
1219         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1220         strfree(CS_CVAR(this).weaponorder_byimpulse);
1221         ClientState_detach(this);
1222
1223         Portal_ClearAll(this);
1224
1225         Unfreeze(this, false);
1226
1227         RemoveGrapplingHooks(this);
1228
1229         // Here, everything has been done that requires this player to be a client.
1230
1231         this.flags &= ~FL_CLIENT;
1232
1233         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1234         if (this.killindicator) delete(this.killindicator);
1235
1236         IL_EACH(g_counters, it.realowner == this,
1237         {
1238                 delete(it);
1239         });
1240
1241         WaypointSprite_PlayerGone(this);
1242
1243         bot_relinkplayerlist();
1244
1245         strfree(this.clientstatus);
1246         if (this.personal) delete(this.personal);
1247
1248         this.playerid = 0;
1249         ReadyCount();
1250         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1251
1252         player_powerups_remove_all(this); // stop powerup sound
1253
1254         ONREMOVE(this);
1255
1256         if (player_count == 0)
1257                 localcmd("\nsv_hook_lastleave\n");
1258 }
1259
1260 void ChatBubbleThink(entity this)
1261 {
1262         this.nextthink = time;
1263         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1264         {
1265                 if(this.owner) // but why can that ever be NULL?
1266                         this.owner.chatbubbleentity = NULL;
1267                 delete(this);
1268                 return;
1269         }
1270
1271         this.mdl = "";
1272
1273         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1274         {
1275                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1276                         this.mdl = "models/sprites/minigame_busy.iqm";
1277                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1278                         this.mdl = "models/misc/chatbubble.spr";
1279         }
1280
1281         if ( this.model != this.mdl )
1282                 _setmodel(this, this.mdl);
1283
1284 }
1285
1286 void UpdateChatBubble(entity this)
1287 {
1288         if (this.alpha < 0)
1289                 return;
1290         // spawn a chatbubble entity if needed
1291         if (!this.chatbubbleentity)
1292         {
1293                 this.chatbubbleentity = new(chatbubbleentity);
1294                 this.chatbubbleentity.owner = this;
1295                 this.chatbubbleentity.exteriormodeltoclient = this;
1296                 setthink(this.chatbubbleentity, ChatBubbleThink);
1297                 this.chatbubbleentity.nextthink = time;
1298                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1299                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1300                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1301                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1302                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1303                 //this.chatbubbleentity.model = "";
1304                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1305         }
1306 }
1307
1308 void calculate_player_respawn_time(entity this)
1309 {
1310         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1311                 return;
1312
1313         float gametype_setting_tmp;
1314         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1315         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1316         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1317         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1318         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1319         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1320
1321         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1322         if (teamplay)
1323         {
1324                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1325                         if(it.team == this.team)
1326                                 ++pcount;
1327                 });
1328                 if (sdelay_small_count == 0)
1329                         sdelay_small_count = 1;
1330                 if (sdelay_large_count == 0)
1331                         sdelay_large_count = 1;
1332         }
1333         else
1334         {
1335                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1336                         ++pcount;
1337                 });
1338                 if (sdelay_small_count == 0)
1339                 {
1340                         if (IS_INDEPENDENT_PLAYER(this))
1341                         {
1342                                 // Players play independently. No point in requiring enemies.
1343                                 sdelay_small_count = 1;
1344                         }
1345                         else
1346                         {
1347                                 // Players play AGAINST each other. Enemies required.
1348                                 sdelay_small_count = 2;
1349                         }
1350                 }
1351                 if (sdelay_large_count == 0)
1352                 {
1353                         if (IS_INDEPENDENT_PLAYER(this))
1354                         {
1355                                 // Players play independently. No point in requiring enemies.
1356                                 sdelay_large_count = 1;
1357                         }
1358                         else
1359                         {
1360                                 // Players play AGAINST each other. Enemies required.
1361                                 sdelay_large_count = 2;
1362                         }
1363                 }
1364         }
1365
1366         float sdelay;
1367
1368         if (pcount <= sdelay_small_count)
1369                 sdelay = sdelay_small;
1370         else if (pcount >= sdelay_large_count)
1371                 sdelay = sdelay_large;
1372         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1373                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1374
1375         if(waves)
1376                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1377         else
1378                 this.respawn_time = time + sdelay;
1379
1380         if(sdelay < sdelay_max)
1381                 this.respawn_time_max = time + sdelay_max;
1382         else
1383                 this.respawn_time_max = this.respawn_time;
1384
1385         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1386                 this.respawn_countdown = 10; // first number to count down from is 10
1387         else
1388                 this.respawn_countdown = -1; // do not count down
1389
1390         if(autocvar_g_forced_respawn)
1391                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1392 }
1393
1394 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1395 // added to the model skins
1396 /*void UpdateColorModHack()
1397 {
1398         float c;
1399         c = this.clientcolors & 15;
1400         // LordHavoc: only bothering to support white, green, red, yellow, blue
1401              if (!teamplay) this.colormod = '0 0 0';
1402         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1403         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1404         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1405         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1406         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1407         else this.colormod = '1 1 1';
1408 }*/
1409
1410 void respawn(entity this)
1411 {
1412         bool damagedbycontents_prev = this.damagedbycontents;
1413         if(this.alpha >= 0)
1414         {
1415                 if(autocvar_g_respawn_ghosts)
1416                 {
1417                         this.solid = SOLID_NOT;
1418                         this.takedamage = DAMAGE_NO;
1419                         this.damagedbycontents = false;
1420                         set_movetype(this, MOVETYPE_FLY);
1421                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1422                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1423                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1424                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1425                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1426                         if(autocvar_g_respawn_ghosts_time > 0)
1427                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1428                 }
1429                 else
1430                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1431         }
1432
1433         CopyBody(this, 1);
1434         this.damagedbycontents = damagedbycontents_prev;
1435
1436         this.effects |= EF_NODRAW; // prevent another CopyBody
1437         PutClientInServer(this);
1438 }
1439
1440 void play_countdown(entity this, float finished, Sound samp)
1441 {
1442         TC(Sound, samp);
1443         float time_left = finished - time;
1444         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1445                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1446 }
1447
1448 // it removes special powerups not handled by StatusEffects
1449 void player_powerups_remove_all(entity this)
1450 {
1451         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1452         {
1453                 // don't play the poweroff sound when the game restarts or the player disconnects
1454                 if (time > game_starttime + 1 && IS_CLIENT(this)
1455                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1456                 {
1457                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1458                 }
1459                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1460                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1461                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1462         }
1463 }
1464
1465 void player_powerups(entity this)
1466 {
1467         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1468                 this.modelflags |= MF_ROCKET;
1469         else
1470                 this.modelflags &= ~MF_ROCKET;
1471
1472         this.effects &= ~EF_NODEPTHTEST;
1473
1474         if (IS_DEAD(this))
1475                 player_powerups_remove_all(this);
1476
1477         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1478                 return;
1479
1480         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1481         int items_prev = this.items;
1482
1483         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1484         {
1485                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1486                 if (this.items & IT_SUPERWEAPON)
1487                 {
1488                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1489                         {
1490                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1491                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1492                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1493                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1494                         }
1495                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1496                         {
1497                                 // don't let them run out
1498                         }
1499                         else
1500                         {
1501                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1502                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1503                                 {
1504                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1505                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1506                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1507                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1508                                 }
1509                         }
1510                 }
1511                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1512                 {
1513                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1514                         {
1515                                 this.items = this.items | IT_SUPERWEAPON;
1516                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1517                                 {
1518                                         if(!g_cts)
1519                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1520                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1521                                 }
1522                         }
1523                         else
1524                         {
1525                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1526                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1527                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1528                         }
1529                 }
1530                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1531                 {
1532                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1533                 }
1534         }
1535
1536         if(autocvar_g_nodepthtestplayers)
1537                 this.effects = this.effects | EF_NODEPTHTEST;
1538
1539         if(autocvar_g_fullbrightplayers)
1540                 this.effects = this.effects | EF_FULLBRIGHT;
1541
1542         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1543 }
1544
1545 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1546 {
1547         if(current > stable)
1548                 return current;
1549         else if(current > stable - 0.25) // when close enough, "snap"
1550                 return stable;
1551         else
1552                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1553 }
1554
1555 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1556 {
1557         if(current < stable)
1558                 return current;
1559         else if(current < stable + 0.25) // when close enough, "snap"
1560                 return stable;
1561         else
1562                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1563 }
1564
1565 void RotRegen(entity this, Resource res, float limit_mod,
1566         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1567         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1568 {
1569         float old = GetResource(this, res);
1570         float current = old;
1571         if(current > rotstable)
1572         {
1573                 if(rotframetime > 0)
1574                 {
1575                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1576                         current = max(rotstable, current - rotlinear * rotframetime);
1577                 }
1578         }
1579         else if(current < regenstable)
1580         {
1581                 if(regenframetime > 0)
1582                 {
1583                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1584                         current = min(regenstable, current + regenlinear * regenframetime);
1585                 }
1586         }
1587
1588         float limit = GetResourceLimit(this, res) * limit_mod;
1589         if(current > limit)
1590                 current = limit;
1591
1592         if (current != old)
1593                 SetResource(this, res, current);
1594 }
1595
1596 void player_regen(entity this)
1597 {
1598         float max_mod, regen_mod, rot_mod, limit_mod;
1599         max_mod = regen_mod = rot_mod = limit_mod = 1;
1600
1601         float regen_health = autocvar_g_balance_health_regen;
1602         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1603         float regen_health_rot = autocvar_g_balance_health_rot;
1604         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1605         float regen_health_stable = autocvar_g_balance_health_regenstable;
1606         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1607         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1608                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1609         max_mod = M_ARGV(1, float);
1610         regen_mod = M_ARGV(2, float);
1611         rot_mod = M_ARGV(3, float);
1612         limit_mod = M_ARGV(4, float);
1613         regen_health = M_ARGV(5, float);
1614         regen_health_linear = M_ARGV(6, float);
1615         regen_health_rot = M_ARGV(7, float);
1616         regen_health_rotlinear = M_ARGV(8, float);
1617         regen_health_stable = M_ARGV(9, float);
1618         regen_health_rotstable = M_ARGV(10, float);
1619
1620         float rotstable, regenstable, rotframetime, regenframetime;
1621
1622         if(!mutator_returnvalue)
1623         if(!STAT(FROZEN, this))
1624         {
1625                 regenstable = autocvar_g_balance_armor_regenstable;
1626                 rotstable = autocvar_g_balance_armor_rotstable;
1627                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1628                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1629                 RotRegen(this, RES_ARMOR, limit_mod,
1630                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1631                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1632
1633                 // NOTE: max_mod is only applied to health
1634                 regenstable = regen_health_stable * max_mod;
1635                 rotstable = regen_health_rotstable * max_mod;
1636                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1637                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1638                 RotRegen(this, RES_HEALTH, limit_mod,
1639                         regenstable, regen_health, regen_health_linear, regenframetime,
1640                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1641         }
1642
1643         // if player rotted to death...  die!
1644         // check this outside above checks, as player may still be able to rot to death
1645         if(GetResource(this, RES_HEALTH) < 1)
1646         {
1647                 if(this.vehicle)
1648                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1649                 if(this.event_damage)
1650                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1651         }
1652
1653         if (!(this.items & IT_UNLIMITED_AMMO))
1654         {
1655                 regenstable = autocvar_g_balance_fuel_regenstable;
1656                 rotstable = autocvar_g_balance_fuel_rotstable;
1657                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1658                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1659                 RotRegen(this, RES_FUEL, 1,
1660                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1661                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1662         }
1663 }
1664
1665 bool zoomstate_set;
1666 void SetZoomState(entity this, float newzoom)
1667 {
1668         if(newzoom != CS(this).zoomstate)
1669         {
1670                 CS(this).zoomstate = newzoom;
1671                 ClientData_Touch(this);
1672         }
1673         zoomstate_set = true;
1674 }
1675
1676 void GetPressedKeys(entity this)
1677 {
1678         MUTATOR_CALLHOOK(GetPressedKeys, this);
1679         if (game_stopped)
1680         {
1681                 CS(this).pressedkeys = 0;
1682                 STAT(PRESSED_KEYS, this) = 0;
1683                 return;
1684         }
1685
1686         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1687         int keys = STAT(PRESSED_KEYS, this);
1688         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1689         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1690         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1691         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1692
1693         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1694         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1695         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1696         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1697         CS(this).pressedkeys = keys; // store for other users
1698
1699         STAT(PRESSED_KEYS, this) = keys;
1700 }
1701
1702 /*
1703 ======================
1704 spectate mode routines
1705 ======================
1706 */
1707
1708 void SpectateCopy(entity this, entity spectatee)
1709 {
1710         TC(Client, this); TC(Client, spectatee);
1711
1712         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1713         PS(this) = PS(spectatee);
1714         this.armortype = spectatee.armortype;
1715         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1716         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1717         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1718         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1719         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1720         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1721         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1722         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1723         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1724         CS(this).impulse = 0;
1725         this.disableclientprediction = 1; // no need to run prediction on a spectator
1726         this.items = spectatee.items;
1727         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1728         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1729         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1730         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1731         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1732         this.punchangle = spectatee.punchangle;
1733         this.view_ofs = spectatee.view_ofs;
1734         this.velocity = spectatee.velocity;
1735         this.dmg_take = spectatee.dmg_take;
1736         this.dmg_save = spectatee.dmg_save;
1737         this.dmg_inflictor = spectatee.dmg_inflictor;
1738         this.v_angle = spectatee.v_angle;
1739         this.angles = spectatee.v_angle;
1740         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1741         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1742         this.viewloc = spectatee.viewloc;
1743         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1744                 this.fixangle = true;
1745         setorigin(this, spectatee.origin);
1746         setsize(this, spectatee.mins, spectatee.maxs);
1747         SetZoomState(this, CS(spectatee).zoomstate);
1748
1749     anticheat_spectatecopy(this, spectatee);
1750         STAT(HUD, this) = STAT(HUD, spectatee);
1751         if(spectatee.vehicle)
1752     {
1753         this.angles = spectatee.v_angle;
1754
1755         //this.fixangle = false;
1756         //this.velocity = spectatee.vehicle.velocity;
1757         this.vehicle_health = spectatee.vehicle_health;
1758         this.vehicle_shield = spectatee.vehicle_shield;
1759         this.vehicle_energy = spectatee.vehicle_energy;
1760         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1761         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1762         this.vehicle_reload1 = spectatee.vehicle_reload1;
1763         this.vehicle_reload2 = spectatee.vehicle_reload2;
1764
1765         //msg_entity = this;
1766
1767        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1768             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1769            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1770            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1771
1772         //WriteByte (MSG_ONE, SVC_SETVIEW);
1773         //    WriteEntity(MSG_ONE, this);
1774         //makevectors(spectatee.v_angle);
1775         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1776     }
1777 }
1778
1779 bool SpectateUpdate(entity this)
1780 {
1781         if(!this.enemy)
1782                 return false;
1783
1784         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1785         {
1786                 SetSpectatee(this, NULL);
1787                 return false;
1788         }
1789
1790         SpectateCopy(this, this.enemy);
1791
1792         return true;
1793 }
1794
1795 bool SpectateSet(entity this)
1796 {
1797         if(!IS_PLAYER(this.enemy))
1798                 return false;
1799
1800         ClientData_Touch(this.enemy);
1801
1802         msg_entity = this;
1803         WriteByte(MSG_ONE, SVC_SETVIEW);
1804         WriteEntity(MSG_ONE, this.enemy);
1805         set_movetype(this, MOVETYPE_NONE);
1806         accuracy_resend(this);
1807
1808         if(!SpectateUpdate(this))
1809                 PutObserverInServer(this, false, true);
1810
1811         return true;
1812 }
1813
1814 void SetSpectatee_status(entity this, int spectatee_num)
1815 {
1816         int oldspectatee_status = CS(this).spectatee_status;
1817         CS(this).spectatee_status = spectatee_num;
1818
1819         if (CS(this).spectatee_status != oldspectatee_status)
1820         {
1821                 if (STAT(PRESSED_KEYS, this))
1822                 {
1823                         CS(this).pressedkeys = 0;
1824                         STAT(PRESSED_KEYS, this) = 0;
1825                 }
1826                 ClientData_Touch(this);
1827                 if (g_race || g_cts) race_InitSpectator();
1828         }
1829 }
1830
1831 void SetSpectatee(entity this, entity spectatee)
1832 {
1833         if(IS_BOT_CLIENT(this))
1834                 return; // bots abuse .enemy, this code is useless to them
1835
1836         entity old_spectatee = this.enemy;
1837
1838         this.enemy = spectatee;
1839
1840         // WEAPONTODO
1841         // these are required to fix the spectator bug with arc
1842         if(old_spectatee)
1843         {
1844                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1845                 {
1846                         .entity weaponentity = weaponentities[slot];
1847                         if(old_spectatee.(weaponentity).arc_beam)
1848                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1849                 }
1850         }
1851         if(spectatee)
1852         {
1853                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1854                 {
1855                         .entity weaponentity = weaponentities[slot];
1856                         if(spectatee.(weaponentity).arc_beam)
1857                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1858                 }
1859         }
1860
1861         if (spectatee)
1862                 SetSpectatee_status(this, etof(spectatee));
1863
1864         // needed to update spectator list
1865         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1866 }
1867
1868 bool Spectate(entity this, entity pl)
1869 {
1870         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1871                 return false;
1872         pl = M_ARGV(1, entity);
1873
1874         SetSpectatee(this, pl);
1875         return SpectateSet(this);
1876 }
1877
1878 bool SpectateNext(entity this)
1879 {
1880         entity ent = find(this.enemy, classname, STR_PLAYER);
1881
1882         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1883                 ent = M_ARGV(1, entity);
1884         else if (!ent)
1885                 ent = find(ent, classname, STR_PLAYER);
1886
1887         if(ent) { SetSpectatee(this, ent); }
1888
1889         return SpectateSet(this);
1890 }
1891
1892 bool SpectatePrev(entity this)
1893 {
1894         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1895         entity ent = findchain(classname, STR_PLAYER);
1896         if (!ent) // no player
1897                 return false;
1898
1899         entity first = ent;
1900         // skip players until current spectated player
1901         if(this.enemy)
1902         while(ent && ent != this.enemy)
1903                 ent = ent.chain;
1904
1905         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1906         {
1907                 case MUT_SPECPREV_FOUND:
1908                         ent = M_ARGV(1, entity);
1909                         break;
1910                 case MUT_SPECPREV_RETURN:
1911                         return true;
1912                 case MUT_SPECPREV_CONTINUE:
1913                 default:
1914                 {
1915                         if(ent.chain)
1916                                 ent = ent.chain;
1917                         else
1918                                 ent = first;
1919                         break;
1920                 }
1921         }
1922
1923         SetSpectatee(this, ent);
1924         return SpectateSet(this);
1925 }
1926
1927 /*
1928 =============
1929 ShowRespawnCountdown()
1930
1931 Update a respawn countdown display.
1932 =============
1933 */
1934 void ShowRespawnCountdown(entity this)
1935 {
1936         float number;
1937         if(!IS_DEAD(this)) // just respawned?
1938                 return;
1939         else
1940         {
1941                 number = ceil(this.respawn_time - time);
1942                 if(number <= 0)
1943                         return;
1944                 if(number <= this.respawn_countdown)
1945                 {
1946                         this.respawn_countdown = number - 1;
1947                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1948                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1949                 }
1950         }
1951 }
1952
1953 .bool team_selected;
1954 bool ShowTeamSelection(entity this)
1955 {
1956         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1957                 return false;
1958         stuffcmd(this, "menu_showteamselect\n");
1959         return true;
1960 }
1961 void Join(entity this)
1962 {
1963         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1964                 ReadyRestart(true);
1965
1966         TRANSMUTE(Player, this);
1967
1968         if(!this.team_selected)
1969         if(autocvar_g_campaign || autocvar_g_balance_teams)
1970                 TeamBalance_JoinBestTeam(this);
1971
1972         if(autocvar_g_campaign)
1973                 campaign_bots_may_start = true;
1974
1975         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1976
1977         PutClientInServer(this);
1978
1979         if(IS_PLAYER(this))
1980         if(teamplay && this.team != -1)
1981         {
1982         }
1983         else
1984                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1985         this.team_selected = false;
1986 }
1987
1988 int GetPlayerLimit()
1989 {
1990         if(g_duel)
1991                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1992         int player_limit = autocvar_g_maxplayers;
1993         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1994         player_limit = M_ARGV(0, int);
1995         return player_limit;
1996 }
1997
1998 /**
1999  * Determines whether the player is allowed to join. This depends on cvar
2000  * g_maxplayers, if it isn't used this function always return true, otherwise
2001  * it checks whether the number of currently playing players exceeds g_maxplayers.
2002  * @return int number of free slots for players, 0 if none
2003  */
2004 int nJoinAllowed(entity this, entity ignore)
2005 {
2006         if(!ignore)
2007         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2008         // so report 0 free slots if restricted
2009         {
2010                 if(autocvar_g_forced_team_otherwise == "spectate")
2011                         return 0;
2012                 if(autocvar_g_forced_team_otherwise == "spectator")
2013                         return 0;
2014         }
2015
2016         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2017                 return 0; // forced spectators can never join
2018
2019         // TODO simplify this
2020         int totalClients = 0;
2021         int currentlyPlaying = 0;
2022         FOREACH_CLIENT(true, {
2023                 if(it != ignore)
2024                         ++totalClients;
2025                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2026                         ++currentlyPlaying;
2027         });
2028
2029         int player_limit = GetPlayerLimit();
2030
2031         int free_slots = 0;
2032         if (!player_limit)
2033                 free_slots = maxclients - totalClients;
2034         else if(player_limit > 0 && currentlyPlaying < player_limit)
2035                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2036
2037         static float msg_time = 0;
2038         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2039         {
2040                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2041                 msg_time = time + 0.5;
2042         }
2043
2044         return free_slots;
2045 }
2046
2047 void PrintWelcomeMessage(entity this)
2048 {
2049         if(CS(this).motd_actived_time == 0)
2050         {
2051                 if (autocvar_g_campaign) {
2052                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2053                                 CS(this).motd_actived_time = time;
2054                                 SendWelcomemessage(this, false);
2055                         }
2056                 } else {
2057                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2058                                 CS(this).motd_actived_time = time;
2059                                 SendWelcomemessage(this, true);
2060                         }
2061                 }
2062         }
2063         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2064         {
2065                 if (autocvar_g_campaign) {
2066                         if (PHYS_INPUT_BUTTON_INFO(this))
2067                                 CS(this).motd_actived_time = time;
2068                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2069                                 CS(this).motd_actived_time = 0;
2070                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2071                         }
2072                 } else {
2073                         if (PHYS_INPUT_BUTTON_INFO(this))
2074                                 CS(this).motd_actived_time = time;
2075                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2076                                 CS(this).motd_actived_time = 0;
2077                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2078                         }
2079                 }
2080         }
2081         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2082         {
2083                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2084                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2085                 else if (CS(this).motd_actived_time == -2)
2086                 {
2087                         // instantly hide MOTD
2088                         CS(this).motd_actived_time = 0;
2089                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2090                 }
2091                 else if (IS_PLAYER(this) || IS_SPEC(this))
2092                 {
2093                         // FIXME occasionally for some reason MOTD never goes away
2094                         // delay MOTD removal a little bit in the hope it fixes this bug
2095                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2096                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2097                         else //if (CS(this).motd_actived_time < -2)
2098                                 CS(this).motd_actived_time++;
2099                 }
2100         }
2101 }
2102
2103 bool joinAllowed(entity this)
2104 {
2105         if (CS(this).version_mismatch) return false;
2106         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2107         if (!nJoinAllowed(this, this)) return false;
2108         if (teamplay && lockteams) return false;
2109         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2110         if (ShowTeamSelection(this)) return false;
2111         return true;
2112 }
2113
2114 .string shootfromfixedorigin;
2115 .bool dualwielding_prev;
2116 bool PlayerThink(entity this)
2117 {
2118         if (game_stopped || intermission_running) {
2119                 this.modelflags &= ~MF_ROCKET;
2120                 if(intermission_running)
2121                         IntermissionThink(this);
2122                 return false;
2123         }
2124
2125         if (timeout_status == TIMEOUT_ACTIVE) {
2126                 // don't allow the player to turn around while game is paused
2127                 // FIXME turn this into CSQC stuff
2128                 this.v_angle = this.lastV_angle;
2129                 this.angles = this.lastV_angle;
2130                 this.fixangle = true;
2131         }
2132
2133         if (frametime) player_powerups(this);
2134
2135         if (IS_DEAD(this)) {
2136                 if (this.personal && g_race_qualifying) {
2137                         if (time > this.respawn_time) {
2138                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2139                                 respawn(this);
2140                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2141                         }
2142                 } else {
2143                         if (frametime) player_anim(this);
2144
2145                         if (this.respawn_flags & RESPAWN_DENY)
2146                         {
2147                                 STAT(RESPAWN_TIME, this) = 0;
2148                                 return false;
2149                         }
2150
2151                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2152
2153                         switch(this.deadflag)
2154                         {
2155                                 case DEAD_DYING:
2156                                 {
2157                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2158                                                 this.deadflag = DEAD_RESPAWNING;
2159                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2160                                                 this.deadflag = DEAD_DEAD;
2161                                         break;
2162                                 }
2163                                 case DEAD_DEAD:
2164                                 {
2165                                         if (button_pressed)
2166                                                 this.deadflag = DEAD_RESPAWNABLE;
2167                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2168                                                 this.deadflag = DEAD_RESPAWNING;
2169                                         break;
2170                                 }
2171                                 case DEAD_RESPAWNABLE:
2172                                 {
2173                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2174                                                 this.deadflag = DEAD_RESPAWNING;
2175                                         break;
2176                                 }
2177                                 case DEAD_RESPAWNING:
2178                                 {
2179                                         if (time > this.respawn_time)
2180                                         {
2181                                                 this.respawn_time = time + 1; // only retry once a second
2182                                                 this.respawn_time_max = this.respawn_time;
2183                                                 respawn(this);
2184                                         }
2185                                         break;
2186                                 }
2187                         }
2188
2189                         ShowRespawnCountdown(this);
2190
2191                         if (this.respawn_flags & RESPAWN_SILENT)
2192                                 STAT(RESPAWN_TIME, this) = 0;
2193                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2194                         {
2195                                 if (time < this.respawn_time)
2196                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2197                                 else if (this.deadflag != DEAD_RESPAWNING)
2198                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2199                         }
2200                         else
2201                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2202                 }
2203
2204                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2205                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2206                         STAT(RESPAWN_TIME, this) *= -1;
2207
2208                 return false;
2209         }
2210
2211         FixPlayermodel(this);
2212
2213         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2214                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2215                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2216         }
2217
2218         // reset gun alignment when dual wielding status changes
2219         // to ensure guns are always aligned right and left
2220         bool dualwielding = W_DualWielding(this);
2221         if(this.dualwielding_prev != dualwielding)
2222         {
2223                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2224                 this.dualwielding_prev = dualwielding;
2225         }
2226
2227         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2228         //if(frametime)
2229         {
2230                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2231                 {
2232                         .entity weaponentity = weaponentities[slot];
2233                         if(WEP_CVAR(vortex, charge_always))
2234                                 W_Vortex_Charge(this, weaponentity, frametime);
2235                         W_WeaponFrame(this, weaponentity);
2236                 }
2237         }
2238
2239         if (frametime)
2240         {
2241                 // WEAPONTODO: Add a weapon request for this
2242                 // rot vortex charge to the charge limit
2243                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2244                 {
2245                         .entity weaponentity = weaponentities[slot];
2246                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2247                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2248                 }
2249
2250                 player_regen(this);
2251                 player_anim(this);
2252                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2253         }
2254
2255         monsters_setstatus(this);
2256
2257         return true;
2258 }
2259
2260 .bool would_spectate;
2261 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2262 void ObserverOrSpectatorThink(entity this)
2263 {
2264         bool is_spec = IS_SPEC(this);
2265         if ( CS(this).impulse )
2266         {
2267                 int r = MinigameImpulse(this, CS(this).impulse);
2268                 if (!is_spec || r)
2269                         CS(this).impulse = 0;
2270
2271                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2272                 {
2273                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2274                         CS(this).impulse = 0;
2275                         return;
2276                 }
2277         }
2278
2279         if (this.flags & FL_JUMPRELEASED) {
2280                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2281                         this.flags &= ~FL_JUMPRELEASED;
2282                         this.flags |= FL_SPAWNING;
2283                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2284                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2285                         this.flags &= ~FL_JUMPRELEASED;
2286                         if(SpectateNext(this)) {
2287                                 TRANSMUTE(Spectator, this);
2288                         } else if (is_spec) {
2289                                 TRANSMUTE(Observer, this);
2290                                 PutClientInServer(this);
2291                         }
2292                         else
2293                                 this.would_spectate = false; // unable to spectate anyone
2294                         if (is_spec)
2295                                 CS(this).impulse = 0;
2296                 } else if (is_spec) {
2297                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2298                                 this.flags &= ~FL_JUMPRELEASED;
2299                                 if(SpectatePrev(this)) {
2300                                         TRANSMUTE(Spectator, this);
2301                                 } else {
2302                                         TRANSMUTE(Observer, this);
2303                                         PutClientInServer(this);
2304                                 }
2305                                 CS(this).impulse = 0;
2306                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2307                                 this.would_spectate = false;
2308                                 this.flags &= ~FL_JUMPRELEASED;
2309                                 TRANSMUTE(Observer, this);
2310                                 PutClientInServer(this);
2311                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2312                                 PutObserverInServer(this, false, true);
2313                                 this.would_spectate = true;
2314                         }
2315                 }
2316                 else {
2317                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2318                         if (PHYS_INPUT_BUTTON_USE(this))
2319                                 wouldclip = !wouldclip;
2320                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2321                         set_movetype(this, preferred_movetype);
2322                 }
2323         } else { // jump pressed
2324                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2325                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2326                         this.flags |= FL_JUMPRELEASED;
2327                         if(this.flags & FL_SPAWNING)
2328                         {
2329                                 this.flags &= ~FL_SPAWNING;
2330                                 if(joinAllowed(this))
2331                                         Join(this);
2332                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2333                                         CS(this).autojoin_checked = -1;
2334                                 return;
2335                         }
2336                 }
2337                 if(is_spec && !SpectateUpdate(this))
2338                         PutObserverInServer(this, false, true);
2339         }
2340         if (is_spec)
2341                 this.flags |= FL_CLIENT | FL_NOTARGET;
2342 }
2343
2344 void PlayerUseKey(entity this)
2345 {
2346         if (!IS_PLAYER(this))
2347                 return;
2348
2349         if(this.vehicle)
2350         {
2351                 if(!game_stopped)
2352                 {
2353                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2354                         return;
2355                 }
2356         }
2357         else if(autocvar_g_vehicles_enter)
2358         {
2359                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2360                 {
2361                         entity head, closest_target = NULL;
2362                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2363
2364                         while(head) // find the closest acceptable target to enter
2365                         {
2366                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2367                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2368                                 {
2369                                         if(closest_target)
2370                                         {
2371                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2372                                                 { closest_target = head; }
2373                                         }
2374                                         else { closest_target = head; }
2375                                 }
2376
2377                                 head = head.chain;
2378                         }
2379
2380                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2381                 }
2382         }
2383
2384         // a use key was pressed; call handlers
2385         MUTATOR_CALLHOOK(PlayerUseKey, this);
2386 }
2387
2388
2389 /*
2390 =============
2391 PlayerPreThink
2392
2393 Called every frame for each client before the physics are run
2394 =============
2395 */
2396 .float last_vehiclecheck;
2397 void PlayerPreThink (entity this)
2398 {
2399         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2400         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2401
2402         WarpZone_PlayerPhysics_FixVAngle(this);
2403
2404         if (frametime) {
2405                 // physics frames: update anticheat stuff
2406                 anticheat_prethink(this);
2407
2408                 // WORKAROUND: only use dropclient in server frames (frametime set).
2409                 // Never use it in cl_movement frames (frametime zero).
2410                 if (blockSpectators && IS_REAL_CLIENT(this)
2411                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2412                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2413                 {
2414                         if (dropclient_schedule(this))
2415                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2416                 }
2417         }
2418
2419         zoomstate_set = false;
2420
2421         // Check for nameless players
2422         if (this.netname == "" || this.netname != CS(this).netname_previous)
2423         {
2424                 bool assume_unchanged = (CS(this).netname_previous == "");
2425                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2426                 {
2427                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2428                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2429                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2430                         assume_unchanged = false;
2431                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2432                 }
2433                 if (isInvisibleString(this.netname))
2434                 {
2435                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2436                         sprint(this, "Warning: invisible names are not allowed.\n");
2437                         assume_unchanged = false;
2438                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2439                 }
2440                 if (!assume_unchanged && autocvar_sv_eventlog)
2441                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2442                 strcpy(CS(this).netname_previous, this.netname);
2443         }
2444
2445         // version nagging
2446         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2447         CS(this).version_nagtime = 0;
2448         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2449             // git client
2450         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2451             // git server
2452             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2453         } else {
2454             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2455             if (r < 0) { // old client
2456                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2457             } else if (r > 0) { // old server
2458                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2459             }
2460         }
2461     }
2462
2463         // GOD MODE info
2464         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2465         {
2466                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2467                 this.max_armorvalue = 0;
2468         }
2469
2470         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2471         {
2472                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2473                 {
2474                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2475                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2476                         if (this.iceblock)
2477                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2478
2479                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2480                                 Unfreeze(this, false);
2481                 }
2482                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2483                 {
2484                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2485                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2486
2487                         if (GetResource(this, RES_HEALTH) < 1)
2488                         {
2489                                 if (this.vehicle)
2490                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2491                                 if(this.event_damage)
2492                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2493                         }
2494                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2495                                 Unfreeze(this, false);
2496                 }
2497         }
2498
2499         MUTATOR_CALLHOOK(PlayerPreThink, this);
2500
2501         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2502         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2503         {
2504                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2505                 {
2506                         if(!it.owner)
2507                         {
2508                                 if(!it.team || SAME_TEAM(this, it))
2509                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2510                                 else if(autocvar_g_vehicles_steal)
2511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2512                         }
2513                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2514                         {
2515                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2516                         }
2517                 });
2518
2519                 this.last_vehiclecheck = time + 1;
2520         }
2521
2522         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2523                 PlayerUseKey(this);
2524         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2525
2526         if (IS_REAL_CLIENT(this))
2527                 PrintWelcomeMessage(this);
2528
2529         if (IS_PLAYER(this)) {
2530                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2531                         error("Client can't be spawned as player on connection!");
2532                 if(!PlayerThink(this))
2533                         return;
2534         }
2535         else if (game_stopped || intermission_running) {
2536                 if(intermission_running)
2537                         IntermissionThink(this);
2538                 return;
2539         }
2540         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2541         {
2542                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2543                 CS(this).autojoin_checked = 1;
2544                 // don't do this in ClientConnect
2545                 // many things can go wrong if a client is spawned as player on connection
2546                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2547                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2548                                 && (!teamplay || autocvar_g_balance_teams)))
2549                 {
2550                         if(joinAllowed(this))
2551                                 Join(this);
2552                         return;
2553                 }
2554         }
2555         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2556                 ObserverOrSpectatorThink(this);
2557         }
2558
2559         // WEAPONTODO: Add weapon request for this
2560         if (!zoomstate_set) {
2561                 bool wep_zoomed = false;
2562                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2563                 {
2564                         .entity weaponentity = weaponentities[slot];
2565                         Weapon thiswep = this.(weaponentity).m_weapon;
2566                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2567                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2568                 }
2569                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2570         }
2571
2572         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2573         {
2574                 CS(this).teamkill_soundtime = 0;
2575
2576                 entity e = CS(this).teamkill_soundsource;
2577                 entity oldpusher = e.pusher;
2578                 e.pusher = this;
2579                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2580                 e.pusher = oldpusher;
2581         }
2582
2583         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2584                 CS(this).taunt_soundtime = 0;
2585                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2586         }
2587
2588         target_voicescript_next(this);
2589 }
2590
2591 void DrownPlayer(entity this)
2592 {
2593         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2594                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2595         {
2596                 STAT(AIR_FINISHED, this) = 0;
2597                 return;
2598         }
2599
2600         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2601         {
2602                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2603                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2604                 STAT(AIR_FINISHED, this) = 0;
2605         }
2606         else
2607         {
2608                 if (!STAT(AIR_FINISHED, this))
2609                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2610                 if (STAT(AIR_FINISHED, this) < time)
2611                 {       // drown!
2612                         if (this.pain_finished < time)
2613                         {
2614                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2615                                 this.pain_finished = time + 0.5;
2616                         }
2617                 }
2618         }
2619 }
2620
2621 .bool move_qcphysics;
2622
2623 void Player_Physics(entity this)
2624 {
2625         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2626
2627         if(!this.move_qcphysics)
2628                 return;
2629
2630         if(!frametime && !CS(this).pm_frametime)
2631                 return;
2632
2633         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2634
2635         CS(this).pm_frametime = 0;
2636 }
2637
2638 /*
2639 =============
2640 PlayerPostThink
2641
2642 Called every frame for each client after the physics are run
2643 =============
2644 */
2645 void PlayerPostThink (entity this)
2646 {
2647         Player_Physics(this);
2648
2649         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2650         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2651         if (IS_REAL_CLIENT(this))
2652         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2653         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2654         {
2655                 int totalClients = 0;
2656                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2657                 {
2658                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2659                         if (server_is_dedicated)
2660                         {
2661                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2662                                 {
2663                                         ++totalClients;
2664                                 });
2665                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2666                                         totalClients = 0;
2667                         }
2668                 }
2669                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2670                 {
2671                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2672                         {
2673                                 ++totalClients;
2674                         });
2675                 }
2676
2677                 if (totalClients < autocvar_sv_maxidle_minplayers)
2678                 {
2679                         // idle kick disabled
2680                         CS(this).parm_idlesince = time;
2681                 }
2682                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2683                 {
2684                         if (CS(this).idlekick_lasttimeleft)
2685                         {
2686                                 CS(this).idlekick_lasttimeleft = 0;
2687                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2688                         }
2689                 }
2690                 else
2691                 {
2692                         float maxidle_time = autocvar_sv_maxidle;
2693                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2694                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2695                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2696                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2697                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2698                         {
2699                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2700                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2701                                 else
2702                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2703                         }
2704                         if (timeleft <= 0) {
2705                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2706                                 {
2707                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2708                                         PutObserverInServer(this, true, true);
2709                                 }
2710                                 else
2711                                 {
2712                                         if (dropclient_schedule(this))
2713                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2714                                 }
2715                                 return;
2716                         }
2717                         else if (timeleft <= countdown_time) {
2718                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2719                                         play2(this, SND(TALK2));
2720                                 CS(this).idlekick_lasttimeleft = timeleft;
2721                         }
2722                 }
2723         }
2724
2725         CheatFrame(this);
2726
2727         if (game_stopped)
2728         {
2729                 this.solid = SOLID_NOT;
2730                 this.takedamage = DAMAGE_NO;
2731                 set_movetype(this, MOVETYPE_NONE);
2732                 CS(this).teamkill_complain = 0;
2733                 CS(this).teamkill_soundtime = 0;
2734                 CS(this).teamkill_soundsource = NULL;
2735         }
2736
2737         if (IS_PLAYER(this)) {
2738                 if(this.death_time == time && IS_DEAD(this))
2739                 {
2740                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2741                         // once all the damage events of this frame have been processed with normal size
2742                         this.maxs.z = 5;
2743                         setsize(this, this.mins, this.maxs);
2744                 }
2745                 DrownPlayer(this);
2746                 UpdateChatBubble(this);
2747                 if (CS(this).impulse) ImpulseCommands(this);
2748                 GetPressedKeys(this);
2749                 if (game_stopped)
2750                 {
2751                         CSQCMODEL_AUTOUPDATE(this);
2752                         return;
2753                 }
2754         }
2755         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2756         {
2757                 CS(this).pressedkeys = 0;
2758                 STAT(PRESSED_KEYS, this) = 0;
2759         }
2760
2761         if (this.waypointsprite_attachedforcarrier) {
2762                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2763                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2764         }
2765
2766         CSQCMODEL_AUTOUPDATE(this);
2767 }
2768
2769 // hack to copy the button fields from the client entity to the Client State
2770 void PM_UpdateButtons(entity this, entity store)
2771 {
2772         if(this.impulse)
2773                 store.impulse = this.impulse;
2774         this.impulse = 0;
2775
2776         bool typing = this.buttonchat || this.button12;
2777
2778         store.button0 = (typing) ? 0 : this.button0;
2779         //button1?!
2780         store.button2 = (typing) ? 0 : this.button2;
2781         store.button3 = (typing) ? 0 : this.button3;
2782         store.button4 = this.button4;
2783         store.button5 = (typing) ? 0 : this.button5;
2784         store.button6 = this.button6;
2785         store.button7 = this.button7;
2786         store.button8 = this.button8;
2787         store.button9 = this.button9;
2788         store.button10 = this.button10;
2789         store.button11 = this.button11;
2790         store.button12 = this.button12;
2791         store.button13 = this.button13;
2792         store.button14 = this.button14;
2793         store.button15 = this.button15;
2794         store.button16 = this.button16;
2795         store.buttonuse = this.buttonuse;
2796         store.buttonchat = this.buttonchat;
2797
2798         store.cursor_active = this.cursor_active;
2799         store.cursor_screen = this.cursor_screen;
2800         store.cursor_trace_start = this.cursor_trace_start;
2801         store.cursor_trace_endpos = this.cursor_trace_endpos;
2802         store.cursor_trace_ent = this.cursor_trace_ent;
2803
2804         store.ping = this.ping;
2805         store.ping_packetloss = this.ping_packetloss;
2806         store.ping_movementloss = this.ping_movementloss;
2807
2808         store.v_angle = this.v_angle;
2809         store.movement = this.movement;
2810 }
2811
2812 NET_HANDLE(fpsreport, bool)
2813 {
2814         int fps = ReadShort();
2815         PlayerScore_Set(sender, SP_FPS, fps);
2816         return true;
2817 }