qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 141                                         sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 /** putting a client as observer in the server */
 239 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 240 {
 241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 242         bool recount_ready = false;
 243         PlayerState_detach(this);
 244
 245         if (IS_PLAYER(this))
 246         {
 247                 if(GetResource(this, RES_HEALTH) >= 1)
 248                 {
 249                         // despawn effect
 250                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 251                 }
 252
 253                 // was a player, recount votes and ready status
 254                 if(IS_REAL_CLIENT(this))
 255                 {
 256                         if (vote_called) { VoteCount(false); }
 257                         this.ready = false;
 258                         recount_ready = true;
 259                 }
 260                 entcs_update_players(this);
 261         }
 262
 263         if (use_spawnpoint)
 264         {
 265                 entity spot = SelectSpawnPoint(this, true);
 266                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 267                 this.angles = vec2(spot.angles);
 268                 // offset it so that the spectator spawns higher off the ground, looks better this way
 269                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 270         }
 271         else // change origin to restore previous view origin
 272                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 273         this.fixangle = true;
 274
 275         if (IS_REAL_CLIENT(this))
 276         {
 277                 msg_entity = this;
 278                 WriteByte(MSG_ONE, SVC_SETVIEW);
 279                 WriteEntity(MSG_ONE, this);
 280         }
 281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 283         if(!autocvar_g_debug_globalsounds)
 284         {
 285                 // needed for player sounds
 286                 this.model = "";
 287                 FixPlayermodel(this);
 288         }
 289         setmodel(this, MDL_Null);
 290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 291         this.view_ofs = '0 0 0';
 292
 293         RemoveGrapplingHooks(this);
 294         Portal_ClearAll(this);
 295         Unfreeze(this, false);
 296         SetSpectatee(this, NULL);
 297
 298         if (this.alivetime)
 299         {
 300                 if (!warmup_stage)
 301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 302                 this.alivetime = 0;
 303         }
 304
 305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 306
 307         TRANSMUTE(Observer, this);
 308
 309         if(recount_ready) ReadyCount();
 310
 311         WaypointSprite_PlayerDead(this);
 312         accuracy_resend(this);
 313
 314         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 315                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 316
 317         CS(this).spectatortime = time;
 318         if(this.bot_attack)
 319                 IL_REMOVE(g_bot_targets, this);
 320         this.bot_attack = false;
 321         if(this.monster_attack)
 322                 IL_REMOVE(g_monster_targets, this);
 323         this.monster_attack = false;
 324         STAT(HUD, this) = HUD_NORMAL;
 325         this.iscreature = false;
 326         this.teleportable = TELEPORT_SIMPLE;
 327         if(this.damagedbycontents)
 328                 IL_REMOVE(g_damagedbycontents, this);
 329         this.damagedbycontents = false;
 330         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 331         SetSpectatee_status(this, etof(this));
 332         this.takedamage = DAMAGE_NO;
 333         this.solid = SOLID_NOT;
 334         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 335         this.flags = FL_CLIENT | FL_NOTARGET;
 336         this.effects = 0;
 337         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 338         this.pauserotarmor_finished = 0;
 339         this.pauserothealth_finished = 0;
 340         this.pauseregen_finished = 0;
 341         this.damageforcescale = 0;
 342         this.death_time = 0;
 343         this.respawn_flags = 0;
 344         this.respawn_time = 0;
 345         STAT(RESPAWN_TIME, this) = 0;
 346         this.alpha = 0;
 347         this.scale = 0;
 348         this.fade_time = 0;
 349         this.pain_finished = 0;
 350         STAT(AIR_FINISHED, this) = 0;
 351         //this.dphitcontentsmask = 0;
 352         this.dphitcontentsmask = DPCONTENTS_SOLID;
 353         if (autocvar_g_playerclip_collisions)
 354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 355         this.pushltime = 0;
 356         this.istypefrag = 0;
 357         setthink(this, func_null);
 358         this.nextthink = 0;
 359         this.deadflag = DEAD_NO;
 360         UNSET_DUCKED(this);
 361         STAT(REVIVE_PROGRESS, this) = 0;
 362         this.revival_time = 0;
 363         this.draggable = drag_undraggable;
 364
 365         player_powerups_remove_all(this);
 366         this.items = 0;
 367         STAT(WEAPONS, this) = '0 0 0';
 368         this.drawonlytoclient = this;
 369
 370         this.viewloc = NULL;
 371
 372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 373
 374         this.weaponmodel = "";
 375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 this.weaponentities[slot] = NULL;
 378         }
 379         this.exteriorweaponentity = NULL;
 380         CS(this).killcount = FRAGS_SPECTATOR;
 381         this.velocity = '0 0 0';
 382         this.avelocity = '0 0 0';
 383         this.punchangle = '0 0 0';
 384         this.punchvector = '0 0 0';
 385         this.oldvelocity = this.velocity;
 386         this.event_damage = func_null;
 387         this.event_heal = func_null;
 388
 389         for(int slot = 0; slot < MAX_AXH; ++slot)
 390         {
 391                 entity axh = this.(AuxiliaryXhair[slot]);
 392                 this.(AuxiliaryXhair[slot]) = NULL;
 393
 394                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 395                         delete(axh);
 396         }
 397
 398         if (mutator_returnvalue)
 399         {
 400                 // mutator prevents resetting teams+score
 401         }
 402         else
 403         {
 404                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 405                 this.frags = FRAGS_SPECTATOR;
 406         }
 407
 408         bot_relinkplayerlist();
 409
 410         if (CS(this).just_joined)
 411                 CS(this).just_joined = false;
 412 }
 413
 414 int player_getspecies(entity this)
 415 {
 416         get_model_parameters(this.model, this.skin);
 417         int s = get_model_parameters_species;
 418         get_model_parameters(string_null, 0);
 419         if (s < 0) return SPECIES_HUMAN;
 420         return s;
 421 }
 422
 423 .float model_randomizer;
 424 void FixPlayermodel(entity player)
 425 {
 426         string defaultmodel = "";
 427         int defaultskin = 0;
 428         if(autocvar_sv_defaultcharacter)
 429         {
 430                 if(teamplay)
 431                 {
 432                         switch(player.team)
 433                         {
 434                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 435                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 436                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 437                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 438                         }
 439                 }
 440
 441                 if(defaultmodel == "")
 442                 {
 443                         defaultmodel = autocvar_sv_defaultplayermodel;
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445                 }
 446
 447                 int n = tokenize_console(defaultmodel);
 448                 if(n > 0)
 449                 {
 450                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 451                         // However, do NOT randomize if the player-selected model is in the list.
 452                         for (int i = 0; i < n; ++i)
 453                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 454                                         defaultmodel = argv(i);
 455                 }
 456
 457                 int i = strstrofs(defaultmodel, ":", 0);
 458                 if(i >= 0)
 459                 {
 460                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 461                         defaultmodel = substring(defaultmodel, 0, i);
 462                 }
 463         }
 464         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 465         {
 466                 if(teamplay)
 467                 {
 468                         switch(player.team)
 469                         {
 470                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 471                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 472                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 473                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 474                         }
 475                 }
 476
 477                 if(!defaultskin)
 478                         defaultskin = autocvar_sv_defaultplayerskin;
 479         }
 480
 481         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 482         defaultmodel = M_ARGV(0, string);
 483         defaultskin = M_ARGV(1, int);
 484
 485         bool chmdl = false;
 486         int oldskin;
 487         if(defaultmodel != "")
 488         {
 489                 if (defaultmodel != player.model)
 490                 {
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, defaultmodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 oldskin = player.skin;
 499                 player.skin = defaultskin;
 500         } else {
 501                 if (player.playermodel != player.model || player.playermodel == "")
 502                 {
 503                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 504                         vector m1 = player.mins;
 505                         vector m2 = player.maxs;
 506                         setplayermodel (player, player.playermodel);
 507                         setsize (player, m1, m2);
 508                         chmdl = true;
 509                 }
 510
 511                 if(!autocvar_sv_defaultcharacterskin)
 512                 {
 513                         oldskin = player.skin;
 514                         player.skin = stof(player.playerskin);
 515                 }
 516                 else
 517                 {
 518                         oldskin = player.skin;
 519                         player.skin = defaultskin;
 520                 }
 521         }
 522
 523         if(chmdl || oldskin != player.skin) // model or skin has changed
 524         {
 525                 player.species = player_getspecies(player); // update species
 526                 if(!autocvar_g_debug_globalsounds)
 527                         UpdatePlayerSounds(player); // update skin sounds
 528         }
 529
 530         if(!teamplay)
 531                 if(strlen(autocvar_sv_defaultplayercolors))
 532                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 533                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 534 }
 535
 536 void PutPlayerInServer(entity this)
 537 {
 538         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 539
 540         PlayerState_attach(this);
 541         accuracy_resend(this);
 542
 543         if (this.team < 0)
 544                 TeamBalance_JoinBestTeam(this);
 545
 546         entity spot = SelectSpawnPoint(this, false);
 547         if (!spot) {
 548                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 549                 return; // spawn failed
 550         }
 551
 552         TRANSMUTE(Player, this);
 553
 554         CS(this).wasplayer = true;
 555         this.iscreature = true;
 556         this.teleportable = TELEPORT_NORMAL;
 557         if(!this.damagedbycontents)
 558                 IL_PUSH(g_damagedbycontents, this);
 559         this.damagedbycontents = true;
 560         set_movetype(this, MOVETYPE_WALK);
 561         this.solid = SOLID_SLIDEBOX;
 562         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 563         if (autocvar_g_playerclip_collisions)
 564                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 565         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 566                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 567         this.frags = FRAGS_PLAYER;
 568         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 569         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 570         if (autocvar__notarget)
 571                 this.flags |= FL_NOTARGET;
 572         this.takedamage = DAMAGE_AIM;
 573         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 574
 575         if (warmup_stage) {
 576                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 577                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 578                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 579                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 580                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 581                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 582                 SetResource(this, RES_HEALTH, warmup_start_health);
 583                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 584                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 585         } else {
 586                 SetResource(this, RES_SHELLS, start_ammo_shells);
 587                 SetResource(this, RES_BULLETS, start_ammo_nails);
 588                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 589                 SetResource(this, RES_CELLS, start_ammo_cells);
 590                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 591                 SetResource(this, RES_FUEL, start_ammo_fuel);
 592                 SetResource(this, RES_HEALTH, start_health);
 593                 SetResource(this, RES_ARMOR, start_armorvalue);
 594                 STAT(WEAPONS, this) = start_weapons;
 595                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 596                 {
 597                         GiveRandomWeapons(this, random_start_weapons_count,
 598                                 autocvar_g_random_start_weapons, random_start_ammo);
 599                 }
 600         }
 601         SetSpectatee_status(this, 0);
 602
 603         PS(this).dual_weapons = '0 0 0';
 604
 605         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 606                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 607
 608         this.items = start_items;
 609
 610         float shieldtime = time + autocvar_g_spawnshieldtime;
 611
 612         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 613         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 614         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 615         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 616         if (!sv_ready_restart_after_countdown && time < game_starttime)
 617         {
 618                 float f = game_starttime - time;
 619                 shieldtime += f;
 620                 this.pauserotarmor_finished += f;
 621                 this.pauserothealth_finished += f;
 622                 this.pauseregen_finished += f;
 623         }
 624
 625         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 626
 627         this.damageforcescale = autocvar_g_player_damageforcescale;
 628         this.death_time = 0;
 629         this.respawn_flags = 0;
 630         this.respawn_time = 0;
 631         STAT(RESPAWN_TIME, this) = 0;
 632         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 633         this.fade_time = 0;
 634         this.pain_finished = 0;
 635         this.pushltime = 0;
 636         setthink(this, func_null); // players have no think function
 637         this.nextthink = 0;
 638         this.dmg_team = 0;
 639         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 640
 641         this.deadflag = DEAD_NO;
 642
 643         this.angles = spot.angles;
 644         this.angles_z = 0; // never spawn tilted even if the spot says to
 645         if (IS_BOT_CLIENT(this))
 646         {
 647                 this.v_angle = this.angles;
 648                 bot_aim_reset(this);
 649         }
 650         this.fixangle = true; // turn this way immediately
 651         this.oldvelocity = this.velocity = '0 0 0';
 652         this.avelocity = '0 0 0';
 653         this.punchangle = '0 0 0';
 654         this.punchvector = '0 0 0';
 655
 656         STAT(REVIVE_PROGRESS, this) = 0;
 657         this.revival_time = 0;
 658
 659         STAT(AIR_FINISHED, this) = 0;
 660         this.waterlevel = WATERLEVEL_NONE;
 661         this.watertype = CONTENT_EMPTY;
 662
 663         entity spawnevent = new_pure(spawnevent);
 664         spawnevent.owner = this;
 665         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 666
 667         // Cut off any still running player sounds.
 668         stopsound(this, CH_PLAYER_SINGLE);
 669
 670         this.model = "";
 671         FixPlayermodel(this);
 672         this.drawonlytoclient = NULL;
 673
 674         this.viewloc = NULL;
 675
 676         for(int slot = 0; slot < MAX_AXH; ++slot)
 677         {
 678                 entity axh = this.(AuxiliaryXhair[slot]);
 679                 this.(AuxiliaryXhair[slot]) = NULL;
 680
 681                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 682                         delete(axh);
 683         }
 684
 685         this.spawnpoint_targ = NULL;
 686
 687         UNSET_DUCKED(this);
 688         this.view_ofs = STAT(PL_VIEW_OFS, this);
 689         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 690         this.spawnorigin = spot.origin;
 691         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 692         // don't reset back to last position, even if new position is stuck in solid
 693         this.oldorigin = this.origin;
 694         if(this.conveyor)
 695                 IL_REMOVE(g_conveyed, this);
 696         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 697         if(this.swampslug)
 698                 IL_REMOVE(g_swamped, this);
 699         this.swampslug = NULL;
 700         this.swamp_interval = 0;
 701         if(this.ladder_entity)
 702                 IL_REMOVE(g_ladderents, this);
 703         this.ladder_entity = NULL;
 704         IL_EACH(g_counters, it.realowner == this,
 705         {
 706                 delete(it);
 707         });
 708         STAT(HUD, this) = HUD_NORMAL;
 709
 710         this.event_damage = PlayerDamage;
 711         this.event_heal = PlayerHeal;
 712
 713         this.draggable = func_null;
 714
 715         if(!this.bot_attack)
 716                 IL_PUSH(g_bot_targets, this);
 717         this.bot_attack = true;
 718         if(!this.monster_attack)
 719                 IL_PUSH(g_monster_targets, this);
 720         this.monster_attack = true;
 721         navigation_dynamicgoal_init(this, false);
 722
 723         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 724
 725         // player was spectator
 726         if (CS(this).killcount == FRAGS_SPECTATOR) {
 727                 PlayerScore_Clear(this);
 728                 CS(this).killcount = 0;
 729                 CS(this).startplaytime = time;
 730         }
 731
 732         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 733         {
 734                 .entity weaponentity = weaponentities[slot];
 735                 CL_SpawnWeaponentity(this, weaponentity);
 736         }
 737         this.alpha = default_player_alpha;
 738         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 739         this.exteriorweaponentity.alpha = default_weapon_alpha;
 740
 741         this.speedrunning = false;
 742
 743         this.counter_cnt = 0;
 744         this.fragsfilter_cnt = 0;
 745
 746         target_voicescript_clear(this);
 747
 748         // reset fields the weapons may use
 749         FOREACH(Weapons, true, {
 750                 it.wr_resetplayer(it, this);
 751                         // reload all reloadable weapons
 752                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 753                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 754                         {
 755                                 .entity weaponentity = weaponentities[slot];
 756                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 757                         }
 758                 }
 759         });
 760
 761         Unfreeze(this, false);
 762
 763         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 void SendWelcomemessage(entity this, bool force_centerprint)
1022 {
1023         msg_entity = this;
1024         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1025         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1026 }
1027
1028 // NOTE csqc uses the active mutators list sent by this function
1029 // to understand which mutators are enabled
1030 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1031 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1032 {
1033         WriteByte(msg_type, boolean(autocvar_g_campaign));
1034         if (boolean(autocvar_g_campaign))
1035         {
1036                 WriteString(msg_type, Campaign_GetTitle());
1037                 WriteByte(msg_type, Campaign_GetLevelNum());
1038                 WriteString(msg_type, Campaign_GetMessage());
1039                 return;
1040         }
1041         WriteByte(msg_type, force_centerprint);
1042         WriteString(msg_type, autocvar_hostname);
1043         WriteString(msg_type, autocvar_g_xonoticversion);
1044         WriteByte(msg_type, CS(this).version_mismatch);
1045         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1046
1047         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1048         string modifications = M_ARGV(0, string);
1049
1050         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1051                 modifications = strcat(modifications, ", No start weapons");
1052         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1053                 modifications = strcat(modifications, ", Low gravity");
1054         if(g_weapon_stay && !g_cts)
1055                 modifications = strcat(modifications, ", Weapons stay");
1056         if(autocvar_g_jetpack)
1057                 modifications = strcat(modifications, ", Jetpack");
1058         modifications = substring(modifications, 2, strlen(modifications) - 2);
1059
1060         WriteString(msg_type, modifications);
1061
1062         WriteString(msg_type, g_weaponarena_list);
1063
1064         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1065         {
1066                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1067                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1068         }
1069
1070         WriteString(msg_type, cache_mutatormsg);
1071
1072         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1073 }
1074
1075 /**
1076 =============
1077 ClientConnect
1078
1079 Called when a client connects to the server
1080 =============
1081 */
1082 void ClientConnect(entity this)
1083 {
1084         if (Ban_MaybeEnforceBanOnce(this)) return;
1085         assert(!IS_CLIENT(this), return);
1086         this.flags |= FL_CLIENT;
1087         assert(player_count >= 0, player_count = 0);
1088
1089         TRANSMUTE(Client, this);
1090         CS(this).version_nagtime = time + 10 + random() * 10;
1091
1092         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1093
1094         bot_clientconnect(this);
1095
1096         Player_DetermineForcedTeam(this);
1097
1098         TRANSMUTE(Observer, this);
1099
1100         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1101
1102         // always track bots, don't ask for cl_allow_uidtracking
1103         if (IS_BOT_CLIENT(this))
1104                 PlayerStats_GameReport_AddPlayer(this);
1105         else
1106                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1107
1108         if (autocvar_sv_eventlog)
1109                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1110
1111         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1112
1113         stuffcmd(this, clientstuff, "\n");
1114         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1115
1116         FixClientCvars(this);
1117
1118         // get version info from player
1119         stuffcmd(this, "cmd clientversion $gameversion\n");
1120
1121         // notify about available teams
1122         if (teamplay)
1123         {
1124                 entity balance = TeamBalance_CheckAllowedTeams(this);
1125                 int t = TeamBalance_GetAllowedTeams(balance);
1126                 TeamBalance_Destroy(balance);
1127                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1128         }
1129         else
1130         {
1131                 stuffcmd(this, "set _teams_available 0\n");
1132         }
1133
1134         bot_relinkplayerlist();
1135
1136         CS(this).spectatortime = time;
1137         if (blockSpectators)
1138         {
1139                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1140         }
1141
1142         CS(this).jointime = time;
1143
1144         if (IS_REAL_CLIENT(this))
1145         {
1146                 if (g_weaponarena_weapons == WEPSET(TUBA))
1147                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1148         }
1149
1150         if (!autocvar_sv_foginterval && world.fog != "")
1151                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1152
1153         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1154                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1155                         send_CSQC_teamnagger();
1156
1157         CSQCMODEL_AUTOINIT(this);
1158
1159         CS(this).model_randomizer = random();
1160
1161         if (IS_REAL_CLIENT(this))
1162                 sv_notice_join(this);
1163
1164         this.move_qcphysics = autocvar_sv_qcphysics;
1165
1166         // update physics stats (players can spawn before physics runs)
1167         Physics_UpdateStats(this);
1168
1169         IL_EACH(g_initforplayer, it.init_for_player, {
1170                 it.init_for_player(it, this);
1171         });
1172
1173         Handicap_Initialize(this);
1174
1175         MUTATOR_CALLHOOK(ClientConnect, this);
1176
1177         if (player_count == 1)
1178                 localcmd("\nsv_hook_firstjoin\n");
1179
1180         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1181                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1182 }
1183 /*
1184 =============
1185 ClientDisconnect
1186
1187 Called when a client disconnects from the server
1188 =============
1189 */
1190 .entity chatbubbleentity;
1191 void player_powerups_remove_all(entity this);
1192
1193 void ClientDisconnect(entity this)
1194 {
1195         assert(IS_CLIENT(this), return);
1196
1197         PlayerStats_GameReport_FinalizePlayer(this);
1198         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1199         if (CS(this).active_minigame) part_minigame(this);
1200         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1201
1202         if (autocvar_sv_eventlog)
1203                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1204
1205         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1206
1207         if(IS_SPEC(this))
1208                 SetSpectatee(this, NULL);
1209
1210         MUTATOR_CALLHOOK(ClientDisconnect, this);
1211
1212         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1213         strfree(CS_CVAR(this).weaponorder_byimpulse);
1214         ClientState_detach(this);
1215
1216         Portal_ClearAll(this);
1217
1218         Unfreeze(this, false);
1219
1220         RemoveGrapplingHooks(this);
1221
1222         // Here, everything has been done that requires this player to be a client.
1223
1224         this.flags &= ~FL_CLIENT;
1225
1226         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1227         if (this.killindicator) delete(this.killindicator);
1228
1229         IL_EACH(g_counters, it.realowner == this,
1230         {
1231                 delete(it);
1232         });
1233
1234         WaypointSprite_PlayerGone(this);
1235
1236         bot_relinkplayerlist();
1237
1238         strfree(this.clientstatus);
1239         if (this.personal) delete(this.personal);
1240
1241         this.playerid = 0;
1242         ReadyCount();
1243         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1244
1245         player_powerups_remove_all(this); // stop powerup sound
1246
1247         ONREMOVE(this);
1248
1249         if (player_count == 0)
1250                 localcmd("\nsv_hook_lastleave\n");
1251 }
1252
1253 void ChatBubbleThink(entity this)
1254 {
1255         this.nextthink = time;
1256         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1257         {
1258                 if(this.owner) // but why can that ever be NULL?
1259                         this.owner.chatbubbleentity = NULL;
1260                 delete(this);
1261                 return;
1262         }
1263
1264         this.mdl = "";
1265
1266         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1267         {
1268                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1269                         this.mdl = "models/sprites/minigame_busy.iqm";
1270                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1271                         this.mdl = "models/misc/chatbubble.spr";
1272         }
1273
1274         if ( this.model != this.mdl )
1275                 _setmodel(this, this.mdl);
1276
1277 }
1278
1279 void UpdateChatBubble(entity this)
1280 {
1281         if (this.alpha < 0)
1282                 return;
1283         // spawn a chatbubble entity if needed
1284         if (!this.chatbubbleentity)
1285         {
1286                 this.chatbubbleentity = new(chatbubbleentity);
1287                 this.chatbubbleentity.owner = this;
1288                 this.chatbubbleentity.exteriormodeltoclient = this;
1289                 setthink(this.chatbubbleentity, ChatBubbleThink);
1290                 this.chatbubbleentity.nextthink = time;
1291                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1292                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1293                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1294                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1295                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1296                 //this.chatbubbleentity.model = "";
1297                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1298         }
1299 }
1300
1301 void calculate_player_respawn_time(entity this)
1302 {
1303         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1304                 return;
1305
1306         float gametype_setting_tmp;
1307         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1308         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1309         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1310         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1311         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1312         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1313
1314         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1315         if (teamplay)
1316         {
1317                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1318                         if(it.team == this.team)
1319                                 ++pcount;
1320                 });
1321                 if (sdelay_small_count == 0)
1322                         sdelay_small_count = 1;
1323                 if (sdelay_large_count == 0)
1324                         sdelay_large_count = 1;
1325         }
1326         else
1327         {
1328                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1329                         ++pcount;
1330                 });
1331                 if (sdelay_small_count == 0)
1332                 {
1333                         if (IS_INDEPENDENT_PLAYER(this))
1334                         {
1335                                 // Players play independently. No point in requiring enemies.
1336                                 sdelay_small_count = 1;
1337                         }
1338                         else
1339                         {
1340                                 // Players play AGAINST each other. Enemies required.
1341                                 sdelay_small_count = 2;
1342                         }
1343                 }
1344                 if (sdelay_large_count == 0)
1345                 {
1346                         if (IS_INDEPENDENT_PLAYER(this))
1347                         {
1348                                 // Players play independently. No point in requiring enemies.
1349                                 sdelay_large_count = 1;
1350                         }
1351                         else
1352                         {
1353                                 // Players play AGAINST each other. Enemies required.
1354                                 sdelay_large_count = 2;
1355                         }
1356                 }
1357         }
1358
1359         float sdelay;
1360
1361         if (pcount <= sdelay_small_count)
1362                 sdelay = sdelay_small;
1363         else if (pcount >= sdelay_large_count)
1364                 sdelay = sdelay_large;
1365         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1366                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1367
1368         if(waves)
1369                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1370         else
1371                 this.respawn_time = time + sdelay;
1372
1373         if(sdelay < sdelay_max)
1374                 this.respawn_time_max = time + sdelay_max;
1375         else
1376                 this.respawn_time_max = this.respawn_time;
1377
1378         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1379                 this.respawn_countdown = 10; // first number to count down from is 10
1380         else
1381                 this.respawn_countdown = -1; // do not count down
1382
1383         if(autocvar_g_forced_respawn)
1384                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1385 }
1386
1387 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1388 // added to the model skins
1389 /*void UpdateColorModHack()
1390 {
1391         float c;
1392         c = this.clientcolors & 15;
1393         // LordHavoc: only bothering to support white, green, red, yellow, blue
1394              if (!teamplay) this.colormod = '0 0 0';
1395         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1396         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1397         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1398         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1399         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1400         else this.colormod = '1 1 1';
1401 }*/
1402
1403 void respawn(entity this)
1404 {
1405         bool damagedbycontents_prev = this.damagedbycontents;
1406         if(this.alpha >= 0)
1407         {
1408                 if(autocvar_g_respawn_ghosts)
1409                 {
1410                         this.solid = SOLID_NOT;
1411                         this.takedamage = DAMAGE_NO;
1412                         this.damagedbycontents = false;
1413                         set_movetype(this, MOVETYPE_FLY);
1414                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1415                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1416                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1417                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1418                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1419                         if(autocvar_g_respawn_ghosts_time > 0)
1420                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1421                 }
1422                 else
1423                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1424         }
1425
1426         CopyBody(this, 1);
1427         this.damagedbycontents = damagedbycontents_prev;
1428
1429         this.effects |= EF_NODRAW; // prevent another CopyBody
1430         PutClientInServer(this);
1431 }
1432
1433 void play_countdown(entity this, float finished, Sound samp)
1434 {
1435         TC(Sound, samp);
1436         float time_left = finished - time;
1437         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1438                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1439 }
1440
1441 // it removes special powerups not handled by StatusEffects
1442 void player_powerups_remove_all(entity this)
1443 {
1444         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1445         {
1446                 // don't play the poweroff sound when the game restarts or the player disconnects
1447                 if (time > game_starttime + 1 && IS_CLIENT(this)
1448                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1449                 {
1450                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1451                 }
1452                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1453                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1454                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1455         }
1456 }
1457
1458 void player_powerups(entity this)
1459 {
1460         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1461                 this.modelflags |= MF_ROCKET;
1462         else
1463                 this.modelflags &= ~MF_ROCKET;
1464
1465         this.effects &= ~EF_NODEPTHTEST;
1466
1467         if (IS_DEAD(this))
1468                 player_powerups_remove_all(this);
1469
1470         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1471                 return;
1472
1473         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1474         int items_prev = this.items;
1475
1476         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1477         {
1478                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1479                 if (this.items & IT_SUPERWEAPON)
1480                 {
1481                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1482                         {
1483                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1484                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1485                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1486                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1487                         }
1488                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1489                         {
1490                                 // don't let them run out
1491                         }
1492                         else
1493                         {
1494                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1495                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1496                                 {
1497                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1498                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1499                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1500                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1501                                 }
1502                         }
1503                 }
1504                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1505                 {
1506                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1507                         {
1508                                 this.items = this.items | IT_SUPERWEAPON;
1509                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1510                                 {
1511                                         if(!g_cts)
1512                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1514                                 }
1515                         }
1516                         else
1517                         {
1518                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1519                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1520                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1521                         }
1522                 }
1523                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1524                 {
1525                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1526                 }
1527         }
1528
1529         if(autocvar_g_nodepthtestplayers)
1530                 this.effects = this.effects | EF_NODEPTHTEST;
1531
1532         if(autocvar_g_fullbrightplayers)
1533                 this.effects = this.effects | EF_FULLBRIGHT;
1534
1535         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1536 }
1537
1538 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1539 {
1540         if(current > stable)
1541                 return current;
1542         else if(current > stable - 0.25) // when close enough, "snap"
1543                 return stable;
1544         else
1545                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1546 }
1547
1548 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1549 {
1550         if(current < stable)
1551                 return current;
1552         else if(current < stable + 0.25) // when close enough, "snap"
1553                 return stable;
1554         else
1555                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1556 }
1557
1558 void RotRegen(entity this, Resource res, float limit_mod,
1559         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1560         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1561 {
1562         float old = GetResource(this, res);
1563         float current = old;
1564         if(current > rotstable)
1565         {
1566                 if(rotframetime > 0)
1567                 {
1568                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1569                         current = max(rotstable, current - rotlinear * rotframetime);
1570                 }
1571         }
1572         else if(current < regenstable)
1573         {
1574                 if(regenframetime > 0)
1575                 {
1576                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1577                         current = min(regenstable, current + regenlinear * regenframetime);
1578                 }
1579         }
1580
1581         float limit = GetResourceLimit(this, res) * limit_mod;
1582         if(current > limit)
1583                 current = limit;
1584
1585         if (current != old)
1586                 SetResource(this, res, current);
1587 }
1588
1589 void player_regen(entity this)
1590 {
1591         float max_mod, regen_mod, rot_mod, limit_mod;
1592         max_mod = regen_mod = rot_mod = limit_mod = 1;
1593
1594         float regen_health = autocvar_g_balance_health_regen;
1595         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1596         float regen_health_rot = autocvar_g_balance_health_rot;
1597         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1598         float regen_health_stable = autocvar_g_balance_health_regenstable;
1599         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1600         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1601                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1602         max_mod = M_ARGV(1, float);
1603         regen_mod = M_ARGV(2, float);
1604         rot_mod = M_ARGV(3, float);
1605         limit_mod = M_ARGV(4, float);
1606         regen_health = M_ARGV(5, float);
1607         regen_health_linear = M_ARGV(6, float);
1608         regen_health_rot = M_ARGV(7, float);
1609         regen_health_rotlinear = M_ARGV(8, float);
1610         regen_health_stable = M_ARGV(9, float);
1611         regen_health_rotstable = M_ARGV(10, float);
1612
1613         float rotstable, regenstable, rotframetime, regenframetime;
1614
1615         if(!mutator_returnvalue)
1616         if(!STAT(FROZEN, this))
1617         {
1618                 regenstable = autocvar_g_balance_armor_regenstable;
1619                 rotstable = autocvar_g_balance_armor_rotstable;
1620                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1621                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1622                 RotRegen(this, RES_ARMOR, limit_mod,
1623                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1624                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1625
1626                 // NOTE: max_mod is only applied to health
1627                 regenstable = regen_health_stable * max_mod;
1628                 rotstable = regen_health_rotstable * max_mod;
1629                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1630                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1631                 RotRegen(this, RES_HEALTH, limit_mod,
1632                         regenstable, regen_health, regen_health_linear, regenframetime,
1633                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1634         }
1635
1636         // if player rotted to death...  die!
1637         // check this outside above checks, as player may still be able to rot to death
1638         if(GetResource(this, RES_HEALTH) < 1)
1639         {
1640                 if(this.vehicle)
1641                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1642                 if(this.event_damage)
1643                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1644         }
1645
1646         if (!(this.items & IT_UNLIMITED_AMMO))
1647         {
1648                 regenstable = autocvar_g_balance_fuel_regenstable;
1649                 rotstable = autocvar_g_balance_fuel_rotstable;
1650                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1651                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1652                 RotRegen(this, RES_FUEL, 1,
1653                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1654                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1655         }
1656 }
1657
1658 bool zoomstate_set;
1659 void SetZoomState(entity this, float newzoom)
1660 {
1661         if(newzoom != CS(this).zoomstate)
1662         {
1663                 CS(this).zoomstate = newzoom;
1664                 ClientData_Touch(this);
1665         }
1666         zoomstate_set = true;
1667 }
1668
1669 void GetPressedKeys(entity this)
1670 {
1671         MUTATOR_CALLHOOK(GetPressedKeys, this);
1672         if (game_stopped)
1673         {
1674                 CS(this).pressedkeys = 0;
1675                 STAT(PRESSED_KEYS, this) = 0;
1676                 return;
1677         }
1678
1679         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1680         int keys = STAT(PRESSED_KEYS, this);
1681         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1682         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1683         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1684         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1685
1686         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1687         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1688         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1689         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1690         CS(this).pressedkeys = keys; // store for other users
1691
1692         STAT(PRESSED_KEYS, this) = keys;
1693 }
1694
1695 /*
1696 ======================
1697 spectate mode routines
1698 ======================
1699 */
1700
1701 void SpectateCopy(entity this, entity spectatee)
1702 {
1703         TC(Client, this); TC(Client, spectatee);
1704
1705         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1706         PS(this) = PS(spectatee);
1707         this.armortype = spectatee.armortype;
1708         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1709         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1710         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1711         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1712         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1713         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1714         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1715         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1716         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1717         CS(this).impulse = 0;
1718         this.disableclientprediction = 1; // no need to run prediction on a spectator
1719         this.items = spectatee.items;
1720         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1721         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1722         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1723         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1724         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1725         this.punchangle = spectatee.punchangle;
1726         this.view_ofs = spectatee.view_ofs;
1727         this.velocity = spectatee.velocity;
1728         this.dmg_take = spectatee.dmg_take;
1729         this.dmg_save = spectatee.dmg_save;
1730         this.dmg_inflictor = spectatee.dmg_inflictor;
1731         this.v_angle = spectatee.v_angle;
1732         this.angles = spectatee.v_angle;
1733         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1734         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1735         this.viewloc = spectatee.viewloc;
1736         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1737                 this.fixangle = true;
1738         setorigin(this, spectatee.origin);
1739         setsize(this, spectatee.mins, spectatee.maxs);
1740         SetZoomState(this, CS(spectatee).zoomstate);
1741
1742     anticheat_spectatecopy(this, spectatee);
1743         STAT(HUD, this) = STAT(HUD, spectatee);
1744         if(spectatee.vehicle)
1745     {
1746         this.angles = spectatee.v_angle;
1747
1748         //this.fixangle = false;
1749         //this.velocity = spectatee.vehicle.velocity;
1750         this.vehicle_health = spectatee.vehicle_health;
1751         this.vehicle_shield = spectatee.vehicle_shield;
1752         this.vehicle_energy = spectatee.vehicle_energy;
1753         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1754         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1755         this.vehicle_reload1 = spectatee.vehicle_reload1;
1756         this.vehicle_reload2 = spectatee.vehicle_reload2;
1757
1758         //msg_entity = this;
1759
1760        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1761             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1762            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1763            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1764
1765         //WriteByte (MSG_ONE, SVC_SETVIEW);
1766         //    WriteEntity(MSG_ONE, this);
1767         //makevectors(spectatee.v_angle);
1768         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1769     }
1770 }
1771
1772 bool SpectateUpdate(entity this)
1773 {
1774         if(!this.enemy)
1775                 return false;
1776
1777         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1778         {
1779                 SetSpectatee(this, NULL);
1780                 return false;
1781         }
1782
1783         SpectateCopy(this, this.enemy);
1784
1785         return true;
1786 }
1787
1788 bool SpectateSet(entity this)
1789 {
1790         if(!IS_PLAYER(this.enemy))
1791                 return false;
1792
1793         ClientData_Touch(this.enemy);
1794
1795         msg_entity = this;
1796         WriteByte(MSG_ONE, SVC_SETVIEW);
1797         WriteEntity(MSG_ONE, this.enemy);
1798         set_movetype(this, MOVETYPE_NONE);
1799         accuracy_resend(this);
1800
1801         if(!SpectateUpdate(this))
1802                 PutObserverInServer(this, false, true);
1803
1804         return true;
1805 }
1806
1807 void SetSpectatee_status(entity this, int spectatee_num)
1808 {
1809         int oldspectatee_status = CS(this).spectatee_status;
1810         CS(this).spectatee_status = spectatee_num;
1811
1812         if (CS(this).spectatee_status != oldspectatee_status)
1813         {
1814                 if (STAT(PRESSED_KEYS, this))
1815                 {
1816                         CS(this).pressedkeys = 0;
1817                         STAT(PRESSED_KEYS, this) = 0;
1818                 }
1819                 ClientData_Touch(this);
1820                 if (g_race || g_cts) race_InitSpectator();
1821         }
1822 }
1823
1824 void SetSpectatee(entity this, entity spectatee)
1825 {
1826         if(IS_BOT_CLIENT(this))
1827                 return; // bots abuse .enemy, this code is useless to them
1828
1829         entity old_spectatee = this.enemy;
1830
1831         this.enemy = spectatee;
1832
1833         // WEAPONTODO
1834         // these are required to fix the spectator bug with arc
1835         if(old_spectatee)
1836         {
1837                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1838                 {
1839                         .entity weaponentity = weaponentities[slot];
1840                         if(old_spectatee.(weaponentity).arc_beam)
1841                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1842                 }
1843         }
1844         if(spectatee)
1845         {
1846                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1847                 {
1848                         .entity weaponentity = weaponentities[slot];
1849                         if(spectatee.(weaponentity).arc_beam)
1850                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1851                 }
1852         }
1853
1854         if (spectatee)
1855                 SetSpectatee_status(this, etof(spectatee));
1856
1857         // needed to update spectator list
1858         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1859 }
1860
1861 bool Spectate(entity this, entity pl)
1862 {
1863         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1864                 return false;
1865         pl = M_ARGV(1, entity);
1866
1867         SetSpectatee(this, pl);
1868         return SpectateSet(this);
1869 }
1870
1871 bool SpectateNext(entity this)
1872 {
1873         entity ent = find(this.enemy, classname, STR_PLAYER);
1874
1875         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1876                 ent = M_ARGV(1, entity);
1877         else if (!ent)
1878                 ent = find(ent, classname, STR_PLAYER);
1879
1880         if(ent) { SetSpectatee(this, ent); }
1881
1882         return SpectateSet(this);
1883 }
1884
1885 bool SpectatePrev(entity this)
1886 {
1887         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1888         entity ent = findchain(classname, STR_PLAYER);
1889         if (!ent) // no player
1890                 return false;
1891
1892         entity first = ent;
1893         // skip players until current spectated player
1894         if(this.enemy)
1895         while(ent && ent != this.enemy)
1896                 ent = ent.chain;
1897
1898         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1899         {
1900                 case MUT_SPECPREV_FOUND:
1901                         ent = M_ARGV(1, entity);
1902                         break;
1903                 case MUT_SPECPREV_RETURN:
1904                         return true;
1905                 case MUT_SPECPREV_CONTINUE:
1906                 default:
1907                 {
1908                         if(ent.chain)
1909                                 ent = ent.chain;
1910                         else
1911                                 ent = first;
1912                         break;
1913                 }
1914         }
1915
1916         SetSpectatee(this, ent);
1917         return SpectateSet(this);
1918 }
1919
1920 /*
1921 =============
1922 ShowRespawnCountdown()
1923
1924 Update a respawn countdown display.
1925 =============
1926 */
1927 void ShowRespawnCountdown(entity this)
1928 {
1929         float number;
1930         if(!IS_DEAD(this)) // just respawned?
1931                 return;
1932         else
1933         {
1934                 number = ceil(this.respawn_time - time);
1935                 if(number <= 0)
1936                         return;
1937                 if(number <= this.respawn_countdown)
1938                 {
1939                         this.respawn_countdown = number - 1;
1940                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1941                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1942                 }
1943         }
1944 }
1945
1946 .bool team_selected;
1947 bool ShowTeamSelection(entity this)
1948 {
1949         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1950                 return false;
1951         stuffcmd(this, "menu_showteamselect\n");
1952         return true;
1953 }
1954 void Join(entity this)
1955 {
1956         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1957                 ReadyRestart(true);
1958
1959         TRANSMUTE(Player, this);
1960
1961         if(!this.team_selected)
1962         if(autocvar_g_campaign || autocvar_g_balance_teams)
1963                 TeamBalance_JoinBestTeam(this);
1964
1965         if(autocvar_g_campaign)
1966                 campaign_bots_may_start = true;
1967
1968         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1969
1970         PutClientInServer(this);
1971
1972         if(IS_PLAYER(this))
1973         if(teamplay && this.team != -1)
1974         {
1975         }
1976         else
1977                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1978         this.team_selected = false;
1979 }
1980
1981 int GetPlayerLimit()
1982 {
1983         if(g_duel)
1984                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1985         int player_limit = autocvar_g_maxplayers;
1986         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1987         player_limit = M_ARGV(0, int);
1988         return player_limit;
1989 }
1990
1991 /**
1992  * Determines whether the player is allowed to join. This depends on cvar
1993  * g_maxplayers, if it isn't used this function always return true, otherwise
1994  * it checks whether the number of currently playing players exceeds g_maxplayers.
1995  * @return int number of free slots for players, 0 if none
1996  */
1997 int nJoinAllowed(entity this, entity ignore)
1998 {
1999         if(!ignore)
2000         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2001         // so report 0 free slots if restricted
2002         {
2003                 if(autocvar_g_forced_team_otherwise == "spectate")
2004                         return 0;
2005                 if(autocvar_g_forced_team_otherwise == "spectator")
2006                         return 0;
2007         }
2008
2009         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2010                 return 0; // forced spectators can never join
2011
2012         // TODO simplify this
2013         int totalClients = 0;
2014         int currentlyPlaying = 0;
2015         FOREACH_CLIENT(true, {
2016                 if(it != ignore)
2017                         ++totalClients;
2018                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2019                         ++currentlyPlaying;
2020         });
2021
2022         int player_limit = GetPlayerLimit();
2023
2024         int free_slots = 0;
2025         if (!player_limit)
2026                 free_slots = maxclients - totalClients;
2027         else if(player_limit > 0 && currentlyPlaying < player_limit)
2028                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2029
2030         static float msg_time = 0;
2031         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2032         {
2033                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2034                 msg_time = time + 0.5;
2035         }
2036
2037         return free_slots;
2038 }
2039
2040 void PrintWelcomeMessage(entity this)
2041 {
2042         if(CS(this).motd_actived_time == 0)
2043         {
2044                 if (autocvar_g_campaign) {
2045                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2046                                 CS(this).motd_actived_time = time;
2047                                 SendWelcomemessage(this, false);
2048                         }
2049                 } else {
2050                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2051                                 CS(this).motd_actived_time = time;
2052                                 SendWelcomemessage(this, true);
2053                         }
2054                 }
2055         }
2056         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2057         {
2058                 if (autocvar_g_campaign) {
2059                         if (PHYS_INPUT_BUTTON_INFO(this))
2060                                 CS(this).motd_actived_time = time;
2061                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2062                                 CS(this).motd_actived_time = 0;
2063                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2064                         }
2065                 } else {
2066                         if (PHYS_INPUT_BUTTON_INFO(this))
2067                                 CS(this).motd_actived_time = time;
2068                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2069                                 CS(this).motd_actived_time = 0;
2070                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2071                         }
2072                 }
2073         }
2074         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2075         {
2076                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2077                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2078                 else if (CS(this).motd_actived_time == -2)
2079                 {
2080                         // instantly hide MOTD
2081                         CS(this).motd_actived_time = 0;
2082                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2083                 }
2084                 else if (IS_PLAYER(this) || IS_SPEC(this))
2085                 {
2086                         // FIXME occasionally for some reason MOTD never goes away
2087                         // delay MOTD removal a little bit in the hope it fixes this bug
2088                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2089                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2090                         else //if (CS(this).motd_actived_time < -2)
2091                                 CS(this).motd_actived_time++;
2092                 }
2093         }
2094 }
2095
2096 bool joinAllowed(entity this)
2097 {
2098         if (CS(this).version_mismatch) return false;
2099         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2100         if (!nJoinAllowed(this, this)) return false;
2101         if (teamplay && lockteams) return false;
2102         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2103         if (ShowTeamSelection(this)) return false;
2104         return true;
2105 }
2106
2107 .string shootfromfixedorigin;
2108 .bool dualwielding_prev;
2109 bool PlayerThink(entity this)
2110 {
2111         if (game_stopped || intermission_running) {
2112                 this.modelflags &= ~MF_ROCKET;
2113                 if(intermission_running)
2114                         IntermissionThink(this);
2115                 return false;
2116         }
2117
2118         if (timeout_status == TIMEOUT_ACTIVE) {
2119                 // don't allow the player to turn around while game is paused
2120                 // FIXME turn this into CSQC stuff
2121                 this.v_angle = this.lastV_angle;
2122                 this.angles = this.lastV_angle;
2123                 this.fixangle = true;
2124         }
2125
2126         if (frametime) player_powerups(this);
2127
2128         if (IS_DEAD(this)) {
2129                 if (this.personal && g_race_qualifying) {
2130                         if (time > this.respawn_time) {
2131                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2132                                 respawn(this);
2133                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2134                         }
2135                 } else {
2136                         if (frametime) player_anim(this);
2137
2138                         if (this.respawn_flags & RESPAWN_DENY)
2139                         {
2140                                 STAT(RESPAWN_TIME, this) = 0;
2141                                 return false;
2142                         }
2143
2144                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2145
2146                         switch(this.deadflag)
2147                         {
2148                                 case DEAD_DYING:
2149                                 {
2150                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2151                                                 this.deadflag = DEAD_RESPAWNING;
2152                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2153                                                 this.deadflag = DEAD_DEAD;
2154                                         break;
2155                                 }
2156                                 case DEAD_DEAD:
2157                                 {
2158                                         if (button_pressed)
2159                                                 this.deadflag = DEAD_RESPAWNABLE;
2160                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2161                                                 this.deadflag = DEAD_RESPAWNING;
2162                                         break;
2163                                 }
2164                                 case DEAD_RESPAWNABLE:
2165                                 {
2166                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2167                                                 this.deadflag = DEAD_RESPAWNING;
2168                                         break;
2169                                 }
2170                                 case DEAD_RESPAWNING:
2171                                 {
2172                                         if (time > this.respawn_time)
2173                                         {
2174                                                 this.respawn_time = time + 1; // only retry once a second
2175                                                 this.respawn_time_max = this.respawn_time;
2176                                                 respawn(this);
2177                                         }
2178                                         break;
2179                                 }
2180                         }
2181
2182                         ShowRespawnCountdown(this);
2183
2184                         if (this.respawn_flags & RESPAWN_SILENT)
2185                                 STAT(RESPAWN_TIME, this) = 0;
2186                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2187                         {
2188                                 if (time < this.respawn_time)
2189                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2190                                 else if (this.deadflag != DEAD_RESPAWNING)
2191                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2192                         }
2193                         else
2194                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2195                 }
2196
2197                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2198                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2199                         STAT(RESPAWN_TIME, this) *= -1;
2200
2201                 return false;
2202         }
2203
2204         FixPlayermodel(this);
2205
2206         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2207                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2208                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2209         }
2210
2211         // reset gun alignment when dual wielding status changes
2212         // to ensure guns are always aligned right and left
2213         bool dualwielding = W_DualWielding(this);
2214         if(this.dualwielding_prev != dualwielding)
2215         {
2216                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2217                 this.dualwielding_prev = dualwielding;
2218         }
2219
2220         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2221         //if(frametime)
2222         {
2223                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2224                 {
2225                         .entity weaponentity = weaponentities[slot];
2226                         if(WEP_CVAR(vortex, charge_always))
2227                                 W_Vortex_Charge(this, weaponentity, frametime);
2228                         W_WeaponFrame(this, weaponentity);
2229                 }
2230         }
2231
2232         if (frametime)
2233         {
2234                 // WEAPONTODO: Add a weapon request for this
2235                 // rot vortex charge to the charge limit
2236                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2237                 {
2238                         .entity weaponentity = weaponentities[slot];
2239                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2240                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2241                 }
2242
2243                 player_regen(this);
2244                 player_anim(this);
2245                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2246         }
2247
2248         monsters_setstatus(this);
2249
2250         return true;
2251 }
2252
2253 .bool would_spectate;
2254 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2255 void ObserverOrSpectatorThink(entity this)
2256 {
2257         bool is_spec = IS_SPEC(this);
2258         if ( CS(this).impulse )
2259         {
2260                 int r = MinigameImpulse(this, CS(this).impulse);
2261                 if (!is_spec || r)
2262                         CS(this).impulse = 0;
2263
2264                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2265                 {
2266                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2267                         CS(this).impulse = 0;
2268                         return;
2269                 }
2270         }
2271
2272         if (this.flags & FL_JUMPRELEASED) {
2273                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2274                         this.flags &= ~FL_JUMPRELEASED;
2275                         this.flags |= FL_SPAWNING;
2276                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2277                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2278                         this.flags &= ~FL_JUMPRELEASED;
2279                         if(SpectateNext(this)) {
2280                                 TRANSMUTE(Spectator, this);
2281                         } else if (is_spec) {
2282                                 TRANSMUTE(Observer, this);
2283                                 PutClientInServer(this);
2284                         }
2285                         else
2286                                 this.would_spectate = false; // unable to spectate anyone
2287                         if (is_spec)
2288                                 CS(this).impulse = 0;
2289                 } else if (is_spec) {
2290                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2291                                 this.flags &= ~FL_JUMPRELEASED;
2292                                 if(SpectatePrev(this)) {
2293                                         TRANSMUTE(Spectator, this);
2294                                 } else {
2295                                         TRANSMUTE(Observer, this);
2296                                         PutClientInServer(this);
2297                                 }
2298                                 CS(this).impulse = 0;
2299                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2300                                 this.would_spectate = false;
2301                                 this.flags &= ~FL_JUMPRELEASED;
2302                                 TRANSMUTE(Observer, this);
2303                                 PutClientInServer(this);
2304                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2305                                 PutObserverInServer(this, false, true);
2306                                 this.would_spectate = true;
2307                         }
2308                 }
2309                 else {
2310                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2311                         if (PHYS_INPUT_BUTTON_USE(this))
2312                                 wouldclip = !wouldclip;
2313                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2314                         set_movetype(this, preferred_movetype);
2315                 }
2316         } else { // jump pressed
2317                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2318                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2319                         this.flags |= FL_JUMPRELEASED;
2320                         if(this.flags & FL_SPAWNING)
2321                         {
2322                                 this.flags &= ~FL_SPAWNING;
2323                                 if(joinAllowed(this))
2324                                         Join(this);
2325                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2326                                         CS(this).autojoin_checked = -1;
2327                                 return;
2328                         }
2329                 }
2330                 if(is_spec && !SpectateUpdate(this))
2331                         PutObserverInServer(this, false, true);
2332         }
2333         if (is_spec)
2334                 this.flags |= FL_CLIENT | FL_NOTARGET;
2335 }
2336
2337 void PlayerUseKey(entity this)
2338 {
2339         if (!IS_PLAYER(this))
2340                 return;
2341
2342         if(this.vehicle)
2343         {
2344                 if(!game_stopped)
2345                 {
2346                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2347                         return;
2348                 }
2349         }
2350         else if(autocvar_g_vehicles_enter)
2351         {
2352                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2353                 {
2354                         entity head, closest_target = NULL;
2355                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2356
2357                         while(head) // find the closest acceptable target to enter
2358                         {
2359                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2360                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2361                                 {
2362                                         if(closest_target)
2363                                         {
2364                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2365                                                 { closest_target = head; }
2366                                         }
2367                                         else { closest_target = head; }
2368                                 }
2369
2370                                 head = head.chain;
2371                         }
2372
2373                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2374                 }
2375         }
2376
2377         // a use key was pressed; call handlers
2378         MUTATOR_CALLHOOK(PlayerUseKey, this);
2379 }
2380
2381
2382 /*
2383 =============
2384 PlayerPreThink
2385
2386 Called every frame for each client before the physics are run
2387 =============
2388 */
2389 .float last_vehiclecheck;
2390 void PlayerPreThink (entity this)
2391 {
2392         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2393         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2394
2395         WarpZone_PlayerPhysics_FixVAngle(this);
2396
2397         if (frametime) {
2398                 // physics frames: update anticheat stuff
2399                 anticheat_prethink(this);
2400
2401                 // WORKAROUND: only use dropclient in server frames (frametime set).
2402                 // Never use it in cl_movement frames (frametime zero).
2403                 if (blockSpectators && IS_REAL_CLIENT(this)
2404                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2405                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2406                 {
2407                         if (dropclient_schedule(this))
2408                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2409                 }
2410         }
2411
2412         zoomstate_set = false;
2413
2414         // Check for nameless players
2415         if (this.netname == "" || this.netname != CS(this).netname_previous)
2416         {
2417                 bool assume_unchanged = (CS(this).netname_previous == "");
2418                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2419                 {
2420                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2421                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2422                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2423                         assume_unchanged = false;
2424                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2425                 }
2426                 if (isInvisibleString(this.netname))
2427                 {
2428                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2429                         sprint(this, "Warning: invisible names are not allowed.\n");
2430                         assume_unchanged = false;
2431                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2432                 }
2433                 if (!assume_unchanged && autocvar_sv_eventlog)
2434                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2435                 strcpy(CS(this).netname_previous, this.netname);
2436         }
2437
2438         // version nagging
2439         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2440         CS(this).version_nagtime = 0;
2441         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2442             // git client
2443         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2444             // git server
2445             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2446         } else {
2447             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2448             if (r < 0) { // old client
2449                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2450             } else if (r > 0) { // old server
2451                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2452             }
2453         }
2454     }
2455
2456         // GOD MODE info
2457         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2458         {
2459                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2460                 this.max_armorvalue = 0;
2461         }
2462
2463         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2464         {
2465                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2466                 {
2467                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2468                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2469                         if (this.iceblock)
2470                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2471
2472                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2473                                 Unfreeze(this, false);
2474                 }
2475                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2476                 {
2477                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2478                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2479
2480                         if (GetResource(this, RES_HEALTH) < 1)
2481                         {
2482                                 if (this.vehicle)
2483                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2484                                 if(this.event_damage)
2485                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2486                         }
2487                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2488                                 Unfreeze(this, false);
2489                 }
2490         }
2491
2492         MUTATOR_CALLHOOK(PlayerPreThink, this);
2493
2494         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2495         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2496         {
2497                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2498                 {
2499                         if(!it.owner)
2500                         {
2501                                 if(!it.team || SAME_TEAM(this, it))
2502                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2503                                 else if(autocvar_g_vehicles_steal)
2504                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2505                         }
2506                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2507                         {
2508                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2509                         }
2510                 });
2511
2512                 this.last_vehiclecheck = time + 1;
2513         }
2514
2515         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2516                 PlayerUseKey(this);
2517         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2518
2519         if (IS_REAL_CLIENT(this))
2520                 PrintWelcomeMessage(this);
2521
2522         if (IS_PLAYER(this)) {
2523                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2524                         error("Client can't be spawned as player on connection!");
2525                 if(!PlayerThink(this))
2526                         return;
2527         }
2528         else if (game_stopped || intermission_running) {
2529                 if(intermission_running)
2530                         IntermissionThink(this);
2531                 return;
2532         }
2533         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2534         {
2535                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2536                 CS(this).autojoin_checked = 1;
2537                 // don't do this in ClientConnect
2538                 // many things can go wrong if a client is spawned as player on connection
2539                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2540                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2541                                 && (!teamplay || autocvar_g_balance_teams)))
2542                 {
2543                         if(joinAllowed(this))
2544                                 Join(this);
2545                         return;
2546                 }
2547         }
2548         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2549                 ObserverOrSpectatorThink(this);
2550         }
2551
2552         // WEAPONTODO: Add weapon request for this
2553         if (!zoomstate_set) {
2554                 bool wep_zoomed = false;
2555                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2556                 {
2557                         .entity weaponentity = weaponentities[slot];
2558                         Weapon thiswep = this.(weaponentity).m_weapon;
2559                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2560                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2561                 }
2562                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2563         }
2564
2565         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2566         {
2567                 CS(this).teamkill_soundtime = 0;
2568
2569                 entity e = CS(this).teamkill_soundsource;
2570                 entity oldpusher = e.pusher;
2571                 e.pusher = this;
2572                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2573                 e.pusher = oldpusher;
2574         }
2575
2576         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2577                 CS(this).taunt_soundtime = 0;
2578                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2579         }
2580
2581         target_voicescript_next(this);
2582 }
2583
2584 void DrownPlayer(entity this)
2585 {
2586         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2587                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2588         {
2589                 STAT(AIR_FINISHED, this) = 0;
2590                 return;
2591         }
2592
2593         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2594         {
2595                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2596                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2597                 STAT(AIR_FINISHED, this) = 0;
2598         }
2599         else
2600         {
2601                 if (!STAT(AIR_FINISHED, this))
2602                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2603                 if (STAT(AIR_FINISHED, this) < time)
2604                 {       // drown!
2605                         if (this.pain_finished < time)
2606                         {
2607                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2608                                 this.pain_finished = time + 0.5;
2609                         }
2610                 }
2611         }
2612 }
2613
2614 .bool move_qcphysics;
2615
2616 void Player_Physics(entity this)
2617 {
2618         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2619
2620         if(!this.move_qcphysics)
2621                 return;
2622
2623         if(!frametime && !CS(this).pm_frametime)
2624                 return;
2625
2626         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2627
2628         CS(this).pm_frametime = 0;
2629 }
2630
2631 /*
2632 =============
2633 PlayerPostThink
2634
2635 Called every frame for each client after the physics are run
2636 =============
2637 */
2638 void PlayerPostThink (entity this)
2639 {
2640         Player_Physics(this);
2641
2642         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2643         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2644         if (IS_REAL_CLIENT(this))
2645         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2646         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2647         {
2648                 int totalClients = 0;
2649                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2650                 {
2651                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2652                         if (server_is_dedicated)
2653                         {
2654                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2655                                 {
2656                                         ++totalClients;
2657                                 });
2658                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2659                                         totalClients = 0;
2660                         }
2661                 }
2662                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2663                 {
2664                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2665                         {
2666                                 ++totalClients;
2667                         });
2668                 }
2669
2670                 if (totalClients < autocvar_sv_maxidle_minplayers)
2671                 {
2672                         // idle kick disabled
2673                         CS(this).parm_idlesince = time;
2674                 }
2675                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2676                 {
2677                         if (CS(this).idlekick_lasttimeleft)
2678                         {
2679                                 CS(this).idlekick_lasttimeleft = 0;
2680                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2681                         }
2682                 }
2683                 else
2684                 {
2685                         float maxidle_time = autocvar_sv_maxidle;
2686                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2687                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2688                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2689                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2690                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2691                         {
2692                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2693                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2694                                 else
2695                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2696                         }
2697                         if (timeleft <= 0) {
2698                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2699                                 {
2700                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2701                                         PutObserverInServer(this, true, true);
2702                                 }
2703                                 else
2704                                 {
2705                                         if (dropclient_schedule(this))
2706                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2707                                 }
2708                                 return;
2709                         }
2710                         else if (timeleft <= countdown_time) {
2711                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2712                                         play2(this, SND(TALK2));
2713                                 CS(this).idlekick_lasttimeleft = timeleft;
2714                         }
2715                 }
2716         }
2717
2718         CheatFrame(this);
2719
2720         if (game_stopped)
2721         {
2722                 this.solid = SOLID_NOT;
2723                 this.takedamage = DAMAGE_NO;
2724                 set_movetype(this, MOVETYPE_NONE);
2725                 CS(this).teamkill_complain = 0;
2726                 CS(this).teamkill_soundtime = 0;
2727                 CS(this).teamkill_soundsource = NULL;
2728         }
2729
2730         if (IS_PLAYER(this)) {
2731                 if(this.death_time == time && IS_DEAD(this))
2732                 {
2733                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2734                         // once all the damage events of this frame have been processed with normal size
2735                         this.maxs.z = 5;
2736                         setsize(this, this.mins, this.maxs);
2737                 }
2738                 DrownPlayer(this);
2739                 UpdateChatBubble(this);
2740                 if (CS(this).impulse) ImpulseCommands(this);
2741                 GetPressedKeys(this);
2742                 if (game_stopped)
2743                 {
2744                         CSQCMODEL_AUTOUPDATE(this);
2745                         return;
2746                 }
2747         }
2748         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2749         {
2750                 CS(this).pressedkeys = 0;
2751                 STAT(PRESSED_KEYS, this) = 0;
2752         }
2753
2754         if (this.waypointsprite_attachedforcarrier) {
2755                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2756                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2757         }
2758
2759         CSQCMODEL_AUTOUPDATE(this);
2760 }
2761
2762 // hack to copy the button fields from the client entity to the Client State
2763 void PM_UpdateButtons(entity this, entity store)
2764 {
2765         if(this.impulse)
2766                 store.impulse = this.impulse;
2767         this.impulse = 0;
2768
2769         bool typing = this.buttonchat || this.button12;
2770
2771         store.button0 = (typing) ? 0 : this.button0;
2772         //button1?!
2773         store.button2 = (typing) ? 0 : this.button2;
2774         store.button3 = (typing) ? 0 : this.button3;
2775         store.button4 = this.button4;
2776         store.button5 = (typing) ? 0 : this.button5;
2777         store.button6 = this.button6;
2778         store.button7 = this.button7;
2779         store.button8 = this.button8;
2780         store.button9 = this.button9;
2781         store.button10 = this.button10;
2782         store.button11 = this.button11;
2783         store.button12 = this.button12;
2784         store.button13 = this.button13;
2785         store.button14 = this.button14;
2786         store.button15 = this.button15;
2787         store.button16 = this.button16;
2788         store.buttonuse = this.buttonuse;
2789         store.buttonchat = this.buttonchat;
2790
2791         store.cursor_active = this.cursor_active;
2792         store.cursor_screen = this.cursor_screen;
2793         store.cursor_trace_start = this.cursor_trace_start;
2794         store.cursor_trace_endpos = this.cursor_trace_endpos;
2795         store.cursor_trace_ent = this.cursor_trace_ent;
2796
2797         store.ping = this.ping;
2798         store.ping_packetloss = this.ping_packetloss;
2799         store.ping_movementloss = this.ping_movementloss;
2800
2801         store.v_angle = this.v_angle;
2802         store.movement = this.movement;
2803 }
2804
2805 NET_HANDLE(fpsreport, bool)
2806 {
2807         int fps = ReadShort();
2808         PlayerScore_Set(sender, SP_FPS, fps);
2809         return true;
2810 }