qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.dphitcontentsmask = oldself.dphitcontentsmask;
 170         self.death_time = oldself.death_time;
 171         self.frame = oldself.frame;
 172         self.pain_finished = oldself.pain_finished;
 173         self.health = oldself.health;
 174         self.armorvalue = oldself.armorvalue;
 175         self.armortype = oldself.armortype;
 176         self.model = oldself.model;
 177         self.modelindex = oldself.modelindex;
 178         self.skin = oldself.skin;
 179         self.species = oldself.species;
 180         self.movetype = oldself.movetype;
 181         self.solid = oldself.solid;
 182         self.ballistics_density = oldself.ballistics_density;
 183         self.takedamage = oldself.takedamage;
 184         self.customizeentityforclient = oldself.customizeentityforclient;
 185         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 186         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 187         if (keepvelocity == 1)
 188                 self.velocity = oldself.velocity;
 189         self.oldvelocity = self.velocity;
 190         self.alpha = oldself.alpha;
 191         self.fade_time = oldself.fade_time;
 192         self.fade_rate = oldself.fade_rate;
 193         //self.weapon = oldself.weapon;
 194         setorigin(self, oldself.origin);
 195         setsize(self, oldself.mins, oldself.maxs);
 196         self.prevorigin = oldself.origin;
 197         self.reset = SUB_Remove;
 198
 199         Drag_MoveDrag(oldself, self);
 200
 201         if(self.colormap <= maxclients && self.colormap > 0)
 202                 self.colormap = 1024 + oldself.clientcolors;
 203
 204         CSQCMODEL_AUTOINIT();
 205         self.CopyBody_nextthink = oldself.nextthink;
 206         self.CopyBody_think = oldself.think;
 207         self.nextthink = time;
 208         self.think = CopyBody_Think;
 209
 210         self = oldself;
 211 }
 212
 213 float player_getspecies()
 214 {
 215         float s;
 216         get_model_parameters(self.model, self.skin);
 217         s = get_model_parameters_species;
 218         get_model_parameters(string_null, 0);
 219         if(s < 0)
 220                 return SPECIES_HUMAN;
 221         return s;
 222 }
 223
 224 void player_setupanimsformodel()
 225 {
 226         // defaults for legacy .zym models without animinfo files
 227         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 228         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 229         self.anim_draw = animfixfps(self, '2 1 3');
 230         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 231         self.anim_duckwalk = animfixfps(self, '4 1 1');
 232         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 233         self.anim_duckidle = animfixfps(self, '6 1 1');
 234         self.anim_idle = animfixfps(self, '7 1 1');
 235         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 236         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 237         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 238         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 239         self.anim_taunt = animfixfps(self, '12 1 0.33');
 240         self.anim_run = animfixfps(self, '13 1 1');
 241         self.anim_runbackwards = animfixfps(self, '14 1 1');
 242         self.anim_strafeleft = animfixfps(self, '15 1 1');
 243         self.anim_straferight = animfixfps(self, '16 1 1');
 244         //self.anim_dead1 = animfixfps(self, '17 1 1');
 245         //self.anim_dead2 = animfixfps(self, '18 1 1');
 246         self.anim_forwardright = animfixfps(self, '19 1 1');
 247         self.anim_forwardleft = animfixfps(self, '20 1 1');
 248         self.anim_backright = animfixfps(self, '21 1 1');
 249         self.anim_backleft  = animfixfps(self, '22 1 1');
 250         self.anim_melee = animfixfps(self, '23 1 1');
 251         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 252         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 253         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 254         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 255         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 256         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 257         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 258         // TODO introspect models for finding right "fps" value (1/duration)
 259         // reset animstate now
 260         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 261 }
 262
 263 void player_anim (void)
 264 {
 265         updateanim(self);
 266         if (self.weaponentity)
 267                 updateanim(self.weaponentity);
 268
 269         if (self.deadflag != DEAD_NO)
 270                 return;
 271
 272         if (!self.animstate_override)
 273         {
 274                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 275                 {
 276                         if (self.crouch)
 277                         {
 278                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 279                                 {
 280                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 281                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 282                                         {
 283                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 284                                                 self.restart_jump = FALSE;
 285                                         }
 286                                 }
 287                         }
 288                         else
 289                         {
 290                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 291                 {
 292                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 293                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 294                     {
 295                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 296                         self.restart_jump = FALSE;
 297                     }
 298                 }
 299                         }
 300                 }
 301                 else if (self.crouch)
 302                 {
 303                         if (self.movement_x > 0 && self.movement_y == 0)
 304                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x < 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x == 0 && self.movement_y > 0)
 308                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y < 0)
 310                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x > 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x < 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 319                         else
 320                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 321                 }
 322                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 323                 {
 324                         if (self.movement_x > 0 && self.movement_y == 0)
 325                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 326                         else if (self.movement_x < 0 && self.movement_y == 0)
 327                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 328                         else if (self.movement_x == 0 && self.movement_y > 0)
 329                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x == 0 && self.movement_y < 0)
 331                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x > 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x > 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x < 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x < 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 340                         else
 341                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 342                 }
 343                 else
 344                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 345         }
 346
 347         if (self.weaponentity)
 348         if (!self.weaponentity.animstate_override)
 349                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 350 }
 351
 352 void SpawnThrownWeapon (vector org, float w)
 353 {
 354         if(g_minstagib)
 355         if(self.ammo_cells <= 0)
 356                 return;
 357
 358         if(g_pinata)
 359         {
 360                 float j;
 361                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 362                 {
 363                         if(WEPSET_CONTAINS_EW(self, j))
 364                                 if(W_IsWeaponThrowable(j))
 365                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 366                 }
 367         }
 368         else
 369         {
 370                 if(W_IsWeaponThrowable(self.weapon))
 371                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 372         }
 373 }
 374
 375 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 376 {
 377         float take, save;
 378         vector v;
 379         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 380
 381         // damage resistance (ignore most of the damage from a bullet or similar)
 382         damage = max(damage - 5, 1);
 383
 384         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 385         take = v_x;
 386         save = v_y;
 387
 388         if(sound_allowed(MSG_BROADCAST, attacker))
 389         {
 390                 if (save > 10)
 391                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 392                 else if (take > 30)
 393                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 394                 else if (take > 10)
 395                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 396         }
 397
 398         if (take > 50)
 399                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 400         if (take > 100)
 401                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 402
 403         if (!(self.flags & FL_GODMODE))
 404         {
 405                 self.armorvalue = self.armorvalue - save;
 406                 self.health = self.health - take;
 407                 // pause regeneration for 5 seconds
 408                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 409         }
 410         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 411         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 412         self.dmg_inflictor = inflictor;
 413
 414         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 415         {
 416                 // don't use any animations as a gib
 417                 self.frame = 0;
 418                 // view just above the floor
 419                 self.view_ofs = '0 0 4';
 420
 421                 Violence_GibSplash(self, 1, 1, attacker);
 422                 self.alpha = -1;
 423                 self.solid = SOLID_NOT; // restore later
 424                 self.takedamage = DAMAGE_NO; // restore later
 425         }
 426 }
 427
 428 void ClientKill_Now_TeamChange();
 429 void freezetag_CheckWinner();
 430
 431 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 432 {
 433         float take, save, waves, sdelay, dh, da, j;
 434         vector v;
 435         float valid_damage_for_weaponstats;
 436         float excess;
 437
 438         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 439                 return;
 440
 441         dh = max(self.health, 0);
 442         da = max(self.armorvalue, 0);
 443
 444         if(!DEATH_ISSPECIAL(deathtype))
 445         {
 446                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 447                 if(self != attacker)
 448                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 449         }
 450
 451         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 452         {
 453                 // tuba causes blood to come out of the ears
 454                 vector ear1, ear2;
 455                 vector d;
 456                 float f;
 457                 ear1 = self.origin;
 458                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 459                 ear2 = ear1;
 460                 makevectors(self.angles);
 461                 ear1 += v_right * -10;
 462                 ear2 += v_right * +10;
 463                 d = inflictor.origin - self.origin;
 464                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 465                 force = v_right * vlen(force);
 466                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 467                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 468                 if(f > 0)
 469                 {
 470                         hitloc = ear1;
 471                         force = force * -1;
 472                 }
 473                 else
 474                 {
 475                         hitloc = ear2;
 476                         // force is already good
 477                 }
 478         }
 479         else
 480                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 481
 482         if (!g_minstagib)
 483         {
 484                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 485                 take = v_x;
 486                 save = v_y;
 487         }
 488         else
 489         {
 490                 save = 0;
 491                 take = damage;
 492         }
 493
 494         frag_inflictor = inflictor;
 495         frag_attacker = attacker;
 496         frag_target = self;
 497         damage_take = take;
 498         damage_save = save;
 499         damage_force = force;
 500         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 501         take = bound(0, damage_take, self.health);
 502         save = bound(0, damage_save, self.armorvalue);
 503         excess = max(0, damage - take - save);
 504
 505         if(sound_allowed(MSG_BROADCAST, attacker))
 506         {
 507                 if (save > 10)
 508                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 509                 else if (take > 30)
 510                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 511                 else if (take > 10)
 512                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 513         }
 514
 515         if (take > 50)
 516                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 517         if (take > 100)
 518                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 519
 520         if (time >= self.spawnshieldtime)
 521         {
 522                 if (!(self.flags & FL_GODMODE))
 523                 {
 524                         self.armorvalue = self.armorvalue - save;
 525                         self.health = self.health - take;
 526                         // pause regeneration for 5 seconds
 527                         if(take)
 528                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 529
 530                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 531                         {
 532                                 self.pain_finished = time + 0.5;        //Supajoe
 533
 534                                 if(sv_gentle < 1) {
 535                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 536                                         {
 537                                                 if (!self.animstate_override)
 538                                                 {
 539                                                         if (random() > 0.5)
 540                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 541                                                         else
 542                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 543                                                 }
 544                                         }
 545
 546                                         if(sound_allowed(MSG_BROADCAST, attacker))
 547                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 548                                         if(self.health > 1)
 549                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 550                                         {
 551                                                 if(deathtype == DEATH_FALL)
 552                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 553                                                 else if(self.health > 75) // TODO make a "gentle" version?
 554                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 555                                                 else if(self.health > 50)
 556                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                                 else if(self.health > 25)
 558                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 559                                                 else
 560                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 561                                         }
 562                                 }
 563
 564                                 // throw off bot aim temporarily
 565                                 float shake;
 566                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 567                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 568                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 569                         }
 570                 }
 571                 else
 572                         self.max_armorvalue += (save + take);
 573         }
 574         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 575         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 576         self.dmg_inflictor = inflictor;
 577
 578         if(attacker == self)
 579         {
 580                 // don't reset pushltime for self damage as it may be an attempt to
 581                 // escape a lava pit or similar
 582                 //self.pushltime = 0;
 583         }
 584         else if(attacker.classname == "player")
 585         {
 586                 self.pusher = attacker;
 587                 self.pushltime = time + autocvar_g_maxpushtime;
 588         }
 589         else if(time < self.pushltime)
 590         {
 591                 attacker = self.pusher;
 592                 self.pushltime = max(self.pushltime, time + 0.6);
 593         }
 594         else
 595                 self.pushltime = 0;
 596
 597         float abot, vbot, awep;
 598         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 599         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 600
 601         valid_damage_for_weaponstats = 0;
 602         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 603         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 604         if(attacker && self != attacker)
 605         if(IsDifferentTeam(self, attacker))
 606         {
 607                 if(DEATH_ISSPECIAL(deathtype))
 608                         awep = attacker.weapon;
 609                 else
 610                         awep = DEATH_WEAPONOF(deathtype);
 611                 valid_damage_for_weaponstats = 1;
 612         }
 613         else
 614                 awep = 0;
 615
 616         if(valid_damage_for_weaponstats)
 617         {
 618                 dh = dh - max(self.health, 0);
 619                 da = da - max(self.armorvalue, 0);
 620                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 621         }
 622
 623         if (self.health < 1)
 624         {
 625                 float defer_ClientKill_Now_TeamChange;
 626                 defer_ClientKill_Now_TeamChange = FALSE;
 627
 628                 if(self.alivetime)
 629                 {
 630                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 631                         self.alivetime = 0;
 632                 }
 633
 634                 if(valid_damage_for_weaponstats)
 635                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 636
 637                 if(sv_gentle < 1) // TODO make a "gentle" version?
 638                 if(sound_allowed(MSG_BROADCAST, attacker))
 639                 {
 640                         if(deathtype == DEATH_DROWN)
 641                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 642                         else
 643                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 644                 }
 645
 646                 // get rid of kill indicator
 647                 if(self.killindicator)
 648                 {
 649                         remove(self.killindicator);
 650                         self.killindicator = world;
 651                         if(self.killindicator_teamchange)
 652                                 defer_ClientKill_Now_TeamChange = TRUE;
 653
 654                         if(self.classname == "body")
 655                         if(deathtype == DEATH_KILL)
 656                         {
 657                                 // for the lemmings fans, a small harmless explosion
 658                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 659                         }
 660                 }
 661
 662                 if(!g_freezetag)
 663                 {
 664                         // become fully visible
 665                         self.alpha = default_player_alpha;
 666                         // throw a weapon
 667                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 668                 }
 669
 670                 // print an obituary message
 671                 Obituary (attacker, inflictor, self, deathtype);
 672                 race_PreDie();
 673                 DropAllRunes(self);
 674
 675         // increment frag counter for used weapon type
 676         float w;
 677         w = DEATH_WEAPONOF(deathtype);
 678         if(WEP_VALID(w))
 679         if(accuracy_isgooddamage(attacker, self))
 680         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 681
 682                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 683                 {
 684                         PutClientInServer();
 685                         count_alive_players(); // re-count players
 686                         freezetag_CheckWinner();
 687                         return;
 688                 }
 689
 690                 frag_attacker = attacker;
 691                 frag_inflictor = inflictor;
 692                 frag_target = self;
 693                 MUTATOR_CALLHOOK(PlayerDies);
 694                 weapon_action(self.weapon, WR_PLAYERDEATH);
 695
 696                 RemoveGrapplingHook(self);
 697
 698                 if(self.flagcarried)
 699                 {
 700                         if(attacker.classname != "player")
 701                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 702                         else if(attacker.team == self.team)
 703                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 704                         else
 705                                 DropFlag(self.flagcarried, world, attacker);
 706                 }
 707                 Portal_ClearAllLater(self);
 708
 709                 if(clienttype(self) == CLIENTTYPE_REAL)
 710                 {
 711                         stuffcmd(self, "-zoom\n");
 712                         self.fixangle = TRUE;
 713                         //msg_entity = self;
 714                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 715                         //WriteAngle (MSG_ONE, self.v_angle_x);
 716                         //WriteAngle (MSG_ONE, self.v_angle_y);
 717                         //WriteAngle (MSG_ONE, 80);
 718                 }
 719
 720                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 721                         ClientKill_Now_TeamChange();
 722
 723                 if(g_arena)
 724                         Spawnqueue_Unmark(self);
 725
 726                 if(g_freezetag)
 727                         return;
 728
 729                 // when we get here, player actually dies
 730                 // clear waypoints (do this AFTER FreezeTag)
 731                 WaypointSprite_PlayerDead();
 732
 733                 // make the corpse upright (not tilted)
 734                 self.angles_x = 0;
 735                 self.angles_z = 0;
 736                 // don't spin
 737                 self.avelocity = '0 0 0';
 738                 // view from the floor
 739                 self.view_ofs = '0 0 -8';
 740                 // toss the corpse
 741                 self.movetype = MOVETYPE_TOSS;
 742                 // shootable corpse
 743                 self.solid = SOLID_CORPSE;
 744                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 745                 // don't stick to the floor
 746                 self.flags &~= FL_ONGROUND;
 747                 // dying animation
 748                 self.deadflag = DEAD_DYING;
 749                 // when to allow respawn
 750                 sdelay = 0;
 751                 waves = 0;
 752                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 753                 if(!sdelay)
 754                 {
 755                         if(g_cts)
 756                                 sdelay = 0; // no respawn delay in CTS
 757                         else
 758                                 sdelay = autocvar_g_respawn_delay;
 759                 }
 760                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 761                 if(!waves)
 762                         waves = autocvar_g_respawn_waves;
 763                 if(waves)
 764                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 765                 else
 766                         self.respawn_time = time + sdelay;
 767                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 768                         self.respawn_countdown = 10; // first number to count down from is 10
 769                 else
 770                         self.respawn_countdown = -1; // do not count down
 771                 self.death_time = time;
 772                 if (random() < 0.5)
 773                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 774                 else
 775                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 776                 if (self.maxs_z > 5)
 777                 {
 778                         self.maxs_z = 5;
 779                         setsize(self, self.mins, self.maxs);
 780                 }
 781                 // set damage function to corpse damage
 782                 self.event_damage = PlayerCorpseDamage;
 783                 // call the corpse damage function just in case it wants to gib
 784                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 785                 // set up to fade out later
 786                 SUB_SetFade (self, time + 6 + random (), 1);
 787
 788                 if(sv_gentle > 0 || autocvar_ekg) {
 789                         // remove corpse
 790                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 791                 }
 792
 793                 // reset fields the weapons may use just in case
 794                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 795                 {
 796                         weapon_action(j, WR_RESETPLAYER);
 797                         ATTACK_FINISHED_FOR(self, j) = 0;
 798                 }
 799         }
 800 }
 801
 802 .float muted; // to be used by prvm_edictset server playernumber muted 1
 803 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 804 // message "": do not say, just test flood control
 805 // return value:
 806 //   1 = accept
 807 //   0 = reject
 808 //  -1 = fake accept
 809 {
 810         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 811         float flood, privatemsgprefixlen;
 812         var .float flood_field;
 813         entity head;
 814         float ret;
 815
 816         if(!teamsay && !privatesay)
 817                 if(substring(msgin, 0, 1) == " ")
 818                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 819
 820         msgin = formatmessage(msgin);
 821
 822         if(source.classname != "player")
 823                 colorstr = "^0"; // black for spectators
 824         else if(teamplay)
 825                 colorstr = Team_ColorCode(source.team);
 826         else
 827         {
 828                 colorstr = "";
 829                 teamsay = FALSE;
 830         }
 831
 832         if(intermission_running)
 833                 teamsay = FALSE;
 834
 835         if(msgin != "")
 836                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 837
 838         /*
 839          * using bprint solves this... me stupid
 840         // how can we prevent the message from appearing in a listen server?
 841         // for now, just give "say" back and only handle say_team
 842         if(!teamsay)
 843         {
 844                 clientcommand(self, strcat("say ", msgin));
 845                 return;
 846         }
 847         */
 848
 849         if(autocvar_g_chat_teamcolors)
 850                 namestr = playername(source);
 851         else
 852                 namestr = source.netname;
 853
 854         if(msgin != "")
 855         {
 856                 if(privatesay)
 857                 {
 858                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 859                         privatemsgprefixlen = strlen(msgstr);
 860                         msgstr = strcat(msgstr, msgin);
 861                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 862                         if(autocvar_g_chat_teamcolors)
 863                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 864                         else
 865                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 866                 }
 867                 else if(teamsay)
 868                 {
 869                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 870                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 871                 }
 872                 else
 873                 {
 874                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 875                         cmsgstr = "";
 876                 }
 877                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 878         }
 879         else
 880         {
 881                 msgstr = cmsgstr = "";
 882         }
 883
 884         fullmsgstr = msgstr;
 885         fullcmsgstr = cmsgstr;
 886
 887         // FLOOD CONTROL
 888         flood = 0;
 889         flood_field = floodcontrol_chat;
 890         if(floodcontrol)
 891         {
 892                 float flood_spl;
 893                 float flood_burst;
 894                 float flood_lmax;
 895                 float lines;
 896                 if(privatesay)
 897                 {
 898                         flood_spl = autocvar_g_chat_flood_spl_tell;
 899                         flood_burst = autocvar_g_chat_flood_burst_tell;
 900                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 901                         flood_field = floodcontrol_chattell;
 902                 }
 903                 else if(teamsay)
 904                 {
 905                         flood_spl = autocvar_g_chat_flood_spl_team;
 906                         flood_burst = autocvar_g_chat_flood_burst_team;
 907                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 908                         flood_field = floodcontrol_chatteam;
 909                 }
 910                 else
 911                 {
 912                         flood_spl = autocvar_g_chat_flood_spl;
 913                         flood_burst = autocvar_g_chat_flood_burst;
 914                         flood_lmax = autocvar_g_chat_flood_lmax;
 915                         flood_field = floodcontrol_chat;
 916                 }
 917                 flood_burst = max(0, flood_burst - 1);
 918                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 919
 920                 // do flood control for the default line size
 921                 if(msgstr != "")
 922                 {
 923                         getWrappedLine_remaining = msgstr;
 924                         msgstr = "";
 925                         lines = 0;
 926                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 927                         {
 928                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 929                                 ++lines;
 930                         }
 931                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 932
 933                         if(getWrappedLine_remaining != "")
 934                         {
 935                                 msgstr = strcat(msgstr, "\n");
 936                                 flood = 2;
 937                         }
 938
 939                         if(time >= source.flood_field)
 940                         {
 941                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 942                         }
 943                         else
 944                         {
 945                                 flood = 1;
 946                                 msgstr = fullmsgstr;
 947                         }
 948                 }
 949                 else
 950                 {
 951                         if(time >= source.flood_field)
 952                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 953                         else
 954                                 flood = 1;
 955                 }
 956
 957                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 958                         source.flood_field = flood = 0;
 959         }
 960
 961         if(flood == 2) // cannot happen for empty msgstr
 962         {
 963                 if(autocvar_g_chat_flood_notify_flooder)
 964                 {
 965                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 966                         sourcecmsgstr = "";
 967                 }
 968                 else
 969                 {
 970                         sourcemsgstr = fullmsgstr;
 971                         sourcecmsgstr = fullcmsgstr;
 972                 }
 973                 cmsgstr = "";
 974         }
 975         else
 976         {
 977                 sourcemsgstr = msgstr;
 978                 sourcecmsgstr = cmsgstr;
 979         }
 980
 981         if(!privatesay)
 982         if(source.classname != "player")
 983         {
 984                 if not(intermission_running)
 985                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 986                                 teamsay = -1; // spectators
 987         }
 988
 989         if(flood)
 990                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 991
 992         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 993         if(privatesay)
 994                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 995
 996         if(source.muted)
 997         {
 998                 // always fake the message
 999                 ret = -1;
1000         }
1001         else if(flood == 1)
1002         {
1003                 if(autocvar_g_chat_flood_notify_flooder)
1004                 {
1005                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1006                         ret = 0;
1007                 }
1008                 else
1009                         ret = -1;
1010         }
1011         else
1012         {
1013                 ret = 1;
1014         }
1015
1016         if(sourcemsgstr != "" && ret != 0)
1017         {
1018                 if(ret < 0) // faked message, because the player is muted
1019                 {
1020                         sprint(source, sourcemsgstr);
1021                         if(sourcecmsgstr != "" && !privatesay)
1022                                 centerprint(source, sourcecmsgstr);
1023                 }
1024                 else if(privatesay) // private message, between 2 people only, not sent to server console
1025                 {
1026                         sprint(source, sourcemsgstr);
1027                         sprint(privatesay, msgstr);
1028                         if(cmsgstr != "")
1029                                 centerprint(privatesay, cmsgstr);
1030                 }
1031                 else if(teamsay > 0) // team message, only sent to team mates
1032                 {
1033                         sprint(source, sourcemsgstr);
1034                         //print(msgstr); // send to server console too
1035                         if(sourcecmsgstr != "")
1036                                 centerprint(source, sourcecmsgstr);
1037                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1038                                 if(head != source)
1039                                 {
1040                                         sprint(head, msgstr);
1041                                         if(cmsgstr != "")
1042                                                 centerprint(head, cmsgstr);
1043                                 }
1044                 }
1045                 else if(teamsay < 0) // spectator message, only sent to spectators
1046                 {
1047                         sprint(source, sourcemsgstr);
1048                         //print(msgstr); // send to server console too
1049                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1050                                 if(head != source)
1051                                         sprint(head, msgstr);
1052                 }
1053                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1054                 {
1055                         sprint(source, sourcemsgstr);
1056                         //print(msgstr); // send to server console too
1057                         FOR_EACH_REALCLIENT(head)
1058                                 if(head != source)
1059                                         sprint(head, msgstr);
1060                 }
1061                 else
1062                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1063         }
1064
1065         return ret;
1066 }
1067
1068 float GetVoiceMessageVoiceType(string type)
1069 {
1070         if(type == "taunt")
1071                 return VOICETYPE_TAUNT;
1072         if(type == "teamshoot")
1073                 return VOICETYPE_LASTATTACKER;
1074         return VOICETYPE_TEAMRADIO;
1075 }
1076
1077 string allvoicesamples;
1078 .string GetVoiceMessageSampleField(string type)
1079 {
1080         GetPlayerSoundSampleField_notFound = 0;
1081         switch(type)
1082         {
1083 #define _VOICEMSG(m) case #m: return playersound_##m;
1084                 ALLVOICEMSGS
1085 #undef _VOICEMSG
1086         }
1087         GetPlayerSoundSampleField_notFound = 1;
1088         return playersound_taunt;
1089 }
1090
1091 .string GetPlayerSoundSampleField(string type)
1092 {
1093         GetPlayerSoundSampleField_notFound = 0;
1094         switch(type)
1095         {
1096 #define _VOICEMSG(m) case #m: return playersound_##m;
1097                 ALLPLAYERSOUNDS
1098 #undef _VOICEMSG
1099         }
1100         GetPlayerSoundSampleField_notFound = 1;
1101         return playersound_taunt;
1102 }
1103
1104 void PrecacheGlobalSound(string samplestring)
1105 {
1106         float n, i;
1107         tokenize_console(samplestring);
1108         n = stof(argv(1));
1109         if(n > 0)
1110         {
1111                 for(i = 1; i <= n; ++i)
1112                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1113         }
1114         else
1115         {
1116                 precache_sound(strcat(argv(0), ".wav"));
1117         }
1118 }
1119
1120 void PrecachePlayerSounds(string f)
1121 {
1122         float fh;
1123         string s;
1124         fh = fopen(f, FILE_READ);
1125         if(fh < 0)
1126                 return;
1127         while((s = fgets(fh)))
1128         {
1129                 if(tokenize_console(s) != 3)
1130                 {
1131                         dprint("Invalid sound info line: ", s, "\n");
1132                         continue;
1133                 }
1134                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1135         }
1136         fclose(fh);
1137
1138         if not(allvoicesamples)
1139         {
1140 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1141                 ALLVOICEMSGS
1142 #undef _VOICEMSG
1143                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1144         }
1145 }
1146
1147 void ClearPlayerSounds()
1148 {
1149 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1150         ALLPLAYERSOUNDS
1151         ALLVOICEMSGS
1152 #undef _VOICEMSG
1153 }
1154
1155 float LoadPlayerSounds(string f, float first)
1156 {
1157         float fh;
1158         string s;
1159         var .string field;
1160         fh = fopen(f, FILE_READ);
1161         if(fh < 0)
1162         {
1163                 dprint("Player sound file not found: ", f, "\n");
1164                 return 0;
1165         }
1166         while((s = fgets(fh)))
1167         {
1168                 if(tokenize_console(s) != 3)
1169                         continue;
1170                 field = GetPlayerSoundSampleField(argv(0));
1171                 if(GetPlayerSoundSampleField_notFound)
1172                         field = GetVoiceMessageSampleField(argv(0));
1173                 if(GetPlayerSoundSampleField_notFound)
1174                         continue;
1175                 if(self.field)
1176                         strunzone(self.field);
1177                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1178         }
1179         fclose(fh);
1180         return 1;
1181 }
1182
1183 .float modelindex_for_playersound;
1184 .float skin_for_playersound;
1185 void UpdatePlayerSounds()
1186 {
1187         if(self.modelindex == self.modelindex_for_playersound)
1188         if(self.skin == self.skin_for_playersound)
1189                 return;
1190         self.modelindex_for_playersound = self.modelindex;
1191         self.skin_for_playersound = self.skin;
1192         ClearPlayerSounds();
1193         LoadPlayerSounds("sound/player/default.sounds", 1);
1194         if(!autocvar_g_debug_defaultsounds)
1195                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1196                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1197 }
1198
1199 void FakeGlobalSound(string sample, float chan, float voicetype)
1200 {
1201         float n;
1202         float tauntrand;
1203
1204         if(sample == "")
1205                 return;
1206
1207         tokenize_console(sample);
1208         n = stof(argv(1));
1209         if(n > 0)
1210                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1211         else
1212                 sample = strcat(argv(0), ".wav"); // randomization
1213
1214         switch(voicetype)
1215         {
1216                 case VOICETYPE_LASTATTACKER_ONLY:
1217                         break;
1218                 case VOICETYPE_LASTATTACKER:
1219                         if(self.pusher)
1220                         {
1221                                 msg_entity = self;
1222                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1223                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1224                         }
1225                         break;
1226                 case VOICETYPE_TEAMRADIO:
1227                         msg_entity = self;
1228                         if(msg_entity.cvar_cl_voice_directional == 1)
1229                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1230                         else
1231                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1232                         break;
1233                 case VOICETYPE_AUTOTAUNT:
1234                         if(!sv_autotaunt)
1235                                 break;
1236                         if(!sv_taunt)
1237                                 break;
1238                         if(sv_gentle)
1239                                 break;
1240                         tauntrand = random();
1241                         msg_entity = self;
1242                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1243                         {
1244                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1245                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1246                                 else
1247                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1248                         }
1249                         break;
1250                 case VOICETYPE_TAUNT:
1251                         if(self.classname == "player")
1252                                 if(self.deadflag == DEAD_NO)
1253                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1254                         if(!sv_taunt)
1255                                 break;
1256                         if(sv_gentle)
1257                                 break;
1258                         msg_entity = self;
1259                         if (msg_entity.cvar_cl_voice_directional >= 1)
1260                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1261                         else
1262                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1263                         break;
1264                 case VOICETYPE_PLAYERSOUND:
1265                         msg_entity = self;
1266                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1267                         break;
1268                 default:
1269                         backtrace("Invalid voice type!");
1270                         break;
1271         }
1272 }
1273
1274 void GlobalSound(string sample, float chan, float voicetype)
1275 {
1276         float n;
1277         float tauntrand;
1278
1279         if(sample == "")
1280                 return;
1281
1282         tokenize_console(sample);
1283         n = stof(argv(1));
1284         if(n > 0)
1285                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1286         else
1287                 sample = strcat(argv(0), ".wav"); // randomization
1288
1289         switch(voicetype)
1290         {
1291                 case VOICETYPE_LASTATTACKER_ONLY:
1292                         if(self.pusher)
1293                         {
1294                                 msg_entity = self.pusher;
1295                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1296                                 {
1297                                         if(msg_entity.cvar_cl_voice_directional == 1)
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1299                                         else
1300                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1301                                 }
1302                         }
1303                         break;
1304                 case VOICETYPE_LASTATTACKER:
1305                         if(self.pusher)
1306                         {
1307                                 msg_entity = self.pusher;
1308                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1309                                 {
1310                                         if(msg_entity.cvar_cl_voice_directional == 1)
1311                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1312                                         else
1313                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1314                                 }
1315                                 msg_entity = self;
1316                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1317                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1318                         }
1319                         break;
1320                 case VOICETYPE_TEAMRADIO:
1321                         FOR_EACH_REALCLIENT(msg_entity)
1322                                 if(!teamplay || msg_entity.team == self.team)
1323                                 {
1324                                         if(msg_entity.cvar_cl_voice_directional == 1)
1325                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1326                                         else
1327                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1328                                 }
1329                         break;
1330                 case VOICETYPE_AUTOTAUNT:
1331                         if(!sv_autotaunt)
1332                                 break;
1333                         if(!sv_taunt)
1334                                 break;
1335                         if(sv_gentle)
1336                                 break;
1337                         tauntrand = random();
1338                         FOR_EACH_REALCLIENT(msg_entity)
1339                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1340                                 {
1341                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1342                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1343                                         else
1344                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1345                                 }
1346                         break;
1347                 case VOICETYPE_TAUNT:
1348                         if(self.classname == "player")
1349                                 if(self.deadflag == DEAD_NO)
1350                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1351                         if(!sv_taunt)
1352                                 break;
1353                         if(sv_gentle)
1354                                 break;
1355                         FOR_EACH_REALCLIENT(msg_entity)
1356                         {
1357                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1358                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1359                                 else
1360                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1361                         }
1362                         break;
1363                 case VOICETYPE_PLAYERSOUND:
1364                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1365                         break;
1366                 default:
1367                         backtrace("Invalid voice type!");
1368                         break;
1369         }
1370 }
1371
1372 void PlayerSound(.string samplefield, float chan, float voicetype)
1373 {
1374         GlobalSound(self.samplefield, chan, voicetype);
1375 }
1376
1377 void VoiceMessage(string type, string msg)
1378 {
1379         var .string sample;
1380         float voicetype, ownteam;
1381         float flood;
1382         sample = GetVoiceMessageSampleField(type);
1383
1384         if(GetPlayerSoundSampleField_notFound)
1385         {
1386                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1387                 return;
1388         }
1389
1390         voicetype = GetVoiceMessageVoiceType(type);
1391         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1392
1393         flood = Say(self, ownteam, world, msg, 1);
1394
1395         if (flood > 0)
1396                 GlobalSound(self.sample, CH_VOICE, voicetype);
1397         else if (flood < 0)
1398                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1399 }
1400
1401 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1402 {
1403 //      show_message
1404 //      0 (00) automove centerprint, admin message
1405 //      1 (01) automove centerprint, no admin message
1406 //      2 (10) no centerprint, admin message
1407 //      3 (11) no centerprint, no admin message
1408
1409         float lockteams_backup;
1410
1411         lockteams_backup = lockteams;  // backup any team lock
1412
1413         lockteams = 0;  // disable locked teams
1414
1415         TeamchangeFrags(client);  // move the players frags
1416         SetPlayerColors(client, team_colour - 1);  // set the players colour
1417         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1418
1419         lockteams = lockteams_backup;  // restore the team lock
1420
1421         LogTeamchange(client.playerid, client.team, type);
1422
1423         if not(show_message & 1) // admin message
1424                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1425
1426         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1427 }