qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 string GetClientVersionMessage(entity this)
1022 {
1023         if (CS(this).version_mismatch) {
1024                 if(CS(this).version < autocvar_gameversion) {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1027                 } else {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1030                 }
1031         } else {
1032                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1033         }
1034 }
1035
1036 void SendWelcomemessage(entity this, bool force_centerprint)
1037 {
1038         msg_entity = this;
1039         WriteHeader(MSG_ONE, TE_CSQC_SERVERINFO);
1040         WriteByte(MSG_ONE, force_centerprint);
1041         WriteString(MSG_ONE, autocvar_hostname);
1042         WriteString(MSG_ONE, GetClientVersionMessage(this));
1043
1044         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1045         string modifications = M_ARGV(0, string);
1046
1047         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1048                 modifications = strcat(modifications, ", No start weapons");
1049         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1050                 modifications = strcat(modifications, ", Low gravity");
1051         if(g_weapon_stay && !g_cts)
1052                 modifications = strcat(modifications, ", Weapons stay");
1053         if(autocvar_g_jetpack)
1054                 modifications = strcat(modifications, ", Jetpack");
1055         modifications = substring(modifications, 2, strlen(modifications) - 2);
1056
1057         WriteString(MSG_ONE, modifications);
1058
1059         WriteString(MSG_ONE, g_weaponarena_list);
1060
1061         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1062         {
1063                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1064                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1065         }
1066
1067         WriteString(MSG_ONE, cache_mutatormsg);
1068
1069         string mutator_msg = "";
1070         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1071         mutator_msg = M_ARGV(0, string);
1072
1073         WriteString(MSG_ONE, mutator_msg); // trust that the mutator will do proper formatting
1074         WriteString(MSG_ONE, strreplace("\\n", "\n", autocvar_sv_motd));
1075 }
1076
1077 void SendWelcomemessage_onConnection_think(entity this)
1078 {
1079         SendWelcomemessage(this, false);
1080 }
1081
1082 void SendWelcomemessage_onConnection(entity this)
1083 {
1084         // give the client time to sent its version
1085         defer(this, 0.5, SendWelcomemessage_onConnection_think);
1086 }
1087
1088 /**
1089 =============
1090 ClientConnect
1091
1092 Called when a client connects to the server
1093 =============
1094 */
1095 void ClientConnect(entity this)
1096 {
1097         if (Ban_MaybeEnforceBanOnce(this)) return;
1098         assert(!IS_CLIENT(this), return);
1099         this.flags |= FL_CLIENT;
1100         assert(player_count >= 0, player_count = 0);
1101
1102         TRANSMUTE(Client, this);
1103         CS(this).version_nagtime = time + 10 + random() * 10;
1104
1105         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1106
1107         bot_clientconnect(this);
1108
1109         Player_DetermineForcedTeam(this);
1110
1111         TRANSMUTE(Observer, this);
1112
1113         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1114
1115         // always track bots, don't ask for cl_allow_uidtracking
1116         if (IS_BOT_CLIENT(this))
1117                 PlayerStats_GameReport_AddPlayer(this);
1118         else
1119                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1120
1121         if (autocvar_sv_eventlog)
1122                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1123
1124         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1125
1126         stuffcmd(this, clientstuff, "\n");
1127         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1128
1129         FixClientCvars(this);
1130
1131         // get version info from player
1132         stuffcmd(this, "cmd clientversion $gameversion\n");
1133
1134         // notify about available teams
1135         if (teamplay)
1136         {
1137                 entity balance = TeamBalance_CheckAllowedTeams(this);
1138                 int t = TeamBalance_GetAllowedTeams(balance);
1139                 TeamBalance_Destroy(balance);
1140                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1141         }
1142         else
1143         {
1144                 stuffcmd(this, "set _teams_available 0\n");
1145         }
1146
1147         bot_relinkplayerlist();
1148
1149         CS(this).spectatortime = time;
1150         if (blockSpectators)
1151         {
1152                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1153         }
1154
1155         CS(this).jointime = time;
1156
1157         if (IS_REAL_CLIENT(this))
1158         {
1159                 if (g_weaponarena_weapons == WEPSET(TUBA))
1160                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1161         }
1162
1163         if (!autocvar_sv_foginterval && world.fog != "")
1164                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1165
1166         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1167                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1168                         send_CSQC_teamnagger();
1169
1170         CSQCMODEL_AUTOINIT(this);
1171
1172         CS(this).model_randomizer = random();
1173
1174         if (IS_REAL_CLIENT(this))
1175         {
1176                 if (!autocvar_g_campaign)
1177                         SendWelcomemessage_onConnection(this);
1178                 sv_notice_join(this);
1179         }
1180
1181         this.move_qcphysics = autocvar_sv_qcphysics;
1182
1183         // update physics stats (players can spawn before physics runs)
1184         Physics_UpdateStats(this);
1185
1186         IL_EACH(g_initforplayer, it.init_for_player, {
1187                 it.init_for_player(it, this);
1188         });
1189
1190         Handicap_Initialize(this);
1191
1192         MUTATOR_CALLHOOK(ClientConnect, this);
1193
1194         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1195                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1196 }
1197 /*
1198 =============
1199 ClientDisconnect
1200
1201 Called when a client disconnects from the server
1202 =============
1203 */
1204 .entity chatbubbleentity;
1205 void player_powerups_remove_all(entity this);
1206
1207 void ClientDisconnect(entity this)
1208 {
1209         assert(IS_CLIENT(this), return);
1210
1211         PlayerStats_GameReport_FinalizePlayer(this);
1212         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1213         if (CS(this).active_minigame) part_minigame(this);
1214         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1215
1216         if (autocvar_sv_eventlog)
1217                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1218
1219         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1220
1221         if(IS_SPEC(this))
1222                 SetSpectatee(this, NULL);
1223
1224         MUTATOR_CALLHOOK(ClientDisconnect, this);
1225
1226         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1227         strfree(CS_CVAR(this).weaponorder_byimpulse);
1228         ClientState_detach(this);
1229
1230         Portal_ClearAll(this);
1231
1232         Unfreeze(this, false);
1233
1234         RemoveGrapplingHooks(this);
1235
1236         // Here, everything has been done that requires this player to be a client.
1237
1238         this.flags &= ~FL_CLIENT;
1239
1240         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1241         if (this.killindicator) delete(this.killindicator);
1242
1243         IL_EACH(g_counters, it.realowner == this,
1244         {
1245                 delete(it);
1246         });
1247
1248         WaypointSprite_PlayerGone(this);
1249
1250         bot_relinkplayerlist();
1251
1252         strfree(this.clientstatus);
1253         if (this.personal) delete(this.personal);
1254
1255         this.playerid = 0;
1256         ReadyCount();
1257         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1258
1259         player_powerups_remove_all(this); // stop powerup sound
1260
1261         ONREMOVE(this);
1262 }
1263
1264 void ChatBubbleThink(entity this)
1265 {
1266         this.nextthink = time;
1267         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1268         {
1269                 if(this.owner) // but why can that ever be NULL?
1270                         this.owner.chatbubbleentity = NULL;
1271                 delete(this);
1272                 return;
1273         }
1274
1275         this.mdl = "";
1276
1277         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1278         {
1279                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1280                         this.mdl = "models/sprites/minigame_busy.iqm";
1281                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1282                         this.mdl = "models/misc/chatbubble.spr";
1283         }
1284
1285         if ( this.model != this.mdl )
1286                 _setmodel(this, this.mdl);
1287
1288 }
1289
1290 void UpdateChatBubble(entity this)
1291 {
1292         if (this.alpha < 0)
1293                 return;
1294         // spawn a chatbubble entity if needed
1295         if (!this.chatbubbleentity)
1296         {
1297                 this.chatbubbleentity = new(chatbubbleentity);
1298                 this.chatbubbleentity.owner = this;
1299                 this.chatbubbleentity.exteriormodeltoclient = this;
1300                 setthink(this.chatbubbleentity, ChatBubbleThink);
1301                 this.chatbubbleentity.nextthink = time;
1302                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1303                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1304                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1305                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1306                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1307                 //this.chatbubbleentity.model = "";
1308                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1309         }
1310 }
1311
1312 void calculate_player_respawn_time(entity this)
1313 {
1314         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1315                 return;
1316
1317         float gametype_setting_tmp;
1318         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1319         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1320         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1321         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1322         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1323         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1324
1325         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1326         if (teamplay)
1327         {
1328                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1329                         if(it.team == this.team)
1330                                 ++pcount;
1331                 });
1332                 if (sdelay_small_count == 0)
1333                         sdelay_small_count = 1;
1334                 if (sdelay_large_count == 0)
1335                         sdelay_large_count = 1;
1336         }
1337         else
1338         {
1339                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1340                         ++pcount;
1341                 });
1342                 if (sdelay_small_count == 0)
1343                 {
1344                         if (IS_INDEPENDENT_PLAYER(this))
1345                         {
1346                                 // Players play independently. No point in requiring enemies.
1347                                 sdelay_small_count = 1;
1348                         }
1349                         else
1350                         {
1351                                 // Players play AGAINST each other. Enemies required.
1352                                 sdelay_small_count = 2;
1353                         }
1354                 }
1355                 if (sdelay_large_count == 0)
1356                 {
1357                         if (IS_INDEPENDENT_PLAYER(this))
1358                         {
1359                                 // Players play independently. No point in requiring enemies.
1360                                 sdelay_large_count = 1;
1361                         }
1362                         else
1363                         {
1364                                 // Players play AGAINST each other. Enemies required.
1365                                 sdelay_large_count = 2;
1366                         }
1367                 }
1368         }
1369
1370         float sdelay;
1371
1372         if (pcount <= sdelay_small_count)
1373                 sdelay = sdelay_small;
1374         else if (pcount >= sdelay_large_count)
1375                 sdelay = sdelay_large;
1376         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1377                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1378
1379         if(waves)
1380                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1381         else
1382                 this.respawn_time = time + sdelay;
1383
1384         if(sdelay < sdelay_max)
1385                 this.respawn_time_max = time + sdelay_max;
1386         else
1387                 this.respawn_time_max = this.respawn_time;
1388
1389         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1390                 this.respawn_countdown = 10; // first number to count down from is 10
1391         else
1392                 this.respawn_countdown = -1; // do not count down
1393
1394         if(autocvar_g_forced_respawn)
1395                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1396 }
1397
1398 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1399 // added to the model skins
1400 /*void UpdateColorModHack()
1401 {
1402         float c;
1403         c = this.clientcolors & 15;
1404         // LordHavoc: only bothering to support white, green, red, yellow, blue
1405              if (!teamplay) this.colormod = '0 0 0';
1406         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1407         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1408         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1409         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1410         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1411         else this.colormod = '1 1 1';
1412 }*/
1413
1414 void respawn(entity this)
1415 {
1416         bool damagedbycontents_prev = this.damagedbycontents;
1417         if(this.alpha >= 0)
1418         {
1419                 if(autocvar_g_respawn_ghosts)
1420                 {
1421                         this.solid = SOLID_NOT;
1422                         this.takedamage = DAMAGE_NO;
1423                         this.damagedbycontents = false;
1424                         set_movetype(this, MOVETYPE_FLY);
1425                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1426                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1427                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1428                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1429                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1430                         if(autocvar_g_respawn_ghosts_time > 0)
1431                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1432                 }
1433                 else
1434                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1435         }
1436
1437         CopyBody(this, 1);
1438         this.damagedbycontents = damagedbycontents_prev;
1439
1440         this.effects |= EF_NODRAW; // prevent another CopyBody
1441         PutClientInServer(this);
1442 }
1443
1444 void play_countdown(entity this, float finished, Sound samp)
1445 {
1446         TC(Sound, samp);
1447         if(IS_REAL_CLIENT(this))
1448                 if(floor(finished - time - frametime) != floor(finished - time))
1449                         if(finished - time < 6)
1450                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1451 }
1452
1453 // it removes special powerups not handled by StatusEffects
1454 void player_powerups_remove_all(entity this)
1455 {
1456         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1457         {
1458                 // don't play the poweroff sound when the game restarts or the player disconnects
1459                 if (time > game_starttime + 1 && IS_CLIENT(this))
1460                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1461                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1462                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1463                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1464         }
1465 }
1466
1467 void player_powerups(entity this)
1468 {
1469         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1470                 this.modelflags |= MF_ROCKET;
1471         else
1472                 this.modelflags &= ~MF_ROCKET;
1473
1474         this.effects &= ~EF_NODEPTHTEST;
1475
1476         if (IS_DEAD(this))
1477                 player_powerups_remove_all(this);
1478
1479         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1480                 return;
1481
1482         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1483         int items_prev = this.items;
1484
1485         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1486         {
1487                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1488                 if (this.items & IT_SUPERWEAPON)
1489                 {
1490                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1491                         {
1492                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1493                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1494                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1495                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1496                         }
1497                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1498                         {
1499                                 // don't let them run out
1500                         }
1501                         else
1502                         {
1503                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1504                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1505                                 {
1506                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1507                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1508                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1509                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1510                                 }
1511                         }
1512                 }
1513                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1514                 {
1515                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1516                         {
1517                                 this.items = this.items | IT_SUPERWEAPON;
1518                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1519                                 {
1520                                         if(!g_cts)
1521                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1522                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1523                                 }
1524                         }
1525                         else
1526                         {
1527                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1528                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1529                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1530                         }
1531                 }
1532                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1533                 {
1534                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1535                 }
1536         }
1537
1538         if(autocvar_g_nodepthtestplayers)
1539                 this.effects = this.effects | EF_NODEPTHTEST;
1540
1541         if(autocvar_g_fullbrightplayers)
1542                 this.effects = this.effects | EF_FULLBRIGHT;
1543
1544         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1545 }
1546
1547 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1548 {
1549         if(current > stable)
1550                 return current;
1551         else if(current > stable - 0.25) // when close enough, "snap"
1552                 return stable;
1553         else
1554                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1555 }
1556
1557 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1558 {
1559         if(current < stable)
1560                 return current;
1561         else if(current < stable + 0.25) // when close enough, "snap"
1562                 return stable;
1563         else
1564                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1565 }
1566
1567 void RotRegen(entity this, Resource res, float limit_mod,
1568         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1569         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1570 {
1571         float old = GetResource(this, res);
1572         float current = old;
1573         if(current > rotstable)
1574         {
1575                 if(rotframetime > 0)
1576                 {
1577                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1578                         current = max(rotstable, current - rotlinear * rotframetime);
1579                 }
1580         }
1581         else if(current < regenstable)
1582         {
1583                 if(regenframetime > 0)
1584                 {
1585                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1586                         current = min(regenstable, current + regenlinear * regenframetime);
1587                 }
1588         }
1589
1590         float limit = GetResourceLimit(this, res) * limit_mod;
1591         if(current > limit)
1592                 current = limit;
1593
1594         if (current != old)
1595                 SetResource(this, res, current);
1596 }
1597
1598 void player_regen(entity this)
1599 {
1600         float max_mod, regen_mod, rot_mod, limit_mod;
1601         max_mod = regen_mod = rot_mod = limit_mod = 1;
1602
1603         float regen_health = autocvar_g_balance_health_regen;
1604         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1605         float regen_health_rot = autocvar_g_balance_health_rot;
1606         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1607         float regen_health_stable = autocvar_g_balance_health_regenstable;
1608         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1609         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1610                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1611         max_mod = M_ARGV(1, float);
1612         regen_mod = M_ARGV(2, float);
1613         rot_mod = M_ARGV(3, float);
1614         limit_mod = M_ARGV(4, float);
1615         regen_health = M_ARGV(5, float);
1616         regen_health_linear = M_ARGV(6, float);
1617         regen_health_rot = M_ARGV(7, float);
1618         regen_health_rotlinear = M_ARGV(8, float);
1619         regen_health_stable = M_ARGV(9, float);
1620         regen_health_rotstable = M_ARGV(10, float);
1621
1622         float rotstable, regenstable, rotframetime, regenframetime;
1623
1624         if(!mutator_returnvalue)
1625         if(!STAT(FROZEN, this))
1626         {
1627                 regenstable = autocvar_g_balance_armor_regenstable;
1628                 rotstable = autocvar_g_balance_armor_rotstable;
1629                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1630                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1631                 RotRegen(this, RES_ARMOR, limit_mod,
1632                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1633                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1634
1635                 // NOTE: max_mod is only applied to health
1636                 regenstable = regen_health_stable * max_mod;
1637                 rotstable = regen_health_rotstable * max_mod;
1638                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1639                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1640                 RotRegen(this, RES_HEALTH, limit_mod,
1641                         regenstable, regen_health, regen_health_linear, regenframetime,
1642                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1643         }
1644
1645         // if player rotted to death...  die!
1646         // check this outside above checks, as player may still be able to rot to death
1647         if(GetResource(this, RES_HEALTH) < 1)
1648         {
1649                 if(this.vehicle)
1650                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1651                 if(this.event_damage)
1652                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1653         }
1654
1655         if (!(this.items & IT_UNLIMITED_AMMO))
1656         {
1657                 regenstable = autocvar_g_balance_fuel_regenstable;
1658                 rotstable = autocvar_g_balance_fuel_rotstable;
1659                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1660                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1661                 RotRegen(this, RES_FUEL, 1,
1662                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1663                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1664         }
1665 }
1666
1667 bool zoomstate_set;
1668 void SetZoomState(entity this, float newzoom)
1669 {
1670         if(newzoom != CS(this).zoomstate)
1671         {
1672                 CS(this).zoomstate = newzoom;
1673                 ClientData_Touch(this);
1674         }
1675         zoomstate_set = true;
1676 }
1677
1678 void GetPressedKeys(entity this)
1679 {
1680         MUTATOR_CALLHOOK(GetPressedKeys, this);
1681         if (game_stopped)
1682         {
1683                 CS(this).pressedkeys = 0;
1684                 STAT(PRESSED_KEYS, this) = 0;
1685                 return;
1686         }
1687
1688         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1689         int keys = STAT(PRESSED_KEYS, this);
1690         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1691         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1692         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1693         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1694
1695         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1696         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1697         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1698         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1699         CS(this).pressedkeys = keys; // store for other users
1700
1701         STAT(PRESSED_KEYS, this) = keys;
1702 }
1703
1704 /*
1705 ======================
1706 spectate mode routines
1707 ======================
1708 */
1709
1710 void SpectateCopy(entity this, entity spectatee)
1711 {
1712         TC(Client, this); TC(Client, spectatee);
1713
1714         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1715         PS(this) = PS(spectatee);
1716         this.armortype = spectatee.armortype;
1717         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1718         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1719         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1720         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1721         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1722         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1723         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1724         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1725         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1726         CS(this).impulse = 0;
1727         this.disableclientprediction = 1; // no need to run prediction on a spectator
1728         this.items = spectatee.items;
1729         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1730         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1731         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1732         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1733         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1734         this.punchangle = spectatee.punchangle;
1735         this.view_ofs = spectatee.view_ofs;
1736         this.velocity = spectatee.velocity;
1737         this.dmg_take = spectatee.dmg_take;
1738         this.dmg_save = spectatee.dmg_save;
1739         this.dmg_inflictor = spectatee.dmg_inflictor;
1740         this.v_angle = spectatee.v_angle;
1741         this.angles = spectatee.v_angle;
1742         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1743         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1744         this.viewloc = spectatee.viewloc;
1745         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1746                 this.fixangle = true;
1747         setorigin(this, spectatee.origin);
1748         setsize(this, spectatee.mins, spectatee.maxs);
1749         SetZoomState(this, CS(spectatee).zoomstate);
1750
1751     anticheat_spectatecopy(this, spectatee);
1752         STAT(HUD, this) = STAT(HUD, spectatee);
1753         if(spectatee.vehicle)
1754     {
1755         this.angles = spectatee.v_angle;
1756
1757         //this.fixangle = false;
1758         //this.velocity = spectatee.vehicle.velocity;
1759         this.vehicle_health = spectatee.vehicle_health;
1760         this.vehicle_shield = spectatee.vehicle_shield;
1761         this.vehicle_energy = spectatee.vehicle_energy;
1762         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1763         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1764         this.vehicle_reload1 = spectatee.vehicle_reload1;
1765         this.vehicle_reload2 = spectatee.vehicle_reload2;
1766
1767         //msg_entity = this;
1768
1769        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1770             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1771            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1772            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1773
1774         //WriteByte (MSG_ONE, SVC_SETVIEW);
1775         //    WriteEntity(MSG_ONE, this);
1776         //makevectors(spectatee.v_angle);
1777         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1778     }
1779 }
1780
1781 bool SpectateUpdate(entity this)
1782 {
1783         if(!this.enemy)
1784                 return false;
1785
1786         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1787         {
1788                 SetSpectatee(this, NULL);
1789                 return false;
1790         }
1791
1792         SpectateCopy(this, this.enemy);
1793
1794         return true;
1795 }
1796
1797 bool SpectateSet(entity this)
1798 {
1799         if(!IS_PLAYER(this.enemy))
1800                 return false;
1801
1802         ClientData_Touch(this.enemy);
1803
1804         msg_entity = this;
1805         WriteByte(MSG_ONE, SVC_SETVIEW);
1806         WriteEntity(MSG_ONE, this.enemy);
1807         set_movetype(this, MOVETYPE_NONE);
1808         accuracy_resend(this);
1809
1810         if(!SpectateUpdate(this))
1811                 PutObserverInServer(this, false, true);
1812
1813         return true;
1814 }
1815
1816 void SetSpectatee_status(entity this, int spectatee_num)
1817 {
1818         int oldspectatee_status = CS(this).spectatee_status;
1819         CS(this).spectatee_status = spectatee_num;
1820
1821         if (CS(this).spectatee_status != oldspectatee_status)
1822         {
1823                 if (STAT(PRESSED_KEYS, this))
1824                 {
1825                         CS(this).pressedkeys = 0;
1826                         STAT(PRESSED_KEYS, this) = 0;
1827                 }
1828                 ClientData_Touch(this);
1829                 if (g_race || g_cts) race_InitSpectator();
1830         }
1831 }
1832
1833 void SetSpectatee(entity this, entity spectatee)
1834 {
1835         if(IS_BOT_CLIENT(this))
1836                 return; // bots abuse .enemy, this code is useless to them
1837
1838         entity old_spectatee = this.enemy;
1839
1840         this.enemy = spectatee;
1841
1842         // WEAPONTODO
1843         // these are required to fix the spectator bug with arc
1844         if(old_spectatee)
1845         {
1846                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1847                 {
1848                         .entity weaponentity = weaponentities[slot];
1849                         if(old_spectatee.(weaponentity).arc_beam)
1850                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1851                 }
1852         }
1853         if(spectatee)
1854         {
1855                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1856                 {
1857                         .entity weaponentity = weaponentities[slot];
1858                         if(spectatee.(weaponentity).arc_beam)
1859                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1860                 }
1861         }
1862
1863         if (spectatee)
1864                 SetSpectatee_status(this, etof(spectatee));
1865
1866         // needed to update spectator list
1867         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1868 }
1869
1870 bool Spectate(entity this, entity pl)
1871 {
1872         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1873                 return false;
1874         pl = M_ARGV(1, entity);
1875
1876         SetSpectatee(this, pl);
1877         return SpectateSet(this);
1878 }
1879
1880 bool SpectateNext(entity this)
1881 {
1882         entity ent = find(this.enemy, classname, STR_PLAYER);
1883
1884         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1885                 ent = M_ARGV(1, entity);
1886         else if (!ent)
1887                 ent = find(ent, classname, STR_PLAYER);
1888
1889         if(ent) { SetSpectatee(this, ent); }
1890
1891         return SpectateSet(this);
1892 }
1893
1894 bool SpectatePrev(entity this)
1895 {
1896         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1897         entity ent = findchain(classname, STR_PLAYER);
1898         if (!ent) // no player
1899                 return false;
1900
1901         entity first = ent;
1902         // skip players until current spectated player
1903         if(this.enemy)
1904         while(ent && ent != this.enemy)
1905                 ent = ent.chain;
1906
1907         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1908         {
1909                 case MUT_SPECPREV_FOUND:
1910                         ent = M_ARGV(1, entity);
1911                         break;
1912                 case MUT_SPECPREV_RETURN:
1913                         return true;
1914                 case MUT_SPECPREV_CONTINUE:
1915                 default:
1916                 {
1917                         if(ent.chain)
1918                                 ent = ent.chain;
1919                         else
1920                                 ent = first;
1921                         break;
1922                 }
1923         }
1924
1925         SetSpectatee(this, ent);
1926         return SpectateSet(this);
1927 }
1928
1929 /*
1930 =============
1931 ShowRespawnCountdown()
1932
1933 Update a respawn countdown display.
1934 =============
1935 */
1936 void ShowRespawnCountdown(entity this)
1937 {
1938         float number;
1939         if(!IS_DEAD(this)) // just respawned?
1940                 return;
1941         else
1942         {
1943                 number = ceil(this.respawn_time - time);
1944                 if(number <= 0)
1945                         return;
1946                 if(number <= this.respawn_countdown)
1947                 {
1948                         this.respawn_countdown = number - 1;
1949                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1950                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1951                 }
1952         }
1953 }
1954
1955 .bool team_selected;
1956 bool ShowTeamSelection(entity this)
1957 {
1958         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1959                 return false;
1960         stuffcmd(this, "menu_showteamselect\n");
1961         return true;
1962 }
1963 void Join(entity this)
1964 {
1965         TRANSMUTE(Player, this);
1966
1967         if(!this.team_selected)
1968         if(autocvar_g_campaign || autocvar_g_balance_teams)
1969                 TeamBalance_JoinBestTeam(this);
1970
1971         if(autocvar_g_campaign)
1972                 campaign_bots_may_start = true;
1973
1974         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1975
1976         PutClientInServer(this);
1977
1978         if(IS_PLAYER(this))
1979         if(teamplay && this.team != -1)
1980         {
1981         }
1982         else
1983                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1984         this.team_selected = false;
1985 }
1986
1987 int GetPlayerLimit()
1988 {
1989         if(g_duel)
1990                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1991         int player_limit = autocvar_g_maxplayers;
1992         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1993         player_limit = M_ARGV(0, int);
1994         return player_limit;
1995 }
1996
1997 /**
1998  * Determines whether the player is allowed to join. This depends on cvar
1999  * g_maxplayers, if it isn't used this function always return true, otherwise
2000  * it checks whether the number of currently playing players exceeds g_maxplayers.
2001  * @return int number of free slots for players, 0 if none
2002  */
2003 int nJoinAllowed(entity this, entity ignore)
2004 {
2005         if(!ignore)
2006         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2007         // so report 0 free slots if restricted
2008         {
2009                 if(autocvar_g_forced_team_otherwise == "spectate")
2010                         return 0;
2011                 if(autocvar_g_forced_team_otherwise == "spectator")
2012                         return 0;
2013         }
2014
2015         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2016                 return 0; // forced spectators can never join
2017
2018         // TODO simplify this
2019         int totalClients = 0;
2020         int currentlyPlaying = 0;
2021         FOREACH_CLIENT(true, {
2022                 if(it != ignore)
2023                         ++totalClients;
2024                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2025                         ++currentlyPlaying;
2026         });
2027
2028         int player_limit = GetPlayerLimit();
2029
2030         int free_slots = 0;
2031         if (!player_limit)
2032                 free_slots = maxclients - totalClients;
2033         else if(player_limit > 0 && currentlyPlaying < player_limit)
2034                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2035
2036         static float msg_time = 0;
2037         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2038         {
2039                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2040                 msg_time = time + 0.5;
2041         }
2042
2043         return free_slots;
2044 }
2045
2046 void PrintWelcomeMessage(entity this)
2047 {
2048         if(CS(this).motd_actived_time == 0)
2049         {
2050                 if (autocvar_g_campaign) {
2051                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2052                                 CS(this).motd_actived_time = time;
2053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2054                         }
2055                 } else {
2056                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2057                                 CS(this).motd_actived_time = time;
2058                                 SendWelcomemessage(this, true);
2059                         }
2060                 }
2061         }
2062         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2063         {
2064                 if (autocvar_g_campaign) {
2065                         if (PHYS_INPUT_BUTTON_INFO(this))
2066                                 CS(this).motd_actived_time = time;
2067                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2068                                 CS(this).motd_actived_time = 0;
2069                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2070                         }
2071                 } else {
2072                         if (PHYS_INPUT_BUTTON_INFO(this))
2073                                 CS(this).motd_actived_time = time;
2074                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2075                                 CS(this).motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2077                         }
2078                 }
2079         }
2080         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2081         {
2082                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2083                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2084                 else if (CS(this).motd_actived_time == -2)
2085                 {
2086                         // instantly hide MOTD
2087                         CS(this).motd_actived_time = 0;
2088                         if (autocvar_g_campaign)
2089                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2090                         else
2091                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2092                 }
2093                 else if (IS_PLAYER(this) || IS_SPEC(this))
2094                 {
2095                         // FIXME occasionally for some reason MOTD never goes away
2096                         // delay MOTD removal a little bit in the hope it fixes this bug
2097                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2098                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2099                         else //if (CS(this).motd_actived_time < -2)
2100                                 CS(this).motd_actived_time++;
2101                 }
2102         }
2103 }
2104
2105 bool joinAllowed(entity this)
2106 {
2107         if (CS(this).version_mismatch) return false;
2108         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2109         if (!nJoinAllowed(this, this)) return false;
2110         if (teamplay && lockteams) return false;
2111         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2112         if (ShowTeamSelection(this)) return false;
2113         return true;
2114 }
2115
2116 .string shootfromfixedorigin;
2117 .bool dualwielding_prev;
2118 bool PlayerThink(entity this)
2119 {
2120         if (game_stopped || intermission_running) {
2121                 this.modelflags &= ~MF_ROCKET;
2122                 if(intermission_running)
2123                         IntermissionThink(this);
2124                 return false;
2125         }
2126
2127         if (timeout_status == TIMEOUT_ACTIVE) {
2128                 // don't allow the player to turn around while game is paused
2129                 // FIXME turn this into CSQC stuff
2130                 this.v_angle = this.lastV_angle;
2131                 this.angles = this.lastV_angle;
2132                 this.fixangle = true;
2133         }
2134
2135         if (frametime) player_powerups(this);
2136
2137         if (IS_DEAD(this)) {
2138                 if (this.personal && g_race_qualifying) {
2139                         if (time > this.respawn_time) {
2140                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2141                                 respawn(this);
2142                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2143                         }
2144                 } else {
2145                         if (frametime) player_anim(this);
2146
2147                         if (this.respawn_flags & RESPAWN_DENY)
2148                         {
2149                                 STAT(RESPAWN_TIME, this) = 0;
2150                                 return false;
2151                         }
2152
2153                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2154
2155                         switch(this.deadflag)
2156                         {
2157                                 case DEAD_DYING:
2158                                 {
2159                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2160                                                 this.deadflag = DEAD_RESPAWNING;
2161                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2162                                                 this.deadflag = DEAD_DEAD;
2163                                         break;
2164                                 }
2165                                 case DEAD_DEAD:
2166                                 {
2167                                         if (button_pressed)
2168                                                 this.deadflag = DEAD_RESPAWNABLE;
2169                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2170                                                 this.deadflag = DEAD_RESPAWNING;
2171                                         break;
2172                                 }
2173                                 case DEAD_RESPAWNABLE:
2174                                 {
2175                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2176                                                 this.deadflag = DEAD_RESPAWNING;
2177                                         break;
2178                                 }
2179                                 case DEAD_RESPAWNING:
2180                                 {
2181                                         if (time > this.respawn_time)
2182                                         {
2183                                                 this.respawn_time = time + 1; // only retry once a second
2184                                                 this.respawn_time_max = this.respawn_time;
2185                                                 respawn(this);
2186                                         }
2187                                         break;
2188                                 }
2189                         }
2190
2191                         ShowRespawnCountdown(this);
2192
2193                         if (this.respawn_flags & RESPAWN_SILENT)
2194                                 STAT(RESPAWN_TIME, this) = 0;
2195                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2196                         {
2197                                 if (time < this.respawn_time)
2198                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2199                                 else if (this.deadflag != DEAD_RESPAWNING)
2200                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2201                         }
2202                         else
2203                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2204                 }
2205
2206                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2207                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2208                         STAT(RESPAWN_TIME, this) *= -1;
2209
2210                 return false;
2211         }
2212
2213         FixPlayermodel(this);
2214
2215         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2216                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2217                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2218         }
2219
2220         // reset gun alignment when dual wielding status changes
2221         // to ensure guns are always aligned right and left
2222         bool dualwielding = W_DualWielding(this);
2223         if(this.dualwielding_prev != dualwielding)
2224         {
2225                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2226                 this.dualwielding_prev = dualwielding;
2227         }
2228
2229         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2230         //if(frametime)
2231         {
2232                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2233                 {
2234                         .entity weaponentity = weaponentities[slot];
2235                         if(WEP_CVAR(vortex, charge_always))
2236                                 W_Vortex_Charge(this, weaponentity, frametime);
2237                         W_WeaponFrame(this, weaponentity);
2238                 }
2239         }
2240
2241         if (frametime)
2242         {
2243                 // WEAPONTODO: Add a weapon request for this
2244                 // rot vortex charge to the charge limit
2245                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2246                 {
2247                         .entity weaponentity = weaponentities[slot];
2248                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2249                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2250                 }
2251
2252                 player_regen(this);
2253                 player_anim(this);
2254                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2255         }
2256
2257         monsters_setstatus(this);
2258
2259         return true;
2260 }
2261
2262 .bool would_spectate;
2263 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2264 void ObserverOrSpectatorThink(entity this)
2265 {
2266         bool is_spec = IS_SPEC(this);
2267         if ( CS(this).impulse )
2268         {
2269                 int r = MinigameImpulse(this, CS(this).impulse);
2270                 if (!is_spec || r)
2271                         CS(this).impulse = 0;
2272
2273                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2274                 {
2275                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2276                         CS(this).impulse = 0;
2277                         return;
2278                 }
2279         }
2280
2281         if (this.flags & FL_JUMPRELEASED) {
2282                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2283                         this.flags &= ~FL_JUMPRELEASED;
2284                         this.flags |= FL_SPAWNING;
2285                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2286                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2287                         this.flags &= ~FL_JUMPRELEASED;
2288                         if(SpectateNext(this)) {
2289                                 TRANSMUTE(Spectator, this);
2290                         } else if (is_spec) {
2291                                 TRANSMUTE(Observer, this);
2292                                 PutClientInServer(this);
2293                         }
2294                         else
2295                                 this.would_spectate = false; // unable to spectate anyone
2296                         if (is_spec)
2297                                 CS(this).impulse = 0;
2298                 } else if (is_spec) {
2299                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2300                                 this.flags &= ~FL_JUMPRELEASED;
2301                                 if(SpectatePrev(this)) {
2302                                         TRANSMUTE(Spectator, this);
2303                                 } else {
2304                                         TRANSMUTE(Observer, this);
2305                                         PutClientInServer(this);
2306                                 }
2307                                 CS(this).impulse = 0;
2308                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2309                                 this.would_spectate = false;
2310                                 this.flags &= ~FL_JUMPRELEASED;
2311                                 TRANSMUTE(Observer, this);
2312                                 PutClientInServer(this);
2313                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2314                                 PutObserverInServer(this, false, true);
2315                                 this.would_spectate = true;
2316                         }
2317                 }
2318                 else {
2319                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2320                         if (PHYS_INPUT_BUTTON_USE(this))
2321                                 wouldclip = !wouldclip;
2322                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2323                         set_movetype(this, preferred_movetype);
2324                 }
2325         } else { // jump pressed
2326                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2327                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2328                         this.flags |= FL_JUMPRELEASED;
2329                         if(this.flags & FL_SPAWNING)
2330                         {
2331                                 this.flags &= ~FL_SPAWNING;
2332                                 if(joinAllowed(this))
2333                                         Join(this);
2334                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2335                                         CS(this).autojoin_checked = -1;
2336                                 return;
2337                         }
2338                 }
2339                 if(is_spec && !SpectateUpdate(this))
2340                         PutObserverInServer(this, false, true);
2341         }
2342         if (is_spec)
2343                 this.flags |= FL_CLIENT | FL_NOTARGET;
2344 }
2345
2346 void PlayerUseKey(entity this)
2347 {
2348         if (!IS_PLAYER(this))
2349                 return;
2350
2351         if(this.vehicle)
2352         {
2353                 if(!game_stopped)
2354                 {
2355                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2356                         return;
2357                 }
2358         }
2359         else if(autocvar_g_vehicles_enter)
2360         {
2361                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2362                 {
2363                         entity head, closest_target = NULL;
2364                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2365
2366                         while(head) // find the closest acceptable target to enter
2367                         {
2368                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2369                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2370                                 {
2371                                         if(closest_target)
2372                                         {
2373                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2374                                                 { closest_target = head; }
2375                                         }
2376                                         else { closest_target = head; }
2377                                 }
2378
2379                                 head = head.chain;
2380                         }
2381
2382                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2383                 }
2384         }
2385
2386         // a use key was pressed; call handlers
2387         MUTATOR_CALLHOOK(PlayerUseKey, this);
2388 }
2389
2390
2391 /*
2392 =============
2393 PlayerPreThink
2394
2395 Called every frame for each client before the physics are run
2396 =============
2397 */
2398 .float last_vehiclecheck;
2399 void PlayerPreThink (entity this)
2400 {
2401         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2402         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2403
2404         WarpZone_PlayerPhysics_FixVAngle(this);
2405
2406         if (frametime) {
2407                 // physics frames: update anticheat stuff
2408                 anticheat_prethink(this);
2409
2410                 // WORKAROUND: only use dropclient in server frames (frametime set).
2411                 // Never use it in cl_movement frames (frametime zero).
2412                 if (blockSpectators && IS_REAL_CLIENT(this)
2413                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2414                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2415                 {
2416                         if (dropclient_schedule(this))
2417                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2418                 }
2419         }
2420
2421         zoomstate_set = false;
2422
2423         // Check for nameless players
2424         if (this.netname == "" || this.netname != CS(this).netname_previous)
2425         {
2426                 bool assume_unchanged = (CS(this).netname_previous == "");
2427                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2428                 {
2429                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2430                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2431                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2432                         assume_unchanged = false;
2433                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2434                 }
2435                 if (isInvisibleString(this.netname))
2436                 {
2437                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2438                         sprint(this, "Warning: invisible names are not allowed.\n");
2439                         assume_unchanged = false;
2440                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2441                 }
2442                 if (!assume_unchanged && autocvar_sv_eventlog)
2443                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2444                 strcpy(CS(this).netname_previous, this.netname);
2445         }
2446
2447         // version nagging
2448         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2449         CS(this).version_nagtime = 0;
2450         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2451             // git client
2452         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2453             // git server
2454             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2455         } else {
2456             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2457             if (r < 0) { // old client
2458                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2459             } else if (r > 0) { // old server
2460                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2461             }
2462         }
2463     }
2464
2465         // GOD MODE info
2466         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2467         {
2468                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2469                 this.max_armorvalue = 0;
2470         }
2471
2472         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2473         {
2474                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2475                 {
2476                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2477                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2478                         if (this.iceblock)
2479                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2480
2481                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2482                                 Unfreeze(this, false);
2483                 }
2484                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2485                 {
2486                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2487                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2488
2489                         if (GetResource(this, RES_HEALTH) < 1)
2490                         {
2491                                 if (this.vehicle)
2492                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2493                                 if(this.event_damage)
2494                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2495                         }
2496                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2497                                 Unfreeze(this, false);
2498                 }
2499         }
2500
2501         MUTATOR_CALLHOOK(PlayerPreThink, this);
2502
2503         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2504         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2505         {
2506                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2507                 {
2508                         if(!it.owner)
2509                         {
2510                                 if(!it.team || SAME_TEAM(this, it))
2511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2512                                 else if(autocvar_g_vehicles_steal)
2513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2514                         }
2515                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2516                         {
2517                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2518                         }
2519                 });
2520
2521                 this.last_vehiclecheck = time + 1;
2522         }
2523
2524         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2525                 PlayerUseKey(this);
2526         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2527
2528         if (IS_REAL_CLIENT(this))
2529                 PrintWelcomeMessage(this);
2530
2531         if (IS_PLAYER(this)) {
2532                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2533                         error("Client can't be spawned as player on connection!");
2534                 if(!PlayerThink(this))
2535                         return;
2536         }
2537         else if (game_stopped || intermission_running) {
2538                 if(intermission_running)
2539                         IntermissionThink(this);
2540                 return;
2541         }
2542         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2543         {
2544                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2545                 CS(this).autojoin_checked = 1;
2546                 // don't do this in ClientConnect
2547                 // many things can go wrong if a client is spawned as player on connection
2548                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2549                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2550                                 && (!teamplay || autocvar_g_balance_teams)))
2551                 {
2552                         campaign_bots_may_start = true;
2553                         if(joinAllowed(this))
2554                                 Join(this);
2555                         return;
2556                 }
2557         }
2558         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2559                 ObserverOrSpectatorThink(this);
2560         }
2561
2562         // WEAPONTODO: Add weapon request for this
2563         if (!zoomstate_set) {
2564                 bool wep_zoomed = false;
2565                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2566                 {
2567                         .entity weaponentity = weaponentities[slot];
2568                         Weapon thiswep = this.(weaponentity).m_weapon;
2569                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2570                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2571                 }
2572                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2573         }
2574
2575         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2576         {
2577                 CS(this).teamkill_soundtime = 0;
2578
2579                 entity e = CS(this).teamkill_soundsource;
2580                 entity oldpusher = e.pusher;
2581                 e.pusher = this;
2582                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2583                 e.pusher = oldpusher;
2584         }
2585
2586         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2587                 CS(this).taunt_soundtime = 0;
2588                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2589         }
2590
2591         target_voicescript_next(this);
2592 }
2593
2594 void DrownPlayer(entity this)
2595 {
2596         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2597                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2598         {
2599                 STAT(AIR_FINISHED, this) = 0;
2600                 return;
2601         }
2602
2603         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2604         {
2605                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2606                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2607                 STAT(AIR_FINISHED, this) = 0;
2608         }
2609         else
2610         {
2611                 if (!STAT(AIR_FINISHED, this))
2612                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2613                 if (STAT(AIR_FINISHED, this) < time)
2614                 {       // drown!
2615                         if (this.pain_finished < time)
2616                         {
2617                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2618                                 this.pain_finished = time + 0.5;
2619                         }
2620                 }
2621         }
2622 }
2623
2624 .bool move_qcphysics;
2625
2626 void Player_Physics(entity this)
2627 {
2628         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2629
2630         if(!this.move_qcphysics)
2631                 return;
2632
2633         if(!frametime && !CS(this).pm_frametime)
2634                 return;
2635
2636         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2637
2638         CS(this).pm_frametime = 0;
2639 }
2640
2641 /*
2642 =============
2643 PlayerPostThink
2644
2645 Called every frame for each client after the physics are run
2646 =============
2647 */
2648 void PlayerPostThink (entity this)
2649 {
2650         Player_Physics(this);
2651
2652         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2653         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2654         if (IS_REAL_CLIENT(this))
2655         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2656         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2657         {
2658                 int totalClients = 0;
2659                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2660                 {
2661                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2662                         if (server_is_dedicated)
2663                         {
2664                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2665                                 {
2666                                         ++totalClients;
2667                                 });
2668                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2669                                         totalClients = 0;
2670                         }
2671                 }
2672                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2673                 {
2674                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2675                         {
2676                                 ++totalClients;
2677                         });
2678                 }
2679
2680                 if (totalClients < autocvar_sv_maxidle_minplayers)
2681                 {
2682                         // idle kick disabled
2683                         CS(this).parm_idlesince = time;
2684                 }
2685                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2686                 {
2687                         if (CS(this).idlekick_lasttimeleft)
2688                         {
2689                                 CS(this).idlekick_lasttimeleft = 0;
2690                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2691                         }
2692                 }
2693                 else
2694                 {
2695                         float maxidle_time = autocvar_sv_maxidle;
2696                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2697                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2698                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2699                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2700                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2701                         {
2702                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2703                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2704                                 else
2705                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2706                         }
2707                         if (timeleft <= 0) {
2708                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2709                                 {
2710                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2711                                         PutObserverInServer(this, true, true);
2712                                 }
2713                                 else
2714                                 {
2715                                         if (dropclient_schedule(this))
2716                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2717                                 }
2718                                 return;
2719                         }
2720                         else if (timeleft <= countdown_time) {
2721                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2722                                         play2(this, SND(TALK2));
2723                                 CS(this).idlekick_lasttimeleft = timeleft;
2724                         }
2725                 }
2726         }
2727
2728         CheatFrame(this);
2729
2730         if (game_stopped)
2731         {
2732                 this.solid = SOLID_NOT;
2733                 this.takedamage = DAMAGE_NO;
2734                 set_movetype(this, MOVETYPE_NONE);
2735                 CS(this).teamkill_complain = 0;
2736                 CS(this).teamkill_soundtime = 0;
2737                 CS(this).teamkill_soundsource = NULL;
2738         }
2739
2740         if (IS_PLAYER(this)) {
2741                 if(this.death_time == time && IS_DEAD(this))
2742                 {
2743                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2744                         // once all the damage events of this frame have been processed with normal size
2745                         this.maxs.z = 5;
2746                         setsize(this, this.mins, this.maxs);
2747                 }
2748                 DrownPlayer(this);
2749                 UpdateChatBubble(this);
2750                 if (CS(this).impulse) ImpulseCommands(this);
2751                 GetPressedKeys(this);
2752                 if (game_stopped)
2753                 {
2754                         CSQCMODEL_AUTOUPDATE(this);
2755                         return;
2756                 }
2757         }
2758         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2759         {
2760                 CS(this).pressedkeys = 0;
2761                 STAT(PRESSED_KEYS, this) = 0;
2762         }
2763
2764         if (this.waypointsprite_attachedforcarrier) {
2765                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2766                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2767         }
2768
2769         CSQCMODEL_AUTOUPDATE(this);
2770 }
2771
2772 // hack to copy the button fields from the client entity to the Client State
2773 void PM_UpdateButtons(entity this, entity store)
2774 {
2775         if(this.impulse)
2776                 store.impulse = this.impulse;
2777         this.impulse = 0;
2778
2779         bool typing = this.buttonchat || this.button12;
2780
2781         store.button0 = (typing) ? 0 : this.button0;
2782         //button1?!
2783         store.button2 = (typing) ? 0 : this.button2;
2784         store.button3 = (typing) ? 0 : this.button3;
2785         store.button4 = this.button4;
2786         store.button5 = (typing) ? 0 : this.button5;
2787         store.button6 = this.button6;
2788         store.button7 = this.button7;
2789         store.button8 = this.button8;
2790         store.button9 = this.button9;
2791         store.button10 = this.button10;
2792         store.button11 = this.button11;
2793         store.button12 = this.button12;
2794         store.button13 = this.button13;
2795         store.button14 = this.button14;
2796         store.button15 = this.button15;
2797         store.button16 = this.button16;
2798         store.buttonuse = this.buttonuse;
2799         store.buttonchat = this.buttonchat;
2800
2801         store.cursor_active = this.cursor_active;
2802         store.cursor_screen = this.cursor_screen;
2803         store.cursor_trace_start = this.cursor_trace_start;
2804         store.cursor_trace_endpos = this.cursor_trace_endpos;
2805         store.cursor_trace_ent = this.cursor_trace_ent;
2806
2807         store.ping = this.ping;
2808         store.ping_packetloss = this.ping_packetloss;
2809         store.ping_movementloss = this.ping_movementloss;
2810
2811         store.v_angle = this.v_angle;
2812         store.movement = this.movement;
2813 }
2814
2815 NET_HANDLE(fpsreport, bool)
2816 {
2817         int fps = ReadShort();
2818         PlayerScore_Set(sender, SP_FPS, fps);
2819         return true;
2820 }