qcsrc/menu/xonotic/statslist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticStatsList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticStatsList, configureXonoticStatsList, void(entity))
   4         ATTRIB(XonoticStatsList, rowsPerItem, float, 1.4)
   5         METHOD(XonoticStatsList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticStatsList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticStatsList, getStats, void(entity))
   8         METHOD(XonoticStatsList, clickListBoxItem, void(entity, float, vector))
   9         METHOD(XonoticStatsList, keyDown, float(entity, float, float, float))
  10         METHOD(XonoticStatsList, destroy, void(entity))
  11         METHOD(XonoticStatsList, showNotify, void(entity))
  12
  13         ATTRIB(XonoticStatsList, listStats, float, -1)
  14         ATTRIB(XonoticStatsList, realFontSize, vector, '0 0 0')
  15         ATTRIB(XonoticStatsList, realUpperMargin, float, 0)
  16         ATTRIB(XonoticStatsList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticStatsList, columnNameSize, float, 0)
  18
  19         ATTRIB(XonoticStatsList, lastClickedDemo, float, -1)
  20         ATTRIB(XonoticStatsList, lastClickedTime, float, 0)
  21 ENDCLASS(XonoticStatsList)
  22
  23 entity statslist; // for reference elsewhere
  24 entity makeXonoticStatsList();
  25 #endif
  26
  27 #ifdef IMPLEMENTATION
  28
  29 entity makeXonoticStatsList()
  30 {
  31         entity me;
  32         me = spawnXonoticStatsList();
  33         me.configureXonoticStatsList(me);
  34         return me;
  35 }
  36
  37 void XonoticStatsList_configureXonoticStatsList(entity me)
  38 {
  39         me.configureXonoticListBox(me);
  40         me.getStats(me);
  41 }
  42
  43 void XonoticStatsList_getStats(entity me)
  44 {
  45         print("XonoticStatsList_getStats() at time: ", ftos(time), "\n");
  46         if (me.listStats >= 0)
  47                 buf_del(me.listStats);
  48         me.listStats = buf_create();
  49         if (me.listStats < 0)
  50         {
  51                 me.nItems = 0;
  52                 return;
  53         }
  54
  55         float order = 0;
  56         string e = "", en = "", data = "";
  57
  58         string outstr = ""; // NOTE: out string MUST use underscores for spaces here, we'll replace them later
  59         string orderstr = "";
  60
  61         float out_total_matches = -1;
  62         float out_total_wins = -1;
  63         float out_total_losses = -1;
  64
  65         float out_total_kills = -1;
  66         float out_total_deaths = -1;
  67
  68         for(e = PS_D_IN_EVL; (en = db_get(PS_D_IN_DB, e)) != ""; e = en)
  69         {
  70                 order = 0;
  71                 outstr = "";
  72                 orderstr = "";
  73                 data = db_get(PS_D_IN_DB, sprintf("#%s", e));
  74
  75                 // non-gamemode specific stuff
  76                 switch(e)
  77                 {
  78                         case "overall/joined_dt":
  79                         {
  80                                 order = 1;
  81                                 outstr = _("Joined:");
  82                                 data = car(data);
  83                                 break;
  84                         }
  85                         case "overall/last_seen_dt":
  86                         {
  87                                 order = 1;
  88                                 outstr = _("Last_Seen:");
  89                                 data = car(data);
  90                                 break;
  91                         }
  92                         case "overall/alivetime":
  93                         {
  94                                 order = 1;
  95                                 outstr = _("Time_Played:");
  96                                 data = process_time(3, stof(data));
  97                                 break;
  98                         }
  99                         case "overall/favorite-map":
 100                         {
 101                                 order = 2;
 102                                 outstr = _("Favorite_Map:");
 103                                 data = car(data);
 104                                 break;
 105                         }
 106                         case "overall/matches":
 107                         {
 108                                 order = -1;
 109                                 out_total_matches = stof(data);
 110                                 break;
 111                         }
 112                         case "overall/wins":
 113                         {
 114                                 order = -1;
 115                                 out_total_wins = stof(data);
 116                                 break;
 117                         }
 118                         case "overall/total-kills":
 119                         {
 120                                 order = -1;
 121                                 out_total_kills = stof(data);
 122                                 break;
 123                         }
 124                         case "overall/total-deaths":
 125                         {
 126                                 order = -1;
 127                                 out_total_deaths = stof(data);
 128                                 break;
 129                         }
 130                 }
 131
 132                 if((order == -1) && (out_total_matches >= 0) && (out_total_wins >= 0))
 133                 {
 134                         bufstr_add(me.listStats, sprintf("003Matches: %d", out_total_matches), TRUE);
 135
 136                         if(out_total_matches > 0) // don't show extra info if there are no matches played
 137                         {
 138                                 out_total_losses = max(0, (out_total_matches - out_total_wins));
 139                                 bufstr_add(me.listStats, sprintf("003Wins/Losses: %d/%d", out_total_wins, out_total_losses), TRUE);
 140                                 bufstr_add(me.listStats, sprintf("004Win_Percentage: %d%%", ((out_total_wins / out_total_matches) * 100)), TRUE);
 141                         }
 142
 143                         out_total_matches = -1;
 144                         out_total_wins = -1;
 145                         out_total_losses = -1;
 146                         continue;
 147                 }
 148
 149                 if((order == -1) && (out_total_kills >= 0) && (out_total_deaths >= 0))
 150                 {
 151                         bufstr_add(me.listStats, sprintf("005Kills/Deaths: %d/%d", out_total_kills, out_total_deaths), TRUE);
 152
 153                         // if there are no deaths, just show kill count
 154                         if(out_total_deaths > 0)
 155                                 bufstr_add(me.listStats, sprintf("006Kill_Ratio: %.2f", (out_total_kills / out_total_deaths)), TRUE);
 156                         else
 157                                 bufstr_add(me.listStats, sprintf("006Kill_Ratio: %.2f", out_total_kills), TRUE);
 158
 159                         out_total_kills = -1;
 160                         out_total_deaths = -1;
 161                         continue;
 162                 }
 163
 164                 // game mode specific stuff
 165                 if(order > 0)
 166                 {
 167                         orderstr = sprintf("%03d", order);
 168                 }
 169                 else
 170                 {
 171                         float dividerpos = strstrofs(e, "/", 0);
 172                         string gametype = substring(e, 0, dividerpos);
 173                         string event = substring(e, (dividerpos + 1), strlen(e) - (dividerpos + 1));
 174
 175                         // if we are ranked, read these sets of possible options
 176                         if(stof(db_get(PS_D_IN_DB, sprintf("#%s/rank", gametype))))
 177                         {
 178                                 switch(event)
 179                                 {
 180                                         case "matches":
 181                                         {
 182                                                 order = 1;
 183                                                 outstr = sprintf(_("%s_Matches:"), strtoupper(gametype));
 184                                                 //data = sprintf(_("%d (unranked)"), data);
 185                                                 break;
 186                                         }
 187                                         case "elo":
 188                                         {
 189                                                 order = 2;
 190                                                 outstr = sprintf(_("%s_ELO:"), strtoupper(gametype));
 191                                                 data = sprintf("%d", stof(data));
 192                                                 break;
 193                                         }
 194                                         case "rank":
 195                                         {
 196                                                 order = 3;
 197                                                 outstr = sprintf(_("%s_Rank:"), strtoupper(gametype));
 198                                                 data = sprintf("%d", stof(data));
 199                                                 break;
 200                                         }
 201                                         case "percentile":
 202                                         {
 203                                                 order = 4;
 204                                                 outstr = sprintf(_("%s_Percentile:"), strtoupper(gametype));
 205                                                 data = sprintf("%d%%", stof(data));
 206                                                 break;
 207                                         }
 208
 209                                         #if 0
 210                                         case "favorite-map":
 211                                         {
 212                                                 order = 5;
 213                                                 outstr = sprintf(_("%s_Favorite_Map:"), strtoupper(gametype));
 214                                                 //data = sprintf(_("%d (unranked)"), data);
 215                                                 break;
 216                                         }
 217                                         #endif
 218
 219                                         default: continue; // nothing to see here
 220                                 }
 221
 222                                 // now set up order for sorting later
 223                                 orderstr = sprintf("%2.2s%d", gametype, order);
 224                         }
 225                         else if(event == "matches")
 226                         {
 227                                 outstr = sprintf(_("%s_Matches:"), strtoupper(gametype));
 228                                 data = sprintf(_("%d (unranked)"), stof(data));
 229
 230                                 // unranked game modes ALWAYS get put last
 231                                 orderstr = "zzz";
 232                         }
 233                         else { continue; }
 234                 }
 235
 236                 bufstr_add(me.listStats, sprintf("%s%s %s", orderstr, outstr, data), TRUE);
 237         }
 238
 239         me.nItems = buf_getsize(me.listStats);
 240         if(me.nItems > 0)
 241                 buf_sort(me.listStats, 128, FALSE);
 242 }
 243
 244 void XonoticStatsList_destroy(entity me)
 245 {
 246         if(me.nItems > 0)
 247                 buf_del(me.listStats);
 248 }
 249
 250 void XonoticStatsList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 251 {
 252         me.itemAbsSize = '0 0 0';
 253         SUPER(XonoticStatsList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 254
 255         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 256         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 257         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 258
 259 #if 0
 260         me.columnNameOrigin = me.realFontSize_x;
 261         me.columnNameSize = 0.5 - me.realFontSize_x; // end halfway at maximum length
 262         me.columnDataOrigin = me.columnNameOrigin + me.columnNameSize;
 263         me.columnDataSize = 1 - me.columnNameSize - me.realFontSize_x; // fill the rest of the control
 264 #else
 265         me.columnNameOrigin = me.realFontSize_x;
 266         me.columnNameSize = 1 - 2 * me.realFontSize_x;
 267 #endif
 268 }
 269
 270 void XonoticStatsList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 271 {
 272         if(isSelected)
 273                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 274
 275         string data = bufstr_get(me.listStats, i);
 276         string s = car(data);
 277         string d = cdr(data);
 278
 279         s = substring(s, 3, strlen(s) - 3);
 280         s = strreplace("_", " ", s);
 281         s = draw_TextShortenToWidth(s, 0.5 * me.columnNameSize, 0, me.realFontSize);
 282         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 1);
 283
 284         d = draw_TextShortenToWidth(d, me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize), 0, me.realFontSize);
 285         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 1 * (me.columnNameSize - draw_TextWidth(d, 0, me.realFontSize))) * eX, d, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 1);
 286 }
 287
 288 void XonoticStatsList_showNotify(entity me)
 289 {
 290         PlayerStats_PlayerDetail();
 291 }
 292
 293 void XonoticStatsList_clickListBoxItem(entity me, float i, vector where)
 294 {
 295         if(i == me.lastClickedDemo)
 296                 if(time < me.lastClickedTime + 0.3)
 297                 {
 298                         // DOUBLE CLICK!
 299                         me.setSelected(me, i);
 300                         //DemoConfirm_ListClick_Check_Gamestatus(me);
 301                 }
 302         me.lastClickedDemo = i;
 303         me.lastClickedTime = time;
 304 }
 305
 306 float XonoticStatsList_keyDown(entity me, float scan, float ascii, float shift)
 307 {
 308         if(scan == K_ENTER || scan == K_KP_ENTER)
 309         {
 310                 //DemoConfirm_ListClick_Check_Gamestatus(me);
 311                 return 1;
 312         }
 313         else
 314         {
 315                 return SUPER(XonoticStatsList).keyDown(me, scan, ascii, shift);
 316         }
 317 }
 318 #endif
 319