qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/impulses/all.qh>
   5 #include <common/items/_mod.qh>
   6 #include <common/mapobjects/func/ladder.qh>
   7 #include <common/mapobjects/teleporters.qh>
   8 #include <common/mapobjects/trigger/hurt.qh>
   9 #include <common/mapobjects/trigger/jumppads.qh>
  10 #include <common/net_linked.qh>
  11 #include <common/physics/player.qh>
  12 #include <common/state.qh>
  13 #include <common/stats.qh>
  14 #include <common/weapons/_all.qh>
  15 #include <common/wepent.qh>
  16 #include <lib/warpzone/common.qh>
  17 #include <server/bot/api.qh>
  18 #include <server/bot/default/aim.qh>
  19 #include <server/bot/default/bot.qh>
  20 #include <server/bot/default/cvars.qh>
  21 #include <server/bot/default/havocbot/roles.qh>
  22 #include <server/bot/default/navigation.qh>
  23 #include <server/bot/default/scripting.qh>
  24 #include <server/bot/default/waypoints.qh>
  25 #include <server/client.qh>
  26 #include <server/damage.qh>
  27 #include <server/items/items.qh>
  28 #include <server/mutators/_mod.qh>
  29 #include <server/weapons/selection.qh>
  30 #include <server/weapons/weaponsystem.qh>
  31 #include <server/world.qh>
  32
  33 void havocbot_ai(entity this)
  34 {
  35         if(this.draggedby)
  36                 return;
  37
  38         this.bot_aimdir_executed = false;
  39         // lock aim if teleported or passing through a warpzone
  40         if (this.lastteleporttime && !this.jumppadcount)
  41                 this.bot_aimdir_executed = true;
  42
  43         if(bot_execute_commands(this))
  44                 return;
  45
  46         if (bot_strategytoken == this && !bot_strategytoken_taken)
  47         {
  48                 if(this.havocbot_blockhead)
  49                 {
  50                         this.havocbot_blockhead = false;
  51                 }
  52                 else
  53                 {
  54                         if (!this.jumppadcount && !STAT(FROZEN, this)
  55                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP) && !IS_ONGROUND(this)))
  56                         {
  57                                 // find a new goal
  58                                 this.havocbot_role(this); // little too far down the rabbit hole
  59                         }
  60                 }
  61
  62                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  63                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  64                 if(!this.goalcurrent)
  65                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  66                 {
  67                         // Look for the closest waypoint out of water
  68                         entity newgoal = NULL;
  69                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  70                         {
  71                                 if(it.origin.z < this.origin.z)
  72                                         continue;
  73
  74                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  75                                         continue;
  76
  77                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  78                                         continue;
  79
  80                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  81
  82                                 if(trace_fraction < 1)
  83                                         continue;
  84
  85                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  86                                         newgoal = it;
  87                         });
  88
  89                         if(newgoal)
  90                         {
  91                         //      te_wizspike(newgoal.origin);
  92                                 navigation_pushroute(this, newgoal);
  93                         }
  94                 }
  95
  96                 // token has been used this frame
  97                 bot_strategytoken_taken = true;
  98         }
  99
 100         if (this.goalcurrent && wasfreed(this.goalcurrent))
 101         {
 102                 navigation_clearroute(this);
 103                 navigation_goalrating_timeout_force(this);
 104                 return;
 105         }
 106
 107         if(IS_DEAD(this) || STAT(FROZEN, this))
 108         {
 109                 if (this.goalcurrent)
 110                         navigation_clearroute(this);
 111                 this.enemy = NULL;
 112                 this.bot_aimtarg = NULL;
 113                 return;
 114         }
 115
 116         havocbot_chooseenemy(this);
 117
 118         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 119         {
 120                 .entity weaponentity = weaponentities[slot];
 121                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 122                 if(this.(weaponentity).bot_chooseweapontime < time)
 123                 {
 124                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 125                         havocbot_chooseweapon(this, weaponentity);
 126                 }
 127         }
 128         havocbot_aim(this);
 129         lag_update(this);
 130
 131         if (this.bot_aimtarg)
 132         {
 133                 this.aistatus |= AI_STATUS_ATTACKING;
 134                 this.aistatus &= ~AI_STATUS_ROAMING;
 135
 136                 if(STAT(WEAPONS, this))
 137                 {
 138                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 139                         {
 140                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 141                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 142                         }
 143                         else
 144                         {
 145                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 146                                 {
 147                                         .entity weaponentity = weaponentities[slot];
 148                                         Weapon w = this.(weaponentity).m_weapon;
 149                                         if(w == WEP_Null && slot != 0)
 150                                                 continue;
 151                                         w.wr_aim(w, this, weaponentity);
 152                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 153                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 154                                 }
 155                         }
 156                 }
 157                 else
 158                 {
 159                         if(IS_PLAYER(this.bot_aimtarg))
 160                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 161                 }
 162         }
 163         else if (this.goalcurrent)
 164         {
 165                 this.aistatus |= AI_STATUS_ROAMING;
 166                 this.aistatus &= ~AI_STATUS_ATTACKING;
 167         }
 168
 169         havocbot_movetogoal(this);
 170         if (!this.bot_aimdir_executed && this.goalcurrent)
 171         {
 172                 // Heading
 173                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 174                 dir -= this.origin + this.view_ofs;
 175                 dir.z = 0;
 176                 bot_aimdir(this, dir, 0);
 177         }
 178
 179         // if the bot is not attacking, consider reloading weapons
 180         if (!(this.aistatus & AI_STATUS_ATTACKING))
 181         {
 182                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 183                 {
 184                         .entity weaponentity = weaponentities[slot];
 185
 186                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 187                                 continue;
 188
 189                         // we are currently holding a weapon that's not fully loaded, reload it
 190                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 191                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 192                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 193
 194                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 195                         // the code above executes next frame, starting the reloading then
 196                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 197                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 198                         {
 199                                 FOREACH(Weapons, it != WEP_Null, {
 200                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 201                                         {
 202                                                 this.(weaponentity).m_switchweapon = it;
 203                                                 break;
 204                                         }
 205                                 });
 206                         }
 207                 }
 208         }
 209 }
 210
 211 void havocbot_bunnyhop(entity this, vector dir)
 212 {
 213         bool can_run = false;
 214         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 215                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 216                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 217                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 218         {
 219                 vector vel_angles = vectoangles(this.velocity);
 220                 vector deviation = vel_angles - vectoangles(dir);
 221                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 222                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 223                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 224                 {
 225                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 226                         float vel = vlen(vec2(this.velocity));
 227
 228                         // with the current physics, jump distance grows linearly with the speed
 229                         float jump_distance = 52.661 + 0.606 * vel;
 230                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 231                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 232                                 can_run = true;
 233                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 234                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 235                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 236                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 237                         {
 238                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 239                                 vector ang = vectoangles(gco - this.origin);
 240                                 deviation = vectoangles(gno - gco) - vel_angles;
 241                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 242                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 243
 244                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 245                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 246                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 247                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 248                                 {
 249                                         can_run = true;
 250                                 }
 251                         }
 252                 }
 253         }
 254
 255         if (can_run)
 256         {
 257                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 258                 this.bot_jump_time = time;
 259                 this.aistatus |= AI_STATUS_RUNNING;
 260         }
 261         else
 262         {
 263                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 264                         this.aistatus &= ~AI_STATUS_RUNNING;
 265         }
 266 }
 267
 268 void havocbot_keyboard_movement(entity this, vector destorg)
 269 {
 270         if(time <= this.havocbot_keyboardtime)
 271                 return;
 272
 273         float sk = skill + this.bot_moveskill;
 274         this.havocbot_keyboardtime =
 275                 max(
 276                         this.havocbot_keyboardtime
 277                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 278                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 279                 , time);
 280         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 281
 282         float trigger = autocvar_bot_ai_keyboard_threshold;
 283
 284         // categorize forward movement
 285         // at skill < 1.5 only forward
 286         // at skill < 2.5 only individual directions
 287         // at skill < 4.5 only individual directions, and forward diagonals
 288         // at skill >= 4.5, all cases allowed
 289         if (keyboard.x > trigger)
 290         {
 291                 keyboard.x = 1;
 292                 if (sk < 2.5)
 293                         keyboard.y = 0;
 294         }
 295         else if (keyboard.x < -trigger && sk > 1.5)
 296         {
 297                 keyboard.x = -1;
 298                 if (sk < 4.5)
 299                         keyboard.y = 0;
 300         }
 301         else
 302         {
 303                 keyboard.x = 0;
 304                 if (sk < 1.5)
 305                         keyboard.y = 0;
 306         }
 307         if (sk < 4.5)
 308                 keyboard.z = 0;
 309
 310         if (keyboard.y > trigger)
 311                 keyboard.y = 1;
 312         else if (keyboard.y < -trigger)
 313                 keyboard.y = -1;
 314         else
 315                 keyboard.y = 0;
 316
 317         if (keyboard.z > trigger)
 318                 keyboard.z = 1;
 319         else if (keyboard.z < -trigger)
 320                 keyboard.z = -1;
 321         else
 322                 keyboard.z = 0;
 323
 324         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 325         if (keyboard == '0 0 0')
 326                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 327
 328         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 329         if (this.havocbot_ducktime > time)
 330                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 331
 332         keyboard = this.havocbot_keyboard;
 333         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 334         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 335         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 336 }
 337
 338 // return true when bot isn't getting closer to the current goal
 339 bool havocbot_checkgoaldistance(entity this, vector gco)
 340 {
 341         if (this.bot_stop_moving_timeout > time)
 342                 return false;
 343         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 344         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 345         float distance_time = this.goalcurrent_distance_time;
 346         if(distance_time < 0)
 347                 distance_time = -distance_time;
 348         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 349         {
 350                 if(!distance_time)
 351                         this.goalcurrent_distance_time = time;
 352                 else if (time - distance_time > 0.5)
 353                         return true;
 354         }
 355         else
 356         {
 357                 // reduce it a little bit so it works even with very small approaches to the goal
 358                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 359                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 360                 this.goalcurrent_distance_time = 0;
 361         }
 362         return false;
 363 }
 364
 365 entity havocbot_select_an_item_of_group(entity this, int gr)
 366 {
 367         entity selected = NULL;
 368         float selected_dist2 = 0;
 369         // select farthest item of this group from bot's position
 370         IL_EACH(g_items, it.item_group == gr && it.solid,
 371         {
 372                 float dist2 = vlen2(this.origin - it.origin);
 373                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 374                 {
 375                         selected = it;
 376                         selected_dist2 = vlen2(this.origin - selected.origin);
 377                 }
 378         });
 379
 380         if (!selected)
 381                 return NULL;
 382
 383         set_tracewalk_dest(selected, this.origin, false);
 384         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 385                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 386         {
 387                 return NULL;
 388         }
 389
 390         return selected;
 391 }
 392
 393 void havocbot_movetogoal(entity this)
 394 {
 395         vector diff;
 396         vector dir;
 397         vector flatdir;
 398         float dodge_enemy_factor = 1;
 399         float maxspeed;
 400         //float dist;
 401         vector dodge;
 402         //if (this.goalentity)
 403         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 404         CS(this).movement = '0 0 0';
 405         maxspeed = autocvar_sv_maxspeed;
 406
 407         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 408
 409         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 410         // Jetpack navigation
 411         if(this.navigation_jetpack_goal)
 412         if(this.goalcurrent==this.navigation_jetpack_goal)
 413         if(GetResource(this, RES_FUEL))
 414         {
 415                 if(autocvar_bot_debug_goalstack)
 416                 {
 417                         debuggoalstack(this);
 418                         te_wizspike(this.navigation_jetpack_point);
 419                 }
 420
 421                 // Take off
 422                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 423                 {
 424                         // Brake almost completely so it can get a good direction
 425                         if(vdist(this.velocity, >, 10))
 426                                 return;
 427                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 428                 }
 429
 430                 makevectors(this.v_angle.y * '0 1 0');
 431                 dir = normalize(this.navigation_jetpack_point - this.origin);
 432
 433                 // Landing
 434                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 435                 {
 436                         // Calculate brake distance in xy
 437                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 438                         float vel2 = vlen2(vec2(this.velocity));
 439                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 440                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 441                         if(d < db || d < 500)
 442                         {
 443                                 // Brake
 444                                 if (vel2 > (maxspeed * 0.3) ** 2)
 445                                 {
 446                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 447                                         return;
 448                                 }
 449                                 // Switch to normal mode
 450                                 this.navigation_jetpack_goal = NULL;
 451                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 452                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 453                                 return;
 454                         }
 455                 }
 456                 else if(checkpvs(this.origin,this.goalcurrent))
 457                 {
 458                         // If I can see the goal switch to landing code
 459                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 460                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 461                         return;
 462                 }
 463
 464                 // Flying
 465                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 466                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 467                 {
 468                         CS(this).movement_x = dir * v_forward * maxspeed;
 469                         CS(this).movement_y = dir * v_right * maxspeed;
 470                 }
 471                 return;
 472         }
 473
 474         // Handling of jump pads
 475         if(this.jumppadcount)
 476         {
 477                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 478                 {
 479                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 480                         if(navigation_poptouchedgoals(this))
 481                                 return;
 482                 }
 483                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 484                 {
 485                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 486                         // but with some randomness so it can try out different paths
 487                         if(!this.goalcurrent)
 488                         {
 489                                 entity newgoal = NULL;
 490                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 491                                 {
 492                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 493                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 494                                                 continue;
 495
 496                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 497
 498                                         if(trace_fraction < 1)
 499                                                 continue;
 500
 501                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 502                                                 newgoal = it;
 503                                 });
 504
 505                                 if(newgoal)
 506                                 {
 507                                         this.ignoregoal = this.goalcurrent;
 508                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 509                                         navigation_clearroute(this);
 510                                         navigation_routetogoal(this, newgoal, this.origin);
 511                                         if(autocvar_bot_debug_goalstack)
 512                                                 debuggoalstack(this);
 513                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 514                                 }
 515                         }
 516                         else //if (this.goalcurrent)
 517                         {
 518                                 if (this.goalcurrent.bot_pickup)
 519                                 {
 520                                         entity jumppad_wp = this.goalcurrent_prev;
 521                                         navigation_poptouchedgoals(this);
 522                                         if(!this.goalcurrent && jumppad_wp.wp00)
 523                                         {
 524                                                 // head to the jumppad destination once bot reaches the goal item
 525                                                 navigation_pushroute(this, jumppad_wp.wp00);
 526                                         }
 527                                 }
 528                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 529                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 530                                 {
 531                                         if (this.velocity.z < 0)
 532                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 533                                 }
 534                                 else if(havocbot_checkgoaldistance(this, gco))
 535                                 {
 536                                         navigation_clearroute(this);
 537                                         navigation_goalrating_timeout_force(this);
 538                                 }
 539                                 else
 540                                         return;
 541                         }
 542                 }
 543                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 544                 {
 545                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 546                         {
 547                                 vector velxy = this.velocity; velxy_z = 0;
 548                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 549                                 {
 550                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 551                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 552                                 }
 553                                 return;
 554                         }
 555
 556                         // Don't chase players while using a jump pad
 557                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 558                                 return;
 559                 }
 560         }
 561         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 562                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 563
 564         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 565         if (skill > 6 && !(IS_ONGROUND(this)))
 566         {
 567                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 568                         * ((STAT(STRENGTH_FINISHED, this) > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 569                         * ((STAT(INVINCIBLE_FINISHED, this) > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 570
 571                 // save some CPU cycles by checking trigger_hurt after checking
 572                 // that something can be done to evade it (cheaper checks)
 573                 int action_for_trigger_hurt = 0;
 574                 if (this.items & IT_JETPACK)
 575                         action_for_trigger_hurt = 1;
 576                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 577                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 578                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 579                 {
 580                         action_for_trigger_hurt = 2;
 581                 }
 582                 else if (!this.goalcurrent)
 583                         action_for_trigger_hurt = 3;
 584
 585                 if (action_for_trigger_hurt)
 586                 {
 587                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 588                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 589                                 action_for_trigger_hurt = 0;
 590                 }
 591
 592                 if(action_for_trigger_hurt == 1) // jetpack
 593                 {
 594                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 595                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 596                         {
 597                                 if(this.velocity.z<0)
 598                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 599                         }
 600                         else
 601                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 602
 603                         // If there is no goal try to move forward
 604
 605                         if(this.goalcurrent==NULL)
 606                                 dir = v_forward;
 607                         else
 608                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 609
 610                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 611                         float xyspeed = xyvelocity * dir;
 612
 613                         if(xyspeed < (maxspeed / 2))
 614                         {
 615                                 makevectors(this.v_angle.y * '0 1 0');
 616                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 617                                 if(trace_fraction==1)
 618                                 {
 619                                         CS(this).movement_x = dir * v_forward * maxspeed;
 620                                         CS(this).movement_y = dir * v_right * maxspeed;
 621                                         if (skill < 10)
 622                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 623                                 }
 624                         }
 625
 626                         this.havocbot_blockhead = true;
 627
 628                         return;
 629                 }
 630                 else if(action_for_trigger_hurt == 2) // rocketjump
 631                 {
 632                         if(this.velocity.z < 0)
 633                         {
 634                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 635                                 {
 636                                         .entity weaponentity = weaponentities[slot];
 637
 638                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 639                                                 continue;
 640
 641                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 642                                         {
 643                                                 CS(this).movement_x = maxspeed;
 644
 645                                                 if(this.rocketjumptime)
 646                                                 {
 647                                                         if(time > this.rocketjumptime)
 648                                                         {
 649                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 650                                                                 this.rocketjumptime = 0;
 651                                                         }
 652                                                         return;
 653                                                 }
 654
 655                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 656                                                 this.v_angle_x = 90;
 657                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 658                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 659                                                 return;
 660                                         }
 661                                 }
 662                         }
 663                 }
 664                 else if(action_for_trigger_hurt == 3) // no goal
 665                 {
 666                         // If there is no goal try to move forward
 667                         CS(this).movement_x = maxspeed;
 668                 }
 669         }
 670
 671         // If we are under water with no goals, swim up
 672         if(this.waterlevel && !this.goalcurrent)
 673         {
 674                 dir = '0 0 0';
 675                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 676                         dir.z = 1;
 677                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 678                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 679                 makevectors(this.v_angle.y * '0 1 0');
 680                 vector v = dir * maxspeed;
 681                 CS(this).movement.x = v * v_forward;
 682                 CS(this).movement.y = v * v_right;
 683                 CS(this).movement.z = v * v_up;
 684         }
 685
 686         // if there is nowhere to go, exit
 687         if (this.goalcurrent == NULL)
 688                 return;
 689
 690
 691         bool locked_goal = false;
 692         if((this.goalentity && wasfreed(this.goalentity))
 693                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 694         {
 695                 navigation_clearroute(this);
 696                 navigation_goalrating_timeout_force(this);
 697                 return;
 698         }
 699         else if(this.goalentity.tag_entity)
 700         {
 701                 navigation_goalrating_timeout_expire(this, 2);
 702         }
 703         else if(this.goalentity.bot_pickup)
 704         {
 705                 if(this.goalentity.bot_pickup_respawning)
 706                 {
 707                         if(this.goalentity.solid) // item respawned
 708                                 this.goalentity.bot_pickup_respawning = false;
 709                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 710                         {
 711                                 if(checkpvs(this.origin, this.goalentity))
 712                                 {
 713                                         this.goalentity.bot_pickup_respawning = false;
 714                                         navigation_goalrating_timeout_expire(this, random());
 715                                 }
 716                                 locked_goal = true; // wait for item to respawn
 717                         }
 718                         else if(this.goalentity == this.goalcurrent)
 719                                 locked_goal = true; // wait for item to respawn
 720                 }
 721                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 722                 {
 723                         if(checkpvs(this.origin, this.goalentity))
 724                         {
 725                                 navigation_goalrating_timeout_expire(this, random());
 726                         }
 727                 }
 728         }
 729         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 730                 locked_goal = true;
 731
 732         if (navigation_shortenpath(this))
 733         {
 734                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 735                         && navigation_goalrating_timeout_can_be_anticipated(this))
 736                 {
 737                         navigation_goalrating_timeout_force(this);
 738                 }
 739         }
 740
 741         bool goalcurrent_can_be_removed = false;
 742         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 743         {
 744                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 745                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 746                 {
 747                         goalcurrent_can_be_removed = true;
 748                         // don't remove if not visible
 749                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 750                         {
 751                                 if (IS_DEAD(this.goalcurrent))
 752                                 {
 753                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 754                                         {
 755                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 756                                                 {
 757                                                         navigation_clearroute(this);
 758                                                         navigation_pushroute(this, it);
 759                                                         // loot can't be immediately rated since it isn't on ground yet
 760                                                         // it will be rated after a second when on ground, meanwhile head to it
 761                                                         navigation_goalrating_timeout_expire(this, 1);
 762                                                         return;
 763                                                 }
 764                                         });
 765                                 }
 766                                 if (!Item_IsLoot(this.goalcurrent))
 767                                 {
 768                                         navigation_goalrating_timeout_force(this);
 769                                         return;
 770                                 }
 771                         }
 772                 }
 773                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 774                 {
 775                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 776                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 777                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 778                         {
 779                                 navigation_goalrating_timeout_force(this);
 780                                 return;
 781                         }
 782                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 783                 }
 784         }
 785
 786         if(!locked_goal)
 787         {
 788                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 789                 // in this case path finding can start directly from a waypoint instead of
 790                 // looking for all the reachable waypoints up to a certain distance
 791                 if (navigation_poptouchedgoals(this))
 792                 {
 793                         if (this.goalcurrent)
 794                         {
 795                                 if (goalcurrent_can_be_removed)
 796                                 {
 797                                         // remove even if not visible
 798                                         navigation_goalrating_timeout_force(this);
 799                                         return;
 800                                 }
 801                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 802                                         navigation_goalrating_timeout_force(this);
 803                         }
 804                         else
 805                         {
 806                                 entity old_goal = this.goalcurrent_prev;
 807                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 808                                 {
 809                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 810                                         // item of the group by telling the bot to head directly to the farthest item.
 811                                         // Next time we let the bot select a goal as usual which can be another item
 812                                         // of this group (the closest one) and so on
 813                                         this.item_group = old_goal.item_group;
 814                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 815                                         if (new_goal)
 816                                                 navigation_pushroute(this, new_goal);
 817                                 }
 818                         }
 819                 }
 820         }
 821
 822         // if ran out of goals try to use an alternative goal or get a new strategy asap
 823         if(this.goalcurrent == NULL)
 824         {
 825                 navigation_goalrating_timeout_force(this);
 826                 return;
 827         }
 828
 829
 830         if(autocvar_bot_debug_goalstack)
 831                 debuggoalstack(this);
 832
 833         bool bunnyhop_forbidden = false;
 834         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 835         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 836         {
 837                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 838                 destorg = this.goalcurrent.origin;
 839         }
 840         else if (this.goalcurrent.wpisbox)
 841         {
 842                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 843                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 844                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 845                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 846                 {
 847                         bunnyhop_forbidden = true;
 848                         destorg = this.goalcurrent.origin;
 849                         if(destorg.z > this.origin.z)
 850                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 851                 }
 852         }
 853
 854         diff = destorg - this.origin;
 855
 856         if (time < this.bot_stop_moving_timeout
 857                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 858         {
 859                 // stop if the locked goal has been reached
 860                 destorg = this.origin;
 861                 diff = dir = '0 0 0';
 862         }
 863         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 864         {
 865                 if (vdist(diff, <, 80))
 866                 {
 867                         // stop if too close to target player (even if frozen)
 868                         destorg = this.origin;
 869                         diff = dir = '0 0 0';
 870                 }
 871                 else
 872                 {
 873                         // move destorg out of target players, otherwise bot will consider them
 874                         // an obstacle that needs to be jumped (especially if frozen)
 875                         dir = normalize(diff);
 876                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 877                         diff = destorg - this.origin;
 878                 }
 879         }
 880         else
 881                 dir = normalize(diff);
 882         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 883
 884         bool danger_detected = false;
 885         vector do_break = '0 0 0';
 886
 887         //if (this.bot_dodgevector_time < time)
 888         {
 889                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 890                 //this.bot_dodgevector_jumpbutton = 1;
 891
 892                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 893                 makevectors(this.v_angle.y * '0 1 0');
 894                 if (this.waterlevel > WATERLEVEL_WETFEET)
 895                 {
 896                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 897                         {
 898                                 if(!this.goalcurrent)
 899                                         this.aistatus |= AI_STATUS_OUT_WATER;
 900                                 else if(destorg.z > this.origin.z)
 901                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 902                         }
 903                         else
 904                         {
 905                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 906                                         (this.aistatus & AI_STATUS_OUT_WATER))
 907                                 {
 908                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 909                                         dir = flatdir;
 910                                 }
 911                                 else
 912                                 {
 913                                         if (destorg.z > this.origin.z)
 914                                                 dir = flatdir;
 915                                 }
 916                         }
 917                 }
 918                 else
 919                 {
 920                         float s;
 921                         vector offset;
 922                         if(this.aistatus & AI_STATUS_OUT_WATER)
 923                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 924
 925                         // jump if going toward an obstacle that doesn't look like stairs we
 926                         // can walk up directly
 927                         vector deviation = '0 0 0';
 928                         float current_speed = vlen(vec2(this.velocity));
 929                         if (current_speed < maxspeed * 0.2)
 930                                 current_speed = maxspeed * 0.2;
 931                         else
 932                         {
 933                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 934                                 while (deviation.y < -180) deviation.y += 360;
 935                                 while (deviation.y > 180) deviation.y -= 360;
 936                         }
 937                         float turning = false;
 938                         vector flat_diff = vec2(diff);
 939                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 940                         vector actual_destorg = this.origin + offset;
 941                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 942                         {
 943                                 if (time > this.bot_stop_moving_timeout
 944                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 945                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 946                                 {
 947                                         this.bot_stop_moving_timeout = time + 0.1;
 948                                 }
 949                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 950                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 951                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 952                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 953                                 )
 954                                 {
 955                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 956                                         this.bot_jump_time = time;
 957                                 }
 958                         }
 959                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 960                         {
 961                                 if (vlen2(flat_diff) < vlen2(offset))
 962                                 {
 963                                         if ((this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP) && this.goalstack01)
 964                                         {
 965                                                 // oblique warpzones need a jump otherwise bots gets stuck
 966                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 967                                         }
 968                                         else
 969                                         {
 970                                                 actual_destorg.x = destorg.x;
 971                                                 actual_destorg.y = destorg.y;
 972                                         }
 973                                 }
 974                         }
 975                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 976                         {
 977                                 actual_destorg.x = destorg.x;
 978                                 actual_destorg.y = destorg.y;
 979                         }
 980                         else if (vlen2(flat_diff) < vlen2(offset))
 981                         {
 982                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 983                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 984                                 float dist = vlen(vec2(this.origin + offset - destorg));
 985                                 // if current and next goal are close to each other make sure
 986                                 // actual_destorg isn't set beyond next_goal_org
 987                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 988                                         actual_destorg = next_goal_org;
 989                                 else
 990                                         actual_destorg = vec2(destorg) + dist * next_dir;
 991                                 actual_destorg.z = this.origin.z;
 992                                 turning = true;
 993                         }
 994
 995                         LABEL(jumpobstacle_check);
 996                         dir = flatdir = normalize(actual_destorg - this.origin);
 997
 998                         bool jump_forbidden = false;
 999                         if (!turning && fabs(deviation.y) > 50)
1000                                 jump_forbidden = true;
1001                         else if (IS_DUCKED(this))
1002                         {
1003                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1004                                 if (trace_startsolid)
1005                                         jump_forbidden = true;
1006                         }
1007
1008                         if (!jump_forbidden)
1009                         {
1010                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1011                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1012                                 {
1013                                         s = trace_fraction;
1014                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1015                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1016                                         {
1017                                                 // found an obstacle
1018                                                 if (turning && fabs(deviation.y) > 5)
1019                                                 {
1020                                                         // check if the obstacle is still there without turning
1021                                                         actual_destorg = destorg;
1022                                                         turning = false;
1023                                                         this.bot_tracewalk_time = time + 0.25;
1024                                                         goto jumpobstacle_check;
1025                                                 }
1026                                                 s = trace_fraction;
1027                                                 // don't artificially reduce max jump height in real-time
1028                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1029                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1030                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1031                                                 if (trace_fraction > s)
1032                                                 {
1033                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1034                                                         this.bot_jump_time = time;
1035                                                 }
1036                                                 else
1037                                                 {
1038                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1039                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1040                                                         if (trace_fraction > s)
1041                                                         {
1042                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1043                                                                 this.bot_jump_time = time;
1044                                                         }
1045                                                 }
1046                                         }
1047                                 }
1048                         }
1049
1050                         // if bot for some reason doesn't get close to the current goal find another one
1051                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1052                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1053                         if(havocbot_checkgoaldistance(this, destorg))
1054                         {
1055                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1056                                 {
1057                                         navigation_clearroute(this);
1058                                         navigation_goalrating_timeout_force(this);
1059                                         return;
1060                                 }
1061
1062                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1063                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1064                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1065                                 {
1066                                         navigation_clearroute(this);
1067                                         navigation_goalrating_timeout_force(this);
1068                                         return;
1069                                 }
1070
1071                                 // give bot only another chance to prevent bot getting stuck
1072                                 // in case it thinks it can walk but actually can't
1073                                 this.goalcurrent_distance_z = FLOAT_MAX;
1074                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1075                                 this.goalcurrent_distance_time = -time; // mark second try
1076                         }
1077
1078                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1079                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1080                         {
1081                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1082                         }
1083
1084                         // Check for water/slime/lava and dangerous edges
1085                         // (only when the bot is on the ground or jumping intentionally)
1086
1087                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1088                         vector dst_ahead = this.origin + this.view_ofs + offset;
1089                         vector dst_down = dst_ahead - '0 0 3000';
1090                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1091
1092                         bool unreachable = false;
1093                         s = CONTENT_SOLID;
1094                         if (trace_fraction == 1 && !this.jumppadcount
1095                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1096                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1097                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1098                         {
1099                                 // Look downwards
1100                                 traceline(dst_ahead , dst_down, true, NULL);
1101                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1102                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1103                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1104                                 {
1105                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1106                                                 danger_detected = true;
1107                                         else if (trace_endpos.z < min(this.origin.z + this.mins.z, this.goalcurrent.origin.z) - 100)
1108                                                 danger_detected = true;
1109                                         else
1110                                         {
1111                                                 s = pointcontents(trace_endpos + '0 0 1');
1112                                                 if (s != CONTENT_SOLID)
1113                                                 {
1114                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1115                                                                 danger_detected = true;
1116                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1117                                                         {
1118                                                                 // the traceline check isn't enough but is good as optimization,
1119                                                                 // when not true (most of the time) this tracebox call is avoided
1120                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1121                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1122                                                                 {
1123                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1124                                                                         {
1125                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1126                                                                                 unreachable = true;
1127                                                                         }
1128                                                                         else
1129                                                                                 danger_detected = true;
1130                                                                 }
1131                                                         }
1132                                                 }
1133                                         }
1134                                 }
1135                         }
1136
1137                         dir = flatdir;
1138                         makevectors(this.v_angle.y * '0 1 0');
1139
1140                         if (danger_detected || (s == CONTENT_WATER))
1141                         {
1142                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1143                                 if(IS_PLAYER(this.goalcurrent))
1144                                         unreachable = true;
1145                         }
1146
1147                         // slow down if bot is in the air and goal is under it
1148                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1149                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1150                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1151                         {
1152                                 // tracebox wouldn't work when bot is still on the ledge
1153                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1154                                 if (this.origin.z - trace_endpos.z > 120)
1155                                         do_break = normalize(this.velocity) * -1;
1156                         }
1157
1158                         if(unreachable)
1159                         {
1160                                 navigation_clearroute(this);
1161                                 navigation_goalrating_timeout_force(this);
1162                                 this.ignoregoal = this.goalcurrent;
1163                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1164                         }
1165                 }
1166
1167                 dodge = havocbot_dodge(this);
1168                 if (dodge)
1169                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1170                 if (this.enemy)
1171                 {
1172                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1173                         if (IS_PLAYER(trace_ent))
1174                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1175                 }
1176         //      this.bot_dodgevector = dir;
1177         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1178         }
1179
1180         float ladder_zdir = 0;
1181         if(this.ladder_entity)
1182         {
1183                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1184                 {
1185                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1186                                 ladder_zdir = 1;
1187                 }
1188                 else
1189                 {
1190                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1191                                 ladder_zdir = -1;
1192                 }
1193                 if (ladder_zdir)
1194                 {
1195                         if (vdist(vec2(diff), <, 40))
1196                                 dir.z = ladder_zdir * 4;
1197                         else
1198                                 dir.z = ladder_zdir * 2;
1199                         dir = normalize(dir);
1200                 }
1201         }
1202
1203         if (this.goalcurrent.wpisbox
1204                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1205         {
1206                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1207                 // head to teleport origin
1208                 dir = (this.goalcurrent.origin - this.origin);
1209                 dir.z = 0;
1210                 dir = normalize(dir);
1211         }
1212
1213         // already executed when bot targets an enemy
1214         if (!this.bot_aimdir_executed)
1215         {
1216                 if (time < this.bot_stop_moving_timeout)
1217                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1218                 else
1219                         bot_aimdir(this, dir, 0);
1220         }
1221
1222         vector evadedanger = '0 0 0';
1223         if (!ladder_zdir)
1224         {
1225                 dir *= dodge_enemy_factor;
1226                 if (danger_detected && vdist(this.velocity, >, maxspeed * 0.8) && this.goalcurrent_prev
1227                         && this.goalcurrent.classname == "waypoint")
1228                 {
1229                         vector p = this.origin + this.velocity * 0.2;
1230                         vector evadedanger = point_line_vec(p, vec2(this.goalcurrent_prev.origin) + eZ * p.z,
1231                                 vec2(destorg - this.goalcurrent_prev.origin));
1232                         if (vdist(evadedanger, >, 20))
1233                         {
1234                                 if (vdist(evadedanger, >, 40))
1235                                         do_break = normalize(this.velocity) * -1;
1236                                 evadedanger = normalize(evadedanger);
1237                                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1238                         }
1239                         else
1240                                 evadedanger = '0 0 0';
1241                 }
1242                 dir = normalize(dir + dodge + do_break + evadedanger);
1243         }
1244
1245         makevectors(this.v_angle);
1246         //dir = this.bot_dodgevector;
1247         //if (this.bot_dodgevector_jumpbutton)
1248         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1249         CS(this).movement_x = dir * v_forward * maxspeed;
1250         CS(this).movement_y = dir * v_right * maxspeed;
1251         CS(this).movement_z = dir * v_up * maxspeed;
1252
1253         // Emulate keyboard interface
1254         if (skill < 10)
1255                 havocbot_keyboard_movement(this, destorg);
1256
1257         // Bunnyhop!
1258         if (!bunnyhop_forbidden && !evadedanger && !do_break && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1259                 havocbot_bunnyhop(this, dir);
1260
1261         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1262                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1263         if (dodge)
1264         {
1265                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1266                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1267                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1268                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1269         }
1270 }
1271
1272 entity havocbot_gettarget(entity this, bool secondary)
1273 {
1274         entity best = NULL;
1275         vector eye = CENTER_OR_VIEWOFS(this);
1276         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1277         {
1278                 vector v = CENTER_OR_VIEWOFS(it);
1279                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1280                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1281                 if(bot_shouldattack(this, it))
1282                 {
1283                         traceline(eye, v, true, this);
1284                         if (trace_ent == it || trace_fraction >= 1)
1285                                 best = it;
1286                 }
1287         });
1288
1289         return best;
1290 }
1291
1292 void havocbot_chooseenemy(entity this)
1293 {
1294         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1295         {
1296                 this.enemy = NULL;
1297                 return;
1298         }
1299
1300         if (this.enemy)
1301         {
1302                 if (!bot_shouldattack(this, this.enemy))
1303                 {
1304                         // enemy died or something, find a new target
1305                         this.enemy = NULL;
1306                         this.havocbot_chooseenemy_finished = time;
1307                 }
1308                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1309                 {
1310                         // tracking last chosen enemy
1311                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1312                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1313                         if (trace_ent == this.enemy || trace_fraction == 1)
1314                         if (vdist(targ_pos - this.origin, <, 1000))
1315                         {
1316                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1317                                 this.havocbot_chooseenemy_finished = time + 0.5;
1318                                 return;
1319                         }
1320
1321                         // stop preferring this enemy
1322                         this.havocbot_stickenemy_time = 0;
1323                 }
1324         }
1325         if (time < this.havocbot_chooseenemy_finished)
1326                 return;
1327         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1328         vector eye = this.origin + this.view_ofs;
1329         entity best = NULL;
1330         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1331
1332         // Backup hit flags
1333         int hf = this.dphitcontentsmask;
1334
1335         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1336
1337         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1338
1339         bool scan_transparent = false;
1340         bool scan_secondary_targets = false;
1341         bool have_secondary_targets = false;
1342         while(true)
1343         {
1344                 scan_secondary_targets = false;
1345 LABEL(scan_targets)
1346                 IL_EACH(g_bot_targets, it.bot_attack,
1347                 {
1348                         if(!scan_secondary_targets)
1349                         {
1350                                 if(it.classname == "misc_breakablemodel")
1351                                 {
1352                                         have_secondary_targets = true;
1353                                         continue;
1354                                 }
1355                         }
1356                         else if(it.classname != "misc_breakablemodel")
1357                                 continue;
1358
1359                         vector v = (it.absmin + it.absmax) * 0.5;
1360                         float rating = vlen2(v - eye);
1361                         if (rating < bestrating && bot_shouldattack(this, it))
1362                         {
1363                                 traceline(eye, v, true, this);
1364                                 if (trace_ent == it || trace_fraction >= 1)
1365                                 {
1366                                         best = it;
1367                                         bestrating = rating;
1368                                 }
1369                         }
1370                 });
1371
1372                 if(!best && have_secondary_targets && !scan_secondary_targets)
1373                 {
1374                         scan_secondary_targets = true;
1375                         // restart the loop
1376                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1377                         goto scan_targets;
1378                 }
1379
1380                 // I want to do a second scan if no enemy was found or I don't have weapons
1381                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1382                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1383                         break;
1384                 if(scan_transparent)
1385                         break;
1386
1387                 // Set flags to see through transparent objects
1388                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1389
1390                 scan_transparent = true;
1391         }
1392
1393         // Restore hit flags
1394         this.dphitcontentsmask = hf;
1395
1396         this.enemy = best;
1397         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1398         if(best && best.classname == "misc_breakablemodel")
1399                 this.havocbot_stickenemy_time = 0;
1400 }
1401
1402 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1403 {
1404         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1405         // so skip this for them, or they'll never get to reload their weapons at all.
1406         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1407         if(skill < 5)
1408                 return false;
1409
1410         // if this weapon is scheduled for reloading, don't switch to it during combat
1411         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1412         {
1413                 FOREACH(Weapons, it != WEP_Null, {
1414                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1415                                 return true; // other weapon available
1416                 });
1417         }
1418
1419         return false;
1420 }
1421
1422 void havocbot_chooseweapon(entity this, .entity weaponentity)
1423 {
1424         int i;
1425
1426         // ;)
1427         if(g_weaponarena_weapons == WEPSET(TUBA))
1428         {
1429                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1430                 return;
1431         }
1432
1433         // TODO: clean this up by moving it to weapon code
1434         if(this.enemy==NULL)
1435         {
1436                 // If no weapon was chosen get the first available weapon
1437                 if(this.(weaponentity).m_weapon==WEP_Null)
1438                 FOREACH(Weapons, it != WEP_Null, {
1439                         if(client_hasweapon(this, it, weaponentity, true, false))
1440                         {
1441                                 this.(weaponentity).m_switchweapon = it;
1442                                 return;
1443                         }
1444                 });
1445                 return;
1446         }
1447
1448         // Do not change weapon during the next second after a combo
1449         float f = time - this.lastcombotime;
1450         if(f < 1)
1451                 return;
1452
1453         float w;
1454         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1455
1456         // Should it do a weapon combo?
1457         float af, ct, combo_time, combo;
1458
1459         af = ATTACK_FINISHED(this, weaponentity);
1460         ct = autocvar_bot_ai_weapon_combo_threshold;
1461
1462         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1463         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1464         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1465
1466         combo = false;
1467
1468         if(autocvar_bot_ai_weapon_combo)
1469         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1470         if(af > combo_time)
1471         {
1472                 combo = true;
1473                 this.lastcombotime = time;
1474         }
1475
1476         distance *= (2 ** this.bot_rangepreference);
1477
1478         // Custom weapon list based on distance to the enemy
1479         if(bot_custom_weapon){
1480
1481                 // Choose weapons for far distance
1482                 if ( distance > bot_distance_far ) {
1483                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_far[i] != -1 ; ++i){
1484                                 w = bot_weapons_far[i];
1485                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1486                                 {
1487                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1488                                                 continue;
1489                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1490                                         return;
1491                                 }
1492                         }
1493                 }
1494
1495                 // Choose weapons for mid distance
1496                 if ( distance > bot_distance_close) {
1497                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_mid[i] != -1 ; ++i){
1498                                 w = bot_weapons_mid[i];
1499                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1500                                 {
1501                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1502                                                 continue;
1503                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1504                                         return;
1505                                 }
1506                         }
1507                 }
1508
1509                 // Choose weapons for close distance
1510                 for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_close[i] != -1 ; ++i){
1511                         w = bot_weapons_close[i];
1512                         if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1513                         {
1514                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1515                                         continue;
1516                                 this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1517                                 return;
1518                         }
1519                 }
1520         }
1521 }
1522
1523 void havocbot_aim(entity this)
1524 {
1525         if (time < this.nextaim)
1526                 return;
1527         this.nextaim = time + 0.1;
1528         vector myvel = this.velocity;
1529         if (!this.waterlevel)
1530                 myvel.z = 0;
1531         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1532         else if (this.enemy)
1533         {
1534                 vector enemyvel = this.enemy.velocity;
1535                 if (!this.enemy.waterlevel)
1536                         enemyvel.z = 0;
1537                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1538         }
1539         else
1540                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1541 }
1542
1543 bool havocbot_moveto_refresh_route(entity this)
1544 {
1545         // Refresh path to goal if necessary
1546         entity wp;
1547         wp = this.havocbot_personal_waypoint;
1548         navigation_goalrating_start(this);
1549         navigation_routerating(this, wp, 10000, 10000);
1550         navigation_goalrating_end(this);
1551         return (this.goalentity != NULL);
1552 }
1553
1554 float havocbot_moveto(entity this, vector pos)
1555 {
1556         entity wp;
1557
1558         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1559         {
1560                 // Step 4: Move to waypoint
1561                 if(this.havocbot_personal_waypoint==NULL)
1562                 {
1563                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1564                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1565                         return CMD_STATUS_ERROR;
1566                 }
1567
1568                 if (!bot_strategytoken_taken)
1569                 if(this.havocbot_personal_waypoint_searchtime<time)
1570                 {
1571                         bot_strategytoken_taken = true;
1572                         if(havocbot_moveto_refresh_route(this))
1573                         {
1574                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1575                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1576                                 this.havocbot_personal_waypoint_failcounter = 0;
1577                         }
1578                         else
1579                         {
1580                                 this.havocbot_personal_waypoint_failcounter += 1;
1581                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1582                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1583                                 {
1584                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1585                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1586                                         delete(this.havocbot_personal_waypoint);
1587                                         return CMD_STATUS_ERROR;
1588                                 }
1589                                 else
1590                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1591                         }
1592                 }
1593
1594                 if(autocvar_bot_debug_goalstack)
1595                         debuggoalstack(this);
1596
1597
1598                 // Go!
1599                 havocbot_movetogoal(this);
1600
1601                 if (!this.bot_aimdir_executed && this.goalcurrent)
1602                 {
1603                         // Heading
1604                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1605                         dir -= this.origin + this.view_ofs;
1606                         dir.z = 0;
1607                         bot_aimdir(this, dir, 0);
1608                 }
1609
1610                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1611                 {
1612                         // Step 5: Waypoint reached
1613                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1614                         waypoint_remove(this.havocbot_personal_waypoint);
1615                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1616                         return CMD_STATUS_FINISHED;
1617                 }
1618
1619                 return CMD_STATUS_EXECUTING;
1620         }
1621
1622         // Step 2: Linking waypoint
1623         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1624         {
1625                 // Wait until it is linked
1626                 if(!this.havocbot_personal_waypoint.wplinked)
1627                 {
1628                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1629                         return CMD_STATUS_EXECUTING;
1630                 }
1631
1632                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1633                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1634                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1635
1636                 // Step 3: Route to waypoint
1637                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1638
1639                 return CMD_STATUS_EXECUTING;
1640         }
1641
1642         // Step 1: Spawning waypoint
1643         wp = waypoint_spawnpersonal(this, pos);
1644         if(wp==NULL)
1645         {
1646                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1647                 return CMD_STATUS_ERROR;
1648         }
1649
1650         this.havocbot_personal_waypoint = wp;
1651         this.havocbot_personal_waypoint_failcounter = 0;
1652         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1653
1654         // if pos is inside a teleport, then let's mark it as teleport waypoint
1655         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1656         {
1657                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1658                 this.lastteleporttime = 0;
1659         });
1660
1661 /*
1662         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1663                 print("routing to a teleporter\n");
1664         else
1665                 print("routing to a non-teleporter\n");
1666 */
1667
1668         return CMD_STATUS_EXECUTING;
1669 }
1670
1671 float havocbot_resetgoal(entity this)
1672 {
1673         navigation_clearroute(this);
1674         return CMD_STATUS_FINISHED;
1675 }
1676
1677 void havocbot_setupbot(entity this)
1678 {
1679         this.bot_ai = havocbot_ai;
1680         this.cmd_moveto = havocbot_moveto;
1681         this.cmd_resetgoal = havocbot_resetgoal;
1682
1683         // NOTE: bot is not player yet
1684         havocbot_chooserole(this);
1685 }
1686
1687 vector havocbot_dodge(entity this)
1688 {
1689         // LordHavoc: disabled because this is too expensive
1690         return '0 0 0';
1691 #if 0
1692         entity head;
1693         vector dodge, v, n;
1694         float danger, bestdanger, vl, d;
1695         dodge = '0 0 0';
1696         bestdanger = -20;
1697         // check for dangerous objects near bot or approaching bot
1698         head = findchainfloat(bot_dodge, true);
1699         while(head)
1700         {
1701                 if (head.owner != this)
1702                 {
1703                         vl = vlen(head.velocity);
1704                         if (vl > autocvar_sv_maxspeed * 0.3)
1705                         {
1706                                 n = normalize(head.velocity);
1707                                 v = this.origin - head.origin;
1708                                 d = v * n;
1709                                 if (d > (0 - head.bot_dodgerating))
1710                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1711                                 {
1712                                         // calculate direction and distance from the flight path, by removing the forward axis
1713                                         v = v - (n * (v * n));
1714                                         danger = head.bot_dodgerating - vlen(v);
1715                                         if (bestdanger < danger)
1716                                         {
1717                                                 bestdanger = danger;
1718                                                 // dodge to the side of the object
1719                                                 dodge = normalize(v);
1720                                         }
1721                                 }
1722                         }
1723                         else
1724                         {
1725                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1726                                 if (bestdanger < danger)
1727                                 {
1728                                         bestdanger = danger;
1729                                         dodge = normalize(this.origin - head.origin);
1730                                 }
1731                         }
1732                 }
1733                 head = head.chain;
1734         }
1735         return dodge;
1736 #endif
1737 }