qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/common.qh>
  56 #include <server/command/vote.qh>
  57 #include <server/compat/quake3.qh>
  58 #include <server/damage.qh>
  59 #include <server/gamelog.qh>
  60 #include <server/handicap.qh>
  61 #include <server/hook.qh>
  62 #include <server/impulse.qh>
  63 #include <server/intermission.qh>
  64 #include <server/ipban.qh>
  65 #include <server/main.qh>
  66 #include <server/mutators/_mod.qh>
  67 #include <server/player.qh>
  68 #include <server/portals.qh>
  69 #include <server/race.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 142                                         sf |= BIT(4); // show spectators
 143
 144         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 145         WriteByte(MSG_ENTITY, sf);
 146
 147         if (sf & BIT(1))
 148                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 149
 150         if(sf & BIT(4))
 151         {
 152                 float specs = CountSpectators(e, to);
 153                 WriteByte(MSG_ENTITY, specs);
 154                 WriteSpectators(e, to);
 155         }
 156
 157         return true;
 158 }
 159
 160 void ClientData_Attach(entity this)
 161 {
 162         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 163         CS(this).clientdata.drawonlytoclient = this;
 164         CS(this).clientdata.owner = this;
 165 }
 166
 167 void ClientData_Detach(entity this)
 168 {
 169         delete(CS(this).clientdata);
 170         CS(this).clientdata = NULL;
 171 }
 172
 173 void ClientData_Touch(entity e)
 174 {
 175         entity cd = CS(e).clientdata;
 176         if (cd) { cd.SendFlags = 1; }
 177
 178         // make it spectatable
 179         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 180         {
 181                 entity cd = CS(it).clientdata;
 182                 if (cd) { cd.SendFlags = 1; }
 183         });
 184 }
 185
 186
 187 /*
 188 =============
 189 CheckPlayerModel
 190
 191 Checks if the argument string can be a valid playermodel.
 192 Returns a valid one in doubt.
 193 =============
 194 */
 195 string FallbackPlayerModel;
 196 string CheckPlayerModel(string plyermodel) {
 197         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 198         {
 199                 // note: we cannot summon Don Strunzone here, some player may
 200                 // still have the model string set. In case anyone manages how
 201                 // to change a cvar default, we'll have a small leak here.
 202                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 203         }
 204         // only in right path
 205         if(substring(plyermodel, 0, 14) != "models/player/")
 206                 return FallbackPlayerModel;
 207         // only good file extensions
 208         if(substring(plyermodel, -4, 4) != ".iqm"
 209                 && substring(plyermodel, -4, 4) != ".zym"
 210                 && substring(plyermodel, -4, 4) != ".dpm"
 211                 && substring(plyermodel, -4, 4) != ".md3"
 212                 && substring(plyermodel, -4, 4) != ".psk")
 213         {
 214                 return FallbackPlayerModel;
 215         }
 216         // forbid the LOD models
 217         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 218                 return FallbackPlayerModel;
 219         if(plyermodel != strtolower(plyermodel))
 220                 return FallbackPlayerModel;
 221         // also, restrict to server models
 222         if(autocvar_sv_servermodelsonly)
 223         {
 224                 if(!fexists(plyermodel))
 225                         return FallbackPlayerModel;
 226         }
 227         return plyermodel;
 228 }
 229
 230 void setplayermodel(entity e, string modelname)
 231 {
 232         precache_model(modelname);
 233         _setmodel(e, modelname);
 234         player_setupanimsformodel(e);
 235         if(!autocvar_g_debug_globalsounds)
 236                 UpdatePlayerSounds(e);
 237 }
 238
 239 /** putting a client as observer in the server */
 240 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 241 {
 242         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 243         bool recount_ready = false;
 244         PlayerState_detach(this);
 245
 246         if (IS_PLAYER(this))
 247         {
 248                 if(GetResource(this, RES_HEALTH) >= 1)
 249                 {
 250                         // despawn effect
 251                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 252                 }
 253
 254                 // was a player, recount votes and ready status
 255                 if(IS_REAL_CLIENT(this))
 256                 {
 257                         if (vote_called) { VoteCount(false); }
 258                         this.ready = false;
 259                         if (warmup_stage) recount_ready = true;
 260                 }
 261                 entcs_update_players(this);
 262         }
 263
 264         if (use_spawnpoint)
 265         {
 266                 entity spot = SelectSpawnPoint(this, true);
 267                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 268                 this.angles = vec2(spot.angles);
 269                 // offset it so that the spectator spawns higher off the ground, looks better this way
 270                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         }
 272         else // change origin to restore previous view origin
 273                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 274         this.fixangle = true;
 275
 276         if (IS_REAL_CLIENT(this))
 277         {
 278                 msg_entity = this;
 279                 WriteByte(MSG_ONE, SVC_SETVIEW);
 280                 WriteEntity(MSG_ONE, this);
 281         }
 282         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 283         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 284         if(!autocvar_g_debug_globalsounds)
 285         {
 286                 // needed for player sounds
 287                 this.model = "";
 288                 FixPlayermodel(this);
 289         }
 290         setmodel(this, MDL_Null);
 291         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 292         this.view_ofs = '0 0 0';
 293
 294         RemoveGrapplingHooks(this);
 295         Portal_ClearAll(this);
 296         Unfreeze(this, false);
 297         SetSpectatee(this, NULL);
 298
 299         if (this.alivetime)
 300         {
 301                 if (!warmup_stage)
 302                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 303                 this.alivetime = 0;
 304         }
 305
 306         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 307
 308         TRANSMUTE(Observer, this);
 309
 310         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 311
 312         WaypointSprite_PlayerDead(this);
 313         accuracy_resend(this);
 314
 315         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 316                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 317
 318         CS(this).spectatortime = time;
 319         if(this.bot_attack)
 320                 IL_REMOVE(g_bot_targets, this);
 321         this.bot_attack = false;
 322         if(this.monster_attack)
 323                 IL_REMOVE(g_monster_targets, this);
 324         this.monster_attack = false;
 325         STAT(HUD, this) = HUD_NORMAL;
 326         this.iscreature = false;
 327         this.teleportable = TELEPORT_SIMPLE;
 328         if(this.damagedbycontents)
 329                 IL_REMOVE(g_damagedbycontents, this);
 330         this.damagedbycontents = false;
 331         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 332         SetSpectatee_status(this, etof(this));
 333         this.takedamage = DAMAGE_NO;
 334         this.solid = SOLID_NOT;
 335         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 336         this.flags = FL_CLIENT | FL_NOTARGET;
 337         this.effects = 0;
 338         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 339         this.pauserotarmor_finished = 0;
 340         this.pauserothealth_finished = 0;
 341         this.pauseregen_finished = 0;
 342         this.damageforcescale = 0;
 343         this.death_time = 0;
 344         this.respawn_flags = 0;
 345         this.respawn_time = 0;
 346         STAT(RESPAWN_TIME, this) = 0;
 347         this.alpha = 0;
 348         this.scale = 0;
 349         this.fade_time = 0;
 350         this.pain_finished = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         player_powerups_remove_all(this);
 367         this.items = 0;
 368         STAT(WEAPONS, this) = '0 0 0';
 369         this.drawonlytoclient = this;
 370
 371         this.viewloc = NULL;
 372
 373         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 374
 375         this.weaponmodel = "";
 376         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 377         {
 378                 this.weaponentities[slot] = NULL;
 379         }
 380         this.exteriorweaponentity = NULL;
 381         CS(this).killcount = FRAGS_SPECTATOR;
 382         this.velocity = '0 0 0';
 383         this.avelocity = '0 0 0';
 384         this.punchangle = '0 0 0';
 385         this.punchvector = '0 0 0';
 386         this.oldvelocity = this.velocity;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void PutPlayerInServer(entity this)
 538 {
 539         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 540
 541         PlayerState_attach(this);
 542         accuracy_resend(this);
 543
 544         if (teamplay && this.bot_forced_team)
 545                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 546
 547         if (this.team < 0)
 548                 TeamBalance_JoinBestTeam(this);
 549
 550         entity spot = SelectSpawnPoint(this, false);
 551         if (!spot) {
 552                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 553                 return; // spawn failed
 554         }
 555
 556         TRANSMUTE(Player, this);
 557
 558         CS(this).wasplayer = true;
 559         this.iscreature = true;
 560         this.teleportable = TELEPORT_NORMAL;
 561         if(!this.damagedbycontents)
 562                 IL_PUSH(g_damagedbycontents, this);
 563         this.damagedbycontents = true;
 564         set_movetype(this, MOVETYPE_WALK);
 565         this.solid = SOLID_SLIDEBOX;
 566         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 567         if (autocvar_g_playerclip_collisions)
 568                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 569         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 570                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 571         this.frags = FRAGS_PLAYER;
 572         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 573         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 574         if (autocvar__notarget)
 575                 this.flags |= FL_NOTARGET;
 576         this.takedamage = DAMAGE_AIM;
 577         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 578
 579         if (warmup_stage) {
 580                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 581                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 582                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 583                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 584                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 585                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 586                 SetResource(this, RES_HEALTH, warmup_start_health);
 587                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 588                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 589         } else {
 590                 SetResource(this, RES_SHELLS, start_ammo_shells);
 591                 SetResource(this, RES_BULLETS, start_ammo_nails);
 592                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 593                 SetResource(this, RES_CELLS, start_ammo_cells);
 594                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 595                 SetResource(this, RES_FUEL, start_ammo_fuel);
 596                 SetResource(this, RES_HEALTH, start_health);
 597                 SetResource(this, RES_ARMOR, start_armorvalue);
 598                 STAT(WEAPONS, this) = start_weapons;
 599                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 600                 {
 601                         GiveRandomWeapons(this, random_start_weapons_count,
 602                                 autocvar_g_random_start_weapons, random_start_ammo);
 603                 }
 604         }
 605         SetSpectatee_status(this, 0);
 606
 607         PS(this).dual_weapons = '0 0 0';
 608
 609         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 610                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 611
 612         this.items = start_items;
 613
 614         float shieldtime = time + autocvar_g_spawnshieldtime;
 615
 616         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 617         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 618         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 619         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 620         if (!sv_ready_restart_after_countdown && time < game_starttime)
 621         {
 622                 float f = game_starttime - time;
 623                 shieldtime += f;
 624                 this.pauserotarmor_finished += f;
 625                 this.pauserothealth_finished += f;
 626                 this.pauseregen_finished += f;
 627         }
 628
 629         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 630
 631         this.damageforcescale = autocvar_g_player_damageforcescale;
 632         this.death_time = 0;
 633         this.respawn_flags = 0;
 634         this.respawn_time = 0;
 635         STAT(RESPAWN_TIME, this) = 0;
 636         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(REVIVE_PROGRESS, this) = 0;
 661         this.revival_time = 0;
 662
 663         STAT(AIR_FINISHED, this) = 0;
 664         this.waterlevel = WATERLEVEL_NONE;
 665         this.watertype = CONTENT_EMPTY;
 666
 667         entity spawnevent = new_pure(spawnevent);
 668         spawnevent.owner = this;
 669         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 670
 671         // Cut off any still running player sounds.
 672         stopsound(this, CH_PLAYER_SINGLE);
 673
 674         this.model = "";
 675         FixPlayermodel(this);
 676         this.drawonlytoclient = NULL;
 677
 678         this.viewloc = NULL;
 679
 680         for(int slot = 0; slot < MAX_AXH; ++slot)
 681         {
 682                 entity axh = this.(AuxiliaryXhair[slot]);
 683                 this.(AuxiliaryXhair[slot]) = NULL;
 684
 685                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 686                         delete(axh);
 687         }
 688
 689         this.spawnpoint_targ = NULL;
 690
 691         UNSET_DUCKED(this);
 692         this.view_ofs = STAT(PL_VIEW_OFS, this);
 693         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 694         this.spawnorigin = spot.origin;
 695         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 696         // don't reset back to last position, even if new position is stuck in solid
 697         this.oldorigin = this.origin;
 698         if(this.conveyor)
 699                 IL_REMOVE(g_conveyed, this);
 700         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 701         if(this.swampslug)
 702                 IL_REMOVE(g_swamped, this);
 703         this.swampslug = NULL;
 704         this.swamp_interval = 0;
 705         if(this.ladder_entity)
 706                 IL_REMOVE(g_ladderents, this);
 707         this.ladder_entity = NULL;
 708         IL_EACH(g_counters, it.realowner == this,
 709         {
 710                 delete(it);
 711         });
 712         STAT(HUD, this) = HUD_NORMAL;
 713
 714         this.event_damage = PlayerDamage;
 715         this.event_heal = PlayerHeal;
 716
 717         this.draggable = func_null;
 718
 719         if(!this.bot_attack)
 720                 IL_PUSH(g_bot_targets, this);
 721         this.bot_attack = true;
 722         if(!this.monster_attack)
 723                 IL_PUSH(g_monster_targets, this);
 724         this.monster_attack = true;
 725         navigation_dynamicgoal_init(this, false);
 726
 727         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 728
 729         // player was spectator
 730         if (CS(this).killcount == FRAGS_SPECTATOR) {
 731                 PlayerScore_Clear(this);
 732                 CS(this).killcount = 0;
 733                 CS(this).startplaytime = time;
 734         }
 735
 736         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 CL_SpawnWeaponentity(this, weaponentity);
 740         }
 741         this.alpha = default_player_alpha;
 742         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 743         this.exteriorweaponentity.alpha = default_weapon_alpha;
 744
 745         this.speedrunning = false;
 746
 747         this.counter_cnt = 0;
 748         this.fragsfilter_cnt = 0;
 749
 750         target_voicescript_clear(this);
 751
 752         // reset fields the weapons may use
 753         FOREACH(Weapons, true, {
 754                 it.wr_resetplayer(it, this);
 755                         // reload all reloadable weapons
 756                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 757                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758                         {
 759                                 .entity weaponentity = weaponentities[slot];
 760                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 761                         }
 762                 }
 763         });
 764
 765         Unfreeze(this, false);
 766
 767         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 768         {
 769                 string s = spot.target;
 770                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 771                         spot.target = string_null;
 772                 SUB_UseTargets(spot, this, NULL);
 773                 if(g_assault || g_race)
 774                         spot.target = s;
 775         }
 776
 777         if (autocvar_spawn_debug)
 778         {
 779                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 780                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 781         }
 782
 783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 784         {
 785                 .entity weaponentity = weaponentities[slot];
 786                 entity w_ent = this.(weaponentity);
 787                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 788                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 789                 else
 790                         w_ent.m_switchweapon = WEP_Null;
 791                 w_ent.m_weapon = WEP_Null;
 792                 w_ent.weaponname = "";
 793                 w_ent.m_switchingweapon = WEP_Null;
 794                 w_ent.cnt = -1;
 795         }
 796
 797         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 798
 799         if (CS(this).impulse) ImpulseCommands(this);
 800
 801         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 802         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 803         {
 804                 .entity weaponentity = weaponentities[slot];
 805                 W_WeaponFrame(this, weaponentity);
 806         }
 807
 808         if (!warmup_stage && !this.alivetime)
 809                 this.alivetime = time;
 810
 811         antilag_clear(this, CS(this));
 812
 813         if (warmup_stage == -1)
 814                 ReadyCount();
 815 }
 816
 817 /** Called when a client spawns in the server */
 818 void PutClientInServer(entity this)
 819 {
 820         if (IS_REAL_CLIENT(this)) {
 821                 msg_entity = this;
 822                 WriteByte(MSG_ONE, SVC_SETVIEW);
 823                 WriteEntity(MSG_ONE, this);
 824         }
 825         if (game_stopped)
 826                 TRANSMUTE(Observer, this);
 827
 828         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 829         SetSpectatee(this, NULL);
 830
 831         // reset player keys
 832         if(PS(this))
 833                 PS(this).itemkeys = 0;
 834
 835         MUTATOR_CALLHOOK(PutClientInServer, this);
 836
 837         if (IS_OBSERVER(this)) {
 838                 PutObserverInServer(this, false, use_spawnpoint);
 839         } else if (IS_PLAYER(this)) {
 840                 PutPlayerInServer(this);
 841         }
 842
 843         bot_relinkplayerlist();
 844 }
 845
 846 // TODO do we need all these fields, or should we stop autodetecting runtime
 847 // changes and just have a console command to update this?
 848 bool ClientInit_SendEntity(entity this, entity to, int sf)
 849 {
 850         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 851         return = true;
 852         msg_entity = to;
 853         // MSG_INIT replacement
 854         // TODO: make easier to use
 855         Registry_send_all();
 856         W_PROP_reload(MSG_ONE, to);
 857         ClientInit_misc(this);
 858         MUTATOR_CALLHOOK(Ent_Init);
 859 }
 860 void ClientInit_misc(entity this)
 861 {
 862         int channel = MSG_ONE;
 863         WriteHeader(channel, ENT_CLIENT_INIT);
 864         WriteByte(channel, g_nexball_meter_period * 32);
 865         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 866         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 867         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 869         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 870         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 871         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 873
 874         if(autocvar_sv_foginterval && world.fog != "")
 875                 WriteString(channel, world.fog);
 876         else
 877                 WriteString(channel, "");
 878         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 879         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 880         WriteByte(channel, serverflags);
 881         WriteCoord(channel, autocvar_g_trueaim_minrange);
 882 }
 883
 884 void ClientInit_CheckUpdate(entity this)
 885 {
 886         this.nextthink = time;
 887         if(this.count != autocvar_g_balance_armor_blockpercent)
 888         {
 889                 this.count = autocvar_g_balance_armor_blockpercent;
 890                 this.SendFlags |= 1;
 891         }
 892         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 893         {
 894                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 895                 this.SendFlags |= 1;
 896         }
 897 }
 898
 899 void ClientInit_Spawn()
 900 {
 901         entity e = new_pure(clientinit);
 902         setthink(e, ClientInit_CheckUpdate);
 903         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 904
 905         ClientInit_CheckUpdate(e);
 906 }
 907
 908 /*
 909 =============
 910 SetNewParms
 911 =============
 912 */
 913 void SetNewParms ()
 914 {
 915         // initialize parms for a new player
 916         parm1 = -(86400 * 366);
 917
 918         MUTATOR_CALLHOOK(SetNewParms);
 919 }
 920
 921 /*
 922 =============
 923 SetChangeParms
 924 =============
 925 */
 926 void SetChangeParms (entity this)
 927 {
 928         // save parms for level change
 929         parm1 = CS(this).parm_idlesince - time;
 930
 931         MUTATOR_CALLHOOK(SetChangeParms);
 932 }
 933
 934 /*
 935 =============
 936 DecodeLevelParms
 937 =============
 938 */
 939 void DecodeLevelParms(entity this)
 940 {
 941         // load parms
 942         CS(this).parm_idlesince = parm1;
 943         if (CS(this).parm_idlesince == -(86400 * 366))
 944                 CS(this).parm_idlesince = time;
 945
 946         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 947         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 948
 949         MUTATOR_CALLHOOK(DecodeLevelParms);
 950 }
 951
 952 void FixClientCvars(entity e)
 953 {
 954         // send prediction settings to the client
 955         if(autocvar_g_antilag == 3) // client side hitscan
 956                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 957         if(autocvar_sv_gentle)
 958                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 959
 960         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 961         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 962
 963         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 964
 965         MUTATOR_CALLHOOK(FixClientCvars, e);
 966 }
 967
 968 bool findinlist_abbrev(string tofind, string list)
 969 {
 970         if(list == "" || tofind == "")
 971                 return false; // empty list or search, just return
 972
 973         // this function allows abbreviated strings!
 974         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 975         {
 976                 return true;
 977         });
 978
 979         return false;
 980 }
 981
 982 bool PlayerInIPList(entity p, string iplist)
 983 {
 984         // some safety checks (never allow local?)
 985         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 986                 return false;
 987
 988         return findinlist_abbrev(p.netaddress, iplist);
 989 }
 990
 991 bool PlayerInIDList(entity p, string idlist)
 992 {
 993         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 994         if(!p.crypto_idfp)
 995                 return false;
 996
 997         return findinlist_abbrev(p.crypto_idfp, idlist);
 998 }
 999
1000 bool PlayerInList(entity player, string list)
1001 {
1002         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1003 }
1004
1005 #ifdef DP_EXT_PRECONNECT
1006 /*
1007 =============
1008 ClientPreConnect
1009
1010 Called once (not at each match start) when a client begins a connection to the server
1011 =============
1012 */
1013 void ClientPreConnect(entity this)
1014 {
1015         if(autocvar_sv_eventlog)
1016         {
1017                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1018                         this.playerid,
1019                         etof(this),
1020                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1021                 ));
1022         }
1023 }
1024 #endif
1025
1026 // NOTE csqc uses the active mutators list sent by this function
1027 // to understand which mutators are enabled
1028 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1029 void SendWelcomeMessage(entity this, int msg_type)
1030 {
1031         WriteByte(msg_type, boolean(autocvar_g_campaign));
1032         if (boolean(autocvar_g_campaign))
1033         {
1034                 WriteString(msg_type, Campaign_GetTitle());
1035                 WriteByte(msg_type, Campaign_GetLevelNum());
1036                 WriteString(msg_type, Campaign_GetMessage());
1037                 return;
1038         }
1039         WriteString(msg_type, autocvar_hostname);
1040         WriteString(msg_type, autocvar_g_xonoticversion);
1041         WriteByte(msg_type, CS(this).version_mismatch);
1042         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1043
1044         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1045         string modifications = M_ARGV(0, string);
1046
1047         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1048                 modifications = strcat(modifications, ", No start weapons");
1049         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1050                 modifications = strcat(modifications, ", Low gravity");
1051         if(g_weapon_stay && !g_cts)
1052                 modifications = strcat(modifications, ", Weapons stay");
1053         if(autocvar_g_jetpack)
1054                 modifications = strcat(modifications, ", Jetpack");
1055         modifications = substring(modifications, 2, strlen(modifications) - 2);
1056
1057         WriteString(msg_type, modifications);
1058
1059         WriteString(msg_type, g_weaponarena_list);
1060
1061         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1062         {
1063                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1064                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1065         }
1066
1067         WriteString(msg_type, cache_mutatormsg);
1068
1069         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1070 }
1071
1072 /**
1073 =============
1074 ClientConnect
1075
1076 Called when a client connects to the server
1077 =============
1078 */
1079 void ClientConnect(entity this)
1080 {
1081         if (Ban_MaybeEnforceBanOnce(this)) return;
1082         assert(!IS_CLIENT(this), return);
1083         this.flags |= FL_CLIENT;
1084         assert(player_count >= 0, player_count = 0);
1085
1086         TRANSMUTE(Client, this);
1087         CS(this).version_nagtime = time + 10 + random() * 10;
1088
1089         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1090
1091         bot_clientconnect(this);
1092
1093         Player_DetermineForcedTeam(this);
1094
1095         TRANSMUTE(Observer, this);
1096
1097         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1098
1099         // always track bots, don't ask for cl_allow_uidtracking
1100         if (IS_BOT_CLIENT(this))
1101                 PlayerStats_GameReport_AddPlayer(this);
1102         else
1103                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1104
1105         if (autocvar_sv_eventlog)
1106                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1107
1108         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1109
1110         stuffcmd(this, clientstuff, "\n");
1111         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1112
1113         FixClientCvars(this);
1114
1115         // get version info from player
1116         stuffcmd(this, "cmd clientversion $gameversion\n");
1117
1118         // notify about available teams
1119         if (teamplay)
1120         {
1121                 entity balance = TeamBalance_CheckAllowedTeams(this);
1122                 int t = TeamBalance_GetAllowedTeams(balance);
1123                 TeamBalance_Destroy(balance);
1124                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1125         }
1126         else
1127         {
1128                 stuffcmd(this, "set _teams_available 0\n");
1129         }
1130
1131         bot_relinkplayerlist();
1132
1133         CS(this).spectatortime = time;
1134         if (blockSpectators)
1135         {
1136                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1137         }
1138
1139         CS(this).jointime = time;
1140
1141         if (IS_REAL_CLIENT(this))
1142         {
1143                 if (g_weaponarena_weapons == WEPSET(TUBA))
1144                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1145                 // quickmenu file must be put in a subfolder with an unique name
1146                 // to reduce chances of overriding custom client quickmenus
1147                 if (waypointeditor_enabled)
1148                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1149                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1150                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1151         }
1152
1153         if (!autocvar_sv_foginterval && world.fog != "")
1154                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1155
1156         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1157                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1158                         send_CSQC_teamnagger();
1159
1160         CSQCMODEL_AUTOINIT(this);
1161
1162         CS(this).model_randomizer = random();
1163
1164         if (IS_REAL_CLIENT(this))
1165                 sv_notice_join(this);
1166
1167         this.move_qcphysics = autocvar_sv_qcphysics;
1168
1169         // update physics stats (players can spawn before physics runs)
1170         Physics_UpdateStats(this);
1171
1172         IL_EACH(g_initforplayer, it.init_for_player, {
1173                 it.init_for_player(it, this);
1174         });
1175
1176         Handicap_Initialize(this);
1177
1178         MUTATOR_CALLHOOK(ClientConnect, this);
1179
1180         if (player_count == 1)
1181                 localcmd("\nsv_hook_firstjoin\n");
1182 }
1183 /*
1184 =============
1185 ClientDisconnect
1186
1187 Called when a client disconnects from the server
1188 =============
1189 */
1190 .entity chatbubbleentity;
1191 void player_powerups_remove_all(entity this);
1192
1193 void ClientDisconnect(entity this)
1194 {
1195         assert(IS_CLIENT(this), return);
1196
1197         PlayerStats_GameReport_FinalizePlayer(this);
1198         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1199         if (CS(this).active_minigame) part_minigame(this);
1200         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1201
1202         if (autocvar_sv_eventlog)
1203                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1204
1205         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1206
1207         if(IS_SPEC(this))
1208                 SetSpectatee(this, NULL);
1209
1210         MUTATOR_CALLHOOK(ClientDisconnect, this);
1211
1212         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1213         strfree(CS_CVAR(this).weaponorder_byimpulse);
1214         ClientState_detach(this);
1215
1216         Portal_ClearAll(this);
1217
1218         Unfreeze(this, false);
1219
1220         RemoveGrapplingHooks(this);
1221
1222         // Here, everything has been done that requires this player to be a client.
1223
1224         this.flags &= ~FL_CLIENT;
1225
1226         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1227         if (this.killindicator) delete(this.killindicator);
1228
1229         IL_EACH(g_counters, it.realowner == this,
1230         {
1231                 delete(it);
1232         });
1233
1234         WaypointSprite_PlayerGone(this);
1235
1236         bot_relinkplayerlist();
1237
1238         strfree(this.clientstatus);
1239         if (this.personal) delete(this.personal);
1240
1241         this.playerid = 0;
1242         if (warmup_stage) ReadyCount();
1243         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1244
1245         player_powerups_remove_all(this); // stop powerup sound
1246
1247         ONREMOVE(this);
1248
1249         if (player_count == 0)
1250                 localcmd("\nsv_hook_lastleave\n");
1251 }
1252
1253 void ChatBubbleThink(entity this)
1254 {
1255         this.nextthink = time;
1256         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1257         {
1258                 if(this.owner) // but why can that ever be NULL?
1259                         this.owner.chatbubbleentity = NULL;
1260                 delete(this);
1261                 return;
1262         }
1263
1264         this.mdl = "";
1265
1266         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1267         {
1268                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1269                         this.mdl = "models/sprites/minigame_busy.iqm";
1270                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1271                         this.mdl = "models/misc/chatbubble.spr";
1272         }
1273
1274         if ( this.model != this.mdl )
1275                 _setmodel(this, this.mdl);
1276
1277 }
1278
1279 void UpdateChatBubble(entity this)
1280 {
1281         if (this.alpha < 0)
1282                 return;
1283         // spawn a chatbubble entity if needed
1284         if (!this.chatbubbleentity)
1285         {
1286                 this.chatbubbleentity = new(chatbubbleentity);
1287                 this.chatbubbleentity.owner = this;
1288                 this.chatbubbleentity.exteriormodeltoclient = this;
1289                 setthink(this.chatbubbleentity, ChatBubbleThink);
1290                 this.chatbubbleentity.nextthink = time;
1291                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1292                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1293                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1294                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1295                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1296                 //this.chatbubbleentity.model = "";
1297                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1298         }
1299 }
1300
1301 void calculate_player_respawn_time(entity this)
1302 {
1303         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1304                 return;
1305
1306         float gametype_setting_tmp;
1307         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1308         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1309         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1310         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1311         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1312         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1313
1314         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1315         if (teamplay)
1316         {
1317                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1318                         if(it.team == this.team)
1319                                 ++pcount;
1320                 });
1321                 if (sdelay_small_count == 0)
1322                         sdelay_small_count = 1;
1323                 if (sdelay_large_count == 0)
1324                         sdelay_large_count = 1;
1325         }
1326         else
1327         {
1328                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1329                         ++pcount;
1330                 });
1331                 if (sdelay_small_count == 0)
1332                 {
1333                         if (IS_INDEPENDENT_PLAYER(this))
1334                         {
1335                                 // Players play independently. No point in requiring enemies.
1336                                 sdelay_small_count = 1;
1337                         }
1338                         else
1339                         {
1340                                 // Players play AGAINST each other. Enemies required.
1341                                 sdelay_small_count = 2;
1342                         }
1343                 }
1344                 if (sdelay_large_count == 0)
1345                 {
1346                         if (IS_INDEPENDENT_PLAYER(this))
1347                         {
1348                                 // Players play independently. No point in requiring enemies.
1349                                 sdelay_large_count = 1;
1350                         }
1351                         else
1352                         {
1353                                 // Players play AGAINST each other. Enemies required.
1354                                 sdelay_large_count = 2;
1355                         }
1356                 }
1357         }
1358
1359         float sdelay;
1360
1361         if (pcount <= sdelay_small_count)
1362                 sdelay = sdelay_small;
1363         else if (pcount >= sdelay_large_count)
1364                 sdelay = sdelay_large;
1365         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1366                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1367
1368         if(waves)
1369                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1370         else
1371                 this.respawn_time = time + sdelay;
1372
1373         if(sdelay < sdelay_max)
1374                 this.respawn_time_max = time + sdelay_max;
1375         else
1376                 this.respawn_time_max = this.respawn_time;
1377
1378         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1379                 this.respawn_countdown = 10; // first number to count down from is 10
1380         else
1381                 this.respawn_countdown = -1; // do not count down
1382
1383         if(autocvar_g_forced_respawn)
1384                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1385 }
1386
1387 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1388 // added to the model skins
1389 /*void UpdateColorModHack()
1390 {
1391         float c;
1392         c = this.clientcolors & 15;
1393         // LordHavoc: only bothering to support white, green, red, yellow, blue
1394              if (!teamplay) this.colormod = '0 0 0';
1395         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1396         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1397         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1398         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1399         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1400         else this.colormod = '1 1 1';
1401 }*/
1402
1403 void respawn(entity this)
1404 {
1405         bool damagedbycontents_prev = this.damagedbycontents;
1406         if(this.alpha >= 0)
1407         {
1408                 if(autocvar_g_respawn_ghosts)
1409                 {
1410                         this.solid = SOLID_NOT;
1411                         this.takedamage = DAMAGE_NO;
1412                         this.damagedbycontents = false;
1413                         set_movetype(this, MOVETYPE_FLY);
1414                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1415                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1416                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1417                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1418                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1419                         if(autocvar_g_respawn_ghosts_time > 0)
1420                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1421                 }
1422                 else
1423                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1424         }
1425
1426         CopyBody(this, 1);
1427         this.damagedbycontents = damagedbycontents_prev;
1428
1429         this.effects |= EF_NODRAW; // prevent another CopyBody
1430         PutClientInServer(this);
1431 }
1432
1433 void play_countdown(entity this, float finished, Sound samp)
1434 {
1435         TC(Sound, samp);
1436         float time_left = finished - time;
1437         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1438                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1439 }
1440
1441 // it removes special powerups not handled by StatusEffects
1442 void player_powerups_remove_all(entity this)
1443 {
1444         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1445         {
1446                 // don't play the poweroff sound when the game restarts or the player disconnects
1447                 if (time > game_starttime + 1 && IS_CLIENT(this)
1448                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1449                 {
1450                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1451                 }
1452                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1453                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1454                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1455         }
1456 }
1457
1458 void player_powerups(entity this)
1459 {
1460         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1461                 this.modelflags |= MF_ROCKET;
1462         else
1463                 this.modelflags &= ~MF_ROCKET;
1464
1465         this.effects &= ~EF_NODEPTHTEST;
1466
1467         if (IS_DEAD(this))
1468                 player_powerups_remove_all(this);
1469
1470         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1471                 return;
1472
1473         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1474         int items_prev = this.items;
1475
1476         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1477         {
1478                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1479                 if (this.items & IT_SUPERWEAPON)
1480                 {
1481                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1482                         {
1483                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1484                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1485                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1486                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1487                         }
1488                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1489                         {
1490                                 // don't let them run out
1491                         }
1492                         else
1493                         {
1494                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1495                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1496                                 {
1497                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1498                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1499                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1500                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1501                                 }
1502                         }
1503                 }
1504                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1505                 {
1506                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1507                         {
1508                                 this.items = this.items | IT_SUPERWEAPON;
1509                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1510                                 {
1511                                         if(!g_cts)
1512                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1514                                 }
1515                         }
1516                         else
1517                         {
1518                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1519                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1520                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1521                         }
1522                 }
1523                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1524                 {
1525                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1526                 }
1527         }
1528
1529         if(autocvar_g_nodepthtestplayers)
1530                 this.effects = this.effects | EF_NODEPTHTEST;
1531
1532         if(autocvar_g_fullbrightplayers)
1533                 this.effects = this.effects | EF_FULLBRIGHT;
1534
1535         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1536 }
1537
1538 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1539 {
1540         if(current > stable)
1541                 return current;
1542         else if(current > stable - 0.25) // when close enough, "snap"
1543                 return stable;
1544         else
1545                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1546 }
1547
1548 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1549 {
1550         if(current < stable)
1551                 return current;
1552         else if(current < stable + 0.25) // when close enough, "snap"
1553                 return stable;
1554         else
1555                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1556 }
1557
1558 void RotRegen(entity this, Resource res, float limit_mod,
1559         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1560         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1561 {
1562         float old = GetResource(this, res);
1563         float current = old;
1564         if(current > rotstable)
1565         {
1566                 if(rotframetime > 0)
1567                 {
1568                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1569                         current = max(rotstable, current - rotlinear * rotframetime);
1570                 }
1571         }
1572         else if(current < regenstable)
1573         {
1574                 if(regenframetime > 0)
1575                 {
1576                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1577                         current = min(regenstable, current + regenlinear * regenframetime);
1578                 }
1579         }
1580
1581         float limit = GetResourceLimit(this, res) * limit_mod;
1582         if(current > limit)
1583                 current = limit;
1584
1585         if (current != old)
1586                 SetResource(this, res, current);
1587 }
1588
1589 void player_regen(entity this)
1590 {
1591         float max_mod, regen_mod, rot_mod, limit_mod;
1592         max_mod = regen_mod = rot_mod = limit_mod = 1;
1593
1594         float regen_health = autocvar_g_balance_health_regen;
1595         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1596         float regen_health_rot = autocvar_g_balance_health_rot;
1597         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1598         float regen_health_stable = autocvar_g_balance_health_regenstable;
1599         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1600         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1601                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1602         max_mod = M_ARGV(1, float);
1603         regen_mod = M_ARGV(2, float);
1604         rot_mod = M_ARGV(3, float);
1605         limit_mod = M_ARGV(4, float);
1606         regen_health = M_ARGV(5, float);
1607         regen_health_linear = M_ARGV(6, float);
1608         regen_health_rot = M_ARGV(7, float);
1609         regen_health_rotlinear = M_ARGV(8, float);
1610         regen_health_stable = M_ARGV(9, float);
1611         regen_health_rotstable = M_ARGV(10, float);
1612
1613         float rotstable, regenstable, rotframetime, regenframetime;
1614
1615         if(!mutator_returnvalue)
1616         if(!STAT(FROZEN, this))
1617         {
1618                 regenstable = autocvar_g_balance_armor_regenstable;
1619                 rotstable = autocvar_g_balance_armor_rotstable;
1620                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1621                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1622                 RotRegen(this, RES_ARMOR, limit_mod,
1623                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1624                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1625
1626                 // NOTE: max_mod is only applied to health
1627                 regenstable = regen_health_stable * max_mod;
1628                 rotstable = regen_health_rotstable * max_mod;
1629                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1630                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1631                 RotRegen(this, RES_HEALTH, limit_mod,
1632                         regenstable, regen_health, regen_health_linear, regenframetime,
1633                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1634         }
1635
1636         // if player rotted to death...  die!
1637         // check this outside above checks, as player may still be able to rot to death
1638         if(GetResource(this, RES_HEALTH) < 1)
1639         {
1640                 if(this.vehicle)
1641                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1642                 if(this.event_damage)
1643                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1644         }
1645
1646         if (!(this.items & IT_UNLIMITED_AMMO))
1647         {
1648                 regenstable = autocvar_g_balance_fuel_regenstable;
1649                 rotstable = autocvar_g_balance_fuel_rotstable;
1650                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1651                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1652                 RotRegen(this, RES_FUEL, 1,
1653                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1654                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1655         }
1656 }
1657
1658 bool zoomstate_set;
1659 void SetZoomState(entity this, float newzoom)
1660 {
1661         if(newzoom != CS(this).zoomstate)
1662         {
1663                 CS(this).zoomstate = newzoom;
1664                 ClientData_Touch(this);
1665         }
1666         zoomstate_set = true;
1667 }
1668
1669 void GetPressedKeys(entity this)
1670 {
1671         MUTATOR_CALLHOOK(GetPressedKeys, this);
1672         if (game_stopped)
1673         {
1674                 CS(this).pressedkeys = 0;
1675                 STAT(PRESSED_KEYS, this) = 0;
1676                 return;
1677         }
1678
1679         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1680         int keys = STAT(PRESSED_KEYS, this);
1681         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1682         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1683         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1684         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1685
1686         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1687         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1688         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1689         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1690         CS(this).pressedkeys = keys; // store for other users
1691
1692         STAT(PRESSED_KEYS, this) = keys;
1693 }
1694
1695 /*
1696 ======================
1697 spectate mode routines
1698 ======================
1699 */
1700
1701 void SpectateCopy(entity this, entity spectatee)
1702 {
1703         TC(Client, this); TC(Client, spectatee);
1704
1705         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1706         PS(this) = PS(spectatee);
1707         this.armortype = spectatee.armortype;
1708         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1709         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1710         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1711         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1712         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1713         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1714         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1715         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1716         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1717         CS(this).impulse = 0;
1718         this.disableclientprediction = 1; // no need to run prediction on a spectator
1719         this.items = spectatee.items;
1720         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1721         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1722         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1723         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1724         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1725         this.punchangle = spectatee.punchangle;
1726         this.view_ofs = spectatee.view_ofs;
1727         this.velocity = spectatee.velocity;
1728         this.dmg_take = spectatee.dmg_take;
1729         this.dmg_save = spectatee.dmg_save;
1730         this.dmg_inflictor = spectatee.dmg_inflictor;
1731         this.v_angle = spectatee.v_angle;
1732         this.angles = spectatee.v_angle;
1733         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1734         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1735         this.viewloc = spectatee.viewloc;
1736         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1737                 this.fixangle = true;
1738         setorigin(this, spectatee.origin);
1739         setsize(this, spectatee.mins, spectatee.maxs);
1740         SetZoomState(this, CS(spectatee).zoomstate);
1741
1742     anticheat_spectatecopy(this, spectatee);
1743         STAT(HUD, this) = STAT(HUD, spectatee);
1744         if(spectatee.vehicle)
1745     {
1746         this.angles = spectatee.v_angle;
1747
1748         //this.fixangle = false;
1749         //this.velocity = spectatee.vehicle.velocity;
1750         this.vehicle_health = spectatee.vehicle_health;
1751         this.vehicle_shield = spectatee.vehicle_shield;
1752         this.vehicle_energy = spectatee.vehicle_energy;
1753         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1754         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1755         this.vehicle_reload1 = spectatee.vehicle_reload1;
1756         this.vehicle_reload2 = spectatee.vehicle_reload2;
1757
1758         //msg_entity = this;
1759
1760        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1761             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1762            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1763            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1764
1765         //WriteByte (MSG_ONE, SVC_SETVIEW);
1766         //    WriteEntity(MSG_ONE, this);
1767         //makevectors(spectatee.v_angle);
1768         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1769     }
1770 }
1771
1772 bool SpectateUpdate(entity this)
1773 {
1774         if(!this.enemy)
1775                 return false;
1776
1777         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1778         {
1779                 SetSpectatee(this, NULL);
1780                 return false;
1781         }
1782
1783         SpectateCopy(this, this.enemy);
1784
1785         return true;
1786 }
1787
1788 bool SpectateSet(entity this)
1789 {
1790         if(!IS_PLAYER(this.enemy))
1791                 return false;
1792
1793         ClientData_Touch(this.enemy);
1794
1795         msg_entity = this;
1796         WriteByte(MSG_ONE, SVC_SETVIEW);
1797         WriteEntity(MSG_ONE, this.enemy);
1798         set_movetype(this, MOVETYPE_NONE);
1799         accuracy_resend(this);
1800
1801         if(!SpectateUpdate(this))
1802                 PutObserverInServer(this, false, true);
1803
1804         return true;
1805 }
1806
1807 void SetSpectatee_status(entity this, int spectatee_num)
1808 {
1809         int oldspectatee_status = CS(this).spectatee_status;
1810         CS(this).spectatee_status = spectatee_num;
1811
1812         if (CS(this).spectatee_status != oldspectatee_status)
1813         {
1814                 if (STAT(PRESSED_KEYS, this))
1815                 {
1816                         CS(this).pressedkeys = 0;
1817                         STAT(PRESSED_KEYS, this) = 0;
1818                 }
1819                 ClientData_Touch(this);
1820                 if (g_race || g_cts) race_InitSpectator();
1821         }
1822 }
1823
1824 void SetSpectatee(entity this, entity spectatee)
1825 {
1826         if(IS_BOT_CLIENT(this))
1827                 return; // bots abuse .enemy, this code is useless to them
1828
1829         entity old_spectatee = this.enemy;
1830
1831         this.enemy = spectatee;
1832
1833         // WEAPONTODO
1834         // these are required to fix the spectator bug with arc
1835         if(old_spectatee)
1836         {
1837                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1838                 {
1839                         .entity weaponentity = weaponentities[slot];
1840                         if(old_spectatee.(weaponentity).arc_beam)
1841                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1842                 }
1843         }
1844         if(spectatee)
1845         {
1846                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1847                 {
1848                         .entity weaponentity = weaponentities[slot];
1849                         if(spectatee.(weaponentity).arc_beam)
1850                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1851                 }
1852         }
1853
1854         if (spectatee)
1855                 SetSpectatee_status(this, etof(spectatee));
1856
1857         // needed to update spectator list
1858         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1859 }
1860
1861 bool Spectate(entity this, entity pl)
1862 {
1863         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1864                 return false;
1865         pl = M_ARGV(1, entity);
1866
1867         SetSpectatee(this, pl);
1868         return SpectateSet(this);
1869 }
1870
1871 bool SpectateNext(entity this)
1872 {
1873         entity ent = find(this.enemy, classname, STR_PLAYER);
1874
1875         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1876                 ent = M_ARGV(1, entity);
1877         else if (!ent)
1878                 ent = find(ent, classname, STR_PLAYER);
1879
1880         if(ent) { SetSpectatee(this, ent); }
1881
1882         return SpectateSet(this);
1883 }
1884
1885 bool SpectatePrev(entity this)
1886 {
1887         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1888         entity ent = findchain(classname, STR_PLAYER);
1889         if (!ent) // no player
1890                 return false;
1891
1892         entity first = ent;
1893         // skip players until current spectated player
1894         if(this.enemy)
1895         while(ent && ent != this.enemy)
1896                 ent = ent.chain;
1897
1898         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1899         {
1900                 case MUT_SPECPREV_FOUND:
1901                         ent = M_ARGV(1, entity);
1902                         break;
1903                 case MUT_SPECPREV_RETURN:
1904                         return true;
1905                 case MUT_SPECPREV_CONTINUE:
1906                 default:
1907                 {
1908                         if(ent.chain)
1909                                 ent = ent.chain;
1910                         else
1911                                 ent = first;
1912                         break;
1913                 }
1914         }
1915
1916         SetSpectatee(this, ent);
1917         return SpectateSet(this);
1918 }
1919
1920 /*
1921 =============
1922 ShowRespawnCountdown()
1923
1924 Update a respawn countdown display.
1925 =============
1926 */
1927 void ShowRespawnCountdown(entity this)
1928 {
1929         float number;
1930         if(!IS_DEAD(this)) // just respawned?
1931                 return;
1932         else
1933         {
1934                 number = ceil(this.respawn_time - time);
1935                 if(number <= 0)
1936                         return;
1937                 if(number <= this.respawn_countdown)
1938                 {
1939                         this.respawn_countdown = number - 1;
1940                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1941                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1942                 }
1943         }
1944 }
1945
1946 .bool team_selected;
1947 bool ShowTeamSelection(entity this)
1948 {
1949         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1950                 return false;
1951         if (frametime) // once per frame is more than enough
1952                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1953         return true;
1954 }
1955 void Join(entity this)
1956 {
1957         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1958                 ReadyRestart(true);
1959
1960         TRANSMUTE(Player, this);
1961
1962         if(!this.team_selected)
1963         if(autocvar_g_campaign || autocvar_g_balance_teams)
1964                 TeamBalance_JoinBestTeam(this);
1965
1966         if(autocvar_g_campaign)
1967                 campaign_bots_may_start = true;
1968
1969         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1970
1971         PutClientInServer(this);
1972
1973         if(IS_PLAYER(this))
1974         if(teamplay && this.team != -1)
1975         {
1976         }
1977         else
1978                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1979         this.team_selected = false;
1980 }
1981
1982 int GetPlayerLimit()
1983 {
1984         if(g_duel)
1985                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1986         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
1987         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
1988         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1989         player_limit = M_ARGV(0, int);
1990         return player_limit < maxclients ? player_limit : 0;
1991 }
1992
1993 /**
1994  * Determines whether the player is allowed to join. This depends on cvar
1995  * g_maxplayers, if it isn't used this function always return true, otherwise
1996  * it checks whether the number of currently playing players exceeds g_maxplayers.
1997  * @return int number of free slots for players, 0 if none
1998  */
1999 int nJoinAllowed(entity this, entity ignore)
2000 {
2001         if(!ignore)
2002         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2003         // so report 0 free slots if restricted
2004         {
2005                 if(autocvar_g_forced_team_otherwise == "spectate")
2006                         return 0;
2007                 if(autocvar_g_forced_team_otherwise == "spectator")
2008                         return 0;
2009         }
2010
2011         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2012                 return 0; // forced spectators can never join
2013
2014         // TODO simplify this
2015         int totalClients = 0;
2016         int currentlyPlaying = 0;
2017         FOREACH_CLIENT(true, {
2018                 if(it != ignore)
2019                         ++totalClients;
2020                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2021                         ++currentlyPlaying;
2022         });
2023
2024         int player_limit = GetPlayerLimit();
2025
2026         int free_slots = 0;
2027         if (!player_limit)
2028                 free_slots = maxclients - totalClients;
2029         else if(player_limit > 0 && currentlyPlaying < player_limit)
2030                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2031
2032         static float msg_time = 0;
2033         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2034         {
2035                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2036                 msg_time = time + 0.5;
2037         }
2038
2039         return free_slots;
2040 }
2041
2042 bool joinAllowed(entity this)
2043 {
2044         if (CS(this).version_mismatch) return false;
2045         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2046         if (!nJoinAllowed(this, this)) return false;
2047         if (teamplay && lockteams) return false;
2048         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2049         if (ShowTeamSelection(this)) return false;
2050         return true;
2051 }
2052
2053 .string shootfromfixedorigin;
2054 .bool dualwielding_prev;
2055 bool PlayerThink(entity this)
2056 {
2057         if (game_stopped || intermission_running) {
2058                 this.modelflags &= ~MF_ROCKET;
2059                 if(intermission_running)
2060                         IntermissionThink(this);
2061                 return false;
2062         }
2063
2064         if (timeout_status == TIMEOUT_ACTIVE) {
2065                 // don't allow the player to turn around while game is paused
2066                 // FIXME turn this into CSQC stuff
2067                 this.v_angle = this.lastV_angle;
2068                 this.angles = this.lastV_angle;
2069                 this.fixangle = true;
2070         }
2071
2072         if (frametime) player_powerups(this);
2073
2074         if (IS_DEAD(this)) {
2075                 if (this.personal && g_race_qualifying) {
2076                         if (time > this.respawn_time) {
2077                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2078                                 respawn(this);
2079                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2080                         }
2081                 } else {
2082                         if (frametime) player_anim(this);
2083
2084                         if (this.respawn_flags & RESPAWN_DENY)
2085                         {
2086                                 STAT(RESPAWN_TIME, this) = 0;
2087                                 return false;
2088                         }
2089
2090                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2091
2092                         switch(this.deadflag)
2093                         {
2094                                 case DEAD_DYING:
2095                                 {
2096                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2097                                                 this.deadflag = DEAD_RESPAWNING;
2098                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2099                                                 this.deadflag = DEAD_DEAD;
2100                                         break;
2101                                 }
2102                                 case DEAD_DEAD:
2103                                 {
2104                                         if (button_pressed)
2105                                                 this.deadflag = DEAD_RESPAWNABLE;
2106                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2107                                                 this.deadflag = DEAD_RESPAWNING;
2108                                         break;
2109                                 }
2110                                 case DEAD_RESPAWNABLE:
2111                                 {
2112                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2113                                                 this.deadflag = DEAD_RESPAWNING;
2114                                         break;
2115                                 }
2116                                 case DEAD_RESPAWNING:
2117                                 {
2118                                         if (time > this.respawn_time)
2119                                         {
2120                                                 this.respawn_time = time + 1; // only retry once a second
2121                                                 this.respawn_time_max = this.respawn_time;
2122                                                 respawn(this);
2123                                         }
2124                                         break;
2125                                 }
2126                         }
2127
2128                         ShowRespawnCountdown(this);
2129
2130                         if (this.respawn_flags & RESPAWN_SILENT)
2131                                 STAT(RESPAWN_TIME, this) = 0;
2132                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2133                         {
2134                                 if (time < this.respawn_time)
2135                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2136                                 else if (this.deadflag != DEAD_RESPAWNING)
2137                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2138                         }
2139                         else
2140                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2141                 }
2142
2143                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2144                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2145                         STAT(RESPAWN_TIME, this) *= -1;
2146
2147                 return false;
2148         }
2149
2150         FixPlayermodel(this);
2151
2152         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2153                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2154                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2155         }
2156
2157         // reset gun alignment when dual wielding status changes
2158         // to ensure guns are always aligned right and left
2159         bool dualwielding = W_DualWielding(this);
2160         if(this.dualwielding_prev != dualwielding)
2161         {
2162                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2163                 this.dualwielding_prev = dualwielding;
2164         }
2165
2166         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2167         //if(frametime)
2168         {
2169                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2170                 {
2171                         .entity weaponentity = weaponentities[slot];
2172                         if(WEP_CVAR(vortex, charge_always))
2173                                 W_Vortex_Charge(this, weaponentity, frametime);
2174                         W_WeaponFrame(this, weaponentity);
2175                 }
2176         }
2177
2178         if (frametime)
2179         {
2180                 // WEAPONTODO: Add a weapon request for this
2181                 // rot vortex charge to the charge limit
2182                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2183                 {
2184                         .entity weaponentity = weaponentities[slot];
2185                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2186                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2187                 }
2188
2189                 player_regen(this);
2190                 player_anim(this);
2191                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2192         }
2193
2194         monsters_setstatus(this);
2195
2196         return true;
2197 }
2198
2199 .bool would_spectate;
2200 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2201 void ObserverOrSpectatorThink(entity this)
2202 {
2203         bool is_spec = IS_SPEC(this);
2204         if ( CS(this).impulse )
2205         {
2206                 int r = MinigameImpulse(this, CS(this).impulse);
2207                 if (!is_spec || r)
2208                         CS(this).impulse = 0;
2209
2210                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2211                 {
2212                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2213                         CS(this).impulse = 0;
2214                         return;
2215                 }
2216         }
2217
2218         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2219         {
2220                 CS(this).autojoin_checked = true;
2221                 TRANSMUTE(Player, this);
2222                 PutClientInServer(this);
2223                 return;
2224         }
2225
2226         if (this.flags & FL_JUMPRELEASED) {
2227                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2228                         this.flags &= ~FL_JUMPRELEASED;
2229                         this.flags |= FL_SPAWNING;
2230                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2231                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2232                         this.flags &= ~FL_JUMPRELEASED;
2233                         if(SpectateNext(this)) {
2234                                 TRANSMUTE(Spectator, this);
2235                         } else if (is_spec) {
2236                                 TRANSMUTE(Observer, this);
2237                                 PutClientInServer(this);
2238                         }
2239                         else
2240                                 this.would_spectate = false; // unable to spectate anyone
2241                         if (is_spec)
2242                                 CS(this).impulse = 0;
2243                 } else if (is_spec) {
2244                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2245                                 this.flags &= ~FL_JUMPRELEASED;
2246                                 if(SpectatePrev(this)) {
2247                                         TRANSMUTE(Spectator, this);
2248                                 } else {
2249                                         TRANSMUTE(Observer, this);
2250                                         PutClientInServer(this);
2251                                 }
2252                                 CS(this).impulse = 0;
2253                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2254                                 this.would_spectate = false;
2255                                 this.flags &= ~FL_JUMPRELEASED;
2256                                 TRANSMUTE(Observer, this);
2257                                 PutClientInServer(this);
2258                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2259                                 PutObserverInServer(this, false, true);
2260                                 this.would_spectate = true;
2261                         }
2262                 }
2263                 else {
2264                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2265                         if (PHYS_INPUT_BUTTON_USE(this))
2266                                 wouldclip = !wouldclip;
2267                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2268                         set_movetype(this, preferred_movetype);
2269                 }
2270         } else { // jump pressed
2271                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2272                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2273                         this.flags |= FL_JUMPRELEASED;
2274                         if(this.flags & FL_SPAWNING)
2275                         {
2276                                 this.flags &= ~FL_SPAWNING;
2277                                 if(joinAllowed(this))
2278                                         Join(this);
2279                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2280                                         CS(this).autojoin_checked = -1;
2281                                 return;
2282                         }
2283                 }
2284                 if(is_spec && !SpectateUpdate(this))
2285                         PutObserverInServer(this, false, true);
2286         }
2287         if (is_spec)
2288                 this.flags |= FL_CLIENT | FL_NOTARGET;
2289 }
2290
2291 void PlayerUseKey(entity this)
2292 {
2293         if (!IS_PLAYER(this))
2294                 return;
2295
2296         if(this.vehicle)
2297         {
2298                 if(!game_stopped)
2299                 {
2300                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2301                         return;
2302                 }
2303         }
2304         else if(autocvar_g_vehicles_enter)
2305         {
2306                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2307                 {
2308                         entity head, closest_target = NULL;
2309                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2310
2311                         while(head) // find the closest acceptable target to enter
2312                         {
2313                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2314                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2315                                 {
2316                                         if(closest_target)
2317                                         {
2318                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2319                                                 { closest_target = head; }
2320                                         }
2321                                         else { closest_target = head; }
2322                                 }
2323
2324                                 head = head.chain;
2325                         }
2326
2327                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2328                 }
2329         }
2330
2331         // a use key was pressed; call handlers
2332         MUTATOR_CALLHOOK(PlayerUseKey, this);
2333 }
2334
2335
2336 /*
2337 =============
2338 PlayerPreThink
2339
2340 Called every frame for each client before the physics are run
2341 =============
2342 */
2343 .float last_vehiclecheck;
2344 void PlayerPreThink (entity this)
2345 {
2346         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2347         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2348
2349         WarpZone_PlayerPhysics_FixVAngle(this);
2350
2351         if (frametime) {
2352                 // physics frames: update anticheat stuff
2353                 anticheat_prethink(this);
2354
2355                 // WORKAROUND: only use dropclient in server frames (frametime set).
2356                 // Never use it in cl_movement frames (frametime zero).
2357                 if (blockSpectators && IS_REAL_CLIENT(this)
2358                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2359                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2360                 {
2361                         if (dropclient_schedule(this))
2362                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2363                 }
2364         }
2365
2366         zoomstate_set = false;
2367
2368         // Check for nameless players
2369         if (this.netname == "" || this.netname != CS(this).netname_previous)
2370         {
2371                 bool assume_unchanged = (CS(this).netname_previous == "");
2372                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2373                 {
2374                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2375                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2376                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2377                         assume_unchanged = false;
2378                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2379                 }
2380                 if (isInvisibleString(this.netname))
2381                 {
2382                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2383                         sprint(this, "Warning: invisible names are not allowed.\n");
2384                         assume_unchanged = false;
2385                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2386                 }
2387                 if (!assume_unchanged && autocvar_sv_eventlog)
2388                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2389                 strcpy(CS(this).netname_previous, this.netname);
2390         }
2391
2392         // version nagging
2393         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2394         CS(this).version_nagtime = 0;
2395         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2396             // git client
2397         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2398             // git server
2399             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2400         } else {
2401             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2402             if (r < 0) { // old client
2403                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2404             } else if (r > 0) { // old server
2405                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2406             }
2407         }
2408     }
2409
2410         // GOD MODE info
2411         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2412         {
2413                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2414                 this.max_armorvalue = 0;
2415         }
2416
2417         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2418         {
2419                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2420                 {
2421                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2422                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2423                         if (this.iceblock)
2424                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2425
2426                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2427                                 Unfreeze(this, false);
2428                 }
2429                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2430                 {
2431                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2432                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2433
2434                         if (GetResource(this, RES_HEALTH) < 1)
2435                         {
2436                                 if (this.vehicle)
2437                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2438                                 if(this.event_damage)
2439                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2440                         }
2441                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2442                                 Unfreeze(this, false);
2443                 }
2444         }
2445
2446         MUTATOR_CALLHOOK(PlayerPreThink, this);
2447
2448         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2449         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2450         {
2451                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2452                 {
2453                         if(!it.owner)
2454                         {
2455                                 if(!it.team || SAME_TEAM(this, it))
2456                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2457                                 else if(autocvar_g_vehicles_steal)
2458                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2459                         }
2460                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2461                         {
2462                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2463                         }
2464                 });
2465
2466                 this.last_vehiclecheck = time + 1;
2467         }
2468
2469         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2470                 PlayerUseKey(this);
2471         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2472
2473         if (IS_PLAYER(this)) {
2474                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2475                         error("Client can't be spawned as player on connection!");
2476                 if(!PlayerThink(this))
2477                         return;
2478         }
2479         else if (game_stopped || intermission_running) {
2480                 if(intermission_running)
2481                         IntermissionThink(this);
2482                 return;
2483         }
2484         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2485         {
2486                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2487                 CS(this).autojoin_checked = 1;
2488                 // don't do this in ClientConnect
2489                 // many things can go wrong if a client is spawned as player on connection
2490                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2491                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2492                                 && (!teamplay || autocvar_g_balance_teams)))
2493                 {
2494                         if(joinAllowed(this))
2495                                 Join(this);
2496                         return;
2497                 }
2498         }
2499         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2500                 ObserverOrSpectatorThink(this);
2501         }
2502
2503         // WEAPONTODO: Add weapon request for this
2504         if (!zoomstate_set) {
2505                 bool wep_zoomed = false;
2506                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2507                 {
2508                         .entity weaponentity = weaponentities[slot];
2509                         Weapon thiswep = this.(weaponentity).m_weapon;
2510                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2511                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2512                 }
2513                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2514         }
2515
2516         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2517         {
2518                 CS(this).teamkill_soundtime = 0;
2519
2520                 entity e = CS(this).teamkill_soundsource;
2521                 entity oldpusher = e.pusher;
2522                 e.pusher = this;
2523                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2524                 e.pusher = oldpusher;
2525         }
2526
2527         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2528                 CS(this).taunt_soundtime = 0;
2529                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2530         }
2531
2532         target_voicescript_next(this);
2533 }
2534
2535 void DrownPlayer(entity this)
2536 {
2537         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2538                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2539         {
2540                 STAT(AIR_FINISHED, this) = 0;
2541                 return;
2542         }
2543
2544         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2545         {
2546                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2547                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2548                 STAT(AIR_FINISHED, this) = 0;
2549         }
2550         else
2551         {
2552                 if (!STAT(AIR_FINISHED, this))
2553                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2554                 if (STAT(AIR_FINISHED, this) < time)
2555                 {       // drown!
2556                         if (this.pain_finished < time)
2557                         {
2558                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2559                                 this.pain_finished = time + 0.5;
2560                         }
2561                 }
2562         }
2563 }
2564
2565 .bool move_qcphysics;
2566
2567 void Player_Physics(entity this)
2568 {
2569         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2570
2571         if(!this.move_qcphysics)
2572                 return;
2573
2574         if(!frametime && !CS(this).pm_frametime)
2575                 return;
2576
2577         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2578
2579         CS(this).pm_frametime = 0;
2580 }
2581
2582 /*
2583 =============
2584 PlayerPostThink
2585
2586 Called every frame for each client after the physics are run
2587 =============
2588 */
2589 void PlayerPostThink (entity this)
2590 {
2591         Player_Physics(this);
2592
2593         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2594         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2595         if (IS_REAL_CLIENT(this))
2596         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2597         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2598         {
2599                 int totalClients = 0;
2600                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2601                 {
2602                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2603                         if (server_is_dedicated)
2604                         {
2605                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2606                                 {
2607                                         ++totalClients;
2608                                 });
2609                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2610                                         totalClients = 0;
2611                         }
2612                 }
2613                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2614                 {
2615                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2616                         {
2617                                 ++totalClients;
2618                         });
2619                 }
2620
2621                 if (totalClients < autocvar_sv_maxidle_minplayers)
2622                 {
2623                         // idle kick disabled
2624                         CS(this).parm_idlesince = time;
2625                 }
2626                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2627                 {
2628                         if (CS(this).idlekick_lasttimeleft)
2629                         {
2630                                 CS(this).idlekick_lasttimeleft = 0;
2631                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2632                         }
2633                 }
2634                 else
2635                 {
2636                         float maxidle_time = autocvar_sv_maxidle;
2637                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2638                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2639                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2640                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2641                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2642                         {
2643                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2644                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2645                                 else
2646                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2647                         }
2648                         if (timeleft <= 0) {
2649                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2650                                 {
2651                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2652                                         PutObserverInServer(this, true, true);
2653                                 }
2654                                 else
2655                                 {
2656                                         if (dropclient_schedule(this))
2657                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2658                                 }
2659                                 return;
2660                         }
2661                         else if (timeleft <= countdown_time) {
2662                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2663                                         play2(this, SND(TALK2));
2664                                 CS(this).idlekick_lasttimeleft = timeleft;
2665                         }
2666                 }
2667         }
2668
2669         CheatFrame(this);
2670
2671         if (game_stopped)
2672         {
2673                 this.solid = SOLID_NOT;
2674                 this.takedamage = DAMAGE_NO;
2675                 set_movetype(this, MOVETYPE_NONE);
2676                 CS(this).teamkill_complain = 0;
2677                 CS(this).teamkill_soundtime = 0;
2678                 CS(this).teamkill_soundsource = NULL;
2679         }
2680
2681         if (IS_PLAYER(this)) {
2682                 if(this.death_time == time && IS_DEAD(this))
2683                 {
2684                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2685                         // once all the damage events of this frame have been processed with normal size
2686                         this.maxs.z = 5;
2687                         setsize(this, this.mins, this.maxs);
2688                 }
2689                 DrownPlayer(this);
2690                 UpdateChatBubble(this);
2691                 if (CS(this).impulse) ImpulseCommands(this);
2692                 GetPressedKeys(this);
2693                 if (game_stopped)
2694                 {
2695                         CSQCMODEL_AUTOUPDATE(this);
2696                         return;
2697                 }
2698         }
2699         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2700         {
2701                 CS(this).pressedkeys = 0;
2702                 STAT(PRESSED_KEYS, this) = 0;
2703         }
2704
2705         if (this.waypointsprite_attachedforcarrier) {
2706                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2707                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2708         }
2709
2710         CSQCMODEL_AUTOUPDATE(this);
2711 }
2712
2713 // hack to copy the button fields from the client entity to the Client State
2714 void PM_UpdateButtons(entity this, entity store)
2715 {
2716         if(this.impulse)
2717                 store.impulse = this.impulse;
2718         this.impulse = 0;
2719
2720         bool typing = this.buttonchat || this.button12;
2721
2722         store.button0 = (typing) ? 0 : this.button0;
2723         //button1?!
2724         store.button2 = (typing) ? 0 : this.button2;
2725         store.button3 = (typing) ? 0 : this.button3;
2726         store.button4 = this.button4;
2727         store.button5 = (typing) ? 0 : this.button5;
2728         store.button6 = this.button6;
2729         store.button7 = this.button7;
2730         store.button8 = this.button8;
2731         store.button9 = this.button9;
2732         store.button10 = this.button10;
2733         store.button11 = this.button11;
2734         store.button12 = this.button12;
2735         store.button13 = this.button13;
2736         store.button14 = this.button14;
2737         store.button15 = this.button15;
2738         store.button16 = this.button16;
2739         store.buttonuse = this.buttonuse;
2740         store.buttonchat = this.buttonchat;
2741
2742         store.cursor_active = this.cursor_active;
2743         store.cursor_screen = this.cursor_screen;
2744         store.cursor_trace_start = this.cursor_trace_start;
2745         store.cursor_trace_endpos = this.cursor_trace_endpos;
2746         store.cursor_trace_ent = this.cursor_trace_ent;
2747
2748         store.ping = this.ping;
2749         store.ping_packetloss = this.ping_packetloss;
2750         store.ping_movementloss = this.ping_movementloss;
2751
2752         store.v_angle = this.v_angle;
2753         store.movement = this.movement;
2754 }
2755
2756 NET_HANDLE(fpsreport, bool)
2757 {
2758         int fps = ReadShort();
2759         PlayerScore_Set(sender, SP_FPS, fps);
2760         return true;
2761 }