qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.dphitcontentsmask = oldself.dphitcontentsmask;
 170         self.death_time = oldself.death_time;
 171         self.frame = oldself.frame;
 172         self.pain_finished = oldself.pain_finished;
 173         self.health = oldself.health;
 174         self.armorvalue = oldself.armorvalue;
 175         self.armortype = oldself.armortype;
 176         self.model = oldself.model;
 177         self.modelindex = oldself.modelindex;
 178         self.skin = oldself.skin;
 179         self.species = oldself.species;
 180         self.movetype = oldself.movetype;
 181         self.solid = oldself.solid;
 182         self.ballistics_density = oldself.ballistics_density;
 183         self.takedamage = oldself.takedamage;
 184         self.customizeentityforclient = oldself.customizeentityforclient;
 185         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 186         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 187         if (keepvelocity == 1)
 188                 self.velocity = oldself.velocity;
 189         self.oldvelocity = self.velocity;
 190         self.alpha = oldself.alpha;
 191         self.fade_time = oldself.fade_time;
 192         self.fade_rate = oldself.fade_rate;
 193         //self.weapon = oldself.weapon;
 194         setorigin(self, oldself.origin);
 195         setsize(self, oldself.mins, oldself.maxs);
 196         self.prevorigin = oldself.origin;
 197         self.reset = SUB_Remove;
 198
 199         Drag_MoveDrag(oldself, self);
 200
 201         if(self.colormap <= maxclients && self.colormap > 0)
 202                 self.colormap = 1024 + oldself.clientcolors;
 203
 204         CSQCMODEL_AUTOINIT();
 205         self.CopyBody_nextthink = oldself.nextthink;
 206         self.CopyBody_think = oldself.think;
 207         self.nextthink = time;
 208         self.think = CopyBody_Think;
 209
 210         self = oldself;
 211 }
 212
 213 float player_getspecies()
 214 {
 215         float s;
 216         get_model_parameters(self.model, self.skin);
 217         s = get_model_parameters_species;
 218         get_model_parameters(string_null, 0);
 219         if(s < 0)
 220                 return SPECIES_HUMAN;
 221         return s;
 222 }
 223
 224 void player_setupanimsformodel()
 225 {
 226         // defaults for legacy .zym models without animinfo files
 227         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 228         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 229         self.anim_draw = animfixfps(self, '2 1 3');
 230         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 231         self.anim_duckwalk = animfixfps(self, '4 1 1');
 232         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 233         self.anim_duckidle = animfixfps(self, '6 1 1');
 234         self.anim_idle = animfixfps(self, '7 1 1');
 235         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 236         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 237         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 238         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 239         self.anim_taunt = animfixfps(self, '12 1 0.33');
 240         self.anim_run = animfixfps(self, '13 1 1');
 241         self.anim_runbackwards = animfixfps(self, '14 1 1');
 242         self.anim_strafeleft = animfixfps(self, '15 1 1');
 243         self.anim_straferight = animfixfps(self, '16 1 1');
 244         //self.anim_dead1 = animfixfps(self, '17 1 1');
 245         //self.anim_dead2 = animfixfps(self, '18 1 1');
 246         self.anim_forwardright = animfixfps(self, '19 1 1');
 247         self.anim_forwardleft = animfixfps(self, '20 1 1');
 248         self.anim_backright = animfixfps(self, '21 1 1');
 249         self.anim_backleft  = animfixfps(self, '22 1 1');
 250         self.anim_melee = animfixfps(self, '23 1 1');
 251         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 252         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 253         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 254         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 255         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 256         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 257         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 258         // TODO introspect models for finding right "fps" value (1/duration)
 259         // reset animstate now
 260         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 261 }
 262
 263 void player_anim (void)
 264 {
 265         updateanim(self);
 266         if (self.weaponentity)
 267                 updateanim(self.weaponentity);
 268
 269         if (self.deadflag != DEAD_NO)
 270                 return;
 271
 272         if (!self.animstate_override)
 273         {
 274                 if (self.freezetag_frozen)
 275                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 276                 else if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 277                 {
 278                         if (self.crouch)
 279                         {
 280                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 281                                 {
 282                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 283                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 284                                         {
 285                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 286                                                 self.restart_jump = FALSE;
 287                                         }
 288                                 }
 289                         }
 290                         else
 291                         {
 292                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 293                 {
 294                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 295                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 296                     {
 297                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 298                         self.restart_jump = FALSE;
 299                     }
 300                 }
 301                         }
 302                 }
 303                 else if (self.crouch)
 304                 {
 305                         if (self.movement_x > 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x < 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y > 0)
 310                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y < 0)
 312                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y > 0)
 314                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y < 0)
 316                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y > 0)
 318                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y < 0)
 320                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 321                         else
 322                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 323                 }
 324                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 325                 {
 326                         if (self.movement_x > 0 && self.movement_y == 0)
 327                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 328                         else if (self.movement_x < 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x == 0 && self.movement_y > 0)
 331                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y < 0)
 333                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x > 0 && self.movement_y > 0)
 335                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y < 0)
 337                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x < 0 && self.movement_y > 0)
 339                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y < 0)
 341                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 342                         else
 343                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 344                 }
 345                 else
 346                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 347         }
 348
 349         if (self.weaponentity)
 350         if (!self.weaponentity.animstate_override)
 351                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 352 }
 353
 354 void SpawnThrownWeapon (vector org, float w)
 355 {
 356         if(g_minstagib)
 357         if(self.ammo_cells <= 0)
 358                 return;
 359
 360         if(g_pinata)
 361         {
 362                 float j;
 363                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 364                 {
 365                         if(WEPSET_CONTAINS_EW(self, j))
 366                                 if(W_IsWeaponThrowable(j))
 367                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 368                 }
 369         }
 370         else
 371         {
 372                 if(W_IsWeaponThrowable(self.weapon))
 373                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 374         }
 375 }
 376
 377 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 378 {
 379         float take, save;
 380         vector v;
 381         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 382
 383         // damage resistance (ignore most of the damage from a bullet or similar)
 384         damage = max(damage - 5, 1);
 385
 386         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 387         take = v_x;
 388         save = v_y;
 389
 390         if(sound_allowed(MSG_BROADCAST, attacker))
 391         {
 392                 if (save > 10)
 393                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 394                 else if (take > 30)
 395                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 396                 else if (take > 10)
 397                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 398         }
 399
 400         if (take > 50)
 401                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 402         if (take > 100)
 403                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 404
 405         if (!(self.flags & FL_GODMODE))
 406         {
 407                 self.armorvalue = self.armorvalue - save;
 408                 self.health = self.health - take;
 409                 // pause regeneration for 5 seconds
 410                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 411         }
 412         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 413         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 414         self.dmg_inflictor = inflictor;
 415
 416         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 417         {
 418                 // don't use any animations as a gib
 419                 self.frame = 0;
 420                 // view just above the floor
 421                 self.view_ofs = '0 0 4';
 422
 423                 Violence_GibSplash(self, 1, 1, attacker);
 424                 self.alpha = -1;
 425                 self.solid = SOLID_NOT; // restore later
 426                 self.takedamage = DAMAGE_NO; // restore later
 427         }
 428 }
 429
 430 void ClientKill_Now_TeamChange();
 431 void freezetag_CheckWinner();
 432
 433 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 434 {
 435         float take, save, waves, sdelay, dh, da, j;
 436         vector v;
 437         float valid_damage_for_weaponstats;
 438         float excess;
 439
 440         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 441                 return;
 442
 443         dh = max(self.health, 0);
 444         da = max(self.armorvalue, 0);
 445
 446         if(!DEATH_ISSPECIAL(deathtype))
 447         {
 448                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 449                 if(self != attacker)
 450                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 451         }
 452
 453         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 454         {
 455                 // tuba causes blood to come out of the ears
 456                 vector ear1, ear2;
 457                 vector d;
 458                 float f;
 459                 ear1 = self.origin;
 460                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 461                 ear2 = ear1;
 462                 makevectors(self.angles);
 463                 ear1 += v_right * -10;
 464                 ear2 += v_right * +10;
 465                 d = inflictor.origin - self.origin;
 466                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 467                 force = v_right * vlen(force);
 468                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 469                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 470                 if(f > 0)
 471                 {
 472                         hitloc = ear1;
 473                         force = force * -1;
 474                 }
 475                 else
 476                 {
 477                         hitloc = ear2;
 478                         // force is already good
 479                 }
 480         }
 481         else
 482                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 483
 484         if (!g_minstagib)
 485         {
 486                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 487                 take = v_x;
 488                 save = v_y;
 489         }
 490         else
 491         {
 492                 save = 0;
 493                 take = damage;
 494         }
 495
 496         frag_inflictor = inflictor;
 497         frag_attacker = attacker;
 498         frag_target = self;
 499         damage_take = take;
 500         damage_save = save;
 501         damage_force = force;
 502         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 503         take = bound(0, damage_take, self.health);
 504         save = bound(0, damage_save, self.armorvalue);
 505         excess = max(0, damage - take - save);
 506
 507         if(sound_allowed(MSG_BROADCAST, attacker))
 508         {
 509                 if (save > 10)
 510                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 511                 else if (take > 30)
 512                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 513                 else if (take > 10)
 514                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 515         }
 516
 517         if (take > 50)
 518                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 519         if (take > 100)
 520                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 521
 522         if (time >= self.spawnshieldtime)
 523         {
 524                 if (!(self.flags & FL_GODMODE))
 525                 {
 526                         self.armorvalue = self.armorvalue - save;
 527                         self.health = self.health - take;
 528                         // pause regeneration for 5 seconds
 529                         if(take)
 530                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 531
 532                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 533                         {
 534                                 self.pain_finished = time + 0.5;        //Supajoe
 535
 536                                 if(sv_gentle < 1) {
 537                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 538                                         {
 539                                                 if (!self.animstate_override)
 540                                                 {
 541                                                         if (random() > 0.5)
 542                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 543                                                         else
 544                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 545                                                 }
 546                                         }
 547
 548                                         if(sound_allowed(MSG_BROADCAST, attacker))
 549                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 550                                         if(self.health > 1)
 551                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 552                                         {
 553                                                 if(deathtype == DEATH_FALL)
 554                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 555                                                 else if(self.health > 75) // TODO make a "gentle" version?
 556                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                                 else if(self.health > 50)
 558                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 559                                                 else if(self.health > 25)
 560                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 561                                                 else
 562                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 563                                         }
 564                                 }
 565
 566                                 // throw off bot aim temporarily
 567                                 float shake;
 568                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 569                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 570                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 571                         }
 572                 }
 573                 else
 574                         self.max_armorvalue += (save + take);
 575         }
 576         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 577         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 578         self.dmg_inflictor = inflictor;
 579
 580         if(attacker == self)
 581         {
 582                 // don't reset pushltime for self damage as it may be an attempt to
 583                 // escape a lava pit or similar
 584                 //self.pushltime = 0;
 585         }
 586         else if(attacker.classname == "player")
 587         {
 588                 self.pusher = attacker;
 589                 self.pushltime = time + autocvar_g_maxpushtime;
 590         }
 591         else if(time < self.pushltime)
 592         {
 593                 attacker = self.pusher;
 594                 self.pushltime = max(self.pushltime, time + 0.6);
 595         }
 596         else
 597                 self.pushltime = 0;
 598
 599         float abot, vbot, awep;
 600         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 601         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 602
 603         valid_damage_for_weaponstats = 0;
 604         awep = 0;
 605
 606         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 607         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 608         if(attacker && self != attacker)
 609         if(IsDifferentTeam(self, attacker))
 610         {
 611                 if(DEATH_ISSPECIAL(deathtype))
 612                         awep = attacker.weapon;
 613                 else
 614                         awep = DEATH_WEAPONOF(deathtype);
 615                 valid_damage_for_weaponstats = 1;
 616         }
 617
 618         if(valid_damage_for_weaponstats)
 619         {
 620                 dh = dh - max(self.health, 0);
 621                 da = da - max(self.armorvalue, 0);
 622                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 623         }
 624
 625         if (self.health < 1)
 626         {
 627                 float defer_ClientKill_Now_TeamChange;
 628                 defer_ClientKill_Now_TeamChange = FALSE;
 629
 630                 if(self.alivetime)
 631                 {
 632                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 633                         self.alivetime = 0;
 634                 }
 635
 636                 if(valid_damage_for_weaponstats)
 637                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 638
 639                 if(sv_gentle < 1) // TODO make a "gentle" version?
 640                 if(sound_allowed(MSG_BROADCAST, attacker))
 641                 {
 642                         if(deathtype == DEATH_DROWN)
 643                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 644                         else
 645                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 646                 }
 647
 648                 // get rid of kill indicator
 649                 if(self.killindicator)
 650                 {
 651                         remove(self.killindicator);
 652                         self.killindicator = world;
 653                         if(self.killindicator_teamchange)
 654                                 defer_ClientKill_Now_TeamChange = TRUE;
 655
 656                         if(self.classname == "body")
 657                         if(deathtype == DEATH_KILL)
 658                         {
 659                                 // for the lemmings fans, a small harmless explosion
 660                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 661                         }
 662                 }
 663
 664                 if(!g_freezetag)
 665                 {
 666                         // become fully visible
 667                         self.alpha = default_player_alpha;
 668                         // throw a weapon
 669                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 670                 }
 671
 672                 // print an obituary message
 673                 Obituary (attacker, inflictor, self, deathtype);
 674                 race_PreDie();
 675                 DropAllRunes(self);
 676
 677         // increment frag counter for used weapon type
 678         float w;
 679         w = DEATH_WEAPONOF(deathtype);
 680         if(WEP_VALID(w))
 681         if(accuracy_isgooddamage(attacker, self))
 682         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 683
 684                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 685                 {
 686                         PutClientInServer();
 687                         count_alive_players(); // re-count players
 688                         freezetag_CheckWinner();
 689                         return;
 690                 }
 691
 692                 frag_attacker = attacker;
 693                 frag_inflictor = inflictor;
 694                 frag_target = self;
 695                 MUTATOR_CALLHOOK(PlayerDies);
 696                 weapon_action(self.weapon, WR_PLAYERDEATH);
 697
 698                 RemoveGrapplingHook(self);
 699
 700                 if(self.flagcarried)
 701                 {
 702                         if(attacker.classname != "player")
 703                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 704                         else if(attacker.team == self.team)
 705                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 706                         else
 707                                 DropFlag(self.flagcarried, world, attacker);
 708                 }
 709                 Portal_ClearAllLater(self);
 710
 711                 if(clienttype(self) == CLIENTTYPE_REAL)
 712                 {
 713                         stuffcmd(self, "-zoom\n");
 714                         self.fixangle = TRUE;
 715                         //msg_entity = self;
 716                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 717                         //WriteAngle (MSG_ONE, self.v_angle_x);
 718                         //WriteAngle (MSG_ONE, self.v_angle_y);
 719                         //WriteAngle (MSG_ONE, 80);
 720                 }
 721
 722                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 723                         ClientKill_Now_TeamChange();
 724
 725                 if(g_arena)
 726                         Spawnqueue_Unmark(self);
 727
 728                 if(g_freezetag)
 729                         return;
 730
 731                 // when we get here, player actually dies
 732                 // clear waypoints (do this AFTER FreezeTag)
 733                 WaypointSprite_PlayerDead();
 734
 735                 // make the corpse upright (not tilted)
 736                 self.angles_x = 0;
 737                 self.angles_z = 0;
 738                 // don't spin
 739                 self.avelocity = '0 0 0';
 740                 // view from the floor
 741                 self.view_ofs = '0 0 -8';
 742                 // toss the corpse
 743                 self.movetype = MOVETYPE_TOSS;
 744                 // shootable corpse
 745                 self.solid = SOLID_CORPSE;
 746                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 747                 // don't stick to the floor
 748                 self.flags &~= FL_ONGROUND;
 749                 // dying animation
 750                 self.deadflag = DEAD_DYING;
 751                 // when to allow respawn
 752                 sdelay = 0;
 753                 waves = 0;
 754                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 755                 if(!sdelay)
 756                 {
 757                         if(g_cts)
 758                                 sdelay = 0; // no respawn delay in CTS
 759                         else
 760                                 sdelay = autocvar_g_respawn_delay;
 761                 }
 762                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 763                 if(!waves)
 764                         waves = autocvar_g_respawn_waves;
 765                 if(waves)
 766                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 767                 else
 768                         self.respawn_time = time + sdelay;
 769                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 770                         self.respawn_countdown = 10; // first number to count down from is 10
 771                 else
 772                         self.respawn_countdown = -1; // do not count down
 773                 self.death_time = time;
 774                 if (random() < 0.5)
 775                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 776                 else
 777                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 778                 if (self.maxs_z > 5)
 779                 {
 780                         self.maxs_z = 5;
 781                         setsize(self, self.mins, self.maxs);
 782                 }
 783                 // set damage function to corpse damage
 784                 self.event_damage = PlayerCorpseDamage;
 785                 // call the corpse damage function just in case it wants to gib
 786                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 787                 // set up to fade out later
 788                 SUB_SetFade (self, time + 6 + random (), 1);
 789
 790                 if(sv_gentle > 0 || autocvar_ekg) {
 791                         // remove corpse
 792                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 793                 }
 794
 795                 // reset fields the weapons may use just in case
 796                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 797                 {
 798                         weapon_action(j, WR_RESETPLAYER);
 799                         ATTACK_FINISHED_FOR(self, j) = 0;
 800                 }
 801         }
 802 }
 803
 804 .float muted; // to be used by prvm_edictset server playernumber muted 1
 805 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 806 // message "": do not say, just test flood control
 807 // return value:
 808 //   1 = accept
 809 //   0 = reject
 810 //  -1 = fake accept
 811 {
 812         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 813         float flood;
 814         var .float flood_field;
 815         entity head;
 816         float ret;
 817         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 818
 819         if(!teamsay && !privatesay)
 820                 if(substring(msgin, 0, 1) == " ")
 821                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 822
 823         msgin = formatmessage(msgin);
 824
 825         if(source.classname != "player")
 826                 colorstr = "^0"; // black for spectators
 827         else if(teamplay)
 828                 colorstr = Team_ColorCode(source.team);
 829         else
 830         {
 831                 colorstr = "";
 832                 teamsay = FALSE;
 833         }
 834
 835         if(intermission_running)
 836                 teamsay = FALSE;
 837
 838         if(msgin != "")
 839                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 840
 841         /*
 842          * using bprint solves this... me stupid
 843         // how can we prevent the message from appearing in a listen server?
 844         // for now, just give "say" back and only handle say_team
 845         if(!teamsay)
 846         {
 847                 clientcommand(self, strcat("say ", msgin));
 848                 return;
 849         }
 850         */
 851
 852         if(autocvar_g_chat_teamcolors)
 853                 namestr = playername(source);
 854         else
 855                 namestr = source.netname;
 856
 857         if(msgin != "")
 858         {
 859                 if(privatesay)
 860                 {
 861                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 862                         privatemsgprefixlen = strlen(msgstr);
 863                         msgstr = strcat(msgstr, msgin);
 864                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 865                         if(autocvar_g_chat_teamcolors)
 866                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 867                         else
 868                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 869                 }
 870                 else if(teamsay)
 871                 {
 872                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 873                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 874                 }
 875                 else
 876                 {
 877                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 878                         cmsgstr = "";
 879                 }
 880                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 881         }
 882         else
 883         {
 884                 msgstr = cmsgstr = "";
 885         }
 886
 887         fullmsgstr = msgstr;
 888         fullcmsgstr = cmsgstr;
 889
 890         // FLOOD CONTROL
 891         flood = 0;
 892         flood_field = floodcontrol_chat;
 893         if(floodcontrol)
 894         {
 895                 float flood_spl;
 896                 float flood_burst;
 897                 float flood_lmax;
 898                 float lines;
 899                 if(privatesay)
 900                 {
 901                         flood_spl = autocvar_g_chat_flood_spl_tell;
 902                         flood_burst = autocvar_g_chat_flood_burst_tell;
 903                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 904                         flood_field = floodcontrol_chattell;
 905                 }
 906                 else if(teamsay)
 907                 {
 908                         flood_spl = autocvar_g_chat_flood_spl_team;
 909                         flood_burst = autocvar_g_chat_flood_burst_team;
 910                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 911                         flood_field = floodcontrol_chatteam;
 912                 }
 913                 else
 914                 {
 915                         flood_spl = autocvar_g_chat_flood_spl;
 916                         flood_burst = autocvar_g_chat_flood_burst;
 917                         flood_lmax = autocvar_g_chat_flood_lmax;
 918                         flood_field = floodcontrol_chat;
 919                 }
 920                 flood_burst = max(0, flood_burst - 1);
 921                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 922
 923                 // do flood control for the default line size
 924                 if(msgstr != "")
 925                 {
 926                         getWrappedLine_remaining = msgstr;
 927                         msgstr = "";
 928                         lines = 0;
 929                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 930                         {
 931                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 932                                 ++lines;
 933                         }
 934                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 935
 936                         if(getWrappedLine_remaining != "")
 937                         {
 938                                 msgstr = strcat(msgstr, "\n");
 939                                 flood = 2;
 940                         }
 941
 942                         if(time >= source.flood_field)
 943                         {
 944                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 945                         }
 946                         else
 947                         {
 948                                 flood = 1;
 949                                 msgstr = fullmsgstr;
 950                         }
 951                 }
 952                 else
 953                 {
 954                         if(time >= source.flood_field)
 955                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 956                         else
 957                                 flood = 1;
 958                 }
 959
 960                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 961                         source.flood_field = flood = 0;
 962         }
 963
 964         if(flood == 2) // cannot happen for empty msgstr
 965         {
 966                 if(autocvar_g_chat_flood_notify_flooder)
 967                 {
 968                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 969                         sourcecmsgstr = "";
 970                 }
 971                 else
 972                 {
 973                         sourcemsgstr = fullmsgstr;
 974                         sourcecmsgstr = fullcmsgstr;
 975                 }
 976                 cmsgstr = "";
 977         }
 978         else
 979         {
 980                 sourcemsgstr = msgstr;
 981                 sourcecmsgstr = cmsgstr;
 982         }
 983
 984         if(!privatesay)
 985         if(source.classname != "player")
 986         {
 987                 if not(intermission_running)
 988                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 989                                 teamsay = -1; // spectators
 990         }
 991
 992         if(flood)
 993                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 994
 995         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 996         if(privatesay)
 997                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 998
 999         if(source.muted)
1000         {
1001                 // always fake the message
1002                 ret = -1;
1003         }
1004         else if(flood == 1)
1005         {
1006                 if(autocvar_g_chat_flood_notify_flooder)
1007                 {
1008                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1009                         ret = 0;
1010                 }
1011                 else
1012                         ret = -1;
1013         }
1014         else
1015         {
1016                 ret = 1;
1017         }
1018
1019         if(sourcemsgstr != "" && ret != 0)
1020         {
1021                 if(ret < 0) // faked message, because the player is muted
1022                 {
1023                         sprint(source, sourcemsgstr);
1024                         if(sourcecmsgstr != "" && !privatesay)
1025                                 centerprint(source, sourcecmsgstr);
1026                 }
1027                 else if(privatesay) // private message, between 2 people only, not sent to server console
1028                 {
1029                         sprint(source, sourcemsgstr);
1030                         sprint(privatesay, msgstr);
1031                         if(cmsgstr != "")
1032                                 centerprint(privatesay, cmsgstr);
1033                 }
1034                 else if(teamsay > 0) // team message, only sent to team mates
1035                 {
1036                         sprint(source, sourcemsgstr);
1037                         //print(msgstr); // send to server console too
1038                         if(sourcecmsgstr != "")
1039                                 centerprint(source, sourcecmsgstr);
1040                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1041                                 if(head != source)
1042                                 {
1043                                         sprint(head, msgstr);
1044                                         if(cmsgstr != "")
1045                                                 centerprint(head, cmsgstr);
1046                                 }
1047                 }
1048                 else if(teamsay < 0) // spectator message, only sent to spectators
1049                 {
1050                         sprint(source, sourcemsgstr);
1051                         //print(msgstr); // send to server console too
1052                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1053                                 if(head != source)
1054                                         sprint(head, msgstr);
1055                 }
1056                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1057                 {
1058                         sprint(source, sourcemsgstr);
1059                         //print(msgstr); // send to server console too
1060                         FOR_EACH_REALCLIENT(head)
1061                                 if(head != source)
1062                                         sprint(head, msgstr);
1063                 }
1064                 else
1065                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1066         }
1067
1068         return ret;
1069 }
1070
1071 float GetVoiceMessageVoiceType(string type)
1072 {
1073         if(type == "taunt")
1074                 return VOICETYPE_TAUNT;
1075         if(type == "teamshoot")
1076                 return VOICETYPE_LASTATTACKER;
1077         return VOICETYPE_TEAMRADIO;
1078 }
1079
1080 string allvoicesamples;
1081 .string GetVoiceMessageSampleField(string type)
1082 {
1083         GetPlayerSoundSampleField_notFound = 0;
1084         switch(type)
1085         {
1086 #define _VOICEMSG(m) case #m: return playersound_##m;
1087                 ALLVOICEMSGS
1088 #undef _VOICEMSG
1089         }
1090         GetPlayerSoundSampleField_notFound = 1;
1091         return playersound_taunt;
1092 }
1093
1094 .string GetPlayerSoundSampleField(string type)
1095 {
1096         GetPlayerSoundSampleField_notFound = 0;
1097         switch(type)
1098         {
1099 #define _VOICEMSG(m) case #m: return playersound_##m;
1100                 ALLPLAYERSOUNDS
1101 #undef _VOICEMSG
1102         }
1103         GetPlayerSoundSampleField_notFound = 1;
1104         return playersound_taunt;
1105 }
1106
1107 void PrecacheGlobalSound(string samplestring)
1108 {
1109         float n, i;
1110         tokenize_console(samplestring);
1111         n = stof(argv(1));
1112         if(n > 0)
1113         {
1114                 for(i = 1; i <= n; ++i)
1115                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1116         }
1117         else
1118         {
1119                 precache_sound(strcat(argv(0), ".wav"));
1120         }
1121 }
1122
1123 void PrecachePlayerSounds(string f)
1124 {
1125         float fh;
1126         string s;
1127         fh = fopen(f, FILE_READ);
1128         if(fh < 0)
1129                 return;
1130         while((s = fgets(fh)))
1131         {
1132                 if(tokenize_console(s) != 3)
1133                 {
1134                         dprint("Invalid sound info line: ", s, "\n");
1135                         continue;
1136                 }
1137                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1138         }
1139         fclose(fh);
1140
1141         if not(allvoicesamples)
1142         {
1143 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1144                 ALLVOICEMSGS
1145 #undef _VOICEMSG
1146                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1147         }
1148 }
1149
1150 void ClearPlayerSounds()
1151 {
1152 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1153         ALLPLAYERSOUNDS
1154         ALLVOICEMSGS
1155 #undef _VOICEMSG
1156 }
1157
1158 float LoadPlayerSounds(string f, float first)
1159 {
1160         float fh;
1161         string s;
1162         var .string field;
1163         fh = fopen(f, FILE_READ);
1164         if(fh < 0)
1165         {
1166                 dprint("Player sound file not found: ", f, "\n");
1167                 return 0;
1168         }
1169         while((s = fgets(fh)))
1170         {
1171                 if(tokenize_console(s) != 3)
1172                         continue;
1173                 field = GetPlayerSoundSampleField(argv(0));
1174                 if(GetPlayerSoundSampleField_notFound)
1175                         field = GetVoiceMessageSampleField(argv(0));
1176                 if(GetPlayerSoundSampleField_notFound)
1177                         continue;
1178                 if(self.field)
1179                         strunzone(self.field);
1180                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1181         }
1182         fclose(fh);
1183         return 1;
1184 }
1185
1186 .float modelindex_for_playersound;
1187 .float skin_for_playersound;
1188 void UpdatePlayerSounds()
1189 {
1190         if(self.modelindex == self.modelindex_for_playersound)
1191         if(self.skin == self.skin_for_playersound)
1192                 return;
1193         self.modelindex_for_playersound = self.modelindex;
1194         self.skin_for_playersound = self.skin;
1195         ClearPlayerSounds();
1196         LoadPlayerSounds("sound/player/default.sounds", 1);
1197         if(!autocvar_g_debug_defaultsounds)
1198                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1199                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1200 }
1201
1202 void FakeGlobalSound(string sample, float chan, float voicetype)
1203 {
1204         float n;
1205         float tauntrand;
1206
1207         if(sample == "")
1208                 return;
1209
1210         tokenize_console(sample);
1211         n = stof(argv(1));
1212         if(n > 0)
1213                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1214         else
1215                 sample = strcat(argv(0), ".wav"); // randomization
1216
1217         switch(voicetype)
1218         {
1219                 case VOICETYPE_LASTATTACKER_ONLY:
1220                         break;
1221                 case VOICETYPE_LASTATTACKER:
1222                         if(self.pusher)
1223                         {
1224                                 msg_entity = self;
1225                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1226                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1227                         }
1228                         break;
1229                 case VOICETYPE_TEAMRADIO:
1230                         msg_entity = self;
1231                         if(msg_entity.cvar_cl_voice_directional == 1)
1232                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1233                         else
1234                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1235                         break;
1236                 case VOICETYPE_AUTOTAUNT:
1237                         if(!sv_autotaunt)
1238                                 break;
1239                         if(!sv_taunt)
1240                                 break;
1241                         if(sv_gentle)
1242                                 break;
1243                         tauntrand = random();
1244                         msg_entity = self;
1245                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1246                         {
1247                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1248                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1249                                 else
1250                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1251                         }
1252                         break;
1253                 case VOICETYPE_TAUNT:
1254                         if(self.classname == "player")
1255                                 if(self.deadflag == DEAD_NO)
1256                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1257                         if(!sv_taunt)
1258                                 break;
1259                         if(sv_gentle)
1260                                 break;
1261                         msg_entity = self;
1262                         if (msg_entity.cvar_cl_voice_directional >= 1)
1263                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1264                         else
1265                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1266                         break;
1267                 case VOICETYPE_PLAYERSOUND:
1268                         msg_entity = self;
1269                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1270                         break;
1271                 default:
1272                         backtrace("Invalid voice type!");
1273                         break;
1274         }
1275 }
1276
1277 void GlobalSound(string sample, float chan, float voicetype)
1278 {
1279         float n;
1280         float tauntrand;
1281
1282         if(sample == "")
1283                 return;
1284
1285         tokenize_console(sample);
1286         n = stof(argv(1));
1287         if(n > 0)
1288                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1289         else
1290                 sample = strcat(argv(0), ".wav"); // randomization
1291
1292         switch(voicetype)
1293         {
1294                 case VOICETYPE_LASTATTACKER_ONLY:
1295                         if(self.pusher)
1296                         {
1297                                 msg_entity = self.pusher;
1298                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1299                                 {
1300                                         if(msg_entity.cvar_cl_voice_directional == 1)
1301                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1302                                         else
1303                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1304                                 }
1305                         }
1306                         break;
1307                 case VOICETYPE_LASTATTACKER:
1308                         if(self.pusher)
1309                         {
1310                                 msg_entity = self.pusher;
1311                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1312                                 {
1313                                         if(msg_entity.cvar_cl_voice_directional == 1)
1314                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1315                                         else
1316                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1317                                 }
1318                                 msg_entity = self;
1319                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1320                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1321                         }
1322                         break;
1323                 case VOICETYPE_TEAMRADIO:
1324                         FOR_EACH_REALCLIENT(msg_entity)
1325                                 if(!teamplay || msg_entity.team == self.team)
1326                                 {
1327                                         if(msg_entity.cvar_cl_voice_directional == 1)
1328                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1329                                         else
1330                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1331                                 }
1332                         break;
1333                 case VOICETYPE_AUTOTAUNT:
1334                         if(!sv_autotaunt)
1335                                 break;
1336                         if(!sv_taunt)
1337                                 break;
1338                         if(sv_gentle)
1339                                 break;
1340                         tauntrand = random();
1341                         FOR_EACH_REALCLIENT(msg_entity)
1342                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1343                                 {
1344                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1345                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1346                                         else
1347                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1348                                 }
1349                         break;
1350                 case VOICETYPE_TAUNT:
1351                         if(self.classname == "player")
1352                                 if(self.deadflag == DEAD_NO)
1353                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1354                         if(!sv_taunt)
1355                                 break;
1356                         if(sv_gentle)
1357                                 break;
1358                         FOR_EACH_REALCLIENT(msg_entity)
1359                         {
1360                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1361                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1362                                 else
1363                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1364                         }
1365                         break;
1366                 case VOICETYPE_PLAYERSOUND:
1367                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1368                         break;
1369                 default:
1370                         backtrace("Invalid voice type!");
1371                         break;
1372         }
1373 }
1374
1375 void PlayerSound(.string samplefield, float chan, float voicetype)
1376 {
1377         GlobalSound(self.samplefield, chan, voicetype);
1378 }
1379
1380 void VoiceMessage(string type, string msg)
1381 {
1382         var .string sample;
1383         float voicetype, ownteam;
1384         float flood;
1385         sample = GetVoiceMessageSampleField(type);
1386
1387         if(GetPlayerSoundSampleField_notFound)
1388         {
1389                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1390                 return;
1391         }
1392
1393         voicetype = GetVoiceMessageVoiceType(type);
1394         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1395
1396         flood = Say(self, ownteam, world, msg, 1);
1397
1398         if (flood > 0)
1399                 GlobalSound(self.sample, CH_VOICE, voicetype);
1400         else if (flood < 0)
1401                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1402 }
1403
1404 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1405 {
1406 //      show_message
1407 //      0 (00) automove centerprint, admin message
1408 //      1 (01) automove centerprint, no admin message
1409 //      2 (10) no centerprint, admin message
1410 //      3 (11) no centerprint, no admin message
1411
1412         float lockteams_backup;
1413
1414         lockteams_backup = lockteams;  // backup any team lock
1415
1416         lockteams = 0;  // disable locked teams
1417
1418         TeamchangeFrags(client);  // move the players frags
1419         SetPlayerColors(client, team_colour - 1);  // set the players colour
1420         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1421
1422         lockteams = lockteams_backup;  // restore the team lock
1423
1424         LogTeamchange(client.playerid, client.team, type);
1425
1426         if not(show_message & 1) // admin message
1427                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1428
1429         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1430 }