qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38
  39 #include "../common/vehicles/all.qh"
  40
  41 #include "weapons/hitplot.qh"
  42 #include "weapons/weaponsystem.qh"
  43
  44 #include "../common/net_notice.qh"
  45 #include "../common/net_linked.qh"
  46 #include "../common/physics/player.qh"
  47
  48 #include "../common/items/_mod.qh"
  49
  50 #include "../common/mutators/mutator/waypoints/all.qh"
  51
  52 #include "../common/triggers/subs.qh"
  53 #include "../common/triggers/triggers.qh"
  54 #include "../common/triggers/trigger/secret.qh"
  55
  56 #include "../common/minigames/sv_minigames.qh"
  57
  58 #include "../common/items/inventory.qh"
  59
  60 #include "../common/monsters/sv_monsters.qh"
  61
  62 #include "../lib/warpzone/server.qh"
  63
  64 STATIC_METHOD(Client, Add, void(Client this, int _team))
  65 {
  66     ClientConnect(this);
  67     TRANSMUTE(Player, this);
  68     this.frame = 12; // 7
  69     this.team = _team;
  70     PutClientInServer(this);
  71 }
  72
  73 void PutObserverInServer(entity this);
  74
  75 STATIC_METHOD(Client, Remove, void(Client this))
  76 {
  77     TRANSMUTE(Observer, this);
  78     PutClientInServer(this);
  79     ClientDisconnect(this);
  80 }
  81
  82 void send_CSQC_teamnagger() {
  83         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  84 }
  85
  86 int CountSpectators(entity player, entity to)
  87 {
  88         if(!player) { return 0; } // not sure how, but best to be safe
  89
  90         int spec_count = 0;
  91
  92         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  93         {
  94                 spec_count++;
  95         });
  96
  97         return spec_count;
  98 }
  99
 100 void WriteSpectators(entity player, entity to)
 101 {
 102         if(!player) { return; } // not sure how, but best to be safe
 103
 104         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 105         {
 106                 WriteByte(MSG_ENTITY, num_for_edict(it));
 107         });
 108 }
 109
 110 bool ClientData_Send(entity this, entity to, int sf)
 111 {
 112         assert(to == this.owner, return false);
 113
 114         entity e = to;
 115         if (IS_SPEC(e)) e = e.enemy;
 116
 117         sf = 0;
 118         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 119         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 120         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 121         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 122
 123         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 124         WriteByte(MSG_ENTITY, sf);
 125
 126         if (sf & BIT(1))
 127                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 128
 129         if(sf & BIT(4))
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         CS(this).clientdata.drawonlytoclient = this;
 143         CS(this).clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(CS(this).clientdata);
 149         CS(this).clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         CS(e).clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 158 }
 159
 160 void SetSpectatee(entity this, entity spectatee);
 161 void SetSpectatee_status(entity this, int spectatee_num);
 162
 163
 164 /*
 165 =============
 166 CheckPlayerModel
 167
 168 Checks if the argument string can be a valid playermodel.
 169 Returns a valid one in doubt.
 170 =============
 171 */
 172 string FallbackPlayerModel;
 173 string CheckPlayerModel(string plyermodel) {
 174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 175         {
 176                 // note: we cannot summon Don Strunzone here, some player may
 177                 // still have the model string set. In case anyone manages how
 178                 // to change a cvar default, we'll have a small leak here.
 179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 180         }
 181         // only in right path
 182         if( substring(plyermodel,0,14) != "models/player/")
 183                 return FallbackPlayerModel;
 184         // only good file extensions
 185         if(substring(plyermodel,-4,4) != ".zym")
 186         if(substring(plyermodel,-4,4) != ".dpm")
 187         if(substring(plyermodel,-4,4) != ".iqm")
 188         if(substring(plyermodel,-4,4) != ".md3")
 189         if(substring(plyermodel,-4,4) != ".psk")
 190                 return FallbackPlayerModel;
 191         // forbid the LOD models
 192         if(substring(plyermodel, -9,5) == "_lod1")
 193                 return FallbackPlayerModel;
 194         if(substring(plyermodel, -9,5) == "_lod2")
 195                 return FallbackPlayerModel;
 196         if(plyermodel != strtolower(plyermodel))
 197                 return FallbackPlayerModel;
 198         // also, restrict to server models
 199         if(autocvar_sv_servermodelsonly)
 200         {
 201                 if(!fexists(plyermodel))
 202                         return FallbackPlayerModel;
 203         }
 204         return plyermodel;
 205 }
 206
 207 void setplayermodel(entity e, string modelname)
 208 {
 209         precache_model(modelname);
 210         _setmodel(e, modelname);
 211         player_setupanimsformodel(e);
 212         if(!autocvar_g_debug_globalsounds)
 213                 UpdatePlayerSounds(e);
 214 }
 215
 216 void FixPlayermodel(entity player);
 217 /** putting a client as observer in the server */
 218 void PutObserverInServer(entity this)
 219 {
 220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 221         PlayerState_detach(this);
 222
 223         if (IS_PLAYER(this))
 224         {
 225                 if(this.health >= 1)
 226                 {
 227                         // despawn effect
 228                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229                 }
 230
 231                 // was a player, recount votes and ready status
 232                 if(IS_REAL_CLIENT(this))
 233                 {
 234                         if (vote_called) { VoteCount(false); }
 235                         ReadyCount();
 236                 }
 237     }
 238
 239     {
 240         entity spot = SelectSpawnPoint(this, true);
 241         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 242         this.angles = vec2(spot.angles);
 243         this.fixangle = true;
 244         // offset it so that the spectator spawns higher off the ground, looks better this way
 245         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 246         if (IS_REAL_CLIENT(this))
 247         {
 248             msg_entity = this;
 249             WriteByte(MSG_ONE, SVC_SETVIEW);
 250             WriteEntity(MSG_ONE, this);
 251         }
 252         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254         if(!autocvar_g_debug_globalsounds)
 255         {
 256                 // needed for player sounds
 257                 this.model = "";
 258                 FixPlayermodel(this);
 259         }
 260         setmodel(this, MDL_Null);
 261         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 262         this.view_ofs = '0 0 0';
 263     }
 264
 265     RemoveGrapplingHooks(this);
 266         Portal_ClearAll(this);
 267         Unfreeze(this);
 268         SetSpectatee(this, NULL);
 269
 270         if (this.alivetime)
 271         {
 272                 if (!warmup_stage)
 273                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 274                 this.alivetime = 0;
 275         }
 276
 277         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 278
 279         WaypointSprite_PlayerDead(this);
 280
 281         if (mutator_returnvalue) {
 282             // mutator prevents resetting teams+score
 283         } else {
 284                 int oldteam = this.team;
 285                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 286                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 287         this.frags = FRAGS_SPECTATOR;
 288         PlayerScore_Clear(this);  // clear scores when needed
 289     }
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 294                 if(!game_stopped)
 295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298                 if(!CS(this).just_joined)
 299                         LogTeamchange(this.playerid, -1, 4);
 300                 else
 301                         CS(this).just_joined = false;
 302         }
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310     this.hud = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         this.health = FRAGS_SPECTATOR;
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.armorvalue = 666;
 324         this.effects = 0;
 325         this.armorvalue = autocvar_g_balance_armor_start;
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         this.stat_respawn_time = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         this.strength_finished = 0;
 340         this.invincible_finished = 0;
 341         this.superweapons_finished = 0;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         this.revive_progress = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         this.weapons = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.weaponmodel = "";
 356         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 357         {
 358                 this.weaponentities[slot] = NULL;
 359         }
 360         this.exteriorweaponentity = NULL;
 361         CS(this).killcount = FRAGS_SPECTATOR;
 362         this.velocity = '0 0 0';
 363         this.avelocity = '0 0 0';
 364         this.punchangle = '0 0 0';
 365         this.punchvector = '0 0 0';
 366         this.oldvelocity = this.velocity;
 367         this.fire_endtime = -1;
 368         this.event_damage = func_null;
 369
 370         for(int slot = 0; slot < MAX_AXH; ++slot)
 371         {
 372                 entity axh = this.(AuxiliaryXhair[slot]);
 373                 this.(AuxiliaryXhair[slot]) = NULL;
 374
 375                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 376                         delete(axh);
 377         }
 378 }
 379
 380 int player_getspecies(entity this)
 381 {
 382         get_model_parameters(this.model, this.skin);
 383         int s = get_model_parameters_species;
 384         get_model_parameters(string_null, 0);
 385         if (s < 0) return SPECIES_HUMAN;
 386         return s;
 387 }
 388
 389 .float model_randomizer;
 390 void FixPlayermodel(entity player)
 391 {
 392         string defaultmodel = "";
 393         int defaultskin = 0;
 394         if(autocvar_sv_defaultcharacter)
 395         {
 396                 if(teamplay)
 397                 {
 398                         switch(player.team)
 399                         {
 400                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 401                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 402                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 403                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 404                         }
 405                 }
 406
 407                 if(defaultmodel == "")
 408                 {
 409                         defaultmodel = autocvar_sv_defaultplayermodel;
 410                         defaultskin = autocvar_sv_defaultplayerskin;
 411                 }
 412
 413                 int n = tokenize_console(defaultmodel);
 414                 if(n > 0)
 415                 {
 416                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 417                         // However, do NOT randomize if the player-selected model is in the list.
 418                         for (int i = 0; i < n; ++i)
 419                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 420                                         defaultmodel = argv(i);
 421                 }
 422
 423                 int i = strstrofs(defaultmodel, ":", 0);
 424                 if(i >= 0)
 425                 {
 426                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 427                         defaultmodel = substring(defaultmodel, 0, i);
 428                 }
 429         }
 430         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 431         {
 432                 if(teamplay)
 433                 {
 434                         switch(player.team)
 435                         {
 436                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 437                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 438                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 439                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 440                         }
 441                 }
 442
 443                 if(!defaultskin)
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445         }
 446
 447         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 448         defaultmodel = M_ARGV(0, string);
 449         defaultskin = M_ARGV(1, int);
 450
 451         bool chmdl = false;
 452         int oldskin;
 453         if(defaultmodel != "")
 454         {
 455                 if (defaultmodel != player.model)
 456                 {
 457                         vector m1 = player.mins;
 458                         vector m2 = player.maxs;
 459                         setplayermodel (player, defaultmodel);
 460                         setsize (player, m1, m2);
 461                         chmdl = true;
 462                 }
 463
 464                 oldskin = player.skin;
 465                 player.skin = defaultskin;
 466         } else {
 467                 if (player.playermodel != player.model || player.playermodel == "")
 468                 {
 469                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 470                         vector m1 = player.mins;
 471                         vector m2 = player.maxs;
 472                         setplayermodel (player, player.playermodel);
 473                         setsize (player, m1, m2);
 474                         chmdl = true;
 475                 }
 476
 477                 if(!autocvar_sv_defaultcharacterskin)
 478                 {
 479                         oldskin = player.skin;
 480                         player.skin = stof(player.playerskin);
 481                 }
 482                 else
 483                 {
 484                         oldskin = player.skin;
 485                         player.skin = defaultskin;
 486                 }
 487         }
 488
 489         if(chmdl || oldskin != player.skin) // model or skin has changed
 490         {
 491                 player.species = player_getspecies(player); // update species
 492                 if(!autocvar_g_debug_globalsounds)
 493                         UpdatePlayerSounds(player); // update skin sounds
 494         }
 495
 496         if(!teamplay)
 497                 if(strlen(autocvar_sv_defaultplayercolors))
 498                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 499                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 500 }
 501
 502 void PutPlayerInServer(entity this)
 503 {
 504         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 505
 506         PlayerState_attach(this);
 507         accuracy_resend(this);
 508
 509         if (this.team < 0)
 510                 JoinBestTeam(this, true);
 511
 512         entity spot = SelectSpawnPoint(this, false);
 513         if (!spot) {
 514                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 515                 return; // spawn failed
 516         }
 517
 518         TRANSMUTE(Player, this);
 519
 520         CS(this).wasplayer = true;
 521         this.iscreature = true;
 522         this.teleportable = TELEPORT_NORMAL;
 523         if(!this.damagedbycontents)
 524                 IL_PUSH(g_damagedbycontents, this);
 525         this.damagedbycontents = true;
 526         set_movetype(this, MOVETYPE_WALK);
 527         this.solid = SOLID_SLIDEBOX;
 528         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 529         if (autocvar_g_playerclip_collisions)
 530                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 531         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 532                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 533         this.frags = FRAGS_PLAYER;
 534         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 535         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 536         if (autocvar__notarget)
 537                 this.flags |= FL_NOTARGET;
 538         this.takedamage = DAMAGE_AIM;
 539         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 540
 541         if (warmup_stage) {
 542                 this.ammo_shells = warmup_start_ammo_shells;
 543                 this.ammo_nails = warmup_start_ammo_nails;
 544                 this.ammo_rockets = warmup_start_ammo_rockets;
 545                 this.ammo_cells = warmup_start_ammo_cells;
 546                 this.ammo_plasma = warmup_start_ammo_plasma;
 547                 this.ammo_fuel = warmup_start_ammo_fuel;
 548                 this.health = warmup_start_health;
 549                 this.armorvalue = warmup_start_armorvalue;
 550                 this.weapons = WARMUP_START_WEAPONS;
 551         } else {
 552                 this.ammo_shells = start_ammo_shells;
 553                 this.ammo_nails = start_ammo_nails;
 554                 this.ammo_rockets = start_ammo_rockets;
 555                 this.ammo_cells = start_ammo_cells;
 556                 this.ammo_plasma = start_ammo_plasma;
 557                 this.ammo_fuel = start_ammo_fuel;
 558                 this.health = start_health;
 559                 this.armorvalue = start_armorvalue;
 560                 this.weapons = start_weapons;
 561                 GiveRandomWeapons(this, random_start_weapons_count,
 562                         autocvar_g_random_start_weapons, random_start_ammo);
 563         }
 564         SetSpectatee_status(this, 0);
 565
 566         PS(this).dual_weapons = '0 0 0';
 567
 568         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 569
 570         this.items = start_items;
 571
 572         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 573         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 574         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 575         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 576         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 577         // extend the pause of rotting if client was reset at the beginning of the countdown
 578         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 579                 float f = game_starttime - time;
 580                 this.spawnshieldtime += f;
 581                 this.pauserotarmor_finished += f;
 582                 this.pauserothealth_finished += f;
 583                 this.pauseregen_finished += f;
 584         }
 585         this.damageforcescale = 2;
 586         this.death_time = 0;
 587         this.respawn_flags = 0;
 588         this.respawn_time = 0;
 589         this.stat_respawn_time = 0;
 590         this.scale = autocvar_sv_player_scale;
 591         this.fade_time = 0;
 592         this.pain_frame = 0;
 593         this.pain_finished = 0;
 594         this.pushltime = 0;
 595         setthink(this, func_null); // players have no think function
 596         this.nextthink = 0;
 597         this.dmg_team = 0;
 598         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 599
 600         this.deadflag = DEAD_NO;
 601
 602         this.angles = spot.angles;
 603         this.angles_z = 0; // never spawn tilted even if the spot says to
 604         if (IS_BOT_CLIENT(this))
 605                 this.v_angle = this.angles;
 606         this.fixangle = true; // turn this way immediately
 607         this.oldvelocity = this.velocity = '0 0 0';
 608         this.avelocity = '0 0 0';
 609         this.punchangle = '0 0 0';
 610         this.punchvector = '0 0 0';
 611
 612         this.strength_finished = 0;
 613         this.invincible_finished = 0;
 614         this.fire_endtime = -1;
 615         this.revive_progress = 0;
 616         this.revival_time = 0;
 617         this.air_finished = time + 12;
 618
 619         entity spawnevent = new_pure(spawnevent);
 620         spawnevent.owner = this;
 621         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 622
 623         // Cut off any still running player sounds.
 624         stopsound(this, CH_PLAYER_SINGLE);
 625
 626         this.model = "";
 627         FixPlayermodel(this);
 628         this.drawonlytoclient = NULL;
 629
 630         this.viewloc = NULL;
 631
 632         this.crouch = false;
 633         this.view_ofs = STAT(PL_VIEW_OFS, this);
 634         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 635         this.spawnorigin = spot.origin;
 636         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 637         // don't reset back to last position, even if new position is stuck in solid
 638         this.oldorigin = this.origin;
 639         if(this.conveyor)
 640                 IL_REMOVE(g_conveyed, this);
 641         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 642         this.hud = HUD_NORMAL;
 643
 644         this.event_damage = PlayerDamage;
 645
 646         if(!this.bot_attack)
 647                 IL_PUSH(g_bot_targets, this);
 648         this.bot_attack = true;
 649         if(!this.monster_attack)
 650                 IL_PUSH(g_monster_targets, this);
 651         this.monster_attack = true;
 652         navigation_dynamicgoal_init(this, false);
 653
 654         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 655
 656         // player was spectator
 657         if (CS(this).killcount == FRAGS_SPECTATOR) {
 658                 PlayerScore_Clear(this);
 659                 CS(this).killcount = 0;
 660                 CS(this).startplaytime = time;
 661         }
 662
 663         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 664         {
 665                 .entity weaponentity = weaponentities[slot];
 666                 entity oldwep = this.(weaponentity);
 667                 CL_SpawnWeaponentity(this, weaponentity);
 668                 if(oldwep && oldwep.owner == this)
 669                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 670         }
 671         this.alpha = default_player_alpha;
 672         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 673         this.exteriorweaponentity.alpha = default_weapon_alpha;
 674
 675         this.speedrunning = false;
 676
 677         target_voicescript_clear(this);
 678
 679         // reset fields the weapons may use
 680         FOREACH(Weapons, true, {
 681                 it.wr_resetplayer(it, this);
 682                         // reload all reloadable weapons
 683                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 684                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 685                         {
 686                                 .entity weaponentity = weaponentities[slot];
 687                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 688                         }
 689                 }
 690         });
 691
 692         {
 693                 string s = spot.target;
 694                 spot.target = string_null;
 695                 SUB_UseTargets(spot, this, NULL);
 696                 spot.target = s;
 697         }
 698
 699         Unfreeze(this);
 700
 701         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 702
 703         if (autocvar_spawn_debug)
 704         {
 705                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 706                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 707         }
 708
 709         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 710         {
 711                 .entity weaponentity = weaponentities[slot];
 712                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 713                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 714                 else
 715                         this.(weaponentity).m_switchweapon = WEP_Null;
 716                 this.(weaponentity).m_weapon = WEP_Null;
 717                 this.(weaponentity).weaponname = "";
 718                 this.(weaponentity).m_switchingweapon = WEP_Null;
 719                 this.(weaponentity).cnt = -1;
 720         }
 721
 722         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 723
 724         if (!warmup_stage && !this.alivetime)
 725                 this.alivetime = time;
 726
 727         antilag_clear(this, CS(this));
 728 }
 729
 730 /** Called when a client spawns in the server */
 731 void PutClientInServer(entity this)
 732 {
 733         if (IS_BOT_CLIENT(this)) {
 734                 TRANSMUTE(Player, this);
 735         } else if (IS_REAL_CLIENT(this)) {
 736                 msg_entity = this;
 737                 WriteByte(MSG_ONE, SVC_SETVIEW);
 738                 WriteEntity(MSG_ONE, this);
 739         }
 740         if (game_stopped)
 741                 TRANSMUTE(Observer, this);
 742
 743         SetSpectatee(this, NULL);
 744
 745         // reset player keys
 746         if(PS(this))
 747                 PS(this).itemkeys = 0;
 748
 749         MUTATOR_CALLHOOK(PutClientInServer, this);
 750
 751         if (IS_OBSERVER(this)) {
 752                 PutObserverInServer(this);
 753         } else if (IS_PLAYER(this)) {
 754                 PutPlayerInServer(this);
 755         }
 756 }
 757
 758 void ClientInit_misc(entity this);
 759
 760 // TODO do we need all these fields, or should we stop autodetecting runtime
 761 // changes and just have a console command to update this?
 762 bool ClientInit_SendEntity(entity this, entity to, int sf)
 763 {
 764         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 765         return = true;
 766         msg_entity = to;
 767         // MSG_INIT replacement
 768         // TODO: make easier to use
 769         Registry_send_all();
 770         W_PROP_reload(MSG_ONE, to);
 771         ClientInit_misc(this);
 772         MUTATOR_CALLHOOK(Ent_Init);
 773 }
 774 void ClientInit_misc(entity this)
 775 {
 776         int channel = MSG_ONE;
 777         WriteHeader(channel, ENT_CLIENT_INIT);
 778         WriteByte(channel, g_nexball_meter_period * 32);
 779         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 780         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 781         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 782         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 783         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 784         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 785         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 786         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 787
 788         if(sv_foginterval && world.fog != "")
 789                 WriteString(channel, world.fog);
 790         else
 791                 WriteString(channel, "");
 792         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 793         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 794         WriteByte(channel, serverflags);
 795         WriteCoord(channel, autocvar_g_trueaim_minrange);
 796 }
 797
 798 void ClientInit_CheckUpdate(entity this)
 799 {
 800         this.nextthink = time;
 801         if(this.count != autocvar_g_balance_armor_blockpercent)
 802         {
 803                 this.count = autocvar_g_balance_armor_blockpercent;
 804                 this.SendFlags |= 1;
 805         }
 806         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 807         {
 808                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 809                 this.SendFlags |= 1;
 810         }
 811 }
 812
 813 void ClientInit_Spawn()
 814 {
 815         entity e = new_pure(clientinit);
 816         setthink(e, ClientInit_CheckUpdate);
 817         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 818
 819         ClientInit_CheckUpdate(e);
 820 }
 821
 822 /*
 823 =============
 824 SetNewParms
 825 =============
 826 */
 827 void SetNewParms ()
 828 {
 829         // initialize parms for a new player
 830         parm1 = -(86400 * 366);
 831
 832         MUTATOR_CALLHOOK(SetNewParms);
 833 }
 834
 835 /*
 836 =============
 837 SetChangeParms
 838 =============
 839 */
 840 void SetChangeParms (entity this)
 841 {
 842         // save parms for level change
 843         parm1 = CS(this).parm_idlesince - time;
 844
 845         MUTATOR_CALLHOOK(SetChangeParms);
 846 }
 847
 848 /*
 849 =============
 850 DecodeLevelParms
 851 =============
 852 */
 853 void DecodeLevelParms(entity this)
 854 {
 855         // load parms
 856         CS(this).parm_idlesince = parm1;
 857         if (CS(this).parm_idlesince == -(86400 * 366))
 858                 CS(this).parm_idlesince = time;
 859
 860         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 861         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 862
 863         MUTATOR_CALLHOOK(DecodeLevelParms);
 864 }
 865
 866 /*
 867 =============
 868 ClientKill
 869
 870 Called when a client types 'kill' in the console
 871 =============
 872 */
 873
 874 .float clientkill_nexttime;
 875 void ClientKill_Now_TeamChange(entity this)
 876 {
 877         if(this.killindicator_teamchange == -1)
 878         {
 879                 JoinBestTeam( this, true );
 880         }
 881         else if(this.killindicator_teamchange == -2)
 882         {
 883                 if(blockSpectators)
 884                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 885                 PutObserverInServer(this);
 886         }
 887         else
 888                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 889         this.killindicator_teamchange = 0;
 890 }
 891
 892 void ClientKill_Now(entity this)
 893 {
 894         if(this.vehicle)
 895         {
 896             vehicles_exit(this.vehicle, VHEF_RELEASE);
 897             if(!this.killindicator_teamchange)
 898             {
 899             this.vehicle_health = -1;
 900             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 901             }
 902         }
 903
 904         if(this.killindicator && !wasfreed(this.killindicator))
 905                 delete(this.killindicator);
 906
 907         this.killindicator = NULL;
 908
 909         if(this.killindicator_teamchange)
 910                 ClientKill_Now_TeamChange(this);
 911
 912         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 913         {
 914                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 915         }
 916
 917         // now I am sure the player IS dead
 918 }
 919 void KillIndicator_Think(entity this)
 920 {
 921         if (game_stopped)
 922         {
 923                 this.owner.killindicator = NULL;
 924                 delete(this);
 925                 return;
 926         }
 927
 928         if (this.owner.alpha < 0 && !this.owner.vehicle)
 929         {
 930                 this.owner.killindicator = NULL;
 931                 delete(this);
 932                 return;
 933         }
 934
 935         if(this.cnt <= 0)
 936         {
 937                 ClientKill_Now(this.owner);
 938                 return;
 939         }
 940     else if(this.health == 1) // health == 1 means that it's silent
 941     {
 942         this.nextthink = time + 1;
 943         this.cnt -= 1;
 944     }
 945         else
 946         {
 947                 if(this.cnt <= 10)
 948                         setmodel(this, MDL_NUM(this.cnt));
 949                 if(IS_REAL_CLIENT(this.owner))
 950                 {
 951                         if(this.cnt <= 10)
 952                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 953                 }
 954                 this.nextthink = time + 1;
 955                 this.cnt -= 1;
 956         }
 957 }
 958
 959 float clientkilltime;
 960 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 961 {
 962         float killtime;
 963         float starttime;
 964
 965         if (game_stopped)
 966                 return;
 967
 968         killtime = autocvar_g_balance_kill_delay;
 969
 970     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 971         return;
 972     killtime = M_ARGV(1, float);
 973
 974         this.killindicator_teamchange = targetteam;
 975
 976     if(!this.killindicator)
 977         {
 978                 if(!IS_DEAD(this))
 979                 {
 980                         killtime = max(killtime, this.clientkill_nexttime - time);
 981                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 982                 }
 983
 984                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 985                 {
 986                         ClientKill_Now(this);
 987                 }
 988                 else
 989                 {
 990                         starttime = max(time, clientkilltime);
 991
 992                         this.killindicator = spawn();
 993                         this.killindicator.owner = this;
 994                         this.killindicator.scale = 0.5;
 995                         setattachment(this.killindicator, this, "");
 996                         setorigin(this.killindicator, '0 0 52');
 997                         setthink(this.killindicator, KillIndicator_Think);
 998                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 999                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1000                         this.killindicator.cnt = ceil(killtime);
1001                         this.killindicator.count = bound(0, ceil(killtime), 10);
1002                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1003
1004                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1005                         {
1006                                 it.killindicator = spawn();
1007                                 it.killindicator.owner = it;
1008                                 it.killindicator.scale = 0.5;
1009                                 setattachment(it.killindicator, it, "");
1010                                 setorigin(it.killindicator, '0 0 52');
1011                                 setthink(it.killindicator, KillIndicator_Think);
1012                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1013                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1014                                 it.killindicator.cnt = ceil(killtime);
1015                         });
1016                         this.lip = 0;
1017                 }
1018         }
1019         if(this.killindicator)
1020         {
1021                 if(targetteam == 0) // just die
1022                 {
1023                         this.killindicator.colormod = '0 0 0';
1024                         if(IS_REAL_CLIENT(this))
1025                         if(this.killindicator.cnt > 0)
1026                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1027                 }
1028                 else if(targetteam == -1) // auto
1029                 {
1030                         this.killindicator.colormod = '0 1 0';
1031                         if(IS_REAL_CLIENT(this))
1032                         if(this.killindicator.cnt > 0)
1033                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1034                 }
1035                 else if(targetteam == -2) // spectate
1036                 {
1037                         this.killindicator.colormod = '0.5 0.5 0.5';
1038                         if(IS_REAL_CLIENT(this))
1039                         if(this.killindicator.cnt > 0)
1040                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1041                 }
1042                 else
1043                 {
1044                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1045                         if(IS_REAL_CLIENT(this))
1046                         if(this.killindicator.cnt > 0)
1047                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1048                 }
1049         }
1050
1051 }
1052
1053 void ClientKill (entity this)
1054 {
1055         if(game_stopped) return;
1056         if(this.player_blocked) return;
1057         if(STAT(FROZEN, this)) return;
1058
1059         ClientKill_TeamChange(this, 0);
1060 }
1061
1062 void FixClientCvars(entity e)
1063 {
1064         // send prediction settings to the client
1065         stuffcmd(e, "\nin_bindmap 0 0\n");
1066         if(autocvar_g_antilag == 3) // client side hitscan
1067                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1068         if(autocvar_sv_gentle)
1069                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1070
1071         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1072         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1073
1074         MUTATOR_CALLHOOK(FixClientCvars, e);
1075 }
1076
1077 bool findinlist_abbrev(string tofind, string list)
1078 {
1079         if(list == "" || tofind == "")
1080                 return false; // empty list or search, just return
1081
1082         // this function allows abbreviated strings!
1083         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1084         {
1085                 return true;
1086         });
1087
1088         return false;
1089 }
1090
1091 bool PlayerInIPList(entity p, string iplist)
1092 {
1093         // some safety checks (never allow local?)
1094         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1095                 return false;
1096
1097         return findinlist_abbrev(p.netaddress, iplist);
1098 }
1099
1100 bool PlayerInIDList(entity p, string idlist)
1101 {
1102         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1103         if(!p.crypto_idfp)
1104                 return false;
1105
1106         return findinlist_abbrev(p.crypto_idfp, idlist);
1107 }
1108
1109 bool PlayerInList(entity player, string list)
1110 {
1111         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1112 }
1113
1114 #ifdef DP_EXT_PRECONNECT
1115 /*
1116 =============
1117 ClientPreConnect
1118
1119 Called once (not at each match start) when a client begins a connection to the server
1120 =============
1121 */
1122 void ClientPreConnect(entity this)
1123 {
1124         if(autocvar_sv_eventlog)
1125         {
1126                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1127                         this.playerid,
1128                         etof(this),
1129                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1130                 ));
1131         }
1132 }
1133 #endif
1134
1135 /**
1136 =============
1137 ClientConnect
1138
1139 Called when a client connects to the server
1140 =============
1141 */
1142 void ClientConnect(entity this)
1143 {
1144         if (Ban_MaybeEnforceBanOnce(this)) return;
1145         assert(!IS_CLIENT(this), return);
1146         this.flags |= FL_CLIENT;
1147         assert(player_count >= 0, player_count = 0);
1148
1149 #ifdef WATERMARK
1150         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1151 #endif
1152         TRANSMUTE(Client, this);
1153         CS(this).version_nagtime = time + 10 + random() * 10;
1154
1155         // identify the right forced team
1156         if (autocvar_g_campaign)
1157         {
1158                 if (IS_REAL_CLIENT(this)) // only players, not bots
1159                 {
1160                         switch (autocvar_g_campaign_forceteam)
1161                         {
1162                                 case 1: this.team_forced = NUM_TEAM_1; break;
1163                                 case 2: this.team_forced = NUM_TEAM_2; break;
1164                                 case 3: this.team_forced = NUM_TEAM_3; break;
1165                                 case 4: this.team_forced = NUM_TEAM_4; break;
1166                                 default: this.team_forced = 0;
1167                         }
1168                 }
1169         }
1170         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1171         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1172         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1173         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1174         else switch (autocvar_g_forced_team_otherwise)
1175         {
1176                 default: this.team_forced = 0; break;
1177                 case "red": this.team_forced = NUM_TEAM_1; break;
1178                 case "blue": this.team_forced = NUM_TEAM_2; break;
1179                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1180                 case "pink": this.team_forced = NUM_TEAM_4; break;
1181                 case "spectate":
1182                 case "spectator":
1183                         this.team_forced = -1;
1184                         break;
1185         }
1186         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1187
1188     {
1189         int id = this.playerid;
1190         this.playerid = 0; // silent
1191             JoinBestTeam(this, false); // if the team number is valid, keep it
1192             this.playerid = id;
1193     }
1194
1195         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1196                 TRANSMUTE(Observer, this);
1197         } else {
1198                 if (!teamplay || autocvar_g_balance_teams) {
1199                         TRANSMUTE(Player, this);
1200                         campaign_bots_may_start = true;
1201                 } else {
1202                         TRANSMUTE(Observer, this); // do it anyway
1203                 }
1204         }
1205
1206         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1207
1208         // always track bots, don't ask for cl_allow_uidtracking
1209         if (IS_BOT_CLIENT(this))
1210                 PlayerStats_GameReport_AddPlayer(this);
1211         else
1212                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1213
1214         if (autocvar_sv_eventlog)
1215                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1216
1217         LogTeamchange(this.playerid, this.team, 1);
1218
1219         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1220
1221         if(teamplay && IS_PLAYER(this))
1222                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1223         else
1224                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1225
1226         stuffcmd(this, clientstuff, "\n");
1227         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1228
1229         FixClientCvars(this);
1230
1231         // get version info from player
1232         stuffcmd(this, "cmd clientversion $gameversion\n");
1233
1234         // notify about available teams
1235         if (teamplay)
1236         {
1237                 CheckAllowedTeams(this);
1238                 int t = 0;
1239                 if (c1 >= 0) t |= BIT(0);
1240                 if (c2 >= 0) t |= BIT(1);
1241                 if (c3 >= 0) t |= BIT(2);
1242                 if (c4 >= 0) t |= BIT(3);
1243                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1244         }
1245         else
1246         {
1247                 stuffcmd(this, "set _teams_available 0\n");
1248         }
1249
1250         bot_relinkplayerlist();
1251
1252         CS(this).spectatortime = time;
1253         if (blockSpectators)
1254         {
1255                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1256         }
1257
1258         CS(this).jointime = time;
1259
1260         if (IS_REAL_CLIENT(this))
1261         {
1262                 if (g_weaponarena_weapons == WEPSET(TUBA))
1263                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1264         }
1265
1266         if (!sv_foginterval && world.fog != "")
1267                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1268
1269         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1270                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1271                         send_CSQC_teamnagger();
1272
1273         CSQCMODEL_AUTOINIT(this);
1274
1275         CS(this).model_randomizer = random();
1276
1277         if (IS_REAL_CLIENT(this))
1278                 sv_notice_join(this);
1279
1280         // update physics stats (players can spawn before physics runs)
1281         Physics_UpdateStats(this);
1282
1283         IL_EACH(g_initforplayer, it.init_for_player, {
1284                 it.init_for_player(it, this);
1285         });
1286
1287         Handicap_Initialize(this);
1288
1289         MUTATOR_CALLHOOK(ClientConnect, this);
1290
1291         if (IS_REAL_CLIENT(this))
1292         {
1293                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1294                 {
1295                         CS(this).motd_actived_time = -1;
1296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1297                 }
1298         }
1299 }
1300 /*
1301 =============
1302 ClientDisconnect
1303
1304 Called when a client disconnects from the server
1305 =============
1306 */
1307 .entity chatbubbleentity;
1308 void ReadyCount();
1309 void ClientDisconnect(entity this)
1310 {
1311         assert(IS_CLIENT(this), return);
1312
1313         PlayerStats_GameReport_FinalizePlayer(this);
1314         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1315         if (CS(this).active_minigame) part_minigame(this);
1316         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1317
1318         if (autocvar_sv_eventlog)
1319                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1320
1321         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1322
1323         if(IS_SPEC(this))
1324                 SetSpectatee(this, NULL);
1325
1326     MUTATOR_CALLHOOK(ClientDisconnect, this);
1327
1328         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1329         ClientState_detach(this);
1330
1331         Portal_ClearAll(this);
1332
1333         Unfreeze(this);
1334
1335         RemoveGrapplingHooks(this);
1336
1337         // Here, everything has been done that requires this player to be a client.
1338
1339         this.flags &= ~FL_CLIENT;
1340
1341         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1342         if (this.killindicator) delete(this.killindicator);
1343
1344         WaypointSprite_PlayerGone(this);
1345
1346         bot_relinkplayerlist();
1347
1348         if (this.clientstatus) strunzone(this.clientstatus);
1349         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1350         if (this.personal) delete(this.personal);
1351
1352         this.playerid = 0;
1353         ReadyCount();
1354         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1355
1356         ONREMOVE(this);
1357 }
1358
1359 void ChatBubbleThink(entity this)
1360 {
1361         this.nextthink = time;
1362         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1363         {
1364                 if(this.owner) // but why can that ever be NULL?
1365                         this.owner.chatbubbleentity = NULL;
1366                 delete(this);
1367                 return;
1368         }
1369
1370         this.mdl = "";
1371
1372         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1373         {
1374                 if ( CS(this.owner).active_minigame )
1375                         this.mdl = "models/sprites/minigame_busy.iqm";
1376                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1377                         this.mdl = "models/misc/chatbubble.spr";
1378         }
1379
1380         if ( this.model != this.mdl )
1381                 _setmodel(this, this.mdl);
1382
1383 }
1384
1385 void UpdateChatBubble(entity this)
1386 {
1387         if (this.alpha < 0)
1388                 return;
1389         // spawn a chatbubble entity if needed
1390         if (!this.chatbubbleentity)
1391         {
1392                 this.chatbubbleentity = new(chatbubbleentity);
1393                 this.chatbubbleentity.owner = this;
1394                 this.chatbubbleentity.exteriormodeltoclient = this;
1395                 setthink(this.chatbubbleentity, ChatBubbleThink);
1396                 this.chatbubbleentity.nextthink = time;
1397                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1398                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1399                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1400                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1401                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1402                 //this.chatbubbleentity.model = "";
1403                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1404         }
1405 }
1406
1407
1408 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1409 // added to the model skins
1410 /*void UpdateColorModHack()
1411 {
1412         float c;
1413         c = this.clientcolors & 15;
1414         // LordHavoc: only bothering to support white, green, red, yellow, blue
1415              if (!teamplay) this.colormod = '0 0 0';
1416         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1417         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1418         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1419         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1420         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1421         else this.colormod = '1 1 1';
1422 }*/
1423
1424 void respawn(entity this)
1425 {
1426         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1427         {
1428                 this.solid = SOLID_NOT;
1429                 this.takedamage = DAMAGE_NO;
1430                 set_movetype(this, MOVETYPE_FLY);
1431                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1432                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1433                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1434                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1435                 if(autocvar_g_respawn_ghosts_maxtime)
1436                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1437         }
1438
1439         CopyBody(this, 1);
1440
1441         this.effects |= EF_NODRAW; // prevent another CopyBody
1442         PutClientInServer(this);
1443 }
1444
1445 void play_countdown(entity this, float finished, Sound samp)
1446 {
1447     TC(Sound, samp);
1448         if(IS_REAL_CLIENT(this))
1449                 if(floor(finished - time - frametime) != floor(finished - time))
1450                         if(finished - time < 6)
1451                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1452 }
1453
1454 void player_powerups(entity this)
1455 {
1456         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1457         int items_prev = this.items;
1458
1459         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1460                 this.modelflags |= MF_ROCKET;
1461         else
1462                 this.modelflags &= ~MF_ROCKET;
1463
1464         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1465
1466         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1467                 return;
1468
1469         Fire_ApplyDamage(this);
1470         Fire_ApplyEffect(this);
1471
1472         if (!g_instagib)
1473         {
1474                 if (this.items & ITEM_Strength.m_itemid)
1475                 {
1476                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1477                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1478                         if (time > this.strength_finished)
1479                         {
1480                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1481                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1482                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1483                         }
1484                 }
1485                 else
1486                 {
1487                         if (time < this.strength_finished)
1488                         {
1489                                 this.items = this.items | ITEM_Strength.m_itemid;
1490                                 if(!g_cts)
1491                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1492                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1493                         }
1494                 }
1495                 if (this.items & ITEM_Shield.m_itemid)
1496                 {
1497                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1498                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1499                         if (time > this.invincible_finished)
1500                         {
1501                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1502                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1503                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1504                         }
1505                 }
1506                 else
1507                 {
1508                         if (time < this.invincible_finished)
1509                         {
1510                                 this.items = this.items | ITEM_Shield.m_itemid;
1511                                 if(!g_cts)
1512                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1513                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1514                         }
1515                 }
1516                 if (this.items & IT_SUPERWEAPON)
1517                 {
1518                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1519                         {
1520                                 this.superweapons_finished = 0;
1521                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1522                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1523                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1524                         }
1525                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1526                         {
1527                                 // don't let them run out
1528                         }
1529                         else
1530                         {
1531                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1532                                 if (time > this.superweapons_finished)
1533                                 {
1534                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1535                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1536                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1537                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1538                                 }
1539                         }
1540                 }
1541                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1542                 {
1543                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1544                         {
1545                                 this.items = this.items | IT_SUPERWEAPON;
1546                                 if(!g_cts)
1547                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1548                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1549                         }
1550                         else
1551                         {
1552                                 this.superweapons_finished = 0;
1553                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1554                         }
1555                 }
1556                 else
1557                 {
1558                         this.superweapons_finished = 0;
1559                 }
1560         }
1561
1562         if(autocvar_g_nodepthtestplayers)
1563                 this.effects = this.effects | EF_NODEPTHTEST;
1564
1565         if(autocvar_g_fullbrightplayers)
1566                 this.effects = this.effects | EF_FULLBRIGHT;
1567
1568         if (time >= game_starttime)
1569         if (time < this.spawnshieldtime)
1570                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1571
1572         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1573 }
1574
1575 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1576 {
1577         if(current > stable)
1578                 return current;
1579         else if(current > stable - 0.25) // when close enough, "snap"
1580                 return stable;
1581         else
1582                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1583 }
1584
1585 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1586 {
1587         if(current < stable)
1588                 return current;
1589         else if(current < stable + 0.25) // when close enough, "snap"
1590                 return stable;
1591         else
1592                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1593 }
1594
1595 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1596 {
1597         if(current > rotstable)
1598         {
1599                 if(rotframetime > 0)
1600                 {
1601                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1602                         current = max(rotstable, current - rotlinear * rotframetime);
1603                 }
1604         }
1605         else if(current < regenstable)
1606         {
1607                 if(regenframetime > 0)
1608                 {
1609                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1610                         current = min(regenstable, current + regenlinear * regenframetime);
1611                 }
1612         }
1613
1614         if(current > limit)
1615                 current = limit;
1616
1617         return current;
1618 }
1619
1620 void player_regen(entity this)
1621 {
1622         float max_mod, regen_mod, rot_mod, limit_mod;
1623         max_mod = regen_mod = rot_mod = limit_mod = 1;
1624
1625         float regen_health = autocvar_g_balance_health_regen;
1626         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1627         float regen_health_rot = autocvar_g_balance_health_rot;
1628         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1629         float regen_health_stable = autocvar_g_balance_health_regenstable;
1630         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1631         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1632                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1633         max_mod = M_ARGV(1, float);
1634         regen_mod = M_ARGV(2, float);
1635         rot_mod = M_ARGV(3, float);
1636         limit_mod = M_ARGV(4, float);
1637         regen_health = M_ARGV(5, float);
1638         regen_health_linear = M_ARGV(6, float);
1639         regen_health_rot = M_ARGV(7, float);
1640         regen_health_rotlinear = M_ARGV(8, float);
1641         regen_health_stable = M_ARGV(9, float);
1642         regen_health_rotstable = M_ARGV(10, float);
1643
1644         if(!mutator_returnvalue)
1645         if(!STAT(FROZEN, this))
1646         {
1647                 float mina, maxa, limith, limita;
1648                 maxa = autocvar_g_balance_armor_rotstable;
1649                 mina = autocvar_g_balance_armor_regenstable;
1650                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1651                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1652
1653                 regen_health_rotstable = regen_health_rotstable * max_mod;
1654                 regen_health_stable = regen_health_stable * max_mod;
1655                 limith = limith * limit_mod;
1656                 limita = limita * limit_mod;
1657
1658                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1659                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1660         }
1661
1662         // if player rotted to death...  die!
1663         // check this outside above checks, as player may still be able to rot to death
1664         if(this.health < 1)
1665         {
1666                 if(this.vehicle)
1667                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1668                 if(this.event_damage)
1669                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1670         }
1671
1672         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1673         {
1674                 float minf, maxf, limitf;
1675
1676                 maxf = autocvar_g_balance_fuel_rotstable;
1677                 minf = autocvar_g_balance_fuel_regenstable;
1678                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1679
1680                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1681         }
1682         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1683         // TODO: Remove this hack when all code uses GivePlayerHealth and
1684         // GivePlayerArmor.
1685         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1686         {
1687                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1688         }
1689         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1690         {
1691                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1692         }
1693         // End hack.
1694 }
1695
1696 bool zoomstate_set;
1697 void SetZoomState(entity this, float newzoom)
1698 {
1699         if(newzoom != CS(this).zoomstate)
1700         {
1701                 CS(this).zoomstate = newzoom;
1702                 ClientData_Touch(this);
1703         }
1704         zoomstate_set = true;
1705 }
1706
1707 void GetPressedKeys(entity this)
1708 {
1709         MUTATOR_CALLHOOK(GetPressedKeys, this);
1710         int keys = STAT(PRESSED_KEYS, this);
1711         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1712         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1713         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1714         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1715
1716         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1717         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1718         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1719         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1720         CS(this).pressedkeys = keys; // store for other users
1721
1722         STAT(PRESSED_KEYS, this) = keys;
1723 }
1724
1725 /*
1726 ======================
1727 spectate mode routines
1728 ======================
1729 */
1730
1731 void SpectateCopy(entity this, entity spectatee)
1732 {
1733     TC(Client, this); TC(Client, spectatee);
1734
1735         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1736         PS(this) = PS(spectatee);
1737         this.armortype = spectatee.armortype;
1738         this.armorvalue = spectatee.armorvalue;
1739         this.ammo_cells = spectatee.ammo_cells;
1740         this.ammo_plasma = spectatee.ammo_plasma;
1741         this.ammo_shells = spectatee.ammo_shells;
1742         this.ammo_nails = spectatee.ammo_nails;
1743         this.ammo_rockets = spectatee.ammo_rockets;
1744         this.ammo_fuel = spectatee.ammo_fuel;
1745         this.clip_load = spectatee.clip_load;
1746         this.clip_size = spectatee.clip_size;
1747         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1748         this.health = spectatee.health;
1749         CS(this).impulse = 0;
1750         this.items = spectatee.items;
1751         this.last_pickup = spectatee.last_pickup;
1752         this.hit_time = spectatee.hit_time;
1753         this.strength_finished = spectatee.strength_finished;
1754         this.invincible_finished = spectatee.invincible_finished;
1755         this.superweapons_finished = spectatee.superweapons_finished;
1756         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1757         this.weapons = spectatee.weapons;
1758         this.vortex_charge = spectatee.vortex_charge;
1759         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1760         this.hagar_load = spectatee.hagar_load;
1761         this.arc_heat_percent = spectatee.arc_heat_percent;
1762         this.minelayer_mines = spectatee.minelayer_mines;
1763         this.punchangle = spectatee.punchangle;
1764         this.view_ofs = spectatee.view_ofs;
1765         this.velocity = spectatee.velocity;
1766         this.dmg_take = spectatee.dmg_take;
1767         this.dmg_save = spectatee.dmg_save;
1768         this.dmg_inflictor = spectatee.dmg_inflictor;
1769         this.v_angle = spectatee.v_angle;
1770         this.angles = spectatee.v_angle;
1771         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1772         this.revive_progress = spectatee.revive_progress;
1773         this.viewloc = spectatee.viewloc;
1774         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1775                 this.fixangle = true;
1776         setorigin(this, spectatee.origin);
1777         setsize(this, spectatee.mins, spectatee.maxs);
1778         SetZoomState(this, CS(spectatee).zoomstate);
1779
1780         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1781         {
1782                 .entity weaponentity = weaponentities[slot];
1783                 this.(weaponentity) = spectatee.(weaponentity);
1784         }
1785
1786         for(int slot = 0; slot < MAX_AXH; ++slot)
1787         {
1788                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1789         }
1790
1791     anticheat_spectatecopy(this, spectatee);
1792         this.hud = spectatee.hud;
1793         if(spectatee.vehicle)
1794     {
1795         this.angles = spectatee.v_angle;
1796
1797         //this.fixangle = false;
1798         //this.velocity = spectatee.vehicle.velocity;
1799         this.vehicle_health = spectatee.vehicle_health;
1800         this.vehicle_shield = spectatee.vehicle_shield;
1801         this.vehicle_energy = spectatee.vehicle_energy;
1802         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1803         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1804         this.vehicle_reload1 = spectatee.vehicle_reload1;
1805         this.vehicle_reload2 = spectatee.vehicle_reload2;
1806
1807         //msg_entity = this;
1808
1809        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1810             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1811            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1812            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1813
1814         //WriteByte (MSG_ONE, SVC_SETVIEW);
1815         //    WriteEntity(MSG_ONE, this);
1816         //makevectors(spectatee.v_angle);
1817         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1818     }
1819 }
1820
1821 bool SpectateUpdate(entity this)
1822 {
1823         if(!this.enemy)
1824                 return false;
1825
1826         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1827         {
1828                 SetSpectatee(this, NULL);
1829                 return false;
1830         }
1831
1832         SpectateCopy(this, this.enemy);
1833
1834         return true;
1835 }
1836
1837 bool SpectateSet(entity this)
1838 {
1839         if(!IS_PLAYER(this.enemy))
1840                 return false;
1841
1842         ClientData_Touch(this.enemy);
1843
1844         msg_entity = this;
1845         WriteByte(MSG_ONE, SVC_SETVIEW);
1846         WriteEntity(MSG_ONE, this.enemy);
1847         set_movetype(this, MOVETYPE_NONE);
1848         accuracy_resend(this);
1849
1850         if(!SpectateUpdate(this))
1851                 PutObserverInServer(this);
1852
1853         return true;
1854 }
1855
1856 void SetSpectatee_status(entity this, int spectatee_num)
1857 {
1858         int oldspectatee_status = CS(this).spectatee_status;
1859         CS(this).spectatee_status = spectatee_num;
1860
1861         if (CS(this).spectatee_status != oldspectatee_status)
1862         {
1863                 ClientData_Touch(this);
1864                 if (g_race || g_cts) race_InitSpectator();
1865         }
1866 }
1867
1868 void SetSpectatee(entity this, entity spectatee)
1869 {
1870         if(IS_BOT_CLIENT(this))
1871                 return; // bots abuse .enemy, this code is useless to them
1872
1873         entity old_spectatee = this.enemy;
1874
1875         this.enemy = spectatee;
1876
1877         // WEAPONTODO
1878         // these are required to fix the spectator bug with arc
1879         if(old_spectatee)
1880         {
1881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1882                 {
1883                         .entity weaponentity = weaponentities[slot];
1884                         if(old_spectatee.(weaponentity).arc_beam)
1885                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1886                 }
1887         }
1888         if(this.enemy)
1889         {
1890                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891                 {
1892                         .entity weaponentity = weaponentities[slot];
1893                         if(this.enemy.(weaponentity).arc_beam)
1894                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1895                 }
1896         }
1897
1898         if (this.enemy)
1899                 SetSpectatee_status(this, etof(this.enemy));
1900
1901         // needed to update spectator list
1902         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1903 }
1904
1905 bool Spectate(entity this, entity pl)
1906 {
1907         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1908                 return false;
1909         pl = M_ARGV(1, entity);
1910
1911         SetSpectatee(this, pl);
1912         return SpectateSet(this);
1913 }
1914
1915 bool SpectateNext(entity this)
1916 {
1917         entity ent = find(this.enemy, classname, STR_PLAYER);
1918
1919         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1920                 ent = M_ARGV(1, entity);
1921         else if (!ent)
1922                 ent = find(ent, classname, STR_PLAYER);
1923
1924         if(ent) { SetSpectatee(this, ent); }
1925
1926         return SpectateSet(this);
1927 }
1928
1929 bool SpectatePrev(entity this)
1930 {
1931         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1932         entity ent = findchain(classname, STR_PLAYER);
1933         if (!ent) // no player
1934                 return false;
1935
1936         entity first = ent;
1937         // skip players until current spectated player
1938         if(this.enemy)
1939         while(ent && ent != this.enemy)
1940                 ent = ent.chain;
1941
1942         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1943         {
1944                 case MUT_SPECPREV_FOUND:
1945                     ent = M_ARGV(1, entity);
1946                     break;
1947                 case MUT_SPECPREV_RETURN:
1948                     return true;
1949                 case MUT_SPECPREV_CONTINUE:
1950                 default:
1951                 {
1952                         if(ent.chain)
1953                                 ent = ent.chain;
1954                         else
1955                                 ent = first;
1956                         break;
1957                 }
1958         }
1959
1960         SetSpectatee(this, ent);
1961         return SpectateSet(this);
1962 }
1963
1964 /*
1965 =============
1966 ShowRespawnCountdown()
1967
1968 Update a respawn countdown display.
1969 =============
1970 */
1971 void ShowRespawnCountdown(entity this)
1972 {
1973         float number;
1974         if(!IS_DEAD(this)) // just respawned?
1975                 return;
1976         else
1977         {
1978                 number = ceil(this.respawn_time - time);
1979                 if(number <= 0)
1980                         return;
1981                 if(number <= this.respawn_countdown)
1982                 {
1983                         this.respawn_countdown = number - 1;
1984                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1985                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1986                 }
1987         }
1988 }
1989
1990 .bool team_selected;
1991 bool ShowTeamSelection(entity this)
1992 {
1993         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1994                 return false;
1995         stuffcmd(this, "menu_showteamselect\n");
1996         return true;
1997 }
1998 void Join(entity this)
1999 {
2000         TRANSMUTE(Player, this);
2001
2002         if(!this.team_selected)
2003         if(autocvar_g_campaign || autocvar_g_balance_teams)
2004                 JoinBestTeam(this, true);
2005
2006         if(autocvar_g_campaign)
2007                 campaign_bots_may_start = true;
2008
2009         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2010
2011         PutClientInServer(this);
2012
2013         if(IS_PLAYER(this))
2014         if(teamplay && this.team != -1)
2015                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2016         else
2017                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2018         this.team_selected = false;
2019 }
2020
2021 /**
2022  * Determines whether the player is allowed to join. This depends on cvar
2023  * g_maxplayers, if it isn't used this function always return true, otherwise
2024  * it checks whether the number of currently playing players exceeds g_maxplayers.
2025  * @return int number of free slots for players, 0 if none
2026  */
2027 int nJoinAllowed(entity this, entity ignore)
2028 {
2029         if(!ignore)
2030         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2031         // so report 0 free slots if restricted
2032         {
2033                 if(autocvar_g_forced_team_otherwise == "spectate")
2034                         return 0;
2035                 if(autocvar_g_forced_team_otherwise == "spectator")
2036                         return 0;
2037         }
2038
2039         if(this && this.team_forced < 0)
2040                 return 0; // forced spectators can never join
2041
2042         // TODO simplify this
2043         int totalClients = 0;
2044         int currentlyPlaying = 0;
2045         FOREACH_CLIENT(true, {
2046                 if(it != ignore)
2047                         ++totalClients;
2048                 if(IS_REAL_CLIENT(it))
2049                 if(IS_PLAYER(it) || it.caplayer)
2050                         ++currentlyPlaying;
2051         });
2052
2053         float free_slots = 0;
2054         if (!autocvar_g_maxplayers)
2055                 free_slots = maxclients - totalClients;
2056         else if(currentlyPlaying < autocvar_g_maxplayers)
2057                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2058
2059         static float join_prevent_msg_time = 0;
2060         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2061         {
2062                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2063                 join_prevent_msg_time = time + 3;
2064         }
2065
2066         return free_slots;
2067 }
2068
2069 /**
2070  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2071  * g_maxplayers_spectator_blocktime seconds
2072  */
2073 void checkSpectatorBlock(entity this)
2074 {
2075         if(IS_SPEC(this) || IS_OBSERVER(this))
2076         if(!this.caplayer)
2077         if(IS_REAL_CLIENT(this))
2078         {
2079                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2080                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2081                         dropclient(this);
2082                 }
2083         }
2084 }
2085
2086 void PrintWelcomeMessage(entity this)
2087 {
2088         if(CS(this).motd_actived_time == 0)
2089         {
2090                 if (autocvar_g_campaign) {
2091                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2092                                 CS(this).motd_actived_time = time;
2093                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2094                         }
2095                 } else {
2096                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2097                                 CS(this).motd_actived_time = time;
2098                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2099                         }
2100                 }
2101         }
2102         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2103         {
2104                 if (autocvar_g_campaign) {
2105                         if (PHYS_INPUT_BUTTON_INFO(this))
2106                                 CS(this).motd_actived_time = time;
2107                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2108                                 CS(this).motd_actived_time = 0;
2109                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2110                         }
2111                 } else {
2112                         if (PHYS_INPUT_BUTTON_INFO(this))
2113                                 CS(this).motd_actived_time = time;
2114                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2115                                 CS(this).motd_actived_time = 0;
2116                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2117                         }
2118                 }
2119         }
2120         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2121         {
2122                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2123                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2124                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2125                 {
2126                         // instanctly hide MOTD
2127                         CS(this).motd_actived_time = 0;
2128                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2129                 }
2130         }
2131 }
2132
2133 bool joinAllowed(entity this)
2134 {
2135         if (CS(this).version_mismatch) return false;
2136         if (!nJoinAllowed(this, this)) return false;
2137         if (teamplay && lockteams) return false;
2138         if (ShowTeamSelection(this)) return false;
2139         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2140         return true;
2141 }
2142
2143 .int items_added;
2144 bool PlayerThink(entity this)
2145 {
2146         if (game_stopped || intermission_running) {
2147                 this.modelflags &= ~MF_ROCKET;
2148                 if(intermission_running)
2149                         IntermissionThink(this);
2150                 return false;
2151         }
2152
2153         if (timeout_status == TIMEOUT_ACTIVE) {
2154         // don't allow the player to turn around while game is paused
2155                 // FIXME turn this into CSQC stuff
2156                 this.v_angle = this.lastV_angle;
2157                 this.angles = this.lastV_angle;
2158                 this.fixangle = true;
2159         }
2160
2161         if (frametime) player_powerups(this);
2162
2163         if (IS_DEAD(this)) {
2164                 if (this.personal && g_race_qualifying) {
2165                         if (time > this.respawn_time) {
2166                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2167                                 respawn(this);
2168                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2169                         }
2170                 } else {
2171                         if (frametime) player_anim(this);
2172
2173                         if (this.respawn_flags & RESPAWN_DENY)
2174                         {
2175                                 STAT(RESPAWN_TIME, this) = 0;
2176                                 return false;
2177                         }
2178
2179                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2180
2181                         switch(this.deadflag)
2182                         {
2183                                 case DEAD_DYING:
2184                                 {
2185                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2186                                                 this.deadflag = DEAD_RESPAWNING;
2187                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2188                                                 this.deadflag = DEAD_DEAD;
2189                                         break;
2190                                 }
2191                                 case DEAD_DEAD:
2192                                 {
2193                                         if (button_pressed)
2194                                                 this.deadflag = DEAD_RESPAWNABLE;
2195                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2196                                                 this.deadflag = DEAD_RESPAWNING;
2197                                         break;
2198                                 }
2199                                 case DEAD_RESPAWNABLE:
2200                                 {
2201                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2202                                                 this.deadflag = DEAD_RESPAWNING;
2203                                         break;
2204                                 }
2205                                 case DEAD_RESPAWNING:
2206                                 {
2207                                         if (time > this.respawn_time)
2208                                         {
2209                                                 this.respawn_time = time + 1; // only retry once a second
2210                                                 this.respawn_time_max = this.respawn_time;
2211                                                 respawn(this);
2212                                         }
2213                                         break;
2214                                 }
2215                         }
2216
2217                         ShowRespawnCountdown(this);
2218
2219                         if (this.respawn_flags & RESPAWN_SILENT)
2220                                 STAT(RESPAWN_TIME, this) = 0;
2221                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2222                         {
2223                                 if (time < this.respawn_time)
2224                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2225                                 else if (this.deadflag != DEAD_RESPAWNING)
2226                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2227                         }
2228                         else
2229                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2230                 }
2231
2232                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2233                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2234                         STAT(RESPAWN_TIME, this) *= -1;
2235
2236                 return false;
2237         }
2238
2239         bool have_hook = false;
2240         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2241         {
2242                 .entity weaponentity = weaponentities[slot];
2243                 if(this.(weaponentity).hook.state)
2244                 {
2245                         have_hook = true;
2246                         break;
2247                 }
2248         }
2249         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2250         if (have_hook) {
2251                 do_crouch = false;
2252         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2253                 do_crouch = false;
2254         } else if (this.vehicle) {
2255                 do_crouch = false;
2256         } else if (STAT(FROZEN, this)) {
2257                 do_crouch = false;
2258     }
2259
2260         if (do_crouch) {
2261                 if (!this.crouch) {
2262                         this.crouch = true;
2263                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2264                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2265                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2266                 }
2267         } else if (this.crouch) {
2268         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2269         if (!trace_startsolid) {
2270             this.crouch = false;
2271             this.view_ofs = STAT(PL_VIEW_OFS, this);
2272             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2273         }
2274         }
2275
2276         FixPlayermodel(this);
2277
2278         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2279         //if(frametime)
2280         {
2281                 this.items &= ~this.items_added;
2282
2283                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2284                 {
2285                         .entity weaponentity = weaponentities[slot];
2286                         W_WeaponFrame(this, weaponentity);
2287
2288                         if(slot == 0)
2289                         {
2290                                 this.clip_load = this.(weaponentity).clip_load;
2291                                 this.clip_size = this.(weaponentity).clip_size;
2292                         }
2293                 }
2294
2295                 this.items_added = 0;
2296                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2297             this.items_added |= IT_FUEL;
2298
2299                 this.items |= this.items_added;
2300         }
2301
2302         player_regen(this);
2303
2304         // WEAPONTODO: Add a weapon request for this
2305         // rot vortex charge to the charge limit
2306         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2307         {
2308                 .entity weaponentity = weaponentities[slot];
2309                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2310                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2311         }
2312
2313         if (frametime) player_anim(this);
2314
2315         // secret status
2316         secrets_setstatus(this);
2317
2318         // monsters status
2319         monsters_setstatus(this);
2320
2321         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2322
2323         return true;
2324 }
2325
2326 void ObserverThink(entity this)
2327 {
2328         if ( CS(this).impulse )
2329         {
2330                 MinigameImpulse(this, CS(this).impulse);
2331                 CS(this).impulse = 0;
2332         }
2333
2334         if (this.flags & FL_JUMPRELEASED) {
2335                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2336                         this.flags &= ~FL_JUMPRELEASED;
2337                         this.flags |= FL_SPAWNING;
2338                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2339                         this.flags &= ~FL_JUMPRELEASED;
2340                         if(SpectateNext(this)) {
2341                                 TRANSMUTE(Spectator, this);
2342                         }
2343                 } else {
2344                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2345                         set_movetype(this, preferred_movetype);
2346                 }
2347         } else {
2348                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2349                         this.flags |= FL_JUMPRELEASED;
2350                         if(this.flags & FL_SPAWNING)
2351                         {
2352                                 this.flags &= ~FL_SPAWNING;
2353                                 Join(this);
2354                                 return;
2355                         }
2356                 }
2357         }
2358 }
2359
2360 void SpectatorThink(entity this)
2361 {
2362         if ( CS(this).impulse )
2363         {
2364                 if(MinigameImpulse(this, CS(this).impulse))
2365                         CS(this).impulse = 0;
2366
2367                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2368                 {
2369                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2370                         CS(this).impulse = 0;
2371                         return;
2372                 }
2373         }
2374
2375         if (this.flags & FL_JUMPRELEASED) {
2376                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2377                         this.flags &= ~FL_JUMPRELEASED;
2378                         this.flags |= FL_SPAWNING;
2379                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2380                         this.flags &= ~FL_JUMPRELEASED;
2381                         if(SpectateNext(this)) {
2382                                 TRANSMUTE(Spectator, this);
2383                         } else {
2384                                 TRANSMUTE(Observer, this);
2385                                 PutClientInServer(this);
2386                         }
2387                         CS(this).impulse = 0;
2388                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2389                         this.flags &= ~FL_JUMPRELEASED;
2390                         if(SpectatePrev(this)) {
2391                                 TRANSMUTE(Spectator, this);
2392                         } else {
2393                                 TRANSMUTE(Observer, this);
2394                                 PutClientInServer(this);
2395                         }
2396                         CS(this).impulse = 0;
2397                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2398                         this.flags &= ~FL_JUMPRELEASED;
2399                         TRANSMUTE(Observer, this);
2400                         PutClientInServer(this);
2401                 } else {
2402                         if(!SpectateUpdate(this))
2403                                 PutObserverInServer(this);
2404                 }
2405         } else {
2406                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2407                         this.flags |= FL_JUMPRELEASED;
2408                         if(this.flags & FL_SPAWNING)
2409                         {
2410                                 this.flags &= ~FL_SPAWNING;
2411                                 Join(this);
2412                                 return;
2413                         }
2414                 }
2415                 if(!SpectateUpdate(this))
2416                         PutObserverInServer(this);
2417         }
2418
2419         this.flags |= FL_CLIENT | FL_NOTARGET;
2420 }
2421
2422 void vehicles_enter (entity pl, entity veh);
2423 void PlayerUseKey(entity this)
2424 {
2425         if (!IS_PLAYER(this))
2426                 return;
2427
2428         if(this.vehicle)
2429         {
2430                 if(!game_stopped)
2431                 {
2432                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2433                         return;
2434                 }
2435         }
2436         else if(autocvar_g_vehicles_enter)
2437         {
2438                 if(!STAT(FROZEN, this))
2439                 if(!IS_DEAD(this))
2440                 if(!game_stopped)
2441                 {
2442                         entity head, closest_target = NULL;
2443                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2444
2445                         while(head) // find the closest acceptable target to enter
2446                         {
2447                                 if(IS_VEHICLE(head))
2448                                 if(!IS_DEAD(head))
2449                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2450                                 if(head.takedamage != DAMAGE_NO)
2451                                 {
2452                                         if(closest_target)
2453                                         {
2454                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2455                                                 { closest_target = head; }
2456                                         }
2457                                         else { closest_target = head; }
2458                                 }
2459
2460                                 head = head.chain;
2461                         }
2462
2463                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2464                 }
2465         }
2466
2467         // a use key was pressed; call handlers
2468         MUTATOR_CALLHOOK(PlayerUseKey, this);
2469 }
2470
2471
2472 /*
2473 =============
2474 PlayerPreThink
2475
2476 Called every frame for each client before the physics are run
2477 =============
2478 */
2479 .float last_vehiclecheck;
2480 void PlayerPreThink (entity this)
2481 {
2482         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2483         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2484
2485         WarpZone_PlayerPhysics_FixVAngle(this);
2486
2487         if (frametime) {
2488                 // physics frames: update anticheat stuff
2489                 anticheat_prethink(this);
2490         }
2491
2492         if (blockSpectators && frametime) {
2493                 // WORKAROUND: only use dropclient in server frames (frametime set).
2494                 // Never use it in cl_movement frames (frametime zero).
2495                 checkSpectatorBlock(this);
2496         }
2497
2498         zoomstate_set = false;
2499
2500         // Check for nameless players
2501         if (this.netname == "" || this.netname != CS(this).netname_previous)
2502         {
2503                 bool assume_unchanged = (CS(this).netname_previous == "");
2504                 if (isInvisibleString(this.netname))
2505                 {
2506                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2507                         assume_unchanged = false;
2508                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2509                 }
2510                 if (!assume_unchanged && autocvar_sv_eventlog)
2511                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2512                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2513                 CS(this).netname_previous = strzone(this.netname);
2514         }
2515
2516         // version nagging
2517         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2518         CS(this).version_nagtime = 0;
2519         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2520             // git client
2521         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2522             // git server
2523             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2524         } else {
2525             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2526             if (r < 0) { // old client
2527                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2528             } else if (r > 0) { // old server
2529                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2530             }
2531         }
2532     }
2533
2534         // GOD MODE info
2535         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2536         {
2537                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2538                 this.max_armorvalue = 0;
2539         }
2540
2541         if(IS_PLAYER(this))
2542         {
2543                 if (STAT(FROZEN, this) == 2)
2544                 {
2545                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2546                         this.health = max(1, this.revive_progress * start_health);
2547                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2548
2549                         if (this.revive_progress >= 1)
2550                                 Unfreeze(this);
2551                 }
2552                 else if (STAT(FROZEN, this) == 3)
2553                 {
2554                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2555                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2556
2557                         if (this.health < 1)
2558                         {
2559                                 if (this.vehicle)
2560                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2561                                 if(this.event_damage)
2562                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2563                         }
2564                         else if (this.revive_progress <= 0)
2565                                 Unfreeze(this);
2566                 }
2567         }
2568
2569         MUTATOR_CALLHOOK(PlayerPreThink, this);
2570
2571         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2572         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2573         {
2574                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2575                 {
2576                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2577                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2578                         {
2579                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2580                         }
2581                         else if(!it.owner)
2582                         {
2583                                 if(!it.team || SAME_TEAM(this, it))
2584                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2585                                 else if(autocvar_g_vehicles_steal)
2586                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2587                         }
2588                 });
2589
2590                 this.last_vehiclecheck = time + 1;
2591         }
2592
2593         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2594         {
2595                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2596                         PlayerUseKey(this);
2597                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2598         }
2599
2600         if (IS_REAL_CLIENT(this))
2601                 PrintWelcomeMessage(this);
2602
2603         if (IS_PLAYER(this)) {
2604                 if(!PlayerThink(this))
2605                         return;
2606         }
2607         else if (game_stopped || intermission_running) {
2608                 if(intermission_running)
2609                         IntermissionThink(this);
2610                 return;
2611         }
2612         else if (IS_OBSERVER(this)) {
2613                 ObserverThink(this);
2614         }
2615         else if (IS_SPEC(this)) {
2616                 SpectatorThink(this);
2617         }
2618
2619         // WEAPONTODO: Add weapon request for this
2620         if (!zoomstate_set) {
2621                 bool wep_zoomed = false;
2622                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2623                 {
2624                         .entity weaponentity = weaponentities[slot];
2625                         Weapon thiswep = this.(weaponentity).m_weapon;
2626                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2627                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2628                 }
2629                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2630     }
2631
2632         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2633         {
2634                 CS(this).teamkill_soundtime = 0;
2635
2636                 entity e = CS(this).teamkill_soundsource;
2637                 entity oldpusher = e.pusher;
2638                 e.pusher = this;
2639                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2640                 e.pusher = oldpusher;
2641         }
2642
2643         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2644                 CS(this).taunt_soundtime = 0;
2645                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2646         }
2647
2648         target_voicescript_next(this);
2649
2650         // WEAPONTODO: Move into weaponsystem somehow
2651         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2652         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2653         {
2654                 .entity weaponentity = weaponentities[slot];
2655                 if(this.(weaponentity).m_weapon == WEP_Null)
2656                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2657         }
2658 }
2659
2660 void DrownPlayer(entity this)
2661 {
2662         if(IS_DEAD(this))
2663                 return;
2664
2665         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2666         {
2667                 if(this.air_finished < time)
2668                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2669                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2670         }
2671         else if (this.air_finished < time)
2672         {       // drown!
2673                 if (this.pain_finished < time)
2674                 {
2675                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2676                         this.pain_finished = time + 0.5;
2677                 }
2678         }
2679 }
2680
2681 .bool move_qcphysics;
2682
2683 void Player_Physics(entity this)
2684 {
2685         set_movetype(this, this.move_movetype);
2686
2687         if(!this.move_qcphysics)
2688                 return;
2689
2690         if(!frametime && !CS(this).pm_frametime)
2691                 return;
2692
2693         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2694
2695         CS(this).pm_frametime = 0;
2696 }
2697
2698 /*
2699 =============
2700 PlayerPostThink
2701
2702 Called every frame for each client after the physics are run
2703 =============
2704 */
2705 void PlayerPostThink (entity this)
2706 {
2707         Player_Physics(this);
2708
2709         if (sv_maxidle > 0)
2710         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2711         if (IS_REAL_CLIENT(this))
2712         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2713         {
2714                 int totalClients = 0;
2715                 if(sv_maxidle_slots > 0)
2716                 {
2717                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2718                         {
2719                                 ++totalClients;
2720                         });
2721                 }
2722
2723                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2724                 { /* do nothing */ }
2725                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2726                 {
2727                         if (CS(this).idlekick_lasttimeleft)
2728                         {
2729                                 CS(this).idlekick_lasttimeleft = 0;
2730                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2731                         }
2732                 }
2733                 else
2734                 {
2735                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2736                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2737                                 if (!CS(this).idlekick_lasttimeleft)
2738                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2739                         }
2740                         if (timeleft <= 0) {
2741                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2742                                 dropclient(this);
2743                                 return;
2744                         }
2745                         else if (timeleft <= 10) {
2746                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2747                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2748                 }
2749                                 CS(this).idlekick_lasttimeleft = timeleft;
2750                         }
2751                 }
2752         }
2753
2754         CheatFrame(this);
2755
2756         if (game_stopped)
2757         {
2758                 this.solid = SOLID_NOT;
2759                 this.takedamage = DAMAGE_NO;
2760                 set_movetype(this, MOVETYPE_NONE);
2761         }
2762
2763         if (IS_PLAYER(this)) {
2764                 DrownPlayer(this);
2765                 UpdateChatBubble(this);
2766                 if (CS(this).impulse) ImpulseCommands(this);
2767                 if (game_stopped)
2768                 {
2769                         CSQCMODEL_AUTOUPDATE(this);
2770                         return;
2771                 }
2772                 GetPressedKeys(this);
2773         }
2774
2775         if (this.waypointsprite_attachedforcarrier) {
2776             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2777                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2778     }
2779
2780         playerdemo_write(this);
2781
2782         CSQCMODEL_AUTOUPDATE(this);
2783 }
2784
2785 // hack to copy the button fields from the client entity to the Client State
2786 void PM_UpdateButtons(entity this, entity store)
2787 {
2788         if(this.impulse)
2789                 store.impulse = this.impulse;
2790         this.impulse = 0;
2791
2792         store.button0 = this.button0;
2793         store.button2 = this.button2;
2794         store.button3 = this.button3;
2795         store.button4 = this.button4;
2796         store.button5 = this.button5;
2797         store.button6 = this.button6;
2798         store.button7 = this.button7;
2799         store.button8 = this.button8;
2800         store.button9 = this.button9;
2801         store.button10 = this.button10;
2802         store.button11 = this.button11;
2803         store.button12 = this.button12;
2804         store.button13 = this.button13;
2805         store.button14 = this.button14;
2806         store.button15 = this.button15;
2807         store.button16 = this.button16;
2808         store.buttonuse = this.buttonuse;
2809         store.buttonchat = this.buttonchat;
2810
2811         store.cursor_active = this.cursor_active;
2812         store.cursor_screen = this.cursor_screen;
2813         store.cursor_trace_start = this.cursor_trace_start;
2814         store.cursor_trace_endpos = this.cursor_trace_endpos;
2815         store.cursor_trace_ent = this.cursor_trace_ent;
2816
2817         store.ping = this.ping;
2818         store.ping_packetloss = this.ping_packetloss;
2819         store.ping_movementloss = this.ping_movementloss;
2820
2821         store.v_angle = this.v_angle;
2822         store.movement = this.movement;
2823 }