qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         STAT(STRENGTH_FINISHED, this) = 0;
 338         STAT(INVINCIBLE_FINISHED, this) = 0;
 339         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 340         this.air_finished = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_frame = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         STAT(STRENGTH_FINISHED, this) = 0;
 642         STAT(INVINCIBLE_FINISHED, this) = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         this.air_finished = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         this.crouch = false;
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 IL_REMOVE(g_swamped, this);
 691         this.swampslug = NULL;
 692         this.swamp_interval = 0;
 693         IL_EACH(g_counters, it.realowner == this,
 694         {
 695                 delete(it);
 696         });
 697         STAT(HUD, this) = HUD_NORMAL;
 698
 699         this.event_damage = PlayerDamage;
 700         this.event_heal = PlayerHeal;
 701
 702         this.draggable = func_null;
 703
 704         if(!this.bot_attack)
 705                 IL_PUSH(g_bot_targets, this);
 706         this.bot_attack = true;
 707         if(!this.monster_attack)
 708                 IL_PUSH(g_monster_targets, this);
 709         this.monster_attack = true;
 710         navigation_dynamicgoal_init(this, false);
 711
 712         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 713
 714         // player was spectator
 715         if (CS(this).killcount == FRAGS_SPECTATOR) {
 716                 PlayerScore_Clear(this);
 717                 CS(this).killcount = 0;
 718                 CS(this).startplaytime = time;
 719         }
 720
 721         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 722         {
 723                 .entity weaponentity = weaponentities[slot];
 724                 CL_SpawnWeaponentity(this, weaponentity);
 725         }
 726         this.alpha = default_player_alpha;
 727         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 728         this.exteriorweaponentity.alpha = default_weapon_alpha;
 729
 730         this.speedrunning = false;
 731
 732         this.counter_cnt = 0;
 733         this.fragsfilter_cnt = 0;
 734
 735         target_voicescript_clear(this);
 736
 737         // reset fields the weapons may use
 738         FOREACH(Weapons, true, {
 739                 it.wr_resetplayer(it, this);
 740                         // reload all reloadable weapons
 741                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 742                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743                         {
 744                                 .entity weaponentity = weaponentities[slot];
 745                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 746                         }
 747                 }
 748         });
 749
 750         {
 751                 string s = spot.target;
 752                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 753                         spot.target = string_null;
 754                 SUB_UseTargets(spot, this, NULL);
 755                 if(g_assault || g_race)
 756                         spot.target = s;
 757         }
 758
 759         Unfreeze(this, false);
 760
 761         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 762
 763         if (autocvar_spawn_debug)
 764         {
 765                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 766                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 767         }
 768
 769         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770         {
 771                 .entity weaponentity = weaponentities[slot];
 772                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 773                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 774                 else
 775                         this.(weaponentity).m_switchweapon = WEP_Null;
 776                 this.(weaponentity).m_weapon = WEP_Null;
 777                 this.(weaponentity).weaponname = "";
 778                 this.(weaponentity).m_switchingweapon = WEP_Null;
 779                 this.(weaponentity).cnt = -1;
 780         }
 781
 782         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 783
 784         if (CS(this).impulse) ImpulseCommands(this);
 785
 786         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 787         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 788         {
 789                 .entity weaponentity = weaponentities[slot];
 790                 W_WeaponFrame(this, weaponentity);
 791         }
 792
 793         if (!warmup_stage && !this.alivetime)
 794                 this.alivetime = time;
 795
 796         antilag_clear(this, CS(this));
 797 }
 798
 799 /** Called when a client spawns in the server */
 800 void PutClientInServer(entity this)
 801 {
 802         if (IS_BOT_CLIENT(this)) {
 803                 TRANSMUTE(Player, this);
 804         } else if (IS_REAL_CLIENT(this)) {
 805                 msg_entity = this;
 806                 WriteByte(MSG_ONE, SVC_SETVIEW);
 807                 WriteEntity(MSG_ONE, this);
 808         }
 809         if (game_stopped)
 810                 TRANSMUTE(Observer, this);
 811
 812         SetSpectatee(this, NULL);
 813
 814         // reset player keys
 815         if(PS(this))
 816                 PS(this).itemkeys = 0;
 817
 818         MUTATOR_CALLHOOK(PutClientInServer, this);
 819
 820         if (IS_OBSERVER(this)) {
 821                 PutObserverInServer(this);
 822         } else if (IS_PLAYER(this)) {
 823                 PutPlayerInServer(this);
 824         }
 825 }
 826
 827 // TODO do we need all these fields, or should we stop autodetecting runtime
 828 // changes and just have a console command to update this?
 829 bool ClientInit_SendEntity(entity this, entity to, int sf)
 830 {
 831         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 832         return = true;
 833         msg_entity = to;
 834         // MSG_INIT replacement
 835         // TODO: make easier to use
 836         Registry_send_all();
 837         W_PROP_reload(MSG_ONE, to);
 838         ClientInit_misc(this);
 839         MUTATOR_CALLHOOK(Ent_Init);
 840 }
 841 void ClientInit_misc(entity this)
 842 {
 843         int channel = MSG_ONE;
 844         WriteHeader(channel, ENT_CLIENT_INIT);
 845         WriteByte(channel, g_nexball_meter_period * 32);
 846         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 850         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 854
 855         if(sv_foginterval && world.fog != "")
 856                 WriteString(channel, world.fog);
 857         else
 858                 WriteString(channel, "");
 859         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 860         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 861         WriteByte(channel, serverflags);
 862         WriteCoord(channel, autocvar_g_trueaim_minrange);
 863 }
 864
 865 void ClientInit_CheckUpdate(entity this)
 866 {
 867         this.nextthink = time;
 868         if(this.count != autocvar_g_balance_armor_blockpercent)
 869         {
 870                 this.count = autocvar_g_balance_armor_blockpercent;
 871                 this.SendFlags |= 1;
 872         }
 873         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 874         {
 875                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 876                 this.SendFlags |= 1;
 877         }
 878 }
 879
 880 void ClientInit_Spawn()
 881 {
 882         entity e = new_pure(clientinit);
 883         setthink(e, ClientInit_CheckUpdate);
 884         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 885
 886         ClientInit_CheckUpdate(e);
 887 }
 888
 889 /*
 890 =============
 891 SetNewParms
 892 =============
 893 */
 894 void SetNewParms ()
 895 {
 896         // initialize parms for a new player
 897         parm1 = -(86400 * 366);
 898
 899         MUTATOR_CALLHOOK(SetNewParms);
 900 }
 901
 902 /*
 903 =============
 904 SetChangeParms
 905 =============
 906 */
 907 void SetChangeParms (entity this)
 908 {
 909         // save parms for level change
 910         parm1 = CS(this).parm_idlesince - time;
 911
 912         MUTATOR_CALLHOOK(SetChangeParms);
 913 }
 914
 915 /*
 916 =============
 917 DecodeLevelParms
 918 =============
 919 */
 920 void DecodeLevelParms(entity this)
 921 {
 922         // load parms
 923         CS(this).parm_idlesince = parm1;
 924         if (CS(this).parm_idlesince == -(86400 * 366))
 925                 CS(this).parm_idlesince = time;
 926
 927         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 928         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 929
 930         MUTATOR_CALLHOOK(DecodeLevelParms);
 931 }
 932
 933 void FixClientCvars(entity e)
 934 {
 935         // send prediction settings to the client
 936         stuffcmd(e, "\nin_bindmap 0 0\n");
 937         if(autocvar_g_antilag == 3) // client side hitscan
 938                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 939         if(autocvar_sv_gentle)
 940                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 941
 942         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 943         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 944
 945         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 946
 947         MUTATOR_CALLHOOK(FixClientCvars, e);
 948 }
 949
 950 bool findinlist_abbrev(string tofind, string list)
 951 {
 952         if(list == "" || tofind == "")
 953                 return false; // empty list or search, just return
 954
 955         // this function allows abbreviated strings!
 956         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 957         {
 958                 return true;
 959         });
 960
 961         return false;
 962 }
 963
 964 bool PlayerInIPList(entity p, string iplist)
 965 {
 966         // some safety checks (never allow local?)
 967         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 968                 return false;
 969
 970         return findinlist_abbrev(p.netaddress, iplist);
 971 }
 972
 973 bool PlayerInIDList(entity p, string idlist)
 974 {
 975         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 976         if(!p.crypto_idfp)
 977                 return false;
 978
 979         return findinlist_abbrev(p.crypto_idfp, idlist);
 980 }
 981
 982 bool PlayerInList(entity player, string list)
 983 {
 984         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 985 }
 986
 987 #ifdef DP_EXT_PRECONNECT
 988 /*
 989 =============
 990 ClientPreConnect
 991
 992 Called once (not at each match start) when a client begins a connection to the server
 993 =============
 994 */
 995 void ClientPreConnect(entity this)
 996 {
 997         if(autocvar_sv_eventlog)
 998         {
 999                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1000                         this.playerid,
1001                         etof(this),
1002                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1003                 ));
1004         }
1005 }
1006 #endif
1007
1008 string GetClientVersionMessage(entity this)
1009 {
1010         if (CS(this).version_mismatch) {
1011                 if(CS(this).version < autocvar_gameversion) {
1012                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1013                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1014                 } else {
1015                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1016                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1017                 }
1018         } else {
1019                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1020         }
1021 }
1022
1023 string getwelcomemessage(entity this)
1024 {
1025         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1026         string modifications = M_ARGV(0, string);
1027
1028         if(g_weaponarena)
1029         {
1030                 if(g_weaponarena_random)
1031                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1032                 else
1033                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1034         }
1035         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1036                 modifications = strcat(modifications, ", No start weapons");
1037         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1038                 modifications = strcat(modifications, ", Low gravity");
1039         if(g_weapon_stay && !g_cts)
1040                 modifications = strcat(modifications, ", Weapons stay");
1041         if(g_jetpack)
1042                 modifications = strcat(modifications, ", Jet pack");
1043         if(autocvar_g_powerups == 0)
1044                 modifications = strcat(modifications, ", No powerups");
1045         if(autocvar_g_powerups > 0)
1046                 modifications = strcat(modifications, ", Powerups");
1047         modifications = substring(modifications, 2, strlen(modifications) - 2);
1048
1049         string versionmessage = GetClientVersionMessage(this);
1050         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1051
1052         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1053
1054         if(modifications != "")
1055                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1056
1057         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1058         {
1059                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1060                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1061         }
1062
1063         if (cache_mutatormsg != "") {
1064                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1065         }
1066
1067         string mutator_msg = "";
1068         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1069         mutator_msg = M_ARGV(0, string);
1070
1071         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1072
1073         string motd = autocvar_sv_motd;
1074         if (motd != "") {
1075                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1076         }
1077         return s;
1078 }
1079
1080 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1081
1082 /**
1083 =============
1084 ClientConnect
1085
1086 Called when a client connects to the server
1087 =============
1088 */
1089 void ClientConnect(entity this)
1090 {
1091         if (Ban_MaybeEnforceBanOnce(this)) return;
1092         assert(!IS_CLIENT(this), return);
1093         this.flags |= FL_CLIENT;
1094         assert(player_count >= 0, player_count = 0);
1095
1096 #ifdef WATERMARK
1097         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1098 #endif
1099         TRANSMUTE(Client, this);
1100         CS(this).version_nagtime = time + 10 + random() * 10;
1101
1102         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1103
1104         bot_clientconnect(this);
1105
1106         Player_DetermineForcedTeam(this);
1107
1108         TRANSMUTE(Observer, this);
1109
1110         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1111
1112         // always track bots, don't ask for cl_allow_uidtracking
1113         if (IS_BOT_CLIENT(this))
1114                 PlayerStats_GameReport_AddPlayer(this);
1115         else
1116                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1117
1118         if (autocvar_sv_eventlog)
1119                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1120
1121         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1122
1123         stuffcmd(this, clientstuff, "\n");
1124         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1125
1126         FixClientCvars(this);
1127
1128         // get version info from player
1129         stuffcmd(this, "cmd clientversion $gameversion\n");
1130
1131         // notify about available teams
1132         if (teamplay)
1133         {
1134                 entity balance = TeamBalance_CheckAllowedTeams(this);
1135                 int t = TeamBalance_GetAllowedTeams(balance);
1136                 TeamBalance_Destroy(balance);
1137                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1138         }
1139         else
1140         {
1141                 stuffcmd(this, "set _teams_available 0\n");
1142         }
1143
1144         bot_relinkplayerlist();
1145
1146         CS(this).spectatortime = time;
1147         if (blockSpectators)
1148         {
1149                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1150         }
1151
1152         CS(this).jointime = time;
1153
1154         if (IS_REAL_CLIENT(this))
1155         {
1156                 if (g_weaponarena_weapons == WEPSET(TUBA))
1157                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1158         }
1159
1160         if (!sv_foginterval && world.fog != "")
1161                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1162
1163         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1164                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1165                         send_CSQC_teamnagger();
1166
1167         CSQCMODEL_AUTOINIT(this);
1168
1169         CS(this).model_randomizer = random();
1170
1171         if (IS_REAL_CLIENT(this))
1172                 sv_notice_join(this);
1173
1174         this.move_qcphysics = autocvar_sv_qcphysics;
1175
1176         // update physics stats (players can spawn before physics runs)
1177         Physics_UpdateStats(this);
1178
1179         IL_EACH(g_initforplayer, it.init_for_player, {
1180                 it.init_for_player(it, this);
1181         });
1182
1183         Handicap_Initialize(this);
1184
1185         MUTATOR_CALLHOOK(ClientConnect, this);
1186
1187         if (IS_REAL_CLIENT(this))
1188         {
1189                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1190                 {
1191                         CS(this).motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1193                 }
1194         }
1195 }
1196 /*
1197 =============
1198 ClientDisconnect
1199
1200 Called when a client disconnects from the server
1201 =============
1202 */
1203 .entity chatbubbleentity;
1204 void ClientDisconnect(entity this)
1205 {
1206         assert(IS_CLIENT(this), return);
1207
1208         PlayerStats_GameReport_FinalizePlayer(this);
1209         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1210         if (CS(this).active_minigame) part_minigame(this);
1211         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1212
1213         if (autocvar_sv_eventlog)
1214                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1215
1216         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1217
1218         if(IS_SPEC(this))
1219                 SetSpectatee(this, NULL);
1220
1221     MUTATOR_CALLHOOK(ClientDisconnect, this);
1222
1223         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1224         strfree(CS(this).weaponorder_byimpulse);
1225         ClientState_detach(this);
1226
1227         Portal_ClearAll(this);
1228
1229         Unfreeze(this, false);
1230
1231         RemoveGrapplingHooks(this);
1232
1233         // Here, everything has been done that requires this player to be a client.
1234
1235         this.flags &= ~FL_CLIENT;
1236
1237         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1238         if (this.killindicator) delete(this.killindicator);
1239
1240         IL_EACH(g_counters, it.realowner == this,
1241         {
1242                 delete(it);
1243         });
1244
1245         WaypointSprite_PlayerGone(this);
1246
1247         bot_relinkplayerlist();
1248
1249         strfree(this.clientstatus);
1250         if (this.personal) delete(this.personal);
1251
1252         this.playerid = 0;
1253         ReadyCount();
1254         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1255
1256         ONREMOVE(this);
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307
1308 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1309 // added to the model skins
1310 /*void UpdateColorModHack()
1311 {
1312         float c;
1313         c = this.clientcolors & 15;
1314         // LordHavoc: only bothering to support white, green, red, yellow, blue
1315              if (!teamplay) this.colormod = '0 0 0';
1316         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1317         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1318         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1319         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1320         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1321         else this.colormod = '1 1 1';
1322 }*/
1323
1324 void respawn(entity this)
1325 {
1326         if(this.alpha >= 0)
1327         {
1328                 if(autocvar_g_respawn_ghosts)
1329                 {
1330                         this.solid = SOLID_NOT;
1331                         this.takedamage = DAMAGE_NO;
1332                         set_movetype(this, MOVETYPE_FLY);
1333                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1334                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1335                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1336                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1337                         if(autocvar_g_respawn_ghosts_maxtime)
1338                                 SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1339                 }
1340                 else
1341                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1342         }
1343
1344         CopyBody(this, 1);
1345
1346         this.effects |= EF_NODRAW; // prevent another CopyBody
1347         PutClientInServer(this);
1348 }
1349
1350 ERASEABLE
1351 void PrintToChat(entity client, string text)
1352 {
1353         text = strcat("\{1}^7", text, "\n");
1354         sprint(client, text);
1355 }
1356
1357 ERASEABLE
1358 void DebugPrintToChat(entity client, string text)
1359 {
1360         if (autocvar_developer > 0)
1361         {
1362                 PrintToChat(client, text);
1363         }
1364 }
1365
1366 ERASEABLE
1367 void PrintToChatAll(string text)
1368 {
1369         text = strcat("\{1}^7", text, "\n");
1370         bprint(text);
1371 }
1372
1373 ERASEABLE
1374 void DebugPrintToChatAll(string text)
1375 {
1376         if (autocvar_developer > 0)
1377         {
1378                 PrintToChatAll(text);
1379         }
1380 }
1381
1382 ERASEABLE
1383 void PrintToChatTeam(int team_num, string text)
1384 {
1385         text = strcat("\{1}^7", text, "\n");
1386         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1387         {
1388                 if (it.team == team_num)
1389                 {
1390                         sprint(it, text);
1391                 }
1392         });
1393 }
1394
1395 ERASEABLE
1396 void DebugPrintToChatTeam(int team_num, string text)
1397 {
1398         if (autocvar_developer > 0)
1399         {
1400                 PrintToChatTeam(team_num, text);
1401         }
1402 }
1403
1404 void play_countdown(entity this, float finished, Sound samp)
1405 {
1406         TC(Sound, samp);
1407         if(IS_REAL_CLIENT(this))
1408                 if(floor(finished - time - frametime) != floor(finished - time))
1409                         if(finished - time < 6)
1410                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1411 }
1412
1413 void player_powerups(entity this)
1414 {
1415         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1416                 this.modelflags |= MF_ROCKET;
1417         else
1418                 this.modelflags &= ~MF_ROCKET;
1419
1420         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1421
1422         if (IS_DEAD(this))
1423         {
1424                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1425                 {
1426                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1427                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1428                         this.items &= ~ITEM_Strength.m_itemid;
1429                         this.items &= ~ITEM_Shield.m_itemid;
1430                         this.items -= (this.items & IT_SUPERWEAPON);
1431                 }
1432         }
1433
1434         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1435                 return;
1436
1437         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1438         int items_prev = this.items;
1439
1440         Fire_ApplyDamage(this);
1441         Fire_ApplyEffect(this);
1442
1443         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1444         {
1445                 if (this.items & ITEM_Strength.m_itemid)
1446                 {
1447                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1448                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1449                         if (time > STAT(STRENGTH_FINISHED, this))
1450                         {
1451                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1452                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1453                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1454                         }
1455                 }
1456                 else
1457                 {
1458                         if (time < STAT(STRENGTH_FINISHED, this))
1459                         {
1460                                 this.items = this.items | ITEM_Strength.m_itemid;
1461                                 if(!g_cts)
1462                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1463                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1464                         }
1465                 }
1466                 if (this.items & ITEM_Shield.m_itemid)
1467                 {
1468                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1469                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1470                         if (time > STAT(INVINCIBLE_FINISHED, this))
1471                         {
1472                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1473                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1474                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1475                         }
1476                 }
1477                 else
1478                 {
1479                         if (time < STAT(INVINCIBLE_FINISHED, this))
1480                         {
1481                                 this.items = this.items | ITEM_Shield.m_itemid;
1482                                 if(!g_cts)
1483                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1484                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1485                         }
1486                 }
1487                 if (this.items & IT_SUPERWEAPON)
1488                 {
1489                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1490                         {
1491                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1492                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1493                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1494                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1495                         }
1496                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1497                         {
1498                                 // don't let them run out
1499                         }
1500                         else
1501                         {
1502                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1503                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1504                                 {
1505                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1506                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1507                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1508                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1509                                 }
1510                         }
1511                 }
1512                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1513                 {
1514                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1515                         {
1516                                 this.items = this.items | IT_SUPERWEAPON;
1517                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1518                                 {
1519                                         if(!g_cts)
1520                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1521                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1522                                 }
1523                         }
1524                         else
1525                         {
1526                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1527                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1528                         }
1529                 }
1530                 else
1531                 {
1532                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1533                 }
1534         }
1535
1536         if(autocvar_g_nodepthtestplayers)
1537                 this.effects = this.effects | EF_NODEPTHTEST;
1538
1539         if(autocvar_g_fullbrightplayers)
1540                 this.effects = this.effects | EF_FULLBRIGHT;
1541
1542         if (time >= game_starttime)
1543         if (time < this.spawnshieldtime)
1544                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1545
1546         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1547 }
1548
1549 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1550 {
1551         if(current > stable)
1552                 return current;
1553         else if(current > stable - 0.25) // when close enough, "snap"
1554                 return stable;
1555         else
1556                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1557 }
1558
1559 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1560 {
1561         if(current < stable)
1562                 return current;
1563         else if(current < stable + 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1567 }
1568
1569 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1570 {
1571         float old = GetResource(this, res);
1572         float current = old;
1573         if(current > rotstable)
1574         {
1575                 if(rotframetime > 0)
1576                 {
1577                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1578                         current = max(rotstable, current - rotlinear * rotframetime);
1579                 }
1580         }
1581         else if(current < regenstable)
1582         {
1583                 if(regenframetime > 0)
1584                 {
1585                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1586                         current = min(regenstable, current + regenlinear * regenframetime);
1587                 }
1588         }
1589
1590         float limit = GetResourceLimit(this, res) * limit_mod;
1591         if(current > limit)
1592                 current = limit;
1593
1594         if (current != old)
1595                 SetResource(this, res, current);
1596 }
1597
1598 void player_regen(entity this)
1599 {
1600         float max_mod, regen_mod, rot_mod, limit_mod;
1601         max_mod = regen_mod = rot_mod = limit_mod = 1;
1602
1603         float regen_health = autocvar_g_balance_health_regen;
1604         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1605         float regen_health_rot = autocvar_g_balance_health_rot;
1606         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1607         float regen_health_stable = autocvar_g_balance_health_regenstable;
1608         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1609         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1610                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1611         max_mod = M_ARGV(1, float);
1612         regen_mod = M_ARGV(2, float);
1613         rot_mod = M_ARGV(3, float);
1614         limit_mod = M_ARGV(4, float);
1615         regen_health = M_ARGV(5, float);
1616         regen_health_linear = M_ARGV(6, float);
1617         regen_health_rot = M_ARGV(7, float);
1618         regen_health_rotlinear = M_ARGV(8, float);
1619         regen_health_stable = M_ARGV(9, float);
1620         regen_health_rotstable = M_ARGV(10, float);
1621
1622         if(!mutator_returnvalue)
1623         if(!STAT(FROZEN, this))
1624         {
1625                 float maxa = autocvar_g_balance_armor_rotstable;
1626                 float mina = autocvar_g_balance_armor_regenstable;
1627
1628                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1629                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1630                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1631
1632                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1633                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1634                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1635         }
1636
1637         // if player rotted to death...  die!
1638         // check this outside above checks, as player may still be able to rot to death
1639         if(GetResource(this, RES_HEALTH) < 1)
1640         {
1641                 if(this.vehicle)
1642                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1643                 if(this.event_damage)
1644                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1645         }
1646
1647         if (!(this.items & IT_UNLIMITED_AMMO))
1648         {
1649                 float maxf = autocvar_g_balance_fuel_rotstable;
1650                 float minf = autocvar_g_balance_fuel_regenstable;
1651
1652                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1653                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1654                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1655         }
1656 }
1657
1658 bool zoomstate_set;
1659 void SetZoomState(entity this, float newzoom)
1660 {
1661         if(newzoom != CS(this).zoomstate)
1662         {
1663                 CS(this).zoomstate = newzoom;
1664                 ClientData_Touch(this);
1665         }
1666         zoomstate_set = true;
1667 }
1668
1669 void GetPressedKeys(entity this)
1670 {
1671         MUTATOR_CALLHOOK(GetPressedKeys, this);
1672         int keys = STAT(PRESSED_KEYS, this);
1673         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1674         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1675         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1676         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1677
1678         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1679         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1680         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1681         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1682         CS(this).pressedkeys = keys; // store for other users
1683
1684         STAT(PRESSED_KEYS, this) = keys;
1685 }
1686
1687 /*
1688 ======================
1689 spectate mode routines
1690 ======================
1691 */
1692
1693 void SpectateCopy(entity this, entity spectatee)
1694 {
1695         TC(Client, this); TC(Client, spectatee);
1696
1697         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1698         PS(this) = PS(spectatee);
1699         this.armortype = spectatee.armortype;
1700         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1701         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1702         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1703         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1704         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1705         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1706         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1707         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1708         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1709         CS(this).impulse = 0;
1710         this.disableclientprediction = 1; // no need to run prediction on a spectator
1711         this.items = spectatee.items;
1712         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1713         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1714         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1715         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1716         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1717         this.air_finished = spectatee.air_finished;
1718         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1719         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1720         this.punchangle = spectatee.punchangle;
1721         this.view_ofs = spectatee.view_ofs;
1722         this.velocity = spectatee.velocity;
1723         this.dmg_take = spectatee.dmg_take;
1724         this.dmg_save = spectatee.dmg_save;
1725         this.dmg_inflictor = spectatee.dmg_inflictor;
1726         this.v_angle = spectatee.v_angle;
1727         this.angles = spectatee.v_angle;
1728         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1729         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1730         this.viewloc = spectatee.viewloc;
1731         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1732                 this.fixangle = true;
1733         setorigin(this, spectatee.origin);
1734         setsize(this, spectatee.mins, spectatee.maxs);
1735         SetZoomState(this, CS(spectatee).zoomstate);
1736
1737     anticheat_spectatecopy(this, spectatee);
1738         STAT(HUD, this) = STAT(HUD, spectatee);
1739         if(spectatee.vehicle)
1740     {
1741         this.angles = spectatee.v_angle;
1742
1743         //this.fixangle = false;
1744         //this.velocity = spectatee.vehicle.velocity;
1745         this.vehicle_health = spectatee.vehicle_health;
1746         this.vehicle_shield = spectatee.vehicle_shield;
1747         this.vehicle_energy = spectatee.vehicle_energy;
1748         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1749         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1750         this.vehicle_reload1 = spectatee.vehicle_reload1;
1751         this.vehicle_reload2 = spectatee.vehicle_reload2;
1752
1753         //msg_entity = this;
1754
1755        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1756             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1757            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1758            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1759
1760         //WriteByte (MSG_ONE, SVC_SETVIEW);
1761         //    WriteEntity(MSG_ONE, this);
1762         //makevectors(spectatee.v_angle);
1763         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1764     }
1765 }
1766
1767 bool SpectateUpdate(entity this)
1768 {
1769         if(!this.enemy)
1770                 return false;
1771
1772         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1773         {
1774                 SetSpectatee(this, NULL);
1775                 return false;
1776         }
1777
1778         SpectateCopy(this, this.enemy);
1779
1780         return true;
1781 }
1782
1783 bool SpectateSet(entity this)
1784 {
1785         if(!IS_PLAYER(this.enemy))
1786                 return false;
1787
1788         ClientData_Touch(this.enemy);
1789
1790         msg_entity = this;
1791         WriteByte(MSG_ONE, SVC_SETVIEW);
1792         WriteEntity(MSG_ONE, this.enemy);
1793         set_movetype(this, MOVETYPE_NONE);
1794         accuracy_resend(this);
1795
1796         if(!SpectateUpdate(this))
1797                 PutObserverInServer(this);
1798
1799         return true;
1800 }
1801
1802 void SetSpectatee_status(entity this, int spectatee_num)
1803 {
1804         int oldspectatee_status = CS(this).spectatee_status;
1805         CS(this).spectatee_status = spectatee_num;
1806
1807         if (CS(this).spectatee_status != oldspectatee_status)
1808         {
1809                 if (STAT(PRESSED_KEYS, this))
1810                 {
1811                         CS(this).pressedkeys = 0;
1812                         STAT(PRESSED_KEYS, this) = 0;
1813                 }
1814                 ClientData_Touch(this);
1815                 if (g_race || g_cts) race_InitSpectator();
1816         }
1817 }
1818
1819 void SetSpectatee(entity this, entity spectatee)
1820 {
1821         if(IS_BOT_CLIENT(this))
1822                 return; // bots abuse .enemy, this code is useless to them
1823
1824         entity old_spectatee = this.enemy;
1825
1826         this.enemy = spectatee;
1827
1828         // WEAPONTODO
1829         // these are required to fix the spectator bug with arc
1830         if(old_spectatee)
1831         {
1832                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1833                 {
1834                         .entity weaponentity = weaponentities[slot];
1835                         if(old_spectatee.(weaponentity).arc_beam)
1836                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1837                 }
1838         }
1839         if(this.enemy)
1840         {
1841                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1842                 {
1843                         .entity weaponentity = weaponentities[slot];
1844                         if(this.enemy.(weaponentity).arc_beam)
1845                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1846                 }
1847         }
1848
1849         if (this.enemy)
1850                 SetSpectatee_status(this, etof(this.enemy));
1851
1852         // needed to update spectator list
1853         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1854 }
1855
1856 bool Spectate(entity this, entity pl)
1857 {
1858         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1859                 return false;
1860         pl = M_ARGV(1, entity);
1861
1862         SetSpectatee(this, pl);
1863         return SpectateSet(this);
1864 }
1865
1866 bool SpectateNext(entity this)
1867 {
1868         entity ent = find(this.enemy, classname, STR_PLAYER);
1869
1870         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1871                 ent = M_ARGV(1, entity);
1872         else if (!ent)
1873                 ent = find(ent, classname, STR_PLAYER);
1874
1875         if(ent) { SetSpectatee(this, ent); }
1876
1877         return SpectateSet(this);
1878 }
1879
1880 bool SpectatePrev(entity this)
1881 {
1882         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1883         entity ent = findchain(classname, STR_PLAYER);
1884         if (!ent) // no player
1885                 return false;
1886
1887         entity first = ent;
1888         // skip players until current spectated player
1889         if(this.enemy)
1890         while(ent && ent != this.enemy)
1891                 ent = ent.chain;
1892
1893         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1894         {
1895                 case MUT_SPECPREV_FOUND:
1896                     ent = M_ARGV(1, entity);
1897                     break;
1898                 case MUT_SPECPREV_RETURN:
1899                     return true;
1900                 case MUT_SPECPREV_CONTINUE:
1901                 default:
1902                 {
1903                         if(ent.chain)
1904                                 ent = ent.chain;
1905                         else
1906                                 ent = first;
1907                         break;
1908                 }
1909         }
1910
1911         SetSpectatee(this, ent);
1912         return SpectateSet(this);
1913 }
1914
1915 /*
1916 =============
1917 ShowRespawnCountdown()
1918
1919 Update a respawn countdown display.
1920 =============
1921 */
1922 void ShowRespawnCountdown(entity this)
1923 {
1924         float number;
1925         if(!IS_DEAD(this)) // just respawned?
1926                 return;
1927         else
1928         {
1929                 number = ceil(this.respawn_time - time);
1930                 if(number <= 0)
1931                         return;
1932                 if(number <= this.respawn_countdown)
1933                 {
1934                         this.respawn_countdown = number - 1;
1935                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1936                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1937                 }
1938         }
1939 }
1940
1941 .bool team_selected;
1942 bool ShowTeamSelection(entity this)
1943 {
1944         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1945                 return false;
1946         stuffcmd(this, "menu_showteamselect\n");
1947         return true;
1948 }
1949 void Join(entity this)
1950 {
1951         TRANSMUTE(Player, this);
1952
1953         if(!this.team_selected)
1954         if(autocvar_g_campaign || autocvar_g_balance_teams)
1955                 TeamBalance_JoinBestTeam(this);
1956
1957         if(autocvar_g_campaign)
1958                 campaign_bots_may_start = true;
1959
1960         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1961
1962         PutClientInServer(this);
1963
1964         if(IS_PLAYER(this))
1965         if(teamplay && this.team != -1)
1966         {
1967         }
1968         else
1969                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1970         this.team_selected = false;
1971 }
1972
1973 int GetPlayerLimit()
1974 {
1975         if(g_duel)
1976                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1977         int player_limit = autocvar_g_maxplayers;
1978         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1979         player_limit = M_ARGV(0, int);
1980         return player_limit;
1981 }
1982
1983 /**
1984  * Determines whether the player is allowed to join. This depends on cvar
1985  * g_maxplayers, if it isn't used this function always return true, otherwise
1986  * it checks whether the number of currently playing players exceeds g_maxplayers.
1987  * @return int number of free slots for players, 0 if none
1988  */
1989 int nJoinAllowed(entity this, entity ignore)
1990 {
1991         if(!ignore)
1992         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1993         // so report 0 free slots if restricted
1994         {
1995                 if(autocvar_g_forced_team_otherwise == "spectate")
1996                         return 0;
1997                 if(autocvar_g_forced_team_otherwise == "spectator")
1998                         return 0;
1999         }
2000
2001         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2002                 return 0; // forced spectators can never join
2003
2004         // TODO simplify this
2005         int totalClients = 0;
2006         int currentlyPlaying = 0;
2007         FOREACH_CLIENT(true, {
2008                 if(it != ignore)
2009                         ++totalClients;
2010                 if(IS_REAL_CLIENT(it))
2011                 if(IS_PLAYER(it) || it.caplayer)
2012                         ++currentlyPlaying;
2013         });
2014
2015         int player_limit = GetPlayerLimit();
2016
2017         float free_slots = 0;
2018         if (!player_limit)
2019                 free_slots = maxclients - totalClients;
2020         else if(currentlyPlaying < player_limit)
2021                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2022
2023         static float msg_time = 0;
2024         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2025         {
2026                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2027                 msg_time = time + 0.5;
2028         }
2029
2030         return free_slots;
2031 }
2032
2033 /**
2034  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2035  * g_maxplayers_spectator_blocktime seconds
2036  */
2037 void checkSpectatorBlock(entity this)
2038 {
2039         if(IS_SPEC(this) || IS_OBSERVER(this))
2040         if(!this.caplayer)
2041         if(IS_REAL_CLIENT(this))
2042         {
2043                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2044                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2045                         dropclient(this);
2046                 }
2047         }
2048 }
2049
2050 void PrintWelcomeMessage(entity this)
2051 {
2052         if(CS(this).motd_actived_time == 0)
2053         {
2054                 if (autocvar_g_campaign) {
2055                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2056                                 CS(this).motd_actived_time = time;
2057                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2058                         }
2059                 } else {
2060                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2061                                 CS(this).motd_actived_time = time;
2062                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2063                         }
2064                 }
2065         }
2066         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2067         {
2068                 if (autocvar_g_campaign) {
2069                         if (PHYS_INPUT_BUTTON_INFO(this))
2070                                 CS(this).motd_actived_time = time;
2071                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2072                                 CS(this).motd_actived_time = 0;
2073                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2074                         }
2075                 } else {
2076                         if (PHYS_INPUT_BUTTON_INFO(this))
2077                                 CS(this).motd_actived_time = time;
2078                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2079                                 CS(this).motd_actived_time = 0;
2080                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2081                         }
2082                 }
2083         }
2084         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2085         {
2086                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2087                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2088                 else if (CS(this).motd_actived_time == -2)
2089                 {
2090                         // instantly hide MOTD
2091                         CS(this).motd_actived_time = 0;
2092                         if (autocvar_g_campaign)
2093                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2094                         else
2095                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2096                 }
2097                 else if (IS_PLAYER(this) || IS_SPEC(this))
2098                 {
2099                         // FIXME occasionally for some reason MOTD never goes away
2100                         // delay MOTD removal a little bit in the hope it fixes this bug
2101                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2102                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2103                         else //if (CS(this).motd_actived_time < -2)
2104                                 CS(this).motd_actived_time++;
2105                 }
2106         }
2107 }
2108
2109 const int MIN_SPEC_TIME = 1;
2110 bool joinAllowed(entity this)
2111 {
2112         if (CS(this).version_mismatch) return false;
2113         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2114         if (!nJoinAllowed(this, this)) return false;
2115         if (teamplay && lockteams) return false;
2116         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2117         if (ShowTeamSelection(this)) return false;
2118         return true;
2119 }
2120
2121 .string shootfromfixedorigin;
2122 .bool dualwielding_prev;
2123 bool PlayerThink(entity this)
2124 {
2125         if (game_stopped || intermission_running) {
2126                 this.modelflags &= ~MF_ROCKET;
2127                 if(intermission_running)
2128                         IntermissionThink(this);
2129                 return false;
2130         }
2131
2132         if (timeout_status == TIMEOUT_ACTIVE) {
2133         // don't allow the player to turn around while game is paused
2134                 // FIXME turn this into CSQC stuff
2135                 this.v_angle = this.lastV_angle;
2136                 this.angles = this.lastV_angle;
2137                 this.fixangle = true;
2138         }
2139
2140         if (frametime) player_powerups(this);
2141
2142         if (IS_DEAD(this)) {
2143                 if (this.personal && g_race_qualifying) {
2144                         if (time > this.respawn_time) {
2145                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2146                                 respawn(this);
2147                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2148                         }
2149                 } else {
2150                         if (frametime) player_anim(this);
2151
2152                         if (this.respawn_flags & RESPAWN_DENY)
2153                         {
2154                                 STAT(RESPAWN_TIME, this) = 0;
2155                                 return false;
2156                         }
2157
2158                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2159
2160                         switch(this.deadflag)
2161                         {
2162                                 case DEAD_DYING:
2163                                 {
2164                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2165                                                 this.deadflag = DEAD_RESPAWNING;
2166                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2167                                                 this.deadflag = DEAD_DEAD;
2168                                         break;
2169                                 }
2170                                 case DEAD_DEAD:
2171                                 {
2172                                         if (button_pressed)
2173                                                 this.deadflag = DEAD_RESPAWNABLE;
2174                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2175                                                 this.deadflag = DEAD_RESPAWNING;
2176                                         break;
2177                                 }
2178                                 case DEAD_RESPAWNABLE:
2179                                 {
2180                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2181                                                 this.deadflag = DEAD_RESPAWNING;
2182                                         break;
2183                                 }
2184                                 case DEAD_RESPAWNING:
2185                                 {
2186                                         if (time > this.respawn_time)
2187                                         {
2188                                                 this.respawn_time = time + 1; // only retry once a second
2189                                                 this.respawn_time_max = this.respawn_time;
2190                                                 respawn(this);
2191                                         }
2192                                         break;
2193                                 }
2194                         }
2195
2196                         ShowRespawnCountdown(this);
2197
2198                         if (this.respawn_flags & RESPAWN_SILENT)
2199                                 STAT(RESPAWN_TIME, this) = 0;
2200                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2201                         {
2202                                 if (time < this.respawn_time)
2203                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2204                                 else if (this.deadflag != DEAD_RESPAWNING)
2205                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2206                         }
2207                         else
2208                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2209                 }
2210
2211                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2212                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2213                         STAT(RESPAWN_TIME, this) *= -1;
2214
2215                 return false;
2216         }
2217
2218         FixPlayermodel(this);
2219
2220         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2221                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2222                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2223         }
2224
2225         // reset gun alignment when dual wielding status changes
2226         // to ensure guns are always aligned right and left
2227         bool dualwielding = W_DualWielding(this);
2228         if(this.dualwielding_prev != dualwielding)
2229         {
2230                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2231                 this.dualwielding_prev = dualwielding;
2232         }
2233
2234         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2235         //if(frametime)
2236         {
2237                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2238                 {
2239                         .entity weaponentity = weaponentities[slot];
2240                         if(WEP_CVAR(vortex, charge_always))
2241                                 W_Vortex_Charge(this, weaponentity, frametime);
2242                         W_WeaponFrame(this, weaponentity);
2243                 }
2244         }
2245
2246         if (frametime)
2247         {
2248                 // WEAPONTODO: Add a weapon request for this
2249                 // rot vortex charge to the charge limit
2250                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2251                 {
2252                         .entity weaponentity = weaponentities[slot];
2253                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2254                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2255                 }
2256
2257                 player_regen(this);
2258                 player_anim(this);
2259                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2260         }
2261
2262         secrets_setstatus(this);
2263         monsters_setstatus(this);
2264
2265         return true;
2266 }
2267
2268 .bool would_spectate;
2269 void ObserverThink(entity this)
2270 {
2271         if ( CS(this).impulse )
2272         {
2273                 MinigameImpulse(this, CS(this).impulse);
2274                 CS(this).impulse = 0;
2275         }
2276
2277         if (this.flags & FL_JUMPRELEASED) {
2278                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2279                         this.flags &= ~FL_JUMPRELEASED;
2280                         this.flags |= FL_SPAWNING;
2281                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2282                         this.flags &= ~FL_JUMPRELEASED;
2283                         if(SpectateNext(this)) {
2284                                 TRANSMUTE(Spectator, this);
2285                         }
2286                 } else {
2287                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2288                         set_movetype(this, preferred_movetype);
2289                 }
2290         } else {
2291                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2292                         this.flags |= FL_JUMPRELEASED;
2293                         if(this.flags & FL_SPAWNING)
2294                         {
2295                                 this.flags &= ~FL_SPAWNING;
2296                                 if(joinAllowed(this))
2297                                         Join(this);
2298                                 return;
2299                         }
2300                 }
2301         }
2302 }
2303
2304 void SpectatorThink(entity this)
2305 {
2306         if ( CS(this).impulse )
2307         {
2308                 if(MinigameImpulse(this, CS(this).impulse))
2309                         CS(this).impulse = 0;
2310
2311                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2312                 {
2313                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2314                         CS(this).impulse = 0;
2315                         return;
2316                 }
2317         }
2318
2319         if (this.flags & FL_JUMPRELEASED) {
2320                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2321                         this.flags &= ~FL_JUMPRELEASED;
2322                         this.flags |= FL_SPAWNING;
2323                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2324                         this.flags &= ~FL_JUMPRELEASED;
2325                         if(SpectateNext(this)) {
2326                                 TRANSMUTE(Spectator, this);
2327                         } else {
2328                                 TRANSMUTE(Observer, this);
2329                                 PutClientInServer(this);
2330                         }
2331                         CS(this).impulse = 0;
2332                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2333                         this.flags &= ~FL_JUMPRELEASED;
2334                         if(SpectatePrev(this)) {
2335                                 TRANSMUTE(Spectator, this);
2336                         } else {
2337                                 TRANSMUTE(Observer, this);
2338                                 PutClientInServer(this);
2339                         }
2340                         CS(this).impulse = 0;
2341                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2342                         this.would_spectate = false;
2343                         this.flags &= ~FL_JUMPRELEASED;
2344                         TRANSMUTE(Observer, this);
2345                         PutClientInServer(this);
2346                 } else {
2347                         if(!SpectateUpdate(this))
2348                         {
2349                                 if(!SpectateNext(this))
2350                                 {
2351                                         PutObserverInServer(this);
2352                                         this.would_spectate = true;
2353                                 }
2354                         }
2355                 }
2356         } else {
2357                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2358                         this.flags |= FL_JUMPRELEASED;
2359                         if(this.flags & FL_SPAWNING)
2360                         {
2361                                 this.flags &= ~FL_SPAWNING;
2362                                 Join(this);
2363                                 return;
2364                         }
2365                 }
2366                 if(!SpectateUpdate(this))
2367                         PutObserverInServer(this);
2368         }
2369
2370         this.flags |= FL_CLIENT | FL_NOTARGET;
2371 }
2372
2373 void PlayerUseKey(entity this)
2374 {
2375         if (!IS_PLAYER(this))
2376                 return;
2377
2378         if(this.vehicle)
2379         {
2380                 if(!game_stopped)
2381                 {
2382                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2383                         return;
2384                 }
2385         }
2386         else if(autocvar_g_vehicles_enter)
2387         {
2388                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2389                 {
2390                         entity head, closest_target = NULL;
2391                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2392
2393                         while(head) // find the closest acceptable target to enter
2394                         {
2395                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2396                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2397                                 {
2398                                         if(closest_target)
2399                                         {
2400                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2401                                                 { closest_target = head; }
2402                                         }
2403                                         else { closest_target = head; }
2404                                 }
2405
2406                                 head = head.chain;
2407                         }
2408
2409                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2410                 }
2411         }
2412
2413         // a use key was pressed; call handlers
2414         MUTATOR_CALLHOOK(PlayerUseKey, this);
2415 }
2416
2417
2418 /*
2419 =============
2420 PlayerPreThink
2421
2422 Called every frame for each client before the physics are run
2423 =============
2424 */
2425 .float last_vehiclecheck;
2426 void PlayerPreThink (entity this)
2427 {
2428         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2429         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2430
2431         WarpZone_PlayerPhysics_FixVAngle(this);
2432
2433         if (frametime) {
2434                 // physics frames: update anticheat stuff
2435                 anticheat_prethink(this);
2436         }
2437
2438         if (blockSpectators && frametime) {
2439                 // WORKAROUND: only use dropclient in server frames (frametime set).
2440                 // Never use it in cl_movement frames (frametime zero).
2441                 checkSpectatorBlock(this);
2442         }
2443
2444         zoomstate_set = false;
2445
2446         // Check for nameless players
2447         if (this.netname == "" || this.netname != CS(this).netname_previous)
2448         {
2449                 bool assume_unchanged = (CS(this).netname_previous == "");
2450                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2451                 {
2452                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2453                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2454                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2455                         assume_unchanged = false;
2456                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2457                 }
2458                 if (isInvisibleString(this.netname))
2459                 {
2460                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2461                         sprint(this, "Warning: invisible names are not allowed.\n");
2462                         assume_unchanged = false;
2463                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2464                 }
2465                 if (!assume_unchanged && autocvar_sv_eventlog)
2466                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2467                 strcpy(CS(this).netname_previous, this.netname);
2468         }
2469
2470         // version nagging
2471         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2472         CS(this).version_nagtime = 0;
2473         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2474             // git client
2475         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2476             // git server
2477             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2478         } else {
2479             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2480             if (r < 0) { // old client
2481                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2482             } else if (r > 0) { // old server
2483                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2484             }
2485         }
2486     }
2487
2488         // GOD MODE info
2489         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2490         {
2491                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2492                 this.max_armorvalue = 0;
2493         }
2494
2495         if (frametime && IS_PLAYER(this))
2496         {
2497                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2498                 {
2499                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2500                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2501                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2502
2503                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2504                                 Unfreeze(this, false);
2505                 }
2506                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2507                 {
2508                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2509                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2510
2511                         if (GetResource(this, RES_HEALTH) < 1)
2512                         {
2513                                 if (this.vehicle)
2514                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2515                                 if(this.event_damage)
2516                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2517                         }
2518                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2519                                 Unfreeze(this, false);
2520                 }
2521         }
2522
2523         MUTATOR_CALLHOOK(PlayerPreThink, this);
2524
2525         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2526         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2527         {
2528                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2529                 {
2530                         if(!it.owner)
2531                         {
2532                                 if(!it.team || SAME_TEAM(this, it))
2533                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2534                                 else if(autocvar_g_vehicles_steal)
2535                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2536                         }
2537                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2538                         {
2539                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2540                         }
2541                 });
2542
2543                 this.last_vehiclecheck = time + 1;
2544         }
2545
2546         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2547         {
2548                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2549                         PlayerUseKey(this);
2550                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2551         }
2552
2553         if (IS_REAL_CLIENT(this))
2554                 PrintWelcomeMessage(this);
2555
2556         if (IS_PLAYER(this)) {
2557                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2558                         error("Client can't be spawned as player on connection!");
2559                 if(!PlayerThink(this))
2560                         return;
2561         }
2562         else if (game_stopped || intermission_running) {
2563                 if(intermission_running)
2564                         IntermissionThink(this);
2565                 return;
2566         }
2567         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2568         {
2569                 CS(this).autojoin_checked = true;
2570                 // don't do this in ClientConnect
2571                 // many things can go wrong if a client is spawned as player on connection
2572                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2573                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2574                                 && (!teamplay || autocvar_g_balance_teams)))
2575                 {
2576                         campaign_bots_may_start = true;
2577                         Join(this);
2578                         return;
2579                 }
2580         }
2581         else if (IS_OBSERVER(this)) {
2582                 ObserverThink(this);
2583         }
2584         else if (IS_SPEC(this)) {
2585                 SpectatorThink(this);
2586         }
2587
2588         // WEAPONTODO: Add weapon request for this
2589         if (!zoomstate_set) {
2590                 bool wep_zoomed = false;
2591                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2592                 {
2593                         .entity weaponentity = weaponentities[slot];
2594                         Weapon thiswep = this.(weaponentity).m_weapon;
2595                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2596                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2597                 }
2598                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2599     }
2600
2601         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2602         {
2603                 CS(this).teamkill_soundtime = 0;
2604
2605                 entity e = CS(this).teamkill_soundsource;
2606                 entity oldpusher = e.pusher;
2607                 e.pusher = this;
2608                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2609                 e.pusher = oldpusher;
2610         }
2611
2612         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2613                 CS(this).taunt_soundtime = 0;
2614                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2615         }
2616
2617         target_voicescript_next(this);
2618
2619         // WEAPONTODO: Move into weaponsystem somehow
2620         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2621         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2622         {
2623                 .entity weaponentity = weaponentities[slot];
2624                 if(this.(weaponentity).m_weapon == WEP_Null)
2625                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2626         }
2627 }
2628
2629 void DrownPlayer(entity this)
2630 {
2631         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2632                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2633         {
2634                 this.air_finished = 0;
2635                 return;
2636         }
2637
2638         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2639         {
2640                 if(this.air_finished && this.air_finished < time)
2641                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2642                 this.air_finished = 0;
2643         }
2644         else
2645         {
2646                 if (!this.air_finished)
2647                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2648                 if (this.air_finished < time)
2649                 {       // drown!
2650                         if (this.pain_finished < time)
2651                         {
2652                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2653                                 this.pain_finished = time + 0.5;
2654                         }
2655                 }
2656         }
2657 }
2658
2659 .bool move_qcphysics;
2660
2661 void Player_Physics(entity this)
2662 {
2663         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2664
2665         if(!this.move_qcphysics)
2666                 return;
2667
2668         if(!frametime && !CS(this).pm_frametime)
2669                 return;
2670
2671         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2672
2673         CS(this).pm_frametime = 0;
2674 }
2675
2676 /*
2677 =============
2678 PlayerPostThink
2679
2680 Called every frame for each client after the physics are run
2681 =============
2682 */
2683 void PlayerPostThink (entity this)
2684 {
2685         Player_Physics(this);
2686
2687         if (sv_maxidle > 0)
2688         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2689         if (IS_REAL_CLIENT(this))
2690         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2691         {
2692                 int totalClients = 0;
2693                 if(sv_maxidle_slots > 0)
2694                 {
2695                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2696                         {
2697                                 ++totalClients;
2698                         });
2699                 }
2700
2701                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2702                 { /* do nothing */ }
2703                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2704                 {
2705                         if (CS(this).idlekick_lasttimeleft)
2706                         {
2707                                 CS(this).idlekick_lasttimeleft = 0;
2708                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2709                         }
2710                 }
2711                 else
2712                 {
2713                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2714                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2715                                 if (!CS(this).idlekick_lasttimeleft)
2716                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2717                         }
2718                         if (timeleft <= 0) {
2719                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2720                                 dropclient(this);
2721                                 return;
2722                         }
2723                         else if (timeleft <= 10) {
2724                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2725                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2726                 }
2727                                 CS(this).idlekick_lasttimeleft = timeleft;
2728                         }
2729                 }
2730         }
2731
2732         CheatFrame(this);
2733
2734         if (game_stopped)
2735         {
2736                 this.solid = SOLID_NOT;
2737                 this.takedamage = DAMAGE_NO;
2738                 set_movetype(this, MOVETYPE_NONE);
2739         }
2740
2741         if (IS_PLAYER(this)) {
2742                 if(this.death_time == time && IS_DEAD(this))
2743                 {
2744                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2745                         // once all the damage events of this frame have been processed with normal size
2746                         this.maxs.z = 5;
2747                         setsize(this, this.mins, this.maxs);
2748                 }
2749                 DrownPlayer(this);
2750                 UpdateChatBubble(this);
2751                 if (CS(this).impulse) ImpulseCommands(this);
2752                 if (game_stopped)
2753                 {
2754                         CSQCMODEL_AUTOUPDATE(this);
2755                         return;
2756                 }
2757                 GetPressedKeys(this);
2758         }
2759         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2760         {
2761                 CS(this).pressedkeys = 0;
2762                 STAT(PRESSED_KEYS, this) = 0;
2763         }
2764
2765         if (this.waypointsprite_attachedforcarrier) {
2766                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2767                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2768         }
2769
2770         CSQCMODEL_AUTOUPDATE(this);
2771 }
2772
2773 /**
2774  * message "": do not say, just test flood control
2775  * return value:
2776  *   1 = accept
2777  *   0 = reject
2778  *  -1 = fake accept
2779  */
2780 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2781 {
2782         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2783                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2784
2785         if (source)
2786                 msgin = formatmessage(source, msgin);
2787
2788         string colorstr;
2789         if (!(IS_PLAYER(source) || source.caplayer))
2790                 colorstr = "^0"; // black for spectators
2791         else if(teamplay)
2792                 colorstr = Team_ColorCode(source.team);
2793         else
2794         {
2795                 colorstr = "";
2796                 teamsay = false;
2797         }
2798
2799         if (!source) {
2800                 colorstr = "";
2801                 teamsay = false;
2802         }
2803
2804         if(msgin != "")
2805                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2806
2807         /*
2808          * using bprint solves this... me stupid
2809         // how can we prevent the message from appearing in a listen server?
2810         // for now, just give "say" back and only handle say_team
2811         if(!teamsay)
2812         {
2813                 clientcommand(source, strcat("say ", msgin));
2814                 return;
2815         }
2816         */
2817
2818         string namestr = "";
2819         if (source)
2820                 namestr = playername(source, autocvar_g_chat_teamcolors);
2821
2822         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2823
2824         string msgstr = "", cmsgstr = "";
2825         string privatemsgprefix = string_null;
2826         int privatemsgprefixlen = 0;
2827         if (msgin != "")
2828         {
2829                 bool found_me = false;
2830                 if(strstrofs(msgin, "/me", 0) >= 0)
2831                 {
2832                         string newmsgin = "";
2833                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2834                         FOREACH_WORD(msgin, true,
2835                         {
2836                                 if(strdecolorize(it) == "/me")
2837                                 {
2838                                         found_me = true;
2839                                         newmsgin = cons(newmsgin, newnamestr);
2840                                 }
2841                                 else
2842                                         newmsgin = cons(newmsgin, it);
2843                         });
2844                         msgin = newmsgin;
2845                 }
2846
2847                 if(privatesay)
2848                 {
2849                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2850                         privatemsgprefixlen = strlen(msgstr);
2851                         msgstr = strcat(msgstr, msgin);
2852                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2853                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2854                 }
2855                 else if(teamsay)
2856                 {
2857                         if(found_me)
2858                         {
2859                                 //msgin = strreplace("/me", "", msgin);
2860                                 //msgin = substring(msgin, 3, strlen(msgin));
2861                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2862                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2863                         }
2864                         else
2865                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2866                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2867                 }
2868                 else
2869                 {
2870                         if(found_me)
2871                         {
2872                                 //msgin = strreplace("/me", "", msgin);
2873                                 //msgin = substring(msgin, 3, strlen(msgin));
2874                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2875                                 msgstr = strcat("\{1}^4* ^7", msgin);
2876                         }
2877                         else {
2878                                 msgstr = "\{1}";
2879                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2880                                 msgstr = strcat(msgstr, msgin);
2881                         }
2882                         cmsgstr = "";
2883                 }
2884                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2885         }
2886
2887         string fullmsgstr = msgstr;
2888         string fullcmsgstr = cmsgstr;
2889
2890         // FLOOD CONTROL
2891         int flood = 0;
2892         var .float flood_field = floodcontrol_chat;
2893         if(floodcontrol && source)
2894         {
2895                 float flood_spl;
2896                 float flood_burst;
2897                 float flood_lmax;
2898                 float lines;
2899                 if(privatesay)
2900                 {
2901                         flood_spl = autocvar_g_chat_flood_spl_tell;
2902                         flood_burst = autocvar_g_chat_flood_burst_tell;
2903                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2904                         flood_field = floodcontrol_chattell;
2905                 }
2906                 else if(teamsay)
2907                 {
2908                         flood_spl = autocvar_g_chat_flood_spl_team;
2909                         flood_burst = autocvar_g_chat_flood_burst_team;
2910                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2911                         flood_field = floodcontrol_chatteam;
2912                 }
2913                 else
2914                 {
2915                         flood_spl = autocvar_g_chat_flood_spl;
2916                         flood_burst = autocvar_g_chat_flood_burst;
2917                         flood_lmax = autocvar_g_chat_flood_lmax;
2918                         flood_field = floodcontrol_chat;
2919                 }
2920                 flood_burst = max(0, flood_burst - 1);
2921                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2922
2923                 // do flood control for the default line size
2924                 if(msgstr != "")
2925                 {
2926                         getWrappedLine_remaining = msgstr;
2927                         msgstr = "";
2928                         lines = 0;
2929                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2930                         {
2931                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2932                                 ++lines;
2933                         }
2934                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2935
2936                         if(getWrappedLine_remaining != "")
2937                         {
2938                                 msgstr = strcat(msgstr, "\n");
2939                                 flood = 2;
2940                         }
2941
2942                         if (time >= source.(flood_field))
2943                         {
2944                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2945                         }
2946                         else
2947                         {
2948                                 flood = 1;
2949                                 msgstr = fullmsgstr;
2950                         }
2951                 }
2952                 else
2953                 {
2954                         if (time >= source.(flood_field))
2955                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2956                         else
2957                                 flood = 1;
2958                 }
2959
2960                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2961                         source.(flood_field) = flood = 0;
2962         }
2963
2964         string sourcemsgstr, sourcecmsgstr;
2965         if(flood == 2) // cannot happen for empty msgstr
2966         {
2967                 if(autocvar_g_chat_flood_notify_flooder)
2968                 {
2969                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2970                         sourcecmsgstr = "";
2971                 }
2972                 else
2973                 {
2974                         sourcemsgstr = fullmsgstr;
2975                         sourcecmsgstr = fullcmsgstr;
2976                 }
2977                 cmsgstr = "";
2978         }
2979         else
2980         {
2981                 sourcemsgstr = msgstr;
2982                 sourcecmsgstr = cmsgstr;
2983         }
2984
2985         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2986         {
2987                 if (!game_stopped)
2988                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2989                         teamsay = -1; // spectators
2990         }
2991
2992         if(flood)
2993                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2994
2995         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2996         if(privatesay)
2997                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2998
2999         int ret;
3000         if(source && CS(source).muted)
3001         {
3002                 // always fake the message
3003                 ret = -1;
3004         }
3005         else if(flood == 1)
3006         {
3007                 if (autocvar_g_chat_flood_notify_flooder)
3008                 {
3009                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3010                         ret = 0;
3011                 }
3012                 else
3013                         ret = -1;
3014         }
3015         else
3016         {
3017                 ret = 1;
3018         }
3019
3020         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3021         {
3022                 if (!game_stopped)
3023                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3024                         ret = -1; // just hide the message completely
3025         }
3026
3027         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3028         ret = M_ARGV(1, int);
3029
3030         string event_log_msg = "";
3031
3032         if(sourcemsgstr != "" && ret != 0)
3033         {
3034                 if(ret < 0) // faked message, because the player is muted
3035                 {
3036                         sprint(source, sourcemsgstr);
3037                         if(sourcecmsgstr != "" && !privatesay)
3038                                 centerprint(source, sourcecmsgstr);
3039                 }
3040                 else if(privatesay) // private message, between 2 people only
3041                 {
3042                         sprint(source, sourcemsgstr);
3043                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3044                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3045                         {
3046                                 sprint(privatesay, msgstr);
3047                                 if(cmsgstr != "")
3048                                         centerprint(privatesay, cmsgstr);
3049                         }
3050                 }
3051                 else if ( teamsay && CS(source).active_minigame )
3052                 {
3053                         sprint(source, sourcemsgstr);
3054                         dedicated_print(msgstr); // send to server console too
3055                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3056                                 sprint(it, msgstr);
3057                         });
3058                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3059
3060                 }
3061                 else if(teamsay > 0) // team message, only sent to team mates
3062                 {
3063                         sprint(source, sourcemsgstr);
3064                         dedicated_print(msgstr); // send to server console too
3065                         if(sourcecmsgstr != "")
3066                                 centerprint(source, sourcecmsgstr);
3067                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3068                                 sprint(it, msgstr);
3069                                 if(cmsgstr != "")
3070                                         centerprint(it, cmsgstr);
3071                         });
3072                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3073                 }
3074                 else if(teamsay < 0) // spectator message, only sent to spectators
3075                 {
3076                         sprint(source, sourcemsgstr);
3077                         dedicated_print(msgstr); // send to server console too
3078                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3079                                 sprint(it, msgstr);
3080                         });
3081                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3082                 }
3083                 else
3084                 {
3085                         if (source) {
3086                                 sprint(source, sourcemsgstr);
3087                                 dedicated_print(msgstr); // send to server console too
3088                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3089                         }
3090                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3091                                 sprint(it, msgstr);
3092                         });
3093                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3094                 }
3095         }
3096
3097         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3098                 GameLogEcho(event_log_msg);
3099         }
3100
3101         return ret;
3102 }
3103
3104 // hack to copy the button fields from the client entity to the Client State
3105 void PM_UpdateButtons(entity this, entity store)
3106 {
3107         if(this.impulse)
3108                 store.impulse = this.impulse;
3109         this.impulse = 0;
3110
3111         bool typing = this.buttonchat || this.button12;
3112
3113         store.button0 = (typing) ? 0 : this.button0;
3114         //button1?!
3115         store.button2 = (typing) ? 0 : this.button2;
3116         store.button3 = (typing) ? 0 : this.button3;
3117         store.button4 = this.button4;
3118         store.button5 = (typing) ? 0 : this.button5;
3119         store.button6 = this.button6;
3120         store.button7 = this.button7;
3121         store.button8 = this.button8;
3122         store.button9 = this.button9;
3123         store.button10 = this.button10;
3124         store.button11 = this.button11;
3125         store.button12 = this.button12;
3126         store.button13 = this.button13;
3127         store.button14 = this.button14;
3128         store.button15 = this.button15;
3129         store.button16 = this.button16;
3130         store.buttonuse = this.buttonuse;
3131         store.buttonchat = this.buttonchat;
3132
3133         store.cursor_active = this.cursor_active;
3134         store.cursor_screen = this.cursor_screen;
3135         store.cursor_trace_start = this.cursor_trace_start;
3136         store.cursor_trace_endpos = this.cursor_trace_endpos;
3137         store.cursor_trace_ent = this.cursor_trace_ent;
3138
3139         store.ping = this.ping;
3140         store.ping_packetloss = this.ping_packetloss;
3141         store.ping_movementloss = this.ping_movementloss;
3142
3143         store.v_angle = this.v_angle;
3144         store.movement = (typing) ? '0 0 0' : this.movement;
3145 }
3146
3147 NET_HANDLE(fpsreport, bool)
3148 {
3149         int fps = ReadShort();
3150         PlayerScore_Set(sender, SP_FPS, fps);
3151         return true;
3152 }