qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_setupmodel(entity wp);
 288 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 289 {
 290         if (!(wp_from && wp_to))
 291                 return;
 292
 293         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 294         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 295         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 296         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 297         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 298         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 299         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 300         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 301
 302         return;
 303 }
 304
 305 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 306 {
 307         if (!(wp_from && wp_to))
 308                 return;
 309
 310         int removed = -1;
 311         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 312         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 313         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 314         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 315         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 316         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 317         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 318         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 319
 320         if (removed >= 0)
 321         {
 322                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 323                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 324                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 325                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 326                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 327                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 328                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 329                 if (removed <= 7) wp_from.wphw07 = NULL;
 330                 if (!wp_from.wphw00)
 331                         waypoint_setupmodel(wp_from);
 332         }
 333
 334         return;
 335 }
 336
 337 void waypoint_setupmodel(entity wp)
 338 {
 339         if (autocvar_g_waypointeditor)
 340         {
 341                 // TODO: add some sort of visible box in edit mode for box waypoints
 342                 vector m1 = wp.mins;
 343                 vector m2 = wp.maxs;
 344                 setmodel(wp, MDL_WAYPOINT);
 345                 setsize(wp, m1, m2);
 346                 wp.effects = EF_LOWPRECISION;
 347                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 348                         wp.colormod = '1 0 0';
 349                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 350                         wp.colormod = '1 1 0';
 351                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 352                         wp.colormod = '1 0.5 0'; // orange
 353                 else if (waypoint_has_hardwiredlinks(wp))
 354                         wp.colormod = '0.5 0 1'; // purple
 355                 else
 356                         wp.colormod = '1 1 1';
 357         }
 358         else
 359                 wp.model = "";
 360 }
 361
 362 entity waypoint_get(vector m1, vector m2)
 363 {
 364         if (m1 == m2)
 365         {
 366                 m1 -= '8 8 8';
 367                 m2 += '8 8 8';
 368         }
 369         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 370
 371         return NULL;
 372 }
 373
 374 .float createdtime;
 375 entity waypoint_spawn(vector m1, vector m2, float f)
 376 {
 377         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 378         {
 379                 entity wp_found = waypoint_get(m1, m2);
 380                 if (wp_found)
 381                         return wp_found;
 382         }
 383         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 384         // otherwise links loaded from file would be applied only to the first destination
 385         // waypoint since link format doesn't specify waypoint entities but just positions
 386         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 387         {
 388                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 389                 {
 390                         return it;
 391                 });
 392         }
 393
 394         entity w = new(waypoint);
 395         IL_PUSH(g_waypoints, w);
 396         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 397         w.wpflags = f;
 398         w.solid = SOLID_TRIGGER;
 399         w.createdtime = time;
 400         setorigin(w, (m1 + m2) * 0.5);
 401         setsize(w, m1 - w.origin, m2 - w.origin);
 402         if (w.size)
 403                 w.wpisbox = true;
 404
 405         if(!w.wpisbox)
 406         {
 407                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 408                 if(!move_out_of_solid(w))
 409                 {
 410                         if(!(f & WAYPOINTFLAG_GENERATED))
 411                         {
 412                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 413                                 delete(w);
 414                                 return NULL;
 415                         }
 416                         else
 417                         {
 418                                 if(autocvar_developer)
 419                                 {
 420                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 421                                         backtrace("Waypoint stuck");
 422                                 }
 423                         }
 424                 }
 425                 setsize(w, '0 0 0', '0 0 0');
 426         }
 427
 428         waypoint_clearlinks(w);
 429         //waypoint_schedulerelink(w);
 430
 431         waypoint_setupmodel(w);
 432
 433         return w;
 434 }
 435
 436 float trigger_push_get_push_time(entity this, vector endpos);
 437 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 438 {
 439         entity jp = NULL;
 440         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 441         {
 442                 jp = it;
 443                 break;
 444         });
 445         if (!jp)
 446                 return;
 447
 448         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 449         wp_from.wp00 = wp_to;
 450         wp_from.wp00mincost = cost;
 451         jp.nearestwaypoint = wp_from;
 452         jp.nearestwaypointtimeout = -1;
 453 }
 454
 455 bool start_wp_is_spawned;
 456 vector start_wp_origin;
 457 bool start_wp_is_hardwired;
 458
 459 void waypoint_clear_start_wp(entity pl, bool warn)
 460 {
 461         start_wp_is_spawned = false;
 462         start_wp_origin = '0 0 0';
 463         pl.wp_locked = NULL;
 464         start_wp_is_hardwired = false;
 465         if (warn)
 466                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 467 }
 468
 469 void waypoint_start_hardwiredlink(entity pl)
 470 {
 471         entity wp = pl.nearestwaypoint;
 472         if ((!start_wp_is_spawned || start_wp_is_hardwired) && wp && !(wp.wpflags & WAYPOINTFLAG_NORELINK))
 473         {
 474                 start_wp_is_hardwired = true;
 475                 start_wp_is_spawned = true;
 476                 start_wp_origin = wp.origin;
 477                 pl.wp_locked = wp;
 478                 LOG_INFOF("^x80fNearest waypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 479         }
 480         else
 481                 start_wp_is_hardwired = false;
 482 }
 483
 484 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp)
 485 {
 486         if (WAYPOINT_VERSION < waypoint_version_loaded)
 487         {
 488                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 489                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 490                 return;
 491         }
 492
 493         entity e = NULL, jp = NULL;
 494         vector org = pl.origin;
 495         if (at_crosshair)
 496         {
 497                 crosshair_trace(pl);
 498                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 499                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 500                 {
 501                         jp = it;
 502                         break;
 503                 });
 504         }
 505         if (jp || is_jump_wp)
 506         {
 507                 if (start_wp_is_spawned)
 508                         start_wp_is_spawned = false;
 509                 LOG_INFO("^xf80Spawning start waypoint...\n");
 510         }
 511         int ctf_flags = havocbot_symmetry_origin_order;
 512         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 513                    || (autocvar_g_waypointeditor_symmetrical < 0));
 514         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 515                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 516         if (sym && ctf_flags < 2)
 517                 ctf_flags = 2;
 518         int wp_num = ctf_flags;
 519
 520         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp)
 521         {
 522                 // snap waypoint to item's origin if close enough
 523                 IL_EACH(g_items, true,
 524                 {
 525                         vector item_org = (it.absmin + it.absmax) * 0.5;
 526                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 527                         if (vlen(item_org - org) < 20)
 528                         {
 529                                 org = item_org;
 530                                 break;
 531                         }
 532                 });
 533         }
 534
 535         vector start_org = '0 0 0';
 536         if (start_wp_is_spawned)
 537         {
 538                 if (!start_wp_is_hardwired)
 539                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 540                 start_org = start_wp_origin;
 541         }
 542
 543         // save org as it can be modified spawning symmetrycal waypoints
 544         vector initial_origin = '0 0 0';
 545         bool initial_origin_is_set = false;
 546
 547         LABEL(add_wp);
 548
 549         if (jp)
 550         {
 551                 e = NULL;
 552                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 553                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 554                 {
 555                         e = it; break;
 556                 });
 557                 if (!e)
 558                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 559                 if (!pl.wp_locked)
 560                         pl.wp_locked = e;
 561         }
 562         else if (is_jump_wp)
 563         {
 564                 entity wp_found = waypoint_get(org, org);
 565                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_JUMP))
 566                 {
 567                         LOG_INFO("Error: can't spawn a jump waypoint over an existent waypoint of a different type\n");
 568                         return;
 569                 }
 570                 e = waypoint_spawn(org, org, WAYPOINTFLAG_JUMP | WAYPOINTFLAG_NORELINK);
 571                 if (!pl.wp_locked)
 572                         pl.wp_locked = e;
 573         }
 574         else
 575                 e = waypoint_spawn(org, org, 0);
 576         if(!e)
 577         {
 578                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 579                 if (start_wp_is_spawned)
 580                         waypoint_clear_start_wp(pl, true);
 581                 return;
 582         }
 583
 584         if (!initial_origin_is_set)
 585         {
 586                 initial_origin = e.origin;
 587                 initial_origin_is_set = true;
 588         }
 589
 590         entity start_wp = NULL;
 591         if (start_wp_is_spawned)
 592         {
 593                 IL_EACH(g_waypoints, (start_wp_is_hardwired || it.wpflags & WAYPOINTFLAG_NORELINK)
 594                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 595                 {
 596                         start_wp = it; break;
 597                 });
 598                 if(!start_wp)
 599                 {
 600                         // should not happen
 601                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 602                         waypoint_clear_start_wp(pl, true);
 603                         return;
 604                 }
 605                 if (start_wp_is_hardwired)
 606                 {
 607                         if (waypoint_is_hardwiredlink(start_wp, e))
 608                         {
 609                                 waypoint_unmark_hardwiredlink(start_wp, e);
 610                                 waypoint_removelink(start_wp, e);
 611                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 612                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 613                         }
 614                         else
 615                         {
 616                                 if (e.createdtime == time)
 617                                 {
 618                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 619                                         waypoint_remove(e);
 620                                         waypoint_clear_start_wp(pl, true);
 621                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp);
 622                                         return;
 623                                 }
 624                                 if (start_wp == e)
 625                                 {
 626                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 627                                         waypoint_clear_start_wp(pl, true);
 628                                         return;
 629                                 }
 630                                 if (waypoint_islinked(start_wp, e))
 631                                 {
 632                                         LOG_INFO("Error: waypoints are already linked.\n");
 633                                         waypoint_clear_start_wp(pl, true);
 634                                         return;
 635                                 }
 636                                 waypoint_addlink(start_wp, e);
 637                                 waypoint_mark_hardwiredlink(start_wp, e);
 638                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 639                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 640                         }
 641                 }
 642                 else
 643                         waypoint_addlink(start_wp, e);
 644         }
 645
 646         if (!(jp || is_jump_wp || start_wp_is_hardwired))
 647                 waypoint_schedulerelink(e);
 648         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 649
 650         if (start_wp_is_spawned)
 651         {
 652                 pl.wp_locked = NULL;
 653                 if (!start_wp_is_hardwired)
 654                         waypoint_schedulerelink(start_wp);
 655                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 656                 {
 657                         if (start_wp.wp00_original == start_wp.wp00)
 658                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 659                         else
 660                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 661                 }
 662         }
 663
 664         if (sym)
 665         {
 666                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 667                 if (jp)
 668                 {
 669                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 670                         {
 671                                 jp = it; break;
 672                         });
 673                 }
 674                 if (start_wp_is_spawned)
 675                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 676                 if (vdist(org - pl.origin, >, 32))
 677                 {
 678                         if(wp_num > 2)
 679                                 wp_num--;
 680                         else
 681                                 sym = false;
 682                         goto add_wp;
 683                 }
 684         }
 685         if (jp || is_jump_wp)
 686         {
 687                 if (!start_wp_is_spawned)
 688                 {
 689                         // we've just created a custom jumppad waypoint
 690                         // the next one created by the user will be the destination waypoint
 691                         start_wp_is_spawned = true;
 692                         start_wp_origin = initial_origin;
 693                 }
 694         }
 695         else if (start_wp_is_spawned)
 696         {
 697                 waypoint_clear_start_wp(pl, false);
 698         }
 699 }
 700
 701 void waypoint_remove(entity wp)
 702 {
 703         IL_EACH(g_waypoints, it != wp,
 704         {
 705                 if (waypoint_islinked(it, wp))
 706                 {
 707                         if (waypoint_is_hardwiredlink(it, wp))
 708                                 waypoint_unmark_hardwiredlink(it, wp);
 709                         waypoint_removelink(it, wp);
 710                 }
 711         });
 712         delete(wp);
 713 }
 714
 715 void waypoint_remove_fromeditor(entity pl)
 716 {
 717         if (WAYPOINT_VERSION < waypoint_version_loaded)
 718         {
 719                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 720                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 721                 return;
 722         }
 723
 724         entity e = navigation_findnearestwaypoint(pl, false);
 725
 726         int ctf_flags = havocbot_symmetry_origin_order;
 727         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 728                    || (autocvar_g_waypointeditor_symmetrical < 0));
 729         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 730                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 731         if (sym && ctf_flags < 2)
 732                 ctf_flags = 2;
 733         int wp_num = ctf_flags;
 734
 735         LABEL(remove_wp);
 736         if (!e) return;
 737
 738         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 739         {
 740                 if (start_wp_is_spawned)
 741                         waypoint_clear_start_wp(pl, true);
 742                 return;
 743         }
 744
 745         if (waypoint_has_hardwiredlinks(e))
 746         {
 747                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 748                 return;
 749         }
 750
 751         entity wp_sym = NULL;
 752         if (sym)
 753         {
 754                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 755                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 756                         if(vdist(org - it.origin, <, 3))
 757                         {
 758                                 wp_sym = it;
 759                                 break;
 760                         }
 761                 });
 762         }
 763
 764         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 765         waypoint_remove(e);
 766
 767         if (sym && wp_sym)
 768         {
 769                 e = wp_sym;
 770                 if(wp_num > 2)
 771                         wp_num--;
 772                 else
 773                         sym = false;
 774                 goto remove_wp;
 775         }
 776
 777         if (start_wp_is_spawned)
 778                 waypoint_clear_start_wp(pl, true);
 779 }
 780
 781 void waypoint_removelink(entity from, entity to)
 782 {
 783         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & WAYPOINTFLAG_JUMP)))
 784                 return;
 785
 786         entity fromwp31_prev = from.wp31;
 787
 788         switch (waypoint_getlinknum(from, to))
 789         {
 790                 // fallthrough all the way
 791                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 792                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 793                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 794                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 795                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 796                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 797                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 798                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 799                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 800                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 801                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 802                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 803                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 804                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 805                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 806                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 807                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 808                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 809                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 810                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 811                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 812                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 813                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 814                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 815                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 816                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 817                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 818                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 819                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 820                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 821                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 822                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 823         }
 824
 825         if (fromwp31_prev && !from.wp31)
 826                 waypoint_schedulerelink(from);
 827 }
 828
 829 int waypoint_getlinknum(entity from, entity to)
 830 {
 831         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 832         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 833         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 834         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 835         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 836         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 837         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 838         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 839         return -1;
 840 }
 841
 842 bool waypoint_islinked(entity from, entity to)
 843 {
 844         return (waypoint_getlinknum(from, to) >= 0);
 845 }
 846
 847 void waypoint_updatecost_foralllinks()
 848 {
 849         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 850         {
 851                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 852                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 853                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 854                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 855                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 856                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 857                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 858                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 859                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 860                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 861                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 862                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 863                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 864                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 865                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 866                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 867                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 868                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 869                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 870                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 871                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 872                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 873                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 874                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 875                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 876                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 877                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 878                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 879                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 880                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 881                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 882                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 883         });
 884 }
 885
 886 float waypoint_getlinearcost(float dist)
 887 {
 888         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 889                 return dist / (autocvar_sv_maxspeed * 1.25);
 890         return dist / autocvar_sv_maxspeed;
 891 }
 892 float waypoint_getlinearcost_underwater(float dist)
 893 {
 894         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 895         return dist / (autocvar_sv_maxspeed * 0.7);
 896 }
 897
 898 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 899 {
 900         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 901         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 902
 903         if (submerged_from && submerged_to)
 904                 return waypoint_getlinearcost_underwater(vlen(to - from));
 905
 906         float c = waypoint_getlinearcost(vlen(to - from));
 907
 908         float height = from.z - to.z;
 909         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 910         {
 911                 float height_cost;
 912                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 913                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 914                 else
 915                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 916                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 917                 if(height_cost > c)
 918                         c = height_cost;
 919         }
 920
 921         if (submerged_from || submerged_to)
 922                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 923         return c;
 924 }
 925
 926 float waypoint_getlinkcost(entity from, entity to)
 927 {
 928         vector v1 = from.origin;
 929         vector v2 = to.origin;
 930         if (from.wpisbox)
 931         {
 932                 vector m1 = from.absmin, m2 = from.absmax;
 933                 v1.x = bound(m1.x, v2.x, m2.x);
 934                 v1.y = bound(m1.y, v2.y, m2.y);
 935                 v1.z = bound(m1.z, v2.z, m2.z);
 936         }
 937         if (to.wpisbox)
 938         {
 939                 vector m1 = to.absmin, m2 = to.absmax;
 940                 v2.x = bound(m1.x, v1.x, m2.x);
 941                 v2.y = bound(m1.y, v1.y, m2.y);
 942                 v2.z = bound(m1.z, v1.z, m2.z);
 943         }
 944         return waypoint_gettravelcost(v1, v2, from, to);
 945 }
 946
 947 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 948 // if c == -1 automatically determine cost of the link
 949 void waypoint_addlink_customcost(entity from, entity to, float c)
 950 {
 951         if (from == to || waypoint_islinked(from, to))
 952                 return;
 953         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & WAYPOINTFLAG_JUMP))
 954                 return;
 955
 956         if(c == -1)
 957                 c = waypoint_getlinkcost(from, to);
 958
 959         if (from.wp31mincost < c) return;
 960         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 961         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 962         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 963         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 964         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 965         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 966         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 967         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 968         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 969         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 970         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 971         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 972         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 973         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 974         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 975         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 976         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 977         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 978         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 979         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 980         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 981         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 982         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 983         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 984         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 985         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 986         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 987         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 988         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 989         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 990         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 991         from.wp00 = to;from.wp00mincost = c;return;
 992 }
 993
 994 void waypoint_addlink(entity from, entity to)
 995 {
 996         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP)))
 997                 waypoint_addlink_for_custom_jumppad(from, to);
 998         else
 999                 waypoint_addlink_customcost(from, to, -1);
1000 }
1001
1002 // relink this spawnfunc_waypoint
1003 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1004 // (SLOW!)
1005 void waypoint_think(entity this)
1006 {
1007         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1008         float sv2_height = 0, ev2_height = 0;
1009
1010         bot_calculate_stepheightvec();
1011
1012         int dphitcontentsmask_save = this.dphitcontentsmask;
1013         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1014
1015         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1016
1017         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1018         IL_EACH(g_waypoints, this != it,
1019         {
1020                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1021                 {
1022                         waypoint_addlink(this, it);
1023                         waypoint_addlink(it, this);
1024                 }
1025                 else
1026                 {
1027                         ++relink_total;
1028                         if(!checkpvs(this.origin, it))
1029                         {
1030                                 ++relink_pvsculled;
1031                                 continue;
1032                         }
1033
1034                         sv = set_tracewalk_dest_2(this, it.origin);
1035                         sv2 = tracewalk_dest;
1036                         sv2_height = tracewalk_dest_height;
1037                         ev = set_tracewalk_dest_2(it, this.origin);
1038                         ev2 = tracewalk_dest;
1039                         ev2_height = tracewalk_dest_height;
1040
1041                         dv = ev - sv;
1042                         dv.z = 0;
1043                         if(vdist(dv, >=, 1050)) // max search distance in XY
1044                         {
1045                                 ++relink_lengthculled;
1046                                 continue;
1047                         }
1048
1049                         navigation_testtracewalk = 0;
1050
1051                         //traceline(this.origin, it.origin, false, NULL);
1052                         //if (trace_fraction == 1)
1053                         if (this.wpisbox || this.wpflags & WAYPOINTFLAG_JUMP)
1054                                 relink_walkculled += 0.5;
1055                         else
1056                         {
1057                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
1058                                         waypoint_addlink(this, it);
1059                                 else
1060                                         relink_walkculled += 0.5;
1061                         }
1062
1063                         if (it.wpisbox || it.wpflags & WAYPOINTFLAG_JUMP)
1064                                 relink_walkculled += 0.5;
1065                         else
1066                         {
1067                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
1068                                         waypoint_addlink(it, this);
1069                                 else
1070                                         relink_walkculled += 0.5;
1071                         }
1072                 }
1073         });
1074         navigation_testtracewalk = 0;
1075         this.wplinked = true;
1076         this.dphitcontentsmask = dphitcontentsmask_save;
1077
1078         setthink(this, func_null);
1079         this.nextthink = 0;
1080 }
1081
1082 void waypoint_clearlinks(entity wp)
1083 {
1084         // clear links to other waypoints
1085         float f = 10000000;
1086         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1087         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1088         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1089         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1090
1091         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1092         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1093         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1094         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1095
1096         wp.wplinked = false;
1097 }
1098
1099 // tell a spawnfunc_waypoint to relink
1100 void waypoint_schedulerelink(entity wp)
1101 {
1102         if (wp == NULL)
1103                 return;
1104
1105         waypoint_setupmodel(wp);
1106         wp.wpisbox = vdist(wp.size, >, 0);
1107         wp.enemy = NULL;
1108         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1109                 wp.owner = NULL;
1110         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
1111                 waypoint_clearlinks(wp);
1112         // schedule an actual relink on next frame
1113         setthink(wp, waypoint_think);
1114         wp.nextthink = time;
1115         wp.effects = EF_LOWPRECISION;
1116 }
1117
1118 // spawnfunc_waypoint map entity
1119 spawnfunc(waypoint)
1120 {
1121         IL_PUSH(g_waypoints, this);
1122
1123         setorigin(this, this.origin);
1124         // schedule a relink after other waypoints have had a chance to spawn
1125         waypoint_clearlinks(this);
1126         //waypoint_schedulerelink(this);
1127 }
1128
1129 // tell all waypoints to relink
1130 // actually this is useful only to update relink_* stats
1131 void waypoint_schedulerelinkall()
1132 {
1133         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1134         IL_EACH(g_waypoints, true,
1135         {
1136                 waypoint_schedulerelink(it);
1137         });
1138         waypoint_load_hardwiredlinks();
1139 }
1140
1141 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1142
1143 // Load waypoint links from file
1144 bool waypoint_load_links()
1145 {
1146         string s;
1147         float file, tokens, c = 0, found;
1148         entity wp_from = NULL, wp_to;
1149         vector wp_to_pos, wp_from_pos;
1150
1151         string gt_ext = GET_GAMETYPE_EXTENSION();
1152
1153         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1154         file = fopen(filename, FILE_READ);
1155
1156         if (gt_ext != "" && file < 0)
1157         {
1158                 // if race waypoint file doesn't exist load the default one
1159                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1160                 file = fopen(filename, FILE_READ);
1161         }
1162
1163         if (file < 0)
1164         {
1165                 LOG_TRACE("waypoint links load from ", filename, " failed");
1166                 waypoint_schedulerelinkall();
1167                 return false;
1168         }
1169
1170         bool parse_comments = true;
1171         float ver = 0;
1172         string links_time = string_null;
1173
1174         while ((s = fgets(file)))
1175         {
1176                 if(parse_comments)
1177                 {
1178                         if(substring(s, 0, 2) == "//")
1179                         {
1180                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1181                                         ver = stof(substring(s, 19, -1));
1182                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1183                                         links_time = substring(s, 16, -1);
1184                                 continue;
1185                         }
1186                         else
1187                         {
1188                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1189                                 {
1190                                         if (links_time != waypoint_time)
1191                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1192                                         else
1193                                                 LOG_TRACE("waypoint links for this map are outdated.");
1194                                         if (g_assault)
1195                                         {
1196                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1197                                         }
1198                                         else
1199                                         {
1200                                                 LOG_TRACE("automatically updating...");
1201                                                 waypoint_schedulerelinkall();
1202                                                 fclose(file);
1203                                                 return false;
1204                                         }
1205                                 }
1206                                 parse_comments = false;
1207                         }
1208                 }
1209
1210                 tokens = tokenizebyseparator(s, "*");
1211
1212                 if (tokens!=2)
1213                 {
1214                         // bad file format
1215                         fclose(file);
1216                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1217                         return false;
1218                 }
1219
1220                 wp_from_pos     = stov(argv(0));
1221                 wp_to_pos       = stov(argv(1));
1222
1223                 // Search "from" waypoint
1224                 if(!wp_from || wp_from.origin!=wp_from_pos)
1225                 {
1226                         wp_from = findradius(wp_from_pos, 1);
1227                         found = false;
1228                         while(wp_from)
1229                         {
1230                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1231                                 if(wp_from.classname == "waypoint")
1232                                 {
1233                                         found = true;
1234                                         break;
1235                                 }
1236                                 wp_from = wp_from.chain;
1237                         }
1238
1239                         if(!found)
1240                         {
1241                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1242                                 continue;
1243                         }
1244                 }
1245
1246                 // Search "to" waypoint
1247                 wp_to = findradius(wp_to_pos, 1);
1248                 found = false;
1249                 while(wp_to)
1250                 {
1251                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1252                         if(wp_to.classname == "waypoint")
1253                         {
1254                                 found = true;
1255                                 break;
1256                         }
1257                         wp_to = wp_to.chain;
1258                 }
1259
1260                 if(!found)
1261                 {
1262                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1263                         continue;
1264                 }
1265
1266                 ++c;
1267                 waypoint_addlink(wp_from, wp_to);
1268                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1269                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1270         }
1271
1272         fclose(file);
1273
1274         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1275
1276         bool scheduled = false;
1277         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1278         {
1279                 if (!it.wp00)
1280                 {
1281                         waypoint_schedulerelink(it);
1282                         scheduled = true;
1283                 }
1284         });
1285         if (scheduled)
1286                 return false;
1287
1288         botframe_cachedwaypointlinks = true;
1289         return true;
1290 }
1291
1292 void waypoint_load_hardwiredlinks()
1293 {
1294         string s;
1295         float file, tokens, c = 0, found;
1296         entity wp_from = NULL, wp_to;
1297         vector wp_to_pos, wp_from_pos;
1298
1299         string gt_ext = GET_GAMETYPE_EXTENSION();
1300
1301         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1302         file = fopen(filename, FILE_READ);
1303
1304         if (gt_ext != "" && file < 0)
1305         {
1306                 // if race waypoint file doesn't exist load the default one
1307                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1308                 file = fopen(filename, FILE_READ);
1309         }
1310
1311         botframe_loadedforcedlinks = true;
1312
1313         if (file < 0)
1314         {
1315                 LOG_TRACE("waypoint links load from ", filename, " failed");
1316                 return;
1317         }
1318
1319         bool is_special = false;
1320         while ((s = fgets(file)))
1321         {
1322                 if(substring(s, 0, 2)=="//")
1323                         continue;
1324
1325                 if(substring(s, 0, 1)=="#")
1326                         continue;
1327
1328                 // special links start with *, so old xonotic versions don't load them
1329                 is_special = false;
1330                 if (substring(s, 0, 1) == "*")
1331                 {
1332                         is_special = true;
1333                         s = substring(s, 1, -1);
1334                 }
1335
1336                 tokens = tokenizebyseparator(s, "*");
1337
1338                 if (tokens!=2)
1339                         continue;
1340
1341                 wp_from_pos     = stov(argv(0));
1342                 wp_to_pos       = stov(argv(1));
1343
1344                 // Search "from" waypoint
1345                 if(!wp_from || wp_from.origin!=wp_from_pos)
1346                 {
1347                         wp_from = findradius(wp_from_pos, 5);
1348                         found = false;
1349                         while(wp_from)
1350                         {
1351                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1352                                 if(wp_from.classname == "waypoint")
1353                                 {
1354                                         found = true;
1355                                         break;
1356                                 }
1357                                 wp_from = wp_from.chain;
1358                         }
1359
1360                         if(!found)
1361                         {
1362                                 LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1363                                 continue;
1364                         }
1365                 }
1366
1367                 // Search "to" waypoint
1368                 wp_to = findradius(wp_to_pos, 5);
1369                 found = false;
1370                 while(wp_to)
1371                 {
1372                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1373                         if(wp_to.classname == "waypoint")
1374                         {
1375                                 found = true;
1376                                 break;
1377                         }
1378                         wp_to = wp_to.chain;
1379                 }
1380
1381                 if(!found)
1382                 {
1383                         LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1384                         continue;
1385                 }
1386
1387                 ++c;
1388
1389                 if (!is_special)
1390                 {
1391                         waypoint_addlink(wp_from, wp_to);
1392                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1393                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1394                         && (wp_from.wpflags & WAYPOINTFLAG_JUMP || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1395                 {
1396                         waypoint_addlink(wp_from, wp_to);
1397                 }
1398         }
1399
1400         fclose(file);
1401
1402         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1403 }
1404
1405 entity waypoint_get_link(entity w, float i)
1406 {
1407         switch(i)
1408         {
1409                 case  0:return w.wp00;
1410                 case  1:return w.wp01;
1411                 case  2:return w.wp02;
1412                 case  3:return w.wp03;
1413                 case  4:return w.wp04;
1414                 case  5:return w.wp05;
1415                 case  6:return w.wp06;
1416                 case  7:return w.wp07;
1417                 case  8:return w.wp08;
1418                 case  9:return w.wp09;
1419                 case 10:return w.wp10;
1420                 case 11:return w.wp11;
1421                 case 12:return w.wp12;
1422                 case 13:return w.wp13;
1423                 case 14:return w.wp14;
1424                 case 15:return w.wp15;
1425                 case 16:return w.wp16;
1426                 case 17:return w.wp17;
1427                 case 18:return w.wp18;
1428                 case 19:return w.wp19;
1429                 case 20:return w.wp20;
1430                 case 21:return w.wp21;
1431                 case 22:return w.wp22;
1432                 case 23:return w.wp23;
1433                 case 24:return w.wp24;
1434                 case 25:return w.wp25;
1435                 case 26:return w.wp26;
1436                 case 27:return w.wp27;
1437                 case 28:return w.wp28;
1438                 case 29:return w.wp29;
1439                 case 30:return w.wp30;
1440                 case 31:return w.wp31;
1441                 default:return NULL;
1442         }
1443 }
1444
1445 // Save all hardwired waypoint links to a file
1446 void waypoint_save_hardwiredlinks()
1447 {
1448         string gt_ext = GET_GAMETYPE_EXTENSION();
1449
1450         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1451         int file = fopen(filename, FILE_WRITE);
1452         if (file < 0)
1453         {
1454                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1455                 return;
1456         }
1457
1458         // write hardwired links to file
1459         fputs(file, "// HARDWIRED LINKS\n");
1460         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1461         {
1462                 for (int j = 0; j < 32; ++j)
1463                 {
1464                         entity link = waypoint_get_link(it, j);
1465                         if (waypoint_is_hardwiredlink(it, link))
1466                         {
1467                                 // NOTE: vtos rounds vector components to 1 decimal place
1468                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1469                                 fputs(file, s);
1470                         }
1471                 }
1472         });
1473
1474         // write special links to file
1475         fputs(file, "\n// SPECIAL LINKS\n");
1476         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP),
1477         {
1478                 for (int j = 0; j < 32; ++j)
1479                 {
1480                         entity link = waypoint_get_link(it, j);
1481                         if (link)
1482                         {
1483                                 // NOTE: vtos rounds vector components to 1 decimal place
1484                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1485                                 fputs(file, s);
1486                         }
1487                 }
1488         });
1489
1490         fclose(file);
1491
1492         LOG_INFOF("saved hardwired waypoint links to %s", filename);
1493 }
1494
1495 // Save all waypoint links to a file
1496 void waypoint_save_links()
1497 {
1498         string gt_ext = GET_GAMETYPE_EXTENSION();
1499
1500         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1501         int file = fopen(filename, FILE_WRITE);
1502         if (file < 0)
1503         {
1504                 LOG_INFOF("waypoint link save to %s failed", filename);
1505                 return;
1506         }
1507
1508         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1509         if (waypoint_time != "")
1510                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1511
1512         int c = 0;
1513         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP)),
1514         {
1515                 for(int j = 0; j < 32; ++j)
1516                 {
1517                         entity link = waypoint_get_link(it, j);
1518                         if (link && !waypoint_is_hardwiredlink(it, link))
1519                         {
1520                                 // NOTE: vtos rounds vector components to 1 decimal place
1521                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1522                                 fputs(file, s);
1523                                 ++c;
1524                         }
1525                 }
1526         });
1527         fclose(file);
1528
1529         botframe_cachedwaypointlinks = true;
1530
1531         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1532 }
1533
1534 // save waypoints to gamedir/data/maps/mapname.waypoints
1535 void waypoint_saveall()
1536 {
1537         if (WAYPOINT_VERSION < waypoint_version_loaded)
1538         {
1539                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1540                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1541                 return;
1542         }
1543         string gt_ext = GET_GAMETYPE_EXTENSION();
1544
1545         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1546         int file = fopen(filename, FILE_WRITE);
1547         if (file < 0)
1548         {
1549                 waypoint_save_links(); // save anyway?
1550                 botframe_loadedforcedlinks = false;
1551
1552                 LOG_INFOF("waypoint links: save to %s failed", filename);
1553                 return;
1554         }
1555
1556         float sym = autocvar_g_waypointeditor_symmetrical;
1557         string sym_str = ftos(sym);
1558         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1559         {
1560                 if (sym == 1)
1561                 {
1562                         sym_str = cons(sym_str, "-");
1563                         sym_str = cons(sym_str, "-");
1564                 }
1565                 else
1566                 {
1567                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1568                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1569                 }
1570                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1571                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1572         }
1573         else if (autocvar_g_waypointeditor_symmetrical == -2)
1574         {
1575                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1576                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1577         }
1578
1579         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1580         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1581         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1582         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1583
1584         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1585         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1586         //fputs(file, strcat("//", "\n"));
1587         //fputs(file, strcat("//", "\n"));
1588         //fputs(file, strcat("//", "\n"));
1589
1590         int c = 0;
1591         IL_EACH(g_waypoints, true,
1592         {
1593                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1594                         continue;
1595
1596                 string s;
1597                 // NOTE: vtos rounds vector components to 1 decimal place
1598                 s = strcat(vtos(it.origin + it.mins), "\n");
1599                 s = strcat(s, vtos(it.origin + it.maxs));
1600                 s = strcat(s, "\n");
1601                 s = strcat(s, ftos(it.wpflags));
1602                 s = strcat(s, "\n");
1603                 fputs(file, s);
1604                 c++;
1605         });
1606         fclose(file);
1607         waypoint_save_links();
1608         waypoint_save_hardwiredlinks();
1609
1610         botframe_loadedforcedlinks = false;
1611
1612         waypoint_version_loaded = WAYPOINT_VERSION;
1613         LOG_INFOF("saved %d waypoints to %s", c, filename);
1614 }
1615
1616 // load waypoints from file
1617 float waypoint_loadall()
1618 {
1619         string s;
1620         float file, cwp, cwb, fl;
1621         vector m1, m2;
1622         cwp = 0;
1623         cwb = 0;
1624
1625         string gt_ext = GET_GAMETYPE_EXTENSION();
1626
1627         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1628         file = fopen(filename, FILE_READ);
1629
1630         if (gt_ext != "" && file < 0)
1631         {
1632                 // if race waypoint file doesn't exist load the default one
1633                 filename = sprintf("maps/%s.waypoints", mapname);
1634                 file = fopen(filename, FILE_READ);
1635         }
1636
1637         if (file < 0)
1638         {
1639                 LOG_TRACE("waypoint load from ", filename, " failed");
1640                 return 0;
1641         }
1642
1643         bool parse_comments = true;
1644         float ver = 0;
1645         float sym = 0;
1646         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1647
1648         while ((s = fgets(file)))
1649         {
1650                 if(parse_comments)
1651                 {
1652                         if(substring(s, 0, 2) == "//")
1653                         {
1654                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1655                                         ver = stof(substring(s, 19, -1));
1656                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1657                                 {
1658                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1659                                         if (tokens) { sym = stof(argv(0)); }
1660                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1661                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1662                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1663                                 }
1664                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1665                                         strcpy(waypoint_time, substring(s, 16, -1));
1666                                 continue;
1667                         }
1668                         else
1669                         {
1670                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1671                                 {
1672                                         LOG_TRACE("waypoints for this map are outdated");
1673                                         LOG_TRACE("please update them in the editor");
1674                                 }
1675                                 parse_comments = false;
1676                         }
1677                 }
1678                 m1 = stov(s);
1679                 s = fgets(file);
1680                 if (!s)
1681                         break;
1682                 m2 = stov(s);
1683                 s = fgets(file);
1684                 if (!s)
1685                         break;
1686                 fl = stof(s);
1687                 waypoint_spawn(m1, m2, fl);
1688                 if (m1 == m2)
1689                         cwp = cwp + 1;
1690                 else
1691                         cwb = cwb + 1;
1692         }
1693         fclose(file);
1694         waypoint_version_loaded = ver;
1695         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1696
1697         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1698         {
1699                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1700                 if (sym == 1 && sym_param3 < 2)
1701                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1702                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1703                 {
1704                         string params;
1705                         if (sym == 1)
1706                                 params = cons("-", "-");
1707                         else
1708                         {
1709                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1710                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1711                         }
1712                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1713                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1714                 }
1715                 else if (sym == -2)
1716                 {
1717                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1718                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1719                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1720                 }
1721                 else
1722                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1723                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1724         }
1725
1726         if (WAYPOINT_VERSION < waypoint_version_loaded)
1727                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1728                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1729
1730         return cwp + cwb;
1731 }
1732
1733 #define waypoint_fixorigin(position, tracetest_ent) \
1734         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1735
1736 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1737 {
1738         vector endpos = position + down_dir * 3000;
1739         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1740         if(trace_startsolid)
1741                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1742         if(trace_startsolid)
1743                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1744         if(trace_fraction < 1)
1745                 position = trace_endpos;
1746         return position;
1747 }
1748
1749 void waypoint_spawnforitem_force(entity e, vector org)
1750 {
1751         // Fix the waypoint altitude if necessary
1752         org = waypoint_fixorigin(org, NULL);
1753
1754         // don't spawn an item spawnfunc_waypoint if it already exists
1755         IL_EACH(g_waypoints, true,
1756         {
1757                 if(it.wpisbox)
1758                 {
1759                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1760                         {
1761                                 e.nearestwaypoint = it;
1762                                 return;
1763                         }
1764                 }
1765                 else
1766                 {
1767                         if(vdist(it.origin - org, <, 16))
1768                         {
1769                                 e.nearestwaypoint = it;
1770                                 return;
1771                         }
1772                 }
1773         });
1774
1775         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1776 }
1777
1778 void waypoint_spawnforitem(entity e)
1779 {
1780         if(!bot_waypoints_for_items)
1781                 return;
1782
1783         waypoint_spawnforitem_force(e, e.origin);
1784 }
1785
1786 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1787 {
1788         entity w;
1789         entity dw;
1790         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1791         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1792         // one way link to the destination
1793         w.wp00_original = dw;
1794         w.wp00 = dw;
1795         w.wp00mincost = timetaken; // this is just for jump pads
1796         // the teleporter's nearest spawnfunc_waypoint is this one
1797         // (teleporters are not goals, so this is probably useless)
1798         e.nearestwaypoint = w;
1799         e.nearestwaypointtimeout = -1;
1800 }
1801
1802 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1803 {
1804         float src_angle = e.warpzone_angles.x;
1805         while (src_angle < -180) src_angle += 360;
1806         while (src_angle > 180) src_angle -= 360;
1807
1808         float dest_angle = e.enemy.warpzone_angles.x;
1809         while (dest_angle < -180) dest_angle += 360;
1810         while (dest_angle > 180) dest_angle -= 360;
1811
1812         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1813         if (src_angle == -90 || dest_angle == -90)
1814                 return;
1815
1816         makevectors(e.warpzone_angles);
1817         vector src = (e.absmin + e.absmax) * 0.5;
1818         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1819         vector down_dir_src = -v_up;
1820
1821         makevectors(e.enemy.warpzone_angles);
1822         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1823         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1824         vector down_dir_dest = -v_up;
1825
1826         int extra_flag = 0;
1827         // don't snap to the ground waypoints for source warpzones pointing downwards
1828         if (src_angle != 90)
1829         {
1830                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1831                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1832                 // oblique warpzones need a jump otherwise bots gets stuck
1833                 if (src_angle != 0)
1834                         extra_flag = WAYPOINTFLAG_JUMP;
1835         }
1836
1837         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1838 }
1839
1840 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1841 {
1842         destination = waypoint_fixorigin(destination, tracetest_ent);
1843         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1844 }
1845
1846 entity waypoint_spawnpersonal(entity this, vector position)
1847 {
1848         entity w;
1849
1850         // drop the waypoint to a proper location:
1851         //   first move it up by a player height
1852         //   then move it down to hit the floor with player bbox size
1853         position = waypoint_fixorigin(position, this);
1854
1855         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1856         w.nearestwaypoint = NULL;
1857         w.nearestwaypointtimeout = 0;
1858         w.owner = this;
1859
1860         waypoint_schedulerelink(w);
1861
1862         return w;
1863 }
1864
1865 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1866 {
1867         if (!(wp1 && wp2))
1868                 return;
1869
1870         if (waypoint_is_hardwiredlink(wp1, wp2))
1871                 te_beam(NULL, wp1.origin, wp2.origin);
1872         else if (display_type == 1)
1873                 te_lightning2(NULL, wp1.origin, wp2.origin);
1874 }
1875
1876 void waypoint_showlinks_to(entity wp, int display_type)
1877 {
1878         IL_EACH(g_waypoints, it != wp,
1879         {
1880                 if (waypoint_islinked(it, wp))
1881                         waypoint_showlink(it, wp, display_type);
1882         });
1883 }
1884
1885 void waypoint_showlinks_from(entity wp, int display_type)
1886 {
1887         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
1888         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
1889         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
1890         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
1891         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
1892         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
1893         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
1894         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
1895         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
1896         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
1897         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
1898         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
1899         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
1900         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
1901         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
1902         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
1903 }
1904
1905 void crosshair_trace_waypoints(entity pl)
1906 {
1907         IL_EACH(g_waypoints, true, {
1908                 it.solid = SOLID_BSP;
1909                 if (!it.wpisbox)
1910                         setsize(it, '-16 -16 -16', '16 16 16');
1911         });
1912
1913         crosshair_trace(pl);
1914
1915         IL_EACH(g_waypoints, true, {
1916                 it.solid = SOLID_TRIGGER;
1917                 if (!it.wpisbox)
1918                         setsize(it, '0 0 0', '0 0 0');
1919         });
1920         if (trace_ent.classname != "waypoint")
1921                 trace_ent = NULL;
1922 }
1923
1924 void botframe_showwaypointlinks()
1925 {
1926         if (time < botframe_waypointeditorlightningtime)
1927                 return;
1928         botframe_waypointeditorlightningtime = time + 0.5;
1929         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1930         {
1931                 int display_type = 0;
1932                 if (wasfreed(it.wp_aimed))
1933                         it.wp_aimed = NULL;
1934                 if (wasfreed(it.wp_locked))
1935                         it.wp_locked = NULL;
1936                 if (PHYS_INPUT_BUTTON_USE(it))
1937                         it.wp_locked = it.wp_aimed;
1938                 entity head = it.wp_locked;
1939                 if (!head)
1940                         head = navigation_findnearestwaypoint(it, false);
1941                 it.nearestwaypoint = head; // mainly useful for debug
1942                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1943                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1944                         display_type = 1; // default
1945                 else if(waypoint_has_hardwiredlinks(head))
1946                         display_type = 2; // only hardwired
1947
1948                 if (display_type)
1949                 {
1950                         //navigation_testtracewalk = true;
1951                         //print("currently selected WP is ", etos(head), "\n");
1952                         //navigation_testtracewalk = false;
1953                         if (head)
1954                         {
1955                                 te_lightning2(NULL, head.origin, it.origin);
1956                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1957                                         waypoint_showlinks_to(head, display_type);
1958                                 else
1959                                         waypoint_showlinks_from(head, display_type);
1960                         }
1961                 }
1962                 string str;
1963                 entity wp = NULL;
1964                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1965                 {
1966                         crosshair_trace_waypoints(it);
1967                         if (trace_ent)
1968                         {
1969                                 wp = trace_ent;
1970                                 if (wp != it.wp_aimed)
1971                                 {
1972                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: %s\n", etof(wp), wp.wpflags, vtos(wp.origin));
1973                                         if (wp.wpisbox)
1974                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1975                                         stuffcmd(it, str);
1976                                         str = sprintf("entity: %d\nflags: %d\norigin: %s", etof(wp), wp.wpflags, vtos(wp.origin));
1977                                         if (wp.wpisbox)
1978                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
1979                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1980                                 }
1981                         }
1982                 }
1983                 if (it.wp_aimed != wp)
1984                         it.wp_aimed = wp;
1985         });
1986 }
1987
1988 float botframe_autowaypoints_fixdown(vector v)
1989 {
1990         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1991         if(trace_fraction >= 1)
1992                 return 0;
1993         return 1;
1994 }
1995
1996 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1997 {
1998         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1999         {
2000                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2001                 return 0;
2002         });
2003
2004         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2005         return 1;
2006 }
2007
2008 // return value:
2009 //    1 = WP created
2010 //    0 = no action needed
2011 //   -1 = temp fail, try from world too
2012 //   -2 = permanent fail, do not retry
2013 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2014 {
2015         // make it possible to go from p to wp, if we can
2016         // if wp is NULL, nearest is chosen
2017
2018         entity w;
2019         vector porg;
2020         float t, tmin, tmax;
2021         vector o;
2022         vector save;
2023
2024         if(!botframe_autowaypoints_fixdown(p.origin))
2025                 return -2;
2026         porg = trace_endpos;
2027
2028         if(wp)
2029         {
2030                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2031
2032                 // if wp -> porg, then OK
2033                 float maxdist;
2034                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2035                 {
2036                         // we may find a better one
2037                         maxdist = vlen(wp.origin - porg);
2038                 }
2039                 else
2040                 {
2041                         // accept any "good"
2042                         maxdist = 2100;
2043                 }
2044
2045                 float bestdist = maxdist;
2046                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
2047                 {
2048                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2049                         if(d < bestdist)
2050                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2051                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2052                         {
2053                                 bestdist = d;
2054                                 p.(fld) = it;
2055                         }
2056                 });
2057                 if(bestdist < maxdist)
2058                 {
2059                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2060                         return 0;
2061                 }
2062
2063                 if(bestdist < 2100)
2064                 {
2065                         // we know maxdist < 2100
2066                         // so wp -> porg is still valid
2067                         // all is good
2068                         p.(fld) = wp;
2069                         return 0;
2070                 }
2071
2072                 // otherwise, no existing WP can fix our issues
2073         }
2074         else
2075         {
2076                 save = p.origin;
2077                 setorigin(p, porg);
2078                 w = navigation_findnearestwaypoint(p, walkfromwp);
2079                 setorigin(p, save);
2080                 if(w)
2081                 {
2082                         p.(fld) = w;
2083                         return 0;
2084                 }
2085         }
2086
2087         tmin = 0;
2088         tmax = 1;
2089         for (;;)
2090         {
2091                 if(tmax - tmin < 0.001)
2092                 {
2093                         // did not get a good candidate
2094                         return -1;
2095                 }
2096
2097                 t = (tmin + tmax) * 0.5;
2098                 o = antilag_takebackorigin(p, CS(p), time - t);
2099                 if(!botframe_autowaypoints_fixdown(o))
2100                         return -2;
2101                 o = trace_endpos;
2102
2103                 if(wp)
2104                 {
2105                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2106                         {
2107                                 // we cannot walk from wp.origin to o
2108                                 // get closer to tmax
2109                                 tmin = t;
2110                                 continue;
2111                         }
2112                 }
2113                 else
2114                 {
2115                         save = p.origin;
2116                         setorigin(p, o);
2117                         w = navigation_findnearestwaypoint(p, walkfromwp);
2118                         setorigin(p, save);
2119                         if(!w)
2120                         {
2121                                 // we cannot walk from any WP to o
2122                                 // get closer to tmax
2123                                 tmin = t;
2124                                 continue;
2125                         }
2126                 }
2127
2128                 // if we get here, o is valid regarding waypoints
2129                 // check if o is connected right to the player
2130                 // we break if it succeeds, as that means o is a good waypoint location
2131                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2132                         break;
2133
2134                 // o is no good, we need to get closer to the player
2135                 tmax = t;
2136         }
2137
2138         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2139         botframe_autowaypoints_createwp(o, p, fld, 0);
2140         return 1;
2141 }
2142
2143 // automatically create missing waypoints
2144 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2145 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2146 {
2147         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2148         if(r != -1)
2149                 return;
2150         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2151         if(r != -1)
2152                 return;
2153
2154         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2155         if(!botframe_autowaypoints_fixdown(p.origin))
2156                 return; // shouldn't happen, caught above
2157         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2158 }
2159
2160 void botframe_deleteuselesswaypoints()
2161 {
2162         IL_EACH(g_items, it.bot_pickup,
2163         {
2164                 // NOTE: this protects waypoints if they're the ONLY nearest
2165                 // waypoint. That's the intention.
2166                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2167                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2168         });
2169         IL_EACH(g_waypoints, true,
2170         {
2171                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2172                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2173                 // WP is useful if:
2174                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2175                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2176                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2177                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2178                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2179                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2180                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2181                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2182                 // b) WP is closest WP for an item/spawnpoint/other entity
2183                 //    This has been done above by protecting these WPs.
2184         });
2185         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2186         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2187         {
2188                 for (int m = 0; m < 32; ++m)
2189                 {
2190                         entity w = waypoint_get_link(it, m);
2191                         if (!w)
2192                                 break;
2193                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2194                                 continue;
2195                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2196                                 continue;
2197                         for (int j = 0; j < 32; ++j)
2198                         {
2199                                 entity w2 = waypoint_get_link(w, j);
2200                                 if (!w2)
2201                                         break;
2202                                 if (it == w2)
2203                                         continue;
2204                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2205                                         continue;
2206                                 // If we got here, it != w2 exist with it -> w
2207                                 // and w -> w2. That means the waypoint is not
2208                                 // a dead end.
2209                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2210                                 for (int k = 0; k < 32; ++k)
2211                                 {
2212                                         if (waypoint_get_link(it, k) == w2)
2213                                                 continue;
2214                                         // IF WE GET HERE, w is proven useful
2215                                         // to get from it to w2!
2216                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2217                                         goto next;
2218                                 }
2219                         }
2220 LABEL(next)
2221                 }
2222         });
2223         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2224         //     they are needed to complete routes while autowaypointing.
2225
2226         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2227         {
2228                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2229                 te_explosion(it.origin);
2230                 waypoint_remove(it);
2231                 break;
2232         });
2233
2234         IL_EACH(g_waypoints, true,
2235         {
2236                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2237         });
2238 }
2239
2240 void botframe_autowaypoints()
2241 {
2242         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2243                 // going back is broken, so only fix waypoints to walk TO the player
2244                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2245                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2246                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2247         });
2248
2249         if (autocvar_g_waypointeditor_auto >= 2) {
2250                 botframe_deleteuselesswaypoints();
2251         }
2252 }
2253