qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/common.qh>
  56 #include <server/command/vote.qh>
  57 #include <server/compat/quake3.qh>
  58 #include <server/damage.qh>
  59 #include <server/gamelog.qh>
  60 #include <server/handicap.qh>
  61 #include <server/hook.qh>
  62 #include <server/impulse.qh>
  63 #include <server/intermission.qh>
  64 #include <server/ipban.qh>
  65 #include <server/main.qh>
  66 #include <server/mutators/_mod.qh>
  67 #include <server/player.qh>
  68 #include <server/portals.qh>
  69 #include <server/race.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 142                                         sf |= BIT(4); // show spectators
 143
 144         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 145         WriteByte(MSG_ENTITY, sf);
 146
 147         if (sf & BIT(1))
 148                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 149
 150         if(sf & BIT(4))
 151         {
 152                 float specs = CountSpectators(e, to);
 153                 WriteByte(MSG_ENTITY, specs);
 154                 WriteSpectators(e, to);
 155         }
 156
 157         return true;
 158 }
 159
 160 void ClientData_Attach(entity this)
 161 {
 162         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 163         CS(this).clientdata.drawonlytoclient = this;
 164         CS(this).clientdata.owner = this;
 165 }
 166
 167 void ClientData_Detach(entity this)
 168 {
 169         delete(CS(this).clientdata);
 170         CS(this).clientdata = NULL;
 171 }
 172
 173 void ClientData_Touch(entity e)
 174 {
 175         entity cd = CS(e).clientdata;
 176         if (cd) { cd.SendFlags = 1; }
 177
 178         // make it spectatable
 179         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 180         {
 181                 entity cd = CS(it).clientdata;
 182                 if (cd) { cd.SendFlags = 1; }
 183         });
 184 }
 185
 186
 187 /*
 188 =============
 189 CheckPlayerModel
 190
 191 Checks if the argument string can be a valid playermodel.
 192 Returns a valid one in doubt.
 193 =============
 194 */
 195 string FallbackPlayerModel;
 196 string CheckPlayerModel(string plyermodel) {
 197         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 198         {
 199                 // note: we cannot summon Don Strunzone here, some player may
 200                 // still have the model string set. In case anyone manages how
 201                 // to change a cvar default, we'll have a small leak here.
 202                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 203         }
 204         // only in right path
 205         if(substring(plyermodel, 0, 14) != "models/player/")
 206                 return FallbackPlayerModel;
 207         // only good file extensions
 208         if(substring(plyermodel, -4, 4) != ".iqm"
 209                 && substring(plyermodel, -4, 4) != ".zym"
 210                 && substring(plyermodel, -4, 4) != ".dpm"
 211                 && substring(plyermodel, -4, 4) != ".md3"
 212                 && substring(plyermodel, -4, 4) != ".psk")
 213         {
 214                 return FallbackPlayerModel;
 215         }
 216         // forbid the LOD models
 217         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 218                 return FallbackPlayerModel;
 219         if(plyermodel != strtolower(plyermodel))
 220                 return FallbackPlayerModel;
 221         // also, restrict to server models
 222         if(autocvar_sv_servermodelsonly)
 223         {
 224                 if(!fexists(plyermodel))
 225                         return FallbackPlayerModel;
 226         }
 227         return plyermodel;
 228 }
 229
 230 void setplayermodel(entity e, string modelname)
 231 {
 232         precache_model(modelname);
 233         _setmodel(e, modelname);
 234         player_setupanimsformodel(e);
 235         if(!autocvar_g_debug_globalsounds)
 236                 UpdatePlayerSounds(e);
 237 }
 238
 239 /** putting a client as observer in the server */
 240 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 241 {
 242         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 243         bool recount_ready = false;
 244         PlayerState_detach(this);
 245
 246         if (IS_PLAYER(this))
 247         {
 248                 if(GetResource(this, RES_HEALTH) >= 1)
 249                 {
 250                         // despawn effect
 251                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 252                 }
 253
 254                 // was a player, recount votes and ready status
 255                 if(IS_REAL_CLIENT(this))
 256                 {
 257                         if (vote_called) { VoteCount(false); }
 258                         this.ready = false;
 259                         if (warmup_stage || game_starttime > time) recount_ready = true;
 260                 }
 261                 entcs_update_players(this);
 262         }
 263
 264         if (use_spawnpoint)
 265         {
 266                 entity spot = SelectSpawnPoint(this, true);
 267                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 268                 this.angles = vec2(spot.angles);
 269                 // offset it so that the spectator spawns higher off the ground, looks better this way
 270                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         }
 272         else // change origin to restore previous view origin
 273                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 274         this.fixangle = true;
 275
 276         if (IS_REAL_CLIENT(this))
 277         {
 278                 msg_entity = this;
 279                 WriteByte(MSG_ONE, SVC_SETVIEW);
 280                 WriteEntity(MSG_ONE, this);
 281         }
 282         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 283         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 284         if(!autocvar_g_debug_globalsounds)
 285         {
 286                 // needed for player sounds
 287                 this.model = "";
 288                 FixPlayermodel(this);
 289         }
 290         setmodel(this, MDL_Null);
 291         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 292         this.view_ofs = '0 0 0';
 293
 294         RemoveGrapplingHooks(this);
 295         Portal_ClearAll(this);
 296         Unfreeze(this, false);
 297         SetSpectatee(this, NULL);
 298
 299         if (this.alivetime)
 300         {
 301                 if (!warmup_stage)
 302                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 303                 this.alivetime = 0;
 304         }
 305
 306         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 307
 308         TRANSMUTE(Observer, this);
 309
 310         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 311
 312         WaypointSprite_PlayerDead(this);
 313         accuracy_resend(this);
 314
 315         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 316                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 317
 318         CS(this).spectatortime = time;
 319         if(this.bot_attack)
 320                 IL_REMOVE(g_bot_targets, this);
 321         this.bot_attack = false;
 322         if(this.monster_attack)
 323                 IL_REMOVE(g_monster_targets, this);
 324         this.monster_attack = false;
 325         STAT(HUD, this) = HUD_NORMAL;
 326         this.iscreature = false;
 327         this.teleportable = TELEPORT_SIMPLE;
 328         if(this.damagedbycontents)
 329                 IL_REMOVE(g_damagedbycontents, this);
 330         this.damagedbycontents = false;
 331         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 332         SetSpectatee_status(this, etof(this));
 333         this.takedamage = DAMAGE_NO;
 334         this.solid = SOLID_NOT;
 335         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 336         this.flags = FL_CLIENT | FL_NOTARGET;
 337         this.effects = 0;
 338         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 339         this.pauserotarmor_finished = 0;
 340         this.pauserothealth_finished = 0;
 341         this.pauseregen_finished = 0;
 342         this.damageforcescale = 0;
 343         this.death_time = 0;
 344         this.respawn_flags = 0;
 345         this.respawn_time = 0;
 346         STAT(RESPAWN_TIME, this) = 0;
 347         this.alpha = 0;
 348         this.scale = 0;
 349         this.fade_time = 0;
 350         this.pain_finished = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         player_powerups_remove_all(this);
 367         this.items = 0;
 368         STAT(WEAPONS, this) = '0 0 0';
 369         this.drawonlytoclient = this;
 370
 371         this.viewloc = NULL;
 372
 373         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 374
 375         this.weaponmodel = "";
 376         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 377         {
 378                 this.weaponentities[slot] = NULL;
 379         }
 380         this.exteriorweaponentity = NULL;
 381         CS(this).killcount = FRAGS_SPECTATOR;
 382         this.velocity = '0 0 0';
 383         this.avelocity = '0 0 0';
 384         this.punchangle = '0 0 0';
 385         this.punchvector = '0 0 0';
 386         this.oldvelocity = this.velocity;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void PutPlayerInServer(entity this)
 538 {
 539         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 540
 541         PlayerState_attach(this);
 542         accuracy_resend(this);
 543
 544         if (teamplay && this.bot_forced_team)
 545                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 546
 547         if (this.team < 0)
 548                 TeamBalance_JoinBestTeam(this);
 549
 550         entity spot = SelectSpawnPoint(this, false);
 551         if (!spot) {
 552                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 553                 return; // spawn failed
 554         }
 555
 556         TRANSMUTE(Player, this);
 557
 558         CS(this).wasplayer = true;
 559         this.iscreature = true;
 560         this.teleportable = TELEPORT_NORMAL;
 561         if(!this.damagedbycontents)
 562                 IL_PUSH(g_damagedbycontents, this);
 563         this.damagedbycontents = true;
 564         set_movetype(this, MOVETYPE_WALK);
 565         this.solid = SOLID_SLIDEBOX;
 566         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 567         if (autocvar_g_playerclip_collisions)
 568                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 569         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 570                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 571         this.frags = FRAGS_PLAYER;
 572         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 573         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 574         if (autocvar__notarget)
 575                 this.flags |= FL_NOTARGET;
 576         this.takedamage = DAMAGE_AIM;
 577         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 578
 579         if (warmup_stage) {
 580                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 581                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 582                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 583                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 584                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 585                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 586                 SetResource(this, RES_HEALTH, warmup_start_health);
 587                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 588                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 589         } else {
 590                 SetResource(this, RES_SHELLS, start_ammo_shells);
 591                 SetResource(this, RES_BULLETS, start_ammo_nails);
 592                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 593                 SetResource(this, RES_CELLS, start_ammo_cells);
 594                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 595                 SetResource(this, RES_FUEL, start_ammo_fuel);
 596                 SetResource(this, RES_HEALTH, start_health);
 597                 SetResource(this, RES_ARMOR, start_armorvalue);
 598                 STAT(WEAPONS, this) = start_weapons;
 599                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 600                 {
 601                         GiveRandomWeapons(this, random_start_weapons_count,
 602                                 autocvar_g_random_start_weapons, random_start_ammo);
 603                 }
 604         }
 605         SetSpectatee_status(this, 0);
 606
 607         PS(this).dual_weapons = '0 0 0';
 608
 609         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 610                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 611
 612         this.items = start_items;
 613
 614         float shieldtime = time + autocvar_g_spawnshieldtime;
 615
 616         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 617         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 618         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 619         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 620         if (!sv_ready_restart_after_countdown && time < game_starttime)
 621         {
 622                 float f = game_starttime - time;
 623                 shieldtime += f;
 624                 this.pauserotarmor_finished += f;
 625                 this.pauserothealth_finished += f;
 626                 this.pauseregen_finished += f;
 627         }
 628
 629         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 630
 631         this.damageforcescale = autocvar_g_player_damageforcescale;
 632         this.death_time = 0;
 633         this.respawn_flags = 0;
 634         this.respawn_time = 0;
 635         STAT(RESPAWN_TIME, this) = 0;
 636         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(REVIVE_PROGRESS, this) = 0;
 661         this.revival_time = 0;
 662
 663         STAT(AIR_FINISHED, this) = 0;
 664         this.waterlevel = WATERLEVEL_NONE;
 665         this.watertype = CONTENT_EMPTY;
 666
 667         entity spawnevent = new_pure(spawnevent);
 668         spawnevent.owner = this;
 669         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 670
 671         // Cut off any still running player sounds.
 672         stopsound(this, CH_PLAYER_SINGLE);
 673
 674         this.model = "";
 675         FixPlayermodel(this);
 676         this.drawonlytoclient = NULL;
 677
 678         this.viewloc = NULL;
 679
 680         for(int slot = 0; slot < MAX_AXH; ++slot)
 681         {
 682                 entity axh = this.(AuxiliaryXhair[slot]);
 683                 this.(AuxiliaryXhair[slot]) = NULL;
 684
 685                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 686                         delete(axh);
 687         }
 688
 689         this.spawnpoint_targ = NULL;
 690
 691         UNSET_DUCKED(this);
 692         this.view_ofs = STAT(PL_VIEW_OFS, this);
 693         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 694         this.spawnorigin = spot.origin;
 695         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 696         // don't reset back to last position, even if new position is stuck in solid
 697         this.oldorigin = this.origin;
 698         if(this.conveyor)
 699                 IL_REMOVE(g_conveyed, this);
 700         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 701         if(this.swampslug)
 702                 IL_REMOVE(g_swamped, this);
 703         this.swampslug = NULL;
 704         this.swamp_interval = 0;
 705         if(this.ladder_entity)
 706                 IL_REMOVE(g_ladderents, this);
 707         this.ladder_entity = NULL;
 708         IL_EACH(g_counters, it.realowner == this,
 709         {
 710                 delete(it);
 711         });
 712         STAT(HUD, this) = HUD_NORMAL;
 713
 714         this.event_damage = PlayerDamage;
 715         this.event_heal = PlayerHeal;
 716
 717         this.draggable = func_null;
 718
 719         if(!this.bot_attack)
 720                 IL_PUSH(g_bot_targets, this);
 721         this.bot_attack = true;
 722         if(!this.monster_attack)
 723                 IL_PUSH(g_monster_targets, this);
 724         this.monster_attack = true;
 725         navigation_dynamicgoal_init(this, false);
 726
 727         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 728
 729         // player was spectator
 730         if (CS(this).killcount == FRAGS_SPECTATOR) {
 731                 PlayerScore_Clear(this);
 732                 CS(this).killcount = 0;
 733                 CS(this).startplaytime = time;
 734         }
 735
 736         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 CL_SpawnWeaponentity(this, weaponentity);
 740         }
 741         this.alpha = default_player_alpha;
 742         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 743         this.exteriorweaponentity.alpha = default_weapon_alpha;
 744
 745         this.speedrunning = false;
 746
 747         this.counter_cnt = 0;
 748         this.fragsfilter_cnt = 0;
 749
 750         target_voicescript_clear(this);
 751
 752         // reset fields the weapons may use
 753         FOREACH(Weapons, true, {
 754                 it.wr_resetplayer(it, this);
 755                         // reload all reloadable weapons
 756                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 757                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758                         {
 759                                 .entity weaponentity = weaponentities[slot];
 760                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 761                         }
 762                 }
 763         });
 764
 765         Unfreeze(this, false);
 766
 767         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 768         {
 769                 string s = spot.target;
 770                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 771                         spot.target = string_null;
 772                 SUB_UseTargets(spot, this, NULL);
 773                 if(g_assault || g_race)
 774                         spot.target = s;
 775         }
 776
 777         if (autocvar_spawn_debug)
 778         {
 779                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 780                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 781         }
 782
 783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 784         {
 785                 .entity weaponentity = weaponentities[slot];
 786                 entity w_ent = this.(weaponentity);
 787                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 788                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 789                 else
 790                         w_ent.m_switchweapon = WEP_Null;
 791                 w_ent.m_weapon = WEP_Null;
 792                 w_ent.weaponname = "";
 793                 w_ent.m_switchingweapon = WEP_Null;
 794                 w_ent.cnt = -1;
 795         }
 796
 797         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 798
 799         if (CS(this).impulse) ImpulseCommands(this);
 800
 801         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 802         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 803         {
 804                 .entity weaponentity = weaponentities[slot];
 805                 W_WeaponFrame(this, weaponentity);
 806         }
 807
 808         if (!warmup_stage && !this.alivetime)
 809                 this.alivetime = time;
 810
 811         antilag_clear(this, CS(this));
 812
 813         if (warmup_stage == -1)
 814                 ReadyCount();
 815 }
 816
 817 /** Called when a client spawns in the server */
 818 void PutClientInServer(entity this)
 819 {
 820         if (IS_REAL_CLIENT(this)) {
 821                 msg_entity = this;
 822                 WriteByte(MSG_ONE, SVC_SETVIEW);
 823                 WriteEntity(MSG_ONE, this);
 824         }
 825         if (game_stopped)
 826                 TRANSMUTE(Observer, this);
 827
 828         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 829         SetSpectatee(this, NULL);
 830
 831         // reset player keys
 832         if(PS(this))
 833                 PS(this).itemkeys = 0;
 834
 835         MUTATOR_CALLHOOK(PutClientInServer, this);
 836
 837         if (IS_OBSERVER(this)) {
 838                 PutObserverInServer(this, false, use_spawnpoint);
 839         } else if (IS_PLAYER(this)) {
 840                 PutPlayerInServer(this);
 841         }
 842
 843         bot_relinkplayerlist();
 844 }
 845
 846 // TODO do we need all these fields, or should we stop autodetecting runtime
 847 // changes and just have a console command to update this?
 848 bool ClientInit_SendEntity(entity this, entity to, int sf)
 849 {
 850         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 851         return = true;
 852         msg_entity = to;
 853         // MSG_INIT replacement
 854         // TODO: make easier to use
 855         Registry_send_all();
 856         W_PROP_reload(MSG_ONE, to);
 857         ClientInit_misc(this);
 858         MUTATOR_CALLHOOK(Ent_Init);
 859 }
 860 void ClientInit_misc(entity this)
 861 {
 862         int channel = MSG_ONE;
 863         WriteHeader(channel, ENT_CLIENT_INIT);
 864         WriteByte(channel, g_nexball_meter_period * 32);
 865         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 866         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 867         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 869         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 870         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 871         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 873
 874         if(autocvar_sv_foginterval && world.fog != "")
 875                 WriteString(channel, world.fog);
 876         else
 877                 WriteString(channel, "");
 878         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 879         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 880         WriteByte(channel, serverflags);
 881         WriteCoord(channel, autocvar_g_trueaim_minrange);
 882 }
 883
 884 void ClientInit_CheckUpdate(entity this)
 885 {
 886         this.nextthink = time;
 887         if(this.count != autocvar_g_balance_armor_blockpercent)
 888         {
 889                 this.count = autocvar_g_balance_armor_blockpercent;
 890                 this.SendFlags |= 1;
 891         }
 892         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 893         {
 894                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 895                 this.SendFlags |= 1;
 896         }
 897 }
 898
 899 void ClientInit_Spawn()
 900 {
 901         entity e = new_pure(clientinit);
 902         setthink(e, ClientInit_CheckUpdate);
 903         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 904
 905         ClientInit_CheckUpdate(e);
 906 }
 907
 908 /*
 909 =============
 910 SetNewParms
 911 =============
 912 */
 913 void SetNewParms ()
 914 {
 915         // initialize parms for a new player
 916         parm1 = -(86400 * 366);
 917
 918         MUTATOR_CALLHOOK(SetNewParms);
 919 }
 920
 921 /*
 922 =============
 923 SetChangeParms
 924 =============
 925 */
 926 void SetChangeParms (entity this)
 927 {
 928         // save parms for level change
 929         parm1 = CS(this).parm_idlesince - time;
 930
 931         MUTATOR_CALLHOOK(SetChangeParms);
 932 }
 933
 934 /*
 935 =============
 936 DecodeLevelParms
 937 =============
 938 */
 939 void DecodeLevelParms(entity this)
 940 {
 941         // load parms
 942         CS(this).parm_idlesince = parm1;
 943         if (CS(this).parm_idlesince == -(86400 * 366))
 944                 CS(this).parm_idlesince = time;
 945
 946         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 947         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 948
 949         MUTATOR_CALLHOOK(DecodeLevelParms);
 950 }
 951
 952 void FixClientCvars(entity e)
 953 {
 954         // send prediction settings to the client
 955         if(autocvar_g_antilag == 3) // client side hitscan
 956                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 957         if(autocvar_sv_gentle)
 958                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 959
 960         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 961         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 962
 963         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 964
 965         MUTATOR_CALLHOOK(FixClientCvars, e);
 966 }
 967
 968 bool findinlist_abbrev(string tofind, string list)
 969 {
 970         if(list == "" || tofind == "")
 971                 return false; // empty list or search, just return
 972
 973         // this function allows abbreviated strings!
 974         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 975         {
 976                 return true;
 977         });
 978
 979         return false;
 980 }
 981
 982 bool PlayerInIPList(entity p, string iplist)
 983 {
 984         // some safety checks (never allow local?)
 985         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 986                 return false;
 987
 988         return findinlist_abbrev(p.netaddress, iplist);
 989 }
 990
 991 bool PlayerInIDList(entity p, string idlist)
 992 {
 993         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 994         if(!p.crypto_idfp)
 995                 return false;
 996
 997         return findinlist_abbrev(p.crypto_idfp, idlist);
 998 }
 999
1000 bool PlayerInList(entity player, string list)
1001 {
1002         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1003 }
1004
1005 #ifdef DP_EXT_PRECONNECT
1006 /*
1007 =============
1008 ClientPreConnect
1009
1010 Called once (not at each match start) when a client begins a connection to the server
1011 =============
1012 */
1013 void ClientPreConnect(entity this)
1014 {
1015         if(autocvar_sv_eventlog)
1016         {
1017                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1018                         this.playerid,
1019                         etof(this),
1020                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1021                 ));
1022         }
1023 }
1024 #endif
1025
1026 // NOTE csqc uses the active mutators list sent by this function
1027 // to understand which mutators are enabled
1028 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1029 void SendWelcomeMessage(entity this, int msg_type)
1030 {
1031         WriteByte(msg_type, boolean(autocvar_g_campaign));
1032         if (boolean(autocvar_g_campaign))
1033         {
1034                 WriteString(msg_type, Campaign_GetTitle());
1035                 WriteByte(msg_type, Campaign_GetLevelNum());
1036                 WriteString(msg_type, Campaign_GetMessage());
1037                 return;
1038         }
1039         WriteString(msg_type, autocvar_hostname);
1040         WriteString(msg_type, autocvar_g_xonoticversion);
1041         WriteByte(msg_type, CS(this).version_mismatch);
1042         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1043         WriteByte(msg_type, map_minplayers);
1044         WriteByte(msg_type, GetPlayerLimit());
1045
1046         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1047         string modifications = M_ARGV(0, string);
1048
1049         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1050                 modifications = strcat(modifications, ", No start weapons");
1051         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1052                 modifications = strcat(modifications, ", Low gravity");
1053         if(g_weapon_stay && !g_cts)
1054                 modifications = strcat(modifications, ", Weapons stay");
1055         if(autocvar_g_jetpack)
1056                 modifications = strcat(modifications, ", Jetpack");
1057         modifications = substring(modifications, 2, strlen(modifications) - 2);
1058
1059         WriteString(msg_type, modifications);
1060
1061         WriteString(msg_type, g_weaponarena_list);
1062
1063         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1064         {
1065                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1066                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1067         }
1068
1069         WriteString(msg_type, cache_mutatormsg);
1070
1071         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1072 }
1073
1074 /**
1075 =============
1076 ClientConnect
1077
1078 Called when a client connects to the server
1079 =============
1080 */
1081 void ClientConnect(entity this)
1082 {
1083         if (Ban_MaybeEnforceBanOnce(this)) return;
1084         assert(!IS_CLIENT(this), return);
1085         this.flags |= FL_CLIENT;
1086         assert(player_count >= 0, player_count = 0);
1087
1088         TRANSMUTE(Client, this);
1089         CS(this).version_nagtime = time + 10 + random() * 10;
1090
1091         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1092
1093         bot_clientconnect(this);
1094
1095         Player_DetermineForcedTeam(this);
1096
1097         TRANSMUTE(Observer, this);
1098
1099         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1100
1101         // always track bots, don't ask for cl_allow_uidtracking
1102         if (IS_BOT_CLIENT(this))
1103                 PlayerStats_GameReport_AddPlayer(this);
1104         else
1105                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1106
1107         if (autocvar_sv_eventlog)
1108                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1109
1110         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1111
1112         stuffcmd(this, clientstuff, "\n");
1113         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1114
1115         FixClientCvars(this);
1116
1117         // get version info from player
1118         stuffcmd(this, "cmd clientversion $gameversion\n");
1119
1120         // notify about available teams
1121         if (teamplay)
1122         {
1123                 entity balance = TeamBalance_CheckAllowedTeams(this);
1124                 int t = TeamBalance_GetAllowedTeams(balance);
1125                 TeamBalance_Destroy(balance);
1126                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1127         }
1128         else
1129         {
1130                 stuffcmd(this, "set _teams_available 0\n");
1131         }
1132
1133         bot_relinkplayerlist();
1134
1135         CS(this).spectatortime = time;
1136         if (blockSpectators)
1137         {
1138                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1139         }
1140
1141         CS(this).jointime = time;
1142
1143         if (IS_REAL_CLIENT(this))
1144         {
1145                 if (g_weaponarena_weapons == WEPSET(TUBA))
1146                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1147                 // quickmenu file must be put in a subfolder with an unique name
1148                 // to reduce chances of overriding custom client quickmenus
1149                 if (waypointeditor_enabled)
1150                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1151                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1152                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1153         }
1154
1155         if (!autocvar_sv_foginterval && world.fog != "")
1156                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1157
1158         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1159                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1160                         send_CSQC_teamnagger();
1161
1162         CSQCMODEL_AUTOINIT(this);
1163
1164         CS(this).model_randomizer = random();
1165
1166         if (IS_REAL_CLIENT(this))
1167                 sv_notice_join(this);
1168
1169         this.move_qcphysics = autocvar_sv_qcphysics;
1170
1171         // update physics stats (players can spawn before physics runs)
1172         Physics_UpdateStats(this);
1173
1174         IL_EACH(g_initforplayer, it.init_for_player, {
1175                 it.init_for_player(it, this);
1176         });
1177
1178         Handicap_Initialize(this);
1179
1180         MUTATOR_CALLHOOK(ClientConnect, this);
1181
1182         if (player_count == 1)
1183                 localcmd("\nsv_hook_firstjoin\n");
1184 }
1185 /*
1186 =============
1187 ClientDisconnect
1188
1189 Called when a client disconnects from the server
1190 =============
1191 */
1192 .entity chatbubbleentity;
1193 void player_powerups_remove_all(entity this);
1194
1195 void ClientDisconnect(entity this)
1196 {
1197         assert(IS_CLIENT(this), return);
1198
1199         PlayerStats_GameReport_FinalizePlayer(this);
1200         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1201         if (CS(this).active_minigame) part_minigame(this);
1202         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1203
1204         if (autocvar_sv_eventlog)
1205                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1206
1207         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1208
1209         if(IS_SPEC(this))
1210                 SetSpectatee(this, NULL);
1211
1212         MUTATOR_CALLHOOK(ClientDisconnect, this);
1213
1214         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1215         strfree(CS_CVAR(this).weaponorder_byimpulse);
1216         ClientState_detach(this);
1217
1218         Portal_ClearAll(this);
1219
1220         Unfreeze(this, false);
1221
1222         RemoveGrapplingHooks(this);
1223
1224         // Here, everything has been done that requires this player to be a client.
1225
1226         this.flags &= ~FL_CLIENT;
1227
1228         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1229         if (this.killindicator) delete(this.killindicator);
1230
1231         IL_EACH(g_counters, it.realowner == this,
1232         {
1233                 delete(it);
1234         });
1235
1236         WaypointSprite_PlayerGone(this);
1237
1238         bot_relinkplayerlist();
1239
1240         strfree(this.clientstatus);
1241         if (this.personal) delete(this.personal);
1242
1243         this.playerid = 0;
1244         if (warmup_stage || game_starttime > time) ReadyCount();
1245         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1246
1247         player_powerups_remove_all(this); // stop powerup sound
1248
1249         ONREMOVE(this);
1250
1251         if (player_count == 0)
1252                 localcmd("\nsv_hook_lastleave\n");
1253 }
1254
1255 void ChatBubbleThink(entity this)
1256 {
1257         this.nextthink = time;
1258         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1259         {
1260                 if(this.owner) // but why can that ever be NULL?
1261                         this.owner.chatbubbleentity = NULL;
1262                 delete(this);
1263                 return;
1264         }
1265
1266         this.mdl = "";
1267
1268         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1269         {
1270                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1271                         this.mdl = "models/sprites/minigame_busy.iqm";
1272                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1273                         this.mdl = "models/misc/chatbubble.spr";
1274         }
1275
1276         if ( this.model != this.mdl )
1277                 _setmodel(this, this.mdl);
1278
1279 }
1280
1281 void UpdateChatBubble(entity this)
1282 {
1283         if (this.alpha < 0)
1284                 return;
1285         // spawn a chatbubble entity if needed
1286         if (!this.chatbubbleentity)
1287         {
1288                 this.chatbubbleentity = new(chatbubbleentity);
1289                 this.chatbubbleentity.owner = this;
1290                 this.chatbubbleentity.exteriormodeltoclient = this;
1291                 setthink(this.chatbubbleentity, ChatBubbleThink);
1292                 this.chatbubbleentity.nextthink = time;
1293                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1294                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1295                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1296                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1297                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1298                 //this.chatbubbleentity.model = "";
1299                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1300         }
1301 }
1302
1303 void calculate_player_respawn_time(entity this)
1304 {
1305         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1306                 return;
1307
1308         float gametype_setting_tmp;
1309         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1310         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1311         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1312         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1313         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1314         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1315
1316         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1317         if (teamplay)
1318         {
1319                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1320                         if(it.team == this.team)
1321                                 ++pcount;
1322                 });
1323                 if (sdelay_small_count == 0)
1324                         sdelay_small_count = 1;
1325                 if (sdelay_large_count == 0)
1326                         sdelay_large_count = 1;
1327         }
1328         else
1329         {
1330                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1331                         ++pcount;
1332                 });
1333                 if (sdelay_small_count == 0)
1334                 {
1335                         if (IS_INDEPENDENT_PLAYER(this))
1336                         {
1337                                 // Players play independently. No point in requiring enemies.
1338                                 sdelay_small_count = 1;
1339                         }
1340                         else
1341                         {
1342                                 // Players play AGAINST each other. Enemies required.
1343                                 sdelay_small_count = 2;
1344                         }
1345                 }
1346                 if (sdelay_large_count == 0)
1347                 {
1348                         if (IS_INDEPENDENT_PLAYER(this))
1349                         {
1350                                 // Players play independently. No point in requiring enemies.
1351                                 sdelay_large_count = 1;
1352                         }
1353                         else
1354                         {
1355                                 // Players play AGAINST each other. Enemies required.
1356                                 sdelay_large_count = 2;
1357                         }
1358                 }
1359         }
1360
1361         float sdelay;
1362
1363         if (pcount <= sdelay_small_count)
1364                 sdelay = sdelay_small;
1365         else if (pcount >= sdelay_large_count)
1366                 sdelay = sdelay_large;
1367         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1368                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1369
1370         if(waves)
1371                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1372         else
1373                 this.respawn_time = time + sdelay;
1374
1375         if(sdelay < sdelay_max)
1376                 this.respawn_time_max = time + sdelay_max;
1377         else
1378                 this.respawn_time_max = this.respawn_time;
1379
1380         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1381                 this.respawn_countdown = 10; // first number to count down from is 10
1382         else
1383                 this.respawn_countdown = -1; // do not count down
1384
1385         if(autocvar_g_forced_respawn)
1386                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1387 }
1388
1389 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1390 // added to the model skins
1391 /*void UpdateColorModHack()
1392 {
1393         float c;
1394         c = this.clientcolors & 15;
1395         // LordHavoc: only bothering to support white, green, red, yellow, blue
1396              if (!teamplay) this.colormod = '0 0 0';
1397         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1398         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1399         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1400         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1401         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1402         else this.colormod = '1 1 1';
1403 }*/
1404
1405 void respawn(entity this)
1406 {
1407         bool damagedbycontents_prev = this.damagedbycontents;
1408         if(this.alpha >= 0)
1409         {
1410                 if(autocvar_g_respawn_ghosts)
1411                 {
1412                         this.solid = SOLID_NOT;
1413                         this.takedamage = DAMAGE_NO;
1414                         this.damagedbycontents = false;
1415                         set_movetype(this, MOVETYPE_FLY);
1416                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1417                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1418                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1419                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1420                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1421                         if(autocvar_g_respawn_ghosts_time > 0)
1422                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1423                 }
1424                 else
1425                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1426         }
1427
1428         CopyBody(this, 1);
1429         this.damagedbycontents = damagedbycontents_prev;
1430
1431         this.effects |= EF_NODRAW; // prevent another CopyBody
1432         PutClientInServer(this);
1433 }
1434
1435 void play_countdown(entity this, float finished, Sound samp)
1436 {
1437         TC(Sound, samp);
1438         float time_left = finished - time;
1439         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1440                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1441 }
1442
1443 // it removes special powerups not handled by StatusEffects
1444 void player_powerups_remove_all(entity this)
1445 {
1446         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1447         {
1448                 // don't play the poweroff sound when the game restarts or the player disconnects
1449                 if (time > game_starttime + 1 && IS_CLIENT(this)
1450                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1451                 {
1452                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1453                 }
1454                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1455                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1456                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1457         }
1458 }
1459
1460 void player_powerups(entity this)
1461 {
1462         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1463                 this.modelflags |= MF_ROCKET;
1464         else
1465                 this.modelflags &= ~MF_ROCKET;
1466
1467         this.effects &= ~EF_NODEPTHTEST;
1468
1469         if (IS_DEAD(this))
1470                 player_powerups_remove_all(this);
1471
1472         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1473                 return;
1474
1475         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1476         int items_prev = this.items;
1477
1478         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1479         {
1480                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1481                 if (this.items & IT_SUPERWEAPON)
1482                 {
1483                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1484                         {
1485                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1486                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1487                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1488                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1489                         }
1490                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1491                         {
1492                                 // don't let them run out
1493                         }
1494                         else
1495                         {
1496                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1497                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1498                                 {
1499                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1500                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1501                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1502                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1503                                 }
1504                         }
1505                 }
1506                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1507                 {
1508                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1509                         {
1510                                 this.items = this.items | IT_SUPERWEAPON;
1511                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1512                                 {
1513                                         if(!g_cts)
1514                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1515                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1516                                 }
1517                         }
1518                         else
1519                         {
1520                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1521                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1522                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1523                         }
1524                 }
1525                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1526                 {
1527                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1528                 }
1529         }
1530
1531         if(autocvar_g_nodepthtestplayers)
1532                 this.effects = this.effects | EF_NODEPTHTEST;
1533
1534         if(autocvar_g_fullbrightplayers)
1535                 this.effects = this.effects | EF_FULLBRIGHT;
1536
1537         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1538 }
1539
1540 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1541 {
1542         if(current > stable)
1543                 return current;
1544         else if(current > stable - 0.25) // when close enough, "snap"
1545                 return stable;
1546         else
1547                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1548 }
1549
1550 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1551 {
1552         if(current < stable)
1553                 return current;
1554         else if(current < stable + 0.25) // when close enough, "snap"
1555                 return stable;
1556         else
1557                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1558 }
1559
1560 void RotRegen(entity this, Resource res, float limit_mod,
1561         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1562         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1563 {
1564         float old = GetResource(this, res);
1565         float current = old;
1566         if(current > rotstable)
1567         {
1568                 if(rotframetime > 0)
1569                 {
1570                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1571                         current = max(rotstable, current - rotlinear * rotframetime);
1572                 }
1573         }
1574         else if(current < regenstable)
1575         {
1576                 if(regenframetime > 0)
1577                 {
1578                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1579                         current = min(regenstable, current + regenlinear * regenframetime);
1580                 }
1581         }
1582
1583         float limit = GetResourceLimit(this, res) * limit_mod;
1584         if(current > limit)
1585                 current = limit;
1586
1587         if (current != old)
1588                 SetResource(this, res, current);
1589 }
1590
1591 void player_regen(entity this)
1592 {
1593         float max_mod, regen_mod, rot_mod, limit_mod;
1594         max_mod = regen_mod = rot_mod = limit_mod = 1;
1595
1596         float regen_health = autocvar_g_balance_health_regen;
1597         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1598         float regen_health_rot = autocvar_g_balance_health_rot;
1599         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1600         float regen_health_stable = autocvar_g_balance_health_regenstable;
1601         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1602         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1603                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1604         max_mod = M_ARGV(1, float);
1605         regen_mod = M_ARGV(2, float);
1606         rot_mod = M_ARGV(3, float);
1607         limit_mod = M_ARGV(4, float);
1608         regen_health = M_ARGV(5, float);
1609         regen_health_linear = M_ARGV(6, float);
1610         regen_health_rot = M_ARGV(7, float);
1611         regen_health_rotlinear = M_ARGV(8, float);
1612         regen_health_stable = M_ARGV(9, float);
1613         regen_health_rotstable = M_ARGV(10, float);
1614
1615         float rotstable, regenstable, rotframetime, regenframetime;
1616
1617         if(!mutator_returnvalue)
1618         if(!STAT(FROZEN, this))
1619         {
1620                 regenstable = autocvar_g_balance_armor_regenstable;
1621                 rotstable = autocvar_g_balance_armor_rotstable;
1622                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1623                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1624                 RotRegen(this, RES_ARMOR, limit_mod,
1625                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1626                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1627
1628                 // NOTE: max_mod is only applied to health
1629                 regenstable = regen_health_stable * max_mod;
1630                 rotstable = regen_health_rotstable * max_mod;
1631                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1632                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1633                 RotRegen(this, RES_HEALTH, limit_mod,
1634                         regenstable, regen_health, regen_health_linear, regenframetime,
1635                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1636         }
1637
1638         // if player rotted to death...  die!
1639         // check this outside above checks, as player may still be able to rot to death
1640         if(GetResource(this, RES_HEALTH) < 1)
1641         {
1642                 if(this.vehicle)
1643                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1644                 if(this.event_damage)
1645                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1646         }
1647
1648         if (!(this.items & IT_UNLIMITED_AMMO))
1649         {
1650                 regenstable = autocvar_g_balance_fuel_regenstable;
1651                 rotstable = autocvar_g_balance_fuel_rotstable;
1652                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1653                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1654                 RotRegen(this, RES_FUEL, 1,
1655                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1656                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1657         }
1658 }
1659
1660 bool zoomstate_set;
1661 void SetZoomState(entity this, float newzoom)
1662 {
1663         if(newzoom != CS(this).zoomstate)
1664         {
1665                 CS(this).zoomstate = newzoom;
1666                 ClientData_Touch(this);
1667         }
1668         zoomstate_set = true;
1669 }
1670
1671 void GetPressedKeys(entity this)
1672 {
1673         MUTATOR_CALLHOOK(GetPressedKeys, this);
1674         if (game_stopped)
1675         {
1676                 CS(this).pressedkeys = 0;
1677                 STAT(PRESSED_KEYS, this) = 0;
1678                 return;
1679         }
1680
1681         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1682         int keys = STAT(PRESSED_KEYS, this);
1683         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1684         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1685         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1686         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1687
1688         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1689         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1690         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1691         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1692         CS(this).pressedkeys = keys; // store for other users
1693
1694         STAT(PRESSED_KEYS, this) = keys;
1695 }
1696
1697 /*
1698 ======================
1699 spectate mode routines
1700 ======================
1701 */
1702
1703 void SpectateCopy(entity this, entity spectatee)
1704 {
1705         TC(Client, this); TC(Client, spectatee);
1706
1707         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1708         PS(this) = PS(spectatee);
1709         this.armortype = spectatee.armortype;
1710         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1711         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1712         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1713         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1714         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1715         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1716         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1717         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1718         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1719         CS(this).impulse = 0;
1720         this.disableclientprediction = 1; // no need to run prediction on a spectator
1721         this.items = spectatee.items;
1722         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1723         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1724         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1725         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1726         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1727         this.punchangle = spectatee.punchangle;
1728         this.view_ofs = spectatee.view_ofs;
1729         this.velocity = spectatee.velocity;
1730         this.dmg_take = spectatee.dmg_take;
1731         this.dmg_save = spectatee.dmg_save;
1732         this.dmg_inflictor = spectatee.dmg_inflictor;
1733         this.v_angle = spectatee.v_angle;
1734         this.angles = spectatee.v_angle;
1735         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1736         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1737         this.viewloc = spectatee.viewloc;
1738         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1739                 this.fixangle = true;
1740         setorigin(this, spectatee.origin);
1741         setsize(this, spectatee.mins, spectatee.maxs);
1742         SetZoomState(this, CS(spectatee).zoomstate);
1743
1744     anticheat_spectatecopy(this, spectatee);
1745         STAT(HUD, this) = STAT(HUD, spectatee);
1746         if(spectatee.vehicle)
1747     {
1748         this.angles = spectatee.v_angle;
1749
1750         //this.fixangle = false;
1751         //this.velocity = spectatee.vehicle.velocity;
1752         this.vehicle_health = spectatee.vehicle_health;
1753         this.vehicle_shield = spectatee.vehicle_shield;
1754         this.vehicle_energy = spectatee.vehicle_energy;
1755         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1756         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1757         this.vehicle_reload1 = spectatee.vehicle_reload1;
1758         this.vehicle_reload2 = spectatee.vehicle_reload2;
1759
1760         //msg_entity = this;
1761
1762        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1763             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1764            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1765            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1766
1767         //WriteByte (MSG_ONE, SVC_SETVIEW);
1768         //    WriteEntity(MSG_ONE, this);
1769         //makevectors(spectatee.v_angle);
1770         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1771     }
1772 }
1773
1774 bool SpectateUpdate(entity this)
1775 {
1776         if(!this.enemy)
1777                 return false;
1778
1779         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1780         {
1781                 SetSpectatee(this, NULL);
1782                 return false;
1783         }
1784
1785         SpectateCopy(this, this.enemy);
1786
1787         return true;
1788 }
1789
1790 bool SpectateSet(entity this)
1791 {
1792         if(!IS_PLAYER(this.enemy))
1793                 return false;
1794
1795         ClientData_Touch(this.enemy);
1796
1797         msg_entity = this;
1798         WriteByte(MSG_ONE, SVC_SETVIEW);
1799         WriteEntity(MSG_ONE, this.enemy);
1800         set_movetype(this, MOVETYPE_NONE);
1801         accuracy_resend(this);
1802
1803         if(!SpectateUpdate(this))
1804                 PutObserverInServer(this, false, true);
1805
1806         return true;
1807 }
1808
1809 void SetSpectatee_status(entity this, int spectatee_num)
1810 {
1811         int oldspectatee_status = CS(this).spectatee_status;
1812         CS(this).spectatee_status = spectatee_num;
1813
1814         if (CS(this).spectatee_status != oldspectatee_status)
1815         {
1816                 if (STAT(PRESSED_KEYS, this))
1817                 {
1818                         CS(this).pressedkeys = 0;
1819                         STAT(PRESSED_KEYS, this) = 0;
1820                 }
1821                 ClientData_Touch(this);
1822                 if (g_race || g_cts) race_InitSpectator();
1823         }
1824 }
1825
1826 void SetSpectatee(entity this, entity spectatee)
1827 {
1828         if(IS_BOT_CLIENT(this))
1829                 return; // bots abuse .enemy, this code is useless to them
1830
1831         entity old_spectatee = this.enemy;
1832
1833         this.enemy = spectatee;
1834
1835         // WEAPONTODO
1836         // these are required to fix the spectator bug with arc
1837         if(old_spectatee)
1838         {
1839                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1840                 {
1841                         .entity weaponentity = weaponentities[slot];
1842                         if(old_spectatee.(weaponentity).arc_beam)
1843                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1844                 }
1845         }
1846         if(spectatee)
1847         {
1848                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1849                 {
1850                         .entity weaponentity = weaponentities[slot];
1851                         if(spectatee.(weaponentity).arc_beam)
1852                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1853                 }
1854         }
1855
1856         if (spectatee)
1857                 SetSpectatee_status(this, etof(spectatee));
1858
1859         // needed to update spectator list
1860         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1861 }
1862
1863 bool Spectate(entity this, entity pl)
1864 {
1865         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1866                 return false;
1867         pl = M_ARGV(1, entity);
1868
1869         SetSpectatee(this, pl);
1870         return SpectateSet(this);
1871 }
1872
1873 bool SpectateNext(entity this)
1874 {
1875         entity ent = find(this.enemy, classname, STR_PLAYER);
1876
1877         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1878                 ent = M_ARGV(1, entity);
1879         else if (!ent)
1880                 ent = find(ent, classname, STR_PLAYER);
1881
1882         if(ent) { SetSpectatee(this, ent); }
1883
1884         return SpectateSet(this);
1885 }
1886
1887 bool SpectatePrev(entity this)
1888 {
1889         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1890         entity ent = findchain(classname, STR_PLAYER);
1891         if (!ent) // no player
1892                 return false;
1893
1894         entity first = ent;
1895         // skip players until current spectated player
1896         if(this.enemy)
1897         while(ent && ent != this.enemy)
1898                 ent = ent.chain;
1899
1900         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1901         {
1902                 case MUT_SPECPREV_FOUND:
1903                         ent = M_ARGV(1, entity);
1904                         break;
1905                 case MUT_SPECPREV_RETURN:
1906                         return true;
1907                 case MUT_SPECPREV_CONTINUE:
1908                 default:
1909                 {
1910                         if(ent.chain)
1911                                 ent = ent.chain;
1912                         else
1913                                 ent = first;
1914                         break;
1915                 }
1916         }
1917
1918         SetSpectatee(this, ent);
1919         return SpectateSet(this);
1920 }
1921
1922 /*
1923 =============
1924 ShowRespawnCountdown()
1925
1926 Update a respawn countdown display.
1927 =============
1928 */
1929 void ShowRespawnCountdown(entity this)
1930 {
1931         float number;
1932         if(!IS_DEAD(this)) // just respawned?
1933                 return;
1934         else
1935         {
1936                 number = ceil(this.respawn_time - time);
1937                 if(number <= 0)
1938                         return;
1939                 if(number <= this.respawn_countdown)
1940                 {
1941                         this.respawn_countdown = number - 1;
1942                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1943                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1944                 }
1945         }
1946 }
1947
1948 .bool team_selected;
1949 bool ShowTeamSelection(entity this)
1950 {
1951         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1952                 return false;
1953         if (frametime) // once per frame is more than enough
1954                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1955         return true;
1956 }
1957 void Join(entity this)
1958 {
1959         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1960                 ReadyRestart(true);
1961
1962         TRANSMUTE(Player, this);
1963
1964         if(!this.team_selected)
1965         if(autocvar_g_campaign || autocvar_g_balance_teams)
1966                 TeamBalance_JoinBestTeam(this);
1967
1968         if(autocvar_g_campaign)
1969                 campaign_bots_may_start = true;
1970
1971         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1972
1973         PutClientInServer(this);
1974
1975         if(IS_PLAYER(this))
1976         if(teamplay && this.team != -1)
1977         {
1978         }
1979         else
1980                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1981         this.team_selected = false;
1982 }
1983
1984 int GetPlayerLimit()
1985 {
1986         if(g_duel)
1987                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1988         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
1989         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
1990         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1991         player_limit = M_ARGV(0, int);
1992         return player_limit < maxclients ? player_limit : 0;
1993 }
1994
1995 /**
1996  * Determines whether the player is allowed to join. This depends on cvar
1997  * g_maxplayers, if it isn't used this function always return true, otherwise
1998  * it checks whether the number of currently playing players exceeds g_maxplayers.
1999  * @return int number of free slots for players, 0 if none
2000  */
2001 int nJoinAllowed(entity this, entity ignore)
2002 {
2003         if(!ignore)
2004         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2005         // so report 0 free slots if restricted
2006         {
2007                 if(autocvar_g_forced_team_otherwise == "spectate")
2008                         return 0;
2009                 if(autocvar_g_forced_team_otherwise == "spectator")
2010                         return 0;
2011         }
2012
2013         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2014                 return 0; // forced spectators can never join
2015
2016         // TODO simplify this
2017         int totalClients = 0;
2018         int currentlyPlaying = 0;
2019         FOREACH_CLIENT(true, {
2020                 if(it != ignore)
2021                         ++totalClients;
2022                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2023                         ++currentlyPlaying;
2024         });
2025
2026         int player_limit = GetPlayerLimit();
2027
2028         int free_slots = 0;
2029         if (!player_limit)
2030                 free_slots = maxclients - totalClients;
2031         else if(player_limit > 0 && currentlyPlaying < player_limit)
2032                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2033
2034         static float msg_time = 0;
2035         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2036         {
2037                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT, player_limit);
2038                 msg_time = time + 0.5;
2039         }
2040
2041         return free_slots;
2042 }
2043
2044 bool joinAllowed(entity this)
2045 {
2046         if (CS(this).version_mismatch) return false;
2047         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2048         if (!nJoinAllowed(this, this)) return false;
2049         if (teamplay && lockteams) return false;
2050         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2051         if (ShowTeamSelection(this)) return false;
2052         return true;
2053 }
2054
2055 .string shootfromfixedorigin;
2056 .bool dualwielding_prev;
2057 bool PlayerThink(entity this)
2058 {
2059         if (game_stopped || intermission_running) {
2060                 this.modelflags &= ~MF_ROCKET;
2061                 if(intermission_running)
2062                         IntermissionThink(this);
2063                 return false;
2064         }
2065
2066         if (timeout_status == TIMEOUT_ACTIVE) {
2067                 // don't allow the player to turn around while game is paused
2068                 // FIXME turn this into CSQC stuff
2069                 this.v_angle = this.lastV_angle;
2070                 this.angles = this.lastV_angle;
2071                 this.fixangle = true;
2072         }
2073
2074         if (frametime) player_powerups(this);
2075
2076         if (IS_DEAD(this)) {
2077                 if (this.personal && g_race_qualifying) {
2078                         if (time > this.respawn_time) {
2079                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2080                                 respawn(this);
2081                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2082                         }
2083                 } else {
2084                         if (frametime) player_anim(this);
2085
2086                         if (this.respawn_flags & RESPAWN_DENY)
2087                         {
2088                                 STAT(RESPAWN_TIME, this) = 0;
2089                                 return false;
2090                         }
2091
2092                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2093
2094                         switch(this.deadflag)
2095                         {
2096                                 case DEAD_DYING:
2097                                 {
2098                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2099                                                 this.deadflag = DEAD_RESPAWNING;
2100                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2101                                                 this.deadflag = DEAD_DEAD;
2102                                         break;
2103                                 }
2104                                 case DEAD_DEAD:
2105                                 {
2106                                         if (button_pressed)
2107                                                 this.deadflag = DEAD_RESPAWNABLE;
2108                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2109                                                 this.deadflag = DEAD_RESPAWNING;
2110                                         break;
2111                                 }
2112                                 case DEAD_RESPAWNABLE:
2113                                 {
2114                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2115                                                 this.deadflag = DEAD_RESPAWNING;
2116                                         break;
2117                                 }
2118                                 case DEAD_RESPAWNING:
2119                                 {
2120                                         if (time > this.respawn_time)
2121                                         {
2122                                                 this.respawn_time = time + 1; // only retry once a second
2123                                                 this.respawn_time_max = this.respawn_time;
2124                                                 respawn(this);
2125                                         }
2126                                         break;
2127                                 }
2128                         }
2129
2130                         ShowRespawnCountdown(this);
2131
2132                         if (this.respawn_flags & RESPAWN_SILENT)
2133                                 STAT(RESPAWN_TIME, this) = 0;
2134                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2135                         {
2136                                 if (time < this.respawn_time)
2137                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2138                                 else if (this.deadflag != DEAD_RESPAWNING)
2139                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2140                         }
2141                         else
2142                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2143                 }
2144
2145                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2146                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2147                         STAT(RESPAWN_TIME, this) *= -1;
2148
2149                 return false;
2150         }
2151
2152         FixPlayermodel(this);
2153
2154         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2155                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2156                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2157         }
2158
2159         // reset gun alignment when dual wielding status changes
2160         // to ensure guns are always aligned right and left
2161         bool dualwielding = W_DualWielding(this);
2162         if(this.dualwielding_prev != dualwielding)
2163         {
2164                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2165                 this.dualwielding_prev = dualwielding;
2166         }
2167
2168         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2169         //if(frametime)
2170         {
2171                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2172                 {
2173                         .entity weaponentity = weaponentities[slot];
2174                         if(WEP_CVAR(vortex, charge_always))
2175                                 W_Vortex_Charge(this, weaponentity, frametime);
2176                         W_WeaponFrame(this, weaponentity);
2177                 }
2178         }
2179
2180         if (frametime)
2181         {
2182                 // WEAPONTODO: Add a weapon request for this
2183                 // rot vortex charge to the charge limit
2184                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2185                 {
2186                         .entity weaponentity = weaponentities[slot];
2187                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2188                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2189                 }
2190
2191                 player_regen(this);
2192                 player_anim(this);
2193                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2194         }
2195
2196         monsters_setstatus(this);
2197
2198         return true;
2199 }
2200
2201 .bool would_spectate;
2202 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2203 void ObserverOrSpectatorThink(entity this)
2204 {
2205         bool is_spec = IS_SPEC(this);
2206         if ( CS(this).impulse )
2207         {
2208                 int r = MinigameImpulse(this, CS(this).impulse);
2209                 if (!is_spec || r)
2210                         CS(this).impulse = 0;
2211
2212                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2213                 {
2214                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2215                         CS(this).impulse = 0;
2216                         return;
2217                 }
2218         }
2219
2220         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2221         {
2222                 CS(this).autojoin_checked = true;
2223                 TRANSMUTE(Player, this);
2224                 PutClientInServer(this);
2225                 return;
2226         }
2227
2228         if (this.flags & FL_JUMPRELEASED) {
2229                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2230                         this.flags &= ~FL_JUMPRELEASED;
2231                         this.flags |= FL_SPAWNING;
2232                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2233                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2234                         this.flags &= ~FL_JUMPRELEASED;
2235                         if(SpectateNext(this)) {
2236                                 TRANSMUTE(Spectator, this);
2237                         } else if (is_spec) {
2238                                 TRANSMUTE(Observer, this);
2239                                 PutClientInServer(this);
2240                         }
2241                         else
2242                                 this.would_spectate = false; // unable to spectate anyone
2243                         if (is_spec)
2244                                 CS(this).impulse = 0;
2245                 } else if (is_spec) {
2246                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2247                                 this.flags &= ~FL_JUMPRELEASED;
2248                                 if(SpectatePrev(this)) {
2249                                         TRANSMUTE(Spectator, this);
2250                                 } else {
2251                                         TRANSMUTE(Observer, this);
2252                                         PutClientInServer(this);
2253                                 }
2254                                 CS(this).impulse = 0;
2255                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2256                                 this.would_spectate = false;
2257                                 this.flags &= ~FL_JUMPRELEASED;
2258                                 TRANSMUTE(Observer, this);
2259                                 PutClientInServer(this);
2260                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2261                                 PutObserverInServer(this, false, true);
2262                                 this.would_spectate = true;
2263                         }
2264                 }
2265                 else {
2266                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2267                         if (PHYS_INPUT_BUTTON_USE(this))
2268                                 wouldclip = !wouldclip;
2269                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2270                         set_movetype(this, preferred_movetype);
2271                 }
2272         } else { // jump pressed
2273                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2274                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2275                         this.flags |= FL_JUMPRELEASED;
2276                         if(this.flags & FL_SPAWNING)
2277                         {
2278                                 this.flags &= ~FL_SPAWNING;
2279                                 if(joinAllowed(this))
2280                                         Join(this);
2281                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2282                                         CS(this).autojoin_checked = -1;
2283                                 return;
2284                         }
2285                 }
2286                 if(is_spec && !SpectateUpdate(this))
2287                         PutObserverInServer(this, false, true);
2288         }
2289         if (is_spec)
2290                 this.flags |= FL_CLIENT | FL_NOTARGET;
2291 }
2292
2293 void PlayerUseKey(entity this)
2294 {
2295         if (!IS_PLAYER(this))
2296                 return;
2297
2298         if(this.vehicle)
2299         {
2300                 if(!game_stopped)
2301                 {
2302                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2303                         return;
2304                 }
2305         }
2306         else if(autocvar_g_vehicles_enter)
2307         {
2308                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2309                 {
2310                         entity head, closest_target = NULL;
2311                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2312
2313                         while(head) // find the closest acceptable target to enter
2314                         {
2315                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2316                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2317                                 {
2318                                         if(closest_target)
2319                                         {
2320                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2321                                                 { closest_target = head; }
2322                                         }
2323                                         else { closest_target = head; }
2324                                 }
2325
2326                                 head = head.chain;
2327                         }
2328
2329                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2330                 }
2331         }
2332
2333         // a use key was pressed; call handlers
2334         MUTATOR_CALLHOOK(PlayerUseKey, this);
2335 }
2336
2337
2338 /*
2339 =============
2340 PlayerPreThink
2341
2342 Called every frame for each client before the physics are run
2343 =============
2344 */
2345 .float last_vehiclecheck;
2346 void PlayerPreThink (entity this)
2347 {
2348         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2349         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2350
2351         WarpZone_PlayerPhysics_FixVAngle(this);
2352
2353         if (frametime) {
2354                 // physics frames: update anticheat stuff
2355                 anticheat_prethink(this);
2356
2357                 // WORKAROUND: only use dropclient in server frames (frametime set).
2358                 // Never use it in cl_movement frames (frametime zero).
2359                 if (blockSpectators && IS_REAL_CLIENT(this)
2360                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2361                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2362                 {
2363                         if (dropclient_schedule(this))
2364                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2365                 }
2366         }
2367
2368         zoomstate_set = false;
2369
2370         // Check for nameless players
2371         if (this.netname == "" || this.netname != CS(this).netname_previous)
2372         {
2373                 bool assume_unchanged = (CS(this).netname_previous == "");
2374                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2375                 {
2376                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2377                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2378                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2379                         assume_unchanged = false;
2380                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2381                 }
2382                 if (isInvisibleString(this.netname))
2383                 {
2384                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2385                         sprint(this, "Warning: invisible names are not allowed.\n");
2386                         assume_unchanged = false;
2387                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2388                 }
2389                 if (!assume_unchanged && autocvar_sv_eventlog)
2390                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2391                 strcpy(CS(this).netname_previous, this.netname);
2392         }
2393
2394         // version nagging
2395         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2396         CS(this).version_nagtime = 0;
2397         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2398             // git client
2399         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2400             // git server
2401             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2402         } else {
2403             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2404             if (r < 0) { // old client
2405                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2406             } else if (r > 0) { // old server
2407                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2408             }
2409         }
2410     }
2411
2412         // GOD MODE info
2413         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2414         {
2415                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2416                 this.max_armorvalue = 0;
2417         }
2418
2419         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2420         {
2421                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2422                 {
2423                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2424                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2425                         if (this.iceblock)
2426                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2427
2428                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2429                                 Unfreeze(this, false);
2430                 }
2431                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2432                 {
2433                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2434                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2435
2436                         if (GetResource(this, RES_HEALTH) < 1)
2437                         {
2438                                 if (this.vehicle)
2439                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2440                                 if(this.event_damage)
2441                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2442                         }
2443                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2444                                 Unfreeze(this, false);
2445                 }
2446         }
2447
2448         MUTATOR_CALLHOOK(PlayerPreThink, this);
2449
2450         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2451         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2452         {
2453                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2454                 {
2455                         if(!it.owner)
2456                         {
2457                                 if(!it.team || SAME_TEAM(this, it))
2458                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2459                                 else if(autocvar_g_vehicles_steal)
2460                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2461                         }
2462                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2463                         {
2464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2465                         }
2466                 });
2467
2468                 this.last_vehiclecheck = time + 1;
2469         }
2470
2471         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2472                 PlayerUseKey(this);
2473         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2474
2475         if (IS_PLAYER(this)) {
2476                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2477                         error("Client can't be spawned as player on connection!");
2478                 if(!PlayerThink(this))
2479                         return;
2480         }
2481         else if (game_stopped || intermission_running) {
2482                 if(intermission_running)
2483                         IntermissionThink(this);
2484                 return;
2485         }
2486         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2487         {
2488                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2489                 CS(this).autojoin_checked = 1;
2490                 // don't do this in ClientConnect
2491                 // many things can go wrong if a client is spawned as player on connection
2492                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2493                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2494                                 && (!teamplay || autocvar_g_balance_teams)))
2495                 {
2496                         if(joinAllowed(this))
2497                                 Join(this);
2498                         return;
2499                 }
2500         }
2501         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2502                 ObserverOrSpectatorThink(this);
2503         }
2504
2505         // WEAPONTODO: Add weapon request for this
2506         if (!zoomstate_set) {
2507                 bool wep_zoomed = false;
2508                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2509                 {
2510                         .entity weaponentity = weaponentities[slot];
2511                         Weapon thiswep = this.(weaponentity).m_weapon;
2512                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2513                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2514                 }
2515                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2516         }
2517
2518         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2519         {
2520                 CS(this).teamkill_soundtime = 0;
2521
2522                 entity e = CS(this).teamkill_soundsource;
2523                 entity oldpusher = e.pusher;
2524                 e.pusher = this;
2525                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2526                 e.pusher = oldpusher;
2527         }
2528
2529         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2530                 CS(this).taunt_soundtime = 0;
2531                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2532         }
2533
2534         target_voicescript_next(this);
2535 }
2536
2537 void DrownPlayer(entity this)
2538 {
2539         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2540                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2541         {
2542                 STAT(AIR_FINISHED, this) = 0;
2543                 return;
2544         }
2545
2546         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2547         {
2548                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2549                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2550                 STAT(AIR_FINISHED, this) = 0;
2551         }
2552         else
2553         {
2554                 if (!STAT(AIR_FINISHED, this))
2555                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2556                 if (STAT(AIR_FINISHED, this) < time)
2557                 {       // drown!
2558                         if (this.pain_finished < time)
2559                         {
2560                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2561                                 this.pain_finished = time + 0.5;
2562                         }
2563                 }
2564         }
2565 }
2566
2567 .bool move_qcphysics;
2568
2569 void Player_Physics(entity this)
2570 {
2571         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2572
2573         if(!this.move_qcphysics)
2574                 return;
2575
2576         if(!frametime && !CS(this).pm_frametime)
2577                 return;
2578
2579         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2580
2581         CS(this).pm_frametime = 0;
2582 }
2583
2584 /*
2585 =============
2586 PlayerPostThink
2587
2588 Called every frame for each client after the physics are run
2589 =============
2590 */
2591 void PlayerPostThink (entity this)
2592 {
2593         Player_Physics(this);
2594
2595         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2596         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2597         if (IS_REAL_CLIENT(this))
2598         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2599         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2600         {
2601                 int totalClients = 0;
2602                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2603                 {
2604                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2605                         if (server_is_dedicated)
2606                         {
2607                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2608                                 {
2609                                         ++totalClients;
2610                                 });
2611                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2612                                         totalClients = 0;
2613                         }
2614                 }
2615                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2616                 {
2617                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2618                         {
2619                                 ++totalClients;
2620                         });
2621                 }
2622
2623                 if (totalClients < autocvar_sv_maxidle_minplayers)
2624                 {
2625                         // idle kick disabled
2626                         CS(this).parm_idlesince = time;
2627                 }
2628                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2629                 {
2630                         if (CS(this).idlekick_lasttimeleft)
2631                         {
2632                                 CS(this).idlekick_lasttimeleft = 0;
2633                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2634                         }
2635                 }
2636                 else
2637                 {
2638                         float maxidle_time = autocvar_sv_maxidle;
2639                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2640                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2641                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2642                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2643                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2644                         {
2645                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2646                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2647                                 else
2648                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2649                         }
2650                         if (timeleft <= 0) {
2651                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2652                                 {
2653                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2654                                         PutObserverInServer(this, true, true);
2655                                 }
2656                                 else
2657                                 {
2658                                         if (dropclient_schedule(this))
2659                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2660                                 }
2661                                 return;
2662                         }
2663                         else if (timeleft <= countdown_time) {
2664                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2665                                         play2(this, SND(TALK2));
2666                                 CS(this).idlekick_lasttimeleft = timeleft;
2667                         }
2668                 }
2669         }
2670
2671         CheatFrame(this);
2672
2673         if (game_stopped)
2674         {
2675                 this.solid = SOLID_NOT;
2676                 this.takedamage = DAMAGE_NO;
2677                 set_movetype(this, MOVETYPE_NONE);
2678                 CS(this).teamkill_complain = 0;
2679                 CS(this).teamkill_soundtime = 0;
2680                 CS(this).teamkill_soundsource = NULL;
2681         }
2682
2683         if (IS_PLAYER(this)) {
2684                 if(this.death_time == time && IS_DEAD(this))
2685                 {
2686                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2687                         // once all the damage events of this frame have been processed with normal size
2688                         this.maxs.z = 5;
2689                         setsize(this, this.mins, this.maxs);
2690                 }
2691                 DrownPlayer(this);
2692                 UpdateChatBubble(this);
2693                 if (CS(this).impulse) ImpulseCommands(this);
2694                 GetPressedKeys(this);
2695                 if (game_stopped)
2696                 {
2697                         CSQCMODEL_AUTOUPDATE(this);
2698                         return;
2699                 }
2700         }
2701         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2702         {
2703                 CS(this).pressedkeys = 0;
2704                 STAT(PRESSED_KEYS, this) = 0;
2705         }
2706
2707         if (this.waypointsprite_attachedforcarrier) {
2708                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2709                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2710         }
2711
2712         CSQCMODEL_AUTOUPDATE(this);
2713 }
2714
2715 // hack to copy the button fields from the client entity to the Client State
2716 void PM_UpdateButtons(entity this, entity store)
2717 {
2718         if(this.impulse)
2719                 store.impulse = this.impulse;
2720         this.impulse = 0;
2721
2722         bool typing = this.buttonchat || this.button12;
2723
2724         store.button0 = (typing) ? 0 : this.button0;
2725         //button1?!
2726         store.button2 = (typing) ? 0 : this.button2;
2727         store.button3 = (typing) ? 0 : this.button3;
2728         store.button4 = this.button4;
2729         store.button5 = (typing) ? 0 : this.button5;
2730         store.button6 = this.button6;
2731         store.button7 = this.button7;
2732         store.button8 = this.button8;
2733         store.button9 = this.button9;
2734         store.button10 = this.button10;
2735         store.button11 = this.button11;
2736         store.button12 = this.button12;
2737         store.button13 = this.button13;
2738         store.button14 = this.button14;
2739         store.button15 = this.button15;
2740         store.button16 = this.button16;
2741         store.buttonuse = this.buttonuse;
2742         store.buttonchat = this.buttonchat;
2743
2744         store.cursor_active = this.cursor_active;
2745         store.cursor_screen = this.cursor_screen;
2746         store.cursor_trace_start = this.cursor_trace_start;
2747         store.cursor_trace_endpos = this.cursor_trace_endpos;
2748         store.cursor_trace_ent = this.cursor_trace_ent;
2749
2750         store.ping = this.ping;
2751         store.ping_packetloss = this.ping_packetloss;
2752         store.ping_movementloss = this.ping_movementloss;
2753
2754         store.v_angle = this.v_angle;
2755         store.movement = this.movement;
2756 }
2757
2758 NET_HANDLE(fpsreport, bool)
2759 {
2760         int fps = ReadShort();
2761         PlayerScore_Set(sender, SP_FPS, fps);
2762         return true;
2763 }