qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27         entity e2 = navigation_findnearestwaypoint(pl, false);
  28         navigation_markroutes(pl, e2);
  29
  30         int j = 0;
  31         int m = 0;
  32         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  33         {
  34                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  35                 it.colormod_z = 8;
  36                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  37                 j++;
  38                 m++;
  39         });
  40         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  41         navigation_markroutes_inverted(e2);
  42
  43         j = 0;
  44         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  45         {
  46                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  47                 it.colormod_x = 8;
  48                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  49                         m++;
  50                 it.effects |= EF_NODEPTHTEST | EF_RED;
  51                 j++;
  52         });
  53         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  54         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  55
  56         j = 0;
  57         IL_EACH(g_spawnpoints, true,
  58         {
  59                 if (navigation_findnearestwaypoint(it, false))
  60                 {
  61                         if(it.spawnpointmodel)
  62                         {
  63                                 delete(it.spawnpointmodel);
  64                                 it.spawnpointmodel = NULL;
  65                         }
  66                 }
  67                 else
  68                 {
  69                         if(!it.spawnpointmodel)
  70                         {
  71                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  72                                 entity e = new(spawnpointmodel);
  73                                 vector org = trace_endpos + eZ;
  74                                 setorigin(e, org);
  75                                 e.solid = SOLID_TRIGGER;
  76                                 it.spawnpointmodel = e;
  77                         }
  78                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  79                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  80                         _setmodel(it.spawnpointmodel, pl.model);
  81                         it.spawnpointmodel.frame = pl.frame;
  82                         it.spawnpointmodel.skin = pl.skin;
  83                         it.spawnpointmodel.colormap = pl.colormap;
  84                         it.spawnpointmodel.colormod = pl.colormod;
  85                         it.spawnpointmodel.glowmod = pl.glowmod;
  86                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  87                         j++;
  88                 }
  89         });
  90         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  91
  92         j = 0;
  93         IL_EACH(g_items, true,
  94         {
  95                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  96                 it.colormod = '0.5 0.5 0.5';
  97         });
  98         IL_EACH(g_items, true,
  99         {
 100                 if (navigation_findnearestwaypoint(it, false))
 101                         continue;
 102                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 103                 it.effects |= EF_NODEPTHTEST | EF_RED;
 104                 it.colormod_x = 8;
 105                 j++;
 106         });
 107         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 108
 109         j = 0;
 110         IL_EACH(g_items, true,
 111         {
 112                 if (navigation_findnearestwaypoint(it, true))
 113                         continue;
 114                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 115                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 116                 it.colormod_z = 8;
 117                 j++;
 118         });
 119         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 120 }
 121
 122 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 123 {
 124         vector new_org = org;
 125         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 126         {
 127                 vector map_center = havocbot_middlepoint;
 128                 if (autocvar_g_waypointeditor_symmetrical == -1)
 129                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 130
 131                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 132         }
 133         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 134         {
 135                 float m = havocbot_symmetryaxis_equation.x;
 136                 float q = havocbot_symmetryaxis_equation.y;
 137                 if (autocvar_g_waypointeditor_symmetrical == -2)
 138                 {
 139                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 140                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 141                 }
 142
 143                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 144                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 145         }
 146         new_org.z = org.z;
 147         return new_org;
 148 }
 149
 150 void waypoint_setupmodel(entity wp)
 151 {
 152         if (autocvar_g_waypointeditor)
 153         {
 154                 // TODO: add some sort of visible box in edit mode for box waypoints
 155                 vector m1 = wp.mins;
 156                 vector m2 = wp.maxs;
 157                 setmodel(wp, MDL_WAYPOINT);
 158                 setsize(wp, m1, m2);
 159                 wp.effects = EF_LOWPRECISION;
 160                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 161                         wp.colormod = '1 0 0';
 162                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 163                         wp.colormod = '1 1 0';
 164                 else
 165                         wp.colormod = '1 1 1';
 166         }
 167         else
 168                 wp.model = "";
 169 }
 170
 171 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 172 // them back to it as well
 173 // (suitable for spawnfunc_waypoint editor)
 174 entity waypoint_spawn(vector m1, vector m2, float f)
 175 {
 176         if(!(f & WAYPOINTFLAG_PERSONAL))
 177         {
 178                 vector em1 = m1;
 179                 vector em2 = m2;
 180                 if (m1 == m2)
 181                 {
 182                         em1 = m1 - '8 8 8';
 183                         em2 = m2 + '8 8 8';
 184                 }
 185                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 186                 {
 187                         return it;
 188                 });
 189         }
 190
 191         entity w = new(waypoint);
 192         IL_PUSH(g_waypoints, w);
 193         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 194         w.wpflags = f;
 195         w.solid = SOLID_TRIGGER;
 196         setorigin(w, (m1 + m2) * 0.5);
 197         setsize(w, m1 - w.origin, m2 - w.origin);
 198         if (w.size)
 199                 w.wpisbox = true;
 200
 201         if(!w.wpisbox)
 202         {
 203                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 204                 if(!move_out_of_solid(w))
 205                 {
 206                         if(!(f & WAYPOINTFLAG_GENERATED))
 207                         {
 208                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 209                                 delete(w);
 210                                 return NULL;
 211                         }
 212                         else
 213                         {
 214                                 if(autocvar_developer)
 215                                 {
 216                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 217                                         backtrace("Waypoint stuck");
 218                                 }
 219                         }
 220                 }
 221                 setsize(w, '0 0 0', '0 0 0');
 222         }
 223
 224         waypoint_clearlinks(w);
 225         //waypoint_schedulerelink(w);
 226
 227         waypoint_setupmodel(w);
 228
 229         return w;
 230 }
 231
 232 void waypoint_spawn_fromeditor(entity pl)
 233 {
 234         entity e;
 235         vector org = pl.origin;
 236         int ctf_flags = havocbot_symmetryaxis_equation.z;
 237         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 238                    || (autocvar_g_waypointeditor_symmetrical < 0));
 239         int order = ctf_flags;
 240         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 241         {
 242                 order = autocvar_g_waypointeditor_symmetrical_order;
 243                 ctf_flags = order;
 244         }
 245
 246         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 247         {
 248                 // snap waypoint to item's origin if close enough
 249                 IL_EACH(g_items, true,
 250                 {
 251                         vector item_org = (it.absmin + it.absmax) * 0.5;
 252                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 253                         if(vlen(item_org - org) < 30)
 254                         {
 255                                 org = item_org;
 256                                 break;
 257                         }
 258                 });
 259         }
 260
 261         LABEL(add_wp);
 262         e = waypoint_spawn(org, org, 0);
 263         waypoint_schedulerelink(e);
 264         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 265         if(sym)
 266         {
 267                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 268                 if (vdist(org - pl.origin, >, 32))
 269                 {
 270                         if(order > 2)
 271                                 order--;
 272                         else
 273                                 sym = false;
 274                         goto add_wp;
 275                 }
 276         }
 277 }
 278
 279 void waypoint_remove(entity wp)
 280 {
 281         // tell all waypoints linked to wp that they need to relink
 282         IL_EACH(g_waypoints, it != wp,
 283         {
 284                 if (waypoint_islinked(it, wp))
 285                         waypoint_removelink(it, wp);
 286         });
 287         delete(wp);
 288 }
 289
 290 void waypoint_remove_fromeditor(entity pl)
 291 {
 292         entity e = navigation_findnearestwaypoint(pl, false);
 293
 294         int ctf_flags = havocbot_symmetryaxis_equation.z;
 295         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 296                    || (autocvar_g_waypointeditor_symmetrical < 0));
 297         int order = ctf_flags;
 298         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 299         {
 300                 order = autocvar_g_waypointeditor_symmetrical_order;
 301                 ctf_flags = order;
 302         }
 303
 304         LABEL(remove_wp);
 305         if (!e) return;
 306         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 307
 308         if (e.wphardwired)
 309         {
 310                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 311                 return;
 312         }
 313
 314         entity wp_sym = NULL;
 315         if (sym)
 316         {
 317                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 318                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 319                         if(vdist(org - it.origin, <, 3))
 320                         {
 321                                 wp_sym = it;
 322                                 break;
 323                         }
 324                 });
 325         }
 326
 327         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 328         waypoint_remove(e);
 329
 330         if (sym && wp_sym)
 331         {
 332                 e = wp_sym;
 333                 if(order > 2)
 334                         order--;
 335                 else
 336                         sym = false;
 337                 goto remove_wp;
 338         }
 339 }
 340
 341 void waypoint_removelink(entity from, entity to)
 342 {
 343         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 344                 return;
 345
 346         bool found = false;
 347         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 348         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 349         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 350         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 351         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 352         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 353         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 354         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 355         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 356         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 357         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 358         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 359         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 360         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 361         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 362         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 363         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 364         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 365         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 366         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 367         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 368         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 369         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 370         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 371         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 372         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 373         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 374         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 375         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 376         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 377         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 378         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 379 }
 380
 381 bool waypoint_islinked(entity from, entity to)
 382 {
 383         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 384         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 385         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 386         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 387         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 388         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 389         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 390         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 391         return false;
 392 }
 393
 394 void waypoint_updatecost_foralllinks()
 395 {
 396         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 397         {
 398                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 399                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 400                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 401                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 402                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 403                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 404                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 405                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 406                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 407                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 408                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 409                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 410                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 411                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 412                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 413                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 414                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 415                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 416                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 417                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 418                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 419                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 420                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 421                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 422                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 423                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 424                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 425                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 426                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 427                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 428                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 429                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 430         });
 431 }
 432
 433 float waypoint_getdistancecost_simple(float dist)
 434 {
 435         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 436                 return dist / (autocvar_sv_maxspeed * 1.25);
 437         return dist / autocvar_sv_maxspeed;
 438 }
 439
 440 float waypoint_getdistancecost(vector from, vector to)
 441 {
 442         float c = waypoint_getdistancecost_simple(vlen(to - from));
 443
 444         float height = from.z - to.z;
 445         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 446         {
 447                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 448                 c = waypoint_getdistancecost_simple(vlen(vec2(to - from))); // xy distance cost
 449                 if(height_cost > c)
 450                         c = height_cost;
 451         }
 452         return c;
 453 }
 454
 455 float waypoint_getlinkcost(entity from, entity to)
 456 {
 457         vector v1 = from.origin;
 458         vector v2 = to.origin;
 459         if (from.wpisbox)
 460         {
 461                 vector m1 = to.absmin, m2 = to.absmax;
 462                 v1_x = bound(m1_x, v1_x, m2_x);
 463                 v1_y = bound(m1_y, v1_y, m2_y);
 464                 v1_z = bound(m1_z, v1_z, m2_z);
 465         }
 466         if (to.wpisbox)
 467         {
 468                 vector m1 = from.absmin, m2 = from.absmax;
 469                 v2_x = bound(m1_x, v2_x, m2_x);
 470                 v2_y = bound(m1_y, v2_y, m2_y);
 471                 v2_z = bound(m1_z, v2_z, m2_z);
 472         }
 473         return waypoint_getdistancecost(v1, v2);
 474 }
 475
 476 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 477 // if c == -1 automatically determine cost of the link
 478 void waypoint_addlink_customcost(entity from, entity to, float c)
 479 {
 480         if (from == to || waypoint_islinked(from, to))
 481                 return;
 482         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 483                 return;
 484
 485         if(c == -1)
 486                 c = waypoint_getlinkcost(from, to);
 487
 488         if (from.wp31mincost < c) return;
 489         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 490         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 491         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 492         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 493         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 494         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 495         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 496         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 497         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 498         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 499         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 500         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 501         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 502         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 503         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 504         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 505         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 506         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 507         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 508         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 509         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 510         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 511         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 512         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 513         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 514         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 515         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 516         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 517         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 518         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 519         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 520         from.wp00 = to;from.wp00mincost = c;return;
 521 }
 522
 523 void waypoint_addlink(entity from, entity to)
 524 {
 525         waypoint_addlink_customcost(from, to, -1);
 526 }
 527
 528 // relink this spawnfunc_waypoint
 529 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 530 // (SLOW!)
 531 void waypoint_think(entity this)
 532 {
 533         vector sv, sm1, sm2, ev, em1, em2, dv;
 534
 535         bot_calculate_stepheightvec();
 536
 537         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 538
 539         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 540         sm1 = this.origin + this.mins;
 541         sm2 = this.origin + this.maxs;
 542         IL_EACH(g_waypoints, this != it,
 543         {
 544                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 545                 {
 546                         waypoint_addlink(this, it);
 547                         waypoint_addlink(it, this);
 548                 }
 549                 else
 550                 {
 551                         ++relink_total;
 552                         if(!checkpvs(this.origin, it))
 553                         {
 554                                 ++relink_pvsculled;
 555                                 continue;
 556                         }
 557                         sv = it.origin;
 558                         sv.x = bound(sm1_x, sv.x, sm2_x);
 559                         sv.y = bound(sm1_y, sv.y, sm2_y);
 560                         sv.z = bound(sm1_z, sv.z, sm2_z);
 561                         ev = this.origin;
 562                         em1 = it.origin + it.mins;
 563                         em2 = it.origin + it.maxs;
 564                         ev.x = bound(em1_x, ev.x, em2_x);
 565                         ev.y = bound(em1_y, ev.y, em2_y);
 566                         ev.z = bound(em1_z, ev.z, em2_z);
 567                         dv = ev - sv;
 568                         dv.z = 0;
 569                         if(vdist(dv, >=, 1050)) // max search distance in XY
 570                         {
 571                                 ++relink_lengthculled;
 572                                 continue;
 573                         }
 574                         navigation_testtracewalk = 0;
 575                         if (!this.wpisbox)
 576                         {
 577                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 578                                 if (!trace_startsolid)
 579                                 {
 580                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 581                                         sv = trace_endpos + '0 0 1';
 582                                 }
 583                         }
 584                         if (!it.wpisbox)
 585                         {
 586                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 587                                 if (!trace_startsolid)
 588                                 {
 589                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 590                                         ev = trace_endpos + '0 0 1';
 591                                 }
 592                         }
 593                         //traceline(this.origin, it.origin, false, NULL);
 594                         //if (trace_fraction == 1)
 595                         if (!this.wpisbox && tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev, MOVE_NOMONSTERS))
 596                                 waypoint_addlink(this, it);
 597                         else
 598                                 relink_walkculled += 0.5;
 599                         if (!it.wpisbox && tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv, MOVE_NOMONSTERS))
 600                                 waypoint_addlink(it, this);
 601                         else
 602                                 relink_walkculled += 0.5;
 603                 }
 604         });
 605         navigation_testtracewalk = 0;
 606         this.wplinked = true;
 607 }
 608
 609 void waypoint_clearlinks(entity wp)
 610 {
 611         // clear links to other waypoints
 612         float f = 10000000;
 613         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 614         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 615         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 616         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 617
 618         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 619         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 620         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 621         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 622
 623         wp.wplinked = false;
 624 }
 625
 626 // tell a spawnfunc_waypoint to relink
 627 void waypoint_schedulerelink(entity wp)
 628 {
 629         if (wp == NULL)
 630                 return;
 631
 632         waypoint_setupmodel(wp);
 633         wp.wpisbox = vdist(wp.size, >, 0);
 634         wp.enemy = NULL;
 635         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 636                 wp.owner = NULL;
 637         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 638                 waypoint_clearlinks(wp);
 639         // schedule an actual relink on next frame
 640         setthink(wp, waypoint_think);
 641         wp.nextthink = time;
 642         wp.effects = EF_LOWPRECISION;
 643 }
 644
 645 // spawnfunc_waypoint map entity
 646 spawnfunc(waypoint)
 647 {
 648         IL_PUSH(g_waypoints, this);
 649
 650         setorigin(this, this.origin);
 651         // schedule a relink after other waypoints have had a chance to spawn
 652         waypoint_clearlinks(this);
 653         //waypoint_schedulerelink(this);
 654 }
 655
 656 // tell all waypoints to relink
 657 // actually this is useful only to update relink_* stats
 658 void waypoint_schedulerelinkall()
 659 {
 660         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 661         IL_EACH(g_waypoints, true,
 662         {
 663                 waypoint_schedulerelink(it);
 664         });
 665         waypoint_load_links_hardwired();
 666 }
 667
 668 // Load waypoint links from file
 669 bool waypoint_load_links()
 670 {
 671         string filename, s;
 672         float file, tokens, c = 0, found;
 673         entity wp_from = NULL, wp_to;
 674         vector wp_to_pos, wp_from_pos;
 675         filename = strcat("maps/", mapname);
 676         filename = strcat(filename, ".waypoints.cache");
 677         file = fopen(filename, FILE_READ);
 678
 679         if (file < 0)
 680         {
 681                 LOG_TRACE("waypoint links load from ");
 682                 LOG_TRACE(filename);
 683                 LOG_TRACE(" failed");
 684                 return false;
 685         }
 686
 687         while ((s = fgets(file)))
 688         {
 689                 tokens = tokenizebyseparator(s, "*");
 690
 691                 if (tokens!=2)
 692                 {
 693                         // bad file format
 694                         fclose(file);
 695                         return false;
 696                 }
 697
 698                 wp_from_pos     = stov(argv(0));
 699                 wp_to_pos       = stov(argv(1));
 700
 701                 // Search "from" waypoint
 702                 if(!wp_from || wp_from.origin!=wp_from_pos)
 703                 {
 704                         wp_from = findradius(wp_from_pos, 1);
 705                         found = false;
 706                         while(wp_from)
 707                         {
 708                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 709                                 if(wp_from.classname == "waypoint")
 710                                 {
 711                                         found = true;
 712                                         break;
 713                                 }
 714                                 wp_from = wp_from.chain;
 715                         }
 716
 717                         if(!found)
 718                         {
 719                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 720                                 continue;
 721                         }
 722
 723                 }
 724
 725                 // Search "to" waypoint
 726                 wp_to = findradius(wp_to_pos, 1);
 727                 found = false;
 728                 while(wp_to)
 729                 {
 730                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 731                         if(wp_to.classname == "waypoint")
 732                         {
 733                                 found = true;
 734                                 break;
 735                         }
 736                         wp_to = wp_to.chain;
 737                 }
 738
 739                 if(!found)
 740                 {
 741                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 742                         continue;
 743                 }
 744
 745                 ++c;
 746                 waypoint_addlink(wp_from, wp_to);
 747         }
 748
 749         fclose(file);
 750
 751         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 752
 753         botframe_cachedwaypointlinks = true;
 754         return true;
 755 }
 756
 757 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 758 {
 759         string filename, s;
 760         float file, tokens, c = 0, found;
 761         entity wp_from = NULL, wp_to;
 762         vector wp_to_pos, wp_from_pos;
 763         filename = strcat("maps/", mapname);
 764         filename = strcat(filename, ".waypoints.hardwired");
 765         file = fopen(filename, FILE_READ);
 766
 767         botframe_loadedforcedlinks = true;
 768
 769         if (file < 0)
 770         {
 771                 if(!removal_mode)
 772                         LOG_TRACE("waypoint links load from ", filename, " failed");
 773                 return;
 774         }
 775
 776         while ((s = fgets(file)))
 777         {
 778                 if(substring(s, 0, 2)=="//")
 779                         continue;
 780
 781                 if(substring(s, 0, 1)=="#")
 782                         continue;
 783
 784                 tokens = tokenizebyseparator(s, "*");
 785
 786                 if (tokens!=2)
 787                         continue;
 788
 789                 wp_from_pos     = stov(argv(0));
 790                 wp_to_pos       = stov(argv(1));
 791
 792                 // Search "from" waypoint
 793                 if(!wp_from || wp_from.origin!=wp_from_pos)
 794                 {
 795                         wp_from = findradius(wp_from_pos, 5);
 796                         found = false;
 797                         while(wp_from)
 798                         {
 799                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 800                                 if(wp_from.classname == "waypoint")
 801                                 {
 802                                         found = true;
 803                                         break;
 804                                 }
 805                                 wp_from = wp_from.chain;
 806                         }
 807
 808                         if(!found)
 809                         {
 810                                 if(!removal_mode)
 811                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 812                                 continue;
 813                         }
 814                 }
 815
 816                 // Search "to" waypoint
 817                 wp_to = findradius(wp_to_pos, 5);
 818                 found = false;
 819                 while(wp_to)
 820                 {
 821                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 822                         if(wp_to.classname == "waypoint")
 823                         {
 824                                 found = true;
 825                                 break;
 826                         }
 827                         wp_to = wp_to.chain;
 828                 }
 829
 830                 if(!found)
 831                 {
 832                         if(!removal_mode)
 833                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 834                         continue;
 835                 }
 836
 837                 ++c;
 838                 if(removal_mode)
 839                 {
 840                         waypoint_removelink(wp_from, wp_to);
 841                         continue;
 842                 }
 843
 844                 waypoint_addlink(wp_from, wp_to);
 845                 wp_from.wphardwired = true;
 846                 wp_to.wphardwired = true;
 847         }
 848
 849         fclose(file);
 850
 851         if(!removal_mode)
 852                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 853 }
 854
 855 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 856 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 857
 858 entity waypoint_get_link(entity w, float i)
 859 {
 860         switch(i)
 861         {
 862                 case  0:return w.wp00;
 863                 case  1:return w.wp01;
 864                 case  2:return w.wp02;
 865                 case  3:return w.wp03;
 866                 case  4:return w.wp04;
 867                 case  5:return w.wp05;
 868                 case  6:return w.wp06;
 869                 case  7:return w.wp07;
 870                 case  8:return w.wp08;
 871                 case  9:return w.wp09;
 872                 case 10:return w.wp10;
 873                 case 11:return w.wp11;
 874                 case 12:return w.wp12;
 875                 case 13:return w.wp13;
 876                 case 14:return w.wp14;
 877                 case 15:return w.wp15;
 878                 case 16:return w.wp16;
 879                 case 17:return w.wp17;
 880                 case 18:return w.wp18;
 881                 case 19:return w.wp19;
 882                 case 20:return w.wp20;
 883                 case 21:return w.wp21;
 884                 case 22:return w.wp22;
 885                 case 23:return w.wp23;
 886                 case 24:return w.wp24;
 887                 case 25:return w.wp25;
 888                 case 26:return w.wp26;
 889                 case 27:return w.wp27;
 890                 case 28:return w.wp28;
 891                 case 29:return w.wp29;
 892                 case 30:return w.wp30;
 893                 case 31:return w.wp31;
 894                 default:return NULL;
 895         }
 896 }
 897
 898 // Save all waypoint links to a file
 899 void waypoint_save_links()
 900 {
 901         // temporarily remove hardwired links so they don't get saved among normal links
 902         waypoint_remove_links_hardwired();
 903
 904         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 905         int file = fopen(filename, FILE_WRITE);
 906         if (file < 0)
 907         {
 908                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 909                 return;
 910         }
 911
 912         int c = 0;
 913         IL_EACH(g_waypoints, true,
 914         {
 915                 for(int j = 0; j < 32; ++j)
 916                 {
 917                         entity link = waypoint_get_link(it, j);
 918                         if(link)
 919                         {
 920                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 921                                 fputs(file, s);
 922                                 ++c;
 923                         }
 924                 }
 925         });
 926         fclose(file);
 927         botframe_cachedwaypointlinks = true;
 928
 929         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 930
 931         waypoint_load_links_hardwired();
 932 }
 933
 934 // save waypoints to gamedir/data/maps/mapname.waypoints
 935 void waypoint_saveall()
 936 {
 937         string filename = sprintf("maps/%s.waypoints", mapname);
 938         int file = fopen(filename, FILE_WRITE);
 939         if (file < 0)
 940         {
 941                 waypoint_save_links(); // save anyway?
 942                 botframe_loadedforcedlinks = false;
 943
 944                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 945                 return;
 946         }
 947
 948         int c = 0;
 949         IL_EACH(g_waypoints, true,
 950         {
 951                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 952                         continue;
 953
 954                 string s;
 955                 s = strcat(vtos(it.origin + it.mins), "\n");
 956                 s = strcat(s, vtos(it.origin + it.maxs));
 957                 s = strcat(s, "\n");
 958                 s = strcat(s, ftos(it.wpflags));
 959                 s = strcat(s, "\n");
 960                 fputs(file, s);
 961                 c++;
 962         });
 963         fclose(file);
 964         waypoint_save_links();
 965         botframe_loadedforcedlinks = false;
 966
 967         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 968 }
 969
 970 // load waypoints from file
 971 float waypoint_loadall()
 972 {
 973         string filename, s;
 974         float file, cwp, cwb, fl;
 975         vector m1, m2;
 976         cwp = 0;
 977         cwb = 0;
 978         filename = strcat("maps/", mapname);
 979         filename = strcat(filename, ".waypoints");
 980         file = fopen(filename, FILE_READ);
 981         if (file >= 0)
 982         {
 983                 while ((s = fgets(file)))
 984                 {
 985                         m1 = stov(s);
 986                         s = fgets(file);
 987                         if (!s)
 988                                 break;
 989                         m2 = stov(s);
 990                         s = fgets(file);
 991                         if (!s)
 992                                 break;
 993                         fl = stof(s);
 994                         waypoint_spawn(m1, m2, fl);
 995                         if (m1 == m2)
 996                                 cwp = cwp + 1;
 997                         else
 998                                 cwb = cwb + 1;
 999                 }
1000                 fclose(file);
1001                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1002         }
1003         else
1004         {
1005                 LOG_TRACE("waypoint load from ", filename, " failed");
1006         }
1007         return cwp + cwb;
1008 }
1009
1010 vector waypoint_fixorigin(vector position)
1011 {
1012         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1013         if(trace_fraction < 1)
1014                 position = trace_endpos;
1015         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1016         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
1017         return position;
1018 }
1019
1020 void waypoint_spawnforitem_force(entity e, vector org)
1021 {
1022         // Fix the waypoint altitude if necessary
1023         org = waypoint_fixorigin(org);
1024
1025         // don't spawn an item spawnfunc_waypoint if it already exists
1026         IL_EACH(g_waypoints, true,
1027         {
1028                 if(it.wpisbox)
1029                 {
1030                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1031                         {
1032                                 e.nearestwaypoint = it;
1033                                 return;
1034                         }
1035                 }
1036                 else
1037                 {
1038                         if(vdist(it.origin - org, <, 16))
1039                         {
1040                                 e.nearestwaypoint = it;
1041                                 return;
1042                         }
1043                 }
1044         });
1045
1046         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1047 }
1048
1049 void waypoint_spawnforitem(entity e)
1050 {
1051         if(!bot_waypoints_for_items)
1052                 return;
1053
1054         waypoint_spawnforitem_force(e, e.origin);
1055 }
1056
1057 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1058 {
1059         entity w;
1060         entity dw;
1061         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1062         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1063         // one way link to the destination
1064         w.wp00 = dw;
1065         w.wp00mincost = timetaken; // this is just for jump pads
1066         // the teleporter's nearest spawnfunc_waypoint is this one
1067         // (teleporters are not goals, so this is probably useless)
1068         e.nearestwaypoint = w;
1069         e.nearestwaypointtimeout = -1;
1070 }
1071
1072 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
1073 {
1074         org = waypoint_fixorigin(org);
1075         destination = waypoint_fixorigin(destination);
1076         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1077 }
1078
1079 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1080 {
1081         destination = waypoint_fixorigin(destination);
1082         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin, e.absmax, destination, destination, timetaken);
1083 }
1084
1085 entity waypoint_spawnpersonal(entity this, vector position)
1086 {
1087         entity w;
1088
1089         // drop the waypoint to a proper location:
1090         //   first move it up by a player height
1091         //   then move it down to hit the floor with player bbox size
1092         position = waypoint_fixorigin(position);
1093
1094         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1095         w.nearestwaypoint = NULL;
1096         w.nearestwaypointtimeout = 0;
1097         w.owner = this;
1098
1099         waypoint_schedulerelink(w);
1100
1101         return w;
1102 }
1103
1104 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1105 {
1106         if (!(wp1 && wp2))
1107                 return;
1108
1109         if (wp1.wphardwired && wp2.wphardwired)
1110                 te_beam(NULL, wp1.origin, wp2.origin);
1111         else if (display_type == 1)
1112                 te_lightning2(NULL, wp1.origin, wp2.origin);
1113 }
1114
1115 void waypoint_showlinks_to(entity wp, int display_type)
1116 {
1117         IL_EACH(g_waypoints, it != wp,
1118         {
1119                 if (waypoint_islinked(it, wp))
1120                         waypoint_showlink(it, wp, display_type);
1121         });
1122 }
1123
1124 void waypoint_showlinks_from(entity wp, int display_type)
1125 {
1126         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1127         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1128         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1129         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1130         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1131         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1132         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1133         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1134         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1135         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1136         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1137         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1138         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1139         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1140         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1141         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1142 }
1143
1144 void botframe_showwaypointlinks()
1145 {
1146         if (time < botframe_waypointeditorlightningtime)
1147                 return;
1148         botframe_waypointeditorlightningtime = time + 0.5;
1149         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1150         {
1151                 int display_type = 0;
1152                 entity head = navigation_findnearestwaypoint(it, false);
1153                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1154                         display_type = 1; // default
1155                 else if(head && (head.wphardwired))
1156                         display_type = 2; // only hardwired
1157
1158                 if (display_type)
1159                 {
1160                         //navigation_testtracewalk = true;
1161                         //print("currently selected WP is ", etos(head), "\n");
1162                         //navigation_testtracewalk = false;
1163                         if (head)
1164                         {
1165                                 te_lightning2(NULL, head.origin, it.origin);
1166                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1167                                         waypoint_showlinks_to(head, display_type);
1168                                 else
1169                                         waypoint_showlinks_from(head, display_type);
1170                         }
1171                 }
1172         });
1173 }
1174
1175 float botframe_autowaypoints_fixdown(vector v)
1176 {
1177         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1178         if(trace_fraction >= 1)
1179                 return 0;
1180         return 1;
1181 }
1182
1183 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1184 {
1185         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1186         {
1187                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1188                 return 0;
1189         });
1190
1191         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1192         return 1;
1193 }
1194
1195 // return value:
1196 //    1 = WP created
1197 //    0 = no action needed
1198 //   -1 = temp fail, try from world too
1199 //   -2 = permanent fail, do not retry
1200 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1201 {
1202         // make it possible to go from p to wp, if we can
1203         // if wp is NULL, nearest is chosen
1204
1205         entity w;
1206         vector porg;
1207         float t, tmin, tmax;
1208         vector o;
1209         vector save;
1210
1211         if(!botframe_autowaypoints_fixdown(p.origin))
1212                 return -2;
1213         porg = trace_endpos;
1214
1215         if(wp)
1216         {
1217                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1218
1219                 // if wp -> porg, then OK
1220                 float maxdist;
1221                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
1222                 {
1223                         // we may find a better one
1224                         maxdist = vlen(wp.origin - porg);
1225                 }
1226                 else
1227                 {
1228                         // accept any "good"
1229                         maxdist = 2100;
1230                 }
1231
1232                 float bestdist = maxdist;
1233                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1234                 {
1235                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1236                         if(d < bestdist)
1237                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
1238                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
1239                         {
1240                                 bestdist = d;
1241                                 p.(fld) = it;
1242                         }
1243                 });
1244                 if(bestdist < maxdist)
1245                 {
1246                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1247                         return 0;
1248                 }
1249
1250                 if(bestdist < 2100)
1251                 {
1252                         // we know maxdist < 2100
1253                         // so wp -> porg is still valid
1254                         // all is good
1255                         p.(fld) = wp;
1256                         return 0;
1257                 }
1258
1259                 // otherwise, no existing WP can fix our issues
1260         }
1261         else
1262         {
1263                 save = p.origin;
1264                 setorigin(p, porg);
1265                 w = navigation_findnearestwaypoint(p, walkfromwp);
1266                 setorigin(p, save);
1267                 if(w)
1268                 {
1269                         p.(fld) = w;
1270                         return 0;
1271                 }
1272         }
1273
1274         tmin = 0;
1275         tmax = 1;
1276         for (;;)
1277         {
1278                 if(tmax - tmin < 0.001)
1279                 {
1280                         // did not get a good candidate
1281                         return -1;
1282                 }
1283
1284                 t = (tmin + tmax) * 0.5;
1285                 o = antilag_takebackorigin(p, CS(p), time - t);
1286                 if(!botframe_autowaypoints_fixdown(o))
1287                         return -2;
1288                 o = trace_endpos;
1289
1290                 if(wp)
1291                 {
1292                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1293                         {
1294                                 // we cannot walk from wp.origin to o
1295                                 // get closer to tmax
1296                                 tmin = t;
1297                                 continue;
1298                         }
1299                 }
1300                 else
1301                 {
1302                         save = p.origin;
1303                         setorigin(p, o);
1304                         w = navigation_findnearestwaypoint(p, walkfromwp);
1305                         setorigin(p, save);
1306                         if(!w)
1307                         {
1308                                 // we cannot walk from any WP to o
1309                                 // get closer to tmax
1310                                 tmin = t;
1311                                 continue;
1312                         }
1313                 }
1314
1315                 // if we get here, o is valid regarding waypoints
1316                 // check if o is connected right to the player
1317                 // we break if it succeeds, as that means o is a good waypoint location
1318                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1319                         break;
1320
1321                 // o is no good, we need to get closer to the player
1322                 tmax = t;
1323         }
1324
1325         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1326         botframe_autowaypoints_createwp(o, p, fld, 0);
1327         return 1;
1328 }
1329
1330 // automatically create missing waypoints
1331 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1332 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1333 {
1334         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1335         if(r != -1)
1336                 return;
1337         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1338         if(r != -1)
1339                 return;
1340
1341         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1342         if(!botframe_autowaypoints_fixdown(p.origin))
1343                 return; // shouldn't happen, caught above
1344         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1345 }
1346
1347 void botframe_deleteuselesswaypoints()
1348 {
1349         IL_EACH(g_items, it.bot_pickup,
1350         {
1351                 // NOTE: this protects waypoints if they're the ONLY nearest
1352                 // waypoint. That's the intention.
1353                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1354                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1355         });
1356         IL_EACH(g_waypoints, true,
1357         {
1358                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1359                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1360                 // WP is useful if:
1361                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1362                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1363                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1364                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1365                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1366                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1367                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1368                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1369                 // b) WP is closest WP for an item/spawnpoint/other entity
1370                 //    This has been done above by protecting these WPs.
1371         });
1372         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1373         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1374         {
1375                 for (int m = 0; m < 32; ++m)
1376                 {
1377                         entity w = waypoint_get_link(it, m);
1378                         if (!w)
1379                                 break;
1380                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1381                                 continue;
1382                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1383                                 continue;
1384                         for (int j = 0; j < 32; ++j)
1385                         {
1386                                 entity w2 = waypoint_get_link(w, j);
1387                                 if (!w2)
1388                                         break;
1389                                 if (it == w2)
1390                                         continue;
1391                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1392                                         continue;
1393                                 // If we got here, it != w2 exist with it -> w
1394                                 // and w -> w2. That means the waypoint is not
1395                                 // a dead end.
1396                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1397                                 for (int k = 0; k < 32; ++k)
1398                                 {
1399                                         if (waypoint_get_link(it, k) == w2)
1400                                                 continue;
1401                                         // IF WE GET HERE, w is proven useful
1402                                         // to get from it to w2!
1403                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1404                                         goto next;
1405                                 }
1406                         }
1407 LABEL(next)
1408                 }
1409         });
1410         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1411         //     they are needed to complete routes while autowaypointing.
1412
1413         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1414         {
1415                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1416                 te_explosion(it.origin);
1417                 waypoint_remove(it);
1418                 break;
1419         });
1420
1421         IL_EACH(g_waypoints, true,
1422         {
1423                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1424         });
1425 }
1426
1427 void botframe_autowaypoints()
1428 {
1429         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1430                 // going back is broken, so only fix waypoints to walk TO the player
1431                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1432                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1433                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1434         ));
1435
1436         if (autocvar_g_waypointeditor_auto >= 2) {
1437                 botframe_deleteuselesswaypoints();
1438         }
1439 }
1440