qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 int CountSpectators(entity player, entity to)
 101 {
 102         if(!player) { return 0; } // not sure how, but best to be safe
 103
 104         int spec_count = 0;
 105
 106         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 107         {
 108                 spec_count++;
 109         });
 110
 111         return spec_count;
 112 }
 113
 114 void WriteSpectators(entity player, entity to)
 115 {
 116         if(!player) { return; } // not sure how, but best to be safe
 117
 118         int spec_count = 0;
 119         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 120         {
 121                 if(spec_count >= MAX_SPECTATORS)
 122                         break;
 123                 WriteByte(MSG_ENTITY, num_for_edict(it));
 124                 ++spec_count;
 125         });
 126 }
 127
 128 bool ClientData_Send(entity this, entity to, int sf)
 129 {
 130         assert(to == this.owner, return false);
 131
 132         entity e = to;
 133         if (IS_SPEC(e)) e = e.enemy;
 134
 135         sf = 0;
 136         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 137         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 138         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 139         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 140
 141         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if (sf & BIT(1))
 145                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 146
 147         if(sf & BIT(4))
 148         {
 149                 float specs = CountSpectators(e, to);
 150                 WriteByte(MSG_ENTITY, specs);
 151                 WriteSpectators(e, to);
 152         }
 153
 154         return true;
 155 }
 156
 157 void ClientData_Attach(entity this)
 158 {
 159         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 160         CS(this).clientdata.drawonlytoclient = this;
 161         CS(this).clientdata.owner = this;
 162 }
 163
 164 void ClientData_Detach(entity this)
 165 {
 166         delete(CS(this).clientdata);
 167         CS(this).clientdata = NULL;
 168 }
 169
 170 void ClientData_Touch(entity e)
 171 {
 172         entity cd = CS(e).clientdata;
 173         if (cd) { cd.SendFlags = 1; }
 174
 175         // make it spectatable
 176         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 177         {
 178                 entity cd = CS(it).clientdata;
 179                 if (cd) { cd.SendFlags = 1; }
 180         });
 181 }
 182
 183
 184 /*
 185 =============
 186 CheckPlayerModel
 187
 188 Checks if the argument string can be a valid playermodel.
 189 Returns a valid one in doubt.
 190 =============
 191 */
 192 string FallbackPlayerModel;
 193 string CheckPlayerModel(string plyermodel) {
 194         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 195         {
 196                 // note: we cannot summon Don Strunzone here, some player may
 197                 // still have the model string set. In case anyone manages how
 198                 // to change a cvar default, we'll have a small leak here.
 199                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 200         }
 201         // only in right path
 202         if(substring(plyermodel, 0, 14) != "models/player/")
 203                 return FallbackPlayerModel;
 204         // only good file extensions
 205         if(substring(plyermodel, -4, 4) != ".iqm"
 206                 && substring(plyermodel, -4, 4) != ".zym"
 207                 && substring(plyermodel, -4, 4) != ".dpm"
 208                 && substring(plyermodel, -4, 4) != ".md3"
 209                 && substring(plyermodel, -4, 4) != ".psk")
 210         {
 211                 return FallbackPlayerModel;
 212         }
 213         // forbid the LOD models
 214         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 215                 return FallbackPlayerModel;
 216         if(plyermodel != strtolower(plyermodel))
 217                 return FallbackPlayerModel;
 218         // also, restrict to server models
 219         if(autocvar_sv_servermodelsonly)
 220         {
 221                 if(!fexists(plyermodel))
 222                         return FallbackPlayerModel;
 223         }
 224         return plyermodel;
 225 }
 226
 227 void setplayermodel(entity e, string modelname)
 228 {
 229         precache_model(modelname);
 230         _setmodel(e, modelname);
 231         player_setupanimsformodel(e);
 232         if(!autocvar_g_debug_globalsounds)
 233                 UpdatePlayerSounds(e);
 234 }
 235
 236 /** putting a client as observer in the server */
 237 void PutObserverInServer(entity this)
 238 {
 239         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 240         PlayerState_detach(this);
 241
 242         if (IS_PLAYER(this))
 243         {
 244                 if(GetResource(this, RES_HEALTH) >= 1)
 245                 {
 246                         // despawn effect
 247                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 248                 }
 249
 250                 // was a player, recount votes and ready status
 251                 if(IS_REAL_CLIENT(this))
 252                 {
 253                         if (vote_called) { VoteCount(false); }
 254                         ReadyCount();
 255                 }
 256                 entcs_update_players(this);
 257         }
 258
 259         entity spot = SelectSpawnPoint(this, true);
 260         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 261         this.angles = vec2(spot.angles);
 262         this.fixangle = true;
 263         // offset it so that the spectator spawns higher off the ground, looks better this way
 264         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 265         if (IS_REAL_CLIENT(this))
 266         {
 267                 msg_entity = this;
 268                 WriteByte(MSG_ONE, SVC_SETVIEW);
 269                 WriteEntity(MSG_ONE, this);
 270         }
 271         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 272         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 273         if(!autocvar_g_debug_globalsounds)
 274         {
 275                 // needed for player sounds
 276                 this.model = "";
 277                 FixPlayermodel(this);
 278         }
 279         setmodel(this, MDL_Null);
 280         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 281         this.view_ofs = '0 0 0';
 282
 283         RemoveGrapplingHooks(this);
 284         Portal_ClearAll(this);
 285         Unfreeze(this, false);
 286         SetSpectatee(this, NULL);
 287
 288         if (this.alivetime)
 289         {
 290                 if (!warmup_stage)
 291                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 292                 this.alivetime = 0;
 293         }
 294
 295         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 296
 297         WaypointSprite_PlayerDead(this);
 298
 299         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 300                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 301
 302         accuracy_resend(this);
 303
 304         CS(this).spectatortime = time;
 305         if(this.bot_attack)
 306                 IL_REMOVE(g_bot_targets, this);
 307         this.bot_attack = false;
 308         if(this.monster_attack)
 309                 IL_REMOVE(g_monster_targets, this);
 310         this.monster_attack = false;
 311         STAT(HUD, this) = HUD_NORMAL;
 312         TRANSMUTE(Observer, this);
 313         this.iscreature = false;
 314         this.teleportable = TELEPORT_SIMPLE;
 315         if(this.damagedbycontents)
 316                 IL_REMOVE(g_damagedbycontents, this);
 317         this.damagedbycontents = false;
 318         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 319         SetSpectatee_status(this, etof(this));
 320         this.takedamage = DAMAGE_NO;
 321         this.solid = SOLID_NOT;
 322         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 323         this.flags = FL_CLIENT | FL_NOTARGET;
 324         this.effects = 0;
 325         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         STAT(RESPAWN_TIME, this) = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_finished = 0;
 338         STAT(STRENGTH_FINISHED, this) = 0;
 339         STAT(INVINCIBLE_FINISHED, this) = 0;
 340         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 341         STAT(AIR_FINISHED, this) = 0;
 342         //this.dphitcontentsmask = 0;
 343         this.dphitcontentsmask = DPCONTENTS_SOLID;
 344         if (autocvar_g_playerclip_collisions)
 345                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 346         this.pushltime = 0;
 347         this.istypefrag = 0;
 348         setthink(this, func_null);
 349         this.nextthink = 0;
 350         this.deadflag = DEAD_NO;
 351         UNSET_DUCKED(this);
 352         STAT(REVIVE_PROGRESS, this) = 0;
 353         this.revival_time = 0;
 354         this.draggable = drag_undraggable;
 355
 356         this.items = 0;
 357         STAT(WEAPONS, this) = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378         this.event_heal = func_null;
 379
 380         for(int slot = 0; slot < MAX_AXH; ++slot)
 381         {
 382                 entity axh = this.(AuxiliaryXhair[slot]);
 383                 this.(AuxiliaryXhair[slot]) = NULL;
 384
 385                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 386                         delete(axh);
 387         }
 388
 389         if (mutator_returnvalue)
 390         {
 391                 // mutator prevents resetting teams+score
 392         }
 393         else
 394         {
 395                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 396                 this.frags = FRAGS_SPECTATOR;
 397         }
 398         if (CS(this).just_joined)
 399                 CS(this).just_joined = false;
 400 }
 401
 402 int player_getspecies(entity this)
 403 {
 404         get_model_parameters(this.model, this.skin);
 405         int s = get_model_parameters_species;
 406         get_model_parameters(string_null, 0);
 407         if (s < 0) return SPECIES_HUMAN;
 408         return s;
 409 }
 410
 411 .float model_randomizer;
 412 void FixPlayermodel(entity player)
 413 {
 414         string defaultmodel = "";
 415         int defaultskin = 0;
 416         if(autocvar_sv_defaultcharacter)
 417         {
 418                 if(teamplay)
 419                 {
 420                         switch(player.team)
 421                         {
 422                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 423                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 424                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 425                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 426                         }
 427                 }
 428
 429                 if(defaultmodel == "")
 430                 {
 431                         defaultmodel = autocvar_sv_defaultplayermodel;
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433                 }
 434
 435                 int n = tokenize_console(defaultmodel);
 436                 if(n > 0)
 437                 {
 438                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 439                         // However, do NOT randomize if the player-selected model is in the list.
 440                         for (int i = 0; i < n; ++i)
 441                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 442                                         defaultmodel = argv(i);
 443                 }
 444
 445                 int i = strstrofs(defaultmodel, ":", 0);
 446                 if(i >= 0)
 447                 {
 448                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 449                         defaultmodel = substring(defaultmodel, 0, i);
 450                 }
 451         }
 452         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 453         {
 454                 if(teamplay)
 455                 {
 456                         switch(player.team)
 457                         {
 458                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 459                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 460                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 461                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 462                         }
 463                 }
 464
 465                 if(!defaultskin)
 466                         defaultskin = autocvar_sv_defaultplayerskin;
 467         }
 468
 469         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 470         defaultmodel = M_ARGV(0, string);
 471         defaultskin = M_ARGV(1, int);
 472
 473         bool chmdl = false;
 474         int oldskin;
 475         if(defaultmodel != "")
 476         {
 477                 if (defaultmodel != player.model)
 478                 {
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, defaultmodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 oldskin = player.skin;
 487                 player.skin = defaultskin;
 488         } else {
 489                 if (player.playermodel != player.model || player.playermodel == "")
 490                 {
 491                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, player.playermodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 if(!autocvar_sv_defaultcharacterskin)
 500                 {
 501                         oldskin = player.skin;
 502                         player.skin = stof(player.playerskin);
 503                 }
 504                 else
 505                 {
 506                         oldskin = player.skin;
 507                         player.skin = defaultskin;
 508                 }
 509         }
 510
 511         if(chmdl || oldskin != player.skin) // model or skin has changed
 512         {
 513                 player.species = player_getspecies(player); // update species
 514                 if(!autocvar_g_debug_globalsounds)
 515                         UpdatePlayerSounds(player); // update skin sounds
 516         }
 517
 518         if(!teamplay)
 519                 if(strlen(autocvar_sv_defaultplayercolors))
 520                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 521                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 522 }
 523
 524 void PutPlayerInServer(entity this)
 525 {
 526         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 527
 528         PlayerState_attach(this);
 529         accuracy_resend(this);
 530
 531         if (this.team < 0)
 532                 TeamBalance_JoinBestTeam(this);
 533
 534         entity spot = SelectSpawnPoint(this, false);
 535         if (!spot) {
 536                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 537                 return; // spawn failed
 538         }
 539
 540         TRANSMUTE(Player, this);
 541
 542         CS(this).wasplayer = true;
 543         this.iscreature = true;
 544         this.teleportable = TELEPORT_NORMAL;
 545         if(!this.damagedbycontents)
 546                 IL_PUSH(g_damagedbycontents, this);
 547         this.damagedbycontents = true;
 548         set_movetype(this, MOVETYPE_WALK);
 549         this.solid = SOLID_SLIDEBOX;
 550         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 551         if (autocvar_g_playerclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 553         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 554                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 555         this.frags = FRAGS_PLAYER;
 556         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 557         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 558         if (autocvar__notarget)
 559                 this.flags |= FL_NOTARGET;
 560         this.takedamage = DAMAGE_AIM;
 561         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 562
 563         if (warmup_stage) {
 564                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 565                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 566                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 567                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 568                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 569                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 570                 SetResource(this, RES_HEALTH, warmup_start_health);
 571                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 572                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 573         } else {
 574                 SetResource(this, RES_SHELLS, start_ammo_shells);
 575                 SetResource(this, RES_BULLETS, start_ammo_nails);
 576                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 577                 SetResource(this, RES_CELLS, start_ammo_cells);
 578                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 579                 SetResource(this, RES_FUEL, start_ammo_fuel);
 580                 SetResource(this, RES_HEALTH, start_health);
 581                 SetResource(this, RES_ARMOR, start_armorvalue);
 582                 STAT(WEAPONS, this) = start_weapons;
 583                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 584                 {
 585                         GiveRandomWeapons(this, random_start_weapons_count,
 586                                 autocvar_g_random_start_weapons, random_start_ammo);
 587                 }
 588         }
 589         SetSpectatee_status(this, 0);
 590
 591         PS(this).dual_weapons = '0 0 0';
 592
 593         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 594
 595         this.items = start_items;
 596
 597         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 598         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 599         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 600         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 601         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 602         if (!sv_ready_restart_after_countdown && time < game_starttime)
 603         {
 604                 float f = game_starttime - time;
 605                 this.spawnshieldtime += f;
 606                 this.pauserotarmor_finished += f;
 607                 this.pauserothealth_finished += f;
 608                 this.pauseregen_finished += f;
 609         }
 610
 611         this.damageforcescale = autocvar_g_player_damageforcescale;
 612         this.death_time = 0;
 613         this.respawn_flags = 0;
 614         this.respawn_time = 0;
 615         STAT(RESPAWN_TIME, this) = 0;
 616         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 617         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 618         this.fade_time = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         STAT(STRENGTH_FINISHED, this) = 0;
 642         STAT(INVINCIBLE_FINISHED, this) = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         STAT(AIR_FINISHED, this) = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         UNSET_DUCKED(this);
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 IL_REMOVE(g_swamped, this);
 691         this.swampslug = NULL;
 692         this.swamp_interval = 0;
 693         if(this.ladder_entity)
 694                 IL_REMOVE(g_ladderents, this);
 695         this.ladder_entity = NULL;
 696         IL_EACH(g_counters, it.realowner == this,
 697         {
 698                 delete(it);
 699         });
 700         STAT(HUD, this) = HUD_NORMAL;
 701
 702         this.event_damage = PlayerDamage;
 703         this.event_heal = PlayerHeal;
 704
 705         this.draggable = func_null;
 706
 707         if(!this.bot_attack)
 708                 IL_PUSH(g_bot_targets, this);
 709         this.bot_attack = true;
 710         if(!this.monster_attack)
 711                 IL_PUSH(g_monster_targets, this);
 712         this.monster_attack = true;
 713         navigation_dynamicgoal_init(this, false);
 714
 715         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 716
 717         // player was spectator
 718         if (CS(this).killcount == FRAGS_SPECTATOR) {
 719                 PlayerScore_Clear(this);
 720                 CS(this).killcount = 0;
 721                 CS(this).startplaytime = time;
 722         }
 723
 724         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 725         {
 726                 .entity weaponentity = weaponentities[slot];
 727                 CL_SpawnWeaponentity(this, weaponentity);
 728         }
 729         this.alpha = default_player_alpha;
 730         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 731         this.exteriorweaponentity.alpha = default_weapon_alpha;
 732
 733         this.speedrunning = false;
 734
 735         this.counter_cnt = 0;
 736         this.fragsfilter_cnt = 0;
 737
 738         target_voicescript_clear(this);
 739
 740         // reset fields the weapons may use
 741         FOREACH(Weapons, true, {
 742                 it.wr_resetplayer(it, this);
 743                         // reload all reloadable weapons
 744                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 745                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 746                         {
 747                                 .entity weaponentity = weaponentities[slot];
 748                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 749                         }
 750                 }
 751         });
 752
 753         {
 754                 string s = spot.target;
 755                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 756                         spot.target = string_null;
 757                 SUB_UseTargets(spot, this, NULL);
 758                 if(g_assault || g_race)
 759                         spot.target = s;
 760         }
 761
 762         Unfreeze(this, false);
 763
 764         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 765
 766         if (autocvar_spawn_debug)
 767         {
 768                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 769                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 770         }
 771
 772         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 773         {
 774                 .entity weaponentity = weaponentities[slot];
 775                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 776                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 777                 else
 778                         this.(weaponentity).m_switchweapon = WEP_Null;
 779                 this.(weaponentity).m_weapon = WEP_Null;
 780                 this.(weaponentity).weaponname = "";
 781                 this.(weaponentity).m_switchingweapon = WEP_Null;
 782                 this.(weaponentity).cnt = -1;
 783         }
 784
 785         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 786
 787         if (CS(this).impulse) ImpulseCommands(this);
 788
 789         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 790         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 791         {
 792                 .entity weaponentity = weaponentities[slot];
 793                 W_WeaponFrame(this, weaponentity);
 794         }
 795
 796         if (!warmup_stage && !this.alivetime)
 797                 this.alivetime = time;
 798
 799         antilag_clear(this, CS(this));
 800 }
 801
 802 /** Called when a client spawns in the server */
 803 void PutClientInServer(entity this)
 804 {
 805         if (IS_BOT_CLIENT(this)) {
 806                 TRANSMUTE(Player, this);
 807         } else if (IS_REAL_CLIENT(this)) {
 808                 msg_entity = this;
 809                 WriteByte(MSG_ONE, SVC_SETVIEW);
 810                 WriteEntity(MSG_ONE, this);
 811         }
 812         if (game_stopped)
 813                 TRANSMUTE(Observer, this);
 814
 815         SetSpectatee(this, NULL);
 816
 817         // reset player keys
 818         if(PS(this))
 819                 PS(this).itemkeys = 0;
 820
 821         MUTATOR_CALLHOOK(PutClientInServer, this);
 822
 823         if (IS_OBSERVER(this)) {
 824                 PutObserverInServer(this);
 825         } else if (IS_PLAYER(this)) {
 826                 PutPlayerInServer(this);
 827         }
 828 }
 829
 830 // TODO do we need all these fields, or should we stop autodetecting runtime
 831 // changes and just have a console command to update this?
 832 bool ClientInit_SendEntity(entity this, entity to, int sf)
 833 {
 834         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 835         return = true;
 836         msg_entity = to;
 837         // MSG_INIT replacement
 838         // TODO: make easier to use
 839         Registry_send_all();
 840         W_PROP_reload(MSG_ONE, to);
 841         ClientInit_misc(this);
 842         MUTATOR_CALLHOOK(Ent_Init);
 843 }
 844 void ClientInit_misc(entity this)
 845 {
 846         int channel = MSG_ONE;
 847         WriteHeader(channel, ENT_CLIENT_INIT);
 848         WriteByte(channel, g_nexball_meter_period * 32);
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 852         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 856         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 857
 858         if(autocvar_sv_foginterval && world.fog != "")
 859                 WriteString(channel, world.fog);
 860         else
 861                 WriteString(channel, "");
 862         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 863         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 864         WriteByte(channel, serverflags);
 865         WriteCoord(channel, autocvar_g_trueaim_minrange);
 866 }
 867
 868 void ClientInit_CheckUpdate(entity this)
 869 {
 870         this.nextthink = time;
 871         if(this.count != autocvar_g_balance_armor_blockpercent)
 872         {
 873                 this.count = autocvar_g_balance_armor_blockpercent;
 874                 this.SendFlags |= 1;
 875         }
 876         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 877         {
 878                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 879                 this.SendFlags |= 1;
 880         }
 881 }
 882
 883 void ClientInit_Spawn()
 884 {
 885         entity e = new_pure(clientinit);
 886         setthink(e, ClientInit_CheckUpdate);
 887         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 888
 889         ClientInit_CheckUpdate(e);
 890 }
 891
 892 /*
 893 =============
 894 SetNewParms
 895 =============
 896 */
 897 void SetNewParms ()
 898 {
 899         // initialize parms for a new player
 900         parm1 = -(86400 * 366);
 901
 902         MUTATOR_CALLHOOK(SetNewParms);
 903 }
 904
 905 /*
 906 =============
 907 SetChangeParms
 908 =============
 909 */
 910 void SetChangeParms (entity this)
 911 {
 912         // save parms for level change
 913         parm1 = CS(this).parm_idlesince - time;
 914
 915         MUTATOR_CALLHOOK(SetChangeParms);
 916 }
 917
 918 /*
 919 =============
 920 DecodeLevelParms
 921 =============
 922 */
 923 void DecodeLevelParms(entity this)
 924 {
 925         // load parms
 926         CS(this).parm_idlesince = parm1;
 927         if (CS(this).parm_idlesince == -(86400 * 366))
 928                 CS(this).parm_idlesince = time;
 929
 930         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 931         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 932
 933         MUTATOR_CALLHOOK(DecodeLevelParms);
 934 }
 935
 936 void FixClientCvars(entity e)
 937 {
 938         // send prediction settings to the client
 939         stuffcmd(e, "\nin_bindmap 0 0\n");
 940         if(autocvar_g_antilag == 3) // client side hitscan
 941                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 942         if(autocvar_sv_gentle)
 943                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 944
 945         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 946         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 947
 948         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 949
 950         MUTATOR_CALLHOOK(FixClientCvars, e);
 951 }
 952
 953 bool findinlist_abbrev(string tofind, string list)
 954 {
 955         if(list == "" || tofind == "")
 956                 return false; // empty list or search, just return
 957
 958         // this function allows abbreviated strings!
 959         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 960         {
 961                 return true;
 962         });
 963
 964         return false;
 965 }
 966
 967 bool PlayerInIPList(entity p, string iplist)
 968 {
 969         // some safety checks (never allow local?)
 970         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 971                 return false;
 972
 973         return findinlist_abbrev(p.netaddress, iplist);
 974 }
 975
 976 bool PlayerInIDList(entity p, string idlist)
 977 {
 978         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 979         if(!p.crypto_idfp)
 980                 return false;
 981
 982         return findinlist_abbrev(p.crypto_idfp, idlist);
 983 }
 984
 985 bool PlayerInList(entity player, string list)
 986 {
 987         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 988 }
 989
 990 #ifdef DP_EXT_PRECONNECT
 991 /*
 992 =============
 993 ClientPreConnect
 994
 995 Called once (not at each match start) when a client begins a connection to the server
 996 =============
 997 */
 998 void ClientPreConnect(entity this)
 999 {
1000         if(autocvar_sv_eventlog)
1001         {
1002                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1003                         this.playerid,
1004                         etof(this),
1005                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1006                 ));
1007         }
1008 }
1009 #endif
1010
1011 string GetClientVersionMessage(entity this)
1012 {
1013         if (CS(this).version_mismatch) {
1014                 if(CS(this).version < autocvar_gameversion) {
1015                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1016                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1017                 } else {
1018                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1019                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1020                 }
1021         } else {
1022                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1023         }
1024 }
1025
1026 string getwelcomemessage(entity this)
1027 {
1028         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1029         string modifications = M_ARGV(0, string);
1030
1031         if(g_weaponarena)
1032         {
1033                 if(g_weaponarena_random)
1034                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1035                 else
1036                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1037         }
1038         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1039                 modifications = strcat(modifications, ", No start weapons");
1040         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1041                 modifications = strcat(modifications, ", Low gravity");
1042         if(g_weapon_stay && !g_cts)
1043                 modifications = strcat(modifications, ", Weapons stay");
1044         if(autocvar_g_jetpack)
1045                 modifications = strcat(modifications, ", Jet pack");
1046         if(autocvar_g_powerups == 0)
1047                 modifications = strcat(modifications, ", No powerups");
1048         if(autocvar_g_powerups > 0)
1049                 modifications = strcat(modifications, ", Powerups");
1050         modifications = substring(modifications, 2, strlen(modifications) - 2);
1051
1052         string versionmessage = GetClientVersionMessage(this);
1053         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1054
1055         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1056
1057         if(modifications != "")
1058                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1059
1060         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1061         {
1062                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1063                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1064         }
1065
1066         if (cache_mutatormsg != "") {
1067                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1068         }
1069
1070         string mutator_msg = "";
1071         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1072         mutator_msg = M_ARGV(0, string);
1073
1074         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1075
1076         string motd = autocvar_sv_motd;
1077         if (motd != "") {
1078                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1079         }
1080         return s;
1081 }
1082
1083 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1084
1085 /**
1086 =============
1087 ClientConnect
1088
1089 Called when a client connects to the server
1090 =============
1091 */
1092 void ClientConnect(entity this)
1093 {
1094         if (Ban_MaybeEnforceBanOnce(this)) return;
1095         assert(!IS_CLIENT(this), return);
1096         this.flags |= FL_CLIENT;
1097         assert(player_count >= 0, player_count = 0);
1098
1099         TRANSMUTE(Client, this);
1100         CS(this).version_nagtime = time + 10 + random() * 10;
1101
1102         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1103
1104         bot_clientconnect(this);
1105
1106         Player_DetermineForcedTeam(this);
1107
1108         TRANSMUTE(Observer, this);
1109
1110         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1111
1112         // always track bots, don't ask for cl_allow_uidtracking
1113         if (IS_BOT_CLIENT(this))
1114                 PlayerStats_GameReport_AddPlayer(this);
1115         else
1116                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1117
1118         if (autocvar_sv_eventlog)
1119                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1120
1121         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1122
1123         stuffcmd(this, clientstuff, "\n");
1124         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1125
1126         FixClientCvars(this);
1127
1128         // get version info from player
1129         stuffcmd(this, "cmd clientversion $gameversion\n");
1130
1131         // notify about available teams
1132         if (teamplay)
1133         {
1134                 entity balance = TeamBalance_CheckAllowedTeams(this);
1135                 int t = TeamBalance_GetAllowedTeams(balance);
1136                 TeamBalance_Destroy(balance);
1137                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1138         }
1139         else
1140         {
1141                 stuffcmd(this, "set _teams_available 0\n");
1142         }
1143
1144         bot_relinkplayerlist();
1145
1146         CS(this).spectatortime = time;
1147         if (blockSpectators)
1148         {
1149                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1150         }
1151
1152         CS(this).jointime = time;
1153
1154         if (IS_REAL_CLIENT(this))
1155         {
1156                 if (g_weaponarena_weapons == WEPSET(TUBA))
1157                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1158         }
1159
1160         if (!autocvar_sv_foginterval && world.fog != "")
1161                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1162
1163         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1164                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1165                         send_CSQC_teamnagger();
1166
1167         CSQCMODEL_AUTOINIT(this);
1168
1169         CS(this).model_randomizer = random();
1170
1171         if (IS_REAL_CLIENT(this))
1172                 sv_notice_join(this);
1173
1174         this.move_qcphysics = autocvar_sv_qcphysics;
1175
1176         // update physics stats (players can spawn before physics runs)
1177         Physics_UpdateStats(this);
1178
1179         IL_EACH(g_initforplayer, it.init_for_player, {
1180                 it.init_for_player(it, this);
1181         });
1182
1183         Handicap_Initialize(this);
1184
1185         MUTATOR_CALLHOOK(ClientConnect, this);
1186
1187         if (IS_REAL_CLIENT(this))
1188         {
1189                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1190                 {
1191                         CS(this).motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1193                 }
1194         }
1195 }
1196 /*
1197 =============
1198 ClientDisconnect
1199
1200 Called when a client disconnects from the server
1201 =============
1202 */
1203 .entity chatbubbleentity;
1204 void ClientDisconnect(entity this)
1205 {
1206         assert(IS_CLIENT(this), return);
1207
1208         PlayerStats_GameReport_FinalizePlayer(this);
1209         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1210         if (CS(this).active_minigame) part_minigame(this);
1211         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1212
1213         if (autocvar_sv_eventlog)
1214                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1215
1216         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1217
1218         if(IS_SPEC(this))
1219                 SetSpectatee(this, NULL);
1220
1221         MUTATOR_CALLHOOK(ClientDisconnect, this);
1222
1223         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1224         strfree(CS_CVAR(this).weaponorder_byimpulse);
1225         ClientState_detach(this);
1226
1227         Portal_ClearAll(this);
1228
1229         Unfreeze(this, false);
1230
1231         RemoveGrapplingHooks(this);
1232
1233         // Here, everything has been done that requires this player to be a client.
1234
1235         this.flags &= ~FL_CLIENT;
1236
1237         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1238         if (this.killindicator) delete(this.killindicator);
1239
1240         IL_EACH(g_counters, it.realowner == this,
1241         {
1242                 delete(it);
1243         });
1244
1245         WaypointSprite_PlayerGone(this);
1246
1247         bot_relinkplayerlist();
1248
1249         strfree(this.clientstatus);
1250         if (this.personal) delete(this.personal);
1251
1252         this.playerid = 0;
1253         ReadyCount();
1254         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1255
1256         ONREMOVE(this);
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307 void calculate_player_respawn_time(entity this)
1308 {
1309         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1310                 return;
1311
1312         float gametype_setting_tmp;
1313         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1314         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1315         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1316         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1317         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1318         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1319
1320         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1321         if (teamplay)
1322         {
1323                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1324                         if(it.team == this.team)
1325                                 ++pcount;
1326                 });
1327                 if (sdelay_small_count == 0)
1328                         sdelay_small_count = 1;
1329                 if (sdelay_large_count == 0)
1330                         sdelay_large_count = 1;
1331         }
1332         else
1333         {
1334                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1335                         ++pcount;
1336                 });
1337                 if (sdelay_small_count == 0)
1338                 {
1339                         if (IS_INDEPENDENT_PLAYER(this))
1340                         {
1341                                 // Players play independently. No point in requiring enemies.
1342                                 sdelay_small_count = 1;
1343                         }
1344                         else
1345                         {
1346                                 // Players play AGAINST each other. Enemies required.
1347                                 sdelay_small_count = 2;
1348                         }
1349                 }
1350                 if (sdelay_large_count == 0)
1351                 {
1352                         if (IS_INDEPENDENT_PLAYER(this))
1353                         {
1354                                 // Players play independently. No point in requiring enemies.
1355                                 sdelay_large_count = 1;
1356                         }
1357                         else
1358                         {
1359                                 // Players play AGAINST each other. Enemies required.
1360                                 sdelay_large_count = 2;
1361                         }
1362                 }
1363         }
1364
1365         float sdelay;
1366
1367         if (pcount <= sdelay_small_count)
1368                 sdelay = sdelay_small;
1369         else if (pcount >= sdelay_large_count)
1370                 sdelay = sdelay_large;
1371         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1372                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1373
1374         if(waves)
1375                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1376         else
1377                 this.respawn_time = time + sdelay;
1378
1379         if(sdelay < sdelay_max)
1380                 this.respawn_time_max = time + sdelay_max;
1381         else
1382                 this.respawn_time_max = this.respawn_time;
1383
1384         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1385                 this.respawn_countdown = 10; // first number to count down from is 10
1386         else
1387                 this.respawn_countdown = -1; // do not count down
1388
1389         if(autocvar_g_forced_respawn)
1390                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1391 }
1392
1393 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1394 // added to the model skins
1395 /*void UpdateColorModHack()
1396 {
1397         float c;
1398         c = this.clientcolors & 15;
1399         // LordHavoc: only bothering to support white, green, red, yellow, blue
1400              if (!teamplay) this.colormod = '0 0 0';
1401         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1402         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1403         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1404         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1405         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1406         else this.colormod = '1 1 1';
1407 }*/
1408
1409 void respawn(entity this)
1410 {
1411         bool damagedbycontents_prev = this.damagedbycontents;
1412         if(this.alpha >= 0)
1413         {
1414                 if(autocvar_g_respawn_ghosts)
1415                 {
1416                         this.solid = SOLID_NOT;
1417                         this.takedamage = DAMAGE_NO;
1418                         this.damagedbycontents = false;
1419                         set_movetype(this, MOVETYPE_FLY);
1420                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1421                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1422                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1423                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1424                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1425                         if(autocvar_g_respawn_ghosts_time > 0)
1426                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1427                 }
1428                 else
1429                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1430         }
1431
1432         CopyBody(this, 1);
1433         this.damagedbycontents = damagedbycontents_prev;
1434
1435         this.effects |= EF_NODRAW; // prevent another CopyBody
1436         PutClientInServer(this);
1437 }
1438
1439 void play_countdown(entity this, float finished, Sound samp)
1440 {
1441         TC(Sound, samp);
1442         if(IS_REAL_CLIENT(this))
1443                 if(floor(finished - time - frametime) != floor(finished - time))
1444                         if(finished - time < 6)
1445                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1446 }
1447
1448 void player_powerups_remove_all(entity this)
1449 {
1450         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1451         {
1452                 if (time > game_starttime + 1)
1453                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1454                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1455                 this.items &= ~ITEM_Strength.m_itemid;
1456                 this.items &= ~ITEM_Shield.m_itemid;
1457                 this.items -= (this.items & IT_SUPERWEAPON);
1458         }
1459 }
1460
1461 void player_powerups(entity this)
1462 {
1463         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1464                 this.modelflags |= MF_ROCKET;
1465         else
1466                 this.modelflags &= ~MF_ROCKET;
1467
1468         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1469
1470         if (IS_DEAD(this))
1471                 player_powerups_remove_all(this);
1472
1473         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1474                 return;
1475
1476         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1477         int items_prev = this.items;
1478
1479         Fire_ApplyDamage(this);
1480         Fire_ApplyEffect(this);
1481
1482         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1483         {
1484                 if (this.items & ITEM_Strength.m_itemid)
1485                 {
1486                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1487                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1488                         if (time > STAT(STRENGTH_FINISHED, this))
1489                         {
1490                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1491                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1492                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1493                         }
1494                 }
1495                 else
1496                 {
1497                         if (time < STAT(STRENGTH_FINISHED, this))
1498                         {
1499                                 this.items = this.items | ITEM_Strength.m_itemid;
1500                                 if(!g_cts)
1501                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1502                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1503                         }
1504                 }
1505                 if (this.items & ITEM_Shield.m_itemid)
1506                 {
1507                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1508                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1509                         if (time > STAT(INVINCIBLE_FINISHED, this))
1510                         {
1511                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1512                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1513                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1514                         }
1515                 }
1516                 else
1517                 {
1518                         if (time < STAT(INVINCIBLE_FINISHED, this))
1519                         {
1520                                 this.items = this.items | ITEM_Shield.m_itemid;
1521                                 if(!g_cts)
1522                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1523                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1524                         }
1525                 }
1526                 if (this.items & IT_SUPERWEAPON)
1527                 {
1528                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1529                         {
1530                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1531                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1532                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1533                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1534                         }
1535                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1536                         {
1537                                 // don't let them run out
1538                         }
1539                         else
1540                         {
1541                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1542                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1543                                 {
1544                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1545                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1546                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1547                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1548                                 }
1549                         }
1550                 }
1551                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1552                 {
1553                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1554                         {
1555                                 this.items = this.items | IT_SUPERWEAPON;
1556                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1557                                 {
1558                                         if(!g_cts)
1559                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1560                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1561                                 }
1562                         }
1563                         else
1564                         {
1565                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1566                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1567                         }
1568                 }
1569                 else
1570                 {
1571                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1572                 }
1573         }
1574
1575         if(autocvar_g_nodepthtestplayers)
1576                 this.effects = this.effects | EF_NODEPTHTEST;
1577
1578         if(autocvar_g_fullbrightplayers)
1579                 this.effects = this.effects | EF_FULLBRIGHT;
1580
1581         if (time >= game_starttime)
1582         if (time < this.spawnshieldtime)
1583                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1584
1585         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1586 }
1587
1588 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1589 {
1590         if(current > stable)
1591                 return current;
1592         else if(current > stable - 0.25) // when close enough, "snap"
1593                 return stable;
1594         else
1595                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1596 }
1597
1598 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1599 {
1600         if(current < stable)
1601                 return current;
1602         else if(current < stable + 0.25) // when close enough, "snap"
1603                 return stable;
1604         else
1605                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1606 }
1607
1608 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1609 {
1610         float old = GetResource(this, res);
1611         float current = old;
1612         if(current > rotstable)
1613         {
1614                 if(rotframetime > 0)
1615                 {
1616                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1617                         current = max(rotstable, current - rotlinear * rotframetime);
1618                 }
1619         }
1620         else if(current < regenstable)
1621         {
1622                 if(regenframetime > 0)
1623                 {
1624                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1625                         current = min(regenstable, current + regenlinear * regenframetime);
1626                 }
1627         }
1628
1629         float limit = GetResourceLimit(this, res) * limit_mod;
1630         if(current > limit)
1631                 current = limit;
1632
1633         if (current != old)
1634                 SetResource(this, res, current);
1635 }
1636
1637 void player_regen(entity this)
1638 {
1639         float max_mod, regen_mod, rot_mod, limit_mod;
1640         max_mod = regen_mod = rot_mod = limit_mod = 1;
1641
1642         float regen_health = autocvar_g_balance_health_regen;
1643         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1644         float regen_health_rot = autocvar_g_balance_health_rot;
1645         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1646         float regen_health_stable = autocvar_g_balance_health_regenstable;
1647         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1648         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1649                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1650         max_mod = M_ARGV(1, float);
1651         regen_mod = M_ARGV(2, float);
1652         rot_mod = M_ARGV(3, float);
1653         limit_mod = M_ARGV(4, float);
1654         regen_health = M_ARGV(5, float);
1655         regen_health_linear = M_ARGV(6, float);
1656         regen_health_rot = M_ARGV(7, float);
1657         regen_health_rotlinear = M_ARGV(8, float);
1658         regen_health_stable = M_ARGV(9, float);
1659         regen_health_rotstable = M_ARGV(10, float);
1660
1661         if(!mutator_returnvalue)
1662         if(!STAT(FROZEN, this))
1663         {
1664                 float maxa = autocvar_g_balance_armor_rotstable;
1665                 float mina = autocvar_g_balance_armor_regenstable;
1666
1667                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1668                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1669                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1670
1671                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1672                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1673                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1674         }
1675
1676         // if player rotted to death...  die!
1677         // check this outside above checks, as player may still be able to rot to death
1678         if(GetResource(this, RES_HEALTH) < 1)
1679         {
1680                 if(this.vehicle)
1681                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1682                 if(this.event_damage)
1683                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1684         }
1685
1686         if (!(this.items & IT_UNLIMITED_AMMO))
1687         {
1688                 float maxf = autocvar_g_balance_fuel_rotstable;
1689                 float minf = autocvar_g_balance_fuel_regenstable;
1690
1691                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1692                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1693                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1694         }
1695 }
1696
1697 bool zoomstate_set;
1698 void SetZoomState(entity this, float newzoom)
1699 {
1700         if(newzoom != CS(this).zoomstate)
1701         {
1702                 CS(this).zoomstate = newzoom;
1703                 ClientData_Touch(this);
1704         }
1705         zoomstate_set = true;
1706 }
1707
1708 void GetPressedKeys(entity this)
1709 {
1710         MUTATOR_CALLHOOK(GetPressedKeys, this);
1711         if (game_stopped)
1712         {
1713                 CS(this).pressedkeys = 0;
1714                 STAT(PRESSED_KEYS, this) = 0;
1715                 return;
1716         }
1717
1718         int keys = STAT(PRESSED_KEYS, this);
1719         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1720         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1721         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1722         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1723
1724         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1725         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1726         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1727         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1728         CS(this).pressedkeys = keys; // store for other users
1729
1730         STAT(PRESSED_KEYS, this) = keys;
1731 }
1732
1733 /*
1734 ======================
1735 spectate mode routines
1736 ======================
1737 */
1738
1739 void SpectateCopy(entity this, entity spectatee)
1740 {
1741         TC(Client, this); TC(Client, spectatee);
1742
1743         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1744         PS(this) = PS(spectatee);
1745         this.armortype = spectatee.armortype;
1746         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1747         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1748         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1749         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1750         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1751         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1752         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1753         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1754         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1755         CS(this).impulse = 0;
1756         this.disableclientprediction = 1; // no need to run prediction on a spectator
1757         this.items = spectatee.items;
1758         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1759         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1760         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1761         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1762         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1763         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1764         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1765         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1766         this.punchangle = spectatee.punchangle;
1767         this.view_ofs = spectatee.view_ofs;
1768         this.velocity = spectatee.velocity;
1769         this.dmg_take = spectatee.dmg_take;
1770         this.dmg_save = spectatee.dmg_save;
1771         this.dmg_inflictor = spectatee.dmg_inflictor;
1772         this.v_angle = spectatee.v_angle;
1773         this.angles = spectatee.v_angle;
1774         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1775         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1776         this.viewloc = spectatee.viewloc;
1777         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1778                 this.fixangle = true;
1779         setorigin(this, spectatee.origin);
1780         setsize(this, spectatee.mins, spectatee.maxs);
1781         SetZoomState(this, CS(spectatee).zoomstate);
1782
1783     anticheat_spectatecopy(this, spectatee);
1784         STAT(HUD, this) = STAT(HUD, spectatee);
1785         if(spectatee.vehicle)
1786     {
1787         this.angles = spectatee.v_angle;
1788
1789         //this.fixangle = false;
1790         //this.velocity = spectatee.vehicle.velocity;
1791         this.vehicle_health = spectatee.vehicle_health;
1792         this.vehicle_shield = spectatee.vehicle_shield;
1793         this.vehicle_energy = spectatee.vehicle_energy;
1794         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1795         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1796         this.vehicle_reload1 = spectatee.vehicle_reload1;
1797         this.vehicle_reload2 = spectatee.vehicle_reload2;
1798
1799         //msg_entity = this;
1800
1801        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1802             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1803            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1804            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1805
1806         //WriteByte (MSG_ONE, SVC_SETVIEW);
1807         //    WriteEntity(MSG_ONE, this);
1808         //makevectors(spectatee.v_angle);
1809         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1810     }
1811 }
1812
1813 bool SpectateUpdate(entity this)
1814 {
1815         if(!this.enemy)
1816                 return false;
1817
1818         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1819         {
1820                 SetSpectatee(this, NULL);
1821                 return false;
1822         }
1823
1824         SpectateCopy(this, this.enemy);
1825
1826         return true;
1827 }
1828
1829 bool SpectateSet(entity this)
1830 {
1831         if(!IS_PLAYER(this.enemy))
1832                 return false;
1833
1834         ClientData_Touch(this.enemy);
1835
1836         msg_entity = this;
1837         WriteByte(MSG_ONE, SVC_SETVIEW);
1838         WriteEntity(MSG_ONE, this.enemy);
1839         set_movetype(this, MOVETYPE_NONE);
1840         accuracy_resend(this);
1841
1842         if(!SpectateUpdate(this))
1843                 PutObserverInServer(this);
1844
1845         return true;
1846 }
1847
1848 void SetSpectatee_status(entity this, int spectatee_num)
1849 {
1850         int oldspectatee_status = CS(this).spectatee_status;
1851         CS(this).spectatee_status = spectatee_num;
1852
1853         if (CS(this).spectatee_status != oldspectatee_status)
1854         {
1855                 if (STAT(PRESSED_KEYS, this))
1856                 {
1857                         CS(this).pressedkeys = 0;
1858                         STAT(PRESSED_KEYS, this) = 0;
1859                 }
1860                 ClientData_Touch(this);
1861                 if (g_race || g_cts) race_InitSpectator();
1862         }
1863 }
1864
1865 void SetSpectatee(entity this, entity spectatee)
1866 {
1867         if(IS_BOT_CLIENT(this))
1868                 return; // bots abuse .enemy, this code is useless to them
1869
1870         entity old_spectatee = this.enemy;
1871
1872         this.enemy = spectatee;
1873
1874         // WEAPONTODO
1875         // these are required to fix the spectator bug with arc
1876         if(old_spectatee)
1877         {
1878                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1879                 {
1880                         .entity weaponentity = weaponentities[slot];
1881                         if(old_spectatee.(weaponentity).arc_beam)
1882                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1883                 }
1884         }
1885         if(this.enemy)
1886         {
1887                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1888                 {
1889                         .entity weaponentity = weaponentities[slot];
1890                         if(this.enemy.(weaponentity).arc_beam)
1891                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1892                 }
1893         }
1894
1895         if (this.enemy)
1896                 SetSpectatee_status(this, etof(this.enemy));
1897
1898         // needed to update spectator list
1899         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1900 }
1901
1902 bool Spectate(entity this, entity pl)
1903 {
1904         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1905                 return false;
1906         pl = M_ARGV(1, entity);
1907
1908         SetSpectatee(this, pl);
1909         return SpectateSet(this);
1910 }
1911
1912 bool SpectateNext(entity this)
1913 {
1914         entity ent = find(this.enemy, classname, STR_PLAYER);
1915
1916         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1917                 ent = M_ARGV(1, entity);
1918         else if (!ent)
1919                 ent = find(ent, classname, STR_PLAYER);
1920
1921         if(ent) { SetSpectatee(this, ent); }
1922
1923         return SpectateSet(this);
1924 }
1925
1926 bool SpectatePrev(entity this)
1927 {
1928         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1929         entity ent = findchain(classname, STR_PLAYER);
1930         if (!ent) // no player
1931                 return false;
1932
1933         entity first = ent;
1934         // skip players until current spectated player
1935         if(this.enemy)
1936         while(ent && ent != this.enemy)
1937                 ent = ent.chain;
1938
1939         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1940         {
1941                 case MUT_SPECPREV_FOUND:
1942                         ent = M_ARGV(1, entity);
1943                         break;
1944                 case MUT_SPECPREV_RETURN:
1945                         return true;
1946                 case MUT_SPECPREV_CONTINUE:
1947                 default:
1948                 {
1949                         if(ent.chain)
1950                                 ent = ent.chain;
1951                         else
1952                                 ent = first;
1953                         break;
1954                 }
1955         }
1956
1957         SetSpectatee(this, ent);
1958         return SpectateSet(this);
1959 }
1960
1961 /*
1962 =============
1963 ShowRespawnCountdown()
1964
1965 Update a respawn countdown display.
1966 =============
1967 */
1968 void ShowRespawnCountdown(entity this)
1969 {
1970         float number;
1971         if(!IS_DEAD(this)) // just respawned?
1972                 return;
1973         else
1974         {
1975                 number = ceil(this.respawn_time - time);
1976                 if(number <= 0)
1977                         return;
1978                 if(number <= this.respawn_countdown)
1979                 {
1980                         this.respawn_countdown = number - 1;
1981                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1982                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1983                 }
1984         }
1985 }
1986
1987 .bool team_selected;
1988 bool ShowTeamSelection(entity this)
1989 {
1990         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1991                 return false;
1992         stuffcmd(this, "menu_showteamselect\n");
1993         return true;
1994 }
1995 void Join(entity this)
1996 {
1997         TRANSMUTE(Player, this);
1998
1999         if(!this.team_selected)
2000         if(autocvar_g_campaign || autocvar_g_balance_teams)
2001                 TeamBalance_JoinBestTeam(this);
2002
2003         if(autocvar_g_campaign)
2004                 campaign_bots_may_start = true;
2005
2006         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2007
2008         PutClientInServer(this);
2009
2010         if(IS_PLAYER(this))
2011         if(teamplay && this.team != -1)
2012         {
2013         }
2014         else
2015                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2016         this.team_selected = false;
2017 }
2018
2019 int GetPlayerLimit()
2020 {
2021         if(g_duel)
2022                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2023         int player_limit = autocvar_g_maxplayers;
2024         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2025         player_limit = M_ARGV(0, int);
2026         return player_limit;
2027 }
2028
2029 /**
2030  * Determines whether the player is allowed to join. This depends on cvar
2031  * g_maxplayers, if it isn't used this function always return true, otherwise
2032  * it checks whether the number of currently playing players exceeds g_maxplayers.
2033  * @return int number of free slots for players, 0 if none
2034  */
2035 int nJoinAllowed(entity this, entity ignore)
2036 {
2037         if(!ignore)
2038         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2039         // so report 0 free slots if restricted
2040         {
2041                 if(autocvar_g_forced_team_otherwise == "spectate")
2042                         return 0;
2043                 if(autocvar_g_forced_team_otherwise == "spectator")
2044                         return 0;
2045         }
2046
2047         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2048                 return 0; // forced spectators can never join
2049
2050         // TODO simplify this
2051         int totalClients = 0;
2052         int currentlyPlaying = 0;
2053         FOREACH_CLIENT(true, {
2054                 if(it != ignore)
2055                         ++totalClients;
2056                 if(IS_REAL_CLIENT(it))
2057                 if(IS_PLAYER(it) || it.caplayer)
2058                         ++currentlyPlaying;
2059         });
2060
2061         int player_limit = GetPlayerLimit();
2062
2063         int free_slots = 0;
2064         if (!player_limit)
2065                 free_slots = maxclients - totalClients;
2066         else if(player_limit > 0 && currentlyPlaying < player_limit)
2067                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2068
2069         static float msg_time = 0;
2070         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2071         {
2072                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2073                 msg_time = time + 0.5;
2074         }
2075
2076         return free_slots;
2077 }
2078
2079 /**
2080  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2081  * g_maxplayers_spectator_blocktime seconds
2082  */
2083 void checkSpectatorBlock(entity this)
2084 {
2085         if(IS_SPEC(this) || IS_OBSERVER(this))
2086         if(!this.caplayer)
2087         if(IS_REAL_CLIENT(this))
2088         {
2089                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2090                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2091                         dropclient(this);
2092                 }
2093         }
2094 }
2095
2096 void PrintWelcomeMessage(entity this)
2097 {
2098         if(CS(this).motd_actived_time == 0)
2099         {
2100                 if (autocvar_g_campaign) {
2101                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2102                                 CS(this).motd_actived_time = time;
2103                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2104                         }
2105                 } else {
2106                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2107                                 CS(this).motd_actived_time = time;
2108                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2109                         }
2110                 }
2111         }
2112         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2113         {
2114                 if (autocvar_g_campaign) {
2115                         if (PHYS_INPUT_BUTTON_INFO(this))
2116                                 CS(this).motd_actived_time = time;
2117                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2118                                 CS(this).motd_actived_time = 0;
2119                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2120                         }
2121                 } else {
2122                         if (PHYS_INPUT_BUTTON_INFO(this))
2123                                 CS(this).motd_actived_time = time;
2124                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2125                                 CS(this).motd_actived_time = 0;
2126                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2127                         }
2128                 }
2129         }
2130         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2131         {
2132                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2133                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2134                 else if (CS(this).motd_actived_time == -2)
2135                 {
2136                         // instantly hide MOTD
2137                         CS(this).motd_actived_time = 0;
2138                         if (autocvar_g_campaign)
2139                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2140                         else
2141                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2142                 }
2143                 else if (IS_PLAYER(this) || IS_SPEC(this))
2144                 {
2145                         // FIXME occasionally for some reason MOTD never goes away
2146                         // delay MOTD removal a little bit in the hope it fixes this bug
2147                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2148                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2149                         else //if (CS(this).motd_actived_time < -2)
2150                                 CS(this).motd_actived_time++;
2151                 }
2152         }
2153 }
2154
2155 bool joinAllowed(entity this)
2156 {
2157         if (CS(this).version_mismatch) return false;
2158         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2159         if (!nJoinAllowed(this, this)) return false;
2160         if (teamplay && lockteams) return false;
2161         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2162         if (ShowTeamSelection(this)) return false;
2163         return true;
2164 }
2165
2166 .string shootfromfixedorigin;
2167 .bool dualwielding_prev;
2168 bool PlayerThink(entity this)
2169 {
2170         if (game_stopped || intermission_running) {
2171                 this.modelflags &= ~MF_ROCKET;
2172                 if(intermission_running)
2173                         IntermissionThink(this);
2174                 return false;
2175         }
2176
2177         if (timeout_status == TIMEOUT_ACTIVE) {
2178                 // don't allow the player to turn around while game is paused
2179                 // FIXME turn this into CSQC stuff
2180                 this.v_angle = this.lastV_angle;
2181                 this.angles = this.lastV_angle;
2182                 this.fixangle = true;
2183         }
2184
2185         if (frametime) player_powerups(this);
2186
2187         if (IS_DEAD(this)) {
2188                 if (this.personal && g_race_qualifying) {
2189                         if (time > this.respawn_time) {
2190                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2191                                 respawn(this);
2192                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2193                         }
2194                 } else {
2195                         if (frametime) player_anim(this);
2196
2197                         if (this.respawn_flags & RESPAWN_DENY)
2198                         {
2199                                 STAT(RESPAWN_TIME, this) = 0;
2200                                 return false;
2201                         }
2202
2203                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2204
2205                         switch(this.deadflag)
2206                         {
2207                                 case DEAD_DYING:
2208                                 {
2209                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2210                                                 this.deadflag = DEAD_RESPAWNING;
2211                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2212                                                 this.deadflag = DEAD_DEAD;
2213                                         break;
2214                                 }
2215                                 case DEAD_DEAD:
2216                                 {
2217                                         if (button_pressed)
2218                                                 this.deadflag = DEAD_RESPAWNABLE;
2219                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2220                                                 this.deadflag = DEAD_RESPAWNING;
2221                                         break;
2222                                 }
2223                                 case DEAD_RESPAWNABLE:
2224                                 {
2225                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2226                                                 this.deadflag = DEAD_RESPAWNING;
2227                                         break;
2228                                 }
2229                                 case DEAD_RESPAWNING:
2230                                 {
2231                                         if (time > this.respawn_time)
2232                                         {
2233                                                 this.respawn_time = time + 1; // only retry once a second
2234                                                 this.respawn_time_max = this.respawn_time;
2235                                                 respawn(this);
2236                                         }
2237                                         break;
2238                                 }
2239                         }
2240
2241                         ShowRespawnCountdown(this);
2242
2243                         if (this.respawn_flags & RESPAWN_SILENT)
2244                                 STAT(RESPAWN_TIME, this) = 0;
2245                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2246                         {
2247                                 if (time < this.respawn_time)
2248                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2249                                 else if (this.deadflag != DEAD_RESPAWNING)
2250                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2251                         }
2252                         else
2253                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2254                 }
2255
2256                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2257                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2258                         STAT(RESPAWN_TIME, this) *= -1;
2259
2260                 return false;
2261         }
2262
2263         FixPlayermodel(this);
2264
2265         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2266                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2267                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2268         }
2269
2270         // reset gun alignment when dual wielding status changes
2271         // to ensure guns are always aligned right and left
2272         bool dualwielding = W_DualWielding(this);
2273         if(this.dualwielding_prev != dualwielding)
2274         {
2275                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2276                 this.dualwielding_prev = dualwielding;
2277         }
2278
2279         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2280         //if(frametime)
2281         {
2282                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2283                 {
2284                         .entity weaponentity = weaponentities[slot];
2285                         if(WEP_CVAR(vortex, charge_always))
2286                                 W_Vortex_Charge(this, weaponentity, frametime);
2287                         W_WeaponFrame(this, weaponentity);
2288                 }
2289         }
2290
2291         if (frametime)
2292         {
2293                 // WEAPONTODO: Add a weapon request for this
2294                 // rot vortex charge to the charge limit
2295                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2296                 {
2297                         .entity weaponentity = weaponentities[slot];
2298                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2299                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2300                 }
2301
2302                 player_regen(this);
2303                 player_anim(this);
2304                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2305         }
2306
2307         monsters_setstatus(this);
2308
2309         return true;
2310 }
2311
2312 .bool would_spectate;
2313 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2314 void ObserverOrSpectatorThink(entity this)
2315 {
2316         bool is_spec = IS_SPEC(this);
2317         if ( CS(this).impulse )
2318         {
2319                 int r = MinigameImpulse(this, CS(this).impulse);
2320                 if (!is_spec || r)
2321                         CS(this).impulse = 0;
2322
2323                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2324                 {
2325                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2326                         CS(this).impulse = 0;
2327                         return;
2328                 }
2329         }
2330
2331         if (this.flags & FL_JUMPRELEASED) {
2332                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2333                         this.flags &= ~FL_JUMPRELEASED;
2334                         this.flags |= FL_SPAWNING;
2335                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2336                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2337                         this.flags &= ~FL_JUMPRELEASED;
2338                         if(SpectateNext(this)) {
2339                                 TRANSMUTE(Spectator, this);
2340                         } else if (is_spec) {
2341                                 TRANSMUTE(Observer, this);
2342                                 PutClientInServer(this);
2343                         }
2344                         if (is_spec)
2345                                 CS(this).impulse = 0;
2346                 } else if (is_spec) {
2347                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2348                                 this.flags &= ~FL_JUMPRELEASED;
2349                                 if(SpectatePrev(this)) {
2350                                         TRANSMUTE(Spectator, this);
2351                                 } else {
2352                                         TRANSMUTE(Observer, this);
2353                                         PutClientInServer(this);
2354                                 }
2355                                 CS(this).impulse = 0;
2356                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2357                                 this.would_spectate = false;
2358                                 this.flags &= ~FL_JUMPRELEASED;
2359                                 TRANSMUTE(Observer, this);
2360                                 PutClientInServer(this);
2361                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2362                                 PutObserverInServer(this);
2363                                 this.would_spectate = true;
2364                         }
2365                 }
2366                 else {
2367                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS_CVAR(this).cvar_cl_clippedspectating : !CS_CVAR(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2368                         set_movetype(this, preferred_movetype);
2369                 }
2370         } else { // jump pressed
2371                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2372                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2373                         this.flags |= FL_JUMPRELEASED;
2374                         if(this.flags & FL_SPAWNING)
2375                         {
2376                                 this.flags &= ~FL_SPAWNING;
2377                                 if(joinAllowed(this))
2378                                         Join(this);
2379                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2380                                         CS(this).autojoin_checked = -1;
2381                                 return;
2382                         }
2383                 }
2384                 if(is_spec && !SpectateUpdate(this))
2385                         PutObserverInServer(this);
2386         }
2387         if (is_spec)
2388                 this.flags |= FL_CLIENT | FL_NOTARGET;
2389 }
2390
2391 void PlayerUseKey(entity this)
2392 {
2393         if (!IS_PLAYER(this))
2394                 return;
2395
2396         if(this.vehicle)
2397         {
2398                 if(!game_stopped)
2399                 {
2400                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2401                         return;
2402                 }
2403         }
2404         else if(autocvar_g_vehicles_enter)
2405         {
2406                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2407                 {
2408                         entity head, closest_target = NULL;
2409                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2410
2411                         while(head) // find the closest acceptable target to enter
2412                         {
2413                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2414                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2415                                 {
2416                                         if(closest_target)
2417                                         {
2418                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2419                                                 { closest_target = head; }
2420                                         }
2421                                         else { closest_target = head; }
2422                                 }
2423
2424                                 head = head.chain;
2425                         }
2426
2427                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2428                 }
2429         }
2430
2431         // a use key was pressed; call handlers
2432         MUTATOR_CALLHOOK(PlayerUseKey, this);
2433 }
2434
2435
2436 /*
2437 =============
2438 PlayerPreThink
2439
2440 Called every frame for each client before the physics are run
2441 =============
2442 */
2443 .float last_vehiclecheck;
2444 void PlayerPreThink (entity this)
2445 {
2446         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2447         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2448
2449         WarpZone_PlayerPhysics_FixVAngle(this);
2450
2451         if (frametime) {
2452                 // physics frames: update anticheat stuff
2453                 anticheat_prethink(this);
2454         }
2455
2456         if (blockSpectators && frametime) {
2457                 // WORKAROUND: only use dropclient in server frames (frametime set).
2458                 // Never use it in cl_movement frames (frametime zero).
2459                 checkSpectatorBlock(this);
2460         }
2461
2462         zoomstate_set = false;
2463
2464         // Check for nameless players
2465         if (this.netname == "" || this.netname != CS(this).netname_previous)
2466         {
2467                 bool assume_unchanged = (CS(this).netname_previous == "");
2468                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2469                 {
2470                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2471                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2472                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2473                         assume_unchanged = false;
2474                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2475                 }
2476                 if (isInvisibleString(this.netname))
2477                 {
2478                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2479                         sprint(this, "Warning: invisible names are not allowed.\n");
2480                         assume_unchanged = false;
2481                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2482                 }
2483                 if (!assume_unchanged && autocvar_sv_eventlog)
2484                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2485                 strcpy(CS(this).netname_previous, this.netname);
2486         }
2487
2488         // version nagging
2489         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2490         CS(this).version_nagtime = 0;
2491         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2492             // git client
2493         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2494             // git server
2495             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2496         } else {
2497             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2498             if (r < 0) { // old client
2499                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2500             } else if (r > 0) { // old server
2501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2502             }
2503         }
2504     }
2505
2506         // GOD MODE info
2507         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2508         {
2509                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2510                 this.max_armorvalue = 0;
2511         }
2512
2513         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2514         {
2515                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2516                 {
2517                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2518                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2519                         if (this.iceblock)
2520                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2521
2522                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2523                                 Unfreeze(this, false);
2524                 }
2525                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2526                 {
2527                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2528                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2529
2530                         if (GetResource(this, RES_HEALTH) < 1)
2531                         {
2532                                 if (this.vehicle)
2533                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2534                                 if(this.event_damage)
2535                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2536                         }
2537                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2538                                 Unfreeze(this, false);
2539                 }
2540         }
2541
2542         MUTATOR_CALLHOOK(PlayerPreThink, this);
2543
2544         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2545         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2546         {
2547                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2548                 {
2549                         if(!it.owner)
2550                         {
2551                                 if(!it.team || SAME_TEAM(this, it))
2552                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2553                                 else if(autocvar_g_vehicles_steal)
2554                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2555                         }
2556                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2557                         {
2558                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2559                         }
2560                 });
2561
2562                 this.last_vehiclecheck = time + 1;
2563         }
2564
2565         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2566         {
2567                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2568                         PlayerUseKey(this);
2569                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2570         }
2571
2572         if (IS_REAL_CLIENT(this))
2573                 PrintWelcomeMessage(this);
2574
2575         if (IS_PLAYER(this)) {
2576                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2577                         error("Client can't be spawned as player on connection!");
2578                 if(!PlayerThink(this))
2579                         return;
2580         }
2581         else if (game_stopped || intermission_running) {
2582                 if(intermission_running)
2583                         IntermissionThink(this);
2584                 return;
2585         }
2586         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2587         {
2588                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2589                 CS(this).autojoin_checked = 1;
2590                 // don't do this in ClientConnect
2591                 // many things can go wrong if a client is spawned as player on connection
2592                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2593                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2594                                 && (!teamplay || autocvar_g_balance_teams)))
2595                 {
2596                         campaign_bots_may_start = true;
2597                         if(joinAllowed(this))
2598                                 Join(this);
2599                         return;
2600                 }
2601         }
2602         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2603                 ObserverOrSpectatorThink(this);
2604         }
2605
2606         // WEAPONTODO: Add weapon request for this
2607         if (!zoomstate_set) {
2608                 bool wep_zoomed = false;
2609                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2610                 {
2611                         .entity weaponentity = weaponentities[slot];
2612                         Weapon thiswep = this.(weaponentity).m_weapon;
2613                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2614                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2615                 }
2616                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2617         }
2618
2619         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2620         {
2621                 CS(this).teamkill_soundtime = 0;
2622
2623                 entity e = CS(this).teamkill_soundsource;
2624                 entity oldpusher = e.pusher;
2625                 e.pusher = this;
2626                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2627                 e.pusher = oldpusher;
2628         }
2629
2630         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2631                 CS(this).taunt_soundtime = 0;
2632                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2633         }
2634
2635         target_voicescript_next(this);
2636 }
2637
2638 void DrownPlayer(entity this)
2639 {
2640         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2641                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2642         {
2643                 STAT(AIR_FINISHED, this) = 0;
2644                 return;
2645         }
2646
2647         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2648         {
2649                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2650                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2651                 STAT(AIR_FINISHED, this) = 0;
2652         }
2653         else
2654         {
2655                 if (!STAT(AIR_FINISHED, this))
2656                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2657                 if (STAT(AIR_FINISHED, this) < time)
2658                 {       // drown!
2659                         if (this.pain_finished < time)
2660                         {
2661                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2662                                 this.pain_finished = time + 0.5;
2663                         }
2664                 }
2665         }
2666 }
2667
2668 .bool move_qcphysics;
2669
2670 void Player_Physics(entity this)
2671 {
2672         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2673
2674         if(!this.move_qcphysics)
2675                 return;
2676
2677         if(!frametime && !CS(this).pm_frametime)
2678                 return;
2679
2680         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2681
2682         CS(this).pm_frametime = 0;
2683 }
2684
2685 /*
2686 =============
2687 PlayerPostThink
2688
2689 Called every frame for each client after the physics are run
2690 =============
2691 */
2692 void PlayerPostThink (entity this)
2693 {
2694         Player_Physics(this);
2695
2696         if (autocvar_sv_maxidle > 0)
2697         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2698         if (IS_REAL_CLIENT(this))
2699         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2700         {
2701                 int totalClients = 0;
2702                 if(autocvar_sv_maxidle_slots > 0)
2703                 {
2704                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2705                         {
2706                                 ++totalClients;
2707                         });
2708                 }
2709
2710                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2711                 { /* do nothing */ }
2712                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2713                 {
2714                         if (CS(this).idlekick_lasttimeleft)
2715                         {
2716                                 CS(this).idlekick_lasttimeleft = 0;
2717                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2718                         }
2719                 }
2720                 else
2721                 {
2722                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2723                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2724                                 if (!CS(this).idlekick_lasttimeleft)
2725                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2726                         }
2727                         if (timeleft <= 0) {
2728                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2729                                 dropclient(this);
2730                                 return;
2731                         }
2732                         else if (timeleft <= 10) {
2733                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2734                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2735                                 CS(this).idlekick_lasttimeleft = timeleft;
2736                         }
2737                 }
2738         }
2739
2740         CheatFrame(this);
2741
2742         if (game_stopped)
2743         {
2744                 this.solid = SOLID_NOT;
2745                 this.takedamage = DAMAGE_NO;
2746                 set_movetype(this, MOVETYPE_NONE);
2747                 CS(this).teamkill_complain = 0;
2748                 CS(this).teamkill_soundtime = 0;
2749                 CS(this).teamkill_soundsource = NULL;
2750         }
2751
2752         if (IS_PLAYER(this)) {
2753                 if(this.death_time == time && IS_DEAD(this))
2754                 {
2755                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2756                         // once all the damage events of this frame have been processed with normal size
2757                         this.maxs.z = 5;
2758                         setsize(this, this.mins, this.maxs);
2759                 }
2760                 DrownPlayer(this);
2761                 UpdateChatBubble(this);
2762                 if (CS(this).impulse) ImpulseCommands(this);
2763                 GetPressedKeys(this);
2764                 if (game_stopped)
2765                 {
2766                         CSQCMODEL_AUTOUPDATE(this);
2767                         return;
2768                 }
2769         }
2770         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2771         {
2772                 CS(this).pressedkeys = 0;
2773                 STAT(PRESSED_KEYS, this) = 0;
2774         }
2775
2776         if (this.waypointsprite_attachedforcarrier) {
2777                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2778                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2779         }
2780
2781         CSQCMODEL_AUTOUPDATE(this);
2782 }
2783
2784 // hack to copy the button fields from the client entity to the Client State
2785 void PM_UpdateButtons(entity this, entity store)
2786 {
2787         if(this.impulse)
2788                 store.impulse = this.impulse;
2789         this.impulse = 0;
2790
2791         bool typing = this.buttonchat || this.button12;
2792
2793         store.button0 = (typing) ? 0 : this.button0;
2794         //button1?!
2795         store.button2 = (typing) ? 0 : this.button2;
2796         store.button3 = (typing) ? 0 : this.button3;
2797         store.button4 = this.button4;
2798         store.button5 = (typing) ? 0 : this.button5;
2799         store.button6 = this.button6;
2800         store.button7 = this.button7;
2801         store.button8 = this.button8;
2802         store.button9 = this.button9;
2803         store.button10 = this.button10;
2804         store.button11 = this.button11;
2805         store.button12 = this.button12;
2806         store.button13 = this.button13;
2807         store.button14 = this.button14;
2808         store.button15 = this.button15;
2809         store.button16 = this.button16;
2810         store.buttonuse = this.buttonuse;
2811         store.buttonchat = this.buttonchat;
2812
2813         store.cursor_active = this.cursor_active;
2814         store.cursor_screen = this.cursor_screen;
2815         store.cursor_trace_start = this.cursor_trace_start;
2816         store.cursor_trace_endpos = this.cursor_trace_endpos;
2817         store.cursor_trace_ent = this.cursor_trace_ent;
2818
2819         store.ping = this.ping;
2820         store.ping_packetloss = this.ping_packetloss;
2821         store.ping_movementloss = this.ping_movementloss;
2822
2823         store.v_angle = this.v_angle;
2824         store.movement = this.movement;
2825 }
2826
2827 NET_HANDLE(fpsreport, bool)
2828 {
2829         int fps = ReadShort();
2830         PlayerScore_Set(sender, SP_FPS, fps);
2831         return true;
2832 }