qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, ibot, jbot, idx;
  16         float fh;
  17         vector v;
  18         string prefix;
  19         if(weaponstats_buffer < 0)
  20                 return;
  21         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  22         if(autocvar_sv_weaponstats_file != "")
  23         {
  24                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  25                 if(fh >= 0)
  26                 {
  27                         fputs(fh, "#begin statsfile\n");
  28                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  29                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  30                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  31                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  32                                 {
  33                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  34                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  35                                         if(v != '0 0 0')
  36                                         {
  37                                                 //vector is: kills hits damage
  38                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  39                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  40                                         }
  41                                 }
  42                         fputs(fh, "#end\n\n");
  43                         fclose(fh);
  44                         print("Weapon stats written\n");
  45                 }
  46         }
  47         buf_del(weaponstats_buffer);
  48         weaponstats_buffer = -1;
  49 }
  50
  51 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  52 {
  53         float idx;
  54         if(weaponstats_buffer < 0)
  55                 return;
  56         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  57                 return;
  58         if(awep > WEP_LAST || vwep > WEP_LAST)
  59                 return;
  60         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  61         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  62 }
  63 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  64 {
  65         if(damage < 0)
  66                 error("negative damage?");
  67         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  68 }
  69 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  70 {
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  72 }
  73
  74 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  75 // merged player_run and player_stand to player_anim
  76 // added death animations to player_anim
  77 // can now spawn thrown weapons from anywhere, not just from players
  78 // thrown weapons now fade out after 20 seconds
  79 // created PlayerGib function
  80 // PlayerDie no longer uses hitloc or damage
  81 // PlayerDie now supports dying animations as well as gibbing
  82 // cleaned up PlayerDie a lot
  83 // added CopyBody
  84
  85 .entity pusher;
  86 .float pushltime;
  87
  88 void CopyBody(float keepvelocity)
  89 {
  90         local entity oldself;
  91         if (self.effects & EF_NODRAW)
  92                 return;
  93         oldself = self;
  94         self = spawn();
  95         self.enemy = oldself;
  96         self.lip = oldself.lip;
  97         self.colormap = oldself.colormap;
  98         self.glowmod = oldself.glowmod;
  99         self.iscreature = oldself.iscreature;
 100         self.angles = oldself.angles;
 101         self.avelocity = oldself.avelocity;
 102         self.classname = "body";
 103         self.damageforcescale = oldself.damageforcescale;
 104         self.effects = oldself.effects;
 105         self.event_damage = oldself.event_damage;
 106         self.animstate_startframe = oldself.animstate_startframe;
 107         self.animstate_numframes = oldself.animstate_numframes;
 108         self.animstate_framerate = oldself.animstate_framerate;
 109         self.animstate_starttime = oldself.animstate_starttime;
 110         self.animstate_endtime = oldself.animstate_endtime;
 111         self.animstate_override = oldself.animstate_override;
 112         self.animstate_looping = oldself.animstate_looping;
 113         self.frame = oldself.frame;
 114         self.dead_frame = oldself.dead_frame;
 115         self.pain_finished = oldself.pain_finished;
 116         self.health = oldself.health;
 117         self.armorvalue = oldself.armorvalue;
 118         self.armortype = oldself.armortype;
 119         self.model = oldself.model;
 120         self.modelindex = oldself.modelindex;
 121         self.modelindex_lod0 = oldself.modelindex_lod0;
 122         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 123         self.modelindex_lod1 = oldself.modelindex_lod1;
 124         self.modelindex_lod2 = oldself.modelindex_lod2;
 125         self.skinindex = oldself.skinindex;
 126         self.species = oldself.species;
 127         self.movetype = oldself.movetype;
 128         self.nextthink = oldself.nextthink;
 129         self.solid = oldself.solid;
 130         self.ballistics_density = oldself.ballistics_density;
 131         self.takedamage = oldself.takedamage;
 132         self.think = oldself.think;
 133         self.customizeentityforclient = oldself.customizeentityforclient;
 134         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 135         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 136         if (keepvelocity == 1)
 137                 self.velocity = oldself.velocity;
 138         self.oldvelocity = self.velocity;
 139         self.fade_time = oldself.fade_time;
 140         self.fade_rate = oldself.fade_rate;
 141         //self.weapon = oldself.weapon;
 142         setorigin(self, oldself.origin);
 143         setsize(self, oldself.mins, oldself.maxs);
 144         self.prevorigin = oldself.origin;
 145         self.reset = SUB_Remove;
 146
 147         Drag_MoveDrag(oldself, self);
 148
 149         Violence_DamageEffect_Copy(oldself, self);
 150
 151         self.owner = oldself;
 152         self = oldself;
 153 }
 154
 155 float player_getspecies()
 156 {
 157         float s;
 158         get_model_parameters(self.model, self.skinindex);
 159         s = get_model_parameters_species;
 160         get_model_parameters(string_null, 0);
 161         if(s < 0)
 162                 return SPECIES_HUMAN;
 163         return s;
 164 }
 165
 166 void player_setupanimsformodel()
 167 {
 168         local string animfilename;
 169         local float animfile;
 170         // defaults for legacy .zym models without animinfo files
 171         self.anim_die1 = '0 1 0.5'; // 2 seconds
 172         self.anim_die2 = '1 1 0.5'; // 2 seconds
 173         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 174         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 175         self.anim_duckwalk = '4 1 1';
 176         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 177         self.anim_duckidle = '6 1 1';
 178         self.anim_idle = '7 1 1';
 179         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 180         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 181         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 182         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 183         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 184         self.anim_run = '13 1 1';
 185         self.anim_runbackwards = '14 1 1';
 186         self.anim_strafeleft = '15 1 1';
 187         self.anim_straferight = '16 1 1';
 188         self.anim_dead1 = '17 1 1';
 189         self.anim_dead2 = '18 1 1';
 190         self.anim_forwardright = '19 1 1';
 191         self.anim_forwardleft = '20 1 1';
 192         self.anim_backright = '21 1 1';
 193         self.anim_backleft  = '22 1 1';
 194         self.anim_melee = '23 1 1';
 195         animparseerror = FALSE;
 196         animfilename = strcat(self.model, ".animinfo");
 197         animfile = fopen(animfilename, FILE_READ);
 198         if (animfile >= 0)
 199         {
 200                 self.anim_die1         = animparseline(animfile);
 201                 self.anim_die2         = animparseline(animfile);
 202                 self.anim_draw         = animparseline(animfile);
 203                 self.anim_duck         = animparseline(animfile);
 204                 self.anim_duckwalk     = animparseline(animfile);
 205                 self.anim_duckjump     = animparseline(animfile);
 206                 self.anim_duckidle     = animparseline(animfile);
 207                 self.anim_idle         = animparseline(animfile);
 208                 self.anim_jump         = animparseline(animfile);
 209                 self.anim_pain1        = animparseline(animfile);
 210                 self.anim_pain2        = animparseline(animfile);
 211                 self.anim_shoot        = animparseline(animfile);
 212                 self.anim_taunt        = animparseline(animfile);
 213                 self.anim_run          = animparseline(animfile);
 214                 self.anim_runbackwards = animparseline(animfile);
 215                 self.anim_strafeleft   = animparseline(animfile);
 216                 self.anim_straferight  = animparseline(animfile);
 217                 self.anim_forwardright = animparseline(animfile);
 218                 self.anim_forwardleft  = animparseline(animfile);
 219                 self.anim_backright    = animparseline(animfile);
 220                 self.anim_backleft     = animparseline(animfile);
 221                 self.anim_melee        = animparseline(animfile);
 222                 fclose(animfile);
 223
 224                 // derived anims
 225                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 226                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 227
 228                 if (animparseerror)
 229                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 230         }
 231         else
 232                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 233         // reset animstate now
 234         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 235 };
 236
 237 void player_anim (void)
 238 {
 239         updateanim(self);
 240         if (self.weaponentity)
 241                 updateanim(self.weaponentity);
 242
 243         if (self.deadflag != DEAD_NO)
 244         {
 245                 if (time > self.animstate_endtime)
 246                 {
 247                         if (self.maxs_z > 5)
 248                         {
 249                                 self.maxs_z = 5;
 250                                 setsize(self, self.mins, self.maxs);
 251                         }
 252                         self.frame = self.dead_frame;
 253                 }
 254                 return;
 255         }
 256
 257         if (!self.animstate_override)
 258         {
 259                 if (!(self.flags & FL_ONGROUND))
 260                 {
 261                         if (self.crouch)
 262                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 263                         else
 264                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 265                         self.restart_jump = FALSE;
 266                 }
 267                 else if (self.crouch)
 268                 {
 269                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 270                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 271                         else
 272                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 273                 }
 274                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 275                 {
 276                         if (self.movement_x > 0 && self.movement_y == 0)
 277                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 278                         else if (self.movement_x < 0 && self.movement_y == 0)
 279                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 280                         else if (self.movement_x == 0 && self.movement_y > 0)
 281                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 282                         else if (self.movement_x == 0 && self.movement_y < 0)
 283                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 284                         else if (self.movement_x > 0 && self.movement_y > 0)
 285                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 286                         else if (self.movement_x > 0 && self.movement_y < 0)
 287                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 288                         else if (self.movement_x < 0 && self.movement_y > 0)
 289                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 290                         else if (self.movement_x < 0 && self.movement_y < 0)
 291                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 292                         else
 293                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 294                 }
 295                 else
 296                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 297         }
 298
 299         if (self.weaponentity)
 300         if (!self.weaponentity.animstate_override)
 301                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 302 }
 303
 304 void SpawnThrownWeapon (vector org, float w)
 305 {
 306         if(g_minstagib)
 307         if(self.ammo_cells <= 0)
 308                 return;
 309
 310         if(g_pinata)
 311         {
 312                 float j;
 313                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 314                 {
 315                         if(self.weapons & W_WeaponBit(j))
 316                                 if(W_IsWeaponThrowable(j))
 317                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 318                 }
 319         }
 320         else
 321         {
 322                 if(W_IsWeaponThrowable(self.weapon))
 323                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 324         }
 325 }
 326
 327 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 328 {
 329         local float take, save;
 330         vector v;
 331         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 332
 333         // damage resistance (ignore most of the damage from a bullet or similar)
 334         damage = max(damage - 5, 1);
 335
 336         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 337         take = v_x;
 338         save = v_y;
 339
 340         if(sound_allowed(MSG_BROADCAST, attacker))
 341         {
 342                 if (save > 10)
 343                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 344                 else if (take > 30)
 345                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 346                 else if (take > 10)
 347                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 348         }
 349
 350         if (take > 50)
 351                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 352         if (take > 100)
 353                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 354
 355         if (!(self.flags & FL_GODMODE))
 356         {
 357                 self.armorvalue = self.armorvalue - save;
 358                 self.health = self.health - take;
 359                 // pause regeneration for 5 seconds
 360                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 361         }
 362         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 363         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 364         self.dmg_inflictor = inflictor;
 365
 366         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 367         {
 368                 // don't use any animations as a gib
 369                 self.frame = 0;
 370                 self.dead_frame = 0;
 371                 // view just above the floor
 372                 self.view_ofs = '0 0 4';
 373
 374                 Violence_GibSplash(self, 1, 1, attacker);
 375                 self.modelindex = 0; // restore later
 376                 self.solid = SOLID_NOT; // restore later
 377                 self.takedamage = DAMAGE_NO; // restore later
 378         }
 379 }
 380
 381 void ClientKill_Now_TeamChange();
 382 void freezetag_CheckWinner();
 383
 384 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 385 {
 386         local float take, save, waves, sdelay, dh, da, j;
 387         vector v;
 388         float valid_damage_for_weaponstats;
 389         float excess;
 390
 391         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 392                 return;
 393
 394         dh = max(self.health, 0);
 395         da = max(self.armorvalue, 0);
 396
 397         if(!DEATH_ISSPECIAL(deathtype))
 398         {
 399                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 400                 if(self != attacker)
 401                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 402         }
 403
 404         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 405         {
 406                 // tuba causes blood to come out of the ears
 407                 vector ear1, ear2;
 408                 vector d;
 409                 float f;
 410                 ear1 = self.origin;
 411                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 412                 ear2 = ear1;
 413                 makevectors(self.angles);
 414                 ear1 += v_right * -10;
 415                 ear2 += v_right * +10;
 416                 d = inflictor.origin - self.origin;
 417                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 418                 force = v_right * vlen(force);
 419                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 420                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 421                 if(f > 0)
 422                 {
 423                         hitloc = ear1;
 424                         force = force * -1;
 425                 }
 426                 else
 427                 {
 428                         hitloc = ear2;
 429                         // force is already good
 430                 }
 431         }
 432         else
 433                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 434
 435         if (!g_minstagib)
 436         {
 437                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 438                 take = v_x;
 439                 save = v_y;
 440         }
 441         else
 442         {
 443                 save = 0;
 444                 take = damage;
 445         }
 446
 447         frag_inflictor = inflictor;
 448         frag_attacker = attacker;
 449         frag_target = self;
 450         damage_take = take;
 451         damage_save = save;
 452         damage_force = force;
 453         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 454         take = bound(0, damage_take, self.health);
 455         save = bound(0, damage_save, self.armorvalue);
 456         excess = max(0, damage - take - save);
 457
 458         if(sound_allowed(MSG_BROADCAST, attacker))
 459         {
 460                 if (save > 10)
 461                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 462                 else if (take > 30)
 463                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 464                 else if (take > 10)
 465                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 466         }
 467
 468         if (take > 50)
 469                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 470         if (take > 100)
 471                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 472
 473         if (time >= self.spawnshieldtime)
 474         {
 475                 if (!(self.flags & FL_GODMODE))
 476                 {
 477                         self.armorvalue = self.armorvalue - save;
 478                         self.health = self.health - take;
 479                         // pause regeneration for 5 seconds
 480                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 481
 482                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 483                         {
 484                                 self.pain_finished = time + 0.5;        //Supajoe
 485
 486                                 if(sv_gentle < 1) {
 487                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 488                                         {
 489                                                 if (random() > 0.5)
 490                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 491                                                 else
 492                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 493                                         }
 494
 495                                         if(sound_allowed(MSG_BROADCAST, attacker))
 496                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 497                                         if(self.health > 1)
 498                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 499                                         {
 500                                                 if(deathtype == DEATH_FALL)
 501                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 502                                                 else if(self.health > 75) // TODO make a "gentle" version?
 503                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 504                                                 else if(self.health > 50)
 505                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 506                                                 else if(self.health > 25)
 507                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 508                                                 else
 509                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 510                                         }
 511                                 }
 512
 513                                 // throw off bot aim temporarily
 514                                 local float shake;
 515                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 516                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 517                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 518                         }
 519                 }
 520                 else
 521                         self.max_armorvalue += (save + take);
 522         }
 523         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 524         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 525         self.dmg_inflictor = inflictor;
 526
 527         if(attacker == self)
 528         {
 529                 // don't reset pushltime for self damage as it may be an attempt to
 530                 // escape a lava pit or similar
 531                 //self.pushltime = 0;
 532         }
 533         else if(attacker.classname == "player" || attacker.classname == "gib")
 534         {
 535                 self.pusher = attacker;
 536                 self.pushltime = time + autocvar_g_maxpushtime;
 537         }
 538         else if(time < self.pushltime)
 539         {
 540                 attacker = self.pusher;
 541                 self.pushltime = max(self.pushltime, time + 0.6);
 542         }
 543         else
 544                 self.pushltime = 0;
 545
 546         float abot, vbot, awep;
 547         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 548         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 549
 550         valid_damage_for_weaponstats = 0;
 551         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 552         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 553         if(attacker && self != attacker)
 554         if(IsDifferentTeam(self, attacker))
 555         {
 556                 if(DEATH_ISSPECIAL(deathtype))
 557                         awep = attacker.weapon;
 558                 else
 559                         awep = DEATH_WEAPONOF(deathtype);
 560                 valid_damage_for_weaponstats = 1;
 561         }
 562
 563         if(valid_damage_for_weaponstats)
 564         {
 565                 dh = dh - max(self.health, 0);
 566                 da = da - max(self.armorvalue, 0);
 567                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 568         }
 569
 570         if (self.health < 1)
 571         {
 572                 float defer_ClientKill_Now_TeamChange;
 573                 defer_ClientKill_Now_TeamChange = FALSE;
 574
 575                 if(self.alivetime)
 576                 {
 577                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 578                         self.alivetime = 0;
 579                 }
 580
 581                 if(valid_damage_for_weaponstats)
 582                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 583
 584                 if(sv_gentle < 1) // TODO make a "gentle" version?
 585                 if(sound_allowed(MSG_BROADCAST, attacker))
 586                 {
 587                         if(deathtype == DEATH_DROWN)
 588                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 589                         else
 590                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 591                 }
 592
 593                 // get rid of kill indicator
 594                 if(self.killindicator)
 595                 {
 596                         remove(self.killindicator);
 597                         self.killindicator = world;
 598                         if(self.killindicator_teamchange)
 599                                 defer_ClientKill_Now_TeamChange = TRUE;
 600
 601                         if(self.classname == "body")
 602                         if(deathtype == DEATH_KILL)
 603                         {
 604                                 // for the lemmings fans, a small harmless explosion
 605                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 606                         }
 607                 }
 608
 609                 if(!g_freezetag)
 610                 {
 611                         // become fully visible
 612                         self.alpha = 1;
 613                         // throw a weapon
 614                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 615                 }
 616
 617                 // print an obituary message
 618                 Obituary (attacker, inflictor, self, deathtype);
 619                 race_PreDie();
 620                 DropAllRunes(self);
 621
 622                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 623                 {
 624                         PutClientInServer();
 625                         count_alive_players(); // re-count players
 626                         freezetag_CheckWinner();
 627                         return;
 628                 }
 629
 630                 frag_attacker = attacker;
 631                 frag_inflictor = inflictor;
 632                 frag_target = self;
 633                 MUTATOR_CALLHOOK(PlayerDies);
 634                 weapon_action(self.weapon, WR_PLAYERDEATH);
 635
 636                 if(self.flagcarried)
 637                 {
 638                         if(attacker.classname != "player" && attacker.classname != "gib")
 639                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 640                         else if(attacker.team == self.team)
 641                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 642                         else
 643                                 DropFlag(self.flagcarried, world, attacker);
 644                 }
 645                 if(self.ballcarried && g_nexball)
 646                         DropBall(self.ballcarried, self.origin, self.velocity);
 647                 Portal_ClearAllLater(self);
 648
 649                 if(clienttype(self) == CLIENTTYPE_REAL)
 650                 {
 651                         stuffcmd(self, "-zoom\n");
 652                         self.fixangle = TRUE;
 653                         //msg_entity = self;
 654                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 655                         //WriteAngle (MSG_ONE, self.v_angle_x);
 656                         //WriteAngle (MSG_ONE, self.v_angle_y);
 657                         //WriteAngle (MSG_ONE, 80);
 658                 }
 659
 660                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 661                         ClientKill_Now_TeamChange();
 662
 663                 if(g_arena)
 664                         Spawnqueue_Unmark(self);
 665
 666                 if(g_freezetag)
 667                         return;
 668
 669                 // when we get here, player actually dies
 670                 // clear waypoints (do this AFTER FreezeTag)
 671                 WaypointSprite_PlayerDead();
 672
 673                 // make the corpse upright (not tilted)
 674                 self.angles_x = 0;
 675                 self.angles_z = 0;
 676                 // don't spin
 677                 self.avelocity = '0 0 0';
 678                 // view from the floor
 679                 self.view_ofs = '0 0 -8';
 680                 // toss the corpse
 681                 self.movetype = MOVETYPE_TOSS;
 682                 // shootable corpse
 683                 self.solid = SOLID_CORPSE;
 684                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 685                 // don't stick to the floor
 686                 self.flags &~= FL_ONGROUND;
 687                 // dying animation
 688                 self.deadflag = DEAD_DYING;
 689                 // when to allow respawn
 690                 sdelay = 0;
 691                 waves = 0;
 692                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 693                 if(!sdelay)
 694                 {
 695                         if(g_cts)
 696                                 sdelay = 0; // no respawn delay in CTS
 697                         else
 698                                 sdelay = autocvar_g_respawn_delay;
 699                 }
 700                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 701                 if(!waves)
 702                         waves = autocvar_g_respawn_waves;
 703                 if(waves)
 704                         self.death_time = ceil((time + sdelay) / waves) * waves;
 705                 else
 706                         self.death_time = time + sdelay;
 707                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 708                         self.respawn_countdown = 10; // first number to count down from is 10
 709                 else
 710                         self.respawn_countdown = -1; // do not count down
 711                 if (random() < 0.5)
 712                 {
 713                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 714                         self.dead_frame = self.anim_dead1_x;
 715                 }
 716                 else
 717                 {
 718                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 719                         self.dead_frame = self.anim_dead2_x;
 720                 }
 721                 // set damage function to corpse damage
 722                 self.event_damage = PlayerCorpseDamage;
 723                 // call the corpse damage function just in case it wants to gib
 724                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 725                 // set up to fade out later
 726                 SUB_SetFade (self, time + 6 + random (), 1);
 727
 728                 if(sv_gentle > 0 || autocvar_ekg) {
 729                         // remove corpse
 730                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 731                 }
 732
 733                 // reset fields the weapons may use just in case
 734                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 735                 {
 736                         weapon_action(j, WR_RESETPLAYER);
 737                         ATTACK_FINISHED_FOR(self, j) = 0;
 738                 }
 739         }
 740 }
 741
 742 .float muted; // to be used by prvm_edictset server playernumber muted 1
 743 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 744 // message "": do not say, just test flood control
 745 // return value:
 746 //   1 = accept
 747 //   0 = reject
 748 //  -1 = fake accept
 749 {
 750         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 751         float flood, privatemsgprefixlen;
 752         var .float flood_field;
 753         entity head;
 754         float ret;
 755
 756         if(Ban_MaybeEnforceBan(source))
 757                 return 0;
 758
 759         if(!teamsay && !privatesay)
 760                 if(substring(msgin, 0, 1) == " ")
 761                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 762
 763         msgin = formatmessage(msgin);
 764
 765         if(source.classname != "player")
 766                 colorstr = "^0"; // black for spectators
 767         else if(teams_matter)
 768                 colorstr = Team_ColorCode(source.team);
 769         else
 770                 teamsay = FALSE;
 771
 772         if(intermission_running)
 773                 teamsay = FALSE;
 774
 775         if(msgin != "")
 776                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 777
 778         /*
 779          * using bprint solves this... me stupid
 780         // how can we prevent the message from appearing in a listen server?
 781         // for now, just give "say" back and only handle say_team
 782         if(!teamsay)
 783         {
 784                 clientcommand(self, strcat("say ", msgin));
 785                 return;
 786         }
 787         */
 788
 789         if(autocvar_g_chat_teamcolors)
 790                 namestr = playername(source);
 791         else
 792                 namestr = source.netname;
 793
 794         if(msgin != "")
 795         {
 796                 if(privatesay)
 797                 {
 798                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 799                         privatemsgprefixlen = strlen(msgstr);
 800                         msgstr = strcat(msgstr, msgin);
 801                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 802                         if(autocvar_g_chat_teamcolors)
 803                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 804                         else
 805                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 806                 }
 807                 else if(teamsay)
 808                 {
 809                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 810                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 811                 }
 812                 else
 813                 {
 814                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 815                         cmsgstr = "";
 816                 }
 817                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 818         }
 819         else
 820         {
 821                 msgstr = cmsgstr = "";
 822         }
 823
 824         fullmsgstr = msgstr;
 825         fullcmsgstr = cmsgstr;
 826
 827         // FLOOD CONTROL
 828         flood = 0;
 829         if(floodcontrol)
 830         {
 831                 float flood_spl;
 832                 float flood_burst;
 833                 float flood_lmax;
 834                 float lines;
 835                 if(privatesay)
 836                 {
 837                         flood_spl = autocvar_g_chat_flood_spl_tell;
 838                         flood_burst = autocvar_g_chat_flood_burst_tell;
 839                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 840                         flood_field = floodcontrol_chattell;
 841                 }
 842                 else if(teamsay)
 843                 {
 844                         flood_spl = autocvar_g_chat_flood_spl_team;
 845                         flood_burst = autocvar_g_chat_flood_burst_team;
 846                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 847                         flood_field = floodcontrol_chatteam;
 848                 }
 849                 else
 850                 {
 851                         flood_spl = autocvar_g_chat_flood_spl;
 852                         flood_burst = autocvar_g_chat_flood_burst;
 853                         flood_lmax = autocvar_g_chat_flood_lmax;
 854                         flood_field = floodcontrol_chat;
 855                 }
 856                 flood_burst = max(0, flood_burst - 1);
 857                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 858
 859                 // do flood control for the default line size
 860                 if(msgstr != "")
 861                 {
 862                         getWrappedLine_remaining = msgstr;
 863                         msgstr = "";
 864                         lines = 0;
 865                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 866                         {
 867                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 868                                 ++lines;
 869                         }
 870                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 871
 872                         if(getWrappedLine_remaining != "")
 873                         {
 874                                 msgstr = strcat(msgstr, "\n");
 875                                 flood = 2;
 876                         }
 877
 878                         if(time >= source.flood_field)
 879                         {
 880                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 881                         }
 882                         else
 883                         {
 884                                 flood = 1;
 885                                 msgstr = fullmsgstr;
 886                         }
 887                 }
 888                 else
 889                 {
 890                         if(time >= source.flood_field)
 891                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 892                         else
 893                                 flood = 1;
 894                 }
 895
 896                 if (timeoutStatus == 2) //when game is paused, no flood protection
 897                         source.flood_field = flood = 0;
 898         }
 899
 900         if(flood == 2) // cannot happen for empty msgstr
 901         {
 902                 if(autocvar_g_chat_flood_notify_flooder)
 903                 {
 904                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 905                         sourcecmsgstr = "";
 906                 }
 907                 else
 908                 {
 909                         sourcemsgstr = fullmsgstr;
 910                         sourcecmsgstr = fullcmsgstr;
 911                 }
 912                 cmsgstr = "";
 913         }
 914         else
 915         {
 916                 sourcemsgstr = msgstr;
 917                 sourcecmsgstr = cmsgstr;
 918         }
 919
 920         if(!privatesay)
 921         if(source.classname != "player")
 922         {
 923                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 924                         teamsay = -1; // spectators
 925         }
 926
 927         if(flood)
 928                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 929
 930         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 931         if(privatesay)
 932                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 933
 934         if(source.muted)
 935         {
 936                 // always fake the message
 937                 ret = -1;
 938         }
 939         else if(flood == 1)
 940         {
 941                 if(autocvar_g_chat_flood_notify_flooder)
 942                 {
 943                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 944                         ret = 0;
 945                 }
 946                 else
 947                         ret = -1;
 948         }
 949         else
 950         {
 951                 ret = 1;
 952         }
 953
 954         if(sourcemsgstr != "" && ret != 0)
 955         {
 956                 if(ret < 0) // fake
 957                 {
 958                         sprint(source, sourcemsgstr);
 959                         if(sourcecmsgstr != "" && !privatesay)
 960                                 centerprint(source, sourcecmsgstr);
 961                 }
 962                 else if(privatesay)
 963                 {
 964                         sprint(source, sourcemsgstr);
 965                         sprint(privatesay, msgstr);
 966                         if(cmsgstr != "")
 967                                 centerprint(privatesay, cmsgstr);
 968                 }
 969                 else if(teamsay > 0)
 970                 {
 971                         sprint(source, sourcemsgstr);
 972                         if(sourcecmsgstr != "")
 973                                 centerprint(source, sourcecmsgstr);
 974                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 975                                 if(head != source)
 976                                 {
 977                                         sprint(head, msgstr);
 978                                         if(cmsgstr != "")
 979                                                 centerprint(head, cmsgstr);
 980                                 }
 981                 }
 982                 else if(teamsay < 0)
 983                 {
 984                         sprint(source, sourcemsgstr);
 985                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 986                                 if(head != source)
 987                                         sprint(head, msgstr);
 988                 }
 989                 else if(sourcemsgstr != msgstr)
 990                 {
 991                         sprint(source, sourcemsgstr);
 992                         FOR_EACH_REALCLIENT(head)
 993                                 if(head != source)
 994                                         sprint(head, msgstr);
 995                 }
 996                 else
 997                         bprint(msgstr);
 998         }
 999
1000         return ret;
1001 }
1002
1003 float GetVoiceMessageVoiceType(string type)
1004 {
1005         if(type == "taunt")
1006                 return VOICETYPE_TAUNT;
1007         if(type == "teamshoot")
1008                 return VOICETYPE_LASTATTACKER;
1009         return VOICETYPE_TEAMRADIO;
1010 }
1011
1012 string allvoicesamples;
1013 .string GetVoiceMessageSampleField(string type)
1014 {
1015         GetPlayerSoundSampleField_notFound = 0;
1016         switch(type)
1017         {
1018 #define _VOICEMSG(m) case #m: return playersound_##m;
1019                 ALLVOICEMSGS
1020 #undef _VOICEMSG
1021         }
1022         GetPlayerSoundSampleField_notFound = 1;
1023         return playersound_taunt;
1024 }
1025
1026 .string GetPlayerSoundSampleField(string type)
1027 {
1028         GetPlayerSoundSampleField_notFound = 0;
1029         switch(type)
1030         {
1031 #define _VOICEMSG(m) case #m: return playersound_##m;
1032                 ALLPLAYERSOUNDS
1033 #undef _VOICEMSG
1034         }
1035         GetPlayerSoundSampleField_notFound = 1;
1036         return playersound_taunt;
1037 }
1038
1039 void PrecacheGlobalSound(string samplestring)
1040 {
1041         float n, i;
1042         tokenize_console(samplestring);
1043         n = stof(argv(1));
1044         if(n > 0)
1045         {
1046                 for(i = 1; i <= n; ++i)
1047                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1048         }
1049         else
1050         {
1051                 precache_sound(strcat(argv(0), ".wav"));
1052         }
1053 }
1054
1055 void PrecachePlayerSounds(string f)
1056 {
1057         float fh;
1058         string s;
1059         fh = fopen(f, FILE_READ);
1060         if(fh < 0)
1061                 return;
1062         while((s = fgets(fh)))
1063         {
1064                 if(tokenize_console(s) != 3)
1065                 {
1066                         dprint("Invalid sound info line: ", s, "\n");
1067                         continue;
1068                 }
1069                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1070         }
1071         fclose(fh);
1072
1073         if not(allvoicesamples)
1074         {
1075 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1076                 ALLVOICEMSGS
1077 #undef _VOICEMSG
1078                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1079         }
1080 }
1081
1082 void ClearPlayerSounds()
1083 {
1084 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1085         ALLPLAYERSOUNDS
1086         ALLVOICEMSGS
1087 #undef _VOICEMSG
1088 }
1089
1090 float LoadPlayerSounds(string f, float first)
1091 {
1092         float fh;
1093         string s;
1094         var .string field;
1095         fh = fopen(f, FILE_READ);
1096         if(fh < 0)
1097         {
1098                 dprint("Player sound file not found: ", f, "\n");
1099                 return 0;
1100         }
1101         while((s = fgets(fh)))
1102         {
1103                 if(tokenize_console(s) != 3)
1104                         continue;
1105                 field = GetPlayerSoundSampleField(argv(0));
1106                 if(GetPlayerSoundSampleField_notFound)
1107                         field = GetVoiceMessageSampleField(argv(0));
1108                 if(GetPlayerSoundSampleField_notFound)
1109                         continue;
1110                 if(self.field)
1111                         strunzone(self.field);
1112                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1113         }
1114         fclose(fh);
1115         return 1;
1116 }
1117
1118 .float modelindex_for_playersound;
1119 .float skinindex_for_playersound;
1120 void UpdatePlayerSounds()
1121 {
1122         if(self.modelindex == self.modelindex_for_playersound)
1123         if(self.skinindex == self.skinindex_for_playersound)
1124                 return;
1125         self.modelindex_for_playersound = self.modelindex;
1126         self.skinindex_for_playersound = self.skinindex;
1127         ClearPlayerSounds();
1128         LoadPlayerSounds("sound/player/default.sounds", 1);
1129         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1130                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1131 }
1132
1133 void FakeGlobalSound(string sample, float chan, float voicetype)
1134 {
1135         float n;
1136         float tauntrand;
1137
1138         if(sample == "")
1139                 return;
1140
1141         tokenize_console(sample);
1142         n = stof(argv(1));
1143         if(n > 0)
1144                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1145         else
1146                 sample = strcat(argv(0), ".wav"); // randomization
1147
1148         switch(voicetype)
1149         {
1150                 case VOICETYPE_LASTATTACKER_ONLY:
1151                         break;
1152                 case VOICETYPE_LASTATTACKER:
1153                         if(self.pusher)
1154                         {
1155                                 msg_entity = self;
1156                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1157                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1158                         }
1159                         break;
1160                 case VOICETYPE_TEAMRADIO:
1161                         msg_entity = self;
1162                         if(msg_entity.cvar_cl_voice_directional == 1)
1163                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1164                         else
1165                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1166                         break;
1167                 case VOICETYPE_AUTOTAUNT:
1168                         if(!sv_autotaunt)
1169                                 break;
1170                         if(!sv_taunt)
1171                                 break;
1172                         if(sv_gentle)
1173                                 break;
1174                         tauntrand = random();
1175                         msg_entity = self;
1176                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1177                         {
1178                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1179                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1180                                 else
1181                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1182                         }
1183                         break;
1184                 case VOICETYPE_TAUNT:
1185                         if(self.classname == "player")
1186                                 if(self.deadflag == DEAD_NO)
1187                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1188                         if(!sv_taunt)
1189                                 break;
1190                         if(sv_gentle)
1191                                 break;
1192                         msg_entity = self;
1193                         if (msg_entity.cvar_cl_voice_directional >= 1)
1194                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1195                         else
1196                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1197                         break;
1198                 case VOICETYPE_PLAYERSOUND:
1199                         msg_entity = self;
1200                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1201                         break;
1202                 default:
1203                         backtrace("Invalid voice type!");
1204                         break;
1205         }
1206 }
1207
1208 void GlobalSound(string sample, float chan, float voicetype)
1209 {
1210         float n;
1211         float tauntrand;
1212
1213         if(sample == "")
1214                 return;
1215
1216         tokenize_console(sample);
1217         n = stof(argv(1));
1218         if(n > 0)
1219                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1220         else
1221                 sample = strcat(argv(0), ".wav"); // randomization
1222
1223         switch(voicetype)
1224         {
1225                 case VOICETYPE_LASTATTACKER_ONLY:
1226                         if(self.pusher)
1227                         {
1228                                 msg_entity = self.pusher;
1229                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1230                                 {
1231                                         if(msg_entity.cvar_cl_voice_directional == 1)
1232                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1233                                         else
1234                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1235                                 }
1236                         }
1237                         break;
1238                 case VOICETYPE_LASTATTACKER:
1239                         if(self.pusher)
1240                         {
1241                                 msg_entity = self.pusher;
1242                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1243                                 {
1244                                         if(msg_entity.cvar_cl_voice_directional == 1)
1245                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1246                                         else
1247                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1248                                 }
1249                                 msg_entity = self;
1250                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1251                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1252                         }
1253                         break;
1254                 case VOICETYPE_TEAMRADIO:
1255                         FOR_EACH_REALCLIENT(msg_entity)
1256                                 if(!teams_matter || msg_entity.team == self.team)
1257                                 {
1258                                         if(msg_entity.cvar_cl_voice_directional == 1)
1259                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1260                                         else
1261                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1262                                 }
1263                         break;
1264                 case VOICETYPE_AUTOTAUNT:
1265                         if(!sv_autotaunt)
1266                                 break;
1267                         if(!sv_taunt)
1268                                 break;
1269                         if(sv_gentle)
1270                                 break;
1271                         tauntrand = random();
1272                         FOR_EACH_REALCLIENT(msg_entity)
1273                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1274                                 {
1275                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1276                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1277                                         else
1278                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1279                                 }
1280                         break;
1281                 case VOICETYPE_TAUNT:
1282                         if(self.classname == "player")
1283                                 if(self.deadflag == DEAD_NO)
1284                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1285                         if(!sv_taunt)
1286                                 break;
1287                         if(sv_gentle)
1288                                 break;
1289                         FOR_EACH_REALCLIENT(msg_entity)
1290                         {
1291                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1292                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1293                                 else
1294                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1295                         }
1296                         break;
1297                 case VOICETYPE_PLAYERSOUND:
1298                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1299                         break;
1300                 default:
1301                         backtrace("Invalid voice type!");
1302                         break;
1303         }
1304 }
1305
1306 void PlayerSound(.string samplefield, float chan, float voicetype)
1307 {
1308         GlobalSound(self.samplefield, chan, voicetype);
1309 }
1310
1311 void VoiceMessage(string type, string msg)
1312 {
1313         var .string sample;
1314         float voicetype, ownteam;
1315         float flood;
1316         sample = GetVoiceMessageSampleField(type);
1317
1318         if(GetPlayerSoundSampleField_notFound)
1319         {
1320                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1321                 return;
1322         }
1323
1324         voicetype = GetVoiceMessageVoiceType(type);
1325         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1326
1327         flood = Say(self, ownteam, world, msg, 1);
1328
1329         if (flood > 0)
1330                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1331         else if (flood < 0)
1332                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1333 }
1334
1335 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1336 {
1337 //      show_message
1338 //      0 (00) automove centerprint, admin message
1339 //      1 (01) automove centerprint, no admin message
1340 //      2 (10) no centerprint, admin message
1341 //      3 (11) no centerprint, no admin message
1342
1343         float lockteams_backup;
1344
1345         lockteams_backup = lockteams;  // backup any team lock
1346
1347         lockteams = 0;  // disable locked teams
1348
1349         TeamchangeFrags(client);  // move the players frags
1350         SetPlayerColors(client, team_colour - 1);  // set the players colour
1351         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1352
1353         lockteams = lockteams_backup;  // restore the team lock
1354
1355         LogTeamchange(client.playerid, client.team, type);
1356
1357         if not(show_message & 1) // admin message
1358                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1359
1360         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1361 }