qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418                 vehicles_exit(VHEF_RELESE);
 419
 420         if(self.flagcarried)
 421                 DropFlag(self.flagcarried, world, world);
 422
 423         WaypointSprite_PlayerDead();
 424
 425         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 426                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 427
 428         if(self.killcount != -666) {
 429                 if(g_lms) {
 430                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 431                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 432                         else
 433                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 434                 } else
 435                         bprint ("^4", self.netname, "^4 is spectating now\n");
 436
 437                 if(self.just_joined == FALSE) {
 438                         LogTeamchange(self.playerid, -1, 4);
 439                 } else
 440                         self.just_joined = FALSE;
 441         }
 442
 443         PlayerScore_Clear(self); // clear scores when needed
 444
 445         accuracy_resend(self);
 446
 447         self.spectatortime = time;
 448
 449         self.classname = "observer";
 450         self.iscreature = FALSE;
 451         self.damagedbycontents = FALSE;
 452         self.health = -666;
 453         self.takedamage = DAMAGE_NO;
 454         self.solid = SOLID_NOT;
 455         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 456         self.flags = FL_CLIENT | FL_NOTARGET;
 457         self.armorvalue = 666;
 458         self.effects = 0;
 459         self.armorvalue = autocvar_g_balance_armor_start;
 460         self.pauserotarmor_finished = 0;
 461         self.pauserothealth_finished = 0;
 462         self.pauseregen_finished = 0;
 463         self.damageforcescale = 0;
 464         self.death_time = 0;
 465         self.respawn_time = 0;
 466         self.alpha = 0;
 467         self.scale = 0;
 468         self.fade_time = 0;
 469         self.pain_frame = 0;
 470         self.pain_finished = 0;
 471         self.strength_finished = 0;
 472         self.invincible_finished = 0;
 473         self.superweapons_finished = 0;
 474         self.pushltime = 0;
 475         self.istypefrag = 0;
 476         self.think = SUB_Null;
 477         self.nextthink = 0;
 478         self.hook_time = 0;
 479         self.runes = 0;
 480         self.deadflag = DEAD_NO;
 481         self.angles = spot.angles;
 482         self.angles_z = 0;
 483         self.fixangle = TRUE;
 484         self.crouch = FALSE;
 485
 486         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 487         self.prevorigin = self.origin;
 488         self.items = 0;
 489         WEPSET_CLEAR_E(self);
 490         self.model = "";
 491         FixPlayermodel();
 492         setmodel(self, "null");
 493         self.drawonlytoclient = self;
 494
 495         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 496         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 497
 498         self.weapon = 0;
 499         self.weaponname = "";
 500         self.switchingweapon = 0;
 501         self.weaponmodel = "";
 502         self.weaponentity = world;
 503         self.exteriorweaponentity = world;
 504         self.killcount = -666;
 505         self.velocity = '0 0 0';
 506         self.avelocity = '0 0 0';
 507         self.punchangle = '0 0 0';
 508         self.punchvector = '0 0 0';
 509         self.oldvelocity = self.velocity;
 510         self.fire_endtime = -1;
 511
 512         if(g_arena)
 513         {
 514                 if(self.version_mismatch)
 515                 {
 516                         Spawnqueue_Unmark(self);
 517                         Spawnqueue_Remove(self);
 518                 }
 519                 else
 520                 {
 521                         Spawnqueue_Insert(self);
 522                 }
 523         }
 524         else if(g_lms)
 525         {
 526                 // Only if the player cannot play at all
 527                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 528                         self.frags = FRAGS_SPECTATOR;
 529                 else
 530                         self.frags = FRAGS_LMS_LOSER;
 531         }
 532         else if(g_ca)
 533         {
 534                 if(self.caplayer)
 535                         self.frags = FRAGS_LMS_LOSER;
 536                 else
 537                         self.frags = FRAGS_SPECTATOR;
 538         }
 539         else
 540                 self.frags = FRAGS_SPECTATOR;
 541 }
 542
 543 .float model_randomizer;
 544 void FixPlayermodel()
 545 {
 546         string defaultmodel;
 547         float defaultskin, chmdl, oldskin, n, i;
 548         vector m1, m2;
 549
 550         defaultmodel = "";
 551         defaultskin = 0;
 552         chmdl = FALSE;
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 if(teamplay)
 557                 {
 558                         string s;
 559                         s = Team_ColorNameLowerCase(self.team);
 560                         if(s != "neutral")
 561                         {
 562                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 563                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 564                         }
 565                 }
 566
 567                 if(defaultmodel == "")
 568                 {
 569                         defaultmodel = autocvar_sv_defaultplayermodel;
 570                         defaultskin = autocvar_sv_defaultplayerskin;
 571                 }
 572
 573                 n = tokenize_console(defaultmodel);
 574                 if(n > 0)
 575                         defaultmodel = argv(floor(n * self.model_randomizer));
 576
 577                 i = strstrofs(defaultmodel, ":", 0);
 578                 if(i >= 0)
 579                 {
 580                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 581                         defaultmodel = substring(defaultmodel, 0, i);
 582                 }
 583         }
 584
 585         if(defaultmodel != "")
 586         {
 587                 if (defaultmodel != self.model)
 588                 {
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, defaultmodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = defaultskin;
 598         } else {
 599                 if (self.playermodel != self.model || self.playermodel == "")
 600                 {
 601                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 602                         m1 = self.mins;
 603                         m2 = self.maxs;
 604                         setplayermodel (self, self.playermodel);
 605                         setsize (self, m1, m2);
 606                         chmdl = TRUE;
 607                 }
 608
 609                 oldskin = self.skin;
 610                 self.skin = stof(self.playerskin);
 611         }
 612
 613         if(chmdl || oldskin != self.skin)
 614                 self.species = player_getspecies(); // model or skin has changed
 615
 616         if(!teamplay)
 617                 if(strlen(autocvar_sv_defaultplayercolors))
 618                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 619                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 620 }
 621
 622 void PlayerTouchExplode(entity p1, entity p2)
 623 {
 624         vector org;
 625         org = (p1.origin + p2.origin) * 0.5;
 626         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 627
 628         te_explosion(org);
 629
 630         entity e;
 631         e = spawn();
 632         setorigin(e, org);
 633         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 634         remove(e);
 635 }
 636
 637 /*
 638 =============
 639 PutClientInServer
 640
 641 Called when a client spawns in the server
 642 =============
 643 */
 644 //void() ctf_playerchanged;
 645
 646 void PutClientInServer (void)
 647 {
 648         if(clienttype(self) == CLIENTTYPE_BOT)
 649         {
 650                 self.classname = "player";
 651                 if(g_ca)
 652                         self.caplayer = 1;
 653         }
 654         else if(clienttype(self) == CLIENTTYPE_REAL)
 655         {
 656                 msg_entity = self;
 657                 WriteByte(MSG_ONE, SVC_SETVIEW);
 658                 WriteEntity(MSG_ONE, self);
 659         }
 660
 661         // reset player keys
 662         self.itemkeys = 0;
 663
 664         // player is dead and becomes observer
 665         // FIXME fix LMS scoring for new system
 666         if(g_lms)
 667         {
 668                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 669                         self.classname = "observer";
 670         }
 671
 672         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 673                 self.classname = "observer";
 674
 675         if(gameover)
 676                 self.classname = "observer";
 677
 678         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 679                 entity spot, oldself;
 680                 float j;
 681
 682                 accuracy_resend(self);
 683
 684                 if(self.team < 0)
 685                         JoinBestTeam(self, FALSE, TRUE);
 686
 687                 race_PreSpawn();
 688
 689                 spot = SelectSpawnPoint (FALSE);
 690                 if(!spot)
 691                 {
 692                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 693                         return; // spawn failed
 694                 }
 695
 696                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 697
 698                 self.classname = "player";
 699                 self.wasplayer = TRUE;
 700                 self.iscreature = TRUE;
 701                 self.damagedbycontents = TRUE;
 702                 self.movetype = MOVETYPE_WALK;
 703                 self.solid = SOLID_SLIDEBOX;
 704                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 705                 if(autocvar_g_playerclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 707                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 709                 self.frags = FRAGS_PLAYER;
 710                 if(INDEPENDENT_PLAYERS)
 711                         MAKE_INDEPENDENT_PLAYER(self);
 712                 self.flags = FL_CLIENT;
 713                 if(autocvar__notarget)
 714                         self.flags |= FL_NOTARGET;
 715                 self.takedamage = DAMAGE_AIM;
 716                 if(g_minstagib)
 717                         self.effects = EF_FULLBRIGHT;
 718                 else
 719                         self.effects = 0;
 720                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 721                 self.air_finished = time + 12;
 722                 self.dmg = 2;
 723                 if(autocvar_g_balance_nex_charge)
 724                 {
 725                         if(autocvar_g_balance_nex_secondary_chargepool)
 726                                 self.nex_chargepool_ammo = 1;
 727                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 728                 }
 729
 730                 if(inWarmupStage)
 731                 {
 732                         self.ammo_shells = warmup_start_ammo_shells;
 733                         self.ammo_nails = warmup_start_ammo_nails;
 734                         self.ammo_rockets = warmup_start_ammo_rockets;
 735                         self.ammo_cells = warmup_start_ammo_cells;
 736                         self.ammo_fuel = warmup_start_ammo_fuel;
 737                         self.health = warmup_start_health;
 738                         self.armorvalue = warmup_start_armorvalue;
 739                         WEPSET_COPY_EA(self, warmup_start_weapons);
 740                 }
 741                 else
 742                 {
 743                         self.ammo_shells = start_ammo_shells;
 744                         self.ammo_nails = start_ammo_nails;
 745                         self.ammo_rockets = start_ammo_rockets;
 746                         self.ammo_cells = start_ammo_cells;
 747                         self.ammo_fuel = start_ammo_fuel;
 748                         self.health = start_health;
 749                         self.armorvalue = start_armorvalue;
 750                         WEPSET_COPY_EA(self, start_weapons);
 751                 }
 752
 753                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 754                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 755                 else
 756                         self.superweapons_finished = 0;
 757
 758                 if(g_weaponarena_random)
 759                 {
 760                         if(g_weaponarena_random_with_laser)
 761                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 762                         W_RandomWeapons(self, g_weaponarena_random);
 763                         if(g_weaponarena_random_with_laser)
 764                                 WEPSET_OR_EW(self, WEP_LASER);
 765                 }
 766
 767                 self.items = start_items;
 768
 769                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 770                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 771                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 772                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 773                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 774                 //extend the pause of rotting if client was reset at the beginning of the countdown
 775                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 776                         self.spawnshieldtime += game_starttime - time;
 777                         self.pauserotarmor_finished += game_starttime - time;
 778                         self.pauserothealth_finished += game_starttime - time;
 779                         self.pauseregen_finished += game_starttime - time;
 780                 }
 781                 self.damageforcescale = 2;
 782                 self.death_time = 0;
 783                 self.respawn_time = 0;
 784                 self.scale = 0;
 785                 self.fade_time = 0;
 786                 self.pain_frame = 0;
 787                 self.pain_finished = 0;
 788                 self.strength_finished = 0;
 789                 self.invincible_finished = 0;
 790                 self.pushltime = 0;
 791                 // players have no think function
 792                 self.think = SUB_Null;
 793                 self.nextthink = 0;
 794                 self.hook_time = 0;
 795                 self.dmg_team = 0;
 796                 self.ballistics_density = autocvar_g_ballistics_density_player;
 797
 798                 self.metertime = 0;
 799
 800                 self.runes = 0;
 801
 802                 self.deadflag = DEAD_NO;
 803
 804                 self.angles = spot.angles;
 805
 806                 self.angles_z = 0; // never spawn tilted even if the spot says to
 807                 self.fixangle = TRUE; // turn this way immediately
 808                 self.velocity = '0 0 0';
 809                 self.avelocity = '0 0 0';
 810                 self.punchangle = '0 0 0';
 811                 self.punchvector = '0 0 0';
 812                 self.oldvelocity = self.velocity;
 813                 self.fire_endtime = -1;
 814
 815                 msg_entity = self;
 816                 WRITESPECTATABLE_MSG_ONE({
 817                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 818                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 819                 });
 820
 821                 self.model = "";
 822                 FixPlayermodel();
 823                 self.drawonlytoclient = world;
 824
 825                 self.crouch = FALSE;
 826                 self.view_ofs = PL_VIEW_OFS;
 827                 setsize (self, PL_MIN, PL_MAX);
 828                 self.spawnorigin = spot.origin;
 829                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 830                 // don't reset back to last position, even if new position is stuck in solid
 831                 self.oldorigin = self.origin;
 832                 self.prevorigin = self.origin;
 833                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 834                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 835         self.hud = HUD_NORMAL;
 836
 837                 if(g_arena)
 838                 {
 839                         Spawnqueue_Remove(self);
 840                         Spawnqueue_Mark(self);
 841                 }
 842                 else if(g_ca)
 843                         self.caplayer = 1;
 844
 845                 self.event_damage = PlayerDamage;
 846
 847                 self.bot_attack = TRUE;
 848
 849                 self.statdraintime = time + 5;
 850                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 851
 852                 if(self.killcount == -666) {
 853                         PlayerScore_Clear(self);
 854                         self.killcount = 0;
 855                 }
 856
 857                 CL_SpawnWeaponentity();
 858                 self.alpha = default_player_alpha;
 859                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 860                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 861
 862                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 863                 self.lms_traveled_distance = 0;
 864                 self.speedrunning = FALSE;
 865
 866                 race_PostSpawn(spot);
 867
 868                 //stuffcmd(self, "chase_active 0");
 869                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 870
 871                 if(g_assault) {
 872                         if(self.team == assault_attacker_team)
 873                                 centerprint(self, "You are attacking!");
 874                         else
 875                                 centerprint(self, "You are defending!");
 876                 }
 877
 878                 target_voicescript_clear(self);
 879
 880                 // reset fields the weapons may use
 881                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 882                 {
 883                         weapon_action(j, WR_RESETPLAYER);
 884
 885                         // all weapons must be fully loaded when we spawn
 886                         entity e;
 887                         e = get_weaponinfo(j);
 888                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 889                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 890                 }
 891
 892                 oldself = self;
 893                 self = spot;
 894                         activator = oldself;
 895                                 string s;
 896                                 s = self.target;
 897                                 self.target = string_null;
 898                                 SUB_UseTargets();
 899                                 self.target = s;
 900                         activator = world;
 901                 self = oldself;
 902
 903                 spawn_spot = spot;
 904                 MUTATOR_CALLHOOK(PlayerSpawn);
 905
 906                 if(autocvar_spawn_debug)
 907                 {
 908                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 909                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 910                 }
 911
 912                 self.switchweapon = w_getbestweapon(self);
 913                 self.cnt = -1; // W_LastWeapon will not complain
 914                 self.weapon = 0;
 915                 self.weaponname = "";
 916                 self.switchingweapon = 0;
 917
 918                 if(!self.alivetime)
 919                         self.alivetime = time;
 920
 921                 antilag_clear(self);
 922
 923                 if (autocvar_g_spawnsound)
 924                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 925         } else if(self.classname == "observer") {
 926                 PutObserverInServer ();
 927         }
 928
 929         //if(g_ctf)
 930         //      ctf_playerchanged();
 931 }
 932
 933 .float ebouncefactor, ebouncestop; // electro's values
 934 // TODO do we need all these fields, or should we stop autodetecting runtime
 935 // changes and just have a console command to update this?
 936 float ClientInit_SendEntity(entity to, float sf)
 937 {
 938         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 939         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 952         if(sv_foginterval && world.fog != "")
 953                 WriteString(MSG_ENTITY, world.fog);
 954         else
 955                 WriteString(MSG_ENTITY, "");
 956         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 957         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 958         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 959         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 960         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 961         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 964         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 966         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 967         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 968         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 969         return TRUE;
 970 }
 971
 972 void ClientInit_CheckUpdate()
 973 {
 974         self.nextthink = time;
 975         if(self.count != autocvar_g_balance_armor_blockpercent)
 976         {
 977                 self.count = autocvar_g_balance_armor_blockpercent;
 978                 self.SendFlags |= 1;
 979         }
 980         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 981         {
 982                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 983                 self.SendFlags |= 1;
 984         }
 985         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 986         {
 987                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 988                 self.SendFlags |= 1;
 989         }
 990         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 991         {
 992                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 993                 self.SendFlags |= 1;
 994         }
 995         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 996         {
 997                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 998                 self.SendFlags |= 1;
 999         }
1000         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1001         {
1002                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1003                 self.SendFlags |= 1;
1004         }
1005 }
1006
1007 void ClientInit_Spawn()
1008 {
1009         entity o;
1010         entity e;
1011         e = spawn();
1012         e.classname = "clientinit";
1013         e.think = ClientInit_CheckUpdate;
1014         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1015
1016         o = self;
1017         self = e;
1018         ClientInit_CheckUpdate();
1019         self = o;
1020 }
1021
1022 /*
1023 =============
1024 SetNewParms
1025 =============
1026 */
1027 void SetNewParms (void)
1028 {
1029         // initialize parms for a new player
1030         parm1 = -(86400 * 366);
1031 }
1032
1033 /*
1034 =============
1035 SetChangeParms
1036 =============
1037 */
1038 void SetChangeParms (void)
1039 {
1040         // save parms for level change
1041         parm1 = self.parm_idlesince - time;
1042 }
1043
1044 /*
1045 =============
1046 DecodeLevelParms
1047 =============
1048 */
1049 void DecodeLevelParms (void)
1050 {
1051         // load parms
1052         self.parm_idlesince = parm1;
1053         if(self.parm_idlesince == -(86400 * 366))
1054                 self.parm_idlesince = time;
1055
1056         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1057         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1058 }
1059
1060 /*
1061 =============
1062 ClientKill
1063
1064 Called when a client types 'kill' in the console
1065 =============
1066 */
1067
1068 .float clientkill_nexttime;
1069 void ClientKill_Now_TeamChange()
1070 {
1071         if(self.killindicator_teamchange == -1)
1072         {
1073                 JoinBestTeam( self, FALSE, TRUE );
1074         }
1075         else if(self.killindicator_teamchange == -2)
1076         {
1077                 if(g_ca)
1078                         self.caplayer = 0;
1079                 if(blockSpectators)
1080                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1081                 PutObserverInServer();
1082         }
1083         else
1084                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1085 }
1086
1087 void ClientKill_Now()
1088 {
1089         if(self.vehicle)
1090         {
1091             vehicles_exit(VHEF_RELESE);
1092             if(!self.killindicator_teamchange)
1093             {
1094             self.vehicle_health = -1;
1095             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1096             }
1097         }
1098
1099         if(self.killindicator && !wasfreed(self.killindicator))
1100                 remove(self.killindicator);
1101
1102         self.killindicator = world;
1103
1104         if(self.killindicator_teamchange)
1105                 ClientKill_Now_TeamChange();
1106
1107         // in any case:
1108         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1109
1110         // now I am sure the player IS dead
1111 }
1112 void KillIndicator_Think()
1113 {
1114         if (gameover)
1115         {
1116                 self.owner.killindicator = world;
1117                 remove(self);
1118                 return;
1119         }
1120
1121         if (self.owner.alpha < 0 && !self.owner.vehicle)
1122         {
1123                 self.owner.killindicator = world;
1124                 remove(self);
1125                 return;
1126         }
1127
1128         if(self.cnt <= 0)
1129         {
1130                 self = self.owner;
1131                 ClientKill_Now(); // no oldself needed
1132                 return;
1133         }
1134     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1135     {
1136         self.nextthink = time + 1;
1137         self.cnt -= 1;
1138     }
1139         else
1140         {
1141                 if(self.cnt <= 10)
1142                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1143                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1144                 {
1145                         if(self.cnt <= 10)
1146                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1147                 }
1148                 self.nextthink = time + 1;
1149                 self.cnt -= 1;
1150         }
1151 }
1152
1153 float clientkilltime;
1154 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1155 {
1156         float killtime;
1157         float starttime;
1158         entity e;
1159
1160         if (gameover)
1161                 return;
1162
1163         killtime = autocvar_g_balance_kill_delay;
1164
1165         if(g_race_qualifying || g_cts)
1166                 killtime = 0;
1167
1168     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1169     {
1170                 remove(self.killindicator);
1171                 self.killindicator = world;
1172
1173         ClientKill_Now(); // allow instant kill in this case
1174         return;
1175     }
1176
1177         self.killindicator_teamchange = targetteam;
1178
1179     if(!self.killindicator)
1180         {
1181                 if(self.deadflag == DEAD_NO)
1182                 {
1183                         killtime = max(killtime, self.clientkill_nexttime - time);
1184                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1185                 }
1186
1187                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1188                 {
1189                         ClientKill_Now();
1190                 }
1191                 else
1192                 {
1193                         starttime = max(time, clientkilltime);
1194
1195                         self.killindicator = spawn();
1196                         self.killindicator.owner = self;
1197                         self.killindicator.scale = 0.5;
1198                         setattachment(self.killindicator, self, "");
1199                         setorigin(self.killindicator, '0 0 52');
1200                         self.killindicator.think = KillIndicator_Think;
1201                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1202                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1203                         self.killindicator.cnt = ceil(killtime);
1204                         self.killindicator.count = bound(0, ceil(killtime), 10);
1205                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1206
1207                         for(e = world; (e = find(e, classname, "body")) != world; )
1208                         {
1209                                 if(e.enemy != self)
1210                                         continue;
1211                                 e.killindicator = spawn();
1212                                 e.killindicator.owner = e;
1213                                 e.killindicator.scale = 0.5;
1214                                 setattachment(e.killindicator, e, "");
1215                                 setorigin(e.killindicator, '0 0 52');
1216                                 e.killindicator.think = KillIndicator_Think;
1217                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1218                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1219                                 e.killindicator.cnt = ceil(killtime);
1220                         }
1221                         self.lip = 0;
1222                 }
1223         }
1224         if(self.killindicator)
1225         {
1226                 if(targetteam == 0) // just die
1227                 {
1228                         self.killindicator.colormod = '0 0 0';
1229                         if(clienttype(self) == CLIENTTYPE_REAL)
1230                         if(self.killindicator.cnt > 0)
1231                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1232                 }
1233                 else if(targetteam == -1) // auto
1234                 {
1235                         self.killindicator.colormod = '0 1 0';
1236                         if(clienttype(self) == CLIENTTYPE_REAL)
1237                         if(self.killindicator.cnt > 0)
1238                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1239                 }
1240                 else if(targetteam == -2) // spectate
1241                 {
1242                         self.killindicator.colormod = '0.5 0.5 0.5';
1243                         if(clienttype(self) == CLIENTTYPE_REAL)
1244                         if(self.killindicator.cnt > 0)
1245                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1246                 }
1247                 else
1248                 {
1249                         self.killindicator.colormod = TeamColor(targetteam);
1250                         if(clienttype(self) == CLIENTTYPE_REAL)
1251                         if(self.killindicator.cnt > 0)
1252                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1253                 }
1254         }
1255
1256 }
1257
1258 void ClientKill (void)
1259 {
1260         if (gameover)
1261                 return;
1262
1263         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1264         {
1265                 // do nothing
1266         }
1267     else if(self.freezetag_frozen)
1268     {
1269         // do nothing
1270     }
1271         else
1272                 ClientKill_TeamChange(0);
1273 }
1274
1275 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1276 {
1277     e.killindicator = spawn();
1278     e.killindicator.owner = e;
1279     e.killindicator.think = KillIndicator_Think;
1280     e.killindicator.nextthink = time + (e.lip) * 0.05;
1281     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1282     e.killindicator.health = 1; // this is used to indicate that it should be silent
1283     e.lip = 0;
1284 }
1285
1286 void FixClientCvars(entity e)
1287 {
1288         // send prediction settings to the client
1289         stuffcmd(e, "\nin_bindmap 0 0\n");
1290         if(g_race || g_cts)
1291                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1292         if(autocvar_g_antilag == 3) // client side hitscan
1293                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1294         if(sv_gentle)
1295                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1296         /*
1297          * we no longer need to stuff this. Remove this comment block if you feel
1298          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1299         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1300         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1301         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1302         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1303         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1304         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1305         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1306         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1307         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1308         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1309         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1310         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1311         stuffcmd(e, "cl_movement_edgefriction 1\n");
1312          */
1313 }
1314
1315 float PlayerInIDList(entity p, string idlist)
1316 {
1317         float n, i;
1318         string s;
1319
1320         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1321         if not(p.crypto_idfp)
1322                 return 0;
1323
1324         // this function allows abbreviated player IDs too!
1325         n = tokenize_console(idlist);
1326         for(i = 0; i < n; ++i)
1327         {
1328                 s = argv(i);
1329                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1330                         return 1;
1331         }
1332
1333         return 0;
1334 }
1335
1336 /*
1337 =============
1338 ClientConnect
1339
1340 Called when a client connects to the server
1341 =============
1342 */
1343 //void ctf_clientconnect();
1344 string ColoredTeamName(float t);
1345 void DecodeLevelParms (void);
1346 //void dom_player_join_team(entity pl);
1347 void set_dom_state(entity e);
1348 void ClientConnect (void)
1349 {
1350         float t;
1351
1352         if(self.flags & FL_CLIENT)
1353         {
1354                 print("Warning: ClientConnect, but already connected!\n");
1355                 return;
1356         }
1357
1358         if(Ban_MaybeEnforceBanOnce(self))
1359                 return;
1360
1361         DecodeLevelParms();
1362
1363 #ifdef WATERMARK
1364         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1365 #endif
1366
1367         self.classname = "player_joining";
1368
1369         self.flags = FL_CLIENT;
1370         self.version_nagtime = time + 10 + random() * 10;
1371
1372         if(player_count<0)
1373         {
1374                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1375                 player_count = 0;
1376         }
1377
1378         PlayerScore_Attach(self);
1379         ClientData_Attach();
1380         accuracy_init(self);
1381
1382         bot_clientconnect();
1383
1384         playerdemo_init();
1385
1386         anticheat_init();
1387
1388         race_PreSpawnObserver();
1389
1390         //if(g_domination)
1391         //      dom_player_join_team(self);
1392
1393         // identify the right forced team
1394         if(autocvar_g_campaign)
1395         {
1396                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1397                 {
1398                         switch(autocvar_g_campaign_forceteam)
1399                         {
1400                                 case 1: self.team_forced = COLOR_TEAM1; break;
1401                                 case 2: self.team_forced = COLOR_TEAM2; break;
1402                                 case 3: self.team_forced = COLOR_TEAM3; break;
1403                                 case 4: self.team_forced = COLOR_TEAM4; break;
1404                                 default: self.team_forced = 0;
1405                         }
1406                 }
1407         }
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1409                 self.team_forced = COLOR_TEAM1;
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1411                 self.team_forced = COLOR_TEAM2;
1412         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1413                 self.team_forced = COLOR_TEAM3;
1414         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1415                 self.team_forced = COLOR_TEAM4;
1416         else if(autocvar_g_forced_team_otherwise == "red")
1417                 self.team_forced = COLOR_TEAM1;
1418         else if(autocvar_g_forced_team_otherwise == "blue")
1419                 self.team_forced = COLOR_TEAM2;
1420         else if(autocvar_g_forced_team_otherwise == "yellow")
1421                 self.team_forced = COLOR_TEAM3;
1422         else if(autocvar_g_forced_team_otherwise == "pink")
1423                 self.team_forced = COLOR_TEAM4;
1424         else if(autocvar_g_forced_team_otherwise == "spectate")
1425                 self.team_forced = -1;
1426         else if(autocvar_g_forced_team_otherwise == "spectator")
1427                 self.team_forced = -1;
1428         else
1429                 self.team_forced = 0;
1430
1431         if(!teamplay)
1432                 if(self.team_forced > 0)
1433                         self.team_forced = 0;
1434
1435         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1436
1437         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1438                 self.classname = "observer";
1439         } else {
1440                 if(teamplay)
1441                 {
1442                         if(autocvar_g_balance_teams)
1443                         {
1444                                 self.classname = "player";
1445                                 campaign_bots_may_start = 1;
1446                         }
1447                         else
1448                         {
1449                                 self.classname = "observer"; // do it anyway
1450                         }
1451                 }
1452                 else
1453                 {
1454                         self.classname = "player";
1455                         campaign_bots_may_start = 1;
1456                 }
1457         }
1458
1459         self.playerid = (playerid_last = playerid_last + 1);
1460
1461         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1462
1463     if(clienttype(self) == CLIENTTYPE_BOT)
1464         PlayerStats_AddPlayer(self);
1465
1466         if(autocvar_sv_eventlog)
1467                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1468
1469         LogTeamchange(self.playerid, self.team, 1);
1470
1471         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1472
1473         self.netname_previous = strzone(self.netname);
1474
1475         bprint("^4", self.netname, "^4 connected");
1476
1477         if(self.classname != "observer" && (g_domination || g_ctf))
1478                 bprint(" and joined the ", ColoredTeamName(self.team));
1479
1480         bprint("\n");
1481
1482         stuffcmd(self, strcat(clientstuff, "\n"));
1483         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1484
1485         FixClientCvars(self);
1486
1487         // spawnfunc_waypoint sprites
1488         WaypointSprite_InitClient(self);
1489
1490         // Wazat's grappling hook
1491         SetGrappleHookBindings();
1492
1493         // get version info from player
1494         stuffcmd(self, "cmd clientversion $gameversion\n");
1495
1496         // get other cvars from player
1497         GetCvars(0);
1498
1499         // notify about available teams
1500         if(teamplay)
1501         {
1502                 CheckAllowedTeams(self);
1503                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1504                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1505         }
1506         else
1507                 stuffcmd(self, "set _teams_available 0\n");
1508
1509         if(g_arena || g_ca)
1510         {
1511                 self.classname = "observer";
1512                 if(g_arena)
1513                         Spawnqueue_Insert(self);
1514         }
1515         /*else if(g_ctf)
1516         {
1517                 ctf_clientconnect();
1518         }*/
1519
1520         attach_entcs();
1521
1522         bot_relinkplayerlist();
1523
1524         self.spectatortime = time;
1525         if(blockSpectators)
1526         {
1527                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1528         }
1529
1530         self.jointime = time;
1531         self.allowed_timeouts = autocvar_sv_timeout_number;
1532
1533         if(clienttype(self) == CLIENTTYPE_REAL)
1534         {
1535                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1536                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1537         }
1538
1539         if(g_lms)
1540         {
1541                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1542                 {
1543                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1544                         self.frags = FRAGS_SPECTATOR;
1545                 }
1546         }
1547
1548         if(!sv_foginterval && world.fog != "")
1549                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1550
1551         SoundEntity_Attach(self);
1552
1553         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1554         {
1555                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1556                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1557         }
1558         else
1559                 self.hitplotfh = -1;
1560
1561         if(g_race || g_cts) {
1562                 string rr;
1563                 if(g_cts)
1564                         rr = CTS_RECORD;
1565                 else
1566                         rr = RACE_RECORD;
1567
1568                 msg_entity = self;
1569                 race_send_recordtime(MSG_ONE);
1570                 race_send_speedaward(MSG_ONE);
1571
1572                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1573                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1574                 race_send_speedaward_alltimebest(MSG_ONE);
1575
1576                 float i;
1577                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1578                         race_SendRankings(i, 0, 0, MSG_ONE);
1579                 }
1580         }
1581         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1582                 send_CSQC_teamnagger();
1583
1584         if (g_domination)
1585                 set_dom_state(self);
1586
1587         CheatInitClient();
1588
1589         if(!autocvar_g_campaign)
1590                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1591
1592         CSQCMODEL_AUTOINIT();
1593
1594         self.model_randomizer = random();
1595
1596     if(clienttype(self) != CLIENTTYPE_REAL)
1597         return;
1598
1599     sv_notice_join();
1600
1601     MUTATOR_CALLHOOK(ClientConnect);
1602 }
1603 /*
1604 =============
1605 ClientDisconnect
1606
1607 Called when a client disconnects from the server
1608 =============
1609 */
1610 .entity chatbubbleentity;
1611 void ReadyCount();
1612 void ClientDisconnect (void)
1613 {
1614         if(self.vehicle)
1615             vehicles_exit(VHEF_RELESE);
1616
1617         if not(self.flags & FL_CLIENT)
1618         {
1619                 print("Warning: ClientDisconnect without ClientConnect\n");
1620                 return;
1621         }
1622
1623         PlayerStats_AddGlobalInfo(self);
1624
1625         CheatShutdownClient();
1626
1627         if(self.hitplotfh >= 0)
1628         {
1629                 fclose(self.hitplotfh);
1630                 self.hitplotfh = -1;
1631         }
1632
1633         anticheat_report();
1634         anticheat_shutdown();
1635
1636         playerdemo_shutdown();
1637
1638         bot_clientdisconnect();
1639
1640         if(self.entcs)
1641                 detach_entcs();
1642
1643         if(autocvar_sv_eventlog)
1644                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1645         bprint ("^4",self.netname);
1646         bprint ("^4 disconnected\n");
1647
1648         SoundEntity_Detach(self);
1649
1650         DropAllRunes(self);
1651         MUTATOR_CALLHOOK(ClientDisconnect);
1652
1653         Portal_ClearAll(self);
1654
1655         RemoveGrapplingHook(self);
1656         if(self.flagcarried)
1657                 DropFlag(self.flagcarried, world, world);
1658
1659         // Here, everything has been done that requires this player to be a client.
1660
1661         self.flags &~= FL_CLIENT;
1662
1663         if (self.chatbubbleentity)
1664                 remove (self.chatbubbleentity);
1665
1666         if (self.killindicator)
1667                 remove (self.killindicator);
1668
1669         WaypointSprite_PlayerGone();
1670
1671         bot_relinkplayerlist();
1672
1673         if(g_arena)
1674         {
1675                 Spawnqueue_Unmark(self);
1676                 Spawnqueue_Remove(self);
1677         }
1678
1679         accuracy_free(self);
1680         ClientData_Detach();
1681         PlayerScore_Detach(self);
1682
1683         if(self.netname_previous)
1684                 strunzone(self.netname_previous);
1685         if(self.clientstatus)
1686                 strunzone(self.clientstatus);
1687         if(self.weaponorder_byimpulse)
1688                 strunzone(self.weaponorder_byimpulse);
1689
1690         ClearPlayerSounds();
1691
1692         if(self.personal)
1693                 remove(self.personal);
1694
1695         self.playerid = 0;
1696         ReadyCount();
1697
1698         // free cvars
1699         GetCvars(-1);
1700 }
1701
1702 .float BUTTON_CHAT;
1703 void ChatBubbleThink()
1704 {
1705         self.nextthink = time;
1706         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1707         {
1708                 if(self.owner) // but why can that ever be world?
1709                         self.owner.chatbubbleentity = world;
1710                 remove(self);
1711                 return;
1712         }
1713         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1714 #ifdef TETRIS
1715                 || self.owner.tetris_on
1716 #endif
1717         )
1718                 self.model = self.mdl;
1719         else
1720                 self.model = "";
1721 }
1722
1723 void UpdateChatBubble()
1724 {
1725         if (self.alpha < 0)
1726                 return;
1727         // spawn a chatbubble entity if needed
1728         if (!self.chatbubbleentity)
1729         {
1730                 self.chatbubbleentity = spawn();
1731                 self.chatbubbleentity.owner = self;
1732                 self.chatbubbleentity.exteriormodeltoclient = self;
1733                 self.chatbubbleentity.think = ChatBubbleThink;
1734                 self.chatbubbleentity.nextthink = time;
1735                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1736                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1737                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1738                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1739                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1740                 self.chatbubbleentity.model = "";
1741                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1742         }
1743 }
1744
1745
1746 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1747 // added to the model skins
1748 /*void UpdateColorModHack()
1749 {
1750         float c;
1751         c = self.clientcolors & 15;
1752         // LordHavoc: only bothering to support white, green, red, yellow, blue
1753              if (!teamplay) self.colormod = '0 0 0';
1754         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1755         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1756         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1757         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1758         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1759         else self.colormod = '1 1 1';
1760 }*/
1761
1762 void respawn(void)
1763 {
1764         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1765         {
1766                 self.solid = SOLID_NOT;
1767                 self.takedamage = DAMAGE_NO;
1768                 self.movetype = MOVETYPE_FLY;
1769                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1770                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1771                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1772                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1773                 if(autocvar_g_respawn_ghosts_maxtime)
1774                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1775         }
1776
1777         CopyBody(1);
1778
1779         self.effects |= EF_NODRAW; // prevent another CopyBody
1780         PutClientInServer();
1781 }
1782
1783 void play_countdown(float finished, string samp)
1784 {
1785         if(clienttype(self) == CLIENTTYPE_REAL)
1786                 if(floor(finished - time - frametime) != floor(finished - time))
1787                         if(finished - time < 6)
1788                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1789 }
1790
1791 void player_powerups (void)
1792 {
1793         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1794         olditems = self.items;
1795
1796         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1797         {
1798                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1799                 self.modelflags |= MF_ROCKET;
1800         }
1801         else
1802         {
1803                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1804                 self.modelflags &~= MF_ROCKET;
1805         }
1806
1807         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1808
1809         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1810                 return;
1811
1812         Fire_ApplyDamage(self);
1813         Fire_ApplyEffect(self);
1814
1815         if (g_minstagib)
1816         {
1817                 self.effects |= EF_FULLBRIGHT;
1818
1819                 if (self.items & IT_STRENGTH)
1820                 {
1821                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1822                         if (time > self.strength_finished)
1823                         {
1824                                 self.alpha = default_player_alpha;
1825                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1826                                 self.items &~= IT_STRENGTH;
1827                                 sprint(self, "^3Invisibility has worn off\n");
1828                         }
1829                 }
1830                 else
1831                 {
1832                         if (time < self.strength_finished)
1833                         {
1834                                 self.alpha = g_minstagib_invis_alpha;
1835                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1836                                 self.items |= IT_STRENGTH;
1837                                 sprint(self, "^3You are invisible\n");
1838                         }
1839                 }
1840
1841                 if (self.items & IT_INVINCIBLE)
1842                 {
1843                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1844                         if (time > self.invincible_finished)
1845                         {
1846                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1847                                 sprint(self, "^3Speed has worn off\n");
1848                         }
1849                 }
1850                 else
1851                 {
1852                         if (time < self.invincible_finished)
1853                         {
1854                                 self.items = self.items | IT_INVINCIBLE;
1855                                 sprint(self, "^3You are on speed\n");
1856                         }
1857                 }
1858         }
1859         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1860         {
1861                 if (self.items & IT_STRENGTH)
1862                 {
1863                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1864                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1865                         if (time > self.strength_finished)
1866                         {
1867                                 self.items = self.items - (self.items & IT_STRENGTH);
1868                                 sprint(self, "^3Strength has worn off\n");
1869                         }
1870                 }
1871                 else
1872                 {
1873                         if (time < self.strength_finished)
1874                         {
1875                                 self.items = self.items | IT_STRENGTH;
1876                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1877                         }
1878                 }
1879                 if (self.items & IT_INVINCIBLE)
1880                 {
1881                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1882                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1883                         if (time > self.invincible_finished)
1884                         {
1885                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1886                                 sprint(self, "^3Shield has worn off\n");
1887                         }
1888                 }
1889                 else
1890                 {
1891                         if (time < self.invincible_finished)
1892                         {
1893                                 self.items = self.items | IT_INVINCIBLE;
1894                                 sprint(self, "^3Shield surrounds you\n");
1895                         }
1896                 }
1897                 if (self.items & IT_SUPERWEAPON)
1898                 {
1899                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1900                         {
1901                                 self.superweapons_finished = 0;
1902                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1903                                 sprint(self, "^3Superweapons have been lost\n");
1904                         }
1905                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1906                         {
1907                                 // don't let them run out
1908                         }
1909                         else
1910                         {
1911                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1912                                 if (time > self.superweapons_finished)
1913                                 {
1914                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1915                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1916                                         sprint(self, "^3Superweapons have broken down\n");
1917                                 }
1918                         }
1919                 }
1920                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1921                 {
1922                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1923                         {
1924                                 self.items = self.items | IT_SUPERWEAPON;
1925                                 sprint(self, "^3You now have a superweapon\n");
1926                         }
1927                         else
1928                         {
1929                                 self.superweapons_finished = 0;
1930                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1931                         }
1932                 }
1933                 else
1934                 {
1935                         self.superweapons_finished = 0;
1936                 }
1937         }
1938
1939         if(autocvar_g_nodepthtestplayers)
1940                 self.effects = self.effects | EF_NODEPTHTEST;
1941
1942         if(autocvar_g_fullbrightplayers)
1943                 self.effects = self.effects | EF_FULLBRIGHT;
1944
1945         // midair gamemode: damage only while in the air
1946         // if in midair mode, being on ground grants temporary invulnerability
1947         // (this is so that multishot weapon don't clear the ground flag on the
1948         // first damage in the frame, leaving the player vulnerable to the
1949         // remaining hits in the same frame)
1950         if (self.flags & FL_ONGROUND)
1951         if (g_midair)
1952                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1953
1954         if (time >= game_starttime)
1955         if (time < self.spawnshieldtime)
1956                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1957
1958         MUTATOR_CALLHOOK(PlayerPowerups);
1959 }
1960
1961 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1962 {
1963         if(current > stable)
1964                 return current;
1965         else if(current > stable - 0.25) // when close enough, "snap"
1966                 return stable;
1967         else
1968                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1969 }
1970
1971 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1972 {
1973         if(current < stable)
1974                 return current;
1975         else if(current < stable + 0.25) // when close enough, "snap"
1976                 return stable;
1977         else
1978                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1979 }
1980
1981 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1982 {
1983         if(current > rotstable)
1984         {
1985                 if(rotframetime > 0)
1986                 {
1987                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1988                         current = max(rotstable, current - rotlinear * rotframetime);
1989                 }
1990         }
1991         else if(current < regenstable)
1992         {
1993                 if(regenframetime > 0)
1994                 {
1995                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1996                         current = min(regenstable, current + regenlinear * regenframetime);
1997                 }
1998         }
1999
2000         if(current > limit)
2001                 current = limit;
2002
2003         return current;
2004 }
2005
2006 void player_regen (void)
2007 {
2008         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2009         maxh = autocvar_g_balance_health_rotstable;
2010         maxa = autocvar_g_balance_armor_rotstable;
2011         maxf = autocvar_g_balance_fuel_rotstable;
2012         minh = autocvar_g_balance_health_regenstable;
2013         mina = autocvar_g_balance_armor_regenstable;
2014         minf = autocvar_g_balance_fuel_regenstable;
2015         limith = autocvar_g_balance_health_limit;
2016         limita = autocvar_g_balance_armor_limit;
2017         limitf = autocvar_g_balance_fuel_limit;
2018
2019         max_mod = regen_mod = rot_mod = limit_mod = 1;
2020
2021         if (self.runes & RUNE_REGEN)
2022         {
2023                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2024                 {
2025                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2026                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2027                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2028                 }
2029                 else
2030                 {
2031                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2032                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2033                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2034                 }
2035         }
2036         else if (self.runes & CURSE_VENOM)
2037         {
2038                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2039                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2040                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2041                 else
2042                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2043                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2044                 //if (!self.runes & RUNE_REGEN)
2045                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2046         }
2047         maxh = maxh * max_mod;
2048         //maxa = maxa * max_mod;
2049         //maxf = maxf * max_mod;
2050         minh = minh * max_mod;
2051         //mina = mina * max_mod;
2052         //minf = minf * max_mod;
2053         limith = limith * limit_mod;
2054         limita = limita * limit_mod;
2055         //limitf = limitf * limit_mod;
2056
2057         if(g_lms && g_ca)
2058                 rot_mod = 0;
2059
2060         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2061         {
2062                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2063                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2064
2065                 // if player rotted to death...  die!
2066                 if(self.health < 1)
2067                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2068         }
2069
2070         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2071                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2072 }
2073
2074 float zoomstate_set;
2075 void SetZoomState(float z)
2076 {
2077         if(z != self.zoomstate)
2078         {
2079                 self.zoomstate = z;
2080                 ClientData_Touch(self);
2081         }
2082         zoomstate_set = 1;
2083 }
2084
2085 void GetPressedKeys(void) {
2086         MUTATOR_CALLHOOK(GetPressedKeys);
2087         if (self.movement_x > 0) // get if movement keys are pressed
2088         {       // forward key pressed
2089                 self.pressedkeys |= KEY_FORWARD;
2090                 self.pressedkeys &~= KEY_BACKWARD;
2091         }
2092         else if (self.movement_x < 0)
2093         {       // backward key pressed
2094                 self.pressedkeys |= KEY_BACKWARD;
2095                 self.pressedkeys &~= KEY_FORWARD;
2096         }
2097         else
2098         {       // no x input
2099                 self.pressedkeys &~= KEY_FORWARD;
2100                 self.pressedkeys &~= KEY_BACKWARD;
2101         }
2102
2103         if (self.movement_y > 0)
2104         {       // right key pressed
2105                 self.pressedkeys |= KEY_RIGHT;
2106                 self.pressedkeys &~= KEY_LEFT;
2107         }
2108         else if (self.movement_y < 0)
2109         {       // left key pressed
2110                 self.pressedkeys |= KEY_LEFT;
2111                 self.pressedkeys &~= KEY_RIGHT;
2112         }
2113         else
2114         {       // no y input
2115                 self.pressedkeys &~= KEY_RIGHT;
2116                 self.pressedkeys &~= KEY_LEFT;
2117         }
2118
2119         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2120                 self.pressedkeys |= KEY_JUMP;
2121         else
2122                 self.pressedkeys &~= KEY_JUMP;
2123         if (self.BUTTON_CROUCH)
2124                 self.pressedkeys |= KEY_CROUCH;
2125         else
2126                 self.pressedkeys &~= KEY_CROUCH;
2127
2128         if (self.BUTTON_ATCK)
2129                 self.pressedkeys |= KEY_ATCK;
2130         else
2131                 self.pressedkeys &~= KEY_ATCK;
2132         if (self.BUTTON_ATCK2)
2133                 self.pressedkeys |= KEY_ATCK2;
2134         else
2135                 self.pressedkeys &~= KEY_ATCK2;
2136 }
2137
2138 /*
2139 ======================
2140 spectate mode routines
2141 ======================
2142 */
2143
2144 void SpectateCopy(entity spectatee) {
2145         other = spectatee;
2146         MUTATOR_CALLHOOK(SpectateCopy);
2147         self.armortype = spectatee.armortype;
2148         self.armorvalue = spectatee.armorvalue;
2149         self.ammo_cells = spectatee.ammo_cells;
2150         self.ammo_shells = spectatee.ammo_shells;
2151         self.ammo_nails = spectatee.ammo_nails;
2152         self.ammo_rockets = spectatee.ammo_rockets;
2153         self.ammo_fuel = spectatee.ammo_fuel;
2154         self.clip_load = spectatee.clip_load;
2155         self.clip_size = spectatee.clip_size;
2156         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2157         self.health = spectatee.health;
2158         self.impulse = 0;
2159         self.items = spectatee.items;
2160         self.last_pickup = spectatee.last_pickup;
2161         self.hit_time = spectatee.hit_time;
2162         self.metertime = spectatee.metertime;
2163         self.strength_finished = spectatee.strength_finished;
2164         self.invincible_finished = spectatee.invincible_finished;
2165         self.pressedkeys = spectatee.pressedkeys;
2166         WEPSET_COPY_EE(self, spectatee);
2167         self.switchweapon = spectatee.switchweapon;
2168         self.switchingweapon = spectatee.switchingweapon;
2169         self.weapon = spectatee.weapon;
2170         self.nex_charge = spectatee.nex_charge;
2171         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2172         self.hagar_load = spectatee.hagar_load;
2173         self.minelayer_mines = spectatee.minelayer_mines;
2174         self.punchangle = spectatee.punchangle;
2175         self.view_ofs = spectatee.view_ofs;
2176         self.velocity = spectatee.velocity;
2177         self.dmg_take = spectatee.dmg_take;
2178         self.dmg_save = spectatee.dmg_save;
2179         self.dmg_inflictor = spectatee.dmg_inflictor;
2180         self.v_angle = spectatee.v_angle;
2181         self.angles = spectatee.v_angle;
2182         if(!self.BUTTON_USE)
2183                 self.fixangle = TRUE;
2184         setorigin(self, spectatee.origin);
2185         setsize(self, spectatee.mins, spectatee.maxs);
2186         SetZoomState(spectatee.zoomstate);
2187
2188     anticheat_spectatecopy(spectatee);
2189         self.hud = spectatee.hud;
2190         if(spectatee.vehicle)
2191     {
2192         self.fixangle = FALSE;
2193         //self.velocity = spectatee.vehicle.velocity;
2194         self.vehicle_health = spectatee.vehicle_health;
2195         self.vehicle_shield = spectatee.vehicle_shield;
2196         self.vehicle_energy = spectatee.vehicle_energy;
2197         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2198         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2199         self.vehicle_reload1 = spectatee.vehicle_reload1;
2200         self.vehicle_reload2 = spectatee.vehicle_reload2;
2201
2202         msg_entity = self;
2203
2204         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2205             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2206             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2207             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2208
2209         //WriteByte (MSG_ONE, SVC_SETVIEW);
2210         //    WriteEntity(MSG_ONE, self);
2211         //makevectors(spectatee.v_angle);
2212         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2213     }
2214 }
2215
2216 float SpectateUpdate() {
2217         if(!self.enemy)
2218             return 0;
2219
2220         if (self == self.enemy)
2221                 return 0;
2222
2223         if(self.enemy.classname != "player")
2224                 return 0;
2225
2226         SpectateCopy(self.enemy);
2227
2228         return 1;
2229 }
2230
2231
2232 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2233 entity CA_SpectateNext(entity start) {
2234         if (start.team == self.team) {
2235                 return start;
2236         }
2237
2238         other = start;
2239         // continue from current player
2240         while(other && other.team != self.team) {
2241                 other = find(other, classname, "player");
2242         }
2243
2244         if (!other) {
2245                 // restart from begining
2246                 other = find(other, classname, "player");
2247                 while(other && other.team != self.team) {
2248                         other = find(other, classname, "player");
2249                 }
2250         }
2251
2252         return other;
2253 }
2254
2255 float SpectateNext(entity _prefer) {
2256
2257         if(_prefer)
2258                 other = _prefer;
2259         else
2260                 other = find(self.enemy, classname, "player");
2261
2262         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2263                 // CA and ca players when spectating enemies is forbidden
2264                 other = CA_SpectateNext(other);
2265         } else {
2266                 // other modes and ca spectators or spectating enemies is allowed
2267                 if (!other)
2268                         other = find(other, classname, "player");
2269         }
2270
2271         if (other)
2272                 self.enemy = other;
2273
2274         if(self.enemy.classname == "player") {
2275             /*if(self.enemy.vehicle)
2276             {
2277
2278             msg_entity = self;
2279             WriteByte(MSG_ONE, SVC_SETVIEW);
2280             WriteEntity(MSG_ONE, self.enemy);
2281             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2282
2283             self.movetype = MOVETYPE_NONE;
2284             accuracy_resend(self);
2285             }
2286             else
2287             {*/
2288             msg_entity = self;
2289             WriteByte(MSG_ONE, SVC_SETVIEW);
2290             WriteEntity(MSG_ONE, self.enemy);
2291             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2292             self.movetype = MOVETYPE_NONE;
2293             accuracy_resend(self);
2294
2295             if(!SpectateUpdate())
2296                 PutObserverInServer();
2297         //}
2298         return 1;
2299         } else {
2300                 return 0;
2301         }
2302 }
2303
2304 /*
2305 =============
2306 ShowRespawnCountdown()
2307
2308 Update a respawn countdown display.
2309 =============
2310 */
2311 void ShowRespawnCountdown()
2312 {
2313         float number;
2314         if(self.deadflag == DEAD_NO) // just respawned?
2315                 return;
2316         else
2317         {
2318                 number = ceil(self.respawn_time - time);
2319                 if(number <= 0)
2320                         return;
2321                 if(number <= self.respawn_countdown)
2322                 {
2323                         self.respawn_countdown = number - 1;
2324                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2325                                 AnnounceTo(self, strcat(ftos(number), ""));
2326                 }
2327         }
2328 }
2329
2330 .float prevent_join_msgtime;
2331 void LeaveSpectatorMode()
2332 {
2333         if(nJoinAllowed(self)) {
2334                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2335                         self.classname = "player";
2336
2337                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2338                                 JoinBestTeam(self, FALSE, TRUE);
2339
2340                         if(autocvar_g_campaign)
2341                                 campaign_bots_may_start = 1;
2342
2343                         PutClientInServer();
2344
2345                         if(self.classname == "player")
2346                                 bprint ("^4", self.netname, "^4 is playing now\n");
2347
2348                         if(!autocvar_g_campaign)
2349                         if (time < self.jointime + autocvar_welcome_message_time)
2350                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2351
2352                         if (self.prevent_join_msgtime)
2353                         {
2354                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2355                                 self.prevent_join_msgtime = 0;
2356                         }
2357
2358                         return;
2359                 } else {
2360                         if (g_ca && self.caplayer) {
2361                         }       // do nothing
2362                         else
2363                                 stuffcmd(self,"menu_showteamselect\n");
2364                         return;
2365                 }
2366         }
2367         else {
2368                 //player may not join because of g_maxplayers is set
2369                 if (time - self.prevent_join_msgtime > 2)
2370                 {
2371                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2372                         self.prevent_join_msgtime = time;
2373                 }
2374         }
2375 }
2376
2377 /**
2378  * Determines whether the player is allowed to join. This depends on cvar
2379  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2380  * it checks whether the number of currently playing players exceeds g_maxplayers.
2381  * @return int number of free slots for players, 0 if none
2382  */
2383 float nJoinAllowed(entity ignore) {
2384         if(!ignore)
2385         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2386         // so report 0 free slots if restricted
2387         {
2388                 if(autocvar_g_forced_team_otherwise == "spectate")
2389                         return 0;
2390                 if(autocvar_g_forced_team_otherwise == "spectator")
2391                         return 0;
2392         }
2393
2394         if(self.team_forced < 0)
2395                 return 0; // forced spectators can never join
2396
2397         // TODO simplify this
2398         entity e;
2399         float totalClients = 0;
2400         FOR_EACH_CLIENT(e)
2401                 if(e != ignore)
2402                         totalClients += 1;
2403
2404         if (!autocvar_g_maxplayers)
2405                 return maxclients - totalClients;
2406
2407         float currentlyPlaying = 0;
2408         FOR_EACH_REALPLAYER(e)
2409                 currentlyPlaying += 1;
2410
2411         if(currentlyPlaying < autocvar_g_maxplayers)
2412                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2413
2414         return 0;
2415 }
2416
2417 /**
2418  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2419  * g_maxplayers_spectator_blocktime seconds
2420  */
2421 void checkSpectatorBlock() {
2422         if(self.classname == "spectator" || self.classname == "observer") {
2423                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2424                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2425                         dropclient(self);
2426                 }
2427         }
2428 }
2429
2430 .float motd_actived_time; // used for both motd and campaign_message
2431 void PrintWelcomeMessage()
2432 {
2433         if (self.motd_actived_time == 0) { // is there already a message showing?
2434                 if (autocvar_g_campaign) {
2435                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2436                                 self.motd_actived_time = time;
2437                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2438                         }
2439                 } else {
2440                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2441                                 self.motd_actived_time = time;
2442                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2443                         }
2444                 }
2445         } else { // showing MOTD or campaign message
2446                 if (autocvar_g_campaign) {
2447                         if (self.BUTTON_INFO)
2448                                 self.motd_actived_time = time;
2449                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2450                                 self.motd_actived_time = 0;
2451                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2452                         }
2453                 } else {
2454                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2455                                 if (self.BUTTON_INFO)
2456                                         self.motd_actived_time = time;
2457                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2458                                         self.motd_actived_time = 0;
2459                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2460                                 }
2461                         }
2462                 }
2463         }
2464 }
2465
2466 void ObserverThink()
2467 {
2468         float prefered_movetype;
2469         if (self.flags & FL_JUMPRELEASED) {
2470                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2471                         self.flags &~= FL_JUMPRELEASED;
2472                         self.flags |= FL_SPAWNING;
2473                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2474                         self.flags &~= FL_JUMPRELEASED;
2475                         if(SpectateNext(world) == 1) {
2476                                 self.classname = "spectator";
2477                         }
2478                 } else {
2479                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2480                         if (self.movetype != prefered_movetype)
2481                                 self.movetype = prefered_movetype;
2482                 }
2483         } else {
2484                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2485                         self.flags |= FL_JUMPRELEASED;
2486                         if(self.flags & FL_SPAWNING)
2487                         {
2488                                 self.flags &~= FL_SPAWNING;
2489                                 LeaveSpectatorMode();
2490                                 return;
2491                         }
2492                 }
2493         }
2494
2495         PrintWelcomeMessage();
2496 }
2497
2498 void SpectatorThink()
2499 {
2500         if (self.flags & FL_JUMPRELEASED) {
2501                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2502                         self.flags &~= FL_JUMPRELEASED;
2503                         self.flags |= FL_SPAWNING;
2504                 } else if(self.BUTTON_ATCK) {
2505                         self.flags &~= FL_JUMPRELEASED;
2506                         if(SpectateNext(world) == 1) {
2507                                 self.classname = "spectator";
2508                         } else {
2509                                 self.classname = "observer";
2510                                 PutClientInServer();
2511                         }
2512                 } else if (self.BUTTON_ATCK2) {
2513                         self.flags &~= FL_JUMPRELEASED;
2514                         self.classname = "observer";
2515                         PutClientInServer();
2516                 } else {
2517                         if(!SpectateUpdate())
2518                                 PutObserverInServer();
2519                 }
2520         } else {
2521                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2522                         self.flags |= FL_JUMPRELEASED;
2523                         if(self.flags & FL_SPAWNING)
2524                         {
2525                                 self.flags &~= FL_SPAWNING;
2526                                 LeaveSpectatorMode();
2527                                 return;
2528                         }
2529                 }
2530                 if(!SpectateUpdate())
2531                         PutObserverInServer();
2532         }
2533
2534         PrintWelcomeMessage();
2535         self.flags |= FL_CLIENT | FL_NOTARGET;
2536 }
2537
2538 float ctf_usekey();
2539 void PlayerUseKey()
2540 {
2541         if(self.classname != "player")
2542                 return;
2543
2544         if(self.vehicle)
2545         {
2546         vehicles_exit(VHEF_NORMAL);
2547         return;
2548         }
2549
2550         // a use key was pressed; call handlers
2551         if(ctf_usekey())
2552                 return;
2553
2554         MUTATOR_CALLHOOK(PlayerUseKey);
2555 }
2556
2557 .float touchexplode_time;
2558
2559 /*
2560 =============
2561 PlayerPreThink
2562
2563 Called every frame for each client before the physics are run
2564 =============
2565 */
2566 .float usekeypressed;
2567 void() ctf_setstatus;
2568 void() nexball_setstatus;
2569 .float items_added;
2570 void PlayerPreThink (void)
2571 {
2572         WarpZone_PlayerPhysics_FixVAngle();
2573
2574         self.stat_game_starttime = game_starttime;
2575         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2576         self.stat_leadlimit = autocvar_leadlimit;
2577
2578         if(frametime)
2579         {
2580                 // physics frames: update anticheat stuff
2581                 anticheat_prethink();
2582         }
2583
2584         if(blockSpectators && frametime)
2585                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2586                 checkSpectatorBlock();
2587
2588         zoomstate_set = 0;
2589
2590         if(self.netname_previous != self.netname)
2591         {
2592                 if(autocvar_sv_eventlog)
2593                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2594                 if(self.netname_previous)
2595                         strunzone(self.netname_previous);
2596                 self.netname_previous = strzone(self.netname);
2597         }
2598
2599         // version nagging
2600         if(self.version_nagtime)
2601                 if(self.cvar_g_xonoticversion)
2602                         if(time > self.version_nagtime)
2603                         {
2604                                 // don't notify git users
2605                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2606                                 {
2607                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2608                                         {
2609                                                 // notify release users if connecting to git
2610                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2611                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2612                                         }
2613                                         else
2614                                         {
2615                                                 float r;
2616                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2617                                                 if(r < 0)
2618                                                 {
2619                                                         // give users new version
2620                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2621                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2622                                                 }
2623                                                 else if(r > 0)
2624                                                 {
2625                                                         // notify users about old server version
2626                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2627                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2628                                                 }
2629                                         }
2630                                 }
2631                                 self.version_nagtime = 0;
2632                         }
2633
2634         // GOD MODE info
2635         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2636         {
2637                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2638                 self.max_armorvalue = 0;
2639         }
2640
2641 #ifdef TETRIS
2642         if (TetrisPreFrame())
2643                 return;
2644 #endif
2645
2646         MUTATOR_CALLHOOK(PlayerPreThink);
2647
2648         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2649         {
2650                 if(self.BUTTON_USE && !self.usekeypressed)
2651                         PlayerUseKey();
2652                 self.usekeypressed = self.BUTTON_USE;
2653         }
2654
2655         PrintWelcomeMessage();
2656
2657         if(self.classname == "player") {
2658 //              if(self.netname == "Wazat")
2659 //                      bprint(self.classname, "\n");
2660
2661                 CheckRules_Player();
2662
2663                 if (intermission_running)
2664                 {
2665                         IntermissionThink ();   // otherwise a button could be missed between
2666                         return;                                 // the think tics
2667                 }
2668
2669                 //don't allow the player to turn around while game is paused!
2670                 if(timeout_status == TIMEOUT_ACTIVE) {
2671                         // FIXME turn this into CSQC stuff
2672                         self.v_angle = self.lastV_angle;
2673                         self.angles = self.lastV_angle;
2674                         self.fixangle = TRUE;
2675                 }
2676
2677                 if(frametime)
2678                 {
2679 #ifndef NO_LEGACY_NETWORKING
2680                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2681 #endif
2682
2683                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2684                         {
2685                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2686                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2687                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2688
2689                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2690                                 {
2691                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2692                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2693                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2694                                 }
2695                         }
2696                         else
2697                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2698
2699                         player_powerups();
2700                 }
2701
2702                 if (g_minstagib)
2703                         minstagib_ammocheck();
2704
2705                 if (self.deadflag != DEAD_NO)
2706                 {
2707                         float button_pressed, force_respawn;
2708                         if(self.personal && g_race_qualifying)
2709                         {
2710                                 if(time > self.respawn_time)
2711                                 {
2712                                         self.respawn_time = time + 1; // only retry once a second
2713                                         respawn();
2714                                         self.impulse = 141;
2715                                 }
2716                         }
2717                         else
2718                         {
2719                                 if(frametime)
2720                                         player_anim();
2721                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2722                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2723                                 if (self.deadflag == DEAD_DYING)
2724                                 {
2725                                         if(force_respawn)
2726                                                 self.deadflag = DEAD_RESPAWNING;
2727                                         else if(!button_pressed)
2728                                                 self.deadflag = DEAD_DEAD;
2729                                 }
2730                                 else if (self.deadflag == DEAD_DEAD)
2731                                 {
2732                                         if(button_pressed)
2733                                                 self.deadflag = DEAD_RESPAWNABLE;
2734                                 }
2735                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2736                                 {
2737                                         if(!button_pressed)
2738                                                 self.deadflag = DEAD_RESPAWNING;
2739                                 }
2740                                 else if (self.deadflag == DEAD_RESPAWNING)
2741                                 {
2742                                         if(time > self.respawn_time)
2743                                         {
2744                                                 self.respawn_time = time + 1; // only retry once a second
2745                                                 respawn();
2746                                         }
2747                                 }
2748                                 ShowRespawnCountdown();
2749                         }
2750                         return;
2751                 }
2752                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2753                 // so (self.deadflag == DEAD_NO) is always true in the code below
2754
2755                 if(g_touchexplode)
2756                 if(time > self.touchexplode_time)
2757                 if(self.classname == "player")
2758                 if(self.deadflag == DEAD_NO)
2759                 if not(IS_INDEPENDENT_PLAYER(self))
2760                 FOR_EACH_PLAYER(other) if(self != other)
2761                 {
2762                         if(time > other.touchexplode_time)
2763                         if(other.deadflag == DEAD_NO)
2764                         if not(IS_INDEPENDENT_PLAYER(other))
2765                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2766                         {
2767                                 PlayerTouchExplode(self, other);
2768                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2769                         }
2770                 }
2771
2772                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2773                 {
2774                         vector dist;
2775
2776                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2777                         dist = self.prevorigin - self.origin;
2778                         dist_z = 0;
2779                         self.lms_traveled_distance += fabs(vlen(dist));
2780
2781                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2782                         {
2783                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2784                                 self.lms_traveled_distance = 0;
2785                         }
2786
2787                         if(time > self.lms_nextcheck)
2788                         {
2789                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2790                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2791                                 {
2792                                         centerprint(self, autocvar_g_lms_campcheck_message);
2793                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2794                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2795                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2796                                 }
2797                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2798                                 self.lms_traveled_distance = 0;
2799                         }
2800                 }
2801
2802                 self.prevorigin = self.origin;
2803
2804                 if (!self.vehicle)
2805                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2806                 {
2807                         if (!self.crouch)
2808                         {
2809                                 self.crouch = TRUE;
2810                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2811                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2812                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2813                         }
2814                 }
2815                 else
2816                 {
2817                         if (self.crouch)
2818                         {
2819                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2820                                 if (!trace_startsolid)
2821                                 {
2822                                         self.crouch = FALSE;
2823                                         self.view_ofs = PL_VIEW_OFS;
2824                                         setsize (self, PL_MIN, PL_MAX);
2825                                 }
2826                         }
2827                 }
2828
2829                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2830                 {
2831                         if(self.bloodloss_timer < time)
2832                         {
2833                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2834                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2835                         }
2836                 }
2837
2838                 FixPlayermodel();
2839
2840                 GrapplingHookFrame();
2841
2842                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2843                 //if(frametime)
2844                 {
2845                         self.items &~= self.items_added;
2846
2847                         W_WeaponFrame();
2848
2849                         self.items_added = 0;
2850                         if(self.items & IT_JETPACK)
2851                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2852                                         self.items_added |= IT_FUEL;
2853
2854                         self.items |= self.items_added;
2855                 }
2856
2857                 player_regen();
2858
2859                 // rot nex charge to the charge limit
2860                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2861                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2862
2863                 if(frametime)
2864                         player_anim();
2865
2866                 if(g_ctf)
2867                         ctf_setstatus();
2868
2869                 if(g_nexball)
2870                         nexball_setstatus();
2871
2872                 // secret status
2873                 secrets_setstatus();
2874
2875                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2876
2877                 //self.angles_y=self.v_angle_y + 90;   // temp
2878         } else if(gameover) {
2879                 if (intermission_running)
2880                         IntermissionThink ();   // otherwise a button could be missed between
2881                 return;
2882         } else if(self.classname == "observer") {
2883                 ObserverThink();
2884         } else if(self.classname == "spectator") {
2885                 SpectatorThink();
2886         }
2887
2888         if(!zoomstate_set)
2889                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2890
2891         float oldspectatee_status;
2892         oldspectatee_status = self.spectatee_status;
2893         if(self.classname == "spectator")
2894                 self.spectatee_status = num_for_edict(self.enemy);
2895         else if(self.classname == "observer")
2896                 self.spectatee_status = num_for_edict(self);
2897         else
2898                 self.spectatee_status = 0;
2899         if(self.spectatee_status != oldspectatee_status)
2900         {
2901                 ClientData_Touch(self);
2902                 if(g_race || g_cts)
2903                         race_InitSpectator();
2904         }
2905
2906         if(self.teamkill_soundtime)
2907         if(time > self.teamkill_soundtime)
2908         {
2909                 self.teamkill_soundtime = 0;
2910
2911                 entity oldpusher, oldself;
2912
2913                 oldself = self; self = self.teamkill_soundsource;
2914                 oldpusher = self.pusher; self.pusher = oldself;
2915
2916                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2917
2918                 self.pusher = oldpusher;
2919                 self = oldself;
2920         }
2921
2922         if(self.taunt_soundtime)
2923         if(time > self.taunt_soundtime)
2924         {
2925                 self.taunt_soundtime = 0;
2926                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2927         }
2928
2929         target_voicescript_next(self);
2930
2931         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2932         if(!self.weapon)
2933                 self.clip_load = self.clip_size = 0;
2934 }
2935
2936 float isInvisibleString(string s)
2937 {
2938         float i, n, c;
2939         s = strdecolorize(s);
2940         for((i = 0), (n = strlen(s)); i < n; ++i)
2941         {
2942                 c = str2chr(s, i);
2943                 switch(c)
2944                 {
2945                         case 0:
2946                         case 32: // space
2947                                 break;
2948                         case 192: // charmap space
2949                                 if (!autocvar_utf8_enable)
2950                                         break;
2951                                 return FALSE;
2952                         case 160: // space in unicode fonts
2953                         case 0xE000 + 192: // utf8 charmap space
2954                                 if (autocvar_utf8_enable)
2955                                         break;
2956                         default:
2957                                 return FALSE;
2958                 }
2959         }
2960         return TRUE;
2961 }
2962
2963 /*
2964 =============
2965 PlayerPostThink
2966
2967 Called every frame for each client after the physics are run
2968 =============
2969 */
2970 .float idlekick_lasttimeleft;
2971 .entity showheadshotbbox;
2972 void showheadshotbbox_think()
2973 {
2974         if(self.owner.showheadshotbbox != self)
2975         {
2976                 remove(self);
2977                 return;
2978         }
2979         self.nextthink = time;
2980         setorigin(self, self.owner.origin);
2981         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2982 }
2983 void PlayerPostThink (void)
2984 {
2985         // Savage: Check for nameless players
2986         if (isInvisibleString(self.netname)) {
2987                 self.netname = "Player";
2988                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2989         }
2990
2991         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2992         {
2993                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2994                 {
2995                         if(self.idlekick_lasttimeleft)
2996                         {
2997                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2998                                 self.idlekick_lasttimeleft = 0;
2999                         }
3000                 }
3001                 else
3002                 {
3003                         float timeleft;
3004                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3005                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3006                         {
3007                                 if(!self.idlekick_lasttimeleft)
3008                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3009                         }
3010                         if(timeleft <= 0)
3011                         {
3012                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3013                                 AnnounceTo(self, "terminated");
3014                                 dropclient(self);
3015                                 return;
3016                         }
3017                         else if(timeleft <= 10)
3018                         {
3019                                 if(timeleft != self.idlekick_lasttimeleft)
3020                                         AnnounceTo(self, ftos(timeleft));
3021                                 self.idlekick_lasttimeleft = timeleft;
3022                         }
3023                 }
3024         }
3025
3026 #ifdef TETRIS
3027         if(self.impulse == 100)
3028                 ImpulseCommands();
3029         if (!TetrisPostFrame())
3030         {
3031 #endif
3032
3033         CheatFrame();
3034
3035         //CheckPlayerJump();
3036
3037         if(self.classname == "player") {
3038                 CheckRules_Player();
3039                 UpdateChatBubble();
3040                 if (self.impulse)
3041                         ImpulseCommands();
3042                 if (intermission_running)
3043                         return;         // intermission or finale
3044                 GetPressedKeys();
3045         } else if (self.classname == "observer") {
3046                 //do nothing
3047         } else if (self.classname == "spectator") {
3048                 //do nothing
3049         }
3050
3051 #ifdef TETRIS
3052         }
3053 #endif
3054
3055         /*
3056         float i;
3057         for(i = 0; i < 1000; ++i)
3058         {
3059                 vector end;
3060                 end = self.origin + '0 0 1024' + 512 * randomvec();
3061                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3062                 if(trace_fraction < 1)
3063                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3064                 {
3065                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3066                         break;
3067                 }
3068         }
3069         */
3070
3071         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3072
3073         if(self.waypointsprite_attachedforcarrier)
3074                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3075
3076         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3077         {
3078                 if(!self.showheadshotbbox)
3079                 {
3080                         self.showheadshotbbox = spawn();
3081                         self.showheadshotbbox.classname = "headshotbbox";
3082                         self.showheadshotbbox.owner = self;
3083                         self.showheadshotbbox.think = showheadshotbbox_think;
3084                         self.showheadshotbbox.nextthink = time;
3085                         self = self.showheadshotbbox;
3086                         self.think();
3087                         self = self.owner;
3088                 }
3089         }
3090         else
3091         {
3092                 if(self.showheadshotbbox)
3093                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3094                 remove(self.showheadshotbbox);
3095         }
3096
3097         playerdemo_write();
3098
3099         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3100         {
3101                 if(!self.stored_netname)
3102                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3103                 if(self.stored_netname != self.netname)
3104                 {
3105                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3106                         strunzone(self.stored_netname);
3107                         self.stored_netname = strzone(self.netname);
3108                 }
3109         }
3110
3111         /*
3112         if(g_race)
3113                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3114         */
3115
3116         CSQCMODEL_AUTOUPDATE();
3117 }