qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 141                                         sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 /** putting a client as observer in the server */
 239 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 240 {
 241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 242         bool recount_ready = false;
 243         PlayerState_detach(this);
 244
 245         if (IS_PLAYER(this))
 246         {
 247                 if(GetResource(this, RES_HEALTH) >= 1)
 248                 {
 249                         // despawn effect
 250                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 251                 }
 252
 253                 // was a player, recount votes and ready status
 254                 if(IS_REAL_CLIENT(this))
 255                 {
 256                         if (vote_called) { VoteCount(false); }
 257                         this.ready = false;
 258                         recount_ready = true;
 259                 }
 260                 entcs_update_players(this);
 261         }
 262
 263         if (use_spawnpoint)
 264         {
 265                 entity spot = SelectSpawnPoint(this, true);
 266                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 267                 this.angles = vec2(spot.angles);
 268                 // offset it so that the spectator spawns higher off the ground, looks better this way
 269                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 270         }
 271         else // change origin to restore previous view origin
 272                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 273         this.fixangle = true;
 274
 275         if (IS_REAL_CLIENT(this))
 276         {
 277                 msg_entity = this;
 278                 WriteByte(MSG_ONE, SVC_SETVIEW);
 279                 WriteEntity(MSG_ONE, this);
 280         }
 281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 283         if(!autocvar_g_debug_globalsounds)
 284         {
 285                 // needed for player sounds
 286                 this.model = "";
 287                 FixPlayermodel(this);
 288         }
 289         setmodel(this, MDL_Null);
 290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 291         this.view_ofs = '0 0 0';
 292
 293         RemoveGrapplingHooks(this);
 294         Portal_ClearAll(this);
 295         Unfreeze(this, false);
 296         SetSpectatee(this, NULL);
 297
 298         if (this.alivetime)
 299         {
 300                 if (!warmup_stage)
 301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 302                 this.alivetime = 0;
 303         }
 304
 305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 306
 307         TRANSMUTE(Observer, this);
 308
 309         if(recount_ready) ReadyCount();
 310
 311         WaypointSprite_PlayerDead(this);
 312         accuracy_resend(this);
 313
 314         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 315                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 316
 317         CS(this).spectatortime = time;
 318         if(this.bot_attack)
 319                 IL_REMOVE(g_bot_targets, this);
 320         this.bot_attack = false;
 321         if(this.monster_attack)
 322                 IL_REMOVE(g_monster_targets, this);
 323         this.monster_attack = false;
 324         STAT(HUD, this) = HUD_NORMAL;
 325         this.iscreature = false;
 326         this.teleportable = TELEPORT_SIMPLE;
 327         if(this.damagedbycontents)
 328                 IL_REMOVE(g_damagedbycontents, this);
 329         this.damagedbycontents = false;
 330         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 331         SetSpectatee_status(this, etof(this));
 332         this.takedamage = DAMAGE_NO;
 333         this.solid = SOLID_NOT;
 334         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 335         this.flags = FL_CLIENT | FL_NOTARGET;
 336         this.effects = 0;
 337         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 338         this.pauserotarmor_finished = 0;
 339         this.pauserothealth_finished = 0;
 340         this.pauseregen_finished = 0;
 341         this.damageforcescale = 0;
 342         this.death_time = 0;
 343         this.respawn_flags = 0;
 344         this.respawn_time = 0;
 345         STAT(RESPAWN_TIME, this) = 0;
 346         this.alpha = 0;
 347         this.scale = 0;
 348         this.fade_time = 0;
 349         this.pain_finished = 0;
 350         STAT(AIR_FINISHED, this) = 0;
 351         //this.dphitcontentsmask = 0;
 352         this.dphitcontentsmask = DPCONTENTS_SOLID;
 353         if (autocvar_g_playerclip_collisions)
 354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 355         this.pushltime = 0;
 356         this.istypefrag = 0;
 357         setthink(this, func_null);
 358         this.nextthink = 0;
 359         this.deadflag = DEAD_NO;
 360         UNSET_DUCKED(this);
 361         STAT(REVIVE_PROGRESS, this) = 0;
 362         this.revival_time = 0;
 363         this.draggable = drag_undraggable;
 364
 365         player_powerups_remove_all(this);
 366         this.items = 0;
 367         STAT(WEAPONS, this) = '0 0 0';
 368         this.drawonlytoclient = this;
 369
 370         this.viewloc = NULL;
 371
 372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 373
 374         this.weaponmodel = "";
 375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 this.weaponentities[slot] = NULL;
 378         }
 379         this.exteriorweaponentity = NULL;
 380         CS(this).killcount = FRAGS_SPECTATOR;
 381         this.velocity = '0 0 0';
 382         this.avelocity = '0 0 0';
 383         this.punchangle = '0 0 0';
 384         this.punchvector = '0 0 0';
 385         this.oldvelocity = this.velocity;
 386         this.event_damage = func_null;
 387         this.event_heal = func_null;
 388
 389         for(int slot = 0; slot < MAX_AXH; ++slot)
 390         {
 391                 entity axh = this.(AuxiliaryXhair[slot]);
 392                 this.(AuxiliaryXhair[slot]) = NULL;
 393
 394                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 395                         delete(axh);
 396         }
 397
 398         if (mutator_returnvalue)
 399         {
 400                 // mutator prevents resetting teams+score
 401         }
 402         else
 403         {
 404                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 405                 this.frags = FRAGS_SPECTATOR;
 406         }
 407
 408         bot_relinkplayerlist();
 409
 410         if (CS(this).just_joined)
 411                 CS(this).just_joined = false;
 412 }
 413
 414 int player_getspecies(entity this)
 415 {
 416         get_model_parameters(this.model, this.skin);
 417         int s = get_model_parameters_species;
 418         get_model_parameters(string_null, 0);
 419         if (s < 0) return SPECIES_HUMAN;
 420         return s;
 421 }
 422
 423 .float model_randomizer;
 424 void FixPlayermodel(entity player)
 425 {
 426         string defaultmodel = "";
 427         int defaultskin = 0;
 428         if(autocvar_sv_defaultcharacter)
 429         {
 430                 if(teamplay)
 431                 {
 432                         switch(player.team)
 433                         {
 434                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 435                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 436                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 437                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 438                         }
 439                 }
 440
 441                 if(defaultmodel == "")
 442                 {
 443                         defaultmodel = autocvar_sv_defaultplayermodel;
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445                 }
 446
 447                 int n = tokenize_console(defaultmodel);
 448                 if(n > 0)
 449                 {
 450                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 451                         // However, do NOT randomize if the player-selected model is in the list.
 452                         for (int i = 0; i < n; ++i)
 453                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 454                                         defaultmodel = argv(i);
 455                 }
 456
 457                 int i = strstrofs(defaultmodel, ":", 0);
 458                 if(i >= 0)
 459                 {
 460                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 461                         defaultmodel = substring(defaultmodel, 0, i);
 462                 }
 463         }
 464         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 465         {
 466                 if(teamplay)
 467                 {
 468                         switch(player.team)
 469                         {
 470                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 471                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 472                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 473                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 474                         }
 475                 }
 476
 477                 if(!defaultskin)
 478                         defaultskin = autocvar_sv_defaultplayerskin;
 479         }
 480
 481         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 482         defaultmodel = M_ARGV(0, string);
 483         defaultskin = M_ARGV(1, int);
 484
 485         bool chmdl = false;
 486         int oldskin;
 487         if(defaultmodel != "")
 488         {
 489                 if (defaultmodel != player.model)
 490                 {
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, defaultmodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 oldskin = player.skin;
 499                 player.skin = defaultskin;
 500         } else {
 501                 if (player.playermodel != player.model || player.playermodel == "")
 502                 {
 503                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 504                         vector m1 = player.mins;
 505                         vector m2 = player.maxs;
 506                         setplayermodel (player, player.playermodel);
 507                         setsize (player, m1, m2);
 508                         chmdl = true;
 509                 }
 510
 511                 if(!autocvar_sv_defaultcharacterskin)
 512                 {
 513                         oldskin = player.skin;
 514                         player.skin = stof(player.playerskin);
 515                 }
 516                 else
 517                 {
 518                         oldskin = player.skin;
 519                         player.skin = defaultskin;
 520                 }
 521         }
 522
 523         if(chmdl || oldskin != player.skin) // model or skin has changed
 524         {
 525                 player.species = player_getspecies(player); // update species
 526                 if(!autocvar_g_debug_globalsounds)
 527                         UpdatePlayerSounds(player); // update skin sounds
 528         }
 529
 530         if(!teamplay)
 531                 if(strlen(autocvar_sv_defaultplayercolors))
 532                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 533                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 534 }
 535
 536 void PutPlayerInServer(entity this)
 537 {
 538         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 539
 540         PlayerState_attach(this);
 541         accuracy_resend(this);
 542
 543         if (teamplay && this.bot_forced_team)
 544                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 545
 546         if (this.team < 0)
 547                 TeamBalance_JoinBestTeam(this);
 548
 549         entity spot = SelectSpawnPoint(this, false);
 550         if (!spot) {
 551                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 552                 return; // spawn failed
 553         }
 554
 555         TRANSMUTE(Player, this);
 556
 557         CS(this).wasplayer = true;
 558         this.iscreature = true;
 559         this.teleportable = TELEPORT_NORMAL;
 560         if(!this.damagedbycontents)
 561                 IL_PUSH(g_damagedbycontents, this);
 562         this.damagedbycontents = true;
 563         set_movetype(this, MOVETYPE_WALK);
 564         this.solid = SOLID_SLIDEBOX;
 565         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 566         if (autocvar_g_playerclip_collisions)
 567                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 568         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 569                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 570         this.frags = FRAGS_PLAYER;
 571         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 572         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 573         if (autocvar__notarget)
 574                 this.flags |= FL_NOTARGET;
 575         this.takedamage = DAMAGE_AIM;
 576         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 577
 578         if (warmup_stage) {
 579                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 580                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 581                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 582                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 583                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 584                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 585                 SetResource(this, RES_HEALTH, warmup_start_health);
 586                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 587                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 588         } else {
 589                 SetResource(this, RES_SHELLS, start_ammo_shells);
 590                 SetResource(this, RES_BULLETS, start_ammo_nails);
 591                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 592                 SetResource(this, RES_CELLS, start_ammo_cells);
 593                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 594                 SetResource(this, RES_FUEL, start_ammo_fuel);
 595                 SetResource(this, RES_HEALTH, start_health);
 596                 SetResource(this, RES_ARMOR, start_armorvalue);
 597                 STAT(WEAPONS, this) = start_weapons;
 598                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 599                 {
 600                         GiveRandomWeapons(this, random_start_weapons_count,
 601                                 autocvar_g_random_start_weapons, random_start_ammo);
 602                 }
 603         }
 604         SetSpectatee_status(this, 0);
 605
 606         PS(this).dual_weapons = '0 0 0';
 607
 608         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 609                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 610
 611         this.items = start_items;
 612
 613         float shieldtime = time + autocvar_g_spawnshieldtime;
 614
 615         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 616         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 617         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 618         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 619         if (!sv_ready_restart_after_countdown && time < game_starttime)
 620         {
 621                 float f = game_starttime - time;
 622                 shieldtime += f;
 623                 this.pauserotarmor_finished += f;
 624                 this.pauserothealth_finished += f;
 625                 this.pauseregen_finished += f;
 626         }
 627
 628         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 629
 630         this.damageforcescale = autocvar_g_player_damageforcescale;
 631         this.death_time = 0;
 632         this.respawn_flags = 0;
 633         this.respawn_time = 0;
 634         STAT(RESPAWN_TIME, this) = 0;
 635         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 636         this.fade_time = 0;
 637         this.pain_finished = 0;
 638         this.pushltime = 0;
 639         setthink(this, func_null); // players have no think function
 640         this.nextthink = 0;
 641         this.dmg_team = 0;
 642         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 643
 644         this.deadflag = DEAD_NO;
 645
 646         this.angles = spot.angles;
 647         this.angles_z = 0; // never spawn tilted even if the spot says to
 648         if (IS_BOT_CLIENT(this))
 649         {
 650                 this.v_angle = this.angles;
 651                 bot_aim_reset(this);
 652         }
 653         this.fixangle = true; // turn this way immediately
 654         this.oldvelocity = this.velocity = '0 0 0';
 655         this.avelocity = '0 0 0';
 656         this.punchangle = '0 0 0';
 657         this.punchvector = '0 0 0';
 658
 659         STAT(REVIVE_PROGRESS, this) = 0;
 660         this.revival_time = 0;
 661
 662         STAT(AIR_FINISHED, this) = 0;
 663         this.waterlevel = WATERLEVEL_NONE;
 664         this.watertype = CONTENT_EMPTY;
 665
 666         entity spawnevent = new_pure(spawnevent);
 667         spawnevent.owner = this;
 668         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 669
 670         // Cut off any still running player sounds.
 671         stopsound(this, CH_PLAYER_SINGLE);
 672
 673         this.model = "";
 674         FixPlayermodel(this);
 675         this.drawonlytoclient = NULL;
 676
 677         this.viewloc = NULL;
 678
 679         for(int slot = 0; slot < MAX_AXH; ++slot)
 680         {
 681                 entity axh = this.(AuxiliaryXhair[slot]);
 682                 this.(AuxiliaryXhair[slot]) = NULL;
 683
 684                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 685                         delete(axh);
 686         }
 687
 688         this.spawnpoint_targ = NULL;
 689
 690         UNSET_DUCKED(this);
 691         this.view_ofs = STAT(PL_VIEW_OFS, this);
 692         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 693         this.spawnorigin = spot.origin;
 694         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 695         // don't reset back to last position, even if new position is stuck in solid
 696         this.oldorigin = this.origin;
 697         if(this.conveyor)
 698                 IL_REMOVE(g_conveyed, this);
 699         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 700         if(this.swampslug)
 701                 IL_REMOVE(g_swamped, this);
 702         this.swampslug = NULL;
 703         this.swamp_interval = 0;
 704         if(this.ladder_entity)
 705                 IL_REMOVE(g_ladderents, this);
 706         this.ladder_entity = NULL;
 707         IL_EACH(g_counters, it.realowner == this,
 708         {
 709                 delete(it);
 710         });
 711         STAT(HUD, this) = HUD_NORMAL;
 712
 713         this.event_damage = PlayerDamage;
 714         this.event_heal = PlayerHeal;
 715
 716         this.draggable = func_null;
 717
 718         if(!this.bot_attack)
 719                 IL_PUSH(g_bot_targets, this);
 720         this.bot_attack = true;
 721         if(!this.monster_attack)
 722                 IL_PUSH(g_monster_targets, this);
 723         this.monster_attack = true;
 724         navigation_dynamicgoal_init(this, false);
 725
 726         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 727
 728         // player was spectator
 729         if (CS(this).killcount == FRAGS_SPECTATOR) {
 730                 PlayerScore_Clear(this);
 731                 CS(this).killcount = 0;
 732                 CS(this).startplaytime = time;
 733         }
 734
 735         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 736         {
 737                 .entity weaponentity = weaponentities[slot];
 738                 CL_SpawnWeaponentity(this, weaponentity);
 739         }
 740         this.alpha = default_player_alpha;
 741         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 742         this.exteriorweaponentity.alpha = default_weapon_alpha;
 743
 744         this.speedrunning = false;
 745
 746         this.counter_cnt = 0;
 747         this.fragsfilter_cnt = 0;
 748
 749         target_voicescript_clear(this);
 750
 751         // reset fields the weapons may use
 752         FOREACH(Weapons, true, {
 753                 it.wr_resetplayer(it, this);
 754                         // reload all reloadable weapons
 755                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 756                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 757                         {
 758                                 .entity weaponentity = weaponentities[slot];
 759                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 760                         }
 761                 }
 762         });
 763
 764         Unfreeze(this, false);
 765
 766         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 767         {
 768                 string s = spot.target;
 769                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 770                         spot.target = string_null;
 771                 SUB_UseTargets(spot, this, NULL);
 772                 if(g_assault || g_race)
 773                         spot.target = s;
 774         }
 775
 776         if (autocvar_spawn_debug)
 777         {
 778                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 779                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 780         }
 781
 782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 783         {
 784                 .entity weaponentity = weaponentities[slot];
 785                 entity w_ent = this.(weaponentity);
 786                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 787                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 788                 else
 789                         w_ent.m_switchweapon = WEP_Null;
 790                 w_ent.m_weapon = WEP_Null;
 791                 w_ent.weaponname = "";
 792                 w_ent.m_switchingweapon = WEP_Null;
 793                 w_ent.cnt = -1;
 794         }
 795
 796         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 797
 798         if (CS(this).impulse) ImpulseCommands(this);
 799
 800         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 801         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 802         {
 803                 .entity weaponentity = weaponentities[slot];
 804                 W_WeaponFrame(this, weaponentity);
 805         }
 806
 807         if (!warmup_stage && !this.alivetime)
 808                 this.alivetime = time;
 809
 810         antilag_clear(this, CS(this));
 811 }
 812
 813 /** Called when a client spawns in the server */
 814 void PutClientInServer(entity this)
 815 {
 816         if (IS_REAL_CLIENT(this)) {
 817                 msg_entity = this;
 818                 WriteByte(MSG_ONE, SVC_SETVIEW);
 819                 WriteEntity(MSG_ONE, this);
 820         }
 821         if (game_stopped)
 822                 TRANSMUTE(Observer, this);
 823
 824         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 825         SetSpectatee(this, NULL);
 826
 827         // reset player keys
 828         if(PS(this))
 829                 PS(this).itemkeys = 0;
 830
 831         MUTATOR_CALLHOOK(PutClientInServer, this);
 832
 833         if (IS_OBSERVER(this)) {
 834                 PutObserverInServer(this, false, use_spawnpoint);
 835         } else if (IS_PLAYER(this)) {
 836                 PutPlayerInServer(this);
 837         }
 838
 839         bot_relinkplayerlist();
 840 }
 841
 842 // TODO do we need all these fields, or should we stop autodetecting runtime
 843 // changes and just have a console command to update this?
 844 bool ClientInit_SendEntity(entity this, entity to, int sf)
 845 {
 846         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 847         return = true;
 848         msg_entity = to;
 849         // MSG_INIT replacement
 850         // TODO: make easier to use
 851         Registry_send_all();
 852         W_PROP_reload(MSG_ONE, to);
 853         ClientInit_misc(this);
 854         MUTATOR_CALLHOOK(Ent_Init);
 855 }
 856 void ClientInit_misc(entity this)
 857 {
 858         int channel = MSG_ONE;
 859         WriteHeader(channel, ENT_CLIENT_INIT);
 860         WriteByte(channel, g_nexball_meter_period * 32);
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 864         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 868         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 869
 870         if(autocvar_sv_foginterval && world.fog != "")
 871                 WriteString(channel, world.fog);
 872         else
 873                 WriteString(channel, "");
 874         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 875         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 876         WriteByte(channel, serverflags);
 877         WriteCoord(channel, autocvar_g_trueaim_minrange);
 878 }
 879
 880 void ClientInit_CheckUpdate(entity this)
 881 {
 882         this.nextthink = time;
 883         if(this.count != autocvar_g_balance_armor_blockpercent)
 884         {
 885                 this.count = autocvar_g_balance_armor_blockpercent;
 886                 this.SendFlags |= 1;
 887         }
 888         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 889         {
 890                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 891                 this.SendFlags |= 1;
 892         }
 893 }
 894
 895 void ClientInit_Spawn()
 896 {
 897         entity e = new_pure(clientinit);
 898         setthink(e, ClientInit_CheckUpdate);
 899         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 900
 901         ClientInit_CheckUpdate(e);
 902 }
 903
 904 /*
 905 =============
 906 SetNewParms
 907 =============
 908 */
 909 void SetNewParms ()
 910 {
 911         // initialize parms for a new player
 912         parm1 = -(86400 * 366);
 913
 914         MUTATOR_CALLHOOK(SetNewParms);
 915 }
 916
 917 /*
 918 =============
 919 SetChangeParms
 920 =============
 921 */
 922 void SetChangeParms (entity this)
 923 {
 924         // save parms for level change
 925         parm1 = CS(this).parm_idlesince - time;
 926
 927         MUTATOR_CALLHOOK(SetChangeParms);
 928 }
 929
 930 /*
 931 =============
 932 DecodeLevelParms
 933 =============
 934 */
 935 void DecodeLevelParms(entity this)
 936 {
 937         // load parms
 938         CS(this).parm_idlesince = parm1;
 939         if (CS(this).parm_idlesince == -(86400 * 366))
 940                 CS(this).parm_idlesince = time;
 941
 942         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 943         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 944
 945         MUTATOR_CALLHOOK(DecodeLevelParms);
 946 }
 947
 948 void FixClientCvars(entity e)
 949 {
 950         // send prediction settings to the client
 951         if(autocvar_g_antilag == 3) // client side hitscan
 952                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 953         if(autocvar_sv_gentle)
 954                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 955
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 957         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 958
 959         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 960
 961         MUTATOR_CALLHOOK(FixClientCvars, e);
 962 }
 963
 964 bool findinlist_abbrev(string tofind, string list)
 965 {
 966         if(list == "" || tofind == "")
 967                 return false; // empty list or search, just return
 968
 969         // this function allows abbreviated strings!
 970         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 971         {
 972                 return true;
 973         });
 974
 975         return false;
 976 }
 977
 978 bool PlayerInIPList(entity p, string iplist)
 979 {
 980         // some safety checks (never allow local?)
 981         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 982                 return false;
 983
 984         return findinlist_abbrev(p.netaddress, iplist);
 985 }
 986
 987 bool PlayerInIDList(entity p, string idlist)
 988 {
 989         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 990         if(!p.crypto_idfp)
 991                 return false;
 992
 993         return findinlist_abbrev(p.crypto_idfp, idlist);
 994 }
 995
 996 bool PlayerInList(entity player, string list)
 997 {
 998         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 999 }
1000
1001 #ifdef DP_EXT_PRECONNECT
1002 /*
1003 =============
1004 ClientPreConnect
1005
1006 Called once (not at each match start) when a client begins a connection to the server
1007 =============
1008 */
1009 void ClientPreConnect(entity this)
1010 {
1011         if(autocvar_sv_eventlog)
1012         {
1013                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1014                         this.playerid,
1015                         etof(this),
1016                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1017                 ));
1018         }
1019 }
1020 #endif
1021
1022 void SendWelcomemessage(entity this, bool force_centerprint)
1023 {
1024         msg_entity = this;
1025         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1026         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1027 }
1028
1029 // NOTE csqc uses the active mutators list sent by this function
1030 // to understand which mutators are enabled
1031 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1032 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1033 {
1034         WriteByte(msg_type, boolean(autocvar_g_campaign));
1035         if (boolean(autocvar_g_campaign))
1036         {
1037                 WriteString(msg_type, Campaign_GetTitle());
1038                 WriteByte(msg_type, Campaign_GetLevelNum());
1039                 WriteString(msg_type, Campaign_GetMessage());
1040                 return;
1041         }
1042         WriteByte(msg_type, force_centerprint);
1043         WriteString(msg_type, autocvar_hostname);
1044         WriteString(msg_type, autocvar_g_xonoticversion);
1045         WriteByte(msg_type, CS(this).version_mismatch);
1046         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1047
1048         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1049         string modifications = M_ARGV(0, string);
1050
1051         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1052                 modifications = strcat(modifications, ", No start weapons");
1053         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1054                 modifications = strcat(modifications, ", Low gravity");
1055         if(g_weapon_stay && !g_cts)
1056                 modifications = strcat(modifications, ", Weapons stay");
1057         if(autocvar_g_jetpack)
1058                 modifications = strcat(modifications, ", Jetpack");
1059         modifications = substring(modifications, 2, strlen(modifications) - 2);
1060
1061         WriteString(msg_type, modifications);
1062
1063         WriteString(msg_type, g_weaponarena_list);
1064
1065         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1066         {
1067                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1068                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1069         }
1070
1071         WriteString(msg_type, cache_mutatormsg);
1072
1073         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1074 }
1075
1076 /**
1077 =============
1078 ClientConnect
1079
1080 Called when a client connects to the server
1081 =============
1082 */
1083 void ClientConnect(entity this)
1084 {
1085         if (Ban_MaybeEnforceBanOnce(this)) return;
1086         assert(!IS_CLIENT(this), return);
1087         this.flags |= FL_CLIENT;
1088         assert(player_count >= 0, player_count = 0);
1089
1090         TRANSMUTE(Client, this);
1091         CS(this).version_nagtime = time + 10 + random() * 10;
1092
1093         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1094
1095         bot_clientconnect(this);
1096
1097         Player_DetermineForcedTeam(this);
1098
1099         TRANSMUTE(Observer, this);
1100
1101         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1102
1103         // always track bots, don't ask for cl_allow_uidtracking
1104         if (IS_BOT_CLIENT(this))
1105                 PlayerStats_GameReport_AddPlayer(this);
1106         else
1107                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1108
1109         if (autocvar_sv_eventlog)
1110                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1111
1112         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1113
1114         stuffcmd(this, clientstuff, "\n");
1115         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1116
1117         FixClientCvars(this);
1118
1119         // get version info from player
1120         stuffcmd(this, "cmd clientversion $gameversion\n");
1121
1122         // notify about available teams
1123         if (teamplay)
1124         {
1125                 entity balance = TeamBalance_CheckAllowedTeams(this);
1126                 int t = TeamBalance_GetAllowedTeams(balance);
1127                 TeamBalance_Destroy(balance);
1128                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1129         }
1130         else
1131         {
1132                 stuffcmd(this, "set _teams_available 0\n");
1133         }
1134
1135         bot_relinkplayerlist();
1136
1137         CS(this).spectatortime = time;
1138         if (blockSpectators)
1139         {
1140                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1141         }
1142
1143         CS(this).jointime = time;
1144
1145         if (IS_REAL_CLIENT(this))
1146         {
1147                 if (g_weaponarena_weapons == WEPSET(TUBA))
1148                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1149         }
1150
1151         if (!autocvar_sv_foginterval && world.fog != "")
1152                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1153
1154         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1155                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1156                         send_CSQC_teamnagger();
1157
1158         CSQCMODEL_AUTOINIT(this);
1159
1160         CS(this).model_randomizer = random();
1161
1162         if (IS_REAL_CLIENT(this))
1163                 sv_notice_join(this);
1164
1165         this.move_qcphysics = autocvar_sv_qcphysics;
1166
1167         // update physics stats (players can spawn before physics runs)
1168         Physics_UpdateStats(this);
1169
1170         IL_EACH(g_initforplayer, it.init_for_player, {
1171                 it.init_for_player(it, this);
1172         });
1173
1174         Handicap_Initialize(this);
1175
1176         MUTATOR_CALLHOOK(ClientConnect, this);
1177
1178         if (player_count == 1)
1179                 localcmd("\nsv_hook_firstjoin\n");
1180
1181         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1182                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1183 }
1184 /*
1185 =============
1186 ClientDisconnect
1187
1188 Called when a client disconnects from the server
1189 =============
1190 */
1191 .entity chatbubbleentity;
1192 void player_powerups_remove_all(entity this);
1193
1194 void ClientDisconnect(entity this)
1195 {
1196         assert(IS_CLIENT(this), return);
1197
1198         PlayerStats_GameReport_FinalizePlayer(this);
1199         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1200         if (CS(this).active_minigame) part_minigame(this);
1201         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1202
1203         if (autocvar_sv_eventlog)
1204                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1205
1206         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1207
1208         if(IS_SPEC(this))
1209                 SetSpectatee(this, NULL);
1210
1211         MUTATOR_CALLHOOK(ClientDisconnect, this);
1212
1213         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1214         strfree(CS_CVAR(this).weaponorder_byimpulse);
1215         ClientState_detach(this);
1216
1217         Portal_ClearAll(this);
1218
1219         Unfreeze(this, false);
1220
1221         RemoveGrapplingHooks(this);
1222
1223         // Here, everything has been done that requires this player to be a client.
1224
1225         this.flags &= ~FL_CLIENT;
1226
1227         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1228         if (this.killindicator) delete(this.killindicator);
1229
1230         IL_EACH(g_counters, it.realowner == this,
1231         {
1232                 delete(it);
1233         });
1234
1235         WaypointSprite_PlayerGone(this);
1236
1237         bot_relinkplayerlist();
1238
1239         strfree(this.clientstatus);
1240         if (this.personal) delete(this.personal);
1241
1242         this.playerid = 0;
1243         ReadyCount();
1244         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1245
1246         player_powerups_remove_all(this); // stop powerup sound
1247
1248         ONREMOVE(this);
1249
1250         if (player_count == 0)
1251                 localcmd("\nsv_hook_lastleave\n");
1252 }
1253
1254 void ChatBubbleThink(entity this)
1255 {
1256         this.nextthink = time;
1257         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1258         {
1259                 if(this.owner) // but why can that ever be NULL?
1260                         this.owner.chatbubbleentity = NULL;
1261                 delete(this);
1262                 return;
1263         }
1264
1265         this.mdl = "";
1266
1267         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1268         {
1269                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1270                         this.mdl = "models/sprites/minigame_busy.iqm";
1271                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1272                         this.mdl = "models/misc/chatbubble.spr";
1273         }
1274
1275         if ( this.model != this.mdl )
1276                 _setmodel(this, this.mdl);
1277
1278 }
1279
1280 void UpdateChatBubble(entity this)
1281 {
1282         if (this.alpha < 0)
1283                 return;
1284         // spawn a chatbubble entity if needed
1285         if (!this.chatbubbleentity)
1286         {
1287                 this.chatbubbleentity = new(chatbubbleentity);
1288                 this.chatbubbleentity.owner = this;
1289                 this.chatbubbleentity.exteriormodeltoclient = this;
1290                 setthink(this.chatbubbleentity, ChatBubbleThink);
1291                 this.chatbubbleentity.nextthink = time;
1292                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1293                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1294                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1295                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1296                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1297                 //this.chatbubbleentity.model = "";
1298                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1299         }
1300 }
1301
1302 void calculate_player_respawn_time(entity this)
1303 {
1304         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1305                 return;
1306
1307         float gametype_setting_tmp;
1308         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1309         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1310         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1311         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1312         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1313         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1314
1315         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1316         if (teamplay)
1317         {
1318                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1319                         if(it.team == this.team)
1320                                 ++pcount;
1321                 });
1322                 if (sdelay_small_count == 0)
1323                         sdelay_small_count = 1;
1324                 if (sdelay_large_count == 0)
1325                         sdelay_large_count = 1;
1326         }
1327         else
1328         {
1329                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1330                         ++pcount;
1331                 });
1332                 if (sdelay_small_count == 0)
1333                 {
1334                         if (IS_INDEPENDENT_PLAYER(this))
1335                         {
1336                                 // Players play independently. No point in requiring enemies.
1337                                 sdelay_small_count = 1;
1338                         }
1339                         else
1340                         {
1341                                 // Players play AGAINST each other. Enemies required.
1342                                 sdelay_small_count = 2;
1343                         }
1344                 }
1345                 if (sdelay_large_count == 0)
1346                 {
1347                         if (IS_INDEPENDENT_PLAYER(this))
1348                         {
1349                                 // Players play independently. No point in requiring enemies.
1350                                 sdelay_large_count = 1;
1351                         }
1352                         else
1353                         {
1354                                 // Players play AGAINST each other. Enemies required.
1355                                 sdelay_large_count = 2;
1356                         }
1357                 }
1358         }
1359
1360         float sdelay;
1361
1362         if (pcount <= sdelay_small_count)
1363                 sdelay = sdelay_small;
1364         else if (pcount >= sdelay_large_count)
1365                 sdelay = sdelay_large;
1366         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1367                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1368
1369         if(waves)
1370                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1371         else
1372                 this.respawn_time = time + sdelay;
1373
1374         if(sdelay < sdelay_max)
1375                 this.respawn_time_max = time + sdelay_max;
1376         else
1377                 this.respawn_time_max = this.respawn_time;
1378
1379         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1380                 this.respawn_countdown = 10; // first number to count down from is 10
1381         else
1382                 this.respawn_countdown = -1; // do not count down
1383
1384         if(autocvar_g_forced_respawn)
1385                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1386 }
1387
1388 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1389 // added to the model skins
1390 /*void UpdateColorModHack()
1391 {
1392         float c;
1393         c = this.clientcolors & 15;
1394         // LordHavoc: only bothering to support white, green, red, yellow, blue
1395              if (!teamplay) this.colormod = '0 0 0';
1396         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1397         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1398         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1399         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1400         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1401         else this.colormod = '1 1 1';
1402 }*/
1403
1404 void respawn(entity this)
1405 {
1406         bool damagedbycontents_prev = this.damagedbycontents;
1407         if(this.alpha >= 0)
1408         {
1409                 if(autocvar_g_respawn_ghosts)
1410                 {
1411                         this.solid = SOLID_NOT;
1412                         this.takedamage = DAMAGE_NO;
1413                         this.damagedbycontents = false;
1414                         set_movetype(this, MOVETYPE_FLY);
1415                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1416                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1417                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1418                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1419                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1420                         if(autocvar_g_respawn_ghosts_time > 0)
1421                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1422                 }
1423                 else
1424                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1425         }
1426
1427         CopyBody(this, 1);
1428         this.damagedbycontents = damagedbycontents_prev;
1429
1430         this.effects |= EF_NODRAW; // prevent another CopyBody
1431         PutClientInServer(this);
1432 }
1433
1434 void play_countdown(entity this, float finished, Sound samp)
1435 {
1436         TC(Sound, samp);
1437         float time_left = finished - time;
1438         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1439                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1440 }
1441
1442 // it removes special powerups not handled by StatusEffects
1443 void player_powerups_remove_all(entity this)
1444 {
1445         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1446         {
1447                 // don't play the poweroff sound when the game restarts or the player disconnects
1448                 if (time > game_starttime + 1 && IS_CLIENT(this)
1449                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1450                 {
1451                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1452                 }
1453                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1454                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1455                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1456         }
1457 }
1458
1459 void player_powerups(entity this)
1460 {
1461         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1462                 this.modelflags |= MF_ROCKET;
1463         else
1464                 this.modelflags &= ~MF_ROCKET;
1465
1466         this.effects &= ~EF_NODEPTHTEST;
1467
1468         if (IS_DEAD(this))
1469                 player_powerups_remove_all(this);
1470
1471         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1472                 return;
1473
1474         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1475         int items_prev = this.items;
1476
1477         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1478         {
1479                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1480                 if (this.items & IT_SUPERWEAPON)
1481                 {
1482                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1483                         {
1484                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1485                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1486                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1487                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1488                         }
1489                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1490                         {
1491                                 // don't let them run out
1492                         }
1493                         else
1494                         {
1495                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1496                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1497                                 {
1498                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1499                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1500                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1501                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1502                                 }
1503                         }
1504                 }
1505                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1506                 {
1507                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1508                         {
1509                                 this.items = this.items | IT_SUPERWEAPON;
1510                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1511                                 {
1512                                         if(!g_cts)
1513                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1514                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1515                                 }
1516                         }
1517                         else
1518                         {
1519                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1520                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1521                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1522                         }
1523                 }
1524                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1525                 {
1526                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1527                 }
1528         }
1529
1530         if(autocvar_g_nodepthtestplayers)
1531                 this.effects = this.effects | EF_NODEPTHTEST;
1532
1533         if(autocvar_g_fullbrightplayers)
1534                 this.effects = this.effects | EF_FULLBRIGHT;
1535
1536         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1537 }
1538
1539 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1540 {
1541         if(current > stable)
1542                 return current;
1543         else if(current > stable - 0.25) // when close enough, "snap"
1544                 return stable;
1545         else
1546                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1547 }
1548
1549 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1550 {
1551         if(current < stable)
1552                 return current;
1553         else if(current < stable + 0.25) // when close enough, "snap"
1554                 return stable;
1555         else
1556                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1557 }
1558
1559 void RotRegen(entity this, Resource res, float limit_mod,
1560         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1561         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1562 {
1563         float old = GetResource(this, res);
1564         float current = old;
1565         if(current > rotstable)
1566         {
1567                 if(rotframetime > 0)
1568                 {
1569                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1570                         current = max(rotstable, current - rotlinear * rotframetime);
1571                 }
1572         }
1573         else if(current < regenstable)
1574         {
1575                 if(regenframetime > 0)
1576                 {
1577                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1578                         current = min(regenstable, current + regenlinear * regenframetime);
1579                 }
1580         }
1581
1582         float limit = GetResourceLimit(this, res) * limit_mod;
1583         if(current > limit)
1584                 current = limit;
1585
1586         if (current != old)
1587                 SetResource(this, res, current);
1588 }
1589
1590 void player_regen(entity this)
1591 {
1592         float max_mod, regen_mod, rot_mod, limit_mod;
1593         max_mod = regen_mod = rot_mod = limit_mod = 1;
1594
1595         float regen_health = autocvar_g_balance_health_regen;
1596         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1597         float regen_health_rot = autocvar_g_balance_health_rot;
1598         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1599         float regen_health_stable = autocvar_g_balance_health_regenstable;
1600         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1601         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1602                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1603         max_mod = M_ARGV(1, float);
1604         regen_mod = M_ARGV(2, float);
1605         rot_mod = M_ARGV(3, float);
1606         limit_mod = M_ARGV(4, float);
1607         regen_health = M_ARGV(5, float);
1608         regen_health_linear = M_ARGV(6, float);
1609         regen_health_rot = M_ARGV(7, float);
1610         regen_health_rotlinear = M_ARGV(8, float);
1611         regen_health_stable = M_ARGV(9, float);
1612         regen_health_rotstable = M_ARGV(10, float);
1613
1614         float rotstable, regenstable, rotframetime, regenframetime;
1615
1616         if(!mutator_returnvalue)
1617         if(!STAT(FROZEN, this))
1618         {
1619                 regenstable = autocvar_g_balance_armor_regenstable;
1620                 rotstable = autocvar_g_balance_armor_rotstable;
1621                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1622                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1623                 RotRegen(this, RES_ARMOR, limit_mod,
1624                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1625                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1626
1627                 // NOTE: max_mod is only applied to health
1628                 regenstable = regen_health_stable * max_mod;
1629                 rotstable = regen_health_rotstable * max_mod;
1630                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1631                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1632                 RotRegen(this, RES_HEALTH, limit_mod,
1633                         regenstable, regen_health, regen_health_linear, regenframetime,
1634                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1635         }
1636
1637         // if player rotted to death...  die!
1638         // check this outside above checks, as player may still be able to rot to death
1639         if(GetResource(this, RES_HEALTH) < 1)
1640         {
1641                 if(this.vehicle)
1642                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1643                 if(this.event_damage)
1644                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1645         }
1646
1647         if (!(this.items & IT_UNLIMITED_AMMO))
1648         {
1649                 regenstable = autocvar_g_balance_fuel_regenstable;
1650                 rotstable = autocvar_g_balance_fuel_rotstable;
1651                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1652                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1653                 RotRegen(this, RES_FUEL, 1,
1654                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1655                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1656         }
1657 }
1658
1659 bool zoomstate_set;
1660 void SetZoomState(entity this, float newzoom)
1661 {
1662         if(newzoom != CS(this).zoomstate)
1663         {
1664                 CS(this).zoomstate = newzoom;
1665                 ClientData_Touch(this);
1666         }
1667         zoomstate_set = true;
1668 }
1669
1670 void GetPressedKeys(entity this)
1671 {
1672         MUTATOR_CALLHOOK(GetPressedKeys, this);
1673         if (game_stopped)
1674         {
1675                 CS(this).pressedkeys = 0;
1676                 STAT(PRESSED_KEYS, this) = 0;
1677                 return;
1678         }
1679
1680         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1681         int keys = STAT(PRESSED_KEYS, this);
1682         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1683         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1684         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1685         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1686
1687         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1688         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1689         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1690         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1691         CS(this).pressedkeys = keys; // store for other users
1692
1693         STAT(PRESSED_KEYS, this) = keys;
1694 }
1695
1696 /*
1697 ======================
1698 spectate mode routines
1699 ======================
1700 */
1701
1702 void SpectateCopy(entity this, entity spectatee)
1703 {
1704         TC(Client, this); TC(Client, spectatee);
1705
1706         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1707         PS(this) = PS(spectatee);
1708         this.armortype = spectatee.armortype;
1709         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1710         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1711         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1712         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1713         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1714         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1715         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1716         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1717         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1718         CS(this).impulse = 0;
1719         this.disableclientprediction = 1; // no need to run prediction on a spectator
1720         this.items = spectatee.items;
1721         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1722         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1723         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1724         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1725         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1726         this.punchangle = spectatee.punchangle;
1727         this.view_ofs = spectatee.view_ofs;
1728         this.velocity = spectatee.velocity;
1729         this.dmg_take = spectatee.dmg_take;
1730         this.dmg_save = spectatee.dmg_save;
1731         this.dmg_inflictor = spectatee.dmg_inflictor;
1732         this.v_angle = spectatee.v_angle;
1733         this.angles = spectatee.v_angle;
1734         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1735         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1736         this.viewloc = spectatee.viewloc;
1737         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1738                 this.fixangle = true;
1739         setorigin(this, spectatee.origin);
1740         setsize(this, spectatee.mins, spectatee.maxs);
1741         SetZoomState(this, CS(spectatee).zoomstate);
1742
1743     anticheat_spectatecopy(this, spectatee);
1744         STAT(HUD, this) = STAT(HUD, spectatee);
1745         if(spectatee.vehicle)
1746     {
1747         this.angles = spectatee.v_angle;
1748
1749         //this.fixangle = false;
1750         //this.velocity = spectatee.vehicle.velocity;
1751         this.vehicle_health = spectatee.vehicle_health;
1752         this.vehicle_shield = spectatee.vehicle_shield;
1753         this.vehicle_energy = spectatee.vehicle_energy;
1754         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1755         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1756         this.vehicle_reload1 = spectatee.vehicle_reload1;
1757         this.vehicle_reload2 = spectatee.vehicle_reload2;
1758
1759         //msg_entity = this;
1760
1761        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1762             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1763            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1764            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1765
1766         //WriteByte (MSG_ONE, SVC_SETVIEW);
1767         //    WriteEntity(MSG_ONE, this);
1768         //makevectors(spectatee.v_angle);
1769         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1770     }
1771 }
1772
1773 bool SpectateUpdate(entity this)
1774 {
1775         if(!this.enemy)
1776                 return false;
1777
1778         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1779         {
1780                 SetSpectatee(this, NULL);
1781                 return false;
1782         }
1783
1784         SpectateCopy(this, this.enemy);
1785
1786         return true;
1787 }
1788
1789 bool SpectateSet(entity this)
1790 {
1791         if(!IS_PLAYER(this.enemy))
1792                 return false;
1793
1794         ClientData_Touch(this.enemy);
1795
1796         msg_entity = this;
1797         WriteByte(MSG_ONE, SVC_SETVIEW);
1798         WriteEntity(MSG_ONE, this.enemy);
1799         set_movetype(this, MOVETYPE_NONE);
1800         accuracy_resend(this);
1801
1802         if(!SpectateUpdate(this))
1803                 PutObserverInServer(this, false, true);
1804
1805         return true;
1806 }
1807
1808 void SetSpectatee_status(entity this, int spectatee_num)
1809 {
1810         int oldspectatee_status = CS(this).spectatee_status;
1811         CS(this).spectatee_status = spectatee_num;
1812
1813         if (CS(this).spectatee_status != oldspectatee_status)
1814         {
1815                 if (STAT(PRESSED_KEYS, this))
1816                 {
1817                         CS(this).pressedkeys = 0;
1818                         STAT(PRESSED_KEYS, this) = 0;
1819                 }
1820                 ClientData_Touch(this);
1821                 if (g_race || g_cts) race_InitSpectator();
1822         }
1823 }
1824
1825 void SetSpectatee(entity this, entity spectatee)
1826 {
1827         if(IS_BOT_CLIENT(this))
1828                 return; // bots abuse .enemy, this code is useless to them
1829
1830         entity old_spectatee = this.enemy;
1831
1832         this.enemy = spectatee;
1833
1834         // WEAPONTODO
1835         // these are required to fix the spectator bug with arc
1836         if(old_spectatee)
1837         {
1838                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1839                 {
1840                         .entity weaponentity = weaponentities[slot];
1841                         if(old_spectatee.(weaponentity).arc_beam)
1842                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1843                 }
1844         }
1845         if(spectatee)
1846         {
1847                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1848                 {
1849                         .entity weaponentity = weaponentities[slot];
1850                         if(spectatee.(weaponentity).arc_beam)
1851                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1852                 }
1853         }
1854
1855         if (spectatee)
1856                 SetSpectatee_status(this, etof(spectatee));
1857
1858         // needed to update spectator list
1859         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1860 }
1861
1862 bool Spectate(entity this, entity pl)
1863 {
1864         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1865                 return false;
1866         pl = M_ARGV(1, entity);
1867
1868         SetSpectatee(this, pl);
1869         return SpectateSet(this);
1870 }
1871
1872 bool SpectateNext(entity this)
1873 {
1874         entity ent = find(this.enemy, classname, STR_PLAYER);
1875
1876         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1877                 ent = M_ARGV(1, entity);
1878         else if (!ent)
1879                 ent = find(ent, classname, STR_PLAYER);
1880
1881         if(ent) { SetSpectatee(this, ent); }
1882
1883         return SpectateSet(this);
1884 }
1885
1886 bool SpectatePrev(entity this)
1887 {
1888         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1889         entity ent = findchain(classname, STR_PLAYER);
1890         if (!ent) // no player
1891                 return false;
1892
1893         entity first = ent;
1894         // skip players until current spectated player
1895         if(this.enemy)
1896         while(ent && ent != this.enemy)
1897                 ent = ent.chain;
1898
1899         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1900         {
1901                 case MUT_SPECPREV_FOUND:
1902                         ent = M_ARGV(1, entity);
1903                         break;
1904                 case MUT_SPECPREV_RETURN:
1905                         return true;
1906                 case MUT_SPECPREV_CONTINUE:
1907                 default:
1908                 {
1909                         if(ent.chain)
1910                                 ent = ent.chain;
1911                         else
1912                                 ent = first;
1913                         break;
1914                 }
1915         }
1916
1917         SetSpectatee(this, ent);
1918         return SpectateSet(this);
1919 }
1920
1921 /*
1922 =============
1923 ShowRespawnCountdown()
1924
1925 Update a respawn countdown display.
1926 =============
1927 */
1928 void ShowRespawnCountdown(entity this)
1929 {
1930         float number;
1931         if(!IS_DEAD(this)) // just respawned?
1932                 return;
1933         else
1934         {
1935                 number = ceil(this.respawn_time - time);
1936                 if(number <= 0)
1937                         return;
1938                 if(number <= this.respawn_countdown)
1939                 {
1940                         this.respawn_countdown = number - 1;
1941                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1942                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1943                 }
1944         }
1945 }
1946
1947 .bool team_selected;
1948 bool ShowTeamSelection(entity this)
1949 {
1950         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1951                 return false;
1952         stuffcmd(this, "menu_showteamselect\n");
1953         return true;
1954 }
1955 void Join(entity this)
1956 {
1957         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1958                 ReadyRestart(true);
1959
1960         TRANSMUTE(Player, this);
1961
1962         if(!this.team_selected)
1963         if(autocvar_g_campaign || autocvar_g_balance_teams)
1964                 TeamBalance_JoinBestTeam(this);
1965
1966         if(autocvar_g_campaign)
1967                 campaign_bots_may_start = true;
1968
1969         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1970
1971         PutClientInServer(this);
1972
1973         if(IS_PLAYER(this))
1974         if(teamplay && this.team != -1)
1975         {
1976         }
1977         else
1978                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1979         this.team_selected = false;
1980 }
1981
1982 int GetPlayerLimit()
1983 {
1984         if(g_duel)
1985                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1986         int player_limit = autocvar_g_maxplayers;
1987         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1988         player_limit = M_ARGV(0, int);
1989         return player_limit;
1990 }
1991
1992 /**
1993  * Determines whether the player is allowed to join. This depends on cvar
1994  * g_maxplayers, if it isn't used this function always return true, otherwise
1995  * it checks whether the number of currently playing players exceeds g_maxplayers.
1996  * @return int number of free slots for players, 0 if none
1997  */
1998 int nJoinAllowed(entity this, entity ignore)
1999 {
2000         if(!ignore)
2001         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2002         // so report 0 free slots if restricted
2003         {
2004                 if(autocvar_g_forced_team_otherwise == "spectate")
2005                         return 0;
2006                 if(autocvar_g_forced_team_otherwise == "spectator")
2007                         return 0;
2008         }
2009
2010         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2011                 return 0; // forced spectators can never join
2012
2013         // TODO simplify this
2014         int totalClients = 0;
2015         int currentlyPlaying = 0;
2016         FOREACH_CLIENT(true, {
2017                 if(it != ignore)
2018                         ++totalClients;
2019                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2020                         ++currentlyPlaying;
2021         });
2022
2023         int player_limit = GetPlayerLimit();
2024
2025         int free_slots = 0;
2026         if (!player_limit)
2027                 free_slots = maxclients - totalClients;
2028         else if(player_limit > 0 && currentlyPlaying < player_limit)
2029                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2030
2031         static float msg_time = 0;
2032         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2033         {
2034                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2035                 msg_time = time + 0.5;
2036         }
2037
2038         return free_slots;
2039 }
2040
2041 void PrintWelcomeMessage(entity this)
2042 {
2043         if(CS(this).motd_actived_time == 0)
2044         {
2045                 if (autocvar_g_campaign) {
2046                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2047                                 CS(this).motd_actived_time = time;
2048                                 SendWelcomemessage(this, false);
2049                         }
2050                 } else {
2051                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2052                                 CS(this).motd_actived_time = time;
2053                                 SendWelcomemessage(this, true);
2054                         }
2055                 }
2056         }
2057         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2058         {
2059                 if (autocvar_g_campaign) {
2060                         if (PHYS_INPUT_BUTTON_INFO(this))
2061                                 CS(this).motd_actived_time = time;
2062                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2063                                 CS(this).motd_actived_time = 0;
2064                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2065                         }
2066                 } else {
2067                         if (PHYS_INPUT_BUTTON_INFO(this))
2068                                 CS(this).motd_actived_time = time;
2069                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2070                                 CS(this).motd_actived_time = 0;
2071                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2072                         }
2073                 }
2074         }
2075         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2076         {
2077                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2078                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2079                 else if (CS(this).motd_actived_time == -2)
2080                 {
2081                         // instantly hide MOTD
2082                         CS(this).motd_actived_time = 0;
2083                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2084                 }
2085                 else if (IS_PLAYER(this) || IS_SPEC(this))
2086                 {
2087                         // FIXME occasionally for some reason MOTD never goes away
2088                         // delay MOTD removal a little bit in the hope it fixes this bug
2089                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2090                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2091                         else //if (CS(this).motd_actived_time < -2)
2092                                 CS(this).motd_actived_time++;
2093                 }
2094         }
2095 }
2096
2097 bool joinAllowed(entity this)
2098 {
2099         if (CS(this).version_mismatch) return false;
2100         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2101         if (!nJoinAllowed(this, this)) return false;
2102         if (teamplay && lockteams) return false;
2103         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2104         if (ShowTeamSelection(this)) return false;
2105         return true;
2106 }
2107
2108 .string shootfromfixedorigin;
2109 .bool dualwielding_prev;
2110 bool PlayerThink(entity this)
2111 {
2112         if (game_stopped || intermission_running) {
2113                 this.modelflags &= ~MF_ROCKET;
2114                 if(intermission_running)
2115                         IntermissionThink(this);
2116                 return false;
2117         }
2118
2119         if (timeout_status == TIMEOUT_ACTIVE) {
2120                 // don't allow the player to turn around while game is paused
2121                 // FIXME turn this into CSQC stuff
2122                 this.v_angle = this.lastV_angle;
2123                 this.angles = this.lastV_angle;
2124                 this.fixangle = true;
2125         }
2126
2127         if (frametime) player_powerups(this);
2128
2129         if (IS_DEAD(this)) {
2130                 if (this.personal && g_race_qualifying) {
2131                         if (time > this.respawn_time) {
2132                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2133                                 respawn(this);
2134                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2135                         }
2136                 } else {
2137                         if (frametime) player_anim(this);
2138
2139                         if (this.respawn_flags & RESPAWN_DENY)
2140                         {
2141                                 STAT(RESPAWN_TIME, this) = 0;
2142                                 return false;
2143                         }
2144
2145                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2146
2147                         switch(this.deadflag)
2148                         {
2149                                 case DEAD_DYING:
2150                                 {
2151                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2152                                                 this.deadflag = DEAD_RESPAWNING;
2153                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2154                                                 this.deadflag = DEAD_DEAD;
2155                                         break;
2156                                 }
2157                                 case DEAD_DEAD:
2158                                 {
2159                                         if (button_pressed)
2160                                                 this.deadflag = DEAD_RESPAWNABLE;
2161                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2162                                                 this.deadflag = DEAD_RESPAWNING;
2163                                         break;
2164                                 }
2165                                 case DEAD_RESPAWNABLE:
2166                                 {
2167                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2168                                                 this.deadflag = DEAD_RESPAWNING;
2169                                         break;
2170                                 }
2171                                 case DEAD_RESPAWNING:
2172                                 {
2173                                         if (time > this.respawn_time)
2174                                         {
2175                                                 this.respawn_time = time + 1; // only retry once a second
2176                                                 this.respawn_time_max = this.respawn_time;
2177                                                 respawn(this);
2178                                         }
2179                                         break;
2180                                 }
2181                         }
2182
2183                         ShowRespawnCountdown(this);
2184
2185                         if (this.respawn_flags & RESPAWN_SILENT)
2186                                 STAT(RESPAWN_TIME, this) = 0;
2187                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2188                         {
2189                                 if (time < this.respawn_time)
2190                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2191                                 else if (this.deadflag != DEAD_RESPAWNING)
2192                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2193                         }
2194                         else
2195                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2196                 }
2197
2198                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2199                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2200                         STAT(RESPAWN_TIME, this) *= -1;
2201
2202                 return false;
2203         }
2204
2205         FixPlayermodel(this);
2206
2207         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2208                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2209                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2210         }
2211
2212         // reset gun alignment when dual wielding status changes
2213         // to ensure guns are always aligned right and left
2214         bool dualwielding = W_DualWielding(this);
2215         if(this.dualwielding_prev != dualwielding)
2216         {
2217                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2218                 this.dualwielding_prev = dualwielding;
2219         }
2220
2221         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2222         //if(frametime)
2223         {
2224                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2225                 {
2226                         .entity weaponentity = weaponentities[slot];
2227                         if(WEP_CVAR(vortex, charge_always))
2228                                 W_Vortex_Charge(this, weaponentity, frametime);
2229                         W_WeaponFrame(this, weaponentity);
2230                 }
2231         }
2232
2233         if (frametime)
2234         {
2235                 // WEAPONTODO: Add a weapon request for this
2236                 // rot vortex charge to the charge limit
2237                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2238                 {
2239                         .entity weaponentity = weaponentities[slot];
2240                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2241                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2242                 }
2243
2244                 player_regen(this);
2245                 player_anim(this);
2246                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2247         }
2248
2249         monsters_setstatus(this);
2250
2251         return true;
2252 }
2253
2254 .bool would_spectate;
2255 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2256 void ObserverOrSpectatorThink(entity this)
2257 {
2258         bool is_spec = IS_SPEC(this);
2259         if ( CS(this).impulse )
2260         {
2261                 int r = MinigameImpulse(this, CS(this).impulse);
2262                 if (!is_spec || r)
2263                         CS(this).impulse = 0;
2264
2265                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2266                 {
2267                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2268                         CS(this).impulse = 0;
2269                         return;
2270                 }
2271         }
2272
2273         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2274         {
2275                 CS(this).autojoin_checked = true;
2276                 TRANSMUTE(Player, this);
2277                 PutClientInServer(this);
2278                 return;
2279         }
2280
2281         if (this.flags & FL_JUMPRELEASED) {
2282                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2283                         this.flags &= ~FL_JUMPRELEASED;
2284                         this.flags |= FL_SPAWNING;
2285                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2286                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2287                         this.flags &= ~FL_JUMPRELEASED;
2288                         if(SpectateNext(this)) {
2289                                 TRANSMUTE(Spectator, this);
2290                         } else if (is_spec) {
2291                                 TRANSMUTE(Observer, this);
2292                                 PutClientInServer(this);
2293                         }
2294                         else
2295                                 this.would_spectate = false; // unable to spectate anyone
2296                         if (is_spec)
2297                                 CS(this).impulse = 0;
2298                 } else if (is_spec) {
2299                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2300                                 this.flags &= ~FL_JUMPRELEASED;
2301                                 if(SpectatePrev(this)) {
2302                                         TRANSMUTE(Spectator, this);
2303                                 } else {
2304                                         TRANSMUTE(Observer, this);
2305                                         PutClientInServer(this);
2306                                 }
2307                                 CS(this).impulse = 0;
2308                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2309                                 this.would_spectate = false;
2310                                 this.flags &= ~FL_JUMPRELEASED;
2311                                 TRANSMUTE(Observer, this);
2312                                 PutClientInServer(this);
2313                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2314                                 PutObserverInServer(this, false, true);
2315                                 this.would_spectate = true;
2316                         }
2317                 }
2318                 else {
2319                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2320                         if (PHYS_INPUT_BUTTON_USE(this))
2321                                 wouldclip = !wouldclip;
2322                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2323                         set_movetype(this, preferred_movetype);
2324                 }
2325         } else { // jump pressed
2326                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2327                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2328                         this.flags |= FL_JUMPRELEASED;
2329                         if(this.flags & FL_SPAWNING)
2330                         {
2331                                 this.flags &= ~FL_SPAWNING;
2332                                 if(joinAllowed(this))
2333                                         Join(this);
2334                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2335                                         CS(this).autojoin_checked = -1;
2336                                 return;
2337                         }
2338                 }
2339                 if(is_spec && !SpectateUpdate(this))
2340                         PutObserverInServer(this, false, true);
2341         }
2342         if (is_spec)
2343                 this.flags |= FL_CLIENT | FL_NOTARGET;
2344 }
2345
2346 void PlayerUseKey(entity this)
2347 {
2348         if (!IS_PLAYER(this))
2349                 return;
2350
2351         if(this.vehicle)
2352         {
2353                 if(!game_stopped)
2354                 {
2355                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2356                         return;
2357                 }
2358         }
2359         else if(autocvar_g_vehicles_enter)
2360         {
2361                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2362                 {
2363                         entity head, closest_target = NULL;
2364                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2365
2366                         while(head) // find the closest acceptable target to enter
2367                         {
2368                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2369                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2370                                 {
2371                                         if(closest_target)
2372                                         {
2373                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2374                                                 { closest_target = head; }
2375                                         }
2376                                         else { closest_target = head; }
2377                                 }
2378
2379                                 head = head.chain;
2380                         }
2381
2382                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2383                 }
2384         }
2385
2386         // a use key was pressed; call handlers
2387         MUTATOR_CALLHOOK(PlayerUseKey, this);
2388 }
2389
2390
2391 /*
2392 =============
2393 PlayerPreThink
2394
2395 Called every frame for each client before the physics are run
2396 =============
2397 */
2398 .float last_vehiclecheck;
2399 void PlayerPreThink (entity this)
2400 {
2401         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2402         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2403
2404         WarpZone_PlayerPhysics_FixVAngle(this);
2405
2406         if (frametime) {
2407                 // physics frames: update anticheat stuff
2408                 anticheat_prethink(this);
2409
2410                 // WORKAROUND: only use dropclient in server frames (frametime set).
2411                 // Never use it in cl_movement frames (frametime zero).
2412                 if (blockSpectators && IS_REAL_CLIENT(this)
2413                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2414                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2415                 {
2416                         if (dropclient_schedule(this))
2417                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2418                 }
2419         }
2420
2421         zoomstate_set = false;
2422
2423         // Check for nameless players
2424         if (this.netname == "" || this.netname != CS(this).netname_previous)
2425         {
2426                 bool assume_unchanged = (CS(this).netname_previous == "");
2427                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2428                 {
2429                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2430                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2431                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2432                         assume_unchanged = false;
2433                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2434                 }
2435                 if (isInvisibleString(this.netname))
2436                 {
2437                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2438                         sprint(this, "Warning: invisible names are not allowed.\n");
2439                         assume_unchanged = false;
2440                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2441                 }
2442                 if (!assume_unchanged && autocvar_sv_eventlog)
2443                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2444                 strcpy(CS(this).netname_previous, this.netname);
2445         }
2446
2447         // version nagging
2448         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2449         CS(this).version_nagtime = 0;
2450         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2451             // git client
2452         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2453             // git server
2454             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2455         } else {
2456             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2457             if (r < 0) { // old client
2458                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2459             } else if (r > 0) { // old server
2460                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2461             }
2462         }
2463     }
2464
2465         // GOD MODE info
2466         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2467         {
2468                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2469                 this.max_armorvalue = 0;
2470         }
2471
2472         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2473         {
2474                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2475                 {
2476                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2477                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2478                         if (this.iceblock)
2479                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2480
2481                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2482                                 Unfreeze(this, false);
2483                 }
2484                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2485                 {
2486                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2487                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2488
2489                         if (GetResource(this, RES_HEALTH) < 1)
2490                         {
2491                                 if (this.vehicle)
2492                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2493                                 if(this.event_damage)
2494                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2495                         }
2496                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2497                                 Unfreeze(this, false);
2498                 }
2499         }
2500
2501         MUTATOR_CALLHOOK(PlayerPreThink, this);
2502
2503         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2504         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2505         {
2506                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2507                 {
2508                         if(!it.owner)
2509                         {
2510                                 if(!it.team || SAME_TEAM(this, it))
2511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2512                                 else if(autocvar_g_vehicles_steal)
2513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2514                         }
2515                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2516                         {
2517                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2518                         }
2519                 });
2520
2521                 this.last_vehiclecheck = time + 1;
2522         }
2523
2524         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2525                 PlayerUseKey(this);
2526         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2527
2528         if (IS_REAL_CLIENT(this))
2529                 PrintWelcomeMessage(this);
2530
2531         if (IS_PLAYER(this)) {
2532                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2533                         error("Client can't be spawned as player on connection!");
2534                 if(!PlayerThink(this))
2535                         return;
2536         }
2537         else if (game_stopped || intermission_running) {
2538                 if(intermission_running)
2539                         IntermissionThink(this);
2540                 return;
2541         }
2542         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2543         {
2544                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2545                 CS(this).autojoin_checked = 1;
2546                 // don't do this in ClientConnect
2547                 // many things can go wrong if a client is spawned as player on connection
2548                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2549                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2550                                 && (!teamplay || autocvar_g_balance_teams)))
2551                 {
2552                         if(joinAllowed(this))
2553                                 Join(this);
2554                         return;
2555                 }
2556         }
2557         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2558                 ObserverOrSpectatorThink(this);
2559         }
2560
2561         // WEAPONTODO: Add weapon request for this
2562         if (!zoomstate_set) {
2563                 bool wep_zoomed = false;
2564                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2565                 {
2566                         .entity weaponentity = weaponentities[slot];
2567                         Weapon thiswep = this.(weaponentity).m_weapon;
2568                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2569                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2570                 }
2571                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2572         }
2573
2574         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2575         {
2576                 CS(this).teamkill_soundtime = 0;
2577
2578                 entity e = CS(this).teamkill_soundsource;
2579                 entity oldpusher = e.pusher;
2580                 e.pusher = this;
2581                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2582                 e.pusher = oldpusher;
2583         }
2584
2585         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2586                 CS(this).taunt_soundtime = 0;
2587                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2588         }
2589
2590         target_voicescript_next(this);
2591 }
2592
2593 void DrownPlayer(entity this)
2594 {
2595         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2596                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2597         {
2598                 STAT(AIR_FINISHED, this) = 0;
2599                 return;
2600         }
2601
2602         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2603         {
2604                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2605                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2606                 STAT(AIR_FINISHED, this) = 0;
2607         }
2608         else
2609         {
2610                 if (!STAT(AIR_FINISHED, this))
2611                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2612                 if (STAT(AIR_FINISHED, this) < time)
2613                 {       // drown!
2614                         if (this.pain_finished < time)
2615                         {
2616                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2617                                 this.pain_finished = time + 0.5;
2618                         }
2619                 }
2620         }
2621 }
2622
2623 .bool move_qcphysics;
2624
2625 void Player_Physics(entity this)
2626 {
2627         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2628
2629         if(!this.move_qcphysics)
2630                 return;
2631
2632         if(!frametime && !CS(this).pm_frametime)
2633                 return;
2634
2635         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2636
2637         CS(this).pm_frametime = 0;
2638 }
2639
2640 /*
2641 =============
2642 PlayerPostThink
2643
2644 Called every frame for each client after the physics are run
2645 =============
2646 */
2647 void PlayerPostThink (entity this)
2648 {
2649         Player_Physics(this);
2650
2651         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2652         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2653         if (IS_REAL_CLIENT(this))
2654         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2655         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2656         {
2657                 int totalClients = 0;
2658                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2659                 {
2660                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2661                         if (server_is_dedicated)
2662                         {
2663                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2664                                 {
2665                                         ++totalClients;
2666                                 });
2667                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2668                                         totalClients = 0;
2669                         }
2670                 }
2671                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2672                 {
2673                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2674                         {
2675                                 ++totalClients;
2676                         });
2677                 }
2678
2679                 if (totalClients < autocvar_sv_maxidle_minplayers)
2680                 {
2681                         // idle kick disabled
2682                         CS(this).parm_idlesince = time;
2683                 }
2684                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2685                 {
2686                         if (CS(this).idlekick_lasttimeleft)
2687                         {
2688                                 CS(this).idlekick_lasttimeleft = 0;
2689                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2690                         }
2691                 }
2692                 else
2693                 {
2694                         float maxidle_time = autocvar_sv_maxidle;
2695                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2696                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2697                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2698                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2699                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2700                         {
2701                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2702                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2703                                 else
2704                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2705                         }
2706                         if (timeleft <= 0) {
2707                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2708                                 {
2709                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2710                                         PutObserverInServer(this, true, true);
2711                                 }
2712                                 else
2713                                 {
2714                                         if (dropclient_schedule(this))
2715                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2716                                 }
2717                                 return;
2718                         }
2719                         else if (timeleft <= countdown_time) {
2720                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2721                                         play2(this, SND(TALK2));
2722                                 CS(this).idlekick_lasttimeleft = timeleft;
2723                         }
2724                 }
2725         }
2726
2727         CheatFrame(this);
2728
2729         if (game_stopped)
2730         {
2731                 this.solid = SOLID_NOT;
2732                 this.takedamage = DAMAGE_NO;
2733                 set_movetype(this, MOVETYPE_NONE);
2734                 CS(this).teamkill_complain = 0;
2735                 CS(this).teamkill_soundtime = 0;
2736                 CS(this).teamkill_soundsource = NULL;
2737         }
2738
2739         if (IS_PLAYER(this)) {
2740                 if(this.death_time == time && IS_DEAD(this))
2741                 {
2742                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2743                         // once all the damage events of this frame have been processed with normal size
2744                         this.maxs.z = 5;
2745                         setsize(this, this.mins, this.maxs);
2746                 }
2747                 DrownPlayer(this);
2748                 UpdateChatBubble(this);
2749                 if (CS(this).impulse) ImpulseCommands(this);
2750                 GetPressedKeys(this);
2751                 if (game_stopped)
2752                 {
2753                         CSQCMODEL_AUTOUPDATE(this);
2754                         return;
2755                 }
2756         }
2757         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2758         {
2759                 CS(this).pressedkeys = 0;
2760                 STAT(PRESSED_KEYS, this) = 0;
2761         }
2762
2763         if (this.waypointsprite_attachedforcarrier) {
2764                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2765                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2766         }
2767
2768         CSQCMODEL_AUTOUPDATE(this);
2769 }
2770
2771 // hack to copy the button fields from the client entity to the Client State
2772 void PM_UpdateButtons(entity this, entity store)
2773 {
2774         if(this.impulse)
2775                 store.impulse = this.impulse;
2776         this.impulse = 0;
2777
2778         bool typing = this.buttonchat || this.button12;
2779
2780         store.button0 = (typing) ? 0 : this.button0;
2781         //button1?!
2782         store.button2 = (typing) ? 0 : this.button2;
2783         store.button3 = (typing) ? 0 : this.button3;
2784         store.button4 = this.button4;
2785         store.button5 = (typing) ? 0 : this.button5;
2786         store.button6 = this.button6;
2787         store.button7 = this.button7;
2788         store.button8 = this.button8;
2789         store.button9 = this.button9;
2790         store.button10 = this.button10;
2791         store.button11 = this.button11;
2792         store.button12 = this.button12;
2793         store.button13 = this.button13;
2794         store.button14 = this.button14;
2795         store.button15 = this.button15;
2796         store.button16 = this.button16;
2797         store.buttonuse = this.buttonuse;
2798         store.buttonchat = this.buttonchat;
2799
2800         store.cursor_active = this.cursor_active;
2801         store.cursor_screen = this.cursor_screen;
2802         store.cursor_trace_start = this.cursor_trace_start;
2803         store.cursor_trace_endpos = this.cursor_trace_endpos;
2804         store.cursor_trace_ent = this.cursor_trace_ent;
2805
2806         store.ping = this.ping;
2807         store.ping_packetloss = this.ping_packetloss;
2808         store.ping_movementloss = this.ping_movementloss;
2809
2810         store.v_angle = this.v_angle;
2811         store.movement = this.movement;
2812 }
2813
2814 NET_HANDLE(fpsreport, bool)
2815 {
2816         int fps = ReadShort();
2817         PlayerScore_Set(sender, SP_FPS, fps);
2818         return true;
2819 }