qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.iscreature = oldself.iscreature;
 138         self.damagedbycontents = oldself.damagedbycontents;
 139         self.angles = oldself.angles;
 140         self.avelocity = oldself.avelocity;
 141         self.classname = "body";
 142         self.damageforcescale = oldself.damageforcescale;
 143         self.effects = oldself.effects;
 144         self.glowmod = oldself.glowmod;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.skin = oldself.skin;
 162         self.species = oldself.species;
 163         self.movetype = oldself.movetype;
 164         self.nextthink = oldself.nextthink;
 165         self.solid = oldself.solid;
 166         self.ballistics_density = oldself.ballistics_density;
 167         self.takedamage = oldself.takedamage;
 168         self.think = oldself.think;
 169         self.customizeentityforclient = oldself.customizeentityforclient;
 170         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 171         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 172         if (keepvelocity == 1)
 173                 self.velocity = oldself.velocity;
 174         self.oldvelocity = self.velocity;
 175         self.fade_time = oldself.fade_time;
 176         self.fade_rate = oldself.fade_rate;
 177         //self.weapon = oldself.weapon;
 178         setorigin(self, oldself.origin);
 179         setsize(self, oldself.mins, oldself.maxs);
 180         self.prevorigin = oldself.origin;
 181         self.reset = SUB_Remove;
 182
 183         Drag_MoveDrag(oldself, self);
 184
 185         if(self.colormap <= maxclients && self.colormap > 0)
 186                 self.colormap = 1024 + self.clientcolors;
 187
 188         CSQCMODEL_AUTOINIT();
 189
 190         self = oldself;
 191 }
 192
 193 float player_getspecies()
 194 {
 195         float s;
 196         get_model_parameters(self.model, self.skin);
 197         s = get_model_parameters_species;
 198         get_model_parameters(string_null, 0);
 199         if(s < 0)
 200                 return SPECIES_HUMAN;
 201         return s;
 202 }
 203
 204 void player_setupanimsformodel()
 205 {
 206         // defaults for legacy .zym models without animinfo files
 207         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 208         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 209         self.anim_draw = animfixfps(self, '2 1 3');
 210         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 211         self.anim_duckwalk = animfixfps(self, '4 1 1');
 212         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 213         self.anim_duckidle = animfixfps(self, '6 1 1');
 214         self.anim_idle = animfixfps(self, '7 1 1');
 215         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 216         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 217         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 218         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 219         self.anim_taunt = animfixfps(self, '12 1 0.33');
 220         self.anim_run = animfixfps(self, '13 1 1');
 221         self.anim_runbackwards = animfixfps(self, '14 1 1');
 222         self.anim_strafeleft = animfixfps(self, '15 1 1');
 223         self.anim_straferight = animfixfps(self, '16 1 1');
 224         self.anim_dead1 = animfixfps(self, '17 1 1');
 225         self.anim_dead2 = animfixfps(self, '18 1 1');
 226         self.anim_forwardright = animfixfps(self, '19 1 1');
 227         self.anim_forwardleft = animfixfps(self, '20 1 1');
 228         self.anim_backright = animfixfps(self, '21 1 1');
 229         self.anim_backleft  = animfixfps(self, '22 1 1');
 230         self.anim_melee = animfixfps(self, '23 1 1');
 231         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 232         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 233         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 234         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 235         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 236         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 237         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 238         // TODO introspect models for finding right "fps" value (1/duration)
 239         // reset animstate now
 240         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 241 }
 242
 243 void player_anim (void)
 244 {
 245         updateanim(self);
 246         if (self.weaponentity)
 247                 updateanim(self.weaponentity);
 248
 249         if (self.deadflag != DEAD_NO)
 250         {
 251                 if (time > self.animstate_endtime)
 252                 {
 253                         if (self.maxs_z > 5)
 254                         {
 255                                 self.maxs_z = 5;
 256                                 setsize(self, self.mins, self.maxs);
 257                         }
 258                         self.frame = self.dead_frame;
 259                 }
 260                 return;
 261         }
 262
 263         if (!self.animstate_override)
 264         {
 265                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 266                 {
 267                         if (self.crouch)
 268                         {
 269                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 270                                 {
 271                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 272                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 273                                         {
 274                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 275                                                 self.restart_jump = FALSE;
 276                                         }
 277                                 }
 278                         }
 279                         else
 280                         {
 281                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 282                 {
 283                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 284                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 285                     {
 286                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 287                         self.restart_jump = FALSE;
 288                     }
 289                 }
 290                         }
 291                 }
 292                 else if (self.crouch)
 293                 {
 294                         if (self.movement_x > 0 && self.movement_y == 0)
 295                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 296                         else if (self.movement_x < 0 && self.movement_y == 0)
 297                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 298                         else if (self.movement_x == 0 && self.movement_y > 0)
 299                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 300                         else if (self.movement_x == 0 && self.movement_y < 0)
 301                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 302                         else if (self.movement_x > 0 && self.movement_y > 0)
 303                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 304                         else if (self.movement_x > 0 && self.movement_y < 0)
 305                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 306                         else if (self.movement_x < 0 && self.movement_y > 0)
 307                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 308                         else if (self.movement_x < 0 && self.movement_y < 0)
 309                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 310                         else
 311                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 312                 }
 313                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 314                 {
 315                         if (self.movement_x > 0 && self.movement_y == 0)
 316                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y == 0)
 318                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x == 0 && self.movement_y > 0)
 320                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x == 0 && self.movement_y < 0)
 322                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 323                         else if (self.movement_x > 0 && self.movement_y > 0)
 324                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 325                         else if (self.movement_x > 0 && self.movement_y < 0)
 326                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 327                         else if (self.movement_x < 0 && self.movement_y > 0)
 328                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 329                         else if (self.movement_x < 0 && self.movement_y < 0)
 330                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 331                         else
 332                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 333                 }
 334                 else
 335                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 336         }
 337
 338         if (self.weaponentity)
 339         if (!self.weaponentity.animstate_override)
 340                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 341 }
 342
 343 void SpawnThrownWeapon (vector org, float w)
 344 {
 345         if(g_minstagib)
 346         if(self.ammo_cells <= 0)
 347                 return;
 348
 349         if(g_pinata)
 350         {
 351                 float j;
 352                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 353                 {
 354                         if(self.weapons & W_WeaponBit(j))
 355                                 if(W_IsWeaponThrowable(j))
 356                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 357                 }
 358         }
 359         else
 360         {
 361                 if(W_IsWeaponThrowable(self.weapon))
 362                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 363         }
 364 }
 365
 366 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 367 {
 368         float take, save;
 369         vector v;
 370         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 371
 372         // damage resistance (ignore most of the damage from a bullet or similar)
 373         damage = max(damage - 5, 1);
 374
 375         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 376         take = v_x;
 377         save = v_y;
 378
 379         if(sound_allowed(MSG_BROADCAST, attacker))
 380         {
 381                 if (save > 10)
 382                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 383                 else if (take > 30)
 384                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 385                 else if (take > 10)
 386                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 387         }
 388
 389         if (take > 50)
 390                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 391         if (take > 100)
 392                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 393
 394         if (!(self.flags & FL_GODMODE))
 395         {
 396                 self.armorvalue = self.armorvalue - save;
 397                 self.health = self.health - take;
 398                 // pause regeneration for 5 seconds
 399                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 400         }
 401         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 402         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 403         self.dmg_inflictor = inflictor;
 404
 405         if (self.health <= -autocvar_sv_gibhealth && !(self.effects & CSQCMODEL_EF_INVISIBLE))
 406         {
 407                 // don't use any animations as a gib
 408                 self.frame = 0;
 409                 self.dead_frame = 0;
 410                 // view just above the floor
 411                 self.view_ofs = '0 0 4';
 412
 413                 Violence_GibSplash(self, 1, 1, attacker);
 414                 self.effects |= CSQCMODEL_EF_INVISIBLE;
 415                 self.solid = SOLID_NOT; // restore later
 416         }
 417 }
 418
 419 void ClientKill_Now_TeamChange();
 420 void freezetag_CheckWinner();
 421
 422 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 423 {
 424         float take, save, waves, sdelay, dh, da, j;
 425         vector v;
 426         float valid_damage_for_weaponstats;
 427         float excess;
 428
 429         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 430                 return;
 431
 432         dh = max(self.health, 0);
 433         da = max(self.armorvalue, 0);
 434
 435         if(!DEATH_ISSPECIAL(deathtype))
 436         {
 437                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 438                 if(self != attacker)
 439                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 440         }
 441
 442         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 443         {
 444                 // tuba causes blood to come out of the ears
 445                 vector ear1, ear2;
 446                 vector d;
 447                 float f;
 448                 ear1 = self.origin;
 449                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 450                 ear2 = ear1;
 451                 makevectors(self.angles);
 452                 ear1 += v_right * -10;
 453                 ear2 += v_right * +10;
 454                 d = inflictor.origin - self.origin;
 455                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 456                 force = v_right * vlen(force);
 457                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 458                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 459                 if(f > 0)
 460                 {
 461                         hitloc = ear1;
 462                         force = force * -1;
 463                 }
 464                 else
 465                 {
 466                         hitloc = ear2;
 467                         // force is already good
 468                 }
 469         }
 470         else
 471                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 472
 473         if (!g_minstagib)
 474         {
 475                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 476                 take = v_x;
 477                 save = v_y;
 478         }
 479         else
 480         {
 481                 save = 0;
 482                 take = damage;
 483         }
 484
 485         frag_inflictor = inflictor;
 486         frag_attacker = attacker;
 487         frag_target = self;
 488         damage_take = take;
 489         damage_save = save;
 490         damage_force = force;
 491         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 492         take = bound(0, damage_take, self.health);
 493         save = bound(0, damage_save, self.armorvalue);
 494         excess = max(0, damage - take - save);
 495
 496         if(sound_allowed(MSG_BROADCAST, attacker))
 497         {
 498                 if (save > 10)
 499                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 500                 else if (take > 30)
 501                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 502                 else if (take > 10)
 503                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 504         }
 505
 506         if (take > 50)
 507                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 508         if (take > 100)
 509                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 510
 511         if (time >= self.spawnshieldtime)
 512         {
 513                 if (!(self.flags & FL_GODMODE))
 514                 {
 515                         self.armorvalue = self.armorvalue - save;
 516                         self.health = self.health - take;
 517                         // pause regeneration for 5 seconds
 518                         if(take)
 519                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 520
 521                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 522                         {
 523                                 self.pain_finished = time + 0.5;        //Supajoe
 524
 525                                 if(sv_gentle < 1) {
 526                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 527                                         {
 528                                                 if (!self.animstate_override)
 529                                                 {
 530                                                         if (random() > 0.5)
 531                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 532                                                         else
 533                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 534                                                 }
 535                                         }
 536
 537                                         if(sound_allowed(MSG_BROADCAST, attacker))
 538                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 539                                         if(self.health > 1)
 540                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 541                                         {
 542                                                 if(deathtype == DEATH_FALL)
 543                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 544                                                 else if(self.health > 75) // TODO make a "gentle" version?
 545                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 546                                                 else if(self.health > 50)
 547                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 548                                                 else if(self.health > 25)
 549                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 550                                                 else
 551                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 552                                         }
 553                                 }
 554
 555                                 // throw off bot aim temporarily
 556                                 float shake;
 557                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 558                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 559                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 560                         }
 561                 }
 562                 else
 563                         self.max_armorvalue += (save + take);
 564         }
 565         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 566         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 567         self.dmg_inflictor = inflictor;
 568
 569         if(attacker == self)
 570         {
 571                 // don't reset pushltime for self damage as it may be an attempt to
 572                 // escape a lava pit or similar
 573                 //self.pushltime = 0;
 574         }
 575         else if(attacker.classname == "player")
 576         {
 577                 self.pusher = attacker;
 578                 self.pushltime = time + autocvar_g_maxpushtime;
 579         }
 580         else if(time < self.pushltime)
 581         {
 582                 attacker = self.pusher;
 583                 self.pushltime = max(self.pushltime, time + 0.6);
 584         }
 585         else
 586                 self.pushltime = 0;
 587
 588         float abot, vbot, awep;
 589         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 590         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 591
 592         valid_damage_for_weaponstats = 0;
 593         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 594         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 595         if(attacker && self != attacker)
 596         if(IsDifferentTeam(self, attacker))
 597         {
 598                 if(DEATH_ISSPECIAL(deathtype))
 599                         awep = attacker.weapon;
 600                 else
 601                         awep = DEATH_WEAPONOF(deathtype);
 602                 valid_damage_for_weaponstats = 1;
 603         }
 604
 605         if(valid_damage_for_weaponstats)
 606         {
 607                 dh = dh - max(self.health, 0);
 608                 da = da - max(self.armorvalue, 0);
 609                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 610         }
 611
 612         if (self.health < 1)
 613         {
 614                 float defer_ClientKill_Now_TeamChange;
 615                 defer_ClientKill_Now_TeamChange = FALSE;
 616
 617                 if(self.alivetime)
 618                 {
 619                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 620                         self.alivetime = 0;
 621                 }
 622
 623                 if(valid_damage_for_weaponstats)
 624                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 625
 626                 if(sv_gentle < 1) // TODO make a "gentle" version?
 627                 if(sound_allowed(MSG_BROADCAST, attacker))
 628                 {
 629                         if(deathtype == DEATH_DROWN)
 630                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 631                         else
 632                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 633                 }
 634
 635                 // get rid of kill indicator
 636                 if(self.killindicator)
 637                 {
 638                         remove(self.killindicator);
 639                         self.killindicator = world;
 640                         if(self.killindicator_teamchange)
 641                                 defer_ClientKill_Now_TeamChange = TRUE;
 642
 643                         if(self.classname == "body")
 644                         if(deathtype == DEATH_KILL)
 645                         {
 646                                 // for the lemmings fans, a small harmless explosion
 647                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 648                         }
 649                 }
 650
 651                 if(!g_freezetag)
 652                 {
 653                         // become fully visible
 654                         self.alpha = 1;
 655                         // throw a weapon
 656                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 657                 }
 658
 659                 // print an obituary message
 660                 Obituary (attacker, inflictor, self, deathtype);
 661                 race_PreDie();
 662                 DropAllRunes(self);
 663
 664         // increment frag counter for used weapon type
 665         float w;
 666         w = DEATH_WEAPONOF(deathtype);
 667         if(WEP_VALID(w))
 668         if(accuracy_isgooddamage(attacker, self))
 669         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 670
 671                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 672                 {
 673                         PutClientInServer();
 674                         count_alive_players(); // re-count players
 675                         freezetag_CheckWinner();
 676                         return;
 677                 }
 678
 679                 frag_attacker = attacker;
 680                 frag_inflictor = inflictor;
 681                 frag_target = self;
 682                 MUTATOR_CALLHOOK(PlayerDies);
 683                 weapon_action(self.weapon, WR_PLAYERDEATH);
 684
 685                 RemoveGrapplingHook(self);
 686
 687                 if(self.flagcarried)
 688                 {
 689                         if(attacker.classname != "player")
 690                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 691                         else if(attacker.team == self.team)
 692                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 693                         else
 694                                 DropFlag(self.flagcarried, world, attacker);
 695                 }
 696                 if(self.ballcarried && g_nexball)
 697                         DropBall(self.ballcarried, self.origin, self.velocity);
 698                 Portal_ClearAllLater(self);
 699
 700                 if(clienttype(self) == CLIENTTYPE_REAL)
 701                 {
 702                         stuffcmd(self, "-zoom\n");
 703                         self.fixangle = TRUE;
 704                         //msg_entity = self;
 705                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 706                         //WriteAngle (MSG_ONE, self.v_angle_x);
 707                         //WriteAngle (MSG_ONE, self.v_angle_y);
 708                         //WriteAngle (MSG_ONE, 80);
 709                 }
 710
 711                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 712                         ClientKill_Now_TeamChange();
 713
 714                 if(g_arena)
 715                         Spawnqueue_Unmark(self);
 716
 717                 if(g_freezetag)
 718                         return;
 719
 720                 // when we get here, player actually dies
 721                 // clear waypoints (do this AFTER FreezeTag)
 722                 WaypointSprite_PlayerDead();
 723
 724                 // make the corpse upright (not tilted)
 725                 self.angles_x = 0;
 726                 self.angles_z = 0;
 727                 // don't spin
 728                 self.avelocity = '0 0 0';
 729                 // view from the floor
 730                 self.view_ofs = '0 0 -8';
 731                 // toss the corpse
 732                 self.movetype = MOVETYPE_TOSS;
 733                 // shootable corpse
 734                 self.solid = SOLID_CORPSE;
 735                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 736                 // don't stick to the floor
 737                 self.flags &~= FL_ONGROUND;
 738                 // dying animation
 739                 self.deadflag = DEAD_DYING;
 740                 // when to allow respawn
 741                 sdelay = 0;
 742                 waves = 0;
 743                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 744                 if(!sdelay)
 745                 {
 746                         if(g_cts)
 747                                 sdelay = 0; // no respawn delay in CTS
 748                         else
 749                                 sdelay = autocvar_g_respawn_delay;
 750                 }
 751                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 752                 if(!waves)
 753                         waves = autocvar_g_respawn_waves;
 754                 if(waves)
 755                         self.death_time = ceil((time + sdelay) / waves) * waves;
 756                 else
 757                         self.death_time = time + sdelay;
 758                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 759                         self.respawn_countdown = 10; // first number to count down from is 10
 760                 else
 761                         self.respawn_countdown = -1; // do not count down
 762                 if (random() < 0.5)
 763                 {
 764                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 765                         self.dead_frame = self.anim_dead1_x;
 766                 }
 767                 else
 768                 {
 769                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 770                         self.dead_frame = self.anim_dead2_x;
 771                 }
 772                 // set damage function to corpse damage
 773                 self.event_damage = PlayerCorpseDamage;
 774                 // call the corpse damage function just in case it wants to gib
 775                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 776                 // set up to fade out later
 777                 SUB_SetFade (self, time + 6 + random (), 1);
 778
 779                 if(sv_gentle > 0 || autocvar_ekg) {
 780                         // remove corpse
 781                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 782                 }
 783
 784                 // reset fields the weapons may use just in case
 785                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 786                 {
 787                         weapon_action(j, WR_RESETPLAYER);
 788                         ATTACK_FINISHED_FOR(self, j) = 0;
 789                 }
 790         }
 791 }
 792
 793 .float muted; // to be used by prvm_edictset server playernumber muted 1
 794 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 795 // message "": do not say, just test flood control
 796 // return value:
 797 //   1 = accept
 798 //   0 = reject
 799 //  -1 = fake accept
 800 {
 801         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 802         float flood, privatemsgprefixlen;
 803         var .float flood_field;
 804         entity head;
 805         float ret;
 806
 807         if(Ban_MaybeEnforceBan(source))
 808                 return 0;
 809
 810         if(!teamsay && !privatesay)
 811                 if(substring(msgin, 0, 1) == " ")
 812                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 813
 814         msgin = formatmessage(msgin);
 815
 816         if(source.classname != "player")
 817                 colorstr = "^0"; // black for spectators
 818         else if(teamplay)
 819                 colorstr = Team_ColorCode(source.team);
 820         else
 821                 teamsay = FALSE;
 822
 823         if(intermission_running)
 824                 teamsay = FALSE;
 825
 826         if(msgin != "")
 827                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 828
 829         /*
 830          * using bprint solves this... me stupid
 831         // how can we prevent the message from appearing in a listen server?
 832         // for now, just give "say" back and only handle say_team
 833         if(!teamsay)
 834         {
 835                 clientcommand(self, strcat("say ", msgin));
 836                 return;
 837         }
 838         */
 839
 840         if(autocvar_g_chat_teamcolors)
 841                 namestr = playername(source);
 842         else
 843                 namestr = source.netname;
 844
 845         if(msgin != "")
 846         {
 847                 if(privatesay)
 848                 {
 849                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 850                         privatemsgprefixlen = strlen(msgstr);
 851                         msgstr = strcat(msgstr, msgin);
 852                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 853                         if(autocvar_g_chat_teamcolors)
 854                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 855                         else
 856                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 857                 }
 858                 else if(teamsay)
 859                 {
 860                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 861                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 862                 }
 863                 else
 864                 {
 865                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 866                         cmsgstr = "";
 867                 }
 868                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 869         }
 870         else
 871         {
 872                 msgstr = cmsgstr = "";
 873         }
 874
 875         fullmsgstr = msgstr;
 876         fullcmsgstr = cmsgstr;
 877
 878         // FLOOD CONTROL
 879         flood = 0;
 880         if(floodcontrol)
 881         {
 882                 float flood_spl;
 883                 float flood_burst;
 884                 float flood_lmax;
 885                 float lines;
 886                 if(privatesay)
 887                 {
 888                         flood_spl = autocvar_g_chat_flood_spl_tell;
 889                         flood_burst = autocvar_g_chat_flood_burst_tell;
 890                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 891                         flood_field = floodcontrol_chattell;
 892                 }
 893                 else if(teamsay)
 894                 {
 895                         flood_spl = autocvar_g_chat_flood_spl_team;
 896                         flood_burst = autocvar_g_chat_flood_burst_team;
 897                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 898                         flood_field = floodcontrol_chatteam;
 899                 }
 900                 else
 901                 {
 902                         flood_spl = autocvar_g_chat_flood_spl;
 903                         flood_burst = autocvar_g_chat_flood_burst;
 904                         flood_lmax = autocvar_g_chat_flood_lmax;
 905                         flood_field = floodcontrol_chat;
 906                 }
 907                 flood_burst = max(0, flood_burst - 1);
 908                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 909
 910                 // do flood control for the default line size
 911                 if(msgstr != "")
 912                 {
 913                         getWrappedLine_remaining = msgstr;
 914                         msgstr = "";
 915                         lines = 0;
 916                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 917                         {
 918                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 919                                 ++lines;
 920                         }
 921                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 922
 923                         if(getWrappedLine_remaining != "")
 924                         {
 925                                 msgstr = strcat(msgstr, "\n");
 926                                 flood = 2;
 927                         }
 928
 929                         if(time >= source.flood_field)
 930                         {
 931                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 932                         }
 933                         else
 934                         {
 935                                 flood = 1;
 936                                 msgstr = fullmsgstr;
 937                         }
 938                 }
 939                 else
 940                 {
 941                         if(time >= source.flood_field)
 942                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 943                         else
 944                                 flood = 1;
 945                 }
 946
 947                 if (timeoutStatus == 2) //when game is paused, no flood protection
 948                         source.flood_field = flood = 0;
 949         }
 950
 951         if(flood == 2) // cannot happen for empty msgstr
 952         {
 953                 if(autocvar_g_chat_flood_notify_flooder)
 954                 {
 955                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 956                         sourcecmsgstr = "";
 957                 }
 958                 else
 959                 {
 960                         sourcemsgstr = fullmsgstr;
 961                         sourcecmsgstr = fullcmsgstr;
 962                 }
 963                 cmsgstr = "";
 964         }
 965         else
 966         {
 967                 sourcemsgstr = msgstr;
 968                 sourcecmsgstr = cmsgstr;
 969         }
 970
 971         if(!privatesay)
 972         if(source.classname != "player")
 973         {
 974                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 975                         teamsay = -1; // spectators
 976         }
 977
 978         if(flood)
 979                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 980
 981         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 982         if(privatesay)
 983                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 984
 985         if(source.muted)
 986         {
 987                 // always fake the message
 988                 ret = -1;
 989         }
 990         else if(flood == 1)
 991         {
 992                 if(autocvar_g_chat_flood_notify_flooder)
 993                 {
 994                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 995                         ret = 0;
 996                 }
 997                 else
 998                         ret = -1;
 999         }
1000         else
1001         {
1002                 ret = 1;
1003         }
1004
1005         if(sourcemsgstr != "" && ret != 0)
1006         {
1007                 if(ret < 0) // fake
1008                 {
1009                         sprint(source, sourcemsgstr);
1010                         if(sourcecmsgstr != "" && !privatesay)
1011                                 centerprint(source, sourcecmsgstr);
1012                 }
1013                 else if(privatesay)
1014                 {
1015                         sprint(source, sourcemsgstr);
1016                         sprint(privatesay, msgstr);
1017                         if(cmsgstr != "")
1018                                 centerprint(privatesay, cmsgstr);
1019                 }
1020                 else if(teamsay > 0)
1021                 {
1022                         sprint(source, sourcemsgstr);
1023                         if(sourcecmsgstr != "")
1024                                 centerprint(source, sourcecmsgstr);
1025                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1026                                 if(head != source)
1027                                 {
1028                                         sprint(head, msgstr);
1029                                         if(cmsgstr != "")
1030                                                 centerprint(head, cmsgstr);
1031                                 }
1032                 }
1033                 else if(teamsay < 0)
1034                 {
1035                         sprint(source, sourcemsgstr);
1036                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1037                                 if(head != source)
1038                                         sprint(head, msgstr);
1039                 }
1040                 else if(sourcemsgstr != msgstr)
1041                 {
1042                         sprint(source, sourcemsgstr);
1043                         FOR_EACH_REALCLIENT(head)
1044                                 if(head != source)
1045                                         sprint(head, msgstr);
1046                 }
1047                 else
1048                         bprint(msgstr);
1049         }
1050
1051         return ret;
1052 }
1053
1054 float GetVoiceMessageVoiceType(string type)
1055 {
1056         if(type == "taunt")
1057                 return VOICETYPE_TAUNT;
1058         if(type == "teamshoot")
1059                 return VOICETYPE_LASTATTACKER;
1060         return VOICETYPE_TEAMRADIO;
1061 }
1062
1063 string allvoicesamples;
1064 .string GetVoiceMessageSampleField(string type)
1065 {
1066         GetPlayerSoundSampleField_notFound = 0;
1067         switch(type)
1068         {
1069 #define _VOICEMSG(m) case #m: return playersound_##m;
1070                 ALLVOICEMSGS
1071 #undef _VOICEMSG
1072         }
1073         GetPlayerSoundSampleField_notFound = 1;
1074         return playersound_taunt;
1075 }
1076
1077 .string GetPlayerSoundSampleField(string type)
1078 {
1079         GetPlayerSoundSampleField_notFound = 0;
1080         switch(type)
1081         {
1082 #define _VOICEMSG(m) case #m: return playersound_##m;
1083                 ALLPLAYERSOUNDS
1084 #undef _VOICEMSG
1085         }
1086         GetPlayerSoundSampleField_notFound = 1;
1087         return playersound_taunt;
1088 }
1089
1090 void PrecacheGlobalSound(string samplestring)
1091 {
1092         float n, i;
1093         tokenize_console(samplestring);
1094         n = stof(argv(1));
1095         if(n > 0)
1096         {
1097                 for(i = 1; i <= n; ++i)
1098                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1099         }
1100         else
1101         {
1102                 precache_sound(strcat(argv(0), ".wav"));
1103         }
1104 }
1105
1106 void PrecachePlayerSounds(string f)
1107 {
1108         float fh;
1109         string s;
1110         fh = fopen(f, FILE_READ);
1111         if(fh < 0)
1112                 return;
1113         while((s = fgets(fh)))
1114         {
1115                 if(tokenize_console(s) != 3)
1116                 {
1117                         dprint("Invalid sound info line: ", s, "\n");
1118                         continue;
1119                 }
1120                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1121         }
1122         fclose(fh);
1123
1124         if not(allvoicesamples)
1125         {
1126 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1127                 ALLVOICEMSGS
1128 #undef _VOICEMSG
1129                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1130         }
1131 }
1132
1133 void ClearPlayerSounds()
1134 {
1135 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1136         ALLPLAYERSOUNDS
1137         ALLVOICEMSGS
1138 #undef _VOICEMSG
1139 }
1140
1141 float LoadPlayerSounds(string f, float first)
1142 {
1143         float fh;
1144         string s;
1145         var .string field;
1146         fh = fopen(f, FILE_READ);
1147         if(fh < 0)
1148         {
1149                 dprint("Player sound file not found: ", f, "\n");
1150                 return 0;
1151         }
1152         while((s = fgets(fh)))
1153         {
1154                 if(tokenize_console(s) != 3)
1155                         continue;
1156                 field = GetPlayerSoundSampleField(argv(0));
1157                 if(GetPlayerSoundSampleField_notFound)
1158                         field = GetVoiceMessageSampleField(argv(0));
1159                 if(GetPlayerSoundSampleField_notFound)
1160                         continue;
1161                 if(self.field)
1162                         strunzone(self.field);
1163                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1164         }
1165         fclose(fh);
1166         return 1;
1167 }
1168
1169 .float modelindex_for_playersound;
1170 .float skin_for_playersound;
1171 void UpdatePlayerSounds()
1172 {
1173         if(self.modelindex == self.modelindex_for_playersound)
1174         if(self.skin == self.skin_for_playersound)
1175                 return;
1176         self.modelindex_for_playersound = self.modelindex;
1177         self.skin_for_playersound = self.skin;
1178         ClearPlayerSounds();
1179         LoadPlayerSounds("sound/player/default.sounds", 1);
1180         if(!autocvar_g_debug_defaultsounds)
1181                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1182                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1183 }
1184
1185 void FakeGlobalSound(string sample, float chan, float voicetype)
1186 {
1187         float n;
1188         float tauntrand;
1189
1190         if(sample == "")
1191                 return;
1192
1193         tokenize_console(sample);
1194         n = stof(argv(1));
1195         if(n > 0)
1196                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1197         else
1198                 sample = strcat(argv(0), ".wav"); // randomization
1199
1200         switch(voicetype)
1201         {
1202                 case VOICETYPE_LASTATTACKER_ONLY:
1203                         break;
1204                 case VOICETYPE_LASTATTACKER:
1205                         if(self.pusher)
1206                         {
1207                                 msg_entity = self;
1208                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1209                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1210                         }
1211                         break;
1212                 case VOICETYPE_TEAMRADIO:
1213                         msg_entity = self;
1214                         if(msg_entity.cvar_cl_voice_directional == 1)
1215                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1216                         else
1217                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1218                         break;
1219                 case VOICETYPE_AUTOTAUNT:
1220                         if(!sv_autotaunt)
1221                                 break;
1222                         if(!sv_taunt)
1223                                 break;
1224                         if(sv_gentle)
1225                                 break;
1226                         tauntrand = random();
1227                         msg_entity = self;
1228                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1229                         {
1230                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1231                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1232                                 else
1233                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1234                         }
1235                         break;
1236                 case VOICETYPE_TAUNT:
1237                         if(self.classname == "player")
1238                                 if(self.deadflag == DEAD_NO)
1239                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1240                         if(!sv_taunt)
1241                                 break;
1242                         if(sv_gentle)
1243                                 break;
1244                         msg_entity = self;
1245                         if (msg_entity.cvar_cl_voice_directional >= 1)
1246                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1247                         else
1248                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1249                         break;
1250                 case VOICETYPE_PLAYERSOUND:
1251                         msg_entity = self;
1252                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1253                         break;
1254                 default:
1255                         backtrace("Invalid voice type!");
1256                         break;
1257         }
1258 }
1259
1260 void GlobalSound(string sample, float chan, float voicetype)
1261 {
1262         float n;
1263         float tauntrand;
1264
1265         if(sample == "")
1266                 return;
1267
1268         tokenize_console(sample);
1269         n = stof(argv(1));
1270         if(n > 0)
1271                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1272         else
1273                 sample = strcat(argv(0), ".wav"); // randomization
1274
1275         switch(voicetype)
1276         {
1277                 case VOICETYPE_LASTATTACKER_ONLY:
1278                         if(self.pusher)
1279                         {
1280                                 msg_entity = self.pusher;
1281                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1282                                 {
1283                                         if(msg_entity.cvar_cl_voice_directional == 1)
1284                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1285                                         else
1286                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1287                                 }
1288                         }
1289                         break;
1290                 case VOICETYPE_LASTATTACKER:
1291                         if(self.pusher)
1292                         {
1293                                 msg_entity = self.pusher;
1294                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1295                                 {
1296                                         if(msg_entity.cvar_cl_voice_directional == 1)
1297                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1298                                         else
1299                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1300                                 }
1301                                 msg_entity = self;
1302                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1303                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1304                         }
1305                         break;
1306                 case VOICETYPE_TEAMRADIO:
1307                         FOR_EACH_REALCLIENT(msg_entity)
1308                                 if(!teamplay || msg_entity.team == self.team)
1309                                 {
1310                                         if(msg_entity.cvar_cl_voice_directional == 1)
1311                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1312                                         else
1313                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1314                                 }
1315                         break;
1316                 case VOICETYPE_AUTOTAUNT:
1317                         if(!sv_autotaunt)
1318                                 break;
1319                         if(!sv_taunt)
1320                                 break;
1321                         if(sv_gentle)
1322                                 break;
1323                         tauntrand = random();
1324                         FOR_EACH_REALCLIENT(msg_entity)
1325                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1326                                 {
1327                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1328                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1329                                         else
1330                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1331                                 }
1332                         break;
1333                 case VOICETYPE_TAUNT:
1334                         if(self.classname == "player")
1335                                 if(self.deadflag == DEAD_NO)
1336                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1337                         if(!sv_taunt)
1338                                 break;
1339                         if(sv_gentle)
1340                                 break;
1341                         FOR_EACH_REALCLIENT(msg_entity)
1342                         {
1343                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1344                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1345                                 else
1346                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1347                         }
1348                         break;
1349                 case VOICETYPE_PLAYERSOUND:
1350                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1351                         break;
1352                 default:
1353                         backtrace("Invalid voice type!");
1354                         break;
1355         }
1356 }
1357
1358 void PlayerSound(.string samplefield, float chan, float voicetype)
1359 {
1360         GlobalSound(self.samplefield, chan, voicetype);
1361 }
1362
1363 void VoiceMessage(string type, string msg)
1364 {
1365         var .string sample;
1366         float voicetype, ownteam;
1367         float flood;
1368         sample = GetVoiceMessageSampleField(type);
1369
1370         if(GetPlayerSoundSampleField_notFound)
1371         {
1372                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1373                 return;
1374         }
1375
1376         voicetype = GetVoiceMessageVoiceType(type);
1377         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1378
1379         flood = Say(self, ownteam, world, msg, 1);
1380
1381         if (flood > 0)
1382                 GlobalSound(self.sample, CH_VOICE, voicetype);
1383         else if (flood < 0)
1384                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1385 }
1386
1387 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1388 {
1389 //      show_message
1390 //      0 (00) automove centerprint, admin message
1391 //      1 (01) automove centerprint, no admin message
1392 //      2 (10) no centerprint, admin message
1393 //      3 (11) no centerprint, no admin message
1394
1395         float lockteams_backup;
1396
1397         lockteams_backup = lockteams;  // backup any team lock
1398
1399         lockteams = 0;  // disable locked teams
1400
1401         TeamchangeFrags(client);  // move the players frags
1402         SetPlayerColors(client, team_colour - 1);  // set the players colour
1403         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1404
1405         lockteams = lockteams_backup;  // restore the team lock
1406
1407         LogTeamchange(client.playerid, client.team, type);
1408
1409         if not(show_message & 1) // admin message
1410                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1411
1412         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1413 }