qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.v_angle = oldself.v_angle;
 159         self.avelocity = oldself.avelocity;
 160         self.classname = "body";
 161         self.damageforcescale = oldself.damageforcescale;
 162         self.effects = oldself.effects;
 163         self.glowmod = oldself.glowmod;
 164         self.event_damage = oldself.event_damage;
 165         self.anim_state = oldself.anim_state;
 166         self.anim_time = oldself.anim_time;
 167         self.anim_lower_action = oldself.anim_lower_action;
 168         self.anim_lower_time = oldself.anim_lower_time;
 169         self.anim_upper_action = oldself.anim_upper_action;
 170         self.anim_upper_time = oldself.anim_upper_time;
 171         self.anim_implicit_state = oldself.anim_implicit_state;
 172         self.anim_implicit_time = oldself.anim_implicit_time;
 173         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 174         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 175         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 176         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 177         self.dphitcontentsmask = oldself.dphitcontentsmask;
 178         self.death_time = oldself.death_time;
 179         self.pain_finished = oldself.pain_finished;
 180         self.health = oldself.health;
 181         self.armorvalue = oldself.armorvalue;
 182         self.armortype = oldself.armortype;
 183         self.model = oldself.model;
 184         self.modelindex = oldself.modelindex;
 185         self.skin = oldself.skin;
 186         self.species = oldself.species;
 187         self.movetype = oldself.movetype;
 188         self.solid = oldself.solid;
 189         self.ballistics_density = oldself.ballistics_density;
 190         self.takedamage = oldself.takedamage;
 191         self.customizeentityforclient = oldself.customizeentityforclient;
 192         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 193         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 194         if (keepvelocity == 1)
 195                 self.velocity = oldself.velocity;
 196         self.oldvelocity = self.velocity;
 197         self.alpha = oldself.alpha;
 198         self.fade_time = oldself.fade_time;
 199         self.fade_rate = oldself.fade_rate;
 200         //self.weapon = oldself.weapon;
 201         setorigin(self, oldself.origin);
 202         setsize(self, oldself.mins, oldself.maxs);
 203         self.prevorigin = oldself.origin;
 204         self.reset = SUB_Remove;
 205
 206         Drag_MoveDrag(oldself, self);
 207
 208         if(self.colormap <= maxclients && self.colormap > 0)
 209                 self.colormap = 1024 + oldself.clientcolors;
 210
 211         CSQCMODEL_AUTOINIT();
 212         self.CopyBody_nextthink = oldself.nextthink;
 213         self.CopyBody_think = oldself.think;
 214         self.nextthink = time;
 215         self.think = CopyBody_Think;
 216         // "bake" the current animation frame for clones (they don't get clientside animation)
 217         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 218
 219         self = oldself;
 220 }
 221
 222 float player_getspecies()
 223 {
 224         float s;
 225         get_model_parameters(self.model, self.skin);
 226         s = get_model_parameters_species;
 227         get_model_parameters(string_null, 0);
 228         if(s < 0)
 229                 return SPECIES_HUMAN;
 230         return s;
 231 }
 232
 233 void player_setupanimsformodel()
 234 {
 235         // load animation info
 236         animdecide_init(self);
 237         animdecide_setstate(self, 0, FALSE);
 238 }
 239
 240 void player_anim (void)
 241 {
 242         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 243         if(self.deadflag && !deadbits)
 244                 if(random() < 0.5)
 245                         deadbits = ANIMSTATE_DEAD1;
 246                 else
 247                         deadbits = ANIMSTATE_DEAD2;
 248         float animbits = deadbits;
 249         if(self.freezetag_frozen)
 250                 animbits |= ANIMSTATE_FROZEN;
 251         if(self.crouch)
 252                 animbits |= ANIMSTATE_DUCK;
 253         animdecide_setstate(self, animbits, FALSE);
 254         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 255
 256         if (self.weaponentity)
 257         {
 258                 updateanim(self.weaponentity);
 259                 if (!self.weaponentity.animstate_override)
 260                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 261         }
 262 }
 263
 264 void SpawnThrownWeapon (vector org, float w)
 265 {
 266         if(self.weapons & WepSet_FromWeapon(self.weapon))
 267                 if(W_IsWeaponThrowable(self.weapon))
 268                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 269 }
 270
 271 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 272 {
 273         float take, save;
 274         vector v;
 275         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 276
 277         // damage resistance (ignore most of the damage from a bullet or similar)
 278         damage = max(damage - 5, 1);
 279
 280         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 281         take = v_x;
 282         save = v_y;
 283
 284         if(sound_allowed(MSG_BROADCAST, attacker))
 285         {
 286                 if (save > 10)
 287                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 288                 else if (take > 30)
 289                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 290                 else if (take > 10)
 291                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 292         }
 293
 294         if (take > 50)
 295                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 296         if (take > 100)
 297                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 298
 299         if (!(self.flags & FL_GODMODE))
 300         {
 301                 self.armorvalue = self.armorvalue - save;
 302                 self.health = self.health - take;
 303                 // pause regeneration for 5 seconds
 304                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 305         }
 306         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 307         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 308         self.dmg_inflictor = inflictor;
 309
 310         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 311         {
 312                 // don't use any animations as a gib
 313                 self.frame = 0;
 314                 // view just above the floor
 315                 self.view_ofs = '0 0 4';
 316
 317                 Violence_GibSplash(self, 1, 1, attacker);
 318                 self.alpha = -1;
 319                 self.solid = SOLID_NOT; // restore later
 320                 self.takedamage = DAMAGE_NO; // restore later
 321                 self.damagedbycontents = FALSE;
 322         }
 323 }
 324
 325 // g_<gametype>_str:
 326 // If 0, default is used.
 327 // If <0, 0 is used.
 328 // Otherwise, g_str (default value) is used.
 329 // For consistency, negative values there are mapped to zero too.
 330 #define GAMETYPE_DEFAULTED_SETTING(str) \
 331         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 332          (gametype_setting_tmp < 0) ? 0 : \
 333          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 334          gametype_setting_tmp)
 335
 336
 337 void calculate_player_respawn_time()
 338 {
 339         float gametype_setting_tmp;
 340         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 341         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 342         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 343         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 344         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 345         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 346
 347         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 348         entity pl;
 349         if (teamplay)
 350         {
 351                 FOR_EACH_PLAYER(pl)
 352                         if (pl != self)
 353                                 if (pl.team == self.team)
 354                                         ++pcount;
 355                 if (sdelay_small_count == 0)
 356                         sdelay_small_count = 1;
 357                 if (sdelay_large_count == 0)
 358                         sdelay_large_count = 1;
 359         }
 360         else
 361         {
 362                 FOR_EACH_PLAYER(pl)
 363                         if (pl != self)
 364                                 ++pcount;
 365                 if (sdelay_small_count == 0)
 366                 {
 367                         if (g_cts)
 368                         {
 369                                 // Players play independently. No point in requiring enemies.
 370                                 sdelay_small_count = 1;
 371                         }
 372                         else
 373                         {
 374                                 // Players play AGAINST each other. Enemies required.
 375                                 sdelay_small_count = 2;
 376                         }
 377                 }
 378                 if (sdelay_large_count == 0)
 379                 {
 380                         if (g_cts)
 381                         {
 382                                 // Players play independently. No point in requiring enemies.
 383                                 sdelay_large_count = 1;
 384                         }
 385                         else
 386                         {
 387                                 // Players play AGAINST each other. Enemies required.
 388                                 sdelay_large_count = 2;
 389                         }
 390                 }
 391         }
 392
 393         float sdelay;
 394
 395         if (pcount <= sdelay_small_count)
 396                 sdelay = sdelay_small;
 397         else if (pcount >= sdelay_large_count)
 398                 sdelay = sdelay_large;
 399         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 400                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 401
 402         if(waves)
 403                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 404         else
 405                 self.respawn_time = time + sdelay;
 406
 407         if(sdelay < sdelay_max)
 408                 self.respawn_time_max = time + sdelay_max;
 409         else
 410                 self.respawn_time_max = self.respawn_time;
 411
 412         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 413                 self.respawn_countdown = 10; // first number to count down from is 10
 414         else
 415                 self.respawn_countdown = -1; // do not count down
 416
 417         if(g_cts || autocvar_g_forced_respawn)
 418                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 419 }
 420
 421 void ClientKill_Now_TeamChange();
 422
 423 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 424 {
 425         float take, save, dh, da, j;
 426         vector v;
 427         float valid_damage_for_weaponstats;
 428         float excess;
 429
 430         dh = max(self.health, 0);
 431         da = max(self.armorvalue, 0);
 432
 433         if(!DEATH_ISSPECIAL(deathtype))
 434         {
 435                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 436                 if(self != attacker)
 437                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 438         }
 439
 440         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 441         {
 442                 // tuba causes blood to come out of the ears
 443                 vector ear1, ear2;
 444                 vector d;
 445                 float f;
 446                 ear1 = self.origin;
 447                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 448                 ear2 = ear1;
 449                 makevectors(self.angles);
 450                 ear1 += v_right * -10;
 451                 ear2 += v_right * +10;
 452                 d = inflictor.origin - self.origin;
 453                 if (d)
 454                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 455                 else
 456                         f = 0;  // Assum ecenter.
 457                 force = v_right * vlen(force);
 458                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 459                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 460                 if(f > 0)
 461                 {
 462                         hitloc = ear1;
 463                         force = force * -1;
 464                 }
 465                 else
 466                 {
 467                         hitloc = ear2;
 468                         // force is already good
 469                 }
 470         }
 471         else
 472                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 473
 474
 475         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 476         take = v_x;
 477         save = v_y;
 478
 479         if(attacker == self)
 480         {
 481                 // don't reset pushltime for self damage as it may be an attempt to
 482                 // escape a lava pit or similar
 483                 //self.pushltime = 0;
 484                 self.istypefrag = 0;
 485         }
 486         else if(IS_PLAYER(attacker))
 487         {
 488                 self.pusher = attacker;
 489                 self.pushltime = time + autocvar_g_maxpushtime;
 490                 self.istypefrag = self.BUTTON_CHAT;
 491         }
 492         else if(time < self.pushltime)
 493         {
 494                 attacker = self.pusher;
 495                 self.pushltime = max(self.pushltime, time + 0.6);
 496         }
 497         else
 498         {
 499                 self.pushltime = 0;
 500                 self.istypefrag = 0;
 501         }
 502
 503         frag_inflictor = inflictor;
 504         frag_attacker = attacker;
 505         frag_target = self;
 506         frag_damage = damage;
 507         damage_take = take;
 508         damage_save = save;
 509         damage_force = force;
 510         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 511         take = bound(0, damage_take, self.health);
 512         save = bound(0, damage_save, self.armorvalue);
 513         excess = max(0, damage - take - save);
 514
 515         if(sound_allowed(MSG_BROADCAST, attacker))
 516         {
 517                 if (save > 10)
 518                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 519                 else if (take > 30)
 520                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 521                 else if (take > 10)
 522                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 523         }
 524
 525         if (take > 50)
 526                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 527         if (take > 100)
 528                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 529
 530         if (time >= self.spawnshieldtime)
 531         {
 532                 if (!(self.flags & FL_GODMODE))
 533                 {
 534                         self.armorvalue = self.armorvalue - save;
 535                         self.health = self.health - take;
 536                         // pause regeneration for 5 seconds
 537                         if(take)
 538                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 539
 540                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 541                         {
 542                                 self.pain_finished = time + 0.5;        //Supajoe
 543
 544                                 if(autocvar_sv_gentle < 1) {
 545                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 546                                         {
 547                                                 if (!self.animstate_override)
 548                                                 {
 549                                                         if (random() > 0.5)
 550                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 551                                                         else
 552                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 553                                                 }
 554                                         }
 555
 556                                         if(sound_allowed(MSG_BROADCAST, attacker))
 557                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 558                                         if(self.health > 1)
 559                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 560                                         {
 561                                                 if(deathtype == DEATH_FALL)
 562                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 563                                                 else if(self.health > 75) // TODO make a "gentle" version?
 564                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 565                                                 else if(self.health > 50)
 566                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 567                                                 else if(self.health > 25)
 568                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 569                                                 else
 570                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 571                                         }
 572                                 }
 573
 574                                 // throw off bot aim temporarily
 575                                 float shake;
 576                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 577                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 578                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 579                         }
 580                 }
 581                 else
 582                         self.max_armorvalue += (save + take);
 583         }
 584         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 585         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 586         self.dmg_inflictor = inflictor;
 587
 588         float abot, vbot, awep;
 589         abot = (IS_BOT_CLIENT(attacker));
 590         vbot = (IS_BOT_CLIENT(self));
 591
 592         valid_damage_for_weaponstats = 0;
 593         awep = 0;
 594
 595         if(vbot || IS_REAL_CLIENT(self))
 596         if(abot || IS_REAL_CLIENT(attacker))
 597         if(attacker && self != attacker)
 598         if(DIFF_TEAM(self, attacker))
 599         {
 600                 if(DEATH_ISSPECIAL(deathtype))
 601                         awep = attacker.weapon;
 602                 else
 603                         awep = DEATH_WEAPONOF(deathtype);
 604                 valid_damage_for_weaponstats = 1;
 605         }
 606
 607         if(valid_damage_for_weaponstats)
 608         {
 609                 dh = dh - max(self.health, 0);
 610                 da = da - max(self.armorvalue, 0);
 611                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 612         }
 613
 614         if (self.health < 1)
 615         {
 616                 float defer_ClientKill_Now_TeamChange;
 617                 defer_ClientKill_Now_TeamChange = FALSE;
 618
 619                 if(self.alivetime)
 620                 {
 621                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                         self.alivetime = 0;
 623                 }
 624
 625                 if(valid_damage_for_weaponstats)
 626                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 627
 628                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 629                 if(sound_allowed(MSG_BROADCAST, attacker))
 630                 {
 631                         if(deathtype == DEATH_DROWN)
 632                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 633                         else
 634                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 635                 }
 636
 637                 // get rid of kill indicator
 638                 if(self.killindicator)
 639                 {
 640                         remove(self.killindicator);
 641                         self.killindicator = world;
 642                         if(self.killindicator_teamchange)
 643                                 defer_ClientKill_Now_TeamChange = TRUE;
 644
 645                         if(self.classname == "body")
 646                         if(deathtype == DEATH_KILL)
 647                         {
 648                                 // for the lemmings fans, a small harmless explosion
 649                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 650                         }
 651                 }
 652
 653                 // print an obituary message
 654                 Obituary (attacker, inflictor, self, deathtype);
 655                 race_PreDie();
 656
 657         // increment frag counter for used weapon type
 658         float w;
 659         w = DEATH_WEAPONOF(deathtype);
 660         if(WEP_VALID(w))
 661         if(accuracy_isgooddamage(attacker, self))
 662         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 663
 664                 frag_attacker = attacker;
 665                 frag_inflictor = inflictor;
 666                 frag_target = self;
 667                 frag_deathtype = deathtype;
 668                 MUTATOR_CALLHOOK(PlayerDies);
 669
 670                 weapon_action(self.weapon, WR_PLAYERDEATH);
 671
 672                 RemoveGrapplingHook(self);
 673
 674                 Portal_ClearAllLater(self);
 675
 676                 if(IS_REAL_CLIENT(self))
 677                 {
 678                         self.fixangle = TRUE;
 679                         //msg_entity = self;
 680                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 681                         //WriteAngle (MSG_ONE, self.v_angle_x);
 682                         //WriteAngle (MSG_ONE, self.v_angle_y);
 683                         //WriteAngle (MSG_ONE, 80);
 684                 }
 685
 686                 if(defer_ClientKill_Now_TeamChange)
 687                         ClientKill_Now_TeamChange(); // can turn player into spectator
 688
 689                 // player could have been miraculously resuscitated ;)
 690                 // e.g. players in freezetag get frozen, they don't really die
 691                 if(self.health >= 1 || !IS_PLAYER(self))
 692                         return;
 693
 694                 // when we get here, player actually dies
 695
 696                 // clear waypoints
 697                 WaypointSprite_PlayerDead();
 698                 // throw a weapon
 699                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 700
 701                 // become fully visible
 702                 self.alpha = default_player_alpha;
 703                 // make the corpse upright (not tilted)
 704                 self.angles_x = 0;
 705                 self.angles_z = 0;
 706                 // don't spin
 707                 self.avelocity = '0 0 0';
 708                 // view from the floor
 709                 self.view_ofs = '0 0 -8';
 710                 // toss the corpse
 711                 self.movetype = MOVETYPE_TOSS;
 712                 // shootable corpse
 713                 self.solid = SOLID_CORPSE;
 714                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 715                 // don't stick to the floor
 716                 self.flags &= ~FL_ONGROUND;
 717                 // dying animation
 718                 self.deadflag = DEAD_DYING;
 719                 // when to allow respawn
 720                 calculate_player_respawn_time();
 721
 722                 self.death_time = time;
 723                 if (random() < 0.5)
 724                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 725                 else
 726                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 727                 if (self.maxs_z > 5)
 728                 {
 729                         self.maxs_z = 5;
 730                         setsize(self, self.mins, self.maxs);
 731                 }
 732                 // set damage function to corpse damage
 733                 self.event_damage = PlayerCorpseDamage;
 734                 // call the corpse damage function just in case it wants to gib
 735                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 736                 // set up to fade out later
 737                 SUB_SetFade (self, time + 6 + random (), 1);
 738
 739                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 740                         // remove corpse
 741                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 742                 }
 743
 744                 // reset fields the weapons may use just in case
 745                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 746                 {
 747                         weapon_action(j, WR_RESETPLAYER);
 748                         ATTACK_FINISHED_FOR(self, j) = 0;
 749                 }
 750         }
 751 }
 752
 753 .float muted; // to be used by prvm_edictset server playernumber muted 1
 754 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 755 // message "": do not say, just test flood control
 756 // return value:
 757 //   1 = accept
 758 //   0 = reject
 759 //  -1 = fake accept
 760 {
 761         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 762         float flood;
 763         var .float flood_field;
 764         entity head;
 765         float ret;
 766         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 767
 768         if(!teamsay && !privatesay)
 769                 if(substring(msgin, 0, 1) == " ")
 770                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 771
 772         msgin = formatmessage(msgin);
 773
 774         if (!IS_PLAYER(source))
 775                 colorstr = "^0"; // black for spectators
 776         else if(teamplay)
 777                 colorstr = Team_ColorCode(source.team);
 778         else
 779         {
 780                 colorstr = "";
 781                 teamsay = FALSE;
 782         }
 783
 784         if(intermission_running)
 785                 teamsay = FALSE;
 786
 787         if(msgin != "")
 788                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 789
 790         /*
 791          * using bprint solves this... me stupid
 792         // how can we prevent the message from appearing in a listen server?
 793         // for now, just give "say" back and only handle say_team
 794         if(!teamsay)
 795         {
 796                 clientcommand(self, strcat("say ", msgin));
 797                 return;
 798         }
 799         */
 800
 801         if(autocvar_g_chat_teamcolors)
 802                 namestr = playername(source);
 803         else
 804                 namestr = source.netname;
 805
 806         if(msgin != "")
 807         {
 808                 if(privatesay)
 809                 {
 810                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 811                         privatemsgprefixlen = strlen(msgstr);
 812                         msgstr = strcat(msgstr, msgin);
 813                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 814                         if(autocvar_g_chat_teamcolors)
 815                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 816                         else
 817                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 818                 }
 819                 else if(teamsay)
 820                 {
 821                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 822                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 823                 }
 824                 else
 825                 {
 826                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 827                         cmsgstr = "";
 828                 }
 829                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 830         }
 831         else
 832         {
 833                 msgstr = cmsgstr = "";
 834         }
 835
 836         fullmsgstr = msgstr;
 837         fullcmsgstr = cmsgstr;
 838
 839         // FLOOD CONTROL
 840         flood = 0;
 841         flood_field = floodcontrol_chat;
 842         if(floodcontrol)
 843         {
 844                 float flood_spl;
 845                 float flood_burst;
 846                 float flood_lmax;
 847                 float lines;
 848                 if(privatesay)
 849                 {
 850                         flood_spl = autocvar_g_chat_flood_spl_tell;
 851                         flood_burst = autocvar_g_chat_flood_burst_tell;
 852                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 853                         flood_field = floodcontrol_chattell;
 854                 }
 855                 else if(teamsay)
 856                 {
 857                         flood_spl = autocvar_g_chat_flood_spl_team;
 858                         flood_burst = autocvar_g_chat_flood_burst_team;
 859                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 860                         flood_field = floodcontrol_chatteam;
 861                 }
 862                 else
 863                 {
 864                         flood_spl = autocvar_g_chat_flood_spl;
 865                         flood_burst = autocvar_g_chat_flood_burst;
 866                         flood_lmax = autocvar_g_chat_flood_lmax;
 867                         flood_field = floodcontrol_chat;
 868                 }
 869                 flood_burst = max(0, flood_burst - 1);
 870                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 871
 872                 // do flood control for the default line size
 873                 if(msgstr != "")
 874                 {
 875                         getWrappedLine_remaining = msgstr;
 876                         msgstr = "";
 877                         lines = 0;
 878                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 879                         {
 880                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 881                                 ++lines;
 882                         }
 883                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 884
 885                         if(getWrappedLine_remaining != "")
 886                         {
 887                                 msgstr = strcat(msgstr, "\n");
 888                                 flood = 2;
 889                         }
 890
 891                         if(time >= source.flood_field)
 892                         {
 893                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 894                         }
 895                         else
 896                         {
 897                                 flood = 1;
 898                                 msgstr = fullmsgstr;
 899                         }
 900                 }
 901                 else
 902                 {
 903                         if(time >= source.flood_field)
 904                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 905                         else
 906                                 flood = 1;
 907                 }
 908
 909                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 910                         source.flood_field = flood = 0;
 911         }
 912
 913         if(flood == 2) // cannot happen for empty msgstr
 914         {
 915                 if(autocvar_g_chat_flood_notify_flooder)
 916                 {
 917                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 918                         sourcecmsgstr = "";
 919                 }
 920                 else
 921                 {
 922                         sourcemsgstr = fullmsgstr;
 923                         sourcecmsgstr = fullcmsgstr;
 924                 }
 925                 cmsgstr = "";
 926         }
 927         else
 928         {
 929                 sourcemsgstr = msgstr;
 930                 sourcecmsgstr = cmsgstr;
 931         }
 932
 933         if(!privatesay)
 934         if (!IS_PLAYER(source))
 935         {
 936                 if (!intermission_running)
 937                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 938                                 teamsay = -1; // spectators
 939         }
 940
 941         if(flood)
 942                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 943
 944         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 945         if(privatesay)
 946                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 947
 948         if(source.muted)
 949         {
 950                 // always fake the message
 951                 ret = -1;
 952         }
 953         else if(flood == 1)
 954         {
 955                 if(autocvar_g_chat_flood_notify_flooder)
 956                 {
 957                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 958                         ret = 0;
 959                 }
 960                 else
 961                         ret = -1;
 962         }
 963         else
 964         {
 965                 ret = 1;
 966         }
 967
 968         if(sourcemsgstr != "" && ret != 0)
 969         {
 970                 if(ret < 0) // faked message, because the player is muted
 971                 {
 972                         sprint(source, sourcemsgstr);
 973                         if(sourcecmsgstr != "" && !privatesay)
 974                                 centerprint(source, sourcecmsgstr);
 975                 }
 976                 else if(privatesay) // private message, between 2 people only
 977                 {
 978                         sprint(source, sourcemsgstr);
 979                         sprint(privatesay, msgstr);
 980                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 981                         if(cmsgstr != "")
 982                                 centerprint(privatesay, cmsgstr);
 983                 }
 984                 else if(teamsay > 0) // team message, only sent to team mates
 985                 {
 986                         sprint(source, sourcemsgstr);
 987                         dedicated_print(msgstr); // send to server console too
 988                         if(sourcecmsgstr != "")
 989                                 centerprint(source, sourcecmsgstr);
 990                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 991                                 if(head != source)
 992                                 {
 993                                         sprint(head, msgstr);
 994                                         if(cmsgstr != "")
 995                                                 centerprint(head, cmsgstr);
 996                                 }
 997                 }
 998                 else if(teamsay < 0) // spectator message, only sent to spectators
 999                 {
1000                         sprint(source, sourcemsgstr);
1001                         dedicated_print(msgstr); // send to server console too
1002                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
1003                                 if(head != source)
1004                                         sprint(head, msgstr);
1005                 }
1006                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1007                 {
1008                         sprint(source, sourcemsgstr);
1009                         dedicated_print(msgstr); // send to server console too
1010                         FOR_EACH_REALCLIENT(head)
1011                                 if(head != source)
1012                                         sprint(head, msgstr);
1013                 }
1014                 else
1015                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1016         }
1017
1018         return ret;
1019 }
1020
1021 float GetVoiceMessageVoiceType(string type)
1022 {
1023         if(type == "taunt")
1024                 return VOICETYPE_TAUNT;
1025         if(type == "teamshoot")
1026                 return VOICETYPE_LASTATTACKER;
1027         return VOICETYPE_TEAMRADIO;
1028 }
1029
1030 string allvoicesamples;
1031 .string GetVoiceMessageSampleField(string type)
1032 {
1033         GetPlayerSoundSampleField_notFound = 0;
1034         switch(type)
1035         {
1036 #define _VOICEMSG(m) case #m: return playersound_##m;
1037                 ALLVOICEMSGS
1038 #undef _VOICEMSG
1039         }
1040         GetPlayerSoundSampleField_notFound = 1;
1041         return playersound_taunt;
1042 }
1043
1044 .string GetPlayerSoundSampleField(string type)
1045 {
1046         GetPlayerSoundSampleField_notFound = 0;
1047         switch(type)
1048         {
1049 #define _VOICEMSG(m) case #m: return playersound_##m;
1050                 ALLPLAYERSOUNDS
1051 #undef _VOICEMSG
1052         }
1053         GetPlayerSoundSampleField_notFound = 1;
1054         return playersound_taunt;
1055 }
1056
1057 void PrecacheGlobalSound(string samplestring)
1058 {
1059         float n, i;
1060         tokenize_console(samplestring);
1061         n = stof(argv(1));
1062         if(n > 0)
1063         {
1064                 for(i = 1; i <= n; ++i)
1065                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1066         }
1067         else
1068         {
1069                 precache_sound(strcat(argv(0), ".wav"));
1070         }
1071 }
1072
1073 void PrecachePlayerSounds(string f)
1074 {
1075         float fh;
1076         string s;
1077         fh = fopen(f, FILE_READ);
1078         if(fh < 0)
1079                 return;
1080         while((s = fgets(fh)))
1081         {
1082                 if(tokenize_console(s) != 3)
1083                 {
1084                         dprint("Invalid sound info line: ", s, "\n");
1085                         continue;
1086                 }
1087                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1088         }
1089         fclose(fh);
1090
1091         if (!allvoicesamples)
1092         {
1093 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1094                 ALLVOICEMSGS
1095 #undef _VOICEMSG
1096                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1097         }
1098 }
1099
1100 void ClearPlayerSounds()
1101 {
1102 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1103         ALLPLAYERSOUNDS
1104         ALLVOICEMSGS
1105 #undef _VOICEMSG
1106 }
1107
1108 float LoadPlayerSounds(string f, float first)
1109 {
1110         float fh;
1111         string s;
1112         var .string field;
1113         fh = fopen(f, FILE_READ);
1114         if(fh < 0)
1115         {
1116                 dprint("Player sound file not found: ", f, "\n");
1117                 return 0;
1118         }
1119         while((s = fgets(fh)))
1120         {
1121                 if(tokenize_console(s) != 3)
1122                         continue;
1123                 field = GetPlayerSoundSampleField(argv(0));
1124                 if(GetPlayerSoundSampleField_notFound)
1125                         field = GetVoiceMessageSampleField(argv(0));
1126                 if(GetPlayerSoundSampleField_notFound)
1127                         continue;
1128                 if(self.field)
1129                         strunzone(self.field);
1130                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1131         }
1132         fclose(fh);
1133         return 1;
1134 }
1135
1136 .float modelindex_for_playersound;
1137 .float skin_for_playersound;
1138 void UpdatePlayerSounds()
1139 {
1140         if(self.modelindex == self.modelindex_for_playersound)
1141         if(self.skin == self.skin_for_playersound)
1142                 return;
1143         self.modelindex_for_playersound = self.modelindex;
1144         self.skin_for_playersound = self.skin;
1145         ClearPlayerSounds();
1146         LoadPlayerSounds("sound/player/default.sounds", 1);
1147         if(!autocvar_g_debug_defaultsounds)
1148                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1149                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1150 }
1151
1152 void FakeGlobalSound(string sample, float chan, float voicetype)
1153 {
1154         float n;
1155         float tauntrand;
1156
1157         if(sample == "")
1158                 return;
1159
1160         tokenize_console(sample);
1161         n = stof(argv(1));
1162         if(n > 0)
1163                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1164         else
1165                 sample = strcat(argv(0), ".wav"); // randomization
1166
1167         switch(voicetype)
1168         {
1169                 case VOICETYPE_LASTATTACKER_ONLY:
1170                         break;
1171                 case VOICETYPE_LASTATTACKER:
1172                         if(self.pusher)
1173                         {
1174                                 msg_entity = self;
1175                                 if(IS_REAL_CLIENT(msg_entity))
1176                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1177                         }
1178                         break;
1179                 case VOICETYPE_TEAMRADIO:
1180                         msg_entity = self;
1181                         if(msg_entity.cvar_cl_voice_directional == 1)
1182                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1183                         else
1184                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1185                         break;
1186                 case VOICETYPE_AUTOTAUNT:
1187                         if(!sv_autotaunt)
1188                                 break;
1189                         if(!sv_taunt)
1190                                 break;
1191                         if(autocvar_sv_gentle)
1192                                 break;
1193                         tauntrand = random();
1194                         msg_entity = self;
1195                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1196                         {
1197                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1198                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1199                                 else
1200                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1201                         }
1202                         break;
1203                 case VOICETYPE_TAUNT:
1204                         if(IS_PLAYER(self))
1205                                 if(self.deadflag == DEAD_NO)
1206                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1207                         if(!sv_taunt)
1208                                 break;
1209                         if(autocvar_sv_gentle)
1210                                 break;
1211                         msg_entity = self;
1212                         if (msg_entity.cvar_cl_voice_directional >= 1)
1213                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1214                         else
1215                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1216                         break;
1217                 case VOICETYPE_PLAYERSOUND:
1218                         msg_entity = self;
1219                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1220                         break;
1221                 default:
1222                         backtrace("Invalid voice type!");
1223                         break;
1224         }
1225 }
1226
1227 void GlobalSound(string sample, float chan, float voicetype)
1228 {
1229         float n;
1230         float tauntrand;
1231
1232         if(sample == "")
1233                 return;
1234
1235         tokenize_console(sample);
1236         n = stof(argv(1));
1237         if(n > 0)
1238                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1239         else
1240                 sample = strcat(argv(0), ".wav"); // randomization
1241
1242         switch(voicetype)
1243         {
1244                 case VOICETYPE_LASTATTACKER_ONLY:
1245                         if(self.pusher)
1246                         {
1247                                 msg_entity = self.pusher;
1248                                 if(IS_REAL_CLIENT(msg_entity))
1249                                 {
1250                                         if(msg_entity.cvar_cl_voice_directional == 1)
1251                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1252                                         else
1253                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1254                                 }
1255                         }
1256                         break;
1257                 case VOICETYPE_LASTATTACKER:
1258                         if(self.pusher)
1259                         {
1260                                 msg_entity = self.pusher;
1261                                 if(IS_REAL_CLIENT(msg_entity))
1262                                 {
1263                                         if(msg_entity.cvar_cl_voice_directional == 1)
1264                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1265                                         else
1266                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1267                                 }
1268                                 msg_entity = self;
1269                                 if(IS_REAL_CLIENT(msg_entity))
1270                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1271                         }
1272                         break;
1273                 case VOICETYPE_TEAMRADIO:
1274                         FOR_EACH_REALCLIENT(msg_entity)
1275                                 if(!teamplay || msg_entity.team == self.team)
1276                                 {
1277                                         if(msg_entity.cvar_cl_voice_directional == 1)
1278                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1279                                         else
1280                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1281                                 }
1282                         break;
1283                 case VOICETYPE_AUTOTAUNT:
1284                         if(!sv_autotaunt)
1285                                 break;
1286                         if(!sv_taunt)
1287                                 break;
1288                         if(autocvar_sv_gentle)
1289                                 break;
1290                         tauntrand = random();
1291                         FOR_EACH_REALCLIENT(msg_entity)
1292                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1293                                 {
1294                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1295                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1296                                         else
1297                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1298                                 }
1299                         break;
1300                 case VOICETYPE_TAUNT:
1301                         if(IS_PLAYER(self))
1302                                 if(self.deadflag == DEAD_NO)
1303                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1304                         if(!sv_taunt)
1305                                 break;
1306                         if(autocvar_sv_gentle)
1307                                 break;
1308                         FOR_EACH_REALCLIENT(msg_entity)
1309                         {
1310                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1311                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1312                                 else
1313                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1314                         }
1315                         break;
1316                 case VOICETYPE_PLAYERSOUND:
1317                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1318                         break;
1319                 default:
1320                         backtrace("Invalid voice type!");
1321                         break;
1322         }
1323 }
1324
1325 void PlayerSound(.string samplefield, float chan, float voicetype)
1326 {
1327         GlobalSound(self.samplefield, chan, voicetype);
1328 }
1329
1330 void VoiceMessage(string type, string msg)
1331 {
1332         var .string sample;
1333         float voicetype, ownteam;
1334         float flood;
1335         sample = GetVoiceMessageSampleField(type);
1336
1337         if(GetPlayerSoundSampleField_notFound)
1338         {
1339                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1340                 return;
1341         }
1342
1343         voicetype = GetVoiceMessageVoiceType(type);
1344         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1345
1346         flood = Say(self, ownteam, world, msg, 1);
1347
1348         if (flood > 0)
1349                 GlobalSound(self.sample, CH_VOICE, voicetype);
1350         else if (flood < 0)
1351                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1352 }
1353
1354 void MoveToTeam(entity client, float team_colour, float type)
1355 {
1356         float lockteams_backup;
1357
1358         lockteams_backup = lockteams;  // backup any team lock
1359
1360         lockteams = 0;  // disable locked teams
1361
1362         TeamchangeFrags(client);  // move the players frags
1363         SetPlayerColors(client, team_colour - 1);  // set the players colour
1364         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1365
1366         lockteams = lockteams_backup;  // restore the team lock
1367
1368         LogTeamchange(client.playerid, client.team, type);
1369 }