qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/debug.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/effects/qc/globalsound.qh>
   8 #include <common/ent_cs.qh>
   9 #include <common/gamemodes/_mod.qh>
  10 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  11 #include <common/items/_mod.qh>
  12 #include <common/items/inventory.qh>
  13 #include <common/mapobjects/func/conveyor.qh>
  14 #include <common/mapobjects/func/ladder.qh>
  15 #include <common/mapobjects/subs.qh>
  16 #include <common/mapobjects/target/spawnpoint.qh>
  17 #include <common/mapobjects/teleporters.qh>
  18 #include <common/mapobjects/trigger/counter.qh>
  19 #include <common/mapobjects/trigger/secret.qh>
  20 #include <common/mapobjects/trigger/swamp.qh>
  21 #include <common/mapobjects/triggers.qh>
  22 #include <common/minigames/sv_minigames.qh>
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  25 #include <common/mutators/mutator/nades/nades.qh>
  26 #include <common/mutators/mutator/overkill/oknex.qh>
  27 #include <common/mutators/mutator/status_effects/_mod.qh>
  28 #include <common/mutators/mutator/waypoints/all.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/playerstats.qh>
  34 #include <common/resources/sv_resources.qh>
  35 #include <common/state.qh>
  36 #include <common/stats.qh>
  37 #include <common/vehicles/all.qh>
  38 #include <common/vehicles/sv_vehicles.qh>
  39 #include <common/viewloc.qh>
  40 #include <common/weapons/_all.qh>
  41 #include <common/weapons/weapon/vortex.qh>
  42 #include <common/wepent.qh>
  43 #include <lib/csqcmodel/sv_model.qh>
  44 #include <lib/warpzone/common.qh>
  45 #include <lib/warpzone/server.qh>
  46 #include <server/anticheat.qh>
  47 #include <server/antilag.qh>
  48 #include <server/bot/api.qh>
  49 #include <server/bot/default/cvars.qh>
  50 #include <server/bot/default/waypoints.qh>
  51 #include <server/campaign.qh>
  52 #include <server/chat.qh>
  53 #include <server/cheats.qh>
  54 #include <server/clientkill.qh>
  55 #include <server/command/banning.qh>
  56 #include <server/command/cmd.qh>
  57 #include <server/command/common.qh>
  58 #include <server/command/vote.qh>
  59 #include <server/compat/quake3.qh>
  60 #include <server/damage.qh>
  61 #include <server/gamelog.qh>
  62 #include <server/handicap.qh>
  63 #include <server/hook.qh>
  64 #include <server/impulse.qh>
  65 #include <server/intermission.qh>
  66 #include <server/ipban.qh>
  67 #include <server/main.qh>
  68 #include <server/mutators/_mod.qh>
  69 #include <server/player.qh>
  70 #include <server/portals.qh>
  71 #include <server/race.qh>
  72 #include <server/scores.qh>
  73 #include <server/scores_rules.qh>
  74 #include <server/spawnpoints.qh>
  75 #include <server/teamplay.qh>
  76 #include <server/weapons/accuracy.qh>
  77 #include <server/weapons/common.qh>
  78 #include <server/weapons/hitplot.qh>
  79 #include <server/weapons/selection.qh>
  80 #include <server/weapons/tracing.qh>
  81 #include <server/weapons/weaponsystem.qh>
  82 #include <server/world.qh>
  83
  84 STATIC_METHOD(Client, Add, void(Client this, int _team))
  85 {
  86     ClientConnect(this);
  87     TRANSMUTE(Player, this);
  88     this.frame = 12; // 7
  89     this.team = _team;
  90     PutClientInServer(this);
  91 }
  92
  93 STATIC_METHOD(Client, Remove, void(Client this))
  94 {
  95     TRANSMUTE(Observer, this);
  96     PutClientInServer(this);
  97     ClientDisconnect(this);
  98 }
  99
 100 void send_CSQC_teamnagger() {
 101         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 102 }
 103
 104 int CountSpectators(entity player, entity to)
 105 {
 106         if(!player) { return 0; } // not sure how, but best to be safe
 107
 108         int spec_count = 0;
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 spec_count++;
 113         });
 114
 115         return spec_count;
 116 }
 117
 118 void WriteSpectators(entity player, entity to)
 119 {
 120         if(!player) { return; } // not sure how, but best to be safe
 121
 122         int spec_count = 0;
 123         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 124         {
 125                 if(spec_count >= MAX_SPECTATORS)
 126                         break;
 127                 WriteByte(MSG_ENTITY, num_for_edict(it));
 128                 ++spec_count;
 129         });
 130 }
 131
 132 bool ClientData_Send(entity this, entity to, int sf)
 133 {
 134         assert(to == this.owner, return false);
 135
 136         entity e = to;
 137         if (IS_SPEC(e)) e = e.enemy;
 138
 139         sf = 0;
 140         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 141         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 142         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 143         if (observe_blocked_if_eliminated && INGAME(to))
 144                                         sf |= BIT(3); // observing blocked
 145         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 146                                         sf |= BIT(4); // show spectators
 147
 148         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 149         WriteByte(MSG_ENTITY, sf);
 150
 151         if (sf & BIT(1))
 152                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 153
 154         if(sf & BIT(4))
 155         {
 156                 float specs = CountSpectators(e, to);
 157                 WriteByte(MSG_ENTITY, specs);
 158                 WriteSpectators(e, to);
 159         }
 160
 161         return true;
 162 }
 163
 164 void ClientData_Attach(entity this)
 165 {
 166         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 167         CS(this).clientdata.drawonlytoclient = this;
 168         CS(this).clientdata.owner = this;
 169 }
 170
 171 void ClientData_Detach(entity this)
 172 {
 173         delete(CS(this).clientdata);
 174         CS(this).clientdata = NULL;
 175 }
 176
 177 void ClientData_Touch(entity e)
 178 {
 179         entity cd = CS(e).clientdata;
 180         if (cd) { cd.SendFlags = 1; }
 181
 182         // make it spectatable
 183         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 184         {
 185                 entity cd = CS(it).clientdata;
 186                 if (cd) { cd.SendFlags = 1; }
 187         });
 188 }
 189
 190
 191 /*
 192 =============
 193 CheckPlayerModel
 194
 195 Checks if the argument string can be a valid playermodel.
 196 Returns a valid one in doubt.
 197 =============
 198 */
 199 string FallbackPlayerModel;
 200 string CheckPlayerModel(string plyermodel) {
 201         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 202         {
 203                 // note: we cannot summon Don Strunzone here, some player may
 204                 // still have the model string set. In case anyone manages how
 205                 // to change a cvar default, we'll have a small leak here.
 206                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 207         }
 208         // only in right path
 209         if(substring(plyermodel, 0, 14) != "models/player/")
 210                 return FallbackPlayerModel;
 211         // only good file extensions
 212         if(substring(plyermodel, -4, 4) != ".iqm"
 213                 && substring(plyermodel, -4, 4) != ".zym"
 214                 && substring(plyermodel, -4, 4) != ".dpm"
 215                 && substring(plyermodel, -4, 4) != ".md3"
 216                 && substring(plyermodel, -4, 4) != ".psk")
 217         {
 218                 return FallbackPlayerModel;
 219         }
 220         // forbid the LOD models
 221         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 222                 return FallbackPlayerModel;
 223         if(plyermodel != strtolower(plyermodel))
 224                 return FallbackPlayerModel;
 225         // also, restrict to server models
 226         if(autocvar_sv_servermodelsonly)
 227         {
 228                 if(!fexists(plyermodel))
 229                         return FallbackPlayerModel;
 230         }
 231         return plyermodel;
 232 }
 233
 234 void setplayermodel(entity e, string modelname)
 235 {
 236         precache_model(modelname);
 237         _setmodel(e, modelname);
 238         player_setupanimsformodel(e);
 239         if(!autocvar_g_debug_globalsounds)
 240                 UpdatePlayerSounds(e);
 241 }
 242
 243 /** putting a client as observer in the server */
 244 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 245 {
 246         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 247         bool recount_ready = false;
 248         PlayerState_detach(this);
 249
 250         if (IS_PLAYER(this))
 251         {
 252                 if(GetResource(this, RES_HEALTH) >= 1)
 253                 {
 254                         // despawn effect
 255                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 256                 }
 257
 258                 // was a player, recount votes and ready status
 259                 if(IS_REAL_CLIENT(this))
 260                 {
 261                         if (vote_called) { VoteCount(false); }
 262                         this.ready = false;
 263                         if (warmup_stage || game_starttime > time) recount_ready = true;
 264                 }
 265                 entcs_update_players(this);
 266         }
 267
 268         if (use_spawnpoint)
 269         {
 270                 entity spot = SelectSpawnPoint(this, true);
 271                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 272                 this.angles = vec2(spot.angles);
 273                 // offset it so that the spectator spawns higher off the ground, looks better this way
 274                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 275         }
 276         else // change origin to restore previous view origin
 277                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 278         this.fixangle = true;
 279
 280         if (IS_REAL_CLIENT(this))
 281         {
 282                 msg_entity = this;
 283                 WriteByte(MSG_ONE, SVC_SETVIEW);
 284                 WriteEntity(MSG_ONE, this);
 285         }
 286         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 287         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 288         if(!autocvar_g_debug_globalsounds)
 289         {
 290                 // needed for player sounds
 291                 this.model = "";
 292                 FixPlayermodel(this);
 293         }
 294         setmodel(this, MDL_Null);
 295         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 296         this.view_ofs = '0 0 0';
 297
 298         RemoveGrapplingHooks(this);
 299         Portal_ClearAll(this);
 300         Unfreeze(this, false);
 301         SetSpectatee(this, NULL);
 302
 303         if (this.alivetime)
 304         {
 305                 if (!warmup_stage)
 306                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 307                 this.alivetime = 0;
 308         }
 309
 310         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 311
 312         TRANSMUTE(Observer, this);
 313
 314         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 315
 316         WaypointSprite_PlayerDead(this);
 317         accuracy_resend(this);
 318
 319         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 320                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 321
 322         CS(this).spectatortime = time;
 323         if(this.bot_attack)
 324                 IL_REMOVE(g_bot_targets, this);
 325         this.bot_attack = false;
 326         if(this.monster_attack)
 327                 IL_REMOVE(g_monster_targets, this);
 328         this.monster_attack = false;
 329         STAT(HUD, this) = HUD_NORMAL;
 330         this.iscreature = false;
 331         this.teleportable = TELEPORT_SIMPLE;
 332         if(this.damagedbycontents)
 333                 IL_REMOVE(g_damagedbycontents, this);
 334         this.damagedbycontents = false;
 335         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 336         SetSpectatee_status(this, etof(this));
 337         this.takedamage = DAMAGE_NO;
 338         this.solid = SOLID_NOT;
 339         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 340         this.flags = FL_CLIENT | FL_NOTARGET;
 341         this.effects = 0;
 342         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 343         this.pauserotarmor_finished = 0;
 344         this.pauserothealth_finished = 0;
 345         this.pauseregen_finished = 0;
 346         this.damageforcescale = 0;
 347         this.death_time = 0;
 348         this.respawn_flags = 0;
 349         this.respawn_time = 0;
 350         STAT(RESPAWN_TIME, this) = 0;
 351         this.alpha = 0;
 352         this.scale = 0;
 353         this.fade_time = 0;
 354         this.pain_finished = 0;
 355         STAT(AIR_FINISHED, this) = 0;
 356         //this.dphitcontentsmask = 0;
 357         this.dphitcontentsmask = DPCONTENTS_SOLID;
 358         if (autocvar_g_playerclip_collisions)
 359                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 360         this.pushltime = 0;
 361         this.istypefrag = 0;
 362         setthink(this, func_null);
 363         this.nextthink = 0;
 364         this.deadflag = DEAD_NO;
 365         UNSET_DUCKED(this);
 366         STAT(REVIVE_PROGRESS, this) = 0;
 367         this.revival_time = 0;
 368         this.draggable = drag_undraggable;
 369
 370         player_powerups_remove_all(this);
 371         this.items = 0;
 372         STAT(WEAPONS, this) = '0 0 0';
 373         this.drawonlytoclient = this;
 374
 375         this.viewloc = NULL;
 376
 377         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 378
 379         this.weaponmodel = "";
 380         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 381         {
 382                 this.weaponentities[slot] = NULL;
 383         }
 384         this.exteriorweaponentity = NULL;
 385         CS(this).killcount = FRAGS_SPECTATOR;
 386         this.velocity = '0 0 0';
 387         this.avelocity = '0 0 0';
 388         this.punchangle = '0 0 0';
 389         this.punchvector = '0 0 0';
 390         this.oldvelocity = this.velocity;
 391         this.event_damage = func_null;
 392         this.event_heal = func_null;
 393
 394         for(int slot = 0; slot < MAX_AXH; ++slot)
 395         {
 396                 entity axh = this.(AuxiliaryXhair[slot]);
 397                 this.(AuxiliaryXhair[slot]) = NULL;
 398
 399                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 400                         delete(axh);
 401         }
 402
 403         if (mutator_returnvalue)
 404         {
 405                 // mutator prevents resetting teams+score
 406         }
 407         else
 408         {
 409                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 410                 this.frags = FRAGS_SPECTATOR;
 411         }
 412
 413         bot_relinkplayerlist();
 414
 415         if (CS(this).just_joined)
 416                 CS(this).just_joined = false;
 417         if (this.wants_join)
 418                 this.wants_join = 0;
 419 }
 420
 421 int player_getspecies(entity this)
 422 {
 423         get_model_parameters(this.model, this.skin);
 424         int s = get_model_parameters_species;
 425         get_model_parameters(string_null, 0);
 426         if (s < 0) return SPECIES_HUMAN;
 427         return s;
 428 }
 429
 430 .float model_randomizer;
 431 void FixPlayermodel(entity player)
 432 {
 433         string defaultmodel = "";
 434         int defaultskin = 0;
 435         if(autocvar_sv_defaultcharacter)
 436         {
 437                 if(teamplay)
 438                 {
 439                         switch(player.team)
 440                         {
 441                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 442                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 443                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 444                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 445                         }
 446                 }
 447
 448                 if(defaultmodel == "")
 449                 {
 450                         defaultmodel = autocvar_sv_defaultplayermodel;
 451                         defaultskin = autocvar_sv_defaultplayerskin;
 452                 }
 453
 454                 int n = tokenize_console(defaultmodel);
 455                 if(n > 0)
 456                 {
 457                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 458                         // However, do NOT randomize if the player-selected model is in the list.
 459                         for (int i = 0; i < n; ++i)
 460                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 461                                         defaultmodel = argv(i);
 462                 }
 463
 464                 int i = strstrofs(defaultmodel, ":", 0);
 465                 if(i >= 0)
 466                 {
 467                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 468                         defaultmodel = substring(defaultmodel, 0, i);
 469                 }
 470         }
 471         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 472         {
 473                 if(teamplay)
 474                 {
 475                         switch(player.team)
 476                         {
 477                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 478                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 479                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 480                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 481                         }
 482                 }
 483
 484                 if(!defaultskin)
 485                         defaultskin = autocvar_sv_defaultplayerskin;
 486         }
 487
 488         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 489         defaultmodel = M_ARGV(0, string);
 490         defaultskin = M_ARGV(1, int);
 491
 492         bool chmdl = false;
 493         int oldskin;
 494         if(defaultmodel != "")
 495         {
 496                 if (defaultmodel != player.model)
 497                 {
 498                         vector m1 = player.mins;
 499                         vector m2 = player.maxs;
 500                         setplayermodel (player, defaultmodel);
 501                         setsize (player, m1, m2);
 502                         chmdl = true;
 503                 }
 504
 505                 oldskin = player.skin;
 506                 player.skin = defaultskin;
 507         } else {
 508                 if (player.playermodel != player.model || player.playermodel == "")
 509                 {
 510                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 511                         vector m1 = player.mins;
 512                         vector m2 = player.maxs;
 513                         setplayermodel (player, player.playermodel);
 514                         setsize (player, m1, m2);
 515                         chmdl = true;
 516                 }
 517
 518                 if(!autocvar_sv_defaultcharacterskin)
 519                 {
 520                         oldskin = player.skin;
 521                         player.skin = stof(player.playerskin);
 522                 }
 523                 else
 524                 {
 525                         oldskin = player.skin;
 526                         player.skin = defaultskin;
 527                 }
 528         }
 529
 530         if(chmdl || oldskin != player.skin) // model or skin has changed
 531         {
 532                 player.species = player_getspecies(player); // update species
 533                 if(!autocvar_g_debug_globalsounds)
 534                         UpdatePlayerSounds(player); // update skin sounds
 535         }
 536
 537         if(!teamplay)
 538                 if(strlen(autocvar_sv_defaultplayercolors))
 539                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 540                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 541 }
 542
 543 void GiveWarmupResources(entity this)
 544 {
 545         SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 546         SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 547         SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 548         SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 549         SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 550         SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 551         SetResource(this, RES_HEALTH, warmup_start_health);
 552         SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 553         STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 554 }
 555
 556 void PutPlayerInServer(entity this)
 557 {
 558         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 559
 560         PlayerState_attach(this);
 561         accuracy_resend(this);
 562
 563         if (teamplay && this.bot_forced_team)
 564                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 565
 566         if (this.team < 0)
 567                 TeamBalance_JoinBestTeam(this);
 568
 569         entity spot = SelectSpawnPoint(this, false);
 570         if (!spot) {
 571                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 572                 return; // spawn failed
 573         }
 574
 575         TRANSMUTE(Player, this);
 576
 577         CS(this).wasplayer = true;
 578         this.iscreature = true;
 579         this.teleportable = TELEPORT_NORMAL;
 580         if(!this.damagedbycontents)
 581                 IL_PUSH(g_damagedbycontents, this);
 582         this.damagedbycontents = true;
 583         set_movetype(this, MOVETYPE_WALK);
 584         this.solid = SOLID_SLIDEBOX;
 585         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 586         if (autocvar_g_playerclip_collisions)
 587                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 588         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 589                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 590         this.frags = FRAGS_PLAYER;
 591         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 592         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 593         if (autocvar__notarget)
 594                 this.flags |= FL_NOTARGET;
 595         this.takedamage = DAMAGE_AIM;
 596         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 597
 598         if (warmup_stage)
 599                 GiveWarmupResources(this);
 600         else
 601         {
 602                 SetResource(this, RES_SHELLS, start_ammo_shells);
 603                 SetResource(this, RES_BULLETS, start_ammo_nails);
 604                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 605                 SetResource(this, RES_CELLS, start_ammo_cells);
 606                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 607                 SetResource(this, RES_FUEL, start_ammo_fuel);
 608                 SetResource(this, RES_HEALTH, start_health);
 609                 SetResource(this, RES_ARMOR, start_armorvalue);
 610                 STAT(WEAPONS, this) = start_weapons;
 611                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 612                 {
 613                         GiveRandomWeapons(this, random_start_weapons_count,
 614                                 autocvar_g_random_start_weapons, random_start_ammo);
 615                 }
 616         }
 617         SetSpectatee_status(this, 0);
 618
 619         PS(this).dual_weapons = '0 0 0';
 620
 621         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 622                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 623
 624         this.items = start_items;
 625
 626         float shieldtime = time + autocvar_g_spawnshieldtime;
 627
 628         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 629         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 630         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 631         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 632         if (!sv_ready_restart_after_countdown && time < game_starttime)
 633         {
 634                 float f = game_starttime - time;
 635                 shieldtime += f;
 636                 this.pauserotarmor_finished += f;
 637                 this.pauserothealth_finished += f;
 638                 this.pauseregen_finished += f;
 639         }
 640
 641         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 642
 643         this.damageforcescale = autocvar_g_player_damageforcescale;
 644         this.death_time = 0;
 645         this.respawn_flags = 0;
 646         this.respawn_time = 0;
 647         STAT(RESPAWN_TIME, this) = 0;
 648         // DP model scaling uses 1/16 accuracy and 13/16 is closest to 56/69
 649         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.8125 : autocvar_sv_player_scale);
 650         this.fade_time = 0;
 651         this.pain_finished = 0;
 652         this.pushltime = 0;
 653         setthink(this, func_null); // players have no think function
 654         this.nextthink = 0;
 655         this.dmg_team = 0;
 656         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 657
 658         this.deadflag = DEAD_NO;
 659
 660         this.angles = spot.angles;
 661         this.angles_z = 0; // never spawn tilted even if the spot says to
 662         if (IS_BOT_CLIENT(this))
 663         {
 664                 this.v_angle = this.angles;
 665                 bot_aim_reset(this);
 666         }
 667         this.fixangle = true; // turn this way immediately
 668         this.oldvelocity = this.velocity = '0 0 0';
 669         this.avelocity = '0 0 0';
 670         this.punchangle = '0 0 0';
 671         this.punchvector = '0 0 0';
 672
 673         STAT(REVIVE_PROGRESS, this) = 0;
 674         this.revival_time = 0;
 675
 676         STAT(AIR_FINISHED, this) = 0;
 677         this.waterlevel = WATERLEVEL_NONE;
 678         this.watertype = CONTENT_EMPTY;
 679
 680         entity spawnevent = new_pure(spawnevent);
 681         spawnevent.owner = this;
 682         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 683
 684         // Cut off any still running player sounds.
 685         stopsound(this, CH_PLAYER_SINGLE);
 686
 687         this.model = "";
 688         FixPlayermodel(this);
 689         this.drawonlytoclient = NULL;
 690
 691         this.viewloc = NULL;
 692
 693         for(int slot = 0; slot < MAX_AXH; ++slot)
 694         {
 695                 entity axh = this.(AuxiliaryXhair[slot]);
 696                 this.(AuxiliaryXhair[slot]) = NULL;
 697
 698                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 699                         delete(axh);
 700         }
 701
 702         this.spawnpoint_targ = NULL;
 703
 704         UNSET_DUCKED(this);
 705         this.view_ofs = STAT(PL_VIEW_OFS, this);
 706         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 707         this.spawnorigin = spot.origin;
 708         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 709         // don't reset back to last position, even if new position is stuck in solid
 710         this.oldorigin = this.origin;
 711         if(this.conveyor)
 712                 IL_REMOVE(g_conveyed, this);
 713         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 714         if(this.swampslug)
 715                 IL_REMOVE(g_swamped, this);
 716         this.swampslug = NULL;
 717         this.swamp_interval = 0;
 718         if(this.ladder_entity)
 719                 IL_REMOVE(g_ladderents, this);
 720         this.ladder_entity = NULL;
 721         IL_EACH(g_counters, it.realowner == this,
 722         {
 723                 delete(it);
 724         });
 725         STAT(HUD, this) = HUD_NORMAL;
 726
 727         this.event_damage = PlayerDamage;
 728         this.event_heal = PlayerHeal;
 729
 730         this.draggable = func_null;
 731
 732         if(!this.bot_attack)
 733                 IL_PUSH(g_bot_targets, this);
 734         this.bot_attack = true;
 735         if(!this.monster_attack)
 736                 IL_PUSH(g_monster_targets, this);
 737         this.monster_attack = true;
 738         navigation_dynamicgoal_init(this, false);
 739
 740         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 741
 742         // player was spectator
 743         if (CS(this).killcount == FRAGS_SPECTATOR) {
 744                 PlayerScore_Clear(this);
 745                 CS(this).killcount = 0;
 746                 CS(this).startplaytime = time;
 747         }
 748
 749         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 750         {
 751                 .entity weaponentity = weaponentities[slot];
 752                 CL_SpawnWeaponentity(this, weaponentity);
 753         }
 754         this.alpha = default_player_alpha;
 755         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 756         this.exteriorweaponentity.alpha = default_weapon_alpha;
 757
 758         this.speedrunning = false;
 759
 760         this.counter_cnt = 0;
 761         this.fragsfilter_cnt = 0;
 762
 763         target_voicescript_clear(this);
 764
 765         // reset fields the weapons may use
 766         FOREACH(Weapons, true, {
 767                 it.wr_resetplayer(it, this);
 768                         // reload all reloadable weapons
 769                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 770                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 771                         {
 772                                 .entity weaponentity = weaponentities[slot];
 773                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 774                         }
 775                 }
 776         });
 777
 778         Unfreeze(this, false);
 779
 780         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 781         {
 782                 string s = spot.target;
 783                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 784                         spot.target = string_null;
 785                 SUB_UseTargets(spot, this, NULL);
 786                 if(g_assault || g_race)
 787                         spot.target = s;
 788         }
 789
 790         if (autocvar_spawn_debug)
 791         {
 792                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 793                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 794         }
 795
 796         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 797         {
 798                 .entity weaponentity = weaponentities[slot];
 799                 entity w_ent = this.(weaponentity);
 800                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 801                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 802                 else
 803                         w_ent.m_switchweapon = WEP_Null;
 804                 w_ent.m_weapon = WEP_Null;
 805                 w_ent.weaponname = "";
 806                 w_ent.m_switchingweapon = WEP_Null;
 807                 w_ent.cnt = -1;
 808         }
 809
 810         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 811
 812         if (CS(this).impulse) ImpulseCommands(this);
 813
 814         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 815         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 816         {
 817                 .entity weaponentity = weaponentities[slot];
 818                 W_WeaponFrame(this, weaponentity);
 819         }
 820
 821         if (!warmup_stage && !this.alivetime)
 822                 this.alivetime = time;
 823
 824         antilag_clear(this, CS(this));
 825
 826         if (warmup_stage < 0 || warmup_stage > 1)
 827                 ReadyCount();
 828 }
 829
 830 /** Called when a client spawns in the server */
 831 void PutClientInServer(entity this)
 832 {
 833         if (IS_REAL_CLIENT(this)) {
 834                 msg_entity = this;
 835                 WriteByte(MSG_ONE, SVC_SETVIEW);
 836                 WriteEntity(MSG_ONE, this);
 837         }
 838         if (game_stopped)
 839                 TRANSMUTE(Observer, this);
 840
 841         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 842         SetSpectatee(this, NULL);
 843
 844         // reset player keys
 845         if(PS(this))
 846                 PS(this).itemkeys = 0;
 847
 848         MUTATOR_CALLHOOK(PutClientInServer, this);
 849
 850         if (IS_OBSERVER(this)) {
 851                 PutObserverInServer(this, false, use_spawnpoint);
 852         } else if (IS_PLAYER(this)) {
 853                 PutPlayerInServer(this);
 854         }
 855
 856         bot_relinkplayerlist();
 857 }
 858
 859 // TODO do we need all these fields, or should we stop autodetecting runtime
 860 // changes and just have a console command to update this?
 861 bool ClientInit_SendEntity(entity this, entity to, int sf)
 862 {
 863         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 864         return = true;
 865         msg_entity = to;
 866         // MSG_INIT replacement
 867         // TODO: make easier to use
 868         Registry_send_all();
 869         W_PROP_reload(MSG_ONE, to);
 870         ClientInit_misc(this);
 871         MUTATOR_CALLHOOK(Ent_Init);
 872 }
 873 void ClientInit_misc(entity this)
 874 {
 875         int channel = MSG_ONE;
 876         WriteHeader(channel, ENT_CLIENT_INIT);
 877         WriteByte(channel, g_nexball_meter_period * 32);
 878         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 879         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 880         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 881         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 882         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 883         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 884         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 885         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 886
 887         if(autocvar_sv_foginterval && world.fog != "")
 888                 WriteString(channel, world.fog);
 889         else
 890                 WriteString(channel, "");
 891         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 892         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 893         WriteByte(channel, serverflags);
 894         WriteCoord(channel, autocvar_g_trueaim_minrange);
 895 }
 896
 897 void ClientInit_CheckUpdate(entity this)
 898 {
 899         this.nextthink = time;
 900         if(this.count != autocvar_g_balance_armor_blockpercent)
 901         {
 902                 this.count = autocvar_g_balance_armor_blockpercent;
 903                 this.SendFlags |= 1;
 904         }
 905         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 906         {
 907                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 908                 this.SendFlags |= 1;
 909         }
 910 }
 911
 912 void ClientInit_Spawn()
 913 {
 914         entity e = new_pure(clientinit);
 915         setthink(e, ClientInit_CheckUpdate);
 916         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 917
 918         ClientInit_CheckUpdate(e);
 919 }
 920
 921 /*
 922 =============
 923 SetNewParms
 924 =============
 925 */
 926 void SetNewParms ()
 927 {
 928         // initialize parms for a new player
 929         parm1 = -(86400 * 366);
 930
 931         MUTATOR_CALLHOOK(SetNewParms);
 932 }
 933
 934 /*
 935 =============
 936 SetChangeParms
 937 =============
 938 */
 939 void SetChangeParms (entity this)
 940 {
 941         // save parms for level change
 942         parm1 = CS(this).parm_idlesince - time;
 943
 944         MUTATOR_CALLHOOK(SetChangeParms);
 945 }
 946
 947 /*
 948 =============
 949 DecodeLevelParms
 950 =============
 951 */
 952 void DecodeLevelParms(entity this)
 953 {
 954         // load parms
 955         CS(this).parm_idlesince = parm1;
 956         if (CS(this).parm_idlesince == -(86400 * 366))
 957                 CS(this).parm_idlesince = time;
 958
 959         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 960         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 961
 962         MUTATOR_CALLHOOK(DecodeLevelParms);
 963 }
 964
 965 void FixClientCvars(entity e)
 966 {
 967         // send prediction settings to the client
 968         if(autocvar_g_antilag == 3) // client side hitscan
 969                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 970         if(autocvar_sv_gentle)
 971                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 972
 973         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 974         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 975
 976         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 977
 978         MUTATOR_CALLHOOK(FixClientCvars, e);
 979 }
 980
 981 bool findinlist_abbrev(string tofind, string list)
 982 {
 983         if(list == "" || tofind == "")
 984                 return false; // empty list or search, just return
 985
 986         // this function allows abbreviated strings!
 987         FOREACH_WORD(list, it != "" && it == substring(tofind, 0, strlen(it)),
 988         {
 989                 return true;
 990         });
 991
 992         return false;
 993 }
 994
 995 bool PlayerInIPList(entity p, string iplist)
 996 {
 997         // some safety checks (never allow local?)
 998         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 999                 return false;
1000
1001         return findinlist_abbrev(p.netaddress, iplist);
1002 }
1003
1004 bool PlayerInIDList(entity p, string idlist)
1005 {
1006         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1007         if(!p.crypto_idfp)
1008                 return false;
1009
1010         return findinlist_abbrev(p.crypto_idfp, idlist);
1011 }
1012
1013 bool PlayerInList(entity player, string list)
1014 {
1015         if (list == "")
1016                 return false;
1017         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1018 }
1019
1020 #ifdef DP_EXT_PRECONNECT
1021 /*
1022 =============
1023 ClientPreConnect
1024
1025 Called once (not at each match start) when a client begins a connection to the server
1026 =============
1027 */
1028 void ClientPreConnect(entity this)
1029 {
1030         if(autocvar_sv_eventlog)
1031         {
1032                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1033                         this.playerid,
1034                         etof(this),
1035                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1036                 ));
1037         }
1038 }
1039 #endif
1040
1041 // NOTE csqc uses the active mutators list sent by this function
1042 // to understand which mutators are enabled
1043 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1044 void SendWelcomeMessage(entity this, int msg_type)
1045 {
1046         WriteByte(msg_type, boolean(autocvar_g_campaign));
1047         if (boolean(autocvar_g_campaign))
1048         {
1049                 WriteByte(msg_type, Campaign_GetLevelNum());
1050                 return;
1051         }
1052         WriteString(msg_type, autocvar_hostname);
1053         WriteString(msg_type, autocvar_g_xonoticversion);
1054         WriteByte(msg_type, CS(this).version_mismatch);
1055         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1056         WriteByte(msg_type, autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers);
1057         WriteByte(msg_type, GetPlayerLimit());
1058
1059         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1060         string modifications = M_ARGV(0, string);
1061
1062         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1063                 modifications = strcat(modifications, ", No start weapons");
1064         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1065                 modifications = strcat(modifications, ", Low gravity");
1066         if(g_weapon_stay && !g_cts)
1067                 modifications = strcat(modifications, ", Weapons stay");
1068         if(autocvar_g_jetpack)
1069                 modifications = strcat(modifications, ", Jetpack");
1070         modifications = substring(modifications, 2, strlen(modifications) - 2);
1071
1072         WriteString(msg_type, modifications);
1073
1074         WriteString(msg_type, g_weaponarena_list);
1075
1076         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1077         {
1078                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1079                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1080         }
1081
1082         WriteString(msg_type, cache_mutatormsg);
1083
1084         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1085 }
1086
1087 /**
1088 =============
1089 ClientConnect
1090
1091 Called when a client connects to the server
1092 =============
1093 */
1094 void ClientConnect(entity this)
1095 {
1096         if (Ban_MaybeEnforceBanOnce(this)) return;
1097         assert(!IS_CLIENT(this), return);
1098         this.flags |= FL_CLIENT;
1099         assert(player_count >= 0, player_count = 0);
1100
1101         TRANSMUTE(Client, this);
1102         CS(this).version_nagtime = time + 10 + random() * 10;
1103
1104         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1105
1106         bot_clientconnect(this);
1107
1108         Player_DetermineForcedTeam(this);
1109
1110         TRANSMUTE(Observer, this);
1111
1112         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1113
1114         // always track bots, don't ask for cl_allow_uidtracking
1115         if (IS_BOT_CLIENT(this))
1116                 PlayerStats_GameReport_AddPlayer(this);
1117         else
1118                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1119
1120         if (autocvar_sv_eventlog)
1121                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1122
1123         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1124         this.wants_join = 0;
1125
1126         stuffcmd(this, clientstuff, "\n");
1127         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1128
1129         FixClientCvars(this);
1130
1131         // get version info from player
1132         stuffcmd(this, "cmd clientversion $gameversion\n");
1133
1134         // notify about available teams
1135         if (teamplay)
1136         {
1137                 entity balance = TeamBalance_CheckAllowedTeams(this);
1138                 int t = TeamBalance_GetAllowedTeams(balance);
1139                 TeamBalance_Destroy(balance);
1140                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1141         }
1142         else
1143         {
1144                 stuffcmd(this, "set _teams_available 0\n");
1145         }
1146
1147         bot_relinkplayerlist();
1148
1149         CS(this).spectatortime = time;
1150         if (blockSpectators)
1151         {
1152                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1153         }
1154
1155         CS(this).jointime = time;
1156
1157         if (IS_REAL_CLIENT(this))
1158         {
1159                 if (g_weaponarena_weapons == WEPSET(TUBA))
1160                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1161                 // quickmenu file must be put in a subfolder with an unique name
1162                 // to reduce chances of overriding custom client quickmenus
1163                 if (waypointeditor_enabled)
1164                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1165                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1166                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1167         }
1168
1169         if (!autocvar_sv_foginterval && world.fog != "")
1170                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1171
1172         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1173                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1174                         send_CSQC_teamnagger();
1175
1176         CSQCMODEL_AUTOINIT(this);
1177
1178         CS(this).model_randomizer = random();
1179
1180         if (IS_REAL_CLIENT(this))
1181                 sv_notice_join(this);
1182
1183         this.move_qcphysics = true;
1184
1185         // update physics stats (players can spawn before physics runs)
1186         Physics_UpdateStats(this);
1187
1188         IL_EACH(g_initforplayer, it.init_for_player, {
1189                 it.init_for_player(it, this);
1190         });
1191
1192         Handicap_Initialize(this);
1193
1194         // playban
1195         if (PlayerInList(this, autocvar_g_playban_list))
1196                 TRANSMUTE(Observer, this);
1197
1198         if (PlayerInList(this, autocvar_g_chatban_list)) // chatban
1199                 CS(this).muted = true;
1200
1201         MUTATOR_CALLHOOK(ClientConnect, this);
1202
1203         if (player_count == 1)
1204         {
1205                 if (autocvar_sv_autopause && server_is_dedicated)
1206                         setpause(0);
1207                 localcmd("\nsv_hook_firstjoin\n");
1208         }
1209 }
1210 /*
1211 =============
1212 ClientDisconnect
1213
1214 Called when a client disconnects from the server
1215 =============
1216 */
1217 .entity chatbubbleentity;
1218 void player_powerups_remove_all(entity this);
1219
1220 void ClientDisconnect(entity this)
1221 {
1222         assert(IS_CLIENT(this), return);
1223
1224         /* from "ignore" command */
1225         strfree(this.ignore_list);
1226         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it.ignore_list,
1227         {
1228                 if(it.crypto_idfp && it.crypto_idfp != "")
1229                         continue;
1230                 string mylist = ignore_removefromlist(it, this);
1231                 if(it.ignore_list)
1232                         strunzone(it.ignore_list);
1233
1234                 it.ignore_list = strzone(mylist);
1235         });
1236         /* from "ignore" command */
1237
1238         PlayerStats_GameReport_FinalizePlayer(this);
1239         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1240         if (CS(this).active_minigame) part_minigame(this);
1241         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1242
1243         if (autocvar_sv_eventlog)
1244                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1245
1246         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1247
1248         if(IS_SPEC(this))
1249                 SetSpectatee(this, NULL);
1250
1251         MUTATOR_CALLHOOK(ClientDisconnect, this);
1252
1253         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1254         strfree(CS_CVAR(this).weaponorder_byimpulse);
1255         ClientState_detach(this);
1256
1257         Portal_ClearAll(this);
1258
1259         Unfreeze(this, false);
1260
1261         RemoveGrapplingHooks(this);
1262
1263         // Here, everything has been done that requires this player to be a client.
1264
1265         this.flags &= ~FL_CLIENT;
1266
1267         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1268         if (this.killindicator) delete(this.killindicator);
1269
1270         IL_EACH(g_counters, it.realowner == this,
1271         {
1272                 delete(it);
1273         });
1274
1275         WaypointSprite_PlayerGone(this);
1276
1277         bot_relinkplayerlist();
1278
1279         strfree(this.clientstatus);
1280         if (this.personal) delete(this.personal);
1281
1282         this.playerid = 0;
1283         if (warmup_stage || game_starttime > time) ReadyCount();
1284         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1285
1286         player_powerups_remove_all(this); // stop powerup sound
1287
1288         ONREMOVE(this);
1289
1290         if (player_count == 0)
1291                 localcmd("\nsv_hook_lastleave\n");
1292
1293         if (teamplay && autocvar_g_balance_teams_remove)
1294                 TeamBalance_RemoveExcessPlayers(NULL);
1295 }
1296
1297 void ChatBubbleThink(entity this)
1298 {
1299         this.nextthink = time;
1300         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1301         {
1302                 if(this.owner) // but why can that ever be NULL?
1303                         this.owner.chatbubbleentity = NULL;
1304                 delete(this);
1305                 return;
1306         }
1307
1308         this.mdl = "";
1309
1310         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1311         {
1312                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1313                         this.mdl = "models/sprites/minigame_busy.iqm";
1314                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1315                         this.mdl = "models/misc/chatbubble.spr";
1316         }
1317
1318         if ( this.model != this.mdl )
1319                 _setmodel(this, this.mdl);
1320
1321 }
1322
1323 void UpdateChatBubble(entity this)
1324 {
1325         if (this.alpha < 0)
1326                 return;
1327         // spawn a chatbubble entity if needed
1328         if (!this.chatbubbleentity)
1329         {
1330                 this.chatbubbleentity = new(chatbubbleentity);
1331                 this.chatbubbleentity.owner = this;
1332                 this.chatbubbleentity.exteriormodeltoclient = this;
1333                 setthink(this.chatbubbleentity, ChatBubbleThink);
1334                 this.chatbubbleentity.nextthink = time;
1335                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1336                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1337                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1338                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1339                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1340                 //this.chatbubbleentity.model = "";
1341                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1342         }
1343 }
1344
1345 void calculate_player_respawn_time(entity this)
1346 {
1347         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1348                 return;
1349
1350         float gametype_setting_tmp;
1351         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1352         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1353         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1354         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1355         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1356         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1357
1358         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1359         if (teamplay)
1360         {
1361                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1362                         if(it.team == this.team)
1363                                 ++pcount;
1364                 });
1365                 if (sdelay_small_count == 0)
1366                         sdelay_small_count = 1;
1367                 if (sdelay_large_count == 0)
1368                         sdelay_large_count = 1;
1369         }
1370         else
1371         {
1372                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1373                         ++pcount;
1374                 });
1375                 if (sdelay_small_count == 0)
1376                 {
1377                         if (IS_INDEPENDENT_PLAYER(this))
1378                         {
1379                                 // Players play independently. No point in requiring enemies.
1380                                 sdelay_small_count = 1;
1381                         }
1382                         else
1383                         {
1384                                 // Players play AGAINST each other. Enemies required.
1385                                 sdelay_small_count = 2;
1386                         }
1387                 }
1388                 if (sdelay_large_count == 0)
1389                 {
1390                         if (IS_INDEPENDENT_PLAYER(this))
1391                         {
1392                                 // Players play independently. No point in requiring enemies.
1393                                 sdelay_large_count = 1;
1394                         }
1395                         else
1396                         {
1397                                 // Players play AGAINST each other. Enemies required.
1398                                 sdelay_large_count = 2;
1399                         }
1400                 }
1401         }
1402
1403         float sdelay;
1404
1405         if (pcount <= sdelay_small_count)
1406                 sdelay = sdelay_small;
1407         else if (pcount >= sdelay_large_count)
1408                 sdelay = sdelay_large;
1409         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1410                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1411
1412         if(waves)
1413                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1414         else
1415                 this.respawn_time = time + sdelay;
1416
1417         if(sdelay < sdelay_max)
1418                 this.respawn_time_max = time + sdelay_max;
1419         else
1420                 this.respawn_time_max = this.respawn_time;
1421
1422         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1423                 this.respawn_countdown = 10; // first number to count down from is 10
1424         else
1425                 this.respawn_countdown = -1; // do not count down
1426
1427         if(autocvar_g_forced_respawn)
1428                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1429 }
1430
1431 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1432 // added to the model skins
1433 /*void UpdateColorModHack()
1434 {
1435         float c;
1436         c = this.clientcolors & 15;
1437         // LordHavoc: only bothering to support white, green, red, yellow, blue
1438              if (!teamplay) this.colormod = '0 0 0';
1439         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1440         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1441         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1442         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1443         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1444         else this.colormod = '1 1 1';
1445 }*/
1446
1447 void respawn(entity this)
1448 {
1449         bool damagedbycontents_prev = this.damagedbycontents;
1450         if(this.alpha >= 0)
1451         {
1452                 if(autocvar_g_respawn_ghosts)
1453                 {
1454                         this.solid = SOLID_NOT;
1455                         this.takedamage = DAMAGE_NO;
1456                         this.damagedbycontents = false;
1457                         set_movetype(this, MOVETYPE_FLY);
1458                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1459                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1460                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1461                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1462                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1463                         if(autocvar_g_respawn_ghosts_time > 0)
1464                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1465                 }
1466                 else
1467                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1468         }
1469
1470         CopyBody(this, 1);
1471         this.damagedbycontents = damagedbycontents_prev;
1472
1473         this.effects |= EF_NODRAW; // prevent another CopyBody
1474         PutClientInServer(this);
1475 }
1476
1477 void play_countdown(entity this, float finished, Sound samp)
1478 {
1479         TC(Sound, samp);
1480         float time_left = finished - time;
1481         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1482                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1483 }
1484
1485 // it removes special powerups not handled by StatusEffects
1486 void player_powerups_remove_all(entity this)
1487 {
1488         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1489         {
1490                 // don't play the poweroff sound when the game restarts or the player disconnects
1491                 if (time > game_starttime + 1 && IS_CLIENT(this)
1492                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1493                 {
1494                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1495                 }
1496                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1497                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1498                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1499         }
1500 }
1501
1502 void player_powerups(entity this)
1503 {
1504         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1505                 this.modelflags |= MF_ROCKET;
1506         else
1507                 this.modelflags &= ~MF_ROCKET;
1508
1509         this.effects &= ~EF_NODEPTHTEST;
1510
1511         if (IS_DEAD(this))
1512                 player_powerups_remove_all(this);
1513
1514         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1515                 return;
1516
1517         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1518         int items_prev = this.items;
1519
1520         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1521         {
1522                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1523                 if (this.items & IT_SUPERWEAPON)
1524                 {
1525                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1526                         {
1527                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1528                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1529                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1530                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1531                         }
1532                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1533                         {
1534                                 // don't let them run out
1535                         }
1536                         else
1537                         {
1538                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1539                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1540                                 {
1541                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1542                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1543                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1544                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1545                                 }
1546                         }
1547                 }
1548                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1549                 {
1550                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1551                         {
1552                                 this.items = this.items | IT_SUPERWEAPON;
1553                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1554                                 {
1555                                         if(!g_cts)
1556                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1557                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1558                                 }
1559                         }
1560                         else
1561                         {
1562                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1563                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1564                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1565                         }
1566                 }
1567                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1568                 {
1569                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1570                 }
1571         }
1572
1573         if(autocvar_g_nodepthtestplayers)
1574                 this.effects = this.effects | EF_NODEPTHTEST;
1575
1576         if(autocvar_g_fullbrightplayers)
1577                 this.effects = this.effects | EF_FULLBRIGHT;
1578
1579         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1580 }
1581
1582 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1583 {
1584         if(current > stable)
1585                 return current;
1586         else if(current > stable - 0.25) // when close enough, "snap"
1587                 return stable;
1588         else
1589                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1590 }
1591
1592 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1593 {
1594         if(current < stable)
1595                 return current;
1596         else if(current < stable + 0.25) // when close enough, "snap"
1597                 return stable;
1598         else
1599                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1600 }
1601
1602 void RotRegen(entity this, Resource res, float limit_mod,
1603         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1604         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1605 {
1606         float old = GetResource(this, res);
1607         float current = old;
1608         if(current > rotstable)
1609         {
1610                 if(rotframetime > 0)
1611                 {
1612                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1613                         current = max(rotstable, current - rotlinear * rotframetime);
1614                 }
1615         }
1616         else if(current < regenstable)
1617         {
1618                 if(regenframetime > 0)
1619                 {
1620                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1621                         current = min(regenstable, current + regenlinear * regenframetime);
1622                 }
1623         }
1624
1625         float limit = GetResourceLimit(this, res) * limit_mod;
1626         if(current > limit)
1627                 current = limit;
1628
1629         if (current != old)
1630                 SetResource(this, res, current);
1631 }
1632
1633 void player_regen(entity this)
1634 {
1635         float max_mod, regen_mod, rot_mod, limit_mod;
1636         max_mod = regen_mod = rot_mod = limit_mod = 1;
1637
1638         float regen_health = autocvar_g_balance_health_regen;
1639         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1640         float regen_health_rot = autocvar_g_balance_health_rot;
1641         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1642         float regen_health_stable = autocvar_g_balance_health_regenstable;
1643         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1644         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1645                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1646         max_mod = M_ARGV(1, float);
1647         regen_mod = M_ARGV(2, float);
1648         rot_mod = M_ARGV(3, float);
1649         limit_mod = M_ARGV(4, float);
1650         regen_health = M_ARGV(5, float);
1651         regen_health_linear = M_ARGV(6, float);
1652         regen_health_rot = M_ARGV(7, float);
1653         regen_health_rotlinear = M_ARGV(8, float);
1654         regen_health_stable = M_ARGV(9, float);
1655         regen_health_rotstable = M_ARGV(10, float);
1656
1657         float rotstable, regenstable, rotframetime, regenframetime;
1658
1659         if(!mutator_returnvalue)
1660         if(!STAT(FROZEN, this))
1661         {
1662                 regenstable = autocvar_g_balance_armor_regenstable;
1663                 rotstable = autocvar_g_balance_armor_rotstable;
1664                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1665                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1666                 RotRegen(this, RES_ARMOR, limit_mod,
1667                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1668                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1669
1670                 // NOTE: max_mod is only applied to health
1671                 regenstable = regen_health_stable * max_mod;
1672                 rotstable = regen_health_rotstable * max_mod;
1673                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1674                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1675                 RotRegen(this, RES_HEALTH, limit_mod,
1676                         regenstable, regen_health, regen_health_linear, regenframetime,
1677                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1678         }
1679
1680         // if player rotted to death...  die!
1681         // check this outside above checks, as player may still be able to rot to death
1682         if(GetResource(this, RES_HEALTH) < 1)
1683         {
1684                 if(this.vehicle)
1685                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1686                 if(this.event_damage)
1687                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1688         }
1689
1690         if (!(this.items & IT_UNLIMITED_AMMO))
1691         {
1692                 regenstable = autocvar_g_balance_fuel_regenstable;
1693                 rotstable = autocvar_g_balance_fuel_rotstable;
1694                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1695                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1696                 RotRegen(this, RES_FUEL, 1,
1697                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1698                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1699         }
1700 }
1701
1702 bool zoomstate_set;
1703 void SetZoomState(entity this, float newzoom)
1704 {
1705         if(newzoom != CS(this).zoomstate)
1706         {
1707                 CS(this).zoomstate = newzoom;
1708                 ClientData_Touch(this);
1709         }
1710         zoomstate_set = true;
1711 }
1712
1713 void GetPressedKeys(entity this)
1714 {
1715         MUTATOR_CALLHOOK(GetPressedKeys, this);
1716         if (game_stopped)
1717         {
1718                 CS(this).pressedkeys = 0;
1719                 STAT(PRESSED_KEYS, this) = 0;
1720                 return;
1721         }
1722
1723         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1724         int keys = STAT(PRESSED_KEYS, this);
1725         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1726         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1727         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1728         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1729
1730         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1731         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1732         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1733         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1734         CS(this).pressedkeys = keys; // store for other users
1735
1736         STAT(PRESSED_KEYS, this) = keys;
1737 }
1738
1739 /*
1740 ======================
1741 spectate mode routines
1742 ======================
1743 */
1744
1745 void SpectateCopy(entity this, entity spectatee)
1746 {
1747         TC(Client, this); TC(Client, spectatee);
1748
1749         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1750         PS(this) = PS(spectatee);
1751         this.armortype = spectatee.armortype;
1752         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1753         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1754         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1755         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1756         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1757         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1758         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1759         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1760         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1761         CS(this).impulse = 0;
1762         this.disableclientprediction = 1; // no need to run prediction on a spectator
1763         this.items = spectatee.items;
1764         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1765         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1766         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1767         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1768         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1769         this.punchangle = spectatee.punchangle;
1770         this.view_ofs = spectatee.view_ofs;
1771         this.velocity = spectatee.velocity;
1772         this.dmg_take = spectatee.dmg_take;
1773         this.dmg_save = spectatee.dmg_save;
1774         this.dmg_inflictor = spectatee.dmg_inflictor;
1775         this.v_angle = spectatee.v_angle;
1776         this.angles = spectatee.v_angle;
1777         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1778         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1779         this.viewloc = spectatee.viewloc;
1780         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1781                 this.fixangle = true;
1782         setorigin(this, spectatee.origin);
1783         setsize(this, spectatee.mins, spectatee.maxs);
1784         SetZoomState(this, CS(spectatee).zoomstate);
1785
1786     anticheat_spectatecopy(this, spectatee);
1787         STAT(HUD, this) = STAT(HUD, spectatee);
1788         if(spectatee.vehicle)
1789     {
1790         this.angles = spectatee.v_angle;
1791
1792         //this.fixangle = false;
1793         //this.velocity = spectatee.vehicle.velocity;
1794         this.vehicle_health = spectatee.vehicle_health;
1795         this.vehicle_shield = spectatee.vehicle_shield;
1796         this.vehicle_energy = spectatee.vehicle_energy;
1797         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1798         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1799         this.vehicle_reload1 = spectatee.vehicle_reload1;
1800         this.vehicle_reload2 = spectatee.vehicle_reload2;
1801
1802         //msg_entity = this;
1803
1804        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1805             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1806            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1807            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1808
1809         //WriteByte (MSG_ONE, SVC_SETVIEW);
1810         //    WriteEntity(MSG_ONE, this);
1811         //makevectors(spectatee.v_angle);
1812         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1813     }
1814 }
1815
1816 bool SpectateUpdate(entity this)
1817 {
1818         if(!this.enemy)
1819                 return false;
1820
1821         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1822         {
1823                 SetSpectatee(this, NULL);
1824                 return false;
1825         }
1826
1827         SpectateCopy(this, this.enemy);
1828
1829         return true;
1830 }
1831
1832 bool SpectateSet(entity this)
1833 {
1834         if(!IS_PLAYER(this.enemy))
1835                 return false;
1836
1837         ClientData_Touch(this.enemy);
1838
1839         msg_entity = this;
1840         WriteByte(MSG_ONE, SVC_SETVIEW);
1841         WriteEntity(MSG_ONE, this.enemy);
1842         set_movetype(this, MOVETYPE_NONE);
1843         accuracy_resend(this);
1844
1845         if(!SpectateUpdate(this))
1846                 PutObserverInServer(this, false, true);
1847
1848         return true;
1849 }
1850
1851 void SetSpectatee_status(entity this, int spectatee_num)
1852 {
1853         int oldspectatee_status = CS(this).spectatee_status;
1854         CS(this).spectatee_status = spectatee_num;
1855
1856         if (CS(this).spectatee_status != oldspectatee_status)
1857         {
1858                 if (STAT(PRESSED_KEYS, this))
1859                 {
1860                         CS(this).pressedkeys = 0;
1861                         STAT(PRESSED_KEYS, this) = 0;
1862                 }
1863                 ClientData_Touch(this);
1864                 if (g_race || g_cts) race_InitSpectator();
1865         }
1866 }
1867
1868 void SetSpectatee(entity this, entity spectatee)
1869 {
1870         if(IS_BOT_CLIENT(this))
1871                 return; // bots abuse .enemy, this code is useless to them
1872
1873         entity old_spectatee = this.enemy;
1874
1875         this.enemy = spectatee;
1876
1877         // WEAPONTODO
1878         // these are required to fix the spectator bug with arc
1879         if(old_spectatee)
1880         {
1881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1882                 {
1883                         .entity weaponentity = weaponentities[slot];
1884                         if(old_spectatee.(weaponentity).arc_beam)
1885                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1886                 }
1887         }
1888         if(spectatee)
1889         {
1890                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891                 {
1892                         .entity weaponentity = weaponentities[slot];
1893                         if(spectatee.(weaponentity).arc_beam)
1894                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1895                 }
1896         }
1897
1898         if (spectatee)
1899                 SetSpectatee_status(this, etof(spectatee));
1900
1901         // needed to update spectator list
1902         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1903 }
1904
1905 bool Spectate(entity this, entity pl)
1906 {
1907         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1908                 return false;
1909         pl = M_ARGV(1, entity);
1910
1911         SetSpectatee(this, pl);
1912         return SpectateSet(this);
1913 }
1914
1915 bool SpectateNext(entity this)
1916 {
1917         entity ent = find(this.enemy, classname, STR_PLAYER);
1918
1919         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1920                 ent = M_ARGV(1, entity);
1921         else if (!ent)
1922                 ent = find(ent, classname, STR_PLAYER);
1923
1924         if(ent) { SetSpectatee(this, ent); }
1925
1926         return SpectateSet(this);
1927 }
1928
1929 bool SpectatePrev(entity this)
1930 {
1931         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1932         entity ent = findchain(classname, STR_PLAYER);
1933         if (!ent) // no player
1934                 return false;
1935
1936         entity first = ent;
1937         // skip players until current spectated player
1938         if(this.enemy)
1939         while(ent && ent != this.enemy)
1940                 ent = ent.chain;
1941
1942         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1943         {
1944                 case MUT_SPECPREV_FOUND:
1945                         ent = M_ARGV(1, entity);
1946                         break;
1947                 case MUT_SPECPREV_RETURN:
1948                         return true;
1949                 case MUT_SPECPREV_CONTINUE:
1950                 default:
1951                 {
1952                         if(ent.chain)
1953                                 ent = ent.chain;
1954                         else
1955                                 ent = first;
1956                         break;
1957                 }
1958         }
1959
1960         SetSpectatee(this, ent);
1961         return SpectateSet(this);
1962 }
1963
1964 /*
1965 =============
1966 ShowRespawnCountdown()
1967
1968 Update a respawn countdown display.
1969 =============
1970 */
1971 void ShowRespawnCountdown(entity this)
1972 {
1973         float number;
1974         if(!IS_DEAD(this)) // just respawned?
1975                 return;
1976         else
1977         {
1978                 number = ceil(this.respawn_time - time);
1979                 if(number <= 0)
1980                         return;
1981                 if(number <= this.respawn_countdown)
1982                 {
1983                         this.respawn_countdown = number - 1;
1984                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1985                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1986                 }
1987         }
1988 }
1989
1990 bool ShowTeamSelection(entity this)
1991 {
1992         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1993                 return false;
1994         if (SpectatorWantsJoin(this))
1995                 return false;
1996         if (frametime) // once per frame is more than enough
1997                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1998         return true;
1999 }
2000
2001 void Join(entity this)
2002 {
2003         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
2004                 ReadyRestart(true);
2005
2006         TRANSMUTE(Player, this);
2007
2008         entity queued_join = SpectatorWantsJoin(this);
2009         if(queued_join)
2010                 this.team_selected = false; // Don't let this player select team
2011
2012         if(!this.team_selected)
2013         if(autocvar_g_campaign || autocvar_g_balance_teams || queued_join)
2014                 TeamBalance_JoinBestTeam(this);
2015
2016         if(autocvar_g_campaign)
2017                 campaign_bots_may_start = true;
2018
2019         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2020
2021         PutClientInServer(this);
2022
2023         if(IS_PLAYER(this))
2024         if(teamplay && this.team != -1)
2025         {
2026                 if(this.wants_join)
2027                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2028         }
2029         else
2030                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2031         this.team_selected = false;
2032         this.wants_join = 0;
2033
2034         if(queued_join)
2035                 Join(queued_join);
2036 }
2037
2038 int GetPlayerLimit()
2039 {
2040         if(g_duel)
2041                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2042         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
2043         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
2044         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2045         player_limit = M_ARGV(0, int);
2046         return player_limit < maxclients ? player_limit : 0;
2047 }
2048
2049 /**
2050  * Determines whether the player is allowed to join. This depends on cvar
2051  * g_maxplayers, if it isn't used this function always return true, otherwise
2052  * it checks whether the number of currently playing players exceeds g_maxplayers.
2053  * @return int number of free slots for players, 0 if none
2054  */
2055 int nJoinAllowed(entity this, entity ignore)
2056 {
2057         if(!ignore)
2058         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2059         // so report 0 free slots if restricted
2060         {
2061                 if(autocvar_g_forced_team_otherwise == "spectate")
2062                         return 0;
2063                 if(autocvar_g_forced_team_otherwise == "spectator")
2064                         return 0;
2065         }
2066
2067         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2068                 return 0; // forced spectators can never join
2069
2070         static float msg_time = 0;
2071         if(this && !INGAME(this) && ignore && PlayerInList(this, autocvar_g_playban_list))
2072         {
2073                 if(time > msg_time)
2074                 {
2075                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PLAYBAN);
2076                         msg_time = time + 0.5;
2077                 }
2078                 return 0;
2079         }
2080
2081         // TODO simplify this
2082         int totalClients = 0;
2083         int currentlyPlaying = 0;
2084         FOREACH_CLIENT(true, {
2085                 if(it != ignore)
2086                         ++totalClients;
2087                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2088                         ++currentlyPlaying;
2089         });
2090
2091         int player_limit = GetPlayerLimit();
2092
2093         int free_slots = 0;
2094         if (!player_limit)
2095                 free_slots = maxclients - totalClients;
2096         else if(player_limit > 0 && currentlyPlaying < player_limit)
2097                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2098
2099         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2100         {
2101                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT, player_limit);
2102                 msg_time = time + 0.5;
2103         }
2104
2105         return free_slots;
2106 }
2107
2108 bool queuePlayer(entity this)
2109 {
2110         if(IsQueueNeeded(this) && !SpectatorWantsJoin(this))
2111         {
2112                 if(autocvar_g_balance_teams)
2113                         TeamBalance_JoinBestTeam(this);
2114                 return true;
2115         }
2116         return false;
2117 }
2118
2119 bool joinAllowed(entity this)
2120 {
2121         if (CS(this).version_mismatch) return false;
2122         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2123         if (!nJoinAllowed(this, this)) return false;
2124         if (teamplay && lockteams) return false;
2125         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2126         if (ShowTeamSelection(this)) return false;
2127         if (this.wants_join) return false;
2128         if (queuePlayer(this)) return false;
2129         return true;
2130 }
2131
2132 void show_entnum(entity this)
2133 {
2134         // waypoint editor implements a similar feature for waypoints
2135         if (waypointeditor_enabled)
2136                 return;
2137
2138         if (wasfreed(this.wp_aimed))
2139                 this.wp_aimed = NULL;
2140
2141         WarpZone_crosshair_trace_plusvisibletriggers(this);
2142         entity ent = NULL;
2143         if (trace_ent)
2144         {
2145                 ent = trace_ent;
2146                 if (ent != this.wp_aimed)
2147                 {
2148                         string str = sprintf(
2149                                 "^7ent #%d\n^8 netname: ^3%s\n^8 classname: ^5%s\n^8 origin: ^2'%s'",
2150                                 etof(ent), ent.netname, ent.classname, vtos(ent.origin));
2151                         debug_text_3d((ent.absmin + ent.absmax) * 0.5, str, 0, 7, '0 0 0');
2152                 }
2153         }
2154         if (this.wp_aimed != ent)
2155                 this.wp_aimed = ent;
2156 }
2157
2158 .string shootfromfixedorigin;
2159 .bool dualwielding_prev;
2160 bool PlayerThink(entity this)
2161 {
2162         if (game_stopped || intermission_running) {
2163                 this.modelflags &= ~MF_ROCKET;
2164                 if(intermission_running)
2165                         IntermissionThink(this);
2166                 return false;
2167         }
2168
2169         if (timeout_status == TIMEOUT_ACTIVE) {
2170                 // don't allow the player to turn around while game is paused
2171                 // FIXME turn this into CSQC stuff
2172                 this.v_angle = this.lastV_angle;
2173                 this.angles = this.lastV_angle;
2174                 this.fixangle = true;
2175         }
2176
2177         if (frametime) player_powerups(this);
2178
2179         if (frametime && autocvar_sv_show_entnum) show_entnum(this);
2180
2181         if (IS_DEAD(this)) {
2182                 if (this.personal && g_race_qualifying) {
2183                         if (time > this.respawn_time) {
2184                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2185                                 respawn(this);
2186                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2187                         }
2188                 } else {
2189                         if (frametime) player_anim(this);
2190
2191                         if (this.respawn_flags & RESPAWN_DENY)
2192                         {
2193                                 STAT(RESPAWN_TIME, this) = 0;
2194                                 return false;
2195                         }
2196
2197                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2198
2199                         switch(this.deadflag)
2200                         {
2201                                 case DEAD_DYING:
2202                                 {
2203                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2204                                                 this.deadflag = DEAD_RESPAWNING;
2205                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2206                                                 this.deadflag = DEAD_DEAD;
2207                                         break;
2208                                 }
2209                                 case DEAD_DEAD:
2210                                 {
2211                                         if (button_pressed)
2212                                                 this.deadflag = DEAD_RESPAWNABLE;
2213                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2214                                                 this.deadflag = DEAD_RESPAWNING;
2215                                         break;
2216                                 }
2217                                 case DEAD_RESPAWNABLE:
2218                                 {
2219                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2220                                                 this.deadflag = DEAD_RESPAWNING;
2221                                         break;
2222                                 }
2223                                 case DEAD_RESPAWNING:
2224                                 {
2225                                         if (time > this.respawn_time)
2226                                         {
2227                                                 this.respawn_time = time + 1; // only retry once a second
2228                                                 this.respawn_time_max = this.respawn_time;
2229                                                 respawn(this);
2230                                         }
2231                                         break;
2232                                 }
2233                         }
2234
2235                         ShowRespawnCountdown(this);
2236
2237                         if (this.respawn_flags & RESPAWN_SILENT)
2238                                 STAT(RESPAWN_TIME, this) = 0;
2239                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2240                         {
2241                                 if (time < this.respawn_time)
2242                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2243                                 else if (this.deadflag != DEAD_RESPAWNING)
2244                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2245                         }
2246                         else
2247                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2248                 }
2249
2250                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2251                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2252                         STAT(RESPAWN_TIME, this) *= -1;
2253
2254                 return false;
2255         }
2256
2257         FixPlayermodel(this);
2258
2259         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2260                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2261                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2262         }
2263
2264         // reset gun alignment when dual wielding status changes
2265         // to ensure guns are always aligned right and left
2266         bool dualwielding = W_DualWielding(this);
2267         if(this.dualwielding_prev != dualwielding)
2268         {
2269                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2270                 this.dualwielding_prev = dualwielding;
2271         }
2272
2273         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2274         //if(frametime)
2275         {
2276                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2277                 {
2278                         .entity weaponentity = weaponentities[slot];
2279                         if(WEP_CVAR(vortex, charge_always))
2280                                 W_Vortex_Charge(this, weaponentity, frametime);
2281                         W_WeaponFrame(this, weaponentity);
2282                 }
2283         }
2284
2285         if (frametime)
2286         {
2287                 // WEAPONTODO: Add a weapon request for this
2288                 // rot vortex charge to the charge limit
2289                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2290                 {
2291                         .entity weaponentity = weaponentities[slot];
2292                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2293                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2294                 }
2295
2296                 player_regen(this);
2297                 player_anim(this);
2298                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2299         }
2300
2301         monsters_setstatus(this);
2302
2303         return true;
2304 }
2305
2306 .bool would_spectate;
2307 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2308 void ObserverOrSpectatorThink(entity this)
2309 {
2310         bool is_spec = IS_SPEC(this);
2311         if ( CS(this).impulse )
2312         {
2313                 int r = MinigameImpulse(this, CS(this).impulse);
2314                 if (!is_spec || r)
2315                         CS(this).impulse = 0;
2316
2317                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2318                 {
2319                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2320                         CS(this).impulse = 0;
2321                         return;
2322                 }
2323         }
2324
2325         if (frametime && autocvar_sv_show_entnum) show_entnum(this);
2326
2327         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2328         {
2329                 CS(this).autojoin_checked = true;
2330                 TRANSMUTE(Player, this);
2331                 PutClientInServer(this);
2332
2333                 .entity weaponentity = weaponentities[0];
2334                 if(this.(weaponentity).m_weapon == WEP_Null)
2335                         W_NextWeapon(this, 0, weaponentity);
2336
2337                 return;
2338         }
2339
2340         if (this.flags & FL_JUMPRELEASED) {
2341                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2342                         this.flags &= ~FL_JUMPRELEASED;
2343                         this.flags |= FL_SPAWNING;
2344                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2345                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2346                         this.flags &= ~FL_JUMPRELEASED;
2347                         if(SpectateNext(this)) {
2348                                 TRANSMUTE(Spectator, this);
2349                         } else if (is_spec) {
2350                                 TRANSMUTE(Observer, this);
2351                                 PutClientInServer(this);
2352                         }
2353                         else
2354                                 this.would_spectate = false; // unable to spectate anyone
2355                         if (is_spec)
2356                                 CS(this).impulse = 0;
2357                 } else if (is_spec) {
2358                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2359                                 this.flags &= ~FL_JUMPRELEASED;
2360                                 if(SpectatePrev(this)) {
2361                                         TRANSMUTE(Spectator, this);
2362                                 } else {
2363                                         TRANSMUTE(Observer, this);
2364                                         PutClientInServer(this);
2365                                 }
2366                                 CS(this).impulse = 0;
2367                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2368                                 if(!observe_blocked_if_eliminated || !INGAME(this)) {
2369                                         this.would_spectate = false;
2370                                         this.flags &= ~FL_JUMPRELEASED;
2371                                         TRANSMUTE(Observer, this);
2372                                         PutClientInServer(this);
2373                                 }
2374                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2375                                 PutObserverInServer(this, false, true);
2376                                 this.would_spectate = true;
2377                         }
2378                 }
2379                 else {
2380                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2381                         if (PHYS_INPUT_BUTTON_USE(this))
2382                                 wouldclip = !wouldclip;
2383                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2384                         set_movetype(this, preferred_movetype);
2385                 }
2386         } else { // jump pressed
2387                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2388                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2389                         this.flags |= FL_JUMPRELEASED;
2390                         // primary attack pressed
2391                         if(this.flags & FL_SPAWNING)
2392                         {
2393                                 this.flags &= ~FL_SPAWNING;
2394                                 if(joinAllowed(this))
2395                                         Join(this);
2396                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2397                                         CS(this).autojoin_checked = -1;
2398                                 return;
2399                         }
2400                 }
2401                 if(is_spec && !SpectateUpdate(this))
2402                         PutObserverInServer(this, false, true);
2403         }
2404         if (is_spec)
2405                 this.flags |= FL_CLIENT | FL_NOTARGET;
2406 }
2407
2408 void PlayerUseKey(entity this)
2409 {
2410         if (!IS_PLAYER(this))
2411                 return;
2412
2413         if(this.vehicle)
2414         {
2415                 if(!game_stopped)
2416                 {
2417                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2418                         return;
2419                 }
2420         }
2421         else if(autocvar_g_vehicles_enter)
2422         {
2423                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2424                 {
2425                         entity head, closest_target = NULL;
2426                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2427
2428                         while(head) // find the closest acceptable target to enter
2429                         {
2430                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2431                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2432                                 {
2433                                         if(closest_target)
2434                                         {
2435                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2436                                                 { closest_target = head; }
2437                                         }
2438                                         else { closest_target = head; }
2439                                 }
2440
2441                                 head = head.chain;
2442                         }
2443
2444                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2445                 }
2446         }
2447
2448         // a use key was pressed; call handlers
2449         MUTATOR_CALLHOOK(PlayerUseKey, this);
2450 }
2451
2452
2453 /*
2454 =============
2455 PlayerPreThink
2456
2457 Called every frame for each client before the physics are run
2458 =============
2459 */
2460 .float last_vehiclecheck;
2461 void PlayerPreThink (entity this)
2462 {
2463         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2464         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2465
2466         WarpZone_PlayerPhysics_FixVAngle(this);
2467
2468         if (frametime) {
2469                 // physics frames: update anticheat stuff
2470                 anticheat_prethink(this);
2471
2472                 // WORKAROUND: only use dropclient in server frames (frametime set).
2473                 // Never use it in cl_movement frames (frametime zero).
2474                 if (blockSpectators && IS_REAL_CLIENT(this)
2475                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2476                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2477                 {
2478                         if (dropclient_schedule(this))
2479                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2480                 }
2481         }
2482
2483         zoomstate_set = false;
2484
2485         // Check for nameless players
2486         if (this.netname == "" || this.netname != CS(this).netname_previous)
2487         {
2488                 bool assume_unchanged = (CS(this).netname_previous == "");
2489                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2490                 {
2491                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2492                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2493                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2494                         assume_unchanged = false;
2495                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2496                 }
2497                 if (isInvisibleString(this.netname))
2498                 {
2499                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2500                         sprint(this, "Warning: invisible names are not allowed.\n");
2501                         assume_unchanged = false;
2502                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2503                 }
2504                 if (!assume_unchanged && autocvar_sv_eventlog)
2505                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2506                 strcpy(CS(this).netname_previous, this.netname);
2507         }
2508
2509         // version nagging
2510         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2511         CS(this).version_nagtime = 0;
2512         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2513             // git client
2514         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2515             // git server
2516             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2517         } else {
2518             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2519             if (r < 0) { // old client
2520                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2521             } else if (r > 0) { // old server
2522                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2523             }
2524         }
2525     }
2526
2527         // GOD MODE info
2528         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2529         {
2530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2531                 this.max_armorvalue = 0;
2532         }
2533
2534         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2535         {
2536                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2537                 {
2538                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2539                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2540                         if (this.iceblock)
2541                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2542
2543                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2544                                 Unfreeze(this, false);
2545                 }
2546                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2547                 {
2548                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2549                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2550
2551                         if (GetResource(this, RES_HEALTH) < 1)
2552                         {
2553                                 if (this.vehicle)
2554                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2555                                 if(this.event_damage)
2556                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2557                         }
2558                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2559                                 Unfreeze(this, false);
2560                 }
2561         }
2562
2563         MUTATOR_CALLHOOK(PlayerPreThink, this);
2564
2565         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2566         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2567         {
2568                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2569                 {
2570                         if(!it.owner)
2571                         {
2572                                 if(!it.team || SAME_TEAM(this, it))
2573                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2574                                 else if(autocvar_g_vehicles_steal)
2575                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2576                         }
2577                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2578                         {
2579                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2580                         }
2581                 });
2582
2583                 this.last_vehiclecheck = time + 1;
2584         }
2585
2586         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2587                 PlayerUseKey(this);
2588         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2589
2590         if (IS_PLAYER(this)) {
2591                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2592                         error("Client can't be spawned as player on connection!");
2593                 if(!PlayerThink(this))
2594                         return;
2595         }
2596         else if (game_stopped || intermission_running) {
2597                 if(intermission_running)
2598                         IntermissionThink(this);
2599                 return;
2600         }
2601         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2602         {
2603                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2604                 CS(this).autojoin_checked = 1;
2605                 // don't do this in ClientConnect
2606                 // many things can go wrong if a client is spawned as player on connection
2607                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2608                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2609                                 && (!teamplay || autocvar_g_balance_teams)))
2610                 {
2611                         if(joinAllowed(this))
2612                                 Join(this);
2613                         return;
2614                 }
2615         }
2616         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2617                 ObserverOrSpectatorThink(this);
2618         }
2619
2620         // WEAPONTODO: Add weapon request for this
2621         if (!zoomstate_set) {
2622                 bool wep_zoomed = false;
2623                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2624                 {
2625                         .entity weaponentity = weaponentities[slot];
2626                         Weapon thiswep = this.(weaponentity).m_weapon;
2627                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2628                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2629                 }
2630                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2631         }
2632
2633         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2634         {
2635                 CS(this).teamkill_soundtime = 0;
2636
2637                 entity e = CS(this).teamkill_soundsource;
2638                 entity oldpusher = e.pusher;
2639                 e.pusher = this;
2640                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2641                 e.pusher = oldpusher;
2642         }
2643
2644         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2645                 CS(this).taunt_soundtime = 0;
2646                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2647         }
2648
2649         target_voicescript_next(this);
2650 }
2651
2652 void DrownPlayer(entity this)
2653 {
2654         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2655                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2656         {
2657                 STAT(AIR_FINISHED, this) = 0;
2658                 return;
2659         }
2660
2661         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2662         {
2663                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2664                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2665                 STAT(AIR_FINISHED, this) = 0;
2666         }
2667         else
2668         {
2669                 if (!STAT(AIR_FINISHED, this))
2670                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2671                 if (STAT(AIR_FINISHED, this) < time)
2672                 {       // drown!
2673                         if (this.pain_finished < time)
2674                         {
2675                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2676                                 this.pain_finished = time + 0.5;
2677                         }
2678                 }
2679         }
2680 }
2681
2682 .bool move_qcphysics;
2683
2684 void Player_Physics(entity this)
2685 {
2686         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2687
2688         if(!this.move_qcphysics)
2689                 return;
2690
2691         if(!frametime && !CS(this).pm_frametime)
2692                 return;
2693
2694         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2695
2696         CS(this).pm_frametime = 0;
2697 }
2698
2699 /*
2700 =============
2701 PlayerPostThink
2702
2703 Called every frame for each client after the physics are run
2704 =============
2705 */
2706 void PlayerPostThink (entity this)
2707 {
2708         Player_Physics(this);
2709
2710         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2711         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2712         if (IS_REAL_CLIENT(this))
2713         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2714         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2715         {
2716                 int totalClients = 0;
2717                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2718                 {
2719                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2720                         if (server_is_dedicated)
2721                         {
2722                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2723                                 {
2724                                         ++totalClients;
2725                                 });
2726                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2727                                         totalClients = 0;
2728                         }
2729                 }
2730                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2731                 {
2732                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2733                         {
2734                                 ++totalClients;
2735                         });
2736                 }
2737
2738                 if (totalClients < autocvar_sv_maxidle_minplayers)
2739                 {
2740                         // idle kick disabled
2741                         CS(this).parm_idlesince = time;
2742                 }
2743                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2744                 {
2745                         if (CS(this).idlekick_lasttimeleft)
2746                         {
2747                                 CS(this).idlekick_lasttimeleft = 0;
2748                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2749                         }
2750                 }
2751                 else
2752                 {
2753                         float maxidle_time = autocvar_sv_maxidle;
2754                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2755                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2756                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2757                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2758                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2759                         {
2760                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2761                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2762                                 else
2763                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2764                         }
2765                         if (timeleft <= 0) {
2766                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2767                                 {
2768                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2769                                         PutObserverInServer(this, true, true);
2770                                         if(autocvar_g_balance_teams_remove)
2771                                                 TeamBalance_RemoveExcessPlayers(this);
2772                                 }
2773                                 else
2774                                 {
2775                                         if (dropclient_schedule(this))
2776                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2777                                 }
2778                                 return;
2779                         }
2780                         else if (timeleft <= countdown_time) {
2781                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2782                                         play2(this, SND(TALK2));
2783                                 CS(this).idlekick_lasttimeleft = timeleft;
2784                         }
2785                 }
2786         }
2787
2788         CheatFrame(this);
2789
2790         if (game_stopped)
2791         {
2792                 this.solid = SOLID_NOT;
2793                 this.takedamage = DAMAGE_NO;
2794                 set_movetype(this, MOVETYPE_NONE);
2795                 CS(this).teamkill_complain = 0;
2796                 CS(this).teamkill_soundtime = 0;
2797                 CS(this).teamkill_soundsource = NULL;
2798         }
2799
2800         if (IS_PLAYER(this)) {
2801                 if(this.death_time == time && IS_DEAD(this))
2802                 {
2803                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2804                         // once all the damage events of this frame have been processed with normal size
2805                         this.maxs.z = 5;
2806                         setsize(this, this.mins, this.maxs);
2807                 }
2808                 DrownPlayer(this);
2809                 UpdateChatBubble(this);
2810                 if (CS(this).impulse) ImpulseCommands(this);
2811                 GetPressedKeys(this);
2812                 if (game_stopped)
2813                 {
2814                         CSQCMODEL_AUTOUPDATE(this);
2815                         return;
2816                 }
2817         }
2818         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2819         {
2820                 CS(this).pressedkeys = 0;
2821                 STAT(PRESSED_KEYS, this) = 0;
2822         }
2823
2824         if (this.waypointsprite_attachedforcarrier) {
2825                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2826                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2827         }
2828
2829         CSQCMODEL_AUTOUPDATE(this);
2830 }
2831
2832 // hack to copy the button fields from the client entity to the Client State
2833 void PM_UpdateButtons(entity this, entity store)
2834 {
2835         if(this.impulse)
2836                 store.impulse = this.impulse;
2837         this.impulse = 0;
2838
2839         bool typing = this.buttonchat || this.button12;
2840
2841         store.button0 = (typing) ? 0 : this.button0;
2842         //button1?!
2843         store.button2 = (typing) ? 0 : this.button2;
2844         store.button3 = (typing) ? 0 : this.button3;
2845         store.button4 = this.button4;
2846         store.button5 = (typing) ? 0 : this.button5;
2847         store.button6 = this.button6;
2848         store.button7 = this.button7;
2849         store.button8 = this.button8;
2850         store.button9 = this.button9;
2851         store.button10 = this.button10;
2852         store.button11 = this.button11;
2853         store.button12 = this.button12;
2854         store.button13 = this.button13;
2855         store.button14 = this.button14;
2856         store.button15 = this.button15;
2857         store.button16 = this.button16;
2858         store.buttonuse = this.buttonuse;
2859         store.buttonchat = this.buttonchat;
2860
2861         store.cursor_active = this.cursor_active;
2862         store.cursor_screen = this.cursor_screen;
2863         store.cursor_trace_start = this.cursor_trace_start;
2864         store.cursor_trace_endpos = this.cursor_trace_endpos;
2865         store.cursor_trace_ent = this.cursor_trace_ent;
2866
2867         store.ping = this.ping;
2868         store.ping_packetloss = this.ping_packetloss;
2869         store.ping_movementloss = this.ping_movementloss;
2870
2871         store.v_angle = this.v_angle;
2872         store.movement = this.movement;
2873 }
2874
2875 NET_HANDLE(fpsreport, bool)
2876 {
2877         int fps = ReadShort();
2878         PlayerScore_Set(sender, SP_FPS, fps);
2879         return true;
2880 }