qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 void waypoint_setupmodel(entity wp)
 264 {
 265         if (autocvar_g_waypointeditor)
 266         {
 267                 // TODO: add some sort of visible box in edit mode for box waypoints
 268                 vector m1 = wp.mins;
 269                 vector m2 = wp.maxs;
 270                 setmodel(wp, MDL_WAYPOINT);
 271                 setsize(wp, m1, m2);
 272                 wp.effects = EF_LOWPRECISION;
 273                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 274                         wp.colormod = '1 0 0';
 275                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 276                         wp.colormod = '1 1 0';
 277                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 278                         wp.colormod = '1 0.5 0'; // orange
 279                 else if (wp.wphardwired)
 280                         wp.colormod = '0.5 0 1'; // violet
 281                 else
 282                         wp.colormod = '1 1 1';
 283         }
 284         else
 285                 wp.model = "";
 286 }
 287
 288 entity waypoint_spawn(vector m1, vector m2, float f)
 289 {
 290         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 291         {
 292                 vector em1 = m1 - '8 8 8';
 293                 vector em2 = m2 + '8 8 8';
 294                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 295                 {
 296                         return it;
 297                 });
 298         }
 299         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 300         // otherwise links loaded from file would be applied only to the first destination
 301         // waypoint since link format doesn't specify waypoint entities but just positions
 302         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 303         {
 304                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 305                 {
 306                         return it;
 307                 });
 308         }
 309
 310         entity w = new(waypoint);
 311         IL_PUSH(g_waypoints, w);
 312         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 313         w.wpflags = f;
 314         w.solid = SOLID_TRIGGER;
 315         setorigin(w, (m1 + m2) * 0.5);
 316         setsize(w, m1 - w.origin, m2 - w.origin);
 317         if (w.size)
 318                 w.wpisbox = true;
 319
 320         if(!w.wpisbox)
 321         {
 322                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 323                 if(!move_out_of_solid(w))
 324                 {
 325                         if(!(f & WAYPOINTFLAG_GENERATED))
 326                         {
 327                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 328                                 delete(w);
 329                                 return NULL;
 330                         }
 331                         else
 332                         {
 333                                 if(autocvar_developer)
 334                                 {
 335                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 336                                         backtrace("Waypoint stuck");
 337                                 }
 338                         }
 339                 }
 340                 setsize(w, '0 0 0', '0 0 0');
 341         }
 342
 343         waypoint_clearlinks(w);
 344         //waypoint_schedulerelink(w);
 345
 346         waypoint_setupmodel(w);
 347
 348         return w;
 349 }
 350
 351 float trigger_push_get_push_time(entity this, vector endpos);
 352 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 353 {
 354         entity jp = NULL;
 355         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 356         {
 357                 jp = it;
 358         });
 359         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 360         wp_from.wp00 = wp_to;
 361         wp_from.wp00mincost = cost;
 362         jp.nearestwaypoint = wp_from;
 363         jp.nearestwaypointtimeout = -1;
 364 }
 365
 366 bool start_wp_is_spawned;
 367 vector start_wp_origin;
 368
 369 void waypoint_clear_start_wp(entity pl)
 370 {
 371         start_wp_is_spawned = false;
 372         start_wp_origin = '0 0 0';
 373         pl.wp_locked = NULL;
 374         LOG_INFO("^xf80Start waypoint has been cleared\n");
 375 }
 376
 377 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair)
 378 {
 379         entity e = NULL, jp = NULL;
 380         vector org = pl.origin;
 381         if (at_crosshair)
 382         {
 383                 crosshair_trace(pl);
 384                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 385                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 386                 {
 387                         jp = it;
 388                         break;
 389                 });
 390                 if (jp && start_wp_is_spawned)
 391                         start_wp_is_spawned = false;
 392                 LOG_INFO("^xf80Spawning start waypoint\n");
 393         }
 394         int ctf_flags = havocbot_symmetry_origin_order;
 395         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 396                    || (autocvar_g_waypointeditor_symmetrical < 0));
 397         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 398                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 399         if (sym && ctf_flags < 2)
 400                 ctf_flags = 2;
 401         int wp_num = ctf_flags;
 402
 403         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair)
 404         {
 405                 // snap waypoint to item's origin if close enough
 406                 IL_EACH(g_items, true,
 407                 {
 408                         vector item_org = (it.absmin + it.absmax) * 0.5;
 409                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 410                         if (vlen(item_org - org) < 20)
 411                         {
 412                                 org = item_org;
 413                                 break;
 414                         }
 415                 });
 416         }
 417
 418         vector start_org = '0 0 0';
 419         if (start_wp_is_spawned)
 420         {
 421                 LOG_INFO("^xf80Spawning destination waypoint\n");
 422                 start_org = start_wp_origin;
 423         }
 424
 425         // save org as it can be modified spawning symmetrycal waypoints
 426         vector org_save = org;
 427
 428         LABEL(add_wp);
 429
 430         if (jp)
 431         {
 432                 e = NULL;
 433                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 434                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 435                 {
 436                         e = it; break;
 437                 });
 438                 if (!e)
 439                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 440                 if (!pl.wp_locked)
 441                         pl.wp_locked = e;
 442         }
 443         else
 444                 e = waypoint_spawn(org, org, 0);
 445         if(!e)
 446         {
 447                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 448                 if (start_wp_is_spawned)
 449                         waypoint_clear_start_wp(pl);
 450                 return;
 451         }
 452
 453         entity start_wp = NULL;
 454         if (start_wp_is_spawned)
 455         {
 456                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 457                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 458                 {
 459                         start_wp = it; break;
 460                 });
 461                 if(!start_wp)
 462                 {
 463                         // should not happen
 464                         LOG_INFOF("Couldn't find custom jumppad waypoint at %v\n", start_org);
 465                         waypoint_clear_start_wp(pl);
 466                         return;
 467                 }
 468                 waypoint_addlink_for_custom_jumppad(start_wp, e);
 469         }
 470
 471         waypoint_schedulerelink(e);
 472         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 473
 474         if (start_wp_is_spawned)
 475         {
 476                 pl.wp_locked = NULL;
 477                 waypoint_schedulerelink(start_wp);
 478         }
 479
 480         if (sym)
 481         {
 482                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 483                 if (jp)
 484                 {
 485                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 486                         {
 487                                 jp = it; break;
 488                         });
 489                 }
 490                 if (start_wp_is_spawned)
 491                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 492                 if (vdist(org - pl.origin, >, 32))
 493                 {
 494                         if(wp_num > 2)
 495                                 wp_num--;
 496                         else
 497                                 sym = false;
 498                         goto add_wp;
 499                 }
 500         }
 501
 502         if (jp)
 503         {
 504                 if (!start_wp_is_spawned)
 505                 {
 506                         // we've just created a custom jumppad waypoint
 507                         // the next one created by the user will be the destination waypoint
 508                         start_wp_is_spawned = true;
 509                         start_wp_origin = org_save;
 510                 }
 511         }
 512 }
 513
 514 void waypoint_remove(entity wp)
 515 {
 516         IL_EACH(g_waypoints, it != wp,
 517         {
 518                 if (waypoint_islinked(it, wp))
 519                         waypoint_removelink(it, wp);
 520         });
 521         delete(wp);
 522 }
 523
 524 void waypoint_remove_fromeditor(entity pl)
 525 {
 526         entity e = navigation_findnearestwaypoint(pl, false);
 527
 528         int ctf_flags = havocbot_symmetry_origin_order;
 529         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 530                    || (autocvar_g_waypointeditor_symmetrical < 0));
 531         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 532                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 533         if (sym && ctf_flags < 2)
 534                 ctf_flags = 2;
 535         int wp_num = ctf_flags;
 536
 537         LABEL(remove_wp);
 538         if (!e) return;
 539         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 540         {
 541                 if (start_wp_is_spawned)
 542                         waypoint_clear_start_wp(pl);
 543                 return;
 544         }
 545
 546         if (e.wphardwired)
 547         {
 548                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 549                 return;
 550         }
 551
 552         entity wp_sym = NULL;
 553         if (sym)
 554         {
 555                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 556                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 557                         if(vdist(org - it.origin, <, 3))
 558                         {
 559                                 wp_sym = it;
 560                                 break;
 561                         }
 562                 });
 563         }
 564
 565         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 566         waypoint_remove(e);
 567
 568         if (sym && wp_sym)
 569         {
 570                 e = wp_sym;
 571                 if(wp_num > 2)
 572                         wp_num--;
 573                 else
 574                         sym = false;
 575                 goto remove_wp;
 576         }
 577
 578         if (start_wp_is_spawned)
 579                 waypoint_clear_start_wp(pl);
 580 }
 581
 582 void waypoint_removelink(entity from, entity to)
 583 {
 584         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 585                 return;
 586
 587         entity fromwp31_prev = from.wp31;
 588
 589         switch (waypoint_getlinknum(from, to))
 590         {
 591                 // fallthrough all the way
 592                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 593                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 594                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 595                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 596                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 597                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 598                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 599                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 600                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 601                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 602                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 603                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 604                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 605                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 606                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 607                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 608                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 609                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 610                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 611                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 612                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 613                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 614                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 615                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 616                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 617                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 618                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 619                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 620                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 621                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 622                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 623                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 624         }
 625
 626         if (fromwp31_prev && !from.wp31)
 627                 waypoint_schedulerelink(from);
 628 }
 629
 630 int waypoint_getlinknum(entity from, entity to)
 631 {
 632         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 633         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 634         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 635         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 636         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 637         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 638         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 639         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 640         return -1;
 641 }
 642
 643 bool waypoint_islinked(entity from, entity to)
 644 {
 645         return (waypoint_getlinknum(from, to) >= 0);
 646 }
 647
 648 void waypoint_updatecost_foralllinks()
 649 {
 650         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 651         {
 652                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 653                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 654                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 655                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 656                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 657                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 658                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 659                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 660                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 661                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 662                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 663                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 664                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 665                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 666                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 667                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 668                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 669                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 670                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 671                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 672                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 673                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 674                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 675                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 676                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 677                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 678                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 679                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 680                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 681                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 682                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 683                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 684         });
 685 }
 686
 687 float waypoint_getlinearcost(float dist)
 688 {
 689         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 690                 return dist / (autocvar_sv_maxspeed * 1.25);
 691         return dist / autocvar_sv_maxspeed;
 692 }
 693 float waypoint_getlinearcost_underwater(float dist)
 694 {
 695         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 696         return dist / (autocvar_sv_maxspeed * 0.7);
 697 }
 698
 699 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 700 {
 701         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 702         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 703
 704         if (submerged_from && submerged_to)
 705                 return waypoint_getlinearcost_underwater(vlen(to - from));
 706
 707         float c = waypoint_getlinearcost(vlen(to - from));
 708
 709         float height = from.z - to.z;
 710         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 711         {
 712                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 713                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 714                 if(height_cost > c)
 715                         c = height_cost;
 716         }
 717
 718         if (submerged_from || submerged_to)
 719                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 720         return c;
 721 }
 722
 723 float waypoint_getlinkcost(entity from, entity to)
 724 {
 725         vector v1 = from.origin;
 726         vector v2 = to.origin;
 727         if (from.wpisbox)
 728         {
 729                 vector m1 = from.absmin, m2 = from.absmax;
 730                 v1.x = bound(m1.x, v2.x, m2.x);
 731                 v1.y = bound(m1.y, v2.y, m2.y);
 732                 v1.z = bound(m1.z, v2.z, m2.z);
 733         }
 734         if (to.wpisbox)
 735         {
 736                 vector m1 = to.absmin, m2 = to.absmax;
 737                 v2.x = bound(m1.x, v1.x, m2.x);
 738                 v2.y = bound(m1.y, v1.y, m2.y);
 739                 v2.z = bound(m1.z, v1.z, m2.z);
 740         }
 741         return waypoint_gettravelcost(v1, v2, from, to);
 742 }
 743
 744 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 745 // if c == -1 automatically determine cost of the link
 746 void waypoint_addlink_customcost(entity from, entity to, float c)
 747 {
 748         if (from == to || waypoint_islinked(from, to))
 749                 return;
 750         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 751                 return;
 752
 753         if(c == -1)
 754                 c = waypoint_getlinkcost(from, to);
 755
 756         if (from.wp31mincost < c) return;
 757         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 758         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 759         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 760         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 761         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 762         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 763         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 764         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 765         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 766         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 767         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 768         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 769         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 770         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 771         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 772         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 773         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 774         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 775         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 776         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 777         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 778         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 779         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 780         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 781         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 782         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 783         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 784         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 785         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 786         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 787         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 788         from.wp00 = to;from.wp00mincost = c;return;
 789 }
 790
 791 void waypoint_addlink(entity from, entity to)
 792 {
 793         waypoint_addlink_customcost(from, to, -1);
 794 }
 795
 796 // relink this spawnfunc_waypoint
 797 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 798 // (SLOW!)
 799 void waypoint_think(entity this)
 800 {
 801         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 802         float sv2_height = 0, ev2_height = 0;
 803
 804         bot_calculate_stepheightvec();
 805
 806         int dphitcontentsmask_save = this.dphitcontentsmask;
 807         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 808
 809         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 810
 811         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 812         IL_EACH(g_waypoints, this != it,
 813         {
 814                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 815                 {
 816                         waypoint_addlink(this, it);
 817                         waypoint_addlink(it, this);
 818                 }
 819                 else
 820                 {
 821                         ++relink_total;
 822                         if(!checkpvs(this.origin, it))
 823                         {
 824                                 ++relink_pvsculled;
 825                                 continue;
 826                         }
 827
 828                         sv = set_tracewalk_dest_2(this, it.origin);
 829                         sv2 = tracewalk_dest;
 830                         sv2_height = tracewalk_dest_height;
 831                         ev = set_tracewalk_dest_2(it, this.origin);
 832                         ev2 = tracewalk_dest;
 833                         ev2_height = tracewalk_dest_height;
 834
 835                         dv = ev - sv;
 836                         dv.z = 0;
 837                         if(vdist(dv, >=, 1050)) // max search distance in XY
 838                         {
 839                                 ++relink_lengthculled;
 840                                 continue;
 841                         }
 842
 843                         navigation_testtracewalk = 0;
 844
 845                         //traceline(this.origin, it.origin, false, NULL);
 846                         //if (trace_fraction == 1)
 847                         if (this.wpisbox)
 848                                 relink_walkculled += 0.5;
 849                         else
 850                         {
 851                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 852                                         waypoint_addlink(this, it);
 853                                 else
 854                                         relink_walkculled += 0.5;
 855                         }
 856
 857                         if (it.wpisbox)
 858                                 relink_walkculled += 0.5;
 859                         else
 860                         {
 861                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 862                                         waypoint_addlink(it, this);
 863                                 else
 864                                         relink_walkculled += 0.5;
 865                         }
 866                 }
 867         });
 868         navigation_testtracewalk = 0;
 869         this.wplinked = true;
 870         this.dphitcontentsmask = dphitcontentsmask_save;
 871 }
 872
 873 void waypoint_clearlinks(entity wp)
 874 {
 875         // clear links to other waypoints
 876         float f = 10000000;
 877         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 878         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 879         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 880         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 881
 882         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 883         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 884         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 885         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 886
 887         wp.wplinked = false;
 888 }
 889
 890 // tell a spawnfunc_waypoint to relink
 891 void waypoint_schedulerelink(entity wp)
 892 {
 893         if (wp == NULL)
 894                 return;
 895
 896         waypoint_setupmodel(wp);
 897         wp.wpisbox = vdist(wp.size, >, 0);
 898         wp.enemy = NULL;
 899         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 900                 wp.owner = NULL;
 901         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 902                 waypoint_clearlinks(wp);
 903         // schedule an actual relink on next frame
 904         setthink(wp, waypoint_think);
 905         wp.nextthink = time;
 906         wp.effects = EF_LOWPRECISION;
 907 }
 908
 909 // spawnfunc_waypoint map entity
 910 spawnfunc(waypoint)
 911 {
 912         IL_PUSH(g_waypoints, this);
 913
 914         setorigin(this, this.origin);
 915         // schedule a relink after other waypoints have had a chance to spawn
 916         waypoint_clearlinks(this);
 917         //waypoint_schedulerelink(this);
 918 }
 919
 920 // tell all waypoints to relink
 921 // actually this is useful only to update relink_* stats
 922 void waypoint_schedulerelinkall()
 923 {
 924         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 925         IL_EACH(g_waypoints, true,
 926         {
 927                 waypoint_schedulerelink(it);
 928         });
 929         waypoint_load_links_hardwired();
 930 }
 931
 932 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 933
 934 // Load waypoint links from file
 935 bool waypoint_load_links()
 936 {
 937         string s;
 938         float file, tokens, c = 0, found;
 939         entity wp_from = NULL, wp_to;
 940         vector wp_to_pos, wp_from_pos;
 941
 942         string gt_ext = GET_GAMETYPE_EXTENSION();
 943
 944         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 945         file = fopen(filename, FILE_READ);
 946
 947         if (gt_ext != "" && file < 0)
 948         {
 949                 // if race waypoint file doesn't exist load the default one
 950                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 951                 file = fopen(filename, FILE_READ);
 952         }
 953
 954         if (file < 0)
 955         {
 956                 LOG_TRACE("waypoint links load from ", filename, " failed");
 957                 waypoint_schedulerelinkall();
 958                 return false;
 959         }
 960
 961         bool parse_comments = true;
 962         float ver = 0;
 963         string links_time = string_null;
 964
 965         while ((s = fgets(file)))
 966         {
 967                 if(parse_comments)
 968                 {
 969                         if(substring(s, 0, 2) == "//")
 970                         {
 971                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 972                                         ver = stof(substring(s, 19, -1));
 973                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
 974                                         links_time = substring(s, 16, -1);
 975                                 continue;
 976                         }
 977                         else
 978                         {
 979                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
 980                                 {
 981                                         if (links_time != waypoint_time)
 982                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
 983                                         else
 984                                                 LOG_TRACE("waypoint links for this map are outdated.");
 985                                         if (g_assault)
 986                                         {
 987                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 988                                         }
 989                                         else
 990                                         {
 991                                                 LOG_TRACE("automatically updating...");
 992                                                 waypoint_schedulerelinkall();
 993                                                 fclose(file);
 994                                                 return false;
 995                                         }
 996                                 }
 997                                 parse_comments = false;
 998                         }
 999                 }
1000
1001                 tokens = tokenizebyseparator(s, "*");
1002
1003                 if (tokens!=2)
1004                 {
1005                         // bad file format
1006                         fclose(file);
1007                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1008                         return false;
1009                 }
1010
1011                 wp_from_pos     = stov(argv(0));
1012                 wp_to_pos       = stov(argv(1));
1013
1014                 // Search "from" waypoint
1015                 if(!wp_from || wp_from.origin!=wp_from_pos)
1016                 {
1017                         wp_from = findradius(wp_from_pos, 1);
1018                         found = false;
1019                         while(wp_from)
1020                         {
1021                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1022                                 if(wp_from.classname == "waypoint")
1023                                 {
1024                                         found = true;
1025                                         break;
1026                                 }
1027                                 wp_from = wp_from.chain;
1028                         }
1029
1030                         if(!found)
1031                         {
1032                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1033                                 continue;
1034                         }
1035                 }
1036
1037                 // Search "to" waypoint
1038                 wp_to = findradius(wp_to_pos, 1);
1039                 found = false;
1040                 while(wp_to)
1041                 {
1042                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1043                         if(wp_to.classname == "waypoint")
1044                         {
1045                                 found = true;
1046                                 break;
1047                         }
1048                         wp_to = wp_to.chain;
1049                 }
1050
1051                 if(!found)
1052                 {
1053                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1054                         continue;
1055                 }
1056
1057                 ++c;
1058                 if ((wp_from.wpflags & WAYPOINTFLAG_NORELINK) && !(wp_from.wpflags & WAYPOINTFLAG_GENERATED))
1059                         waypoint_addlink_for_custom_jumppad(wp_from, wp_to);
1060                 else
1061                         waypoint_addlink(wp_from, wp_to);
1062         }
1063
1064         fclose(file);
1065
1066         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1067
1068         bool scheduled = false;
1069         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1070         {
1071                 if (!it.wp00)
1072                 {
1073                         waypoint_schedulerelink(it);
1074                         scheduled = true;
1075                 }
1076         });
1077         if (scheduled)
1078                 return false;
1079
1080         botframe_cachedwaypointlinks = true;
1081         return true;
1082 }
1083
1084 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
1085 {
1086         string s;
1087         float file, tokens, c = 0, found;
1088         entity wp_from = NULL, wp_to;
1089         vector wp_to_pos, wp_from_pos;
1090
1091         string gt_ext = GET_GAMETYPE_EXTENSION();
1092
1093         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1094         file = fopen(filename, FILE_READ);
1095
1096         if (gt_ext != "" && file < 0)
1097         {
1098                 // if race waypoint file doesn't exist load the default one
1099                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1100                 file = fopen(filename, FILE_READ);
1101         }
1102
1103         botframe_loadedforcedlinks = true;
1104
1105         if (file < 0)
1106         {
1107                 if(!removal_mode)
1108                         LOG_TRACE("waypoint links load from ", filename, " failed");
1109                 return;
1110         }
1111
1112         while ((s = fgets(file)))
1113         {
1114                 if(substring(s, 0, 2)=="//")
1115                         continue;
1116
1117                 if(substring(s, 0, 1)=="#")
1118                         continue;
1119
1120                 tokens = tokenizebyseparator(s, "*");
1121
1122                 if (tokens!=2)
1123                         continue;
1124
1125                 wp_from_pos     = stov(argv(0));
1126                 wp_to_pos       = stov(argv(1));
1127
1128                 // Search "from" waypoint
1129                 if(!wp_from || wp_from.origin!=wp_from_pos)
1130                 {
1131                         wp_from = findradius(wp_from_pos, 5);
1132                         found = false;
1133                         while(wp_from)
1134                         {
1135                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1136                                 if(wp_from.classname == "waypoint")
1137                                 {
1138                                         found = true;
1139                                         break;
1140                                 }
1141                                 wp_from = wp_from.chain;
1142                         }
1143
1144                         if(!found)
1145                         {
1146                                 if(!removal_mode)
1147                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1148                                 continue;
1149                         }
1150                 }
1151
1152                 // Search "to" waypoint
1153                 wp_to = findradius(wp_to_pos, 5);
1154                 found = false;
1155                 while(wp_to)
1156                 {
1157                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1158                         if(wp_to.classname == "waypoint")
1159                         {
1160                                 found = true;
1161                                 break;
1162                         }
1163                         wp_to = wp_to.chain;
1164                 }
1165
1166                 if(!found)
1167                 {
1168                         if(!removal_mode)
1169                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1170                         continue;
1171                 }
1172
1173                 ++c;
1174                 if(removal_mode)
1175                 {
1176                         waypoint_removelink(wp_from, wp_to);
1177                         continue;
1178                 }
1179
1180                 waypoint_addlink(wp_from, wp_to);
1181                 wp_from.wphardwired = true;
1182                 wp_to.wphardwired = true;
1183                 waypoint_setupmodel(wp_from);
1184                 waypoint_setupmodel(wp_to);
1185         }
1186
1187         fclose(file);
1188
1189         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
1190                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1191 }
1192
1193 entity waypoint_get_link(entity w, float i)
1194 {
1195         switch(i)
1196         {
1197                 case  0:return w.wp00;
1198                 case  1:return w.wp01;
1199                 case  2:return w.wp02;
1200                 case  3:return w.wp03;
1201                 case  4:return w.wp04;
1202                 case  5:return w.wp05;
1203                 case  6:return w.wp06;
1204                 case  7:return w.wp07;
1205                 case  8:return w.wp08;
1206                 case  9:return w.wp09;
1207                 case 10:return w.wp10;
1208                 case 11:return w.wp11;
1209                 case 12:return w.wp12;
1210                 case 13:return w.wp13;
1211                 case 14:return w.wp14;
1212                 case 15:return w.wp15;
1213                 case 16:return w.wp16;
1214                 case 17:return w.wp17;
1215                 case 18:return w.wp18;
1216                 case 19:return w.wp19;
1217                 case 20:return w.wp20;
1218                 case 21:return w.wp21;
1219                 case 22:return w.wp22;
1220                 case 23:return w.wp23;
1221                 case 24:return w.wp24;
1222                 case 25:return w.wp25;
1223                 case 26:return w.wp26;
1224                 case 27:return w.wp27;
1225                 case 28:return w.wp28;
1226                 case 29:return w.wp29;
1227                 case 30:return w.wp30;
1228                 case 31:return w.wp31;
1229                 default:return NULL;
1230         }
1231 }
1232
1233 // Save all waypoint links to a file
1234 void waypoint_save_links()
1235 {
1236         // temporarily remove hardwired links so they don't get saved among normal links
1237         waypoint_remove_links_hardwired();
1238
1239         string gt_ext = GET_GAMETYPE_EXTENSION();
1240
1241         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1242         int file = fopen(filename, FILE_WRITE);
1243         if (file < 0)
1244         {
1245                 LOG_INFOF("waypoint link save to %s failed", filename);
1246                 return;
1247         }
1248
1249         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1250         if (waypoint_time != "")
1251                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1252
1253         int c = 0;
1254         IL_EACH(g_waypoints, true,
1255         {
1256                 for(int j = 0; j < 32; ++j)
1257                 {
1258                         entity link = waypoint_get_link(it, j);
1259                         if(link)
1260                         {
1261                                 // NOTE: vtos rounds vector components to 1 decimal place
1262                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1263                                 fputs(file, s);
1264                                 ++c;
1265                         }
1266                 }
1267         });
1268         fclose(file);
1269
1270         botframe_cachedwaypointlinks = true;
1271
1272         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1273
1274         waypoint_load_links_hardwired();
1275 }
1276
1277 // save waypoints to gamedir/data/maps/mapname.waypoints
1278 void waypoint_saveall()
1279 {
1280         string gt_ext = GET_GAMETYPE_EXTENSION();
1281
1282         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1283         int file = fopen(filename, FILE_WRITE);
1284         if (file < 0)
1285         {
1286                 waypoint_save_links(); // save anyway?
1287                 botframe_loadedforcedlinks = false;
1288
1289                 LOG_INFOF("waypoint links: save to %s failed", filename);
1290                 return;
1291         }
1292
1293         float sym = autocvar_g_waypointeditor_symmetrical;
1294         string sym_str = ftos(sym);
1295         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1296         {
1297                 if (sym == 1)
1298                 {
1299                         sym_str = cons(sym_str, "-");
1300                         sym_str = cons(sym_str, "-");
1301                 }
1302                 else
1303                 {
1304                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1305                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1306                 }
1307                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1308                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1309         }
1310         else if (autocvar_g_waypointeditor_symmetrical == -2)
1311         {
1312                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1313                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1314         }
1315
1316         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1317         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1318         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1319         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1320
1321         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1322         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1323         //fputs(file, strcat("//", "\n"));
1324         //fputs(file, strcat("//", "\n"));
1325         //fputs(file, strcat("//", "\n"));
1326
1327         int c = 0;
1328         IL_EACH(g_waypoints, true,
1329         {
1330                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1331                         continue;
1332
1333                 string s;
1334                 // NOTE: vtos rounds vector components to 1 decimal place
1335                 s = strcat(vtos(it.origin + it.mins), "\n");
1336                 s = strcat(s, vtos(it.origin + it.maxs));
1337                 s = strcat(s, "\n");
1338                 s = strcat(s, ftos(it.wpflags));
1339                 s = strcat(s, "\n");
1340                 fputs(file, s);
1341                 c++;
1342         });
1343         fclose(file);
1344         waypoint_save_links();
1345         botframe_loadedforcedlinks = false;
1346
1347         LOG_INFOF("saved %d waypoints to %s", c, filename);
1348 }
1349
1350 // load waypoints from file
1351 float waypoint_loadall()
1352 {
1353         string s;
1354         float file, cwp, cwb, fl;
1355         vector m1, m2;
1356         cwp = 0;
1357         cwb = 0;
1358
1359         string gt_ext = GET_GAMETYPE_EXTENSION();
1360
1361         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1362         file = fopen(filename, FILE_READ);
1363
1364         if (gt_ext != "" && file < 0)
1365         {
1366                 // if race waypoint file doesn't exist load the default one
1367                 filename = sprintf("maps/%s.waypoints", mapname);
1368                 file = fopen(filename, FILE_READ);
1369         }
1370
1371         if (file < 0)
1372         {
1373                 LOG_TRACE("waypoint load from ", filename, " failed");
1374                 return 0;
1375         }
1376
1377         bool parse_comments = true;
1378         float ver = 0;
1379         float sym = 0;
1380         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1381
1382         while ((s = fgets(file)))
1383         {
1384                 if(parse_comments)
1385                 {
1386                         if(substring(s, 0, 2) == "//")
1387                         {
1388                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1389                                         ver = stof(substring(s, 19, -1));
1390                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1391                                 {
1392                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1393                                         if (tokens) { sym = stof(argv(0)); }
1394                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1395                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1396                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1397                                 }
1398                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1399                                         strcpy(waypoint_time, substring(s, 16, -1));
1400                                 continue;
1401                         }
1402                         else
1403                         {
1404                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1405                                 {
1406                                         LOG_TRACE("waypoints for this map are outdated");
1407                                         LOG_TRACE("please update them in the editor");
1408                                 }
1409                                 parse_comments = false;
1410                         }
1411                 }
1412                 m1 = stov(s);
1413                 s = fgets(file);
1414                 if (!s)
1415                         break;
1416                 m2 = stov(s);
1417                 s = fgets(file);
1418                 if (!s)
1419                         break;
1420                 fl = stof(s);
1421                 waypoint_spawn(m1, m2, fl);
1422                 if (m1 == m2)
1423                         cwp = cwp + 1;
1424                 else
1425                         cwb = cwb + 1;
1426         }
1427         fclose(file);
1428         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1429
1430         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1431         {
1432                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1433                 if (sym == 1 && sym_param3 < 2)
1434                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1435                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1436                 {
1437                         string params;
1438                         if (sym == 1)
1439                                 params = cons("-", "-");
1440                         else
1441                         {
1442                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1443                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1444                         }
1445                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1446                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1447                 }
1448                 else if (sym == -2)
1449                 {
1450                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1451                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1452                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1453                 }
1454                 else
1455                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1456                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1457         }
1458
1459         return cwp + cwb;
1460 }
1461
1462 #define waypoint_fixorigin(position, tracetest_ent) \
1463         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1464
1465 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1466 {
1467         vector endpos = position + down_dir * 3000;
1468         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1469         if(trace_startsolid)
1470                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1471         if(trace_startsolid)
1472                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1473         if(trace_fraction < 1)
1474                 position = trace_endpos;
1475         return position;
1476 }
1477
1478 void waypoint_spawnforitem_force(entity e, vector org)
1479 {
1480         // Fix the waypoint altitude if necessary
1481         org = waypoint_fixorigin(org, NULL);
1482
1483         // don't spawn an item spawnfunc_waypoint if it already exists
1484         IL_EACH(g_waypoints, true,
1485         {
1486                 if(it.wpisbox)
1487                 {
1488                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1489                         {
1490                                 e.nearestwaypoint = it;
1491                                 return;
1492                         }
1493                 }
1494                 else
1495                 {
1496                         if(vdist(it.origin - org, <, 16))
1497                         {
1498                                 e.nearestwaypoint = it;
1499                                 return;
1500                         }
1501                 }
1502         });
1503
1504         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1505 }
1506
1507 void waypoint_spawnforitem(entity e)
1508 {
1509         if(!bot_waypoints_for_items)
1510                 return;
1511
1512         waypoint_spawnforitem_force(e, e.origin);
1513 }
1514
1515 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1516 {
1517         entity w;
1518         entity dw;
1519         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1520         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1521         // one way link to the destination
1522         w.wp00 = dw;
1523         w.wp00mincost = timetaken; // this is just for jump pads
1524         // the teleporter's nearest spawnfunc_waypoint is this one
1525         // (teleporters are not goals, so this is probably useless)
1526         e.nearestwaypoint = w;
1527         e.nearestwaypointtimeout = -1;
1528 }
1529
1530 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1531 {
1532         float src_angle = e.warpzone_angles.x;
1533         while (src_angle < -180) src_angle += 360;
1534         while (src_angle > 180) src_angle -= 360;
1535
1536         float dest_angle = e.enemy.warpzone_angles.x;
1537         while (dest_angle < -180) dest_angle += 360;
1538         while (dest_angle > 180) dest_angle -= 360;
1539
1540         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1541         if (src_angle == -90 || dest_angle == -90)
1542                 return;
1543
1544         makevectors(e.warpzone_angles);
1545         vector src = (e.absmin + e.absmax) * 0.5;
1546         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1547         vector down_dir_src = -v_up;
1548
1549         makevectors(e.enemy.warpzone_angles);
1550         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1551         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1552         vector down_dir_dest = -v_up;
1553
1554         int extra_flag = 0;
1555         // don't snap to the ground waypoints for source warpzones pointing downwards
1556         if (src_angle != 90)
1557         {
1558                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1559                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1560                 // oblique warpzones need a jump otherwise bots gets stuck
1561                 if (src_angle != 0)
1562                         extra_flag = WAYPOINTFLAG_JUMP;
1563         }
1564
1565         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1566 }
1567
1568 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1569 {
1570         destination = waypoint_fixorigin(destination, tracetest_ent);
1571         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1572 }
1573
1574 entity waypoint_spawnpersonal(entity this, vector position)
1575 {
1576         entity w;
1577
1578         // drop the waypoint to a proper location:
1579         //   first move it up by a player height
1580         //   then move it down to hit the floor with player bbox size
1581         position = waypoint_fixorigin(position, this);
1582
1583         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1584         w.nearestwaypoint = NULL;
1585         w.nearestwaypointtimeout = 0;
1586         w.owner = this;
1587
1588         waypoint_schedulerelink(w);
1589
1590         return w;
1591 }
1592
1593 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1594 {
1595         if (!(wp1 && wp2))
1596                 return;
1597
1598         if (wp1.wphardwired && wp2.wphardwired)
1599                 te_beam(NULL, wp1.origin, wp2.origin);
1600         else if (display_type == 1)
1601                 te_lightning2(NULL, wp1.origin, wp2.origin);
1602 }
1603
1604 void waypoint_showlinks_to(entity wp, int display_type)
1605 {
1606         IL_EACH(g_waypoints, it != wp,
1607         {
1608                 if (waypoint_islinked(it, wp))
1609                         waypoint_showlink(it, wp, display_type);
1610         });
1611 }
1612
1613 void waypoint_showlinks_from(entity wp, int display_type)
1614 {
1615         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1616         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1617         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1618         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1619         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1620         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1621         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1622         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1623         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1624         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1625         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1626         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1627         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1628         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1629         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1630         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1631 }
1632
1633 void crosshair_trace_waypoints(entity pl)
1634 {
1635         IL_EACH(g_waypoints, true, {
1636                 it.solid = SOLID_BSP;
1637                 if (!it.wpisbox)
1638                         setsize(it, '-16 -16 -16', '16 16 16');
1639         });
1640
1641         crosshair_trace(pl);
1642
1643         IL_EACH(g_waypoints, true, {
1644                 it.solid = SOLID_TRIGGER;
1645                 if (!it.wpisbox)
1646                         setsize(it, '0 0 0', '0 0 0');
1647         });
1648         if (trace_ent.classname != "waypoint")
1649                 trace_ent = NULL;
1650 }
1651
1652 void botframe_showwaypointlinks()
1653 {
1654         if (time < botframe_waypointeditorlightningtime)
1655                 return;
1656         botframe_waypointeditorlightningtime = time + 0.5;
1657         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1658         {
1659                 int display_type = 0;
1660                 if (wasfreed(it.wp_aimed))
1661                         it.wp_aimed = NULL;
1662                 if (wasfreed(it.wp_locked))
1663                         it.wp_locked = NULL;
1664                 if (PHYS_INPUT_BUTTON_USE(it))
1665                         it.wp_locked = it.wp_aimed;
1666                 entity head = it.wp_locked;
1667                 if (!head)
1668                         head = navigation_findnearestwaypoint(it, false);
1669                 it.nearestwaypoint = head; // mainly useful for debug
1670                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1671                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1672                         display_type = 1; // default
1673                 else if(head && (head.wphardwired))
1674                         display_type = 2; // only hardwired
1675
1676                 if (display_type)
1677                 {
1678                         //navigation_testtracewalk = true;
1679                         //print("currently selected WP is ", etos(head), "\n");
1680                         //navigation_testtracewalk = false;
1681                         if (head)
1682                         {
1683                                 te_lightning2(NULL, head.origin, it.origin);
1684                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1685                                         waypoint_showlinks_to(head, display_type);
1686                                 else
1687                                         waypoint_showlinks_from(head, display_type);
1688                         }
1689                 }
1690                 string str;
1691                 entity wp = NULL;
1692                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1693                 {
1694                         crosshair_trace_waypoints(it);
1695                         if (trace_ent)
1696                         {
1697                                 wp = trace_ent;
1698                                 if (wp != it.wp_aimed)
1699                                 {
1700                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: '%s'\n", etof(wp), wp.wpflags, vtos(wp.origin));
1701                                         if (wp.wpisbox)
1702                                                 str = strcat(str, sprintf("echo \" absmin: '%s', absmax: '%s'\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1703                                         stuffcmd(it, str);
1704                                         str = sprintf("entity: %d\nflags: %d\norigin: \'%s\'", etof(wp), wp.wpflags, vtos(wp.origin));
1705                                         if (wp.wpisbox)
1706                                                 str = strcat(str, sprintf(" \nabsmin: '%s'\nabsmax: '%s'", vtos(wp.absmin), vtos(wp.absmax)));
1707                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1708                                 }
1709                         }
1710                 }
1711                 if (it.wp_aimed != wp)
1712                         it.wp_aimed = wp;
1713         });
1714 }
1715
1716 float botframe_autowaypoints_fixdown(vector v)
1717 {
1718         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1719         if(trace_fraction >= 1)
1720                 return 0;
1721         return 1;
1722 }
1723
1724 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1725 {
1726         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1727         {
1728                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1729                 return 0;
1730         });
1731
1732         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1733         return 1;
1734 }
1735
1736 // return value:
1737 //    1 = WP created
1738 //    0 = no action needed
1739 //   -1 = temp fail, try from world too
1740 //   -2 = permanent fail, do not retry
1741 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1742 {
1743         // make it possible to go from p to wp, if we can
1744         // if wp is NULL, nearest is chosen
1745
1746         entity w;
1747         vector porg;
1748         float t, tmin, tmax;
1749         vector o;
1750         vector save;
1751
1752         if(!botframe_autowaypoints_fixdown(p.origin))
1753                 return -2;
1754         porg = trace_endpos;
1755
1756         if(wp)
1757         {
1758                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1759
1760                 // if wp -> porg, then OK
1761                 float maxdist;
1762                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1763                 {
1764                         // we may find a better one
1765                         maxdist = vlen(wp.origin - porg);
1766                 }
1767                 else
1768                 {
1769                         // accept any "good"
1770                         maxdist = 2100;
1771                 }
1772
1773                 float bestdist = maxdist;
1774                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1775                 {
1776                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1777                         if(d < bestdist)
1778                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1779                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1780                         {
1781                                 bestdist = d;
1782                                 p.(fld) = it;
1783                         }
1784                 });
1785                 if(bestdist < maxdist)
1786                 {
1787                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1788                         return 0;
1789                 }
1790
1791                 if(bestdist < 2100)
1792                 {
1793                         // we know maxdist < 2100
1794                         // so wp -> porg is still valid
1795                         // all is good
1796                         p.(fld) = wp;
1797                         return 0;
1798                 }
1799
1800                 // otherwise, no existing WP can fix our issues
1801         }
1802         else
1803         {
1804                 save = p.origin;
1805                 setorigin(p, porg);
1806                 w = navigation_findnearestwaypoint(p, walkfromwp);
1807                 setorigin(p, save);
1808                 if(w)
1809                 {
1810                         p.(fld) = w;
1811                         return 0;
1812                 }
1813         }
1814
1815         tmin = 0;
1816         tmax = 1;
1817         for (;;)
1818         {
1819                 if(tmax - tmin < 0.001)
1820                 {
1821                         // did not get a good candidate
1822                         return -1;
1823                 }
1824
1825                 t = (tmin + tmax) * 0.5;
1826                 o = antilag_takebackorigin(p, CS(p), time - t);
1827                 if(!botframe_autowaypoints_fixdown(o))
1828                         return -2;
1829                 o = trace_endpos;
1830
1831                 if(wp)
1832                 {
1833                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1834                         {
1835                                 // we cannot walk from wp.origin to o
1836                                 // get closer to tmax
1837                                 tmin = t;
1838                                 continue;
1839                         }
1840                 }
1841                 else
1842                 {
1843                         save = p.origin;
1844                         setorigin(p, o);
1845                         w = navigation_findnearestwaypoint(p, walkfromwp);
1846                         setorigin(p, save);
1847                         if(!w)
1848                         {
1849                                 // we cannot walk from any WP to o
1850                                 // get closer to tmax
1851                                 tmin = t;
1852                                 continue;
1853                         }
1854                 }
1855
1856                 // if we get here, o is valid regarding waypoints
1857                 // check if o is connected right to the player
1858                 // we break if it succeeds, as that means o is a good waypoint location
1859                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1860                         break;
1861
1862                 // o is no good, we need to get closer to the player
1863                 tmax = t;
1864         }
1865
1866         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1867         botframe_autowaypoints_createwp(o, p, fld, 0);
1868         return 1;
1869 }
1870
1871 // automatically create missing waypoints
1872 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1873 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1874 {
1875         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1876         if(r != -1)
1877                 return;
1878         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1879         if(r != -1)
1880                 return;
1881
1882         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1883         if(!botframe_autowaypoints_fixdown(p.origin))
1884                 return; // shouldn't happen, caught above
1885         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1886 }
1887
1888 void botframe_deleteuselesswaypoints()
1889 {
1890         IL_EACH(g_items, it.bot_pickup,
1891         {
1892                 // NOTE: this protects waypoints if they're the ONLY nearest
1893                 // waypoint. That's the intention.
1894                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1895                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1896         });
1897         IL_EACH(g_waypoints, true,
1898         {
1899                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1900                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1901                 // WP is useful if:
1902                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1903                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1904                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1905                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1906                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1907                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1908                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1909                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1910                 // b) WP is closest WP for an item/spawnpoint/other entity
1911                 //    This has been done above by protecting these WPs.
1912         });
1913         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1914         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1915         {
1916                 for (int m = 0; m < 32; ++m)
1917                 {
1918                         entity w = waypoint_get_link(it, m);
1919                         if (!w)
1920                                 break;
1921                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1922                                 continue;
1923                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1924                                 continue;
1925                         for (int j = 0; j < 32; ++j)
1926                         {
1927                                 entity w2 = waypoint_get_link(w, j);
1928                                 if (!w2)
1929                                         break;
1930                                 if (it == w2)
1931                                         continue;
1932                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1933                                         continue;
1934                                 // If we got here, it != w2 exist with it -> w
1935                                 // and w -> w2. That means the waypoint is not
1936                                 // a dead end.
1937                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1938                                 for (int k = 0; k < 32; ++k)
1939                                 {
1940                                         if (waypoint_get_link(it, k) == w2)
1941                                                 continue;
1942                                         // IF WE GET HERE, w is proven useful
1943                                         // to get from it to w2!
1944                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1945                                         goto next;
1946                                 }
1947                         }
1948 LABEL(next)
1949                 }
1950         });
1951         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1952         //     they are needed to complete routes while autowaypointing.
1953
1954         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1955         {
1956                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1957                 te_explosion(it.origin);
1958                 waypoint_remove(it);
1959                 break;
1960         });
1961
1962         IL_EACH(g_waypoints, true,
1963         {
1964                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1965         });
1966 }
1967
1968 void botframe_autowaypoints()
1969 {
1970         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1971                 // going back is broken, so only fix waypoints to walk TO the player
1972                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1973                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1974                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1975         });
1976
1977         if (autocvar_g_waypointeditor_auto >= 2) {
1978                 botframe_deleteuselesswaypoints();
1979         }
1980 }
1981